tools/lto/CMakeLists.txt

   1 set(LLVM_LINK_COMPONENTS
   2   ${LLVM_TARGETS_TO_BUILD}
   3   ipo scalaropts linker bitreader bitwriter lto mcdisassembler vectorize)
   4
   5 add_definitions( -DLLVM_VERSION_INFO=\"${PACKAGE_VERSION}\" )
   6
   7 set(SOURCES
   8   LTODisassembler.cpp
   9   lto.cpp
  10   )
  11
  12 if( NOT CYGWIN AND LLVM_ENABLE_PIC )
  13   if ( WIN32 )
  14     # Create .def file containing a list of exports preceeded by
  15     # 'EXPORTS'.  The file "lto.exports" already contains the list, so we
  16     # massage it into the correct format here to create "lto.exports.def".
  17     set(LTO_EXPORTS_DEF ${CMAKE_CURRENT_BINARY_DIR}/lto.exports.def)
  18     file(READ "lto.exports" exports_list)
  19     file(WRITE ${LTO_EXPORTS_DEF} "LIBRARY LTO\n")
  20     file(APPEND ${LTO_EXPORTS_DEF} "EXPORTS\n")
  21     file(APPEND ${LTO_EXPORTS_DEF} ${exports_list})
  22     set(SOURCES ${SOURCES} ${LTO_EXPORTS_DEF})
  23   endif()
  24
  25   set(bsl ${BUILD_SHARED_LIBS})
  26   set(BUILD_SHARED_LIBS ON)
  27   add_llvm_library(LTO ${SOURCES})
  28   set_property(TARGET LTO PROPERTY OUTPUT_NAME "LTO")
  29   set(BUILD_SHARED_LIBS ${bsl})
  30   set(LTO_STATIC_TARGET_NAME LTO_static)
  31 else()
  32   set(LTO_STATIC_TARGET_NAME LTO)
  33 endif()
  34
  35 if( NOT BUILD_SHARED_LIBS )
  36   add_llvm_library(${LTO_STATIC_TARGET_NAME} ${SOURCES})
  37   set_property(TARGET ${LTO_STATIC_TARGET_NAME} PROPERTY OUTPUT_NAME "LTO")
  38 endif()
  39
  40 if( NOT CYGWIN )
  41   install(FILES ${LLVM_MAIN_INCLUDE_DIR}/llvm-c/lto.h
  42           DESTINATION include/llvm-c)
  43 endif()