utils/llvm.grm

   1 (*
   2
   3 polygen grammar for LLVM assembly language.
   4
   5 This file defines an LLVM assembly language grammar for polygen,
   6 which is a tool for generating random text based on a grammar.
   7 It is strictly syntax-based, and makes no attempt to generate
   8 IR that is semantically valid. Most of the IR produced doesn't
   9 pass the Verifier.
  10
  11 *)
  12
  13 I ::=   "title:    LLVM assembly language\n"
  14       ^ "status:   experimental\n"
  15       ^ "audience: LLVM developers\n"
  16 ;
  17
  18 S ::= Module ;
  19
  20 (*
  21 Define rules for non-keyword tokens. This is currently just a bunch
  22 of hacks. They don't cover many valid forms of tokens, and they also
  23 generate some invalid forms of tokens. The LLVM parser has custom
  24 C++ code to lex these; custom C++ code for emitting them would be
  25 convenient, but polygen doesn't support that.
  26 *)
  27 NonZeroDecimalDigit ::=     1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  28 DecimalDigit        ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  29 DecimalDigitSeq     ::= DecimalDigit [^ DecimalDigitSeq ];
  30 HexDigit            ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9
  31                       | a | b | c | d | e | f ;
  32 HexDigitSeq         ::= HexDigit [^ HexDigitSeq ];
  33 StringChar          ::= a | b | c | d | e | f | g | h | i | j | k | l | m
  34                       | n | o | p | q | r | s | t | u | v | w | x | y | z ;
  35 StringConstantSeq   ::= StringChar [^ StringConstantSeq ];
  36 StringConstant      ::= StringChar [^ StringConstantSeq ];
  37 EUINT64VAL          ::= NonZeroDecimalDigit [^ DecimalDigitSeq ];
  38 ESINT64VAL          ::= [ "-" ] ^ EUINT64VAL ;
  39 EUAPINTVAL          ::= EUINT64VAL ;
  40 ESAPINTVAL          ::= ESINT64VAL ;
  41 LOCALVALID          ::= "%" ^ DecimalDigitSeq ;
  42 GLOBALVALID         ::= "@" ^ DecimalDigitSeq ;
  43 INTTYPE             ::= "i" ^ EUINT64VAL ;
  44 GLOBALVAR           ::= "@" ^ StringConstant ;
  45 LOCALVAR            ::= "%" ^ StringConstant ;
  46 STRINGCONSTANT      ::= "\"" ^ StringConstant ^ "\"" ;
  47 ATSTRINGCONSTANT    ::= "@" ^ STRINGCONSTANT ;
  48 PCTSTRINGCONSTANT   ::= "%" ^ STRINGCONSTANT ;
  49 LABELSTR            ::= StringConstant ;
  50 FPVAL               ::= ESAPINTVAL ^ "." ^ EUAPINTVAL | "0x" ^ HexDigitSeq ;
  51
  52 (*
  53 The rest of this file is derived directly from llvmAsmParser.y.
  54 *)
  55
  56 ArithmeticOps ::= + OptNW add | fadd | OptNW sub | fsub | OptNW mul | fmul |
  57                   udiv | OptExact sdiv | fdiv | urem | srem | frem ;
  58 LogicalOps    ::= shl | lshr | ashr | and | or | xor;
  59 CastOps       ::= trunc | zext | sext | fptrunc | fpext | bitcast |
  60                   uitofp | sitofp | fptoui | fptosi | inttoptr | ptrtoint ;
  61
  62 IPredicates ::= eq | ne | slt | sgt | sle | sge | ult | ugt | ule | uge ;
  63
  64 FPredicates ::= oeq | one | olt | ogt | ole | oge | ord | uno | ueq | une
  65               | ult | ugt | ule | uge | true | false ;
  66
  67 IntType ::= INTTYPE;
  68 FPType  ::= float | double | "ppc_fp128" | fp128 | "x86_fp80";
  69
  70 LocalName ::= LOCALVAR | STRINGCONSTANT | PCTSTRINGCONSTANT ;
  71 OptLocalName ::= LocalName | _ ;
  72
  73 OptAddrSpace ::= - addrspace ^ "(" ^ EUINT64VAL ^ ")" | _ ;
  74
  75 OptLocalAssign ::= LocalName "=" | _ ;
  76
  77 GlobalName ::= GLOBALVAR | ATSTRINGCONSTANT ;
  78
  79 OptGlobalAssign ::= GlobalAssign | _ ;
  80
  81 GlobalAssign ::= GlobalName "=" ;
  82
  83 GVInternalLinkage
  84   ::= + internal
  85  | weak
  86  | "weak_odr"
  87  | linkonce
  88  | "linkonce_odr"
  89  | appending
  90  | dllexport
  91  | common
  92  | private
  93  ;
  94
  95 GVExternalLinkage
  96   ::= dllimport
  97  | "extern_weak"
  98  | + external
  99  ;
 100
 101 GVVisibilityStyle
 102   ::= + _
 103  | default
 104  | hidden
 105  | protected
 106  ;
 107
 108 FunctionDeclareLinkage
 109   ::= + _
 110  | dllimport
 111  | "extern_weak"
 112  ;
 113
 114 FunctionDefineLinkage
 115   ::= + _
 116  | internal
 117  | linkonce
 118  | "linkonce_odr"
 119  | weak
 120  | "weak_odr"
 121  | dllexport
 122  ;
 123
 124 AliasLinkage ::= + _ | weak | "weak_odr" | internal ;
 125
 126 OptCallingConv ::= + _ |
 127                  ccc |
 128                  fastcc |
 129                  coldcc |
 130                  "x86_stdcallcc" |
 131                  "x86_fastcallcc" |
 132                  cc EUINT64VAL ;
 133
 134 ParamAttr ::= zeroext
 135  | signext
 136  | inreg
 137  | sret
 138  | noalias
 139  | nocapture
 140  | byval
 141  | nest
 142  | align EUINT64VAL
 143  ;
 144
 145 OptParamAttrs ::= + _ | OptParamAttrs ParamAttr ;
 146
 147 RetAttr       ::= inreg
 148               | zeroext
 149               | signext
 150               | noalias
 151               ;
 152
 153 OptRetAttrs  ::= _
 154              | OptRetAttrs RetAttr
 155              ;
 156
 157 FuncAttr      ::= noreturn
 158  | nounwind
 159  | inreg
 160  | zeroext
 161  | signext
 162  | readnone
 163  | readonly
 164  | inlinehint
 165  | alignstack
 166  | noinline
 167  | alwaysinline
 168  | optsize
 169  | ssp
 170  | sspreq
 171  ;
 172
 173 OptFuncAttrs  ::= + _ | OptFuncAttrs FuncAttr ;
 174
 175 OptGC         ::= + _ | gc STRINGCONSTANT ;
 176
 177 OptAlign      ::= + _ | align EUINT64VAL ;
 178 OptCAlign     ::= + _ | ^ "," align EUINT64VAL ;
 179
 180 SectionString ::= section STRINGCONSTANT ;
 181
 182 OptSection    ::= + _ | SectionString ;
 183
 184 GlobalVarAttributes ::= + _ | ^ "," GlobalVarAttribute GlobalVarAttributes ;
 185 GlobalVarAttribute  ::= SectionString | align EUINT64VAL ;
 186
 187 PrimType ::= INTTYPE | float | double | "ppc_fp128" | fp128 | "x86_fp80"
 188           | - label ;
 189
 190 Types
 191   ::= opaque
 192  | PrimType
 193  | Types OptAddrSpace ^ "*"
 194  | SymbolicValueRef
 195  | "\\" ^ EUINT64VAL
 196  | Types "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 197  | void "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 198  | "[" ^ EUINT64VAL "x" Types ^ "]"
 199  | "<" ^ EUINT64VAL "x" Types ^ ">"
 200  | "{" TypeListI "}"
 201  | "{" ^ "}"
 202  | "<" ^ "{" TypeListI "}" ^ ">"
 203  | "<" ^ "{" ^ "}" ^ ">"
 204  ;
 205
 206 ArgType ::= Types OptParamAttrs ;
 207
 208 ResultTypes ::= Types | void ;
 209
 210 ArgTypeList ::= ArgType | ArgTypeList ^ "," ArgType ;
 211
 212 ArgTypeListI ::= ArgTypeList | ArgTypeList ^ "," "..." | "..." | _ ;
 213
 214 TypeListI ::= Types | TypeListI ^ "," Types ;
 215
 216 ConstVal::= Types "[" ^ ConstVector ^ "]"
 217  | Types "[" ^ "]"
 218  | Types "c" ^ STRINGCONSTANT
 219  | Types "<" ^ ConstVector ^ ">"
 220  | Types "{" ConstVector "}"
 221  | Types "{" ^ "}"
 222  | Types "<" ^ "{" ConstVector "}" ^ ">"
 223  | Types "<" ^ "{" ^ "}" ^ ">"
 224  | Types null
 225  | Types undef
 226  | Types SymbolicValueRef
 227  | Types ConstExpr
 228  | Types zeroinitializer
 229  | Types ESINT64VAL
 230  | Types ESAPINTVAL
 231  | Types EUINT64VAL
 232  | Types EUAPINTVAL
 233  | Types true
 234  | Types false
 235  | Types FPVAL ;
 236
 237 ConstExpr::= CastOps "(" ^ ConstVal to Types ^ ")"
 238  | getelementptr OptInBounds "(" ^ ConstVal IndexList ^ ")"
 239  | select "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 240  | ArithmeticOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 241  | LogicalOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 242  | icmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 243  | fcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 244  | extractelement "(" ^ ConstVal ^ "," ConstVal ^ ")"
 245  | insertelement "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 246  | shufflevector "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 247  | extractvalue "(" ^ ConstVal ^ ConstantIndexList ^ ")"
 248  | insertvalue "(" ^ ConstVal ^ "," ConstVal ^ ConstantIndexList ^ ")" ;
 249
 250 ConstVector ::= ConstVector ^ "," ConstVal | ConstVal ;
 251
 252 GlobalType ::= global | constant ;
 253
 254 ThreadLocal ::= - "thread_local" | _ ;
 255
 256 AliaseeRef ::= ResultTypes SymbolicValueRef
 257  | bitcast "(" ^ AliaseeRef to Types ^ ")" ;
 258
 259 Module ::= +++ DefinitionList | --- _ ;
 260
 261 DefinitionList ::= - Definition | + DefinitionList Definition ;
 262
 263 Definition
 264   ::= ^ ( +++++ define Function
 265  | declare FunctionProto
 266  | - module asm AsmBlock
 267  | OptLocalAssign type Types
 268  | OptGlobalAssign GVVisibilityStyle ThreadLocal OptAddrSpace GlobalType
 269    ConstVal GlobalVarAttributes
 270  | OptGlobalAssign GVInternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 271    GlobalType ConstVal GlobalVarAttributes
 272  | OptGlobalAssign GVExternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 273    GlobalType Types GlobalVarAttributes
 274  | OptGlobalAssign GVVisibilityStyle alias AliasLinkage AliaseeRef
 275  | target TargetDefinition
 276  | deplibs "=" LibrariesDefinition
 277  ) ^ "\n";
 278
 279 AsmBlock ::= STRINGCONSTANT ;
 280
 281 TargetDefinition ::= triple "=" STRINGCONSTANT
 282  | datalayout "=" STRINGCONSTANT ;
 283
 284 LibrariesDefinition ::= "[" ( LibList | _ ) "]";
 285
 286 LibList ::= LibList ^ "," STRINGCONSTANT | STRINGCONSTANT ;
 287
 288 ArgListH ::= ArgListH ^ "," Types OptParamAttrs OptLocalName
 289  | Types OptParamAttrs OptLocalName ;
 290
 291 ArgList ::= ArgListH | ArgListH ^ "," "..." | "..." | _ ;
 292
 293 FunctionHeaderH ::= OptCallingConv OptRetAttrs ResultTypes
 294                   GlobalName ^ "(" ^ ArgList ^ ")"
 295                   OptFuncAttrs OptSection OptAlign OptGC ;
 296
 297 BEGIN ::= ( begin | "{" ) ^ "\n";
 298
 299 FunctionHeader ::=
 300   FunctionDefineLinkage GVVisibilityStyle FunctionHeaderH BEGIN ;
 301
 302 END ::= ^ ( end | "}" ) ^ "\n";
 303
 304 Function ::= BasicBlockList END ;
 305
 306 FunctionProto ::= FunctionDeclareLinkage GVVisibilityStyle FunctionHeaderH ;
 307
 308 OptSideEffect ::= _ | sideeffect ;
 309
 310 ConstValueRef ::= ESINT64VAL
 311  | EUINT64VAL
 312  | FPVAL
 313  | true
 314  | false
 315  | null
 316  | undef
 317  | zeroinitializer
 318  | "<" ConstVector ">"
 319  | "[" ConstVector "]"
 320  | "[" ^ "]"
 321  | "c" ^ STRINGCONSTANT
 322  | "{" ConstVector "}"
 323  | "{" ^ "}"
 324  | "<" ^ "{" ConstVector "}" ^ ">"
 325  | "<" ^ "{" ^ "}" ^ ">"
 326  | ConstExpr
 327  | asm OptSideEffect STRINGCONSTANT ^ "," STRINGCONSTANT ;
 328
 329 SymbolicValueRef ::= LOCALVALID
 330  | GLOBALVALID
 331  | LocalName
 332  | GlobalName ;
 333
 334 ValueRef ::= SymbolicValueRef | ConstValueRef;
 335
 336 ResolvedVal ::= Types ValueRef ;
 337
 338 ReturnedVal ::= ResolvedVal | ReturnedVal ^ "," ResolvedVal ;
 339
 340 BasicBlockList ::= BasicBlockList BasicBlock | FunctionHeader BasicBlock ;
 341
 342 BasicBlock ::= InstructionList OptLocalAssign BBTerminatorInst ;
 343
 344 InstructionList ::= +++ InstructionList Inst
 345  | - _
 346  | ^ LABELSTR ^ ":\n" ;
 347
 348 BBTerminatorInst ::= ^ "  " ^
 349  ( ret ReturnedVal
 350  | ret void
 351  | br label ValueRef
 352  | br INTTYPE ValueRef ^ "," label ValueRef ^ "," label ValueRef
 353  | switch IntType ValueRef ^ "," label ValueRef "[" JumpTable "]"
 354  | switch IntType ValueRef ^ "," label ValueRef "[" ^ "]"
 355  | invoke OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 356    OptFuncAttrs
 357    to label ValueRef unwind label ValueRef
 358  | unwind
 359  | unreachable ) ^ "\n";
 360
 361 JumpTable ::= JumpTable IntType ConstValueRef ^ "," label ValueRef
 362  | IntType ConstValueRef ^ "," label ValueRef ;
 363
 364 Inst ::= ^ "  " ^ OptLocalAssign InstVal ^ "\n";
 365
 366 PHIList ::= Types "[" ValueRef ^ "," ValueRef "]"
 367  | PHIList ^ "," "[" ValueRef ^ "," ValueRef "]" ;
 368
 369 ParamList ::= Types OptParamAttrs ValueRef OptParamAttrs
 370  | label OptParamAttrs ValueRef OptParamAttrs
 371  | ParamList ^ "," Types OptParamAttrs ValueRef OptParamAttrs
 372  | ParamList ^ "," label OptParamAttrs ValueRef OptParamAttrs
 373  | - _ ;
 374
 375 IndexList ::= _ | IndexList ^ "," ResolvedVal ;
 376
 377 ConstantIndexList ::= "," EUINT64VAL | ConstantIndexList ^ "," EUINT64VAL ;
 378
 379 OptTailCall ::= tail call | call ;
 380
 381 InstVal ::=
 382    ArithmeticOps Types ValueRef ^ "," ValueRef
 383  | LogicalOps Types ValueRef ^ "," ValueRef
 384  | icmp IPredicates Types ValueRef ^ "," ValueRef
 385  | fcmp FPredicates Types ValueRef ^ "," ValueRef
 386  | CastOps ResolvedVal to Types
 387  | select ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 388  | "va_arg" ResolvedVal ^ "," Types
 389  | extractelement ResolvedVal ^ "," ResolvedVal
 390  | insertelement ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 391  | shufflevector ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 392  | phi PHIList
 393  | OptTailCall OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 394    OptFuncAttrs
 395  | MemoryInst ;
 396
 397 OptVolatile ::= - volatile | _ ;
 398 OptExact ::= - exact | _ ;
 399 OptNSW ::= - nsw | _ ;
 400 OptNUW ::= - nuw | _ ;
 401 OptNW  ::= OptNUW OptNSW | OptNSW OptNUW ;
 402 OptInBounds  ::= - inbounds | _ ;
 403
 404 MemoryInst ::= malloc Types OptCAlign
 405  | malloc Types ^ "," INTTYPE ValueRef OptCAlign
 406  | alloca Types OptCAlign
 407  | alloca Types ^ "," INTTYPE ValueRef OptCAlign
 408  | free ResolvedVal
 409  | OptVolatile load Types ValueRef OptCAlign
 410  | OptVolatile store ResolvedVal ^ "," Types ValueRef OptCAlign
 411  | getresult Types ValueRef ^ "," EUINT64VAL
 412  | getelementptr OptInBounds Types ValueRef IndexList
 413  | extractvalue Types ValueRef ^ ConstantIndexList
 414  | insertvalue Types ValueRef ^ "," Types ValueRef ^ ConstantIndexList ;