lib/Target/X86/X86InstrFPStack.td

   1 //==- X86InstrFPStack.td - Describe the X86 Instruction Set -------*- C++ -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Evan Cheng and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 x87 FPU instruction set, defining the
  11 // instructions, and properties of the instructions which are needed for code
  12 // generation, machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // FPStack specific DAG Nodes.
  18 //===----------------------------------------------------------------------===//
  19
  20 def SDTX86FpGet     : SDTypeProfile<1, 0, [SDTCisFP<0>]>;
  21 def SDTX86FpSet     : SDTypeProfile<0, 1, [SDTCisFP<0>]>;
  22 def SDTX86Fld       : SDTypeProfile<1, 2, [SDTCisFP<0>,
  23                                            SDTCisPtrTy<1>,
  24                                            SDTCisVT<2, OtherVT>]>;
  25 def SDTX86Fst       : SDTypeProfile<0, 3, [SDTCisFP<0>,
  26                                            SDTCisPtrTy<1>,
  27                                            SDTCisVT<2, OtherVT>]>;
  28 def SDTX86Fild      : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisPtrTy<1>,
  29                                            SDTCisVT<2, OtherVT>]>;
  30 def SDTX86FpToIMem  : SDTypeProfile<0, 2, [SDTCisFP<0>, SDTCisPtrTy<1>]>;
  31
  32 def X86fpget        : SDNode<"X86ISD::FP_GET_RESULT", SDTX86FpGet,
  33                         [SDNPHasChain, SDNPInFlag, SDNPOutFlag]>;
  34 def X86fpset        : SDNode<"X86ISD::FP_SET_RESULT", SDTX86FpSet,
  35                         [SDNPHasChain, SDNPOutFlag]>;
  36 def X86fld          : SDNode<"X86ISD::FLD",      SDTX86Fld,
  37                         [SDNPHasChain]>;
  38 def X86fst          : SDNode<"X86ISD::FST",      SDTX86Fst,
  39                         [SDNPHasChain, SDNPInFlag]>;
  40 def X86fild         : SDNode<"X86ISD::FILD",     SDTX86Fild,
  41                         [SDNPHasChain]>;
  42 def X86fildflag     : SDNode<"X86ISD::FILD_FLAG",SDTX86Fild,
  43                         [SDNPHasChain, SDNPOutFlag]>;
  44 def X86fp_to_i16mem : SDNode<"X86ISD::FP_TO_INT16_IN_MEM", SDTX86FpToIMem,
  45                         [SDNPHasChain]>;
  46 def X86fp_to_i32mem : SDNode<"X86ISD::FP_TO_INT32_IN_MEM", SDTX86FpToIMem,
  47                         [SDNPHasChain]>;
  48 def X86fp_to_i64mem : SDNode<"X86ISD::FP_TO_INT64_IN_MEM", SDTX86FpToIMem,
  49                         [SDNPHasChain]>;
  50
  51 //===----------------------------------------------------------------------===//
  52 // FPStack pattern fragments
  53 //===----------------------------------------------------------------------===//
  54
  55 def fpimm0 : PatLeaf<(fpimm), [{
  56   return N->isExactlyValue(+0.0);
  57 }]>;
  58
  59 def fpimmneg0 : PatLeaf<(fpimm), [{
  60   return N->isExactlyValue(-0.0);
  61 }]>;
  62
  63 def fpimm1 : PatLeaf<(fpimm), [{
  64   return N->isExactlyValue(+1.0);
  65 }]>;
  66
  67 def fpimmneg1 : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(-1.0);
  69 }]>;
  70
  71 // Some 'special' instructions
  72 let usesCustomDAGSchedInserter = 1 in {  // Expanded by the scheduler.
  73   def FP32_TO_INT16_IN_MEM : I<0, Pseudo,
  74                               (outs), (ins i16mem:$dst, RFP32:$src),
  75                               "#FP32_TO_INT16_IN_MEM PSEUDO!",
  76                               [(X86fp_to_i16mem RFP32:$src, addr:$dst)]>;
  77   def FP32_TO_INT32_IN_MEM : I<0, Pseudo,
  78                               (outs), (ins i32mem:$dst, RFP32:$src),
  79                               "#FP32_TO_INT32_IN_MEM PSEUDO!",
  80                               [(X86fp_to_i32mem RFP32:$src, addr:$dst)]>;
  81   def FP32_TO_INT64_IN_MEM : I<0, Pseudo,
  82                               (outs), (ins i64mem:$dst, RFP32:$src),
  83                               "#FP32_TO_INT64_IN_MEM PSEUDO!",
  84                               [(X86fp_to_i64mem RFP32:$src, addr:$dst)]>;
  85   def FP64_TO_INT16_IN_MEM : I<0, Pseudo,
  86                               (outs), (ins i16mem:$dst, RFP64:$src),
  87                               "#FP64_TO_INT16_IN_MEM PSEUDO!",
  88                               [(X86fp_to_i16mem RFP64:$src, addr:$dst)]>;
  89   def FP64_TO_INT32_IN_MEM : I<0, Pseudo,
  90                               (outs), (ins i32mem:$dst, RFP64:$src),
  91                               "#FP64_TO_INT32_IN_MEM PSEUDO!",
  92                               [(X86fp_to_i32mem RFP64:$src, addr:$dst)]>;
  93   def FP64_TO_INT64_IN_MEM : I<0, Pseudo,
  94                               (outs), (ins i64mem:$dst, RFP64:$src),
  95                               "#FP64_TO_INT64_IN_MEM PSEUDO!",
  96                               [(X86fp_to_i64mem RFP64:$src, addr:$dst)]>;
  97   def FP80_TO_INT16_IN_MEM : I<0, Pseudo,
  98                               (outs), (ins i16mem:$dst, RFP80:$src),
  99                               "#FP80_TO_INT16_IN_MEM PSEUDO!",
 100                               [(X86fp_to_i16mem RFP80:$src, addr:$dst)]>;
 101   def FP80_TO_INT32_IN_MEM : I<0, Pseudo,
 102                               (outs), (ins i32mem:$dst, RFP80:$src),
 103                               "#FP80_TO_INT32_IN_MEM PSEUDO!",
 104                               [(X86fp_to_i32mem RFP80:$src, addr:$dst)]>;
 105   def FP80_TO_INT64_IN_MEM : I<0, Pseudo,
 106                               (outs), (ins i64mem:$dst, RFP80:$src),
 107                               "#FP80_TO_INT64_IN_MEM PSEUDO!",
 108                               [(X86fp_to_i64mem RFP80:$src, addr:$dst)]>;
 109 }
 110
 111 let isTerminator = 1 in
 112   let Defs = [FP0, FP1, FP2, FP3, FP4, FP5, FP6] in
 113     def FP_REG_KILL  : I<0, Pseudo, (outs), (ins), "#FP_REG_KILL", []>;
 114
 115 // All FP Stack operations are represented with four instructions here.  The
 116 // first three instructions, generated by the instruction selector, use "RFP32"
 117 // "RFP64" or "RFP80" registers: traditional register files to reference 32-bit,
 118 // 64-bit or 80-bit floating point values.  These sizes apply to the values,
 119 // not the registers, which are always 80 bits; RFP32, RFP64 and RFP80 can be
 120 // copied to each other without losing information.  These instructions are all
 121 // pseudo instructions and use the "_Fp" suffix.
 122 // In some cases there are additional variants with a mixture of different
 123 // register sizes.
 124 // The second instruction is defined with FPI, which is the actual instruction
 125 // emitted by the assembler.  These use "RST" registers, although frequently
 126 // the actual register(s) used are implicit.  These are always 80 bits.
 127 // The FP stackifier pass converts one to the other after register allocation
 128 // occurs.
 129 //
 130 // Note that the FpI instruction should have instruction selection info (e.g.
 131 // a pattern) and the FPI instruction should have emission info (e.g. opcode
 132 // encoding and asm printing info).
 133
 134 // Pseudo Instructions for FP stack return values.
 135 def FpGETRESULT32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP,
 136                       [(set RFP32:$dst, X86fpget)]>;           // FPR = ST(0)
 137
 138 def FpGETRESULT64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP,
 139                       [(set RFP64:$dst, X86fpget)]>;           // FPR = ST(0)
 140
 141 def FpGETRESULT80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP,
 142                       [(set RFP80:$dst, X86fpget)]>;           // FPR = ST(0)
 143
 144 let Defs = [ST0] in {
 145 def FpSETRESULT32 : FpI_<(outs), (ins RFP32:$src), SpecialFP,
 146                       [(X86fpset RFP32:$src)]>;// ST(0) = FPR
 147
 148 def FpSETRESULT64 : FpI_<(outs), (ins RFP64:$src), SpecialFP,
 149                       [(X86fpset RFP64:$src)]>;// ST(0) = FPR
 150
 151 def FpSETRESULT80 : FpI_<(outs), (ins RFP80:$src), SpecialFP,
 152                       [(X86fpset RFP80:$src)]>;// ST(0) = FPR
 153 }
 154
 155 // FpIf32, FpIf64 - Floating Point Psuedo Instruction template.
 156 // f32 instructions can use SSE1 and are predicated on FPStackf32 == !SSE1.
 157 // f64 instructions can use SSE2 and are predicated on FPStackf64 == !SSE2.
 158 // f80 instructions cannot use SSE and use neither of these.
 159 class FpIf32<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 160   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf32]>;
 161 class FpIf64<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 162   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf64]>;
 163
 164 // Register copies.  Just copies, the shortening ones do not truncate.
 165 def MOV_Fp3232       : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), SpecialFP, []>;
 166 def MOV_Fp3264       : FpIf32<(outs RFP64:$dst), (ins RFP32:$src), SpecialFP, []>;
 167 def MOV_Fp6432       : FpIf32<(outs RFP32:$dst), (ins RFP64:$src), SpecialFP, []>;
 168 def MOV_Fp6464       : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), SpecialFP, []>;
 169 def MOV_Fp8032       : FpIf32<(outs RFP32:$dst), (ins RFP80:$src), SpecialFP, []>;
 170 def MOV_Fp3280       : FpIf32<(outs RFP80:$dst), (ins RFP32:$src), SpecialFP, []>;
 171 def MOV_Fp8064       : FpIf64<(outs RFP64:$dst), (ins RFP80:$src), SpecialFP, []>;
 172 def MOV_Fp6480       : FpIf64<(outs RFP80:$dst), (ins RFP64:$src), SpecialFP, []>;
 173 def MOV_Fp8080       : FpI_<(outs RFP80:$dst), (ins RFP80:$src), SpecialFP, []>;
 174
 175 // Factoring for arithmetic.
 176 multiclass FPBinary_rr<SDNode OpNode> {
 177 // Register op register -> register
 178 // These are separated out because they have no reversed form.
 179 def _Fp32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), TwoArgFP,
 180                 [(set RFP32:$dst, (OpNode RFP32:$src1, RFP32:$src2))]>;
 181 def _Fp64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), TwoArgFP,
 182                 [(set RFP64:$dst, (OpNode RFP64:$src1, RFP64:$src2))]>;
 183 def _Fp80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2), TwoArgFP,
 184                 [(set RFP80:$dst, (OpNode RFP80:$src1, RFP80:$src2))]>;
 185 }
 186 // The FopST0 series are not included here because of the irregularities
 187 // in where the 'r' goes in assembly output.
 188 // These instructions cannot address 80-bit memory.
 189 multiclass FPBinary<SDNode OpNode, Format fp, string asmstring> {
 190 // ST(0) = ST(0) + [mem]
 191 def _Fp32m  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, f32mem:$src2), OneArgFPRW,
 192                   [(set RFP32:$dst,
 193                     (OpNode RFP32:$src1, (loadf32 addr:$src2)))]>;
 194 def _Fp64m  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, f64mem:$src2), OneArgFPRW,
 195                   [(set RFP64:$dst,
 196                     (OpNode RFP64:$src1, (loadf64 addr:$src2)))]>;
 197 def _Fp64m32: FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, f32mem:$src2), OneArgFPRW,
 198                   [(set RFP64:$dst,
 199                     (OpNode RFP64:$src1, (f64 (extloadf32 addr:$src2))))]>;
 200 def _Fp80m32: FpI_<(outs RFP80:$dst), (ins RFP80:$src1, f32mem:$src2), OneArgFPRW,
 201                   [(set RFP80:$dst,
 202                     (OpNode RFP80:$src1, (f80 (extloadf32 addr:$src2))))]>;
 203 def _Fp80m64: FpI_<(outs RFP80:$dst), (ins RFP80:$src1, f64mem:$src2), OneArgFPRW,
 204                   [(set RFP80:$dst,
 205                     (OpNode RFP80:$src1, (f80 (extloadf64 addr:$src2))))]>;
 206 def _F32m  : FPI<0xD8, fp, (outs), (ins f32mem:$src),
 207                  !strconcat("f", !strconcat(asmstring, "{s}\t$src"))>;
 208 def _F64m  : FPI<0xDC, fp, (outs), (ins f64mem:$src),
 209                  !strconcat("f", !strconcat(asmstring, "{l}\t$src"))>;
 210 // ST(0) = ST(0) + [memint]
 211 def _FpI16m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i16mem:$src2), OneArgFPRW,
 212                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 213                                        (X86fild addr:$src2, i16)))]>;
 214 def _FpI32m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i32mem:$src2), OneArgFPRW,
 215                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 216                                        (X86fild addr:$src2, i32)))]>;
 217 def _FpI16m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i16mem:$src2), OneArgFPRW,
 218                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 219                                        (X86fild addr:$src2, i16)))]>;
 220 def _FpI32m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i32mem:$src2), OneArgFPRW,
 221                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 222                                        (X86fild addr:$src2, i32)))]>;
 223 def _FpI16m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i16mem:$src2), OneArgFPRW,
 224                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 225                                        (X86fild addr:$src2, i16)))]>;
 226 def _FpI32m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i32mem:$src2), OneArgFPRW,
 227                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 228                                        (X86fild addr:$src2, i32)))]>;
 229 def _FI16m  : FPI<0xDE, fp, (outs), (ins i16mem:$src),
 230                   !strconcat("fi", !strconcat(asmstring, "{s}\t$src"))>;
 231 def _FI32m  : FPI<0xDA, fp, (outs), (ins i32mem:$src),
 232                   !strconcat("fi", !strconcat(asmstring, "{l}\t$src"))>;
 233 }
 234
 235 defm ADD : FPBinary_rr<fadd>;
 236 defm SUB : FPBinary_rr<fsub>;
 237 defm MUL : FPBinary_rr<fmul>;
 238 defm DIV : FPBinary_rr<fdiv>;
 239 defm ADD : FPBinary<fadd, MRM0m, "add">;
 240 defm SUB : FPBinary<fsub, MRM4m, "sub">;
 241 defm SUBR: FPBinary<fsub ,MRM5m, "subr">;
 242 defm MUL : FPBinary<fmul, MRM1m, "mul">;
 243 defm DIV : FPBinary<fdiv, MRM6m, "div">;
 244 defm DIVR: FPBinary<fdiv, MRM7m, "divr">;
 245
 246 class FPST0rInst<bits<8> o, string asm>
 247   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, D8;
 248 class FPrST0Inst<bits<8> o, string asm>
 249   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DC;
 250 class FPrST0PInst<bits<8> o, string asm>
 251   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DE;
 252
 253 // NOTE: GAS and apparently all other AT&T style assemblers have a broken notion
 254 // of some of the 'reverse' forms of the fsub and fdiv instructions.  As such,
 255 // we have to put some 'r's in and take them out of weird places.
 256 def ADD_FST0r   : FPST0rInst <0xC0, "fadd\t$op">;
 257 def ADD_FrST0   : FPrST0Inst <0xC0, "fadd\t{%st(0), $op|$op, %ST(0)}">;
 258 def ADD_FPrST0  : FPrST0PInst<0xC0, "faddp\t$op">;
 259 def SUBR_FST0r  : FPST0rInst <0xE8, "fsubr\t$op">;
 260 def SUB_FrST0   : FPrST0Inst <0xE8, "fsub{r}\t{%st(0), $op|$op, %ST(0)}">;
 261 def SUB_FPrST0  : FPrST0PInst<0xE8, "fsub{r}p\t$op">;
 262 def SUB_FST0r   : FPST0rInst <0xE0, "fsub\t$op">;
 263 def SUBR_FrST0  : FPrST0Inst <0xE0, "fsub{|r}\t{%st(0), $op|$op, %ST(0)}">;
 264 def SUBR_FPrST0 : FPrST0PInst<0xE0, "fsub{|r}p\t$op">;
 265 def MUL_FST0r   : FPST0rInst <0xC8, "fmul\t$op">;
 266 def MUL_FrST0   : FPrST0Inst <0xC8, "fmul\t{%st(0), $op|$op, %ST(0)}">;
 267 def MUL_FPrST0  : FPrST0PInst<0xC8, "fmulp\t$op">;
 268 def DIVR_FST0r  : FPST0rInst <0xF8, "fdivr\t$op">;
 269 def DIV_FrST0   : FPrST0Inst <0xF8, "fdiv{r}\t{%st(0), $op|$op, %ST(0)}">;
 270 def DIV_FPrST0  : FPrST0PInst<0xF8, "fdiv{r}p\t$op">;
 271 def DIV_FST0r   : FPST0rInst <0xF0, "fdiv\t$op">;
 272 def DIVR_FrST0  : FPrST0Inst <0xF0, "fdiv{|r}\t{%st(0), $op|$op, %ST(0)}">;
 273 def DIVR_FPrST0 : FPrST0PInst<0xF0, "fdiv{|r}p\t$op">;
 274
 275 // Unary operations.
 276 multiclass FPUnary<SDNode OpNode, bits<8> opcode, string asmstring> {
 277 def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), OneArgFPRW,
 278                  [(set RFP32:$dst, (OpNode RFP32:$src))]>;
 279 def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), OneArgFPRW,
 280                  [(set RFP64:$dst, (OpNode RFP64:$src))]>;
 281 def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src), OneArgFPRW,
 282                  [(set RFP80:$dst, (OpNode RFP80:$src))]>;
 283 def _F     : FPI<opcode, RawFrm, (outs), (ins), asmstring>, D9;
 284 }
 285
 286 defm CHS : FPUnary<fneg, 0xE0, "fchs">;
 287 defm ABS : FPUnary<fabs, 0xE1, "fabs">;
 288 defm SQRT: FPUnary<fsqrt,0xFA, "fsqrt">;
 289 defm SIN : FPUnary<fsin, 0xFE, "fsin">;
 290 defm COS : FPUnary<fcos, 0xFF, "fcos">;
 291
 292 def TST_Fp32  : FpIf32<(outs), (ins RFP32:$src), OneArgFP,
 293                  []>;
 294 def TST_Fp64  : FpIf64<(outs), (ins RFP64:$src), OneArgFP,
 295                  []>;
 296 def TST_Fp80  : FpI_<(outs), (ins RFP80:$src), OneArgFP,
 297                  []>;
 298 def TST_F  : FPI<0xE4, RawFrm, (outs), (ins), "ftst">, D9;
 299
 300 // Floating point cmovs.
 301 multiclass FPCMov<PatLeaf cc> {
 302   def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), CondMovFP,
 303                      [(set RFP32:$dst, (X86cmov RFP32:$src1, RFP32:$src2,
 304                                         cc))]>;
 305   def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), CondMovFP,
 306                      [(set RFP64:$dst, (X86cmov RFP64:$src1, RFP64:$src2,
 307                                         cc))]>;
 308   def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2), CondMovFP,
 309                      [(set RFP80:$dst, (X86cmov RFP80:$src1, RFP80:$src2,
 310                                         cc))]>;
 311 }
 312 let isTwoAddress = 1 in {
 313 defm CMOVB  : FPCMov<X86_COND_B>;
 314 defm CMOVBE : FPCMov<X86_COND_BE>;
 315 defm CMOVE  : FPCMov<X86_COND_E>;
 316 defm CMOVP  : FPCMov<X86_COND_P>;
 317 defm CMOVNB : FPCMov<X86_COND_AE>;
 318 defm CMOVNBE: FPCMov<X86_COND_A>;
 319 defm CMOVNE : FPCMov<X86_COND_NE>;
 320 defm CMOVNP : FPCMov<X86_COND_NP>;
 321 }
 322
 323 multiclass NEW_FPCMov<PatLeaf cc> {
 324   def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2),
 325                        CondMovFP,
 326                      [(set RFP32:$dst, (X86cmov_new RFP32:$src1, RFP32:$src2,
 327                                         cc, EFLAGS))]>;
 328   def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2),
 329                        CondMovFP,
 330                      [(set RFP64:$dst, (X86cmov_new RFP64:$src1, RFP64:$src2,
 331                                         cc, EFLAGS))]>;
 332   def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2),
 333                      CondMovFP,
 334                      [(set RFP80:$dst, (X86cmov_new RFP80:$src1, RFP80:$src2,
 335                                         cc, EFLAGS))]>;
 336 }
 337 let Uses = [EFLAGS], isTwoAddress = 1 in {
 338 defm NEW_CMOVB  : NEW_FPCMov<X86_COND_B>;
 339 defm NEW_CMOVBE : NEW_FPCMov<X86_COND_BE>;
 340 defm NEW_CMOVE  : NEW_FPCMov<X86_COND_E>;
 341 defm NEW_CMOVP  : NEW_FPCMov<X86_COND_P>;
 342 defm NEW_CMOVNB : NEW_FPCMov<X86_COND_AE>;
 343 defm NEW_CMOVNBE: NEW_FPCMov<X86_COND_A>;
 344 defm NEW_CMOVNE : NEW_FPCMov<X86_COND_NE>;
 345 defm NEW_CMOVNP : NEW_FPCMov<X86_COND_NP>;
 346 }
 347
 348 // These are not factored because there's no clean way to pass DA/DB.
 349 def CMOVB_F  : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 350                   "fcmovb\t{$op, %st(0)|%ST(0), $op}">, DA;
 351 def CMOVBE_F : FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 352                   "fcmovbe\t{$op, %st(0)|%ST(0), $op}">, DA;
 353 def CMOVE_F  : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 354                   "fcmove\t{$op, %st(0)|%ST(0), $op}">, DA;
 355 def CMOVP_F  : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 356                   "fcmovu\t {$op, %st(0)|%ST(0), $op}">, DA;
 357 def CMOVNB_F : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 358                   "fcmovnb\t{$op, %st(0)|%ST(0), $op}">, DB;
 359 def CMOVNBE_F: FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 360                   "fcmovnbe\t{$op, %st(0)|%ST(0), $op}">, DB;
 361 def CMOVNE_F : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 362                   "fcmovne\t{$op, %st(0)|%ST(0), $op}">, DB;
 363 def CMOVNP_F : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 364                   "fcmovnu\t{$op, %st(0)|%ST(0), $op}">, DB;
 365
 366 // Floating point loads & stores.
 367 let isLoad = 1 in {
 368 def LD_Fp32m   : FpIf32<(outs RFP32:$dst), (ins f32mem:$src), ZeroArgFP,
 369                   [(set RFP32:$dst, (loadf32 addr:$src))]>;
 370 def LD_Fp64m   : FpIf64<(outs RFP64:$dst), (ins f64mem:$src), ZeroArgFP,
 371                   [(set RFP64:$dst, (loadf64 addr:$src))]>;
 372 def LD_Fp80m   : FpI_<(outs RFP80:$dst), (ins f80mem:$src), ZeroArgFP,
 373                   [(set RFP80:$dst, (loadf80 addr:$src))]>;
 374 }
 375 def LD_Fp32m64 : FpIf64<(outs RFP64:$dst), (ins f32mem:$src), ZeroArgFP,
 376                   [(set RFP64:$dst, (f64 (extloadf32 addr:$src)))]>;
 377 def LD_Fp64m80 : FpI_<(outs RFP80:$dst), (ins f64mem:$src), ZeroArgFP,
 378                   [(set RFP80:$dst, (f80 (extloadf64 addr:$src)))]>;
 379 def LD_Fp32m80 : FpI_<(outs RFP80:$dst), (ins f32mem:$src), ZeroArgFP,
 380                   [(set RFP80:$dst, (f80 (extloadf32 addr:$src)))]>;
 381 def ILD_Fp16m32: FpIf32<(outs RFP32:$dst), (ins i16mem:$src), ZeroArgFP,
 382                   [(set RFP32:$dst, (X86fild addr:$src, i16))]>;
 383 def ILD_Fp32m32: FpIf32<(outs RFP32:$dst), (ins i32mem:$src), ZeroArgFP,
 384                   [(set RFP32:$dst, (X86fild addr:$src, i32))]>;
 385 def ILD_Fp64m32: FpIf32<(outs RFP32:$dst), (ins i64mem:$src), ZeroArgFP,
 386                   [(set RFP32:$dst, (X86fild addr:$src, i64))]>;
 387 def ILD_Fp16m64: FpIf64<(outs RFP64:$dst), (ins i16mem:$src), ZeroArgFP,
 388                   [(set RFP64:$dst, (X86fild addr:$src, i16))]>;
 389 def ILD_Fp32m64: FpIf64<(outs RFP64:$dst), (ins i32mem:$src), ZeroArgFP,
 390                   [(set RFP64:$dst, (X86fild addr:$src, i32))]>;
 391 def ILD_Fp64m64: FpIf64<(outs RFP64:$dst), (ins i64mem:$src), ZeroArgFP,
 392                   [(set RFP64:$dst, (X86fild addr:$src, i64))]>;
 393 def ILD_Fp16m80: FpI_<(outs RFP80:$dst), (ins i16mem:$src), ZeroArgFP,
 394                   [(set RFP80:$dst, (X86fild addr:$src, i16))]>;
 395 def ILD_Fp32m80: FpI_<(outs RFP80:$dst), (ins i32mem:$src), ZeroArgFP,
 396                   [(set RFP80:$dst, (X86fild addr:$src, i32))]>;
 397 def ILD_Fp64m80: FpI_<(outs RFP80:$dst), (ins i64mem:$src), ZeroArgFP,
 398                   [(set RFP80:$dst, (X86fild addr:$src, i64))]>;
 399
 400 def ST_Fp32m   : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP,
 401                   [(store RFP32:$src, addr:$op)]>;
 402 def ST_Fp64m32 : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP,
 403                   [(truncstoref32 RFP64:$src, addr:$op)]>;
 404 def ST_Fp64m   : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP,
 405                   [(store RFP64:$src, addr:$op)]>;
 406 def ST_Fp80m32 : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP,
 407                   [(truncstoref32 RFP80:$src, addr:$op)]>;
 408 def ST_Fp80m64 : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP,
 409                   [(truncstoref64 RFP80:$src, addr:$op)]>;
 410 // FST does not support 80-bit memory target; FSTP must be used.
 411
 412 def ST_FpP32m    : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP, []>;
 413 def ST_FpP64m32  : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP, []>;
 414 def ST_FpP64m    : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP, []>;
 415 def ST_FpP80m32  : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP, []>;
 416 def ST_FpP80m64  : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP, []>;
 417 def ST_FpP80m    : FpI_<(outs), (ins f80mem:$op, RFP80:$src), OneArgFP,
 418                     [(store RFP80:$src, addr:$op)]>;
 419 def IST_Fp16m32  : FpIf32<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP, []>;
 420 def IST_Fp32m32  : FpIf32<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP, []>;
 421 def IST_Fp64m32  : FpIf32<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP, []>;
 422 def IST_Fp16m64  : FpIf64<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP, []>;
 423 def IST_Fp32m64  : FpIf64<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP, []>;
 424 def IST_Fp64m64  : FpIf64<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP, []>;
 425 def IST_Fp16m80  : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP, []>;
 426 def IST_Fp32m80  : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP, []>;
 427 def IST_Fp64m80  : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP, []>;
 428
 429 def LD_F32m   : FPI<0xD9, MRM0m, (outs), (ins f32mem:$src), "fld{s}\t$src">;
 430 def LD_F64m   : FPI<0xDD, MRM0m, (outs), (ins f64mem:$src), "fld{l}\t$src">;
 431 def LD_F80m   : FPI<0xDB, MRM5m, (outs), (ins f80mem:$src), "fld{t}\t$src">;
 432 def ILD_F16m  : FPI<0xDF, MRM0m, (outs), (ins i16mem:$src), "fild{s}\t$src">;
 433 def ILD_F32m  : FPI<0xDB, MRM0m, (outs), (ins i32mem:$src), "fild{l}\t$src">;
 434 def ILD_F64m  : FPI<0xDF, MRM5m, (outs), (ins i64mem:$src), "fild{ll}\t$src">;
 435 def ST_F32m   : FPI<0xD9, MRM2m, (outs), (ins f32mem:$dst), "fst{s}\t$dst">;
 436 def ST_F64m   : FPI<0xDD, MRM2m, (outs), (ins f64mem:$dst), "fst{l}\t$dst">;
 437 def ST_FP32m  : FPI<0xD9, MRM3m, (outs), (ins f32mem:$dst), "fstp{s}\t$dst">;
 438 def ST_FP64m  : FPI<0xDD, MRM3m, (outs), (ins f64mem:$dst), "fstp{l}\t$dst">;
 439 def ST_FP80m  : FPI<0xDB, MRM7m, (outs), (ins f80mem:$dst), "fstp{t}\t$dst">;
 440 def IST_F16m  : FPI<0xDF, MRM2m, (outs), (ins i16mem:$dst), "fist{s}\t$dst">;
 441 def IST_F32m  : FPI<0xDB, MRM2m, (outs), (ins i32mem:$dst), "fist{l}\t$dst">;
 442 def IST_FP16m : FPI<0xDF, MRM3m, (outs), (ins i16mem:$dst), "fistp{s}\t$dst">;
 443 def IST_FP32m : FPI<0xDB, MRM3m, (outs), (ins i32mem:$dst), "fistp{l}\t$dst">;
 444 def IST_FP64m : FPI<0xDF, MRM7m, (outs), (ins i64mem:$dst), "fistp{ll}\t$dst">;
 445
 446 // FISTTP requires SSE3 even though it's a FPStack op.
 447 def ISTT_Fp16m32 : FpI_<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP,
 448                     [(X86fp_to_i16mem RFP32:$src, addr:$op)]>,
 449                     Requires<[HasSSE3]>;
 450 def ISTT_Fp32m32 : FpI_<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP,
 451                     [(X86fp_to_i32mem RFP32:$src, addr:$op)]>,
 452                     Requires<[HasSSE3]>;
 453 def ISTT_Fp64m32 : FpI_<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP,
 454                     [(X86fp_to_i64mem RFP32:$src, addr:$op)]>,
 455                     Requires<[HasSSE3]>;
 456 def ISTT_Fp16m64 : FpI_<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP,
 457                     [(X86fp_to_i16mem RFP64:$src, addr:$op)]>,
 458                     Requires<[HasSSE3]>;
 459 def ISTT_Fp32m64 : FpI_<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP,
 460                     [(X86fp_to_i32mem RFP64:$src, addr:$op)]>,
 461                     Requires<[HasSSE3]>;
 462 def ISTT_Fp64m64 : FpI_<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP,
 463                     [(X86fp_to_i64mem RFP64:$src, addr:$op)]>,
 464                     Requires<[HasSSE3]>;
 465 def ISTT_Fp16m80 : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP,
 466                     [(X86fp_to_i16mem RFP80:$src, addr:$op)]>,
 467                     Requires<[HasSSE3]>;
 468 def ISTT_Fp32m80 : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP,
 469                     [(X86fp_to_i32mem RFP80:$src, addr:$op)]>,
 470                     Requires<[HasSSE3]>;
 471 def ISTT_Fp64m80 : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP,
 472                     [(X86fp_to_i64mem RFP80:$src, addr:$op)]>,
 473                     Requires<[HasSSE3]>;
 474
 475 def ISTT_FP16m : FPI<0xDF, MRM1m, (outs), (ins i16mem:$dst), "fisttp{s}\t$dst">;
 476 def ISTT_FP32m : FPI<0xDB, MRM1m, (outs), (ins i32mem:$dst), "fisttp{l}\t$dst">;
 477 def ISTT_FP64m : FPI<0xDD, MRM1m, (outs), (ins i64mem:$dst), "fisttp{ll}\t$dst">;
 478
 479 // FP Stack manipulation instructions.
 480 def LD_Frr   : FPI<0xC0, AddRegFrm, (outs), (ins RST:$op), "fld\t$op">, D9;
 481 def ST_Frr   : FPI<0xD0, AddRegFrm, (outs), (ins RST:$op), "fst\t$op">, DD;
 482 def ST_FPrr  : FPI<0xD8, AddRegFrm, (outs), (ins RST:$op), "fstp\t$op">, DD;
 483 def XCH_F    : FPI<0xC8, AddRegFrm, (outs), (ins RST:$op), "fxch\t$op">, D9;
 484
 485 // Floating point constant loads.
 486 let isReMaterializable = 1 in {
 487 def LD_Fp032 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 488                 [(set RFP32:$dst, fpimm0)]>;
 489 def LD_Fp132 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 490                 [(set RFP32:$dst, fpimm1)]>;
 491 def LD_Fp064 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 492                 [(set RFP64:$dst, fpimm0)]>;
 493 def LD_Fp164 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 494                 [(set RFP64:$dst, fpimm1)]>;
 495 def LD_Fp080 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 496                 [(set RFP80:$dst, fpimm0)]>;
 497 def LD_Fp180 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 498                 [(set RFP80:$dst, fpimm1)]>;
 499 }
 500
 501 def LD_F0 : FPI<0xEE, RawFrm, (outs), (ins), "fldz">, D9;
 502 def LD_F1 : FPI<0xE8, RawFrm, (outs), (ins), "fld1">, D9;
 503
 504
 505 // Floating point compares.
 506 def UCOM_Fpr32 : FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 507                   []>;  // FPSW = cmp ST(0) with ST(i)
 508 def UCOM_FpIr32: FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 509                   [(X86cmp RFP32:$lhs, RFP32:$rhs)]>; // CC = ST(0) cmp ST(i)
 510 def UCOM_Fpr64 : FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 511                   []>;  // FPSW = cmp ST(0) with ST(i)
 512 def UCOM_FpIr64: FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 513                   [(X86cmp RFP64:$lhs, RFP64:$rhs)]>; // CC = ST(0) cmp ST(i)
 514 def UCOM_Fpr80 : FpI_<(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 515                   []>;  // FPSW = cmp ST(0) with ST(i)
 516 def UCOM_FpIr80: FpI_<(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 517                   [(X86cmp RFP80:$lhs, RFP80:$rhs)]>; // CC = ST(0) cmp ST(i)
 518
 519 let Defs = [EFLAGS], Uses = [ST0] in {
 520 def UCOM_Fr    : FPI<0xE0, AddRegFrm,    // FPSW = cmp ST(0) with ST(i)
 521                     (outs), (ins RST:$reg),
 522                     "fucom\t$reg">, DD;
 523 def UCOM_FPr   : FPI<0xE8, AddRegFrm,    // FPSW = cmp ST(0) with ST(i), pop
 524                     (outs), (ins RST:$reg),
 525                     "fucomp\t$reg">, DD;
 526 def UCOM_FPPr  : FPI<0xE9, RawFrm,       // cmp ST(0) with ST(1), pop, pop
 527                     (outs), (ins),
 528                     "fucompp">, DA;
 529
 530 def UCOM_FIr   : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i)
 531                     (outs), (ins RST:$reg),
 532                     "fucomi\t{$reg, %st(0)|%ST(0), $reg}">, DB;
 533 def UCOM_FIPr  : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i), pop
 534                     (outs), (ins RST:$reg),
 535                     "fucomip\t{$reg, %st(0)|%ST(0), $reg}">, DF;
 536 }
 537
 538 // Floating point flag ops.
 539 let Defs = [AX] in
 540 def FNSTSW8r  : I<0xE0, RawFrm,                  // AX = fp flags
 541                   (outs), (ins), "fnstsw", []>, DF;
 542
 543 def FNSTCW16m : I<0xD9, MRM7m,                   // [mem16] = X87 control world
 544                   (outs), (ins i16mem:$dst), "fnstcw\t$dst", []>;
 545 def FLDCW16m  : I<0xD9, MRM5m,                   // X87 control world = [mem16]
 546                   (outs), (ins i16mem:$dst), "fldcw\t$dst", []>;
 547
 548 //===----------------------------------------------------------------------===//
 549 // Non-Instruction Patterns
 550 //===----------------------------------------------------------------------===//
 551
 552 // Required for RET of f32 / f64 / f80 values.
 553 def : Pat<(X86fld addr:$src, f32), (LD_Fp32m addr:$src)>;
 554 def : Pat<(X86fld addr:$src, f64), (LD_Fp64m addr:$src)>;
 555 def : Pat<(X86fld addr:$src, f80), (LD_Fp80m addr:$src)>;
 556
 557 // Required for CALL which return f32 / f64 / f80 values.
 558 def : Pat<(X86fst RFP32:$src, addr:$op, f32), (ST_Fp32m addr:$op, RFP32:$src)>;
 559 def : Pat<(X86fst RFP64:$src, addr:$op, f32), (ST_Fp64m32 addr:$op, RFP64:$src)>;
 560 def : Pat<(X86fst RFP64:$src, addr:$op, f64), (ST_Fp64m addr:$op, RFP64:$src)>;
 561 def : Pat<(X86fst RFP80:$src, addr:$op, f32), (ST_Fp80m32 addr:$op, RFP80:$src)>;
 562 def : Pat<(X86fst RFP80:$src, addr:$op, f64), (ST_Fp80m64 addr:$op, RFP80:$src)>;
 563 def : Pat<(X86fst RFP80:$src, addr:$op, f80), (ST_FpP80m addr:$op, RFP80:$src)>;
 564
 565 // Floating point constant -0.0 and -1.0
 566 def : Pat<(f32 fpimmneg0), (CHS_Fp32 (LD_Fp032))>, Requires<[FPStackf32]>;
 567 def : Pat<(f32 fpimmneg1), (CHS_Fp32 (LD_Fp132))>, Requires<[FPStackf32]>;
 568 def : Pat<(f64 fpimmneg0), (CHS_Fp64 (LD_Fp064))>, Requires<[FPStackf64]>;
 569 def : Pat<(f64 fpimmneg1), (CHS_Fp64 (LD_Fp164))>, Requires<[FPStackf64]>;
 570 def : Pat<(f80 fpimmneg0), (CHS_Fp80 (LD_Fp080))>;
 571 def : Pat<(f80 fpimmneg1), (CHS_Fp80 (LD_Fp180))>;
 572
 573 // Used to conv. i64 to f64 since there isn't a SSE version.
 574 def : Pat<(X86fildflag addr:$src, i64), (ILD_Fp64m64 addr:$src)>;
 575
 576 def : Pat<(f64 (fextend RFP32:$src)), (MOV_Fp3264 RFP32:$src)>, Requires<[FPStackf32]>;
 577 def : Pat<(f80 (fextend RFP32:$src)), (MOV_Fp3280 RFP32:$src)>, Requires<[FPStackf32]>;
 578 def : Pat<(f80 (fextend RFP64:$src)), (MOV_Fp6480 RFP64:$src)>, Requires<[FPStackf64]>;