CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 project(LLVM)
  20
  21 # Add path for custom modules
  22 set(CMAKE_MODULE_PATH
  23   ${CMAKE_MODULE_PATH}
  24   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  25   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  26   )
  27
  28 set(LLVM_VERSION_MAJOR 3)
  29 set(LLVM_VERSION_MINOR 5)
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  33 endif()
  34
  35 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  36
  37 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  38 if ( LLVM_USE_FOLDERS )
  39   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  40 endif()
  41
  42 include(VersionFromVCS)
  43
  44 option(LLVM_APPEND_VC_REV
  45   "Append the version control system revision id to LLVM version" OFF)
  46
  47 if( LLVM_APPEND_VC_REV )
  48   add_version_info_from_vcs(PACKAGE_VERSION)
  49 endif()
  50
  51 set(PACKAGE_NAME LLVM)
  52 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  53 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  54
  55 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  56   "Default URL where bug reports are to be submitted.")
  57
  58 # Configure CPack.
  59 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  60 set(CPACK_PACKAGE_VENDOR "LLVM")
  61 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  62 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  63 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  64 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  65 if(WIN32 AND NOT UNIX)
  66   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  67   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  68   set(CPACK_NSIS_MODIFY_PATH "ON")
  69   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  70   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  71     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  72   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  73     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  74 endif()
  75 include(CPack)
  76
  77 # Sanity check our source directory to make sure that we are not trying to
  78 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  79 # sure that we don't have any stray generated files lying around in the tree
  80 # (which would end up getting picked up by header search, instead of the correct
  81 # versions).
  82 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  83   message(FATAL_ERROR "In-source builds are not allowed.
  84 CMake would overwrite the makefiles distributed with LLVM.
  85 Please create a directory and run cmake from there, passing the path
  86 to this source directory as the last argument.
  87 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  88 Please delete them.")
  89 endif()
  90 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  91   file(GLOB_RECURSE
  92     tablegenned_files_on_include_dir
  93     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  94   file(GLOB_RECURSE
  95     tablegenned_files_on_lib_dir
  96     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  97   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  98     message(FATAL_ERROR "Apparently there is a previous in-source build,
  99 probably as the result of running `configure' and `make' on
 100 ${CMAKE_CURRENT_SOURCE_DIR}.
 101 This may cause problems. The suspicious files are:
 102 ${tablegenned_files_on_lib_dir}
 103 ${tablegenned_files_on_include_dir}
 104 Please clean the source directory.")
 105   endif()
 106 endif()
 107
 108 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 109
 110 # They are used as destination of target generators.
 111 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 112 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 113
 114 # Each of them corresponds to llvm-config's.
 115 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 116 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 117 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 118 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 119 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 120
 121 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 122 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 123 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 124
 125 set(LLVM_ALL_TARGETS
 126   AArch64
 127   ARM
 128   CppBackend
 129   Hexagon
 130   Mips
 131   MSP430
 132   NVPTX
 133   PowerPC
 134   R600
 135   Sparc
 136   SystemZ
 137   X86
 138   XCore
 139   )
 140
 141 # List of targets with JIT support:
 142 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 143
 144 set(LLVM_TARGETS_TO_BUILD "all"
 145     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 146
 147 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 148   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 149
 150 option(BUILD_SHARED_LIBS
 151   "Build all libraries as shared libraries instead of static" OFF)
 152
 153 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 154 if(LLVM_ENABLE_TIMESTAMPS)
 155   set(ENABLE_TIMESTAMPS 1)
 156 endif()
 157
 158 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 159 if(LLVM_ENABLE_BACKTRACES)
 160   set(ENABLE_BACKTRACES 1)
 161 endif()
 162
 163 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 164 if(LLVM_ENABLE_CRASH_OVERRIDES)
 165   set(ENABLE_CRASH_OVERRIDES 1)
 166 endif()
 167
 168 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 169 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 170 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 171
 172 set(LLVM_TARGET_ARCH "host"
 173   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 174
 175 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 176
 177 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 178
 179 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 180
 181 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 182   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 183 endif()
 184
 185 set(LLVM_TARGETS_TO_BUILD
 186    ${LLVM_TARGETS_TO_BUILD}
 187    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 188 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 189
 190 include(AddLLVMDefinitions)
 191
 192 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 193
 194 # MSVC has a gazillion warnings with this.
 195 if( MSVC )
 196   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 197 else( MSVC )
 198   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 199 endif()
 200
 201 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 202 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 203 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 204 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 205
 206 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 207   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 208 else()
 209   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 210 endif()
 211
 212 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 213        "Set to ON to force using an old, unsupported host toolchain." OFF)
 214
 215 option(LLVM_USE_INTEL_JITEVENTS
 216   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 217   OFF)
 218
 219 if( LLVM_USE_INTEL_JITEVENTS )
 220   # Verify we are on a supported platform
 221   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 222     message(FATAL_ERROR
 223       "Intel JIT API support is available on Linux and Windows only.")
 224   endif()
 225 endif( LLVM_USE_INTEL_JITEVENTS )
 226
 227 option(LLVM_USE_OPROFILE
 228   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 229
 230 # If enabled, verify we are on a platform that supports oprofile.
 231 if( LLVM_USE_OPROFILE )
 232   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 233     message(FATAL_ERROR "OProfile support is available on Linux only.")
 234   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 235 endif( LLVM_USE_OPROFILE )
 236
 237 set(LLVM_USE_SANITIZER "" CACHE STRING
 238   "Define the sanitizer used to build binaries and tests.")
 239
 240 option(LLVM_USE_SPLIT_DWARF
 241   "Use -gsplit-dwarf when compiling llvm." OFF)
 242
 243 # Define an option controlling whether we should build for 32-bit on 64-bit
 244 # platforms, where supported.
 245 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 246   # TODO: support other platforms and toolchains.
 247   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 248 endif()
 249
 250 # Define the default arguments to use with 'lit', and an option for the user to
 251 # override.
 252 set(LIT_ARGS_DEFAULT "-sv")
 253 if (MSVC OR XCODE)
 254   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 255 endif()
 256 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 257
 258 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 259 if( WIN32 AND NOT CYGWIN )
 260   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 261 endif()
 262
 263 # Define options to control the inclusion and default build behavior for
 264 # components which may not strictly be necessary (tools, examples, and tests).
 265 #
 266 # This is primarily to support building smaller or faster project files.
 267 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 268 option(LLVM_BUILD_TOOLS
 269   "Build the LLVM tools. If OFF, just generate build targets." ON)
 270
 271 option(LLVM_BUILD_RUNTIME
 272   "Build the LLVM runtime libraries." ON)
 273 option(LLVM_BUILD_EXAMPLES
 274   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 275 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 276
 277 option(LLVM_BUILD_TESTS
 278   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 279 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 280
 281 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 282 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 283 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 284
 285 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 286   "Build compiler-rt as an external project." OFF)
 287
 288 # All options referred to from HandleLLVMOptions have to be specified
 289 # BEFORE this include, otherwise options will not be correctly set on
 290 # first cmake run
 291 include(config-ix)
 292
 293 # By default, we target the host, but this can be overridden at CMake
 294 # invocation time.
 295 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 296   "Default target for which LLVM will generate code." )
 297 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 298
 299 include(HandleLLVMOptions)
 300
 301 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 302 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 303 include(FindPythonInterp)
 304 if( NOT PYTHONINTERP_FOUND )
 305   message(FATAL_ERROR
 306 "Unable to find Python interpreter, required for builds and testing.
 307
 308 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 309 endif()
 310
 311 ######
 312 # LLVMBuild Integration
 313 #
 314 # We use llvm-build to generate all the data required by the CMake based
 315 # build system in one swoop:
 316 #
 317 #  - We generate a file (a CMake fragment) in the object root which contains
 318 #    all the definitions that are required by CMake.
 319 #
 320 #  - We generate the library table used by llvm-config.
 321 #
 322 #  - We generate the dependencies for the CMake fragment, so that we will
 323 #    automatically reconfigure outselves.
 324
 325 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 326 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 327   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 328 set(LLVMBUILDCMAKEFRAG
 329   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 330
 331 # Create the list of optional components that are enabled
 332 if (LLVM_USE_INTEL_JITEVENTS)
 333   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 334 endif (LLVM_USE_INTEL_JITEVENTS)
 335 if (LLVM_USE_OPROFILE)
 336   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 337 endif (LLVM_USE_OPROFILE)
 338
 339 message(STATUS "Constructing LLVMBuild project information")
 340 execute_process(
 341   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 342             --native-target "${LLVM_NATIVE_ARCH}"
 343             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 344             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 345             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 346             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 347             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 348             ERROR_VARIABLE LLVMBUILDERRORS
 349             OUTPUT_STRIP_TRAILING_WHITESPACE
 350             ERROR_STRIP_TRAILING_WHITESPACE
 351   RESULT_VARIABLE LLVMBUILDRESULT)
 352
 353 # On Win32, CMake doesn't properly handle piping the default output/error
 354 # streams into the GUI console. So, we explicitly catch and report them.
 355 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 356   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 357 endif()
 358 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 359   message(FATAL_ERROR
 360     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 361 endif()
 362
 363 # Include the generated CMake fragment. This will define properties from the
 364 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 365 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 366 # files change.
 367 include(${LLVMBUILDCMAKEFRAG})
 368
 369 ######
 370
 371 # Configure all of the various header file fragments LLVM uses which depend on
 372 # configuration variables.
 373 set(LLVM_ENUM_TARGETS "")
 374 set(LLVM_ENUM_ASM_PRINTERS "")
 375 set(LLVM_ENUM_ASM_PARSERS "")
 376 set(LLVM_ENUM_DISASSEMBLERS "")
 377 foreach(t ${LLVM_TARGETS_TO_BUILD})
 378   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 379
 380   list(FIND LLVM_ALL_TARGETS ${t} idx)
 381   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 382   if( idx LESS 0 AND idy LESS 0 )
 383     message(FATAL_ERROR "The target `${t}' does not exist.
 384     It should be one of\n${LLVM_ALL_TARGETS}")
 385   else()
 386     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 387   endif()
 388
 389   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 390   if( asmp_file )
 391     set(LLVM_ENUM_ASM_PRINTERS
 392       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 393   endif()
 394   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 395     set(LLVM_ENUM_ASM_PARSERS
 396       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 397   endif()
 398   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 399     set(LLVM_ENUM_DISASSEMBLERS
 400       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 401   endif()
 402 endforeach(t)
 403
 404 # Produce the target definition files, which provide a way for clients to easily
 405 # include various classes of targets.
 406 configure_file(
 407   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 408   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 409   )
 410 configure_file(
 411   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 412   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 413   )
 414 configure_file(
 415   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 416   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 417   )
 418 configure_file(
 419   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 420   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 421   )
 422
 423 # Configure the three LLVM configuration header files.
 424 configure_file(
 425   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 426   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 427 configure_file(
 428   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 429   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 430 configure_file(
 431   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 432   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 433
 434 # They are not referenced. See set_output_directory().
 435 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 436 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 437 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 438
 439 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 440 if (APPLE)
 441   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 442   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 443 else(UNIX)
 444   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 445     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 446   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 447 endif()
 448
 449 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 450
 451 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 452
 453 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 454   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 455   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 456   include_directories("/usr/local/include")
 457   link_directories("/usr/local/lib")
 458 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 459
 460 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 461    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 462 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 463
 464 # Make sure we don't get -rdynamic in every binary. For those that need it,
 465 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 466 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 467
 468 include(AddLLVM)
 469 include(TableGen)
 470
 471 if( MINGW )
 472   # People report that -O3 is unreliable on MinGW. The traditional
 473   # build also uses -O2 for that reason:
 474   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 475 endif()
 476
 477 # Put this before tblgen. Else we have a circular dependence.
 478 add_subdirectory(lib/Support)
 479 add_subdirectory(lib/TableGen)
 480
 481 add_subdirectory(utils/TableGen)
 482
 483 add_subdirectory(include/llvm)
 484
 485 add_subdirectory(lib)
 486
 487 add_subdirectory(utils/FileCheck)
 488 add_subdirectory(utils/FileUpdate)
 489 add_subdirectory(utils/count)
 490 add_subdirectory(utils/not)
 491 add_subdirectory(utils/llvm-lit)
 492 add_subdirectory(utils/yaml-bench)
 493
 494 if(LLVM_INCLUDE_TESTS)
 495   add_subdirectory(utils/unittest)
 496 endif()
 497
 498 add_subdirectory(projects)
 499
 500 if( LLVM_INCLUDE_TOOLS )
 501   add_subdirectory(tools)
 502 endif()
 503
 504 if( LLVM_INCLUDE_EXAMPLES )
 505   add_subdirectory(examples)
 506 endif()
 507
 508 if( LLVM_INCLUDE_TESTS )
 509   add_subdirectory(test)
 510   add_subdirectory(unittests)
 511   if (MSVC)
 512     # This utility is used to prevent crashing tests from calling Dr. Watson on
 513     # Windows.
 514     add_subdirectory(utils/KillTheDoctor)
 515   endif()
 516
 517   # Add a global check rule now that all subdirectories have been traversed
 518   # and we know the total set of lit testsuites.
 519   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 520   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 521   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 522   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 523   add_lit_target(check-all
 524     "Running all regression tests"
 525     ${LLVM_LIT_TESTSUITES}
 526     PARAMS ${LLVM_LIT_PARAMS}
 527     DEPENDS ${LLVM_LIT_DEPENDS}
 528     ARGS ${LLVM_LIT_EXTRA_ARGS}
 529     )
 530 endif()
 531
 532 if (LLVM_INCLUDE_DOCS)
 533   add_subdirectory(docs)
 534 endif()
 535
 536 add_subdirectory(cmake/modules)
 537
 538 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 539   install(DIRECTORY include/llvm include/llvm-c
 540     DESTINATION include
 541     FILES_MATCHING
 542     PATTERN "*.def"
 543     PATTERN "*.h"
 544     PATTERN "*.td"
 545     PATTERN "*.inc"
 546     PATTERN "LICENSE.TXT"
 547     PATTERN ".svn" EXCLUDE
 548     )
 549
 550   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 551     DESTINATION include
 552     FILES_MATCHING
 553     PATTERN "*.def"
 554     PATTERN "*.h"
 555     PATTERN "*.gen"
 556     PATTERN "*.inc"
 557     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 558     PATTERN "CMakeFiles" EXCLUDE
 559     PATTERN ".svn" EXCLUDE
 560     )
 561 endif()
 562
 563 # Workaround for MSVS10 to avoid the Dialog Hell
 564 # FIXME: This could be removed with future version of CMake.
 565 if(MSVC_VERSION EQUAL 1600)
 566   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 567   if( EXISTS "${LLVM_SLN_FILENAME}" )
 568     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 569   endif()
 570 endif()
 571