utils/llvm.grm

   1 (*
   2
   3 polygen grammar for LLVM assembly language.
   4
   5 This file defines an LLVM assembly language grammar for polygen,
   6 which is a tool for generating random text based on a grammar.
   7 It is strictly syntax-based, and makes no attempt to generate
   8 IR that is semantically valid. Most of the IR produced doesn't
   9 pass the Verifier.
  10
  11 *)
  12
  13 I ::=   "title:    LLVM assembly language\n"
  14       ^ "status:   experimental\n"
  15       ^ "audience: LLVM developers\n"
  16 ;
  17
  18 S ::= Module ;
  19
  20 (*
  21 Define rules for non-keyword tokens. This is currently just a bunch
  22 of hacks. They don't cover many valid forms of tokens, and they also
  23 generate some invalid forms of tokens. The LLVM parser has custom
  24 C++ code to lex these; custom C++ code for emitting them would be
  25 convenient, but polygen doesn't support that.
  26 *)
  27 NonZeroDecimalDigit ::=     1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  28 DecimalDigit        ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  29 DecimalDigitSeq     ::= DecimalDigit [^ DecimalDigitSeq ];
  30 HexDigit            ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9
  31                       | a | b | c | d | e | f ;
  32 HexDigitSeq         ::= HexDigit [^ HexDigitSeq ];
  33 StringChar          ::= a | b | c | d | e | f | g | h | i | j | k | l | m
  34                       | n | o | p | q | r | s | t | u | v | w | x | y | z ;
  35 StringConstantSeq   ::= StringChar [^ StringConstantSeq ];
  36 StringConstant      ::= StringChar [^ StringConstantSeq ];
  37 EUINT64VAL          ::= NonZeroDecimalDigit [^ DecimalDigitSeq ];
  38 ESINT64VAL          ::= [ "-" ] ^ EUINT64VAL ;
  39 EUAPINTVAL          ::= EUINT64VAL ;
  40 ESAPINTVAL          ::= ESINT64VAL ;
  41 LOCALVALID          ::= "%" ^ DecimalDigitSeq ;
  42 GLOBALVALID         ::= "@" ^ DecimalDigitSeq ;
  43 INTTYPE             ::= "i" ^ EUINT64VAL ;
  44 GLOBALVAR           ::= "@" ^ StringConstant ;
  45 LOCALVAR            ::= "%" ^ StringConstant ;
  46 STRINGCONSTANT      ::= "\"" ^ StringConstant ^ "\"" ;
  47 ATSTRINGCONSTANT    ::= "@" ^ STRINGCONSTANT ;
  48 PCTSTRINGCONSTANT   ::= "%" ^ STRINGCONSTANT ;
  49 LABELSTR            ::= StringConstant ;
  50 FPVAL               ::= ESAPINTVAL ^ "." ^ EUAPINTVAL | "0x" ^ HexDigitSeq ;
  51
  52 (*
  53 The rest of this file is derived directly from llvmAsmParser.y.
  54 *)
  55
  56 ArithmeticOps ::= add | sub | mul | udiv | sdiv | fdiv | urem | srem | frem ;
  57 LogicalOps    ::= shl | lshr | ashr | and | or | xor;
  58 CastOps       ::= trunc | zext | sext | fptrunc | fpext | bitcast |
  59                   uitofp | sitofp | fptoui | fptosi | inttoptr | ptrtoint ;
  60
  61 IPredicates ::= eq | ne | slt | sgt | sle | sge | ult | ugt | ule | uge ;
  62
  63 FPredicates ::= oeq | one | olt | ogt | ole | oge | ord | uno | ueq | une
  64               | ult | ugt | ule | uge | true | false ;
  65
  66 IntType ::= INTTYPE;
  67 FPType  ::= float | double | "ppc_fp128" | fp128 | "x86_fp80";
  68
  69 LocalName ::= LOCALVAR | STRINGCONSTANT | PCTSTRINGCONSTANT ;
  70 OptLocalName ::= LocalName | _ ;
  71
  72 OptAddrSpace ::= - addrspace ^ "(" ^ EUINT64VAL ^ ")" | _ ;
  73
  74 OptLocalAssign ::= LocalName "=" | _ ;
  75
  76 GlobalName ::= GLOBALVAR | ATSTRINGCONSTANT ;
  77
  78 OptGlobalAssign ::= GlobalAssign | _ ;
  79
  80 GlobalAssign ::= GlobalName "=" ;
  81
  82 GVInternalLinkage
  83   ::= + internal
  84  | weak
  85  | "weak_odr"
  86  | linkonce
  87  | "linkonce_odr"
  88  | appending
  89  | dllexport
  90  | common
  91  | "common_odr"
  92  ;
  93
  94 GVExternalLinkage
  95   ::= dllimport
  96  | "extern_weak"
  97  | "extern_weak_odr"
  98  | + external
  99  ;
 100
 101 GVVisibilityStyle
 102   ::= + _
 103  | default
 104  | hidden
 105  | protected
 106  ;
 107
 108 FunctionDeclareLinkage
 109   ::= + _
 110  | dllimport
 111  | "extern_weak"
 112  | "extern_weak_odr"
 113  ;
 114
 115 FunctionDefineLinkage
 116   ::= + _
 117  | internal
 118  | linkonce
 119  | "linkonce_odr"
 120  | weak
 121  | "weak_odr"
 122  | dllexport
 123  ;
 124
 125 AliasLinkage ::= + _ | weak | "weak_odr" | internal ;
 126
 127 OptCallingConv ::= + _ |
 128                  ccc |
 129                  fastcc |
 130                  coldcc |
 131                  "x86_stdcallcc" |
 132                  "x86_fastcallcc" |
 133                  cc EUINT64VAL ;
 134
 135 ParamAttr ::= zeroext
 136  | zext
 137  | signext
 138  | sext
 139  | inreg
 140  | sret
 141  | noalias
 142  | nocapture
 143  | byval
 144  | nest
 145  | align EUINT64VAL
 146  ;
 147
 148 OptParamAttrs ::= + _ | OptParamAttrs ParamAttr ;
 149
 150 RetAttr       ::= inreg
 151               | zeroext
 152               | signext
 153               | noalias
 154               ;
 155
 156 OptRetAttrs  ::= _
 157              | OptRetAttrs RetAttr
 158              ;
 159
 160 FuncAttr      ::= noreturn
 161  | nounwind
 162  | inreg
 163  | zeroext
 164  | signext
 165  | readnone
 166  | readonly
 167  | noinline
 168  | alwaysinline
 169  | optsize
 170  | ssp
 171  | sspreq
 172  ;
 173
 174 OptFuncAttrs  ::= + _ | OptFuncAttrs FuncAttr ;
 175
 176 OptGC         ::= + _ | gc STRINGCONSTANT ;
 177
 178 OptAlign      ::= + _ | align EUINT64VAL ;
 179 OptCAlign     ::= + _ | ^ "," align EUINT64VAL ;
 180
 181 SectionString ::= section STRINGCONSTANT ;
 182
 183 OptSection    ::= + _ | SectionString ;
 184
 185 GlobalVarAttributes ::= + _ | ^ "," GlobalVarAttribute GlobalVarAttributes ;
 186 GlobalVarAttribute  ::= SectionString | align EUINT64VAL ;
 187
 188 PrimType ::= INTTYPE | float | double | "ppc_fp128" | fp128 | "x86_fp80"
 189           | - label ;
 190
 191 Types
 192   ::= opaque
 193  | PrimType
 194  | Types OptAddrSpace ^ "*"
 195  | SymbolicValueRef
 196  | "\\" ^ EUINT64VAL
 197  | Types "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 198  | void "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 199  | "[" ^ EUINT64VAL "x" Types ^ "]"
 200  | "<" ^ EUINT64VAL "x" Types ^ ">"
 201  | "{" TypeListI "}"
 202  | "{" ^ "}"
 203  | "<" ^ "{" TypeListI "}" ^ ">"
 204  | "<" ^ "{" ^ "}" ^ ">"
 205  ;
 206
 207 ArgType ::= Types OptParamAttrs ;
 208
 209 ResultTypes ::= Types | void ;
 210
 211 ArgTypeList ::= ArgType | ArgTypeList ^ "," ArgType ;
 212
 213 ArgTypeListI ::= ArgTypeList | ArgTypeList ^ "," "..." | "..." | _ ;
 214
 215 TypeListI ::= Types | TypeListI ^ "," Types ;
 216
 217 ConstVal::= Types "[" ^ ConstVector ^ "]"
 218  | Types "[" ^ "]"
 219  | Types "c" ^ STRINGCONSTANT
 220  | Types "<" ^ ConstVector ^ ">"
 221  | Types "{" ConstVector "}"
 222  | Types "{" ^ "}"
 223  | Types "<" ^ "{" ConstVector "}" ^ ">"
 224  | Types "<" ^ "{" ^ "}" ^ ">"
 225  | Types null
 226  | Types undef
 227  | Types SymbolicValueRef
 228  | Types ConstExpr
 229  | Types zeroinitializer
 230  | Types ESINT64VAL
 231  | Types ESAPINTVAL
 232  | Types EUINT64VAL
 233  | Types EUAPINTVAL
 234  | Types true
 235  | Types false
 236  | Types FPVAL ;
 237
 238 ConstExpr::= CastOps "(" ^ ConstVal to Types ^ ")"
 239  | getelementptr "(" ^ ConstVal IndexList ^ ")"
 240  | select "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 241  | ArithmeticOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 242  | LogicalOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 243  | icmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 244  | fcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 245  | vicmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 246  | vfcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 247  | extractelement "(" ^ ConstVal ^ "," ConstVal ^ ")"
 248  | insertelement "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 249  | shufflevector "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 250  | extractvalue "(" ^ ConstVal ^ ConstantIndexList ^ ")"
 251  | insertvalue "(" ^ ConstVal ^ "," ConstVal ^ ConstantIndexList ^ ")" ;
 252
 253 ConstVector ::= ConstVector ^ "," ConstVal | ConstVal ;
 254
 255 GlobalType ::= global | constant ;
 256
 257 ThreadLocal ::= - "thread_local" | _ ;
 258
 259 AliaseeRef ::= ResultTypes SymbolicValueRef
 260  | bitcast "(" ^ AliaseeRef to Types ^ ")" ;
 261
 262 Module ::= +++ DefinitionList | --- _ ;
 263
 264 DefinitionList ::= - Definition | + DefinitionList Definition ;
 265
 266 Definition
 267   ::= ^ ( +++++ define Function
 268  | declare FunctionProto
 269  | - module asm AsmBlock
 270  | OptLocalAssign type Types
 271  | OptGlobalAssign GVVisibilityStyle ThreadLocal OptAddrSpace GlobalType
 272    ConstVal GlobalVarAttributes
 273  | OptGlobalAssign GVInternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 274    GlobalType ConstVal GlobalVarAttributes
 275  | OptGlobalAssign GVExternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 276    GlobalType Types GlobalVarAttributes
 277  | OptGlobalAssign GVVisibilityStyle alias AliasLinkage AliaseeRef
 278  | target TargetDefinition
 279  | deplibs "=" LibrariesDefinition
 280  ) ^ "\n";
 281
 282 AsmBlock ::= STRINGCONSTANT ;
 283
 284 TargetDefinition ::= triple "=" STRINGCONSTANT
 285  | datalayout "=" STRINGCONSTANT ;
 286
 287 LibrariesDefinition ::= "[" ( LibList | _ ) "]";
 288
 289 LibList ::= LibList ^ "," STRINGCONSTANT | STRINGCONSTANT ;
 290
 291 ArgListH ::= ArgListH ^ "," Types OptParamAttrs OptLocalName
 292  | Types OptParamAttrs OptLocalName ;
 293
 294 ArgList ::= ArgListH | ArgListH ^ "," "..." | "..." | _ ;
 295
 296 FunctionHeaderH ::= OptCallingConv OptRetAttrs ResultTypes
 297                   GlobalName ^ "(" ^ ArgList ^ ")"
 298                   OptFuncAttrs OptSection OptAlign OptGC ;
 299
 300 BEGIN ::= ( begin | "{" ) ^ "\n";
 301
 302 FunctionHeader ::=
 303   FunctionDefineLinkage GVVisibilityStyle FunctionHeaderH BEGIN ;
 304
 305 END ::= ^ ( end | "}" ) ^ "\n";
 306
 307 Function ::= BasicBlockList END ;
 308
 309 FunctionProto ::= FunctionDeclareLinkage GVVisibilityStyle FunctionHeaderH ;
 310
 311 OptSideEffect ::= _ | sideeffect ;
 312
 313 ConstValueRef ::= ESINT64VAL
 314  | EUINT64VAL
 315  | FPVAL
 316  | true
 317  | false
 318  | null
 319  | undef
 320  | zeroinitializer
 321  | "<" ConstVector ">"
 322  | "[" ConstVector "]"
 323  | "[" ^ "]"
 324  | "c" ^ STRINGCONSTANT
 325  | "{" ConstVector "}"
 326  | "{" ^ "}"
 327  | "<" ^ "{" ConstVector "}" ^ ">"
 328  | "<" ^ "{" ^ "}" ^ ">"
 329  | ConstExpr
 330  | asm OptSideEffect STRINGCONSTANT ^ "," STRINGCONSTANT ;
 331
 332 SymbolicValueRef ::= LOCALVALID
 333  | GLOBALVALID
 334  | LocalName
 335  | GlobalName ;
 336
 337 ValueRef ::= SymbolicValueRef | ConstValueRef;
 338
 339 ResolvedVal ::= Types ValueRef ;
 340
 341 ReturnedVal ::= ResolvedVal | ReturnedVal ^ "," ResolvedVal ;
 342
 343 BasicBlockList ::= BasicBlockList BasicBlock | FunctionHeader BasicBlock ;
 344
 345 BasicBlock ::= InstructionList OptLocalAssign BBTerminatorInst ;
 346
 347 InstructionList ::= +++ InstructionList Inst
 348  | - _
 349  | ^ LABELSTR ^ ":\n" ;
 350
 351 BBTerminatorInst ::= ^ "  " ^
 352  ( ret ReturnedVal
 353  | ret void
 354  | br label ValueRef
 355  | br INTTYPE ValueRef ^ "," label ValueRef ^ "," label ValueRef
 356  | switch IntType ValueRef ^ "," label ValueRef "[" JumpTable "]"
 357  | switch IntType ValueRef ^ "," label ValueRef "[" ^ "]"
 358  | invoke OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 359    OptFuncAttrs
 360    to label ValueRef unwind label ValueRef
 361  | unwind
 362  | unreachable ) ^ "\n";
 363
 364 JumpTable ::= JumpTable IntType ConstValueRef ^ "," label ValueRef
 365  | IntType ConstValueRef ^ "," label ValueRef ;
 366
 367 Inst ::= ^ "  " ^ OptLocalAssign InstVal ^ "\n";
 368
 369 PHIList ::= Types "[" ValueRef ^ "," ValueRef "]"
 370  | PHIList ^ "," "[" ValueRef ^ "," ValueRef "]" ;
 371
 372 ParamList ::= Types OptParamAttrs ValueRef OptParamAttrs
 373  | label OptParamAttrs ValueRef OptParamAttrs
 374  | ParamList ^ "," Types OptParamAttrs ValueRef OptParamAttrs
 375  | ParamList ^ "," label OptParamAttrs ValueRef OptParamAttrs
 376  | - _ ;
 377
 378 IndexList ::= _ | IndexList ^ "," ResolvedVal ;
 379
 380 ConstantIndexList ::= "," EUINT64VAL | ConstantIndexList ^ "," EUINT64VAL ;
 381
 382 OptTailCall ::= tail call | call ;
 383
 384 InstVal ::=
 385    ArithmeticOps Types ValueRef ^ "," ValueRef
 386  | LogicalOps Types ValueRef ^ "," ValueRef
 387  | icmp IPredicates Types ValueRef ^ "," ValueRef
 388  | fcmp FPredicates Types ValueRef ^ "," ValueRef
 389  | vicmp IPredicates Types ValueRef ^ "," ValueRef
 390  | vfcmp FPredicates Types ValueRef ^ "," ValueRef
 391  | CastOps ResolvedVal to Types
 392  | select ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 393  | "va_arg" ResolvedVal ^ "," Types
 394  | extractelement ResolvedVal ^ "," ResolvedVal
 395  | insertelement ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 396  | shufflevector ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 397  | phi PHIList
 398  | OptTailCall OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 399    OptFuncAttrs
 400  | MemoryInst ;
 401
 402 OptVolatile ::= - volatile | _ ;
 403
 404 MemoryInst ::= malloc Types OptCAlign
 405  | malloc Types ^ "," INTTYPE ValueRef OptCAlign
 406  | alloca Types OptCAlign
 407  | alloca Types ^ "," INTTYPE ValueRef OptCAlign
 408  | free ResolvedVal
 409  | OptVolatile load Types ValueRef OptCAlign
 410  | OptVolatile store ResolvedVal ^ "," Types ValueRef OptCAlign
 411  | getresult Types ValueRef ^ "," EUINT64VAL
 412  | getelementptr Types ValueRef IndexList
 413  | extractvalue Types ValueRef ^ ConstantIndexList
 414  | insertvalue Types ValueRef ^ "," Types ValueRef ^ ConstantIndexList ;