CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 # FIXME: It may be removed when we use 2.8.12.
  11 if(CMAKE_VERSION VERSION_LESS 2.8.12)
  12   # Invalidate a couple of keywords.
  13   set(cmake_2_8_12_INTERFACE)
  14   set(cmake_2_8_12_PRIVATE)
  15 else()
  16   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  17   set(cmake_2_8_12_INTERFACE INTERFACE)
  18   set(cmake_2_8_12_PRIVATE PRIVATE)
  19   if(POLICY CMP0022)
  20     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  21   endif()
  22 endif()
  23
  24 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  25   set(cmake_3_2_USES_TERMINAL)
  26 else()
  27   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  28 endif()
  29
  30 project(LLVM)
  31
  32 # The following only works with the Ninja generator in CMake >= 3.0.
  33 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  34   "Define the maximum number of concurrent compilation jobs.")
  35 if(LLVM_PARALLEL_COMPILE_JOBS)
  36   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  37   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  38 endif()
  39
  40 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  41   "Define the maximum number of concurrent link jobs.")
  42 if(LLVM_PARALLEL_LINK_JOBS)
  43   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  44   set(CMAKE_JOB_POOL_LINK link_job_pool)
  45 endif()
  46
  47 # Add path for custom modules
  48 set(CMAKE_MODULE_PATH
  49   ${CMAKE_MODULE_PATH}
  50   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  51   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  52   )
  53
  54 set(LLVM_VERSION_MAJOR 3)
  55 set(LLVM_VERSION_MINOR 7)
  56 set(LLVM_VERSION_PATCH 0)
  57 set(LLVM_VERSION_SUFFIX svn)
  58
  59 if (NOT PACKAGE_VERSION)
  60   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  61 endif()
  62
  63 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  64
  65 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  66 if ( LLVM_USE_FOLDERS )
  67   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  68 endif()
  69
  70 include(VersionFromVCS)
  71
  72 option(LLVM_APPEND_VC_REV
  73   "Append the version control system revision id to LLVM version" OFF)
  74
  75 if( LLVM_APPEND_VC_REV )
  76   add_version_info_from_vcs(PACKAGE_VERSION)
  77 endif()
  78
  79 set(PACKAGE_NAME LLVM)
  80 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  81 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  82
  83 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  84   "Default URL where bug reports are to be submitted.")
  85
  86 # Configure CPack.
  87 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  88 set(CPACK_PACKAGE_VENDOR "LLVM")
  89 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  90 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  91 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  92 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  93 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  94 if(WIN32 AND NOT UNIX)
  95   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  96   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  97   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  98   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  99   set(CPACK_NSIS_MODIFY_PATH "ON")
 100   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 101   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 102     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 103   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 104     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 105   if( CMAKE_CL_64 )
 106     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 107   endif()
 108 endif()
 109 include(CPack)
 110
 111 # Sanity check our source directory to make sure that we are not trying to
 112 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 113 # sure that we don't have any stray generated files lying around in the tree
 114 # (which would end up getting picked up by header search, instead of the correct
 115 # versions).
 116 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 117   message(FATAL_ERROR "In-source builds are not allowed.
 118 CMake would overwrite the makefiles distributed with LLVM.
 119 Please create a directory and run cmake from there, passing the path
 120 to this source directory as the last argument.
 121 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 122 Please delete them.")
 123 endif()
 124 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 125   file(GLOB_RECURSE
 126     tablegenned_files_on_include_dir
 127     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 128   file(GLOB_RECURSE
 129     tablegenned_files_on_lib_dir
 130     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 131   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 132     message(FATAL_ERROR "Apparently there is a previous in-source build,
 133 probably as the result of running `configure' and `make' on
 134 ${CMAKE_CURRENT_SOURCE_DIR}.
 135 This may cause problems. The suspicious files are:
 136 ${tablegenned_files_on_lib_dir}
 137 ${tablegenned_files_on_include_dir}
 138 Please clean the source directory.")
 139   endif()
 140 endif()
 141
 142 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 143
 144 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 145
 146 # They are used as destination of target generators.
 147 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 148 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 149 if(WIN32 OR CYGWIN)
 150   # DLL platform -- put DLLs into bin.
 151   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 152 else()
 153   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 154 endif()
 155
 156 # Each of them corresponds to llvm-config's.
 157 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 158 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 159 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 160 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 161 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 162
 163 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 164 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 165
 166 set(LLVM_ALL_TARGETS
 167   AArch64
 168   ARM
 169   CppBackend
 170   Hexagon
 171   Mips
 172   MSP430
 173   NVPTX
 174   PowerPC
 175   R600
 176   Sparc
 177   SystemZ
 178   X86
 179   XCore
 180   )
 181
 182 # List of targets with JIT support:
 183 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 184
 185 set(LLVM_TARGETS_TO_BUILD "all"
 186     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 187
 188 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 189   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 190
 191 option(BUILD_SHARED_LIBS
 192   "Build all libraries as shared libraries instead of static" OFF)
 193
 194 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 195 if(LLVM_ENABLE_TIMESTAMPS)
 196   set(ENABLE_TIMESTAMPS 1)
 197 endif()
 198
 199 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 200 if(LLVM_ENABLE_BACKTRACES)
 201   set(ENABLE_BACKTRACES 1)
 202 endif()
 203
 204 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 205 if(LLVM_ENABLE_CRASH_OVERRIDES)
 206   set(ENABLE_CRASH_OVERRIDES 1)
 207 endif()
 208
 209 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 210 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 211 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 212
 213 set(LLVM_TARGET_ARCH "host"
 214   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 215
 216 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 217
 218 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 219
 220 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 221
 222 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 223   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 224 endif()
 225
 226 set(LLVM_TARGETS_TO_BUILD
 227    ${LLVM_TARGETS_TO_BUILD}
 228    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 229 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 230
 231 include(AddLLVMDefinitions)
 232
 233 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 234
 235 # MSVC has a gazillion warnings with this.
 236 if( MSVC )
 237   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 238 else()
 239   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 240 endif()
 241
 242 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 243 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 244 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 245 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 246 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 247
 248 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 249   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 250 else()
 251   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 252 endif()
 253
 254 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 255        "Set to ON to force using an old, unsupported host toolchain." OFF)
 256
 257 option(LLVM_USE_INTEL_JITEVENTS
 258   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 259   OFF)
 260
 261 if( LLVM_USE_INTEL_JITEVENTS )
 262   # Verify we are on a supported platform
 263   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 264     message(FATAL_ERROR
 265       "Intel JIT API support is available on Linux and Windows only.")
 266   endif()
 267 endif( LLVM_USE_INTEL_JITEVENTS )
 268
 269 option(LLVM_USE_OPROFILE
 270   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 271
 272 # If enabled, verify we are on a platform that supports oprofile.
 273 if( LLVM_USE_OPROFILE )
 274   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 275     message(FATAL_ERROR "OProfile support is available on Linux only.")
 276   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 277 endif( LLVM_USE_OPROFILE )
 278
 279 set(LLVM_USE_SANITIZER "" CACHE STRING
 280   "Define the sanitizer used to build binaries and tests.")
 281
 282 option(LLVM_USE_SPLIT_DWARF
 283   "Use -gsplit-dwarf when compiling llvm." OFF)
 284
 285 option(WITH_POLLY "Build LLVM with Polly" ON)
 286 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 287
 288 # Define an option controlling whether we should build for 32-bit on 64-bit
 289 # platforms, where supported.
 290 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 291   # TODO: support other platforms and toolchains.
 292   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 293 endif()
 294
 295 # Define the default arguments to use with 'lit', and an option for the user to
 296 # override.
 297 set(LIT_ARGS_DEFAULT "-sv")
 298 if (MSVC OR XCODE)
 299   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 300 endif()
 301 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 302
 303 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 304 if( WIN32 AND NOT CYGWIN )
 305   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 306 endif()
 307
 308 # Define options to control the inclusion and default build behavior for
 309 # components which may not strictly be necessary (tools, examples, and tests).
 310 #
 311 # This is primarily to support building smaller or faster project files.
 312 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 313 option(LLVM_BUILD_TOOLS
 314   "Build the LLVM tools. If OFF, just generate build targets." ON)
 315
 316 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 317
 318 option(LLVM_BUILD_RUNTIME
 319   "Build the LLVM runtime libraries." ON)
 320 option(LLVM_BUILD_EXAMPLES
 321   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 322 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 323
 324 option(LLVM_BUILD_TESTS
 325   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 326 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 327
 328 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 329 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 330 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 331 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 332
 333 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 334   "Build compiler-rt as an external project." OFF)
 335
 336 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 337 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 338 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 339   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 340 endif()
 341
 342 # All options referred to from HandleLLVMOptions have to be specified
 343 # BEFORE this include, otherwise options will not be correctly set on
 344 # first cmake run
 345 include(config-ix)
 346
 347 # By default, we target the host, but this can be overridden at CMake
 348 # invocation time.
 349 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 350   "Default target for which LLVM will generate code." )
 351 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 352
 353 include(HandleLLVMOptions)
 354
 355 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 356 # FIXME: We should support systems with only Python 3, but that requires work
 357 # on LLDB.
 358 set(Python_ADDITIONAL_VERSIONS 2.7)
 359 include(FindPythonInterp)
 360 if( NOT PYTHONINTERP_FOUND )
 361   message(FATAL_ERROR
 362 "Unable to find Python interpreter, required for builds and testing.
 363
 364 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 365 endif()
 366
 367 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 368   message(FATAL_ERROR "Python 2.7 or newer is required")
 369 endif()
 370
 371 ######
 372 # LLVMBuild Integration
 373 #
 374 # We use llvm-build to generate all the data required by the CMake based
 375 # build system in one swoop:
 376 #
 377 #  - We generate a file (a CMake fragment) in the object root which contains
 378 #    all the definitions that are required by CMake.
 379 #
 380 #  - We generate the library table used by llvm-config.
 381 #
 382 #  - We generate the dependencies for the CMake fragment, so that we will
 383 #    automatically reconfigure outselves.
 384
 385 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 386 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 387   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 388 set(LLVMBUILDCMAKEFRAG
 389   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 390
 391 # Create the list of optional components that are enabled
 392 if (LLVM_USE_INTEL_JITEVENTS)
 393   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 394 endif (LLVM_USE_INTEL_JITEVENTS)
 395 if (LLVM_USE_OPROFILE)
 396   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 397 endif (LLVM_USE_OPROFILE)
 398
 399 message(STATUS "Constructing LLVMBuild project information")
 400 execute_process(
 401   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 402             --native-target "${LLVM_NATIVE_ARCH}"
 403             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 404             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 405             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 406             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 407             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 408             ERROR_VARIABLE LLVMBUILDERRORS
 409             OUTPUT_STRIP_TRAILING_WHITESPACE
 410             ERROR_STRIP_TRAILING_WHITESPACE
 411   RESULT_VARIABLE LLVMBUILDRESULT)
 412
 413 # On Win32, CMake doesn't properly handle piping the default output/error
 414 # streams into the GUI console. So, we explicitly catch and report them.
 415 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 416   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 417 endif()
 418 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 419   message(FATAL_ERROR
 420     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 421 endif()
 422
 423 # Include the generated CMake fragment. This will define properties from the
 424 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 425 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 426 # files change.
 427 include(${LLVMBUILDCMAKEFRAG})
 428
 429 ######
 430
 431 # Configure all of the various header file fragments LLVM uses which depend on
 432 # configuration variables.
 433 set(LLVM_ENUM_TARGETS "")
 434 set(LLVM_ENUM_ASM_PRINTERS "")
 435 set(LLVM_ENUM_ASM_PARSERS "")
 436 set(LLVM_ENUM_DISASSEMBLERS "")
 437 foreach(t ${LLVM_TARGETS_TO_BUILD})
 438   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 439
 440   list(FIND LLVM_ALL_TARGETS ${t} idx)
 441   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 442   if( idx LESS 0 AND idy LESS 0 )
 443     message(FATAL_ERROR "The target `${t}' does not exist.
 444     It should be one of\n${LLVM_ALL_TARGETS}")
 445   else()
 446     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 447   endif()
 448
 449   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 450   if( asmp_file )
 451     set(LLVM_ENUM_ASM_PRINTERS
 452       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 453   endif()
 454   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 455     set(LLVM_ENUM_ASM_PARSERS
 456       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 457   endif()
 458   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 459     set(LLVM_ENUM_DISASSEMBLERS
 460       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 461   endif()
 462 endforeach(t)
 463
 464 # Produce the target definition files, which provide a way for clients to easily
 465 # include various classes of targets.
 466 configure_file(
 467   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 468   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 469   )
 470 configure_file(
 471   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 472   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 473   )
 474 configure_file(
 475   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 476   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 477   )
 478 configure_file(
 479   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 480   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 481   )
 482
 483 # Configure the three LLVM configuration header files.
 484 configure_file(
 485   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 486   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 487 configure_file(
 488   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 489   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 490 configure_file(
 491   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 492   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 493
 494 # They are not referenced. See set_output_directory().
 495 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 496 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 497 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 498
 499 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 500 if (APPLE)
 501   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 502   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 503 else(UNIX)
 504   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 505     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 506     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 507       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 508       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 509     endif()
 510   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 511 endif()
 512
 513 # Work around a broken bfd ld behavior. When linking a binary with a
 514 # foo.so library, it will try to find any library that foo.so uses and
 515 # check its symbols. This is wasteful (the check was done when foo.so
 516 # was created) and can fail since it is not the dynamic linker and
 517 # doesn't know how to handle search paths correctly.
 518 if (UNIX AND NOT APPLE)
 519   set(CMAKE_EXE_LINKER_FLAGS
 520       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 521 endif()
 522
 523 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 524
 525 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 526
 527 # when crosscompiling import the executable targets from a file
 528 if(CMAKE_CROSSCOMPILING)
 529   include(CrossCompile)
 530 endif(CMAKE_CROSSCOMPILING)
 531
 532 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 533   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 534   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 535   include_directories("/usr/local/include")
 536   link_directories("/usr/local/lib")
 537 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 538
 539 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 540    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 541 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 542
 543 # Make sure we don't get -rdynamic in every binary. For those that need it,
 544 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 545 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 546
 547 include(AddLLVM)
 548 include(TableGen)
 549
 550 if( MINGW )
 551   # People report that -O3 is unreliable on MinGW. The traditional
 552   # build also uses -O2 for that reason:
 553   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 554 endif()
 555
 556 # Put this before tblgen. Else we have a circular dependence.
 557 add_subdirectory(lib/Support)
 558 add_subdirectory(lib/TableGen)
 559
 560 add_subdirectory(utils/TableGen)
 561
 562 add_subdirectory(include/llvm)
 563
 564 add_subdirectory(lib)
 565
 566 if( LLVM_INCLUDE_UTILS )
 567   add_subdirectory(utils/FileCheck)
 568   add_subdirectory(utils/PerfectShuffle)
 569   add_subdirectory(utils/count)
 570   add_subdirectory(utils/not)
 571   add_subdirectory(utils/llvm-lit)
 572   add_subdirectory(utils/yaml-bench)
 573 else()
 574   if ( LLVM_INCLUDE_TESTS )
 575     message(FATAL_ERROR "Including tests when not building utils will not work.
 576     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 577   endif()
 578 endif()
 579
 580 if(LLVM_INCLUDE_TESTS)
 581   add_subdirectory(utils/unittest)
 582 endif()
 583
 584 foreach( binding ${LLVM_BINDINGS_LIST} )
 585   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 586     add_subdirectory(bindings/${binding})
 587   endif()
 588 endforeach()
 589
 590 add_subdirectory(projects)
 591
 592 if(WITH_POLLY)
 593   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 594     set(WITH_POLLY OFF)
 595   endif()
 596 endif(WITH_POLLY)
 597
 598 if( LLVM_INCLUDE_TOOLS )
 599   add_subdirectory(tools)
 600 endif()
 601
 602 if( LLVM_INCLUDE_EXAMPLES )
 603   add_subdirectory(examples)
 604 endif()
 605
 606 if( LLVM_INCLUDE_TESTS )
 607   add_subdirectory(test)
 608   add_subdirectory(unittests)
 609   if (MSVC)
 610     # This utility is used to prevent crashing tests from calling Dr. Watson on
 611     # Windows.
 612     add_subdirectory(utils/KillTheDoctor)
 613   endif()
 614
 615   # Add a global check rule now that all subdirectories have been traversed
 616   # and we know the total set of lit testsuites.
 617   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 618   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 619   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 620   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 621   add_lit_target(check-all
 622     "Running all regression tests"
 623     ${LLVM_LIT_TESTSUITES}
 624     PARAMS ${LLVM_LIT_PARAMS}
 625     DEPENDS ${LLVM_LIT_DEPENDS}
 626     ARGS ${LLVM_LIT_EXTRA_ARGS}
 627     )
 628 endif()
 629
 630 if (LLVM_INCLUDE_DOCS)
 631   add_subdirectory(docs)
 632 endif()
 633
 634 add_subdirectory(cmake/modules)
 635
 636 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 637   install(DIRECTORY include/llvm include/llvm-c
 638     DESTINATION include
 639     COMPONENT llvm-headers
 640     FILES_MATCHING
 641     PATTERN "*.def"
 642     PATTERN "*.h"
 643     PATTERN "*.td"
 644     PATTERN "*.inc"
 645     PATTERN "LICENSE.TXT"
 646     PATTERN ".svn" EXCLUDE
 647     )
 648
 649   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 650     DESTINATION include
 651     COMPONENT llvm-headers
 652     FILES_MATCHING
 653     PATTERN "*.def"
 654     PATTERN "*.h"
 655     PATTERN "*.gen"
 656     PATTERN "*.inc"
 657     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 658     PATTERN "CMakeFiles" EXCLUDE
 659     PATTERN "config.h" EXCLUDE
 660     PATTERN ".svn" EXCLUDE
 661     )
 662
 663   if (NOT CMAKE_CONFIGURATION_TYPES)
 664     add_custom_target(installhdrs
 665                       DEPENDS ${name}
 666                       COMMAND "${CMAKE_COMMAND}"
 667                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 668                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 669   endif()
 670 endif()