include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 // IntrNoduplicate - Calls to this intrinsic cannot be duplicated.
  73 // Parallels the noduplicate attribute on LLVM IR functions.
  74 def IntrNoDuplicate : IntrinsicProperty;
  75
  76 //===----------------------------------------------------------------------===//
  77 // Types used by intrinsics.
  78 //===----------------------------------------------------------------------===//
  79
  80 class LLVMType<ValueType vt> {
  81   ValueType VT = vt;
  82 }
  83
  84 class LLVMQualPointerType<LLVMType elty, int addrspace>
  85   : LLVMType<iPTR>{
  86   LLVMType ElTy = elty;
  87   int AddrSpace = addrspace;
  88 }
  89
  90 class LLVMPointerType<LLVMType elty>
  91   : LLVMQualPointerType<elty, 0>;
  92
  93 class LLVMAnyPointerType<LLVMType elty>
  94   : LLVMType<iPTRAny>{
  95   LLVMType ElTy = elty;
  96 }
  97
  98 // Match the type of another intrinsic parameter.  Number is an index into the
  99 // list of overloaded types for the intrinsic, excluding all the fixed types.
 100 // The Number value must refer to a previously listed type.  For example:
 101 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
 102 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
 103 // refers to the first overloaded type, which is the 2nd argument.
 104 class LLVMMatchType<int num>
 105   : LLVMType<OtherVT>{
 106   int Number = num;
 107 }
 108
 109 // Match the type of another intrinsic parameter that is expected to be based on
 110 // an integral type (i.e. either iN or <N x iM>), but change the scalar size to
 111 // be twice as wide or half as wide as the other type.  This is only useful when
 112 // the intrinsic is overloaded, so the matched type should be declared as iAny.
 113 class LLVMExtendedType<int num> : LLVMMatchType<num>;
 114 class LLVMTruncatedType<int num> : LLVMMatchType<num>;
 115 class LLVMVectorSameWidth<int num, LLVMType elty>
 116   : LLVMMatchType<num> {
 117   ValueType ElTy = elty.VT;
 118 }
 119 class LLVMPointerTo<int num> : LLVMMatchType<num>;
 120 class LLVMVectorOfPointersToElt<int num> : LLVMMatchType<num>;
 121
 122 // Match the type of another intrinsic parameter that is expected to be a
 123 // vector type, but change the element count to be half as many
 124 class LLVMHalfElementsVectorType<int num> : LLVMMatchType<num>;
 125
 126 def llvm_void_ty       : LLVMType<isVoid>;
 127 def llvm_any_ty        : LLVMType<Any>;
 128 def llvm_anyint_ty     : LLVMType<iAny>;
 129 def llvm_anyfloat_ty   : LLVMType<fAny>;
 130 def llvm_anyvector_ty  : LLVMType<vAny>;
 131 def llvm_i1_ty         : LLVMType<i1>;
 132 def llvm_i8_ty         : LLVMType<i8>;
 133 def llvm_i16_ty        : LLVMType<i16>;
 134 def llvm_i32_ty        : LLVMType<i32>;
 135 def llvm_i64_ty        : LLVMType<i64>;
 136 def llvm_half_ty       : LLVMType<f16>;
 137 def llvm_float_ty      : LLVMType<f32>;
 138 def llvm_double_ty     : LLVMType<f64>;
 139 def llvm_f80_ty        : LLVMType<f80>;
 140 def llvm_f128_ty       : LLVMType<f128>;
 141 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 142 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 143 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 144 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 145 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 146 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 147 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 148
 149 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 150 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 151
 152 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 153 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 154 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 155 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 156 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 157 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 158 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 159 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 160 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 161 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 162 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 163 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 164 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 165
 166 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 167 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 168 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 169 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 170 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 171 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 172
 173 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 174 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 175 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 176 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 177 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 178 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 179 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 180 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 181 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 182 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 183
 184 def llvm_v1i128_ty     : LLVMType<v1i128>;   //  1 x i128
 185
 186 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 187 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 188 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 189 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 190 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 191 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 192 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 193 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 194 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 195 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 196 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 197 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 198
 199 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 200
 201
 202 //===----------------------------------------------------------------------===//
 203 // Intrinsic Definitions.
 204 //===----------------------------------------------------------------------===//
 205
 206 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 207 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 208 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 209 // example, llvm.bswap.i16 -> int_bswap_i16.
 210 //
 211 //  * RetTypes is a list containing the return types expected for the
 212 //    intrinsic.
 213 //  * ParamTypes is a list containing the parameter types expected for the
 214 //    intrinsic.
 215 //  * Properties can be set to describe the behavior of the intrinsic.
 216 //
 217 class SDPatternOperator;
 218 class Intrinsic<list<LLVMType> ret_types,
 219                 list<LLVMType> param_types = [],
 220                 list<IntrinsicProperty> properties = [],
 221                 string name = ""> : SDPatternOperator {
 222   string LLVMName = name;
 223   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 224   list<LLVMType> RetTypes = ret_types;
 225   list<LLVMType> ParamTypes = param_types;
 226   list<IntrinsicProperty> Properties = properties;
 227
 228   bit isTarget = 0;
 229 }
 230
 231 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 232 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 233 /// support.
 234 class GCCBuiltin<string name> {
 235   string GCCBuiltinName = name;
 236 }
 237
 238 class MSBuiltin<string name> {
 239   string MSBuiltinName = name;
 240 }
 241
 242
 243 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 244 //
 245
 246 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 247 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 248                             "llvm.va_copy">;
 249 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 250
 251 //===------------------- Garbage Collection Intrinsics --------------------===//
 252 //
 253 def int_gcroot  : Intrinsic<[],
 254                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 255 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 256                             [llvm_ptr_ty, llvm_ptrptr_ty],
 257                             [IntrReadArgMem]>;
 258 def int_gcwrite : Intrinsic<[],
 259                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 260                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 261
 262 //===--------------------- Code Generator Intrinsics ----------------------===//
 263 //
 264 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 265 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 266 def int_frameescape : Intrinsic<[], [llvm_vararg_ty]>;
 267 def int_framerecover : Intrinsic<[llvm_ptr_ty],
 268                                  [llvm_ptr_ty, llvm_ptr_ty, llvm_i32_ty],
 269                                  [IntrNoMem]>;
 270 def int_read_register  : Intrinsic<[llvm_anyint_ty], [llvm_metadata_ty],
 271                                    [IntrReadMem], "llvm.read_register">;
 272 def int_write_register : Intrinsic<[], [llvm_metadata_ty, llvm_anyint_ty],
 273                                    [], "llvm.write_register">;
 274
 275 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 276 // model their dependencies on allocas.
 277 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 278                         GCCBuiltin<"__builtin_stack_save">;
 279 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 280                         GCCBuiltin<"__builtin_stack_restore">;
 281
 282 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 283 // however it does conveniently prevent the prefetch from being reordered
 284 // with respect to nearby accesses to the same memory.
 285 def int_prefetch      : Intrinsic<[],
 286                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 287                                    llvm_i32_ty],
 288                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 289 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 290
 291 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 292
 293 // The assume intrinsic is marked as arbitrarily writing so that proper
 294 // control dependencies will be maintained.
 295 def int_assume        : Intrinsic<[], [llvm_i1_ty], []>;
 296
 297 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 298 // guard to the correct place on the stack frame.
 299 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 300 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 301                                         [IntrReadWriteArgMem]>;
 302
 303 // A counter increment for instrumentation based profiling.
 304 def int_instrprof_increment : Intrinsic<[],
 305                                         [llvm_ptr_ty, llvm_i64_ty,
 306                                          llvm_i32_ty, llvm_i32_ty],
 307                                         []>;
 308
 309 //===------------------- Standard C Library Intrinsics --------------------===//
 310 //
 311
 312 def int_memcpy  : Intrinsic<[],
 313                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 314                               llvm_i32_ty, llvm_i1_ty],
 315                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 316                              ReadOnly<1>]>;
 317 def int_memmove : Intrinsic<[],
 318                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 319                              llvm_i32_ty, llvm_i1_ty],
 320                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 321                              ReadOnly<1>]>;
 322 def int_memset  : Intrinsic<[],
 323                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 324                              llvm_i32_ty, llvm_i1_ty],
 325                             [IntrReadWriteArgMem, NoCapture<0>]>;
 326
 327 let Properties = [IntrNoMem] in {
 328   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 329                            [LLVMMatchType<0>, LLVMMatchType<0>,
 330                             LLVMMatchType<0>]>;
 331   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 332                               [LLVMMatchType<0>, LLVMMatchType<0>,
 333                                LLVMMatchType<0>]>;
 334
 335   // These functions do not read memory, but are sensitive to the
 336   // rounding mode. LLVM purposely does not model changes to the FP
 337   // environment so they can be treated as readnone.
 338   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 339   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 340   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 341   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 342   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 343                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 344   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 345   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 346   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 347   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 348   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 349   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 350   def int_minnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 351   def int_maxnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 352   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 353                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 354   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 355   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 356   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 357   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 358   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 359   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 360 }
 361
 362 // NOTE: these are internal interfaces.
 363 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 364 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 365 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 366 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 367
 368 // Internal interface for object size checking
 369 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 370                                [IntrNoMem]>,
 371                                GCCBuiltin<"__builtin_object_size">;
 372
 373 //===------------------------- Expect Intrinsics --------------------------===//
 374 //
 375 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 376                                               LLVMMatchType<0>], [IntrNoMem]>;
 377
 378 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 379 //
 380
 381 // None of these intrinsics accesses memory at all.
 382 let Properties = [IntrNoMem] in {
 383   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 384   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 385   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 386   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 387 }
 388
 389 //===------------------------ Debugger Intrinsics -------------------------===//
 390 //
 391
 392 // None of these intrinsics accesses memory at all...but that doesn't mean the
 393 // optimizers can change them aggressively.  Special handling needed in a few
 394 // places.
 395 let Properties = [IntrNoMem] in {
 396   def int_dbg_declare      : Intrinsic<[],
 397                                        [llvm_metadata_ty,
 398                                        llvm_metadata_ty,
 399                                        llvm_metadata_ty]>;
 400   def int_dbg_value        : Intrinsic<[],
 401                                        [llvm_metadata_ty, llvm_i64_ty,
 402                                         llvm_metadata_ty,
 403                                         llvm_metadata_ty]>;
 404 }
 405
 406 //===------------------ Exception Handling Intrinsics----------------------===//
 407 //
 408
 409 // The result of eh.typeid.for depends on the enclosing function, but inside a
 410 // given function it is 'const' and may be CSE'd etc.
 411 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 412
 413 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 414 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 415
 416 // eh.begincatch takes a pointer returned by a landingpad instruction and
 417 // copies the exception object into the memory pointed to by the second
 418 // parameter. If the second parameter is null, no copy occurs.
 419 def int_eh_begincatch : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 420                                   [NoCapture<0>, NoCapture<1>]>;
 421 def int_eh_endcatch : Intrinsic<[], []>;
 422
 423 // Represents the list of actions to take when an exception is thrown.
 424 def int_eh_actions : Intrinsic<[llvm_ptr_ty], [llvm_vararg_ty], []>;
 425
 426 def int_eh_exceptioncode : Intrinsic<[llvm_i32_ty], []>;
 427 def int_eh_exceptioninfo : Intrinsic<[llvm_ptr_ty], []>;
 428
 429 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 430 // callee-saved registers to be saved and restored (regardless of whether they
 431 // are used) in the calling function. It is used by libgcc_eh.
 432 def int_eh_unwind_init: Intrinsic<[]>,
 433                         GCCBuiltin<"__builtin_unwind_init">;
 434
 435 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 436
 437 let Properties = [IntrNoMem] in {
 438   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 439   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 440 }
 441 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 442 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 443 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 444
 445 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 446 //
 447 def int_var_annotation : Intrinsic<[],
 448                                    [llvm_ptr_ty, llvm_ptr_ty,
 449                                     llvm_ptr_ty, llvm_i32_ty],
 450                                    [], "llvm.var.annotation">;
 451 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 452                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 453                                     llvm_i32_ty],
 454                                    [], "llvm.ptr.annotation">;
 455 def int_annotation : Intrinsic<[llvm_anyint_ty],
 456                                [LLVMMatchType<0>, llvm_ptr_ty,
 457                                 llvm_ptr_ty, llvm_i32_ty],
 458                                [], "llvm.annotation">;
 459
 460 //===------------------------ Trampoline Intrinsics -----------------------===//
 461 //
 462 def int_init_trampoline : Intrinsic<[],
 463                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 464                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 465                                    GCCBuiltin<"__builtin_init_trampoline">;
 466
 467 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 468                                       [IntrReadArgMem]>,
 469                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 470
 471 //===------------------------ Overflow Intrinsics -------------------------===//
 472 //
 473
 474 // Expose the carry flag from add operations on two integrals.
 475 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 476                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 477                                        [IntrNoMem]>;
 478 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 479                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 480                                        [IntrNoMem]>;
 481
 482 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 483                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 484                                        [IntrNoMem]>;
 485 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 486                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 487                                        [IntrNoMem]>;
 488
 489 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 490                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 491                                        [IntrNoMem]>;
 492 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 493                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 494                                        [IntrNoMem]>;
 495
 496 //===------------------------- Memory Use Markers -------------------------===//
 497 //
 498 def int_lifetime_start  : Intrinsic<[],
 499                                     [llvm_i64_ty, llvm_ptr_ty],
 500                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 501 def int_lifetime_end    : Intrinsic<[],
 502                                     [llvm_i64_ty, llvm_ptr_ty],
 503                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 504 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 505                                     [llvm_i64_ty, llvm_ptr_ty],
 506                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 507 def int_invariant_end   : Intrinsic<[],
 508                                     [llvm_descriptor_ty, llvm_i64_ty,
 509                                      llvm_ptr_ty],
 510                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 511
 512 //===------------------------ Stackmap Intrinsics -------------------------===//
 513 //
 514 def int_experimental_stackmap : Intrinsic<[],
 515                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty],
 516                                   [Throws]>;
 517 def int_experimental_patchpoint_void : Intrinsic<[],
 518                                                  [llvm_i64_ty, llvm_i32_ty,
 519                                                   llvm_ptr_ty, llvm_i32_ty,
 520                                                   llvm_vararg_ty],
 521                                                   [Throws]>;
 522 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 523                                                 [llvm_i64_ty, llvm_i32_ty,
 524                                                  llvm_ptr_ty, llvm_i32_ty,
 525                                                  llvm_vararg_ty],
 526                                                  [Throws]>;
 527
 528
 529 //===------------------------ Garbage Collection Intrinsics ---------------===//
 530 // These are documented in docs/Statepoint.rst
 531
 532 def int_experimental_gc_statepoint : Intrinsic<[llvm_i32_ty],
 533                                [llvm_i64_ty, llvm_i32_ty,
 534                                 llvm_anyptr_ty, llvm_i32_ty,
 535                                 llvm_i32_ty, llvm_vararg_ty]>;
 536
 537 def int_experimental_gc_result   : Intrinsic<[llvm_any_ty], [llvm_i32_ty]>;
 538 def int_experimental_gc_relocate : Intrinsic<[llvm_anyptr_ty],
 539                                 [llvm_i32_ty, llvm_i32_ty, llvm_i32_ty]>;
 540
 541 // Deprecated: will be removed in a couple of weeks
 542 def int_experimental_gc_result_int : Intrinsic<[llvm_anyint_ty], [llvm_i32_ty]>;
 543 def int_experimental_gc_result_float : Intrinsic<[llvm_anyfloat_ty],
 544                                                  [llvm_i32_ty]>;
 545 def int_experimental_gc_result_ptr : Intrinsic<[llvm_anyptr_ty], [llvm_i32_ty]>;
 546
 547 //===-------------------------- Other Intrinsics --------------------------===//
 548 //
 549 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 550                      GCCBuiltin<"__builtin_flt_rounds">;
 551 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 552                GCCBuiltin<"__builtin_trap">;
 553 def int_debugtrap : Intrinsic<[]>,
 554                     GCCBuiltin<"__builtin_debugtrap">;
 555
 556 // NOP: calls/invokes to this intrinsic are removed by codegen
 557 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 558
 559 // Intrisics to support half precision floating point format
 560 let Properties = [IntrNoMem] in {
 561 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_anyfloat_ty]>;
 562 def int_convert_from_fp16 : Intrinsic<[llvm_anyfloat_ty], [llvm_i16_ty]>;
 563 }
 564
 565 // These convert intrinsics are to support various conversions between
 566 // various types with rounding and saturation. NOTE: avoid using these
 567 // intrinsics as they might be removed sometime in the future and
 568 // most targets don't support them.
 569 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 570                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 571 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 572                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 573 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 574                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 575 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 576                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 577 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 578                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 579 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 580                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 581 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 582                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 583 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 584                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 585 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 586                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 587
 588 // Clear cache intrinsic, default to ignore (ie. emit nothing)
 589 // maps to void __clear_cache() on supporting platforms
 590 def int_clear_cache : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 591                                 [], "llvm.clear_cache">;
 592
 593 //===-------------------------- Masked Intrinsics -------------------------===//
 594 //
 595 def int_masked_store : Intrinsic<[], [llvm_anyvector_ty, LLVMPointerTo<0>,
 596                                       llvm_i32_ty,
 597                                       LLVMVectorSameWidth<0, llvm_i1_ty>],
 598                                  [IntrReadWriteArgMem]>;
 599
 600 def int_masked_load  : Intrinsic<[llvm_anyvector_ty],
 601                                  [LLVMPointerTo<0>, llvm_i32_ty,
 602                                   LLVMVectorSameWidth<0, llvm_i1_ty>, LLVMMatchType<0>],
 603                                  [IntrReadArgMem]>;
 604
 605 def int_masked_gather: Intrinsic<[llvm_anyvector_ty],
 606                                  [LLVMVectorOfPointersToElt<0>, llvm_i32_ty,
 607                                   LLVMVectorSameWidth<0, llvm_i1_ty>,
 608                                   LLVMMatchType<0>],
 609                                  [IntrReadArgMem]>;
 610
 611 def int_masked_scatter: Intrinsic<[],
 612                                   [llvm_anyvector_ty,
 613                                    LLVMVectorOfPointersToElt<0>, llvm_i32_ty,
 614                                    LLVMVectorSameWidth<0, llvm_i1_ty>],
 615                                   [IntrReadWriteArgMem]>;
 616
 617 // Intrinsics to support bit sets.
 618 def int_bitset_test : Intrinsic<[llvm_i1_ty], [llvm_ptr_ty, llvm_metadata_ty],
 619                                 [IntrNoMem]>;
 620
 621 //===----------------------------------------------------------------------===//
 622 // Target-specific intrinsics
 623 //===----------------------------------------------------------------------===//
 624
 625 include "llvm/IR/IntrinsicsPowerPC.td"
 626 include "llvm/IR/IntrinsicsX86.td"
 627 include "llvm/IR/IntrinsicsARM.td"
 628 include "llvm/IR/IntrinsicsAArch64.td"
 629 include "llvm/IR/IntrinsicsXCore.td"
 630 include "llvm/IR/IntrinsicsHexagon.td"
 631 include "llvm/IR/IntrinsicsNVVM.td"
 632 include "llvm/IR/IntrinsicsMips.td"
 633 include "llvm/IR/IntrinsicsR600.td"
 634 include "llvm/IR/IntrinsicsBPF.td"
 635 include "llvm/IR/IntrinsicsSystemZ.td"