utils/llvm.grm

   1 (*
   2
   3 polygen grammar for LLVM assembly language.
   4
   5 This file defines an LLVM assembly language grammar for polygen,
   6 which is a tool for generating random text based on a grammar.
   7 It is strictly syntax-based, and makes no attempt to generate
   8 IR that is semantically valid. Most of the IR produced doesn't
   9 pass the Verifier.
  10
  11 *)
  12
  13 I ::=   "title:    LLVM assembly language\n"
  14       ^ "status:   experimental\n"
  15       ^ "audience: LLVM developers\n"
  16 ;
  17
  18 S ::= Module ;
  19
  20 (*
  21 Define rules for non-keyword tokens. This is currently just a bunch
  22 of hacks. They don't cover many valid forms of tokens, and they also
  23 generate some invalid forms of tokens. The LLVM parser has custom
  24 C++ code to lex these; custom C++ code for emitting them would be
  25 convenient, but polygen doesn't support that.
  26 *)
  27 NonZeroDecimalDigit ::=     1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  28 DecimalDigit        ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  29 DecimalDigitSeq     ::= DecimalDigit [^ DecimalDigitSeq ];
  30 HexDigit            ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9
  31                       | a | b | c | d | e | f ;
  32 HexDigitSeq         ::= HexDigit [^ HexDigitSeq ];
  33 StringChar          ::= a | b | c | d | e | f | g | h | i | j | k | l | m
  34                       | n | o | p | q | r | s | t | u | v | w | x | y | z ;
  35 StringConstantSeq   ::= StringChar [^ StringConstantSeq ];
  36 StringConstant      ::= StringChar [^ StringConstantSeq ];
  37 EUINT64VAL          ::= NonZeroDecimalDigit [^ DecimalDigitSeq ];
  38 ESINT64VAL          ::= [ "-" ] ^ EUINT64VAL ;
  39 EUAPINTVAL          ::= EUINT64VAL ;
  40 ESAPINTVAL          ::= ESINT64VAL ;
  41 LOCALVALID          ::= "%" ^ DecimalDigitSeq ;
  42 GLOBALVALID         ::= "@" ^ DecimalDigitSeq ;
  43 INTTYPE             ::= "i" ^ EUINT64VAL ;
  44 GLOBALVAR           ::= "@" ^ StringConstant ;
  45 LOCALVAR            ::= "%" ^ StringConstant ;
  46 STRINGCONSTANT      ::= "\"" ^ StringConstant ^ "\"" ;
  47 ATSTRINGCONSTANT    ::= "@" ^ STRINGCONSTANT ;
  48 PCTSTRINGCONSTANT   ::= "%" ^ STRINGCONSTANT ;
  49 LABELSTR            ::= StringConstant ;
  50 FPVAL               ::= ESAPINTVAL ^ "." ^ EUAPINTVAL | "0x" ^ HexDigitSeq ;
  51
  52 (*
  53 The rest of this file is derived directly from llvmAsmParser.y.
  54 *)
  55
  56 ArithmeticOps ::= add | sub | mul | udiv | sdiv | fdiv | urem | srem | frem ;
  57 LogicalOps    ::= shl | lshr | ashr | and | or | xor;
  58 CastOps       ::= trunc | zext | sext | fptrunc | fpext | bitcast |
  59                   uitofp | sitofp | fptoui | fptosi | inttoptr | ptrtoint ;
  60
  61 IPredicates ::= eq | ne | slt | sgt | sle | sge | ult | ugt | ule | uge ;
  62
  63 FPredicates ::= oeq | one | olt | ogt | ole | oge | ord | uno | ueq | une
  64               | ult | ugt | ule | uge | true | false ;
  65
  66 IntType ::= INTTYPE;
  67 FPType  ::= float | double | "ppc_fp128" | fp128 | "x86_fp80";
  68
  69 LocalName ::= LOCALVAR | STRINGCONSTANT | PCTSTRINGCONSTANT ;
  70 OptLocalName ::= LocalName | _ ;
  71
  72 OptAddrSpace ::= - addrspace ^ "(" ^ EUINT64VAL ^ ")" | _ ;
  73
  74 OptLocalAssign ::= LocalName "=" | _ ;
  75
  76 GlobalName ::= GLOBALVAR | ATSTRINGCONSTANT ;
  77
  78 OptGlobalAssign ::= GlobalAssign | _ ;
  79
  80 GlobalAssign ::= GlobalName "=" ;
  81
  82 GVInternalLinkage
  83   ::= + internal
  84  | weak
  85  | linkonce
  86  | appending
  87  | dllexport
  88  | common
  89  ;
  90
  91 GVExternalLinkage
  92   ::= dllimport
  93  | "extern_weak"
  94  | + external
  95  ;
  96
  97 GVVisibilityStyle
  98   ::= + _
  99  | default
 100  | hidden
 101  | protected
 102  ;
 103
 104 FunctionDeclareLinkage
 105   ::= + _
 106  | dllimport
 107  | "extern_weak"
 108  ;
 109
 110 FunctionDefineLinkage
 111   ::= + _
 112  | internal
 113  | linkonce
 114  | weak
 115  | dllexport
 116  ;
 117
 118 AliasLinkage ::= + _ | weak | internal ;
 119
 120 OptCallingConv ::= + _ |
 121                  ccc |
 122                  fastcc |
 123                  coldcc |
 124                  "x86_stdcallcc" |
 125                  "x86_fastcallcc" |
 126                  cc EUINT64VAL ;
 127
 128 ParamAttr ::= zeroext
 129  | zext
 130  | signext
 131  | sext
 132  | inreg
 133  | sret
 134  | noalias
 135  | nocapture
 136  | byval
 137  | nest
 138  | align EUINT64VAL
 139  ;
 140
 141 OptParamAttrs ::= + _ | OptParamAttrs ParamAttr ;
 142
 143 RetAttr       ::= inreg
 144               | zeroext
 145               | signext
 146               | noalias
 147               ;
 148
 149 OptRetAttrs  ::= _
 150              | OptRetAttrs RetAttr
 151              ;
 152
 153 FuncAttr      ::= noreturn
 154  | nounwind
 155  | inreg
 156  | zeroext
 157  | signext
 158  | readnone
 159  | readonly
 160  | noinline
 161  | alwaysinline
 162  | optsize
 163  | ssp
 164  | sspreq
 165  ;
 166
 167 OptFuncAttrs  ::= + _ | OptFuncAttrs FuncAttr ;
 168
 169 OptGC         ::= + _ | gc STRINGCONSTANT ;
 170
 171 OptAlign      ::= + _ | align EUINT64VAL ;
 172 OptCAlign     ::= + _ | ^ "," align EUINT64VAL ;
 173
 174 SectionString ::= section STRINGCONSTANT ;
 175
 176 OptSection    ::= + _ | SectionString ;
 177
 178 GlobalVarAttributes ::= + _ | ^ "," GlobalVarAttribute GlobalVarAttributes ;
 179 GlobalVarAttribute  ::= SectionString | align EUINT64VAL ;
 180
 181 PrimType ::= INTTYPE | float | double | "ppc_fp128" | fp128 | "x86_fp80"
 182           | - label ;
 183
 184 Types
 185   ::= opaque
 186  | PrimType
 187  | Types OptAddrSpace ^ "*"
 188  | SymbolicValueRef
 189  | "\\" ^ EUINT64VAL
 190  | Types "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 191  | void "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 192  | "[" ^ EUINT64VAL "x" Types ^ "]"
 193  | "<" ^ EUINT64VAL "x" Types ^ ">"
 194  | "{" TypeListI "}"
 195  | "{" ^ "}"
 196  | "<" ^ "{" TypeListI "}" ^ ">"
 197  | "<" ^ "{" ^ "}" ^ ">"
 198  ;
 199
 200 ArgType ::= Types OptParamAttrs ;
 201
 202 ResultTypes ::= Types | void ;
 203
 204 ArgTypeList ::= ArgType | ArgTypeList ^ "," ArgType ;
 205
 206 ArgTypeListI ::= ArgTypeList | ArgTypeList ^ "," "..." | "..." | _ ;
 207
 208 TypeListI ::= Types | TypeListI ^ "," Types ;
 209
 210 ConstVal::= Types "[" ^ ConstVector ^ "]"
 211  | Types "[" ^ "]"
 212  | Types "c" ^ STRINGCONSTANT
 213  | Types "<" ^ ConstVector ^ ">"
 214  | Types "{" ConstVector "}"
 215  | Types "{" ^ "}"
 216  | Types "<" ^ "{" ConstVector "}" ^ ">"
 217  | Types "<" ^ "{" ^ "}" ^ ">"
 218  | Types null
 219  | Types undef
 220  | Types SymbolicValueRef
 221  | Types ConstExpr
 222  | Types zeroinitializer
 223  | Types ESINT64VAL
 224  | Types ESAPINTVAL
 225  | Types EUINT64VAL
 226  | Types EUAPINTVAL
 227  | Types true
 228  | Types false
 229  | Types FPVAL ;
 230
 231 ConstExpr::= CastOps "(" ^ ConstVal to Types ^ ")"
 232  | getelementptr "(" ^ ConstVal IndexList ^ ")"
 233  | select "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 234  | ArithmeticOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 235  | LogicalOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 236  | icmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 237  | fcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 238  | vicmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 239  | vfcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 240  | extractelement "(" ^ ConstVal ^ "," ConstVal ^ ")"
 241  | insertelement "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 242  | shufflevector "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 243  | extractvalue "(" ^ ConstVal ^ ConstantIndexList ^ ")"
 244  | insertvalue "(" ^ ConstVal ^ "," ConstVal ^ ConstantIndexList ^ ")" ;
 245
 246 ConstVector ::= ConstVector ^ "," ConstVal | ConstVal ;
 247
 248 GlobalType ::= global | constant ;
 249
 250 ThreadLocal ::= - "thread_local" | _ ;
 251
 252 AliaseeRef ::= ResultTypes SymbolicValueRef
 253  | bitcast "(" ^ AliaseeRef to Types ^ ")" ;
 254
 255 Module ::= +++ DefinitionList | --- _ ;
 256
 257 DefinitionList ::= - Definition | + DefinitionList Definition ;
 258
 259 Definition
 260   ::= ^ ( +++++ define Function
 261  | declare FunctionProto
 262  | - module asm AsmBlock
 263  | OptLocalAssign type Types
 264  | OptGlobalAssign GVVisibilityStyle ThreadLocal OptAddrSpace OptAddrSpace
 265    ConstVal GlobalVarAttributes
 266  | OptGlobalAssign GVInternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 267    GlobalType ConstVal GlobalVarAttributes
 268  | OptGlobalAssign GVExternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 269    GlobalType Types GlobalVarAttributes
 270  | OptGlobalAssign GVVisibilityStyle alias AliasLinkage AliaseeRef
 271  | target TargetDefinition
 272  | deplibs "=" LibrariesDefinition
 273  ) ^ "\n";
 274
 275 AsmBlock ::= STRINGCONSTANT ;
 276
 277 TargetDefinition ::= triple "=" STRINGCONSTANT
 278  | datalayout "=" STRINGCONSTANT ;
 279
 280 LibrariesDefinition ::= "[" ( LibList | _ ) "]";
 281
 282 LibList ::= LibList ^ "," STRINGCONSTANT | STRINGCONSTANT ;
 283
 284 ArgListH ::= ArgListH ^ "," Types OptParamAttrs OptLocalName
 285  | Types OptParamAttrs OptLocalName ;
 286
 287 ArgList ::= ArgListH | ArgListH ^ "," "..." | "..." | _ ;
 288
 289 FunctionHeaderH ::= OptCallingConv OptRetAttrs ResultTypes
 290                   GlobalName ^ "(" ^ ArgList ^ ")"
 291                   OptFuncAttrs OptSection OptAlign OptGC ;
 292
 293 BEGIN ::= ( begin | "{" ) ^ "\n";
 294
 295 FunctionHeader ::=
 296   FunctionDefineLinkage GVVisibilityStyle FunctionHeaderH BEGIN ;
 297
 298 END ::= ^ ( end | "}" ) ^ "\n";
 299
 300 Function ::= BasicBlockList END ;
 301
 302 FunctionProto ::= FunctionDeclareLinkage GVVisibilityStyle FunctionHeaderH ;
 303
 304 OptSideEffect ::= _ | sideeffect ;
 305
 306 ConstValueRef ::= ESINT64VAL
 307  | EUINT64VAL
 308  | FPVAL
 309  | true
 310  | false
 311  | null
 312  | undef
 313  | zeroinitializer
 314  | "<" ConstVector ">"
 315  | "[" ConstVector "]"
 316  | "[" ^ "]"
 317  | "c" ^ STRINGCONSTANT
 318  | "{" ConstVector "}"
 319  | "{" ^ "}"
 320  | "<" ^ "{" ConstVector "}" ^ ">"
 321  | "<" ^ "{" ^ "}" ^ ">"
 322  | ConstExpr
 323  | asm OptSideEffect STRINGCONSTANT ^ "," STRINGCONSTANT ;
 324
 325 SymbolicValueRef ::= LOCALVALID
 326  | GLOBALVALID
 327  | LocalName
 328  | GlobalName ;
 329
 330 ValueRef ::= SymbolicValueRef | ConstValueRef;
 331
 332 ResolvedVal ::= Types ValueRef ;
 333
 334 ReturnedVal ::= ResolvedVal | ReturnedVal ^ "," ResolvedVal ;
 335
 336 BasicBlockList ::= BasicBlockList BasicBlock | FunctionHeader BasicBlock ;
 337
 338 BasicBlock ::= InstructionList OptLocalAssign BBTerminatorInst ;
 339
 340 InstructionList ::= +++ InstructionList Inst
 341  | - _
 342  | ^ LABELSTR ^ ":\n" ;
 343
 344 BBTerminatorInst ::= ^ "  " ^
 345  ( ret ReturnedVal
 346  | ret void
 347  | br label ValueRef
 348  | br INTTYPE ValueRef ^ "," label ValueRef ^ "," label ValueRef
 349  | switch IntType ValueRef ^ "," label ValueRef "[" JumpTable "]"
 350  | switch IntType ValueRef ^ "," label ValueRef "[" ^ "]"
 351  | invoke OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 352    OptFuncAttrs
 353    to label ValueRef unwind label ValueRef
 354  | unwind
 355  | unreachable ) ^ "\n";
 356
 357 JumpTable ::= JumpTable IntType ConstValueRef ^ "," label ValueRef
 358  | IntType ConstValueRef ^ "," label ValueRef ;
 359
 360 Inst ::= ^ "  " ^ OptLocalAssign InstVal ^ "\n";
 361
 362 PHIList ::= Types "[" ValueRef ^ "," ValueRef "]"
 363  | PHIList ^ "," "[" ValueRef ^ "," ValueRef "]" ;
 364
 365 ParamList ::= Types OptParamAttrs ValueRef OptParamAttrs
 366  | label OptParamAttrs ValueRef OptParamAttrs
 367  | ParamList ^ "," Types OptParamAttrs ValueRef OptParamAttrs
 368  | ParamList ^ "," label OptParamAttrs ValueRef OptParamAttrs
 369  | - _ ;
 370
 371 IndexList ::= _ | IndexList ^ "," ResolvedVal ;
 372
 373 ConstantIndexList ::= "," EUINT64VAL | ConstantIndexList ^ "," EUINT64VAL ;
 374
 375 OptTailCall ::= tail call | call ;
 376
 377 InstVal ::=
 378    ArithmeticOps Types ValueRef ^ "," ValueRef
 379  | LogicalOps Types ValueRef ^ "," ValueRef
 380  | icmp IPredicates Types ValueRef ^ "," ValueRef
 381  | fcmp FPredicates Types ValueRef ^ "," ValueRef
 382  | vicmp IPredicates Types ValueRef ^ "," ValueRef
 383  | vfcmp FPredicates Types ValueRef ^ "," ValueRef
 384  | CastOps ResolvedVal to Types
 385  | select ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 386  | "va_arg" ResolvedVal ^ "," Types
 387  | extractelement ResolvedVal ^ "," ResolvedVal
 388  | insertelement ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 389  | shufflevector ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 390  | phi PHIList
 391  | OptTailCall OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 392    OptFuncAttrs
 393  | MemoryInst ;
 394
 395 OptVolatile ::= - volatile | _ ;
 396
 397 MemoryInst ::= malloc Types OptCAlign
 398  | malloc Types ^ "," INTTYPE ValueRef OptCAlign
 399  | alloca Types OptCAlign
 400  | alloca Types ^ "," INTTYPE ValueRef OptCAlign
 401  | free ResolvedVal
 402  | OptVolatile load Types ValueRef OptCAlign
 403  | OptVolatile store ResolvedVal ^ "," Types ValueRef OptCAlign
 404  | getresult Types ValueRef ^ "," EUINT64VAL
 405  | getelementptr Types ValueRef IndexList
 406  | extractvalue Types ValueRef ^ ConstantIndexList
 407  | insertvalue Types ValueRef ^ "," Types ValueRef ^ ConstantIndexList ;