utils/llvm.grm

   1 (*
   2
   3 polygen grammar for LLVM assembly language.
   4
   5 This file defines an LLVM assembly language grammar for polygen,
   6 which is a tool for generating random text based on a grammar.
   7 It is strictly syntax-based, and makes no attempt to generate
   8 IR that is semantically valid. Most of the IR produced doesn't
   9 pass the Verifier.
  10
  11 TODO: Metadata, in all its forms
  12
  13 *)
  14
  15 I ::=   "title:    LLVM assembly language\n"
  16       ^ "status:   experimental\n"
  17       ^ "audience: LLVM developers\n"
  18 ;
  19
  20 S ::= Module ;
  21
  22 (*
  23 Define rules for non-keyword tokens. This is currently just a bunch
  24 of hacks. They don't cover many valid forms of tokens, and they also
  25 generate some invalid forms of tokens. The LLVM parser has custom
  26 C++ code to lex these; custom C++ code for emitting them would be
  27 convenient, but polygen doesn't support that.
  28 *)
  29 NonZeroDecimalDigit ::=     1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  30 DecimalDigit        ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  31 DecimalDigitSeq     ::= DecimalDigit [^ DecimalDigitSeq ];
  32 HexDigit            ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9
  33                       | a | b | c | d | e | f ;
  34 HexDigitSeq         ::= HexDigit [^ HexDigitSeq ];
  35 StringChar          ::= a | b | c | d | e | f | g | h | i | j | k | l | m
  36                       | n | o | p | q | r | s | t | u | v | w | x | y | z ;
  37 StringConstantSeq   ::= StringChar [^ StringConstantSeq ];
  38 StringConstant      ::= StringChar [^ StringConstantSeq ];
  39 EUINT64VAL          ::= NonZeroDecimalDigit [^ DecimalDigitSeq ];
  40 ESINT64VAL          ::= [ "-" ] ^ EUINT64VAL ;
  41 EUAPINTVAL          ::= EUINT64VAL ;
  42 ESAPINTVAL          ::= ESINT64VAL ;
  43 LOCALVALID          ::= "%" ^ DecimalDigitSeq ;
  44 GLOBALVALID         ::= "@" ^ DecimalDigitSeq ;
  45 INTTYPE             ::= "i" ^ EUINT64VAL ;
  46 GLOBALVAR           ::= "@" ^ StringConstant ;
  47 LOCALVAR            ::= "%" ^ StringConstant ;
  48 STRINGCONSTANT      ::= "\"" ^ StringConstant ^ "\"" ;
  49 ATSTRINGCONSTANT    ::= "@" ^ STRINGCONSTANT ;
  50 PCTSTRINGCONSTANT   ::= "%" ^ STRINGCONSTANT ;
  51 LABELSTR            ::= StringConstant ;
  52 FPVAL               ::= ESAPINTVAL ^ "." ^ EUAPINTVAL | "0x" ^ HexDigitSeq ;
  53
  54 (*
  55 The rest of this file is derived directly from llvmAsmParser.y.
  56 *)
  57
  58 ArithmeticOps ::= + OptNW add | fadd | OptNW sub | fsub | OptNW mul | fmul |
  59                   udiv | OptExact sdiv | fdiv | urem | srem | frem ;
  60 LogicalOps    ::= shl | lshr | ashr | and | or | xor;
  61 CastOps       ::= trunc | zext | sext | fptrunc | fpext | bitcast |
  62                   uitofp | sitofp | fptoui | fptosi | inttoptr | ptrtoint ;
  63
  64 IPredicates ::= eq | ne | slt | sgt | sle | sge | ult | ugt | ule | uge ;
  65
  66 FPredicates ::= oeq | one | olt | ogt | ole | oge | ord | uno | ueq | une
  67               | ult | ugt | ule | uge | true | false ;
  68
  69 IntType ::= INTTYPE;
  70 FPType  ::= float | double | "ppc_fp128" | fp128 | "x86_fp80";
  71
  72 LocalName ::= LOCALVAR | STRINGCONSTANT | PCTSTRINGCONSTANT ;
  73 OptLocalName ::= LocalName | _ ;
  74
  75 OptAddrSpace ::= - addrspace ^ "(" ^ EUINT64VAL ^ ")" | _ ;
  76
  77 OptLocalAssign ::= LocalName "=" | _ ;
  78
  79 GlobalName ::= GLOBALVAR | ATSTRINGCONSTANT ;
  80
  81 OptGlobalAssign ::= GlobalAssign | _ ;
  82
  83 GlobalAssign ::= GlobalName "=" ;
  84
  85 GVInternalLinkage
  86   ::= + internal
  87  | weak
  88  | "weak_odr"
  89  | linkonce
  90  | "linkonce_odr"
  91  | appending
  92  | dllexport
  93  | common
  94  | private
  95  | "linker_private"
  96  | "linker_private_weak"
  97  ;
  98
  99 GVExternalLinkage
 100   ::= dllimport
 101  | "extern_weak"
 102  | + external
 103  ;
 104
 105 GVVisibilityStyle
 106   ::= + _
 107  | default
 108  | hidden
 109  | protected
 110  ;
 111
 112 FunctionDeclareLinkage
 113   ::= + _
 114  | dllimport
 115  | "extern_weak"
 116  ;
 117
 118 FunctionDefineLinkage
 119   ::= + _
 120  | internal
 121  | linkonce
 122  | "linkonce_odr"
 123  | weak
 124  | "weak_odr"
 125  | dllexport
 126  ;
 127
 128 AliasLinkage ::= + _ | weak | "weak_odr" | internal ;
 129
 130 OptCallingConv ::= + _ |
 131                  ccc |
 132                  fastcc |
 133                  coldcc |
 134                  "x86_stdcallcc" |
 135                  "x86_fastcallcc" |
 136                  cc EUINT64VAL ;
 137
 138 ParamAttr ::= zeroext
 139  | signext
 140  | inreg
 141  | sret
 142  | noalias
 143  | nocapture
 144  | byval
 145  | nest
 146  | align EUINT64VAL
 147  ;
 148
 149 OptParamAttrs ::= + _ | OptParamAttrs ParamAttr ;
 150
 151 RetAttr       ::= inreg
 152               | zeroext
 153               | signext
 154               | noalias
 155               ;
 156
 157 OptRetAttrs  ::= _
 158              | OptRetAttrs RetAttr
 159              ;
 160
 161 FuncAttr      ::= noreturn
 162  | nounwind
 163  | inreg
 164  | zeroext
 165  | signext
 166  | readnone
 167  | readonly
 168  | inlinehint
 169  | alignstack
 170  | noinline
 171  | alwaysinline
 172  | optsize
 173  | ssp
 174  | sspreq
 175  | returns_twice
 176  | nonlazybind
 177  | address_safety
 178  | ia_nsdialect
 179  ;
 180
 181 OptFuncAttrs  ::= + _ | OptFuncAttrs FuncAttr ;
 182
 183 OptGC         ::= + _ | gc STRINGCONSTANT ;
 184
 185 OptAlign      ::= + _ | align EUINT64VAL ;
 186 OptCAlign     ::= + _ | ^ "," align EUINT64VAL ;
 187
 188 SectionString ::= section STRINGCONSTANT ;
 189
 190 OptSection    ::= + _ | SectionString ;
 191
 192 GlobalVarAttributes ::= + _ | ^ "," GlobalVarAttribute GlobalVarAttributes ;
 193 GlobalVarAttribute  ::= SectionString | align EUINT64VAL ;
 194
 195 PrimType ::= INTTYPE | float | double | "ppc_fp128" | fp128 | "x86_fp80"
 196           | - label ;
 197
 198 Types
 199   ::= opaque
 200  | PrimType
 201  | Types OptAddrSpace ^ "*"
 202  | SymbolicValueRef
 203  | "\\" ^ EUINT64VAL
 204  | Types "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 205  | void "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 206  | "[" ^ EUINT64VAL "x" Types ^ "]"
 207  | "<" ^ EUINT64VAL "x" Types ^ ">"
 208  | "{" TypeListI "}"
 209  | "{" ^ "}"
 210  | "<" ^ "{" TypeListI "}" ^ ">"
 211  | "<" ^ "{" ^ "}" ^ ">"
 212  ;
 213
 214 ArgType ::= Types OptParamAttrs ;
 215
 216 ResultTypes ::= Types | void ;
 217
 218 ArgTypeList ::= ArgType | ArgTypeList ^ "," ArgType ;
 219
 220 ArgTypeListI ::= ArgTypeList | ArgTypeList ^ "," "..." | "..." | _ ;
 221
 222 TypeListI ::= Types | TypeListI ^ "," Types ;
 223
 224 ConstVal::= Types "[" ^ ConstVector ^ "]"
 225  | Types "[" ^ "]"
 226  | Types "c" ^ STRINGCONSTANT
 227  | Types "<" ^ ConstVector ^ ">"
 228  | Types "{" ConstVector "}"
 229  | Types "{" ^ "}"
 230  | Types "<" ^ "{" ConstVector "}" ^ ">"
 231  | Types "<" ^ "{" ^ "}" ^ ">"
 232  | Types null
 233  | Types undef
 234  | Types SymbolicValueRef
 235  | Types ConstExpr
 236  | Types zeroinitializer
 237  | Types ESINT64VAL
 238  | Types ESAPINTVAL
 239  | Types EUINT64VAL
 240  | Types EUAPINTVAL
 241  | Types true
 242  | Types false
 243  | Types FPVAL ;
 244
 245 ConstExpr::= CastOps "(" ^ ConstVal to Types ^ ")"
 246  | getelementptr OptInBounds "(" ^ ConstVal IndexList ^ ")"
 247  | select "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 248  | ArithmeticOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 249  | LogicalOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 250  | icmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 251  | fcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 252  | extractelement "(" ^ ConstVal ^ "," ConstVal ^ ")"
 253  | insertelement "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 254  | shufflevector "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 255  | extractvalue "(" ^ ConstVal ^ ConstantIndexList ^ ")"
 256  | insertvalue "(" ^ ConstVal ^ "," ConstVal ^ ConstantIndexList ^ ")" ;
 257
 258 ConstVector ::= ConstVector ^ "," ConstVal | ConstVal ;
 259
 260 GlobalType ::= global | constant ;
 261
 262 ThreadLocal ::= - "thread_local" | _ ;
 263
 264 AliaseeRef ::= ResultTypes SymbolicValueRef
 265  | bitcast "(" ^ AliaseeRef to Types ^ ")" ;
 266
 267 Module ::= +++ DefinitionList | --- _ ;
 268
 269 DefinitionList ::= - Definition | + DefinitionList Definition ;
 270
 271 Definition
 272   ::= ^ ( +++++ define Function
 273  | declare FunctionProto
 274  | - module asm AsmBlock
 275  | OptLocalAssign type Types
 276  | OptGlobalAssign GVVisibilityStyle ThreadLocal OptAddrSpace GlobalType
 277    ConstVal GlobalVarAttributes
 278  | OptGlobalAssign GVInternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 279    GlobalType ConstVal GlobalVarAttributes
 280  | OptGlobalAssign GVExternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 281    GlobalType Types GlobalVarAttributes
 282  | OptGlobalAssign GVVisibilityStyle alias AliasLinkage AliaseeRef
 283  | target TargetDefinition
 284  | deplibs "=" LibrariesDefinition
 285  ) ^ "\n";
 286
 287 AsmBlock ::= STRINGCONSTANT ;
 288
 289 TargetDefinition ::= triple "=" STRINGCONSTANT
 290  | datalayout "=" STRINGCONSTANT ;
 291
 292 LibrariesDefinition ::= "[" ( LibList | _ ) "]";
 293
 294 LibList ::= LibList ^ "," STRINGCONSTANT | STRINGCONSTANT ;
 295
 296 ArgListH ::= ArgListH ^ "," Types OptParamAttrs OptLocalName
 297  | Types OptParamAttrs OptLocalName ;
 298
 299 ArgList ::= ArgListH | ArgListH ^ "," "..." | "..." | _ ;
 300
 301 FunctionHeaderH ::= OptCallingConv OptRetAttrs ResultTypes
 302                   GlobalName ^ "(" ^ ArgList ^ ")"
 303                   OptFuncAttrs OptSection OptAlign OptGC ;
 304
 305 BEGIN ::= ( begin | "{" ) ^ "\n";
 306
 307 FunctionHeader ::=
 308   FunctionDefineLinkage GVVisibilityStyle FunctionHeaderH BEGIN ;
 309
 310 END ::= ^ ( end | "}" ) ^ "\n";
 311
 312 Function ::= BasicBlockList END ;
 313
 314 FunctionProto ::= FunctionDeclareLinkage GVVisibilityStyle FunctionHeaderH ;
 315
 316 OptSideEffect ::= _ | sideeffect ;
 317
 318 ConstValueRef ::= ESINT64VAL
 319  | EUINT64VAL
 320  | FPVAL
 321  | true
 322  | false
 323  | null
 324  | undef
 325  | zeroinitializer
 326  | "<" ConstVector ">"
 327  | "[" ConstVector "]"
 328  | "[" ^ "]"
 329  | "c" ^ STRINGCONSTANT
 330  | "{" ConstVector "}"
 331  | "{" ^ "}"
 332  | "<" ^ "{" ConstVector "}" ^ ">"
 333  | "<" ^ "{" ^ "}" ^ ">"
 334  | ConstExpr
 335  | asm OptSideEffect STRINGCONSTANT ^ "," STRINGCONSTANT ;
 336
 337 SymbolicValueRef ::= LOCALVALID
 338  | GLOBALVALID
 339  | LocalName
 340  | GlobalName ;
 341
 342 ValueRef ::= SymbolicValueRef | ConstValueRef;
 343
 344 ResolvedVal ::= Types ValueRef ;
 345
 346 ReturnedVal ::= ResolvedVal | ReturnedVal ^ "," ResolvedVal ;
 347
 348 BasicBlockList ::= BasicBlockList BasicBlock | FunctionHeader BasicBlock ;
 349
 350 BasicBlock ::= InstructionList OptLocalAssign BBTerminatorInst ;
 351
 352 InstructionList ::= +++ InstructionList Inst
 353  | - _
 354  | ^ LABELSTR ^ ":\n" ;
 355
 356 BBTerminatorInst ::= ^ "  " ^
 357  ( ret ReturnedVal
 358  | ret void
 359  | br label ValueRef
 360  | br INTTYPE ValueRef ^ "," label ValueRef ^ "," label ValueRef
 361  | switch IntType ValueRef ^ "," label ValueRef "[" JumpTable "]"
 362  | switch IntType ValueRef ^ "," label ValueRef "[" ^ "]"
 363  | invoke OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 364    OptFuncAttrs
 365    to label ValueRef unwind label ValueRef
 366  | unwind
 367  | unreachable ) ^ "\n";
 368
 369 JumpTable ::= JumpTable IntType ConstValueRef ^ "," label ValueRef
 370  | IntType ConstValueRef ^ "," label ValueRef ;
 371
 372 Inst ::= ^ "  " ^ OptLocalAssign InstVal ^ "\n";
 373
 374 PHIList ::= Types "[" ValueRef ^ "," ValueRef "]"
 375  | PHIList ^ "," "[" ValueRef ^ "," ValueRef "]" ;
 376
 377 ParamList ::= Types OptParamAttrs ValueRef OptParamAttrs
 378  | label OptParamAttrs ValueRef OptParamAttrs
 379  | ParamList ^ "," Types OptParamAttrs ValueRef OptParamAttrs
 380  | ParamList ^ "," label OptParamAttrs ValueRef OptParamAttrs
 381  | - _ ;
 382
 383 IndexList ::= _ | IndexList ^ "," ResolvedVal ;
 384
 385 ConstantIndexList ::= "," EUINT64VAL | ConstantIndexList ^ "," EUINT64VAL ;
 386
 387 OptTailCall ::= tail call | call ;
 388
 389 InstVal ::=
 390    ArithmeticOps Types ValueRef ^ "," ValueRef
 391  | LogicalOps Types ValueRef ^ "," ValueRef
 392  | icmp IPredicates Types ValueRef ^ "," ValueRef
 393  | fcmp FPredicates Types ValueRef ^ "," ValueRef
 394  | CastOps ResolvedVal to Types
 395  | select ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 396  | "va_arg" ResolvedVal ^ "," Types
 397  | extractelement ResolvedVal ^ "," ResolvedVal
 398  | insertelement ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 399  | shufflevector ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 400  | phi PHIList
 401  | OptTailCall OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 402    OptFuncAttrs
 403  | MemoryInst ;
 404
 405 OptVolatile ::= - volatile | _ ;
 406 OptExact ::= - exact | _ ;
 407 OptNSW ::= - nsw | _ ;
 408 OptNUW ::= - nuw | _ ;
 409 OptNW  ::= OptNUW OptNSW | OptNSW OptNUW ;
 410 OptInBounds  ::= - inbounds | _ ;
 411
 412 MemoryInst ::= malloc Types OptCAlign
 413  | malloc Types ^ "," INTTYPE ValueRef OptCAlign
 414  | alloca Types OptCAlign
 415  | alloca Types ^ "," INTTYPE ValueRef OptCAlign
 416  | free ResolvedVal
 417  | OptVolatile load Types ValueRef OptCAlign
 418  | OptVolatile store ResolvedVal ^ "," Types ValueRef OptCAlign
 419  | getresult Types ValueRef ^ "," EUINT64VAL
 420  | getelementptr OptInBounds Types ValueRef IndexList
 421  | extractvalue Types ValueRef ^ ConstantIndexList
 422  | insertvalue Types ValueRef ^ "," Types ValueRef ^ ConstantIndexList ;