utils/llvm.grm

   1 (*
   2
   3 polygen grammar for LLVM assembly language.
   4
   5 This file defines an LLVM assembly language grammar for polygen,
   6 which is a tool for generating random text based on a grammar.
   7 It is strictly syntax-based, and makes no attempt to generate
   8 IR that is semantically valid. Most of the IR produced doesn't
   9 pass the Verifier.
  10
  11 *)
  12
  13 I ::=   "title:    LLVM assembly language\n"
  14       ^ "status:   experimental\n"
  15       ^ "audience: LLVM developers\n"
  16 ;
  17
  18 S ::= Module ;
  19
  20 (*
  21 Define rules for non-keyword tokens. This is currently just a bunch
  22 of hacks. They don't cover many valid forms of tokens, and they also
  23 generate some invalid forms of tokens. The LLVM parser has custom
  24 C++ code to lex these; custom C++ code for emitting them would be
  25 convenient, but polygen doesn't support that.
  26 *)
  27 NonZeroDecimalDigit ::=     1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  28 DecimalDigit        ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  29 DecimalDigitSeq     ::= DecimalDigit [^ DecimalDigitSeq ];
  30 HexDigit            ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9
  31                       | a | b | c | d | e | f ;
  32 HexDigitSeq         ::= HexDigit [^ HexDigitSeq ];
  33 StringChar          ::= a | b | c | d | e | f | g | h | i | j | k | l | m
  34                       | n | o | p | q | r | s | t | u | v | w | x | y | z ;
  35 StringConstantSeq   ::= StringChar [^ StringConstantSeq ];
  36 StringConstant      ::= StringChar [^ StringConstantSeq ];
  37 EUINT64VAL          ::= NonZeroDecimalDigit [^ DecimalDigitSeq ];
  38 ESINT64VAL          ::= [ "-" ] ^ EUINT64VAL ;
  39 EUAPINTVAL          ::= EUINT64VAL ;
  40 ESAPINTVAL          ::= ESINT64VAL ;
  41 LOCALVALID          ::= "%" ^ DecimalDigitSeq ;
  42 GLOBALVALID         ::= "@" ^ DecimalDigitSeq ;
  43 INTTYPE             ::= "i" ^ EUINT64VAL ;
  44 GLOBALVAR           ::= "@" ^ StringConstant ;
  45 LOCALVAR            ::= "%" ^ StringConstant ;
  46 STRINGCONSTANT      ::= "\"" ^ StringConstant ^ "\"" ;
  47 ATSTRINGCONSTANT    ::= "@" ^ STRINGCONSTANT ;
  48 PCTSTRINGCONSTANT   ::= "%" ^ STRINGCONSTANT ;
  49 LABELSTR            ::= StringConstant ;
  50 FPVAL               ::= ESAPINTVAL ^ "." ^ EUAPINTVAL | "0x" ^ HexDigitSeq ;
  51
  52 (*
  53 The rest of this file is derived directly from llvmAsmParser.y.
  54 *)
  55
  56 ArithmeticOps ::= add | sub | mul | udiv | sdiv | fdiv | urem | srem | frem ;
  57 LogicalOps    ::= shl | lshr | ashr | and | or | xor;
  58 CastOps       ::= trunc | zext | sext | fptrunc | fpext | bitcast |
  59                   uitofp | sitofp | fptoui | fptosi | inttoptr | ptrtoint ;
  60
  61 IPredicates ::= eq | ne | slt | sgt | sle | sge | ult | ugt | ule | uge ;
  62
  63 FPredicates ::= oeq | one | olt | ogt | ole | oge | ord | uno | ueq | une
  64               | ult | ugt | ule | uge | true | false ;
  65
  66 IntType ::= INTTYPE;
  67 FPType  ::= float | double | "ppc_fp128" | fp128 | "x86_fp80";
  68
  69 LocalName ::= LOCALVAR | STRINGCONSTANT | PCTSTRINGCONSTANT ;
  70 OptLocalName ::= LocalName | _ ;
  71
  72 OptAddrSpace ::= - addrspace "(" ^ EUINT64VAL ^ ")" | _ ;
  73
  74 OptLocalAssign ::= LocalName "=" | _ ;
  75
  76 GlobalName ::= GLOBALVAR | ATSTRINGCONSTANT ;
  77
  78 OptGlobalAssign ::= GlobalAssign | _ ;
  79
  80 GlobalAssign ::= GlobalName "=" ;
  81
  82 GVInternalLinkage
  83   ::= + internal
  84  | weak
  85  | linkonce
  86  | appending
  87  | dllexport
  88  | common
  89  ;
  90
  91 GVExternalLinkage
  92   ::= dllimport
  93  | "extern_weak"
  94  | + external
  95  ;
  96
  97 GVVisibilityStyle
  98   ::= + _
  99  | default
 100  | hidden
 101  | protected
 102  ;
 103
 104 FunctionDeclareLinkage
 105   ::= + _
 106  | dllimport
 107  | "extern_weak"
 108  ;
 109
 110 FunctionDefineLinkage
 111   ::= + _
 112  | internal
 113  | linkonce
 114  | weak
 115  | dllexport
 116  ;
 117
 118 AliasLinkage ::= + _ | weak | internal ;
 119
 120 OptCallingConv ::= + _ |
 121                  ccc |
 122                  fastcc |
 123                  coldcc |
 124                  "x86_stdcallcc" |
 125                  "x86_fastcallcc" |
 126                  "x86_ssecallcc" |
 127                  cc EUINT64VAL ;
 128
 129 ParamAttr ::= zeroext
 130  | zext
 131  | signext
 132  | sext
 133  | inreg
 134  | sret
 135  | noalias
 136  | byval
 137  | nest
 138  | align EUINT64VAL
 139  ;
 140
 141 OptParamAttrs ::= + _ | OptParamAttrs ParamAttr ;
 142
 143 FuncAttr      ::= noreturn
 144  | nounwind
 145  | zeroext
 146  | signext
 147  | readnone
 148  | readonly
 149  ;
 150
 151 OptFuncAttrs  ::= + _ | OptFuncAttrs FuncAttr ;
 152
 153 FuncNoteList  ::= FuncNote
 154               | FuncNoteList ^ "," FuncNote
 155               ;
 156
 157 FuncNote      ::= inline ^ "=" ^ never
 158               | inline ^ "=" ^ always
 159               | "opt_size"
 160               ;
 161
 162 OptFuncNotes  ::= _
 163               | notes ^ "(" ^ FuncNoteList ^ ")"
 164               ;
 165
 166 OptGC         ::= + _ | gc STRINGCONSTANT ;
 167
 168 OptAlign      ::= + _ | align EUINT64VAL ;
 169 OptCAlign     ::= + _ | ^ "," align EUINT64VAL ;
 170
 171 SectionString ::= section STRINGCONSTANT ;
 172
 173 OptSection    ::= + _ | SectionString ;
 174
 175 GlobalVarAttributes ::= + _ | ^ "," GlobalVarAttribute GlobalVarAttributes ;
 176 GlobalVarAttribute  ::= SectionString | align EUINT64VAL ;
 177
 178 PrimType ::= INTTYPE | float | double | "ppc_fp128" | fp128 | "x86_fp80"
 179           | - label ;
 180
 181 Types
 182   ::= opaque
 183  | PrimType
 184  | Types OptAddrSpace ^ "*"
 185  | SymbolicValueRef
 186  | "\\" ^ EUINT64VAL
 187  | Types "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 188  | void "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 189  | "[" ^ EUINT64VAL "x" Types ^ "]"
 190  | "<" ^ EUINT64VAL "x" Types ^ ">"
 191  | "{" TypeListI "}"
 192  | "{" ^ "}"
 193  | "<" ^ "{" TypeListI "}" ^ ">"
 194  | "<" ^ "{" ^ "}" ^ ">"
 195  ;
 196
 197 ArgType ::= Types OptParamAttrs ;
 198
 199 ResultTypes ::= Types | void ;
 200
 201 ArgTypeList ::= ArgType | ArgTypeList ^ "," ArgType ;
 202
 203 ArgTypeListI ::= ArgTypeList | ArgTypeList ^ "," "..." | "..." | _ ;
 204
 205 TypeListI ::= Types | TypeListI ^ "," Types ;
 206
 207 ConstVal::= Types "[" ^ ConstVector ^ "]"
 208  | Types "[" ^ "]"
 209  | Types "c" ^ STRINGCONSTANT
 210  | Types "<" ^ ConstVector ^ ">"
 211  | Types "{" ConstVector "}"
 212  | Types "{" ^ "}"
 213  | Types "<" ^ "{" ConstVector "}" ^ ">"
 214  | Types "<" ^ "{" ^ "}" ^ ">"
 215  | Types null
 216  | Types undef
 217  | Types SymbolicValueRef
 218  | Types ConstExpr
 219  | Types zeroinitializer
 220  | IntType ESINT64VAL
 221  | IntType ESAPINTVAL
 222  | IntType EUINT64VAL
 223  | IntType EUAPINTVAL
 224  | INTTYPE true
 225  | INTTYPE false
 226  | FPType FPVAL ;
 227
 228 ConstExpr::= CastOps "(" ^ ConstVal to Types ^ ")"
 229  | getelementptr "(" ^ ConstVal IndexList ^ ")"
 230  | select "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 231  | ArithmeticOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 232  | LogicalOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 233  | icmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 234  | fcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 235  | vicmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 236  | vfcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 237  | extractelement "(" ^ ConstVal ^ "," ConstVal ^ ")"
 238  | insertelement "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 239  | shufflevector "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 240  | extractvalue "(" ^ ConstVal ^ ConstantIndexList ^ ")"
 241  | insertvalue "(" ^ ConstVal ^ "," ConstVal ^ ConstantIndexList ^ ")" ;
 242
 243 ConstVector ::= ConstVector ^ "," ConstVal | ConstVal ;
 244
 245 GlobalType ::= global | constant ;
 246
 247 ThreadLocal ::= - "thread_local" | _ ;
 248
 249 AliaseeRef ::= ResultTypes SymbolicValueRef
 250  | bitcast "(" ^ AliaseeRef to Types ^ ")" ;
 251
 252 Module ::= +++ DefinitionList | --- _ ;
 253
 254 DefinitionList ::= - Definition | + DefinitionList Definition ;
 255
 256 Definition
 257   ::= ^ ( +++++ define Function
 258  | declare FunctionProto
 259  | - module asm AsmBlock
 260  | OptLocalAssign type Types
 261  | OptLocalAssign type void
 262  | OptGlobalAssign GVVisibilityStyle ThreadLocal GlobalType ConstVal
 263    OptAddrSpace GlobalVarAttributes
 264  | OptGlobalAssign GVInternalLinkage GVVisibilityStyle ThreadLocal GlobalType
 265    ConstVal OptAddrSpace GlobalVarAttributes
 266  | OptGlobalAssign GVExternalLinkage GVVisibilityStyle ThreadLocal GlobalType
 267    Types OptAddrSpace GlobalVarAttributes
 268  | OptGlobalAssign GVVisibilityStyle alias AliasLinkage AliaseeRef
 269  | target TargetDefinition
 270  | deplibs "=" LibrariesDefinition
 271  ) ^ "\n";
 272
 273 AsmBlock ::= STRINGCONSTANT ;
 274
 275 TargetDefinition ::= triple "=" STRINGCONSTANT
 276  | datalayout "=" STRINGCONSTANT ;
 277
 278 LibrariesDefinition ::= "[" LibList "]";
 279
 280 LibList ::= LibList ^ "," STRINGCONSTANT | STRINGCONSTANT | _ ;
 281
 282 ArgListH ::= ArgListH ^ "," Types OptParamAttrs OptLocalName
 283  | Types OptParamAttrs OptLocalName ;
 284
 285 ArgList ::= ArgListH | ArgListH ^ "," "..." | "..." | _ ;
 286
 287 FunctionHeaderH ::= OptCallingConv ResultTypes GlobalName "(" ^ ArgList ^ ")"
 288                   OptFuncAttrs OptSection OptAlign OptGC OptFuncNotes ;
 289
 290 BEGIN ::= ( begin | "{" ) ^ "\n";
 291
 292 FunctionHeader ::=
 293   FunctionDefineLinkage GVVisibilityStyle FunctionHeaderH BEGIN ;
 294
 295 END ::= ^ ( end | "}" ) ^ "\n";
 296
 297 Function ::= BasicBlockList END ;
 298
 299 FunctionProto ::= FunctionDeclareLinkage GVVisibilityStyle FunctionHeaderH ;
 300
 301 OptSideEffect ::= _ | sideeffect ;
 302
 303 ConstValueRef ::= ESINT64VAL
 304  | EUINT64VAL
 305  | FPVAL
 306  | true
 307  | false
 308  | null
 309  | undef
 310  | zeroinitializer
 311  | "<" ConstVector ">"
 312  | "[" ConstVector "]"
 313  | "[" ^ "]"
 314  | "c" ^ STRINGCONSTANT
 315  | "{" ConstVector "}"
 316  | "{" ^ "}"
 317  | "<" ^ "{" ConstVector "}" ^ ">"
 318  | "<" ^ "{" ^ "}" ^ ">"
 319  | ConstExpr
 320  | asm OptSideEffect STRINGCONSTANT ^ "," STRINGCONSTANT ;
 321
 322 SymbolicValueRef ::= LOCALVALID
 323  | GLOBALVALID
 324  | LocalName
 325  | GlobalName ;
 326
 327 ValueRef ::= SymbolicValueRef | ConstValueRef;
 328
 329 ResolvedVal ::= Types ValueRef ;
 330
 331 ReturnedVal ::= ResolvedVal | ReturnedVal ^ "," ResolvedVal ;
 332
 333 BasicBlockList ::= BasicBlockList BasicBlock | FunctionHeader BasicBlock ;
 334
 335 BasicBlock ::= InstructionList OptLocalAssign BBTerminatorInst ;
 336
 337 InstructionList ::= +++ InstructionList Inst
 338  | - _
 339  | ^ LABELSTR ^ ":\n" ;
 340
 341 BBTerminatorInst ::= ^ "  " ^
 342  ( ret ReturnedVal
 343  | ret void
 344  | br label ValueRef
 345  | br INTTYPE ValueRef ^ "," label ValueRef ^ "," label ValueRef
 346  | switch IntType ValueRef ^ "," label ValueRef "[" JumpTable "]"
 347  | switch IntType ValueRef ^ "," label ValueRef "[" ^ "]"
 348  | invoke OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 349    OptFuncAttrs
 350    to label ValueRef unwind label ValueRef
 351  | unwind
 352  | unreachable ) ^ "\n";
 353
 354 JumpTable ::= JumpTable IntType ConstValueRef ^ "," label ValueRef
 355  | IntType ConstValueRef ^ "," label ValueRef ;
 356
 357 Inst ::= ^ "  " ^ OptLocalAssign InstVal ^ "\n";
 358
 359 PHIList ::= Types "[" ValueRef ^ "," ValueRef "]"
 360  | PHIList ^ "," "[" ValueRef ^ "," ValueRef "]" ;
 361
 362 ParamList ::= Types OptParamAttrs ValueRef OptParamAttrs
 363  | label OptParamAttrs ValueRef OptParamAttrs
 364  | ParamList ^ "," Types OptParamAttrs ValueRef OptParamAttrs
 365  | ParamList ^ "," label OptParamAttrs ValueRef OptParamAttrs
 366  | - _ ;
 367
 368 IndexList ::= _ | IndexList ^ "," ResolvedVal ;
 369
 370 ConstantIndexList ::= "," EUINT64VAL | ConstantIndexList ^ "," EUINT64VAL ;
 371
 372 OptTailCall ::= tail call | call ;
 373
 374 InstVal ::=
 375    ArithmeticOps Types ValueRef ^ "," ValueRef
 376  | LogicalOps Types ValueRef ^ "," ValueRef
 377  | icmp IPredicates Types ValueRef ^ "," ValueRef
 378  | fcmp FPredicates Types ValueRef ^ "," ValueRef
 379  | vicmp IPredicates Types ValueRef ^ "," ValueRef
 380  | vfcmp FPredicates Types ValueRef ^ "," ValueRef
 381  | CastOps ResolvedVal to Types
 382  | select ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 383  | "va_arg" ResolvedVal ^ "," Types
 384  | extractelement ResolvedVal ^ "," ResolvedVal
 385  | insertelement ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 386  | shufflevector ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 387  | phi PHIList
 388  | OptTailCall OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 389    OptFuncAttrs
 390  | MemoryInst ;
 391
 392 OptVolatile ::= - volatile | _ ;
 393
 394 MemoryInst ::= malloc Types OptCAlign
 395  | malloc Types ^ "," INTTYPE ValueRef OptCAlign
 396  | alloca Types OptCAlign
 397  | alloca Types ^ "," INTTYPE ValueRef OptCAlign
 398  | free ResolvedVal
 399  | OptVolatile load Types ValueRef OptCAlign
 400  | OptVolatile store ResolvedVal ^ "," Types ValueRef OptCAlign
 401  | getresult Types ValueRef ^ "," EUINT64VAL
 402  | getelementptr Types ValueRef IndexList
 403  | extractvalue Types ValueRef ^ ConstantIndexList
 404  | insertvalue Types ValueRef ^ "," Types ValueRef ^ ConstantIndexList ;