test/Transforms/SROA/basictest.ll

   1 ; RUN: opt < %s -sroa -S | FileCheck %s
   2 ; RUN: opt < %s -sroa -force-ssa-updater -S | FileCheck %s
   3
   4 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:32:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-n8:16:32:64"
   5
   6 declare void @llvm.lifetime.start(i64, i8* nocapture)
   7 declare void @llvm.lifetime.end(i64, i8* nocapture)
   8
   9 define i32 @test0() {
  10 ; CHECK: @test0
  11 ; CHECK-NOT: alloca
  12 ; CHECK: ret i32
  13
  14 entry:
  15   %a1 = alloca i32
  16   %a2 = alloca float
  17
  18   %a1.i8 = bitcast i32* %a1 to i8*
  19   call void @llvm.lifetime.start(i64 4, i8* %a1.i8)
  20
  21   store i32 0, i32* %a1
  22   %v1 = load i32* %a1
  23
  24   call void @llvm.lifetime.end(i64 4, i8* %a1.i8)
  25
  26   %a2.i8 = bitcast float* %a2 to i8*
  27   call void @llvm.lifetime.start(i64 4, i8* %a2.i8)
  28
  29   store float 0.0, float* %a2
  30   %v2 = load float * %a2
  31   %v2.int = bitcast float %v2 to i32
  32   %sum1 = add i32 %v1, %v2.int
  33
  34   call void @llvm.lifetime.end(i64 4, i8* %a2.i8)
  35
  36   ret i32 %sum1
  37 }
  38
  39 define i32 @test1() {
  40 ; CHECK: @test1
  41 ; CHECK-NOT: alloca
  42 ; CHECK: ret i32 0
  43
  44 entry:
  45   %X = alloca { i32, float }
  46   %Y = getelementptr { i32, float }* %X, i64 0, i32 0
  47   store i32 0, i32* %Y
  48   %Z = load i32* %Y
  49   ret i32 %Z
  50 }
  51
  52 define i64 @test2(i64 %X) {
  53 ; CHECK: @test2
  54 ; CHECK-NOT: alloca
  55 ; CHECK: ret i64 %X
  56
  57 entry:
  58   %A = alloca [8 x i8]
  59   %B = bitcast [8 x i8]* %A to i64*
  60   store i64 %X, i64* %B
  61   br label %L2
  62
  63 L2:
  64   %Z = load i64* %B
  65   ret i64 %Z
  66 }
  67
  68 define void @test3(i8* %dst, i8* %src) {
  69 ; CHECK: @test3
  70
  71 entry:
  72   %a = alloca [300 x i8]
  73 ; CHECK-NOT:  alloca
  74 ; CHECK:      %[[test3_a1:.*]] = alloca [42 x i8]
  75 ; CHECK-NEXT: %[[test3_a2:.*]] = alloca [99 x i8]
  76 ; CHECK-NEXT: %[[test3_a3:.*]] = alloca [16 x i8]
  77 ; CHECK-NEXT: %[[test3_a4:.*]] = alloca [42 x i8]
  78 ; CHECK-NEXT: %[[test3_a5:.*]] = alloca [7 x i8]
  79 ; CHECK-NEXT: %[[test3_a6:.*]] = alloca [7 x i8]
  80 ; CHECK-NEXT: %[[test3_a7:.*]] = alloca [85 x i8]
  81
  82   %b = getelementptr [300 x i8]* %a, i64 0, i64 0
  83   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %b, i8* %src, i32 300, i32 1, i1 false)
  84 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [42 x i8]* %[[test3_a1]], i64 0, i64 0
  85 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %src, i32 42
  86 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %src, i64 42
  87 ; CHECK-NEXT: %[[test3_r1:.*]] = load i8* %[[gep]]
  88 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 43
  89 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [99 x i8]* %[[test3_a2]], i64 0, i64 0
  90 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 99
  91 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 142
  92 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 0
  93 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 16
  94 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 158
  95 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [42 x i8]* %[[test3_a4]], i64 0, i64 0
  96 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 42
  97 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 200
  98 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a5]], i64 0, i64 0
  99 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 100 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %src, i64 207
 101 ; CHECK-NEXT: %[[test3_r2:.*]] = load i8* %[[gep]]
 102 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 208
 103 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 0
 104 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 105 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 215
 106 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [85 x i8]* %[[test3_a7]], i64 0, i64 0
 107 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 85
 108
 109   ; Clobber a single element of the array, this should be promotable.
 110   %c = getelementptr [300 x i8]* %a, i64 0, i64 42
 111   store i8 0, i8* %c
 112
 113   ; Make a sequence of overlapping stores to the array. These overlap both in
 114   ; forward strides and in shrinking accesses.
 115   %overlap.1.i8 = getelementptr [300 x i8]* %a, i64 0, i64 142
 116   %overlap.2.i8 = getelementptr [300 x i8]* %a, i64 0, i64 143
 117   %overlap.3.i8 = getelementptr [300 x i8]* %a, i64 0, i64 144
 118   %overlap.4.i8 = getelementptr [300 x i8]* %a, i64 0, i64 145
 119   %overlap.5.i8 = getelementptr [300 x i8]* %a, i64 0, i64 146
 120   %overlap.6.i8 = getelementptr [300 x i8]* %a, i64 0, i64 147
 121   %overlap.7.i8 = getelementptr [300 x i8]* %a, i64 0, i64 148
 122   %overlap.8.i8 = getelementptr [300 x i8]* %a, i64 0, i64 149
 123   %overlap.9.i8 = getelementptr [300 x i8]* %a, i64 0, i64 150
 124   %overlap.1.i16 = bitcast i8* %overlap.1.i8 to i16*
 125   %overlap.1.i32 = bitcast i8* %overlap.1.i8 to i32*
 126   %overlap.1.i64 = bitcast i8* %overlap.1.i8 to i64*
 127   %overlap.2.i64 = bitcast i8* %overlap.2.i8 to i64*
 128   %overlap.3.i64 = bitcast i8* %overlap.3.i8 to i64*
 129   %overlap.4.i64 = bitcast i8* %overlap.4.i8 to i64*
 130   %overlap.5.i64 = bitcast i8* %overlap.5.i8 to i64*
 131   %overlap.6.i64 = bitcast i8* %overlap.6.i8 to i64*
 132   %overlap.7.i64 = bitcast i8* %overlap.7.i8 to i64*
 133   %overlap.8.i64 = bitcast i8* %overlap.8.i8 to i64*
 134   %overlap.9.i64 = bitcast i8* %overlap.9.i8 to i64*
 135   store i8 1, i8* %overlap.1.i8
 136 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 0
 137 ; CHECK-NEXT: store i8 1, i8* %[[gep]]
 138   store i16 1, i16* %overlap.1.i16
 139 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast [16 x i8]* %[[test3_a3]] to i16*
 140 ; CHECK-NEXT: store i16 1, i16* %[[bitcast]]
 141   store i32 1, i32* %overlap.1.i32
 142 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast [16 x i8]* %[[test3_a3]] to i32*
 143 ; CHECK-NEXT: store i32 1, i32* %[[bitcast]]
 144   store i64 1, i64* %overlap.1.i64
 145 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast [16 x i8]* %[[test3_a3]] to i64*
 146 ; CHECK-NEXT: store i64 1, i64* %[[bitcast]]
 147   store i64 2, i64* %overlap.2.i64
 148 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 1
 149 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i64*
 150 ; CHECK-NEXT: store i64 2, i64* %[[bitcast]]
 151   store i64 3, i64* %overlap.3.i64
 152 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 2
 153 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i64*
 154 ; CHECK-NEXT: store i64 3, i64* %[[bitcast]]
 155   store i64 4, i64* %overlap.4.i64
 156 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 3
 157 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i64*
 158 ; CHECK-NEXT: store i64 4, i64* %[[bitcast]]
 159   store i64 5, i64* %overlap.5.i64
 160 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 4
 161 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i64*
 162 ; CHECK-NEXT: store i64 5, i64* %[[bitcast]]
 163   store i64 6, i64* %overlap.6.i64
 164 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 5
 165 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i64*
 166 ; CHECK-NEXT: store i64 6, i64* %[[bitcast]]
 167   store i64 7, i64* %overlap.7.i64
 168 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 6
 169 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i64*
 170 ; CHECK-NEXT: store i64 7, i64* %[[bitcast]]
 171   store i64 8, i64* %overlap.8.i64
 172 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 7
 173 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i64*
 174 ; CHECK-NEXT: store i64 8, i64* %[[bitcast]]
 175   store i64 9, i64* %overlap.9.i64
 176 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 8
 177 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i64*
 178 ; CHECK-NEXT: store i64 9, i64* %[[bitcast]]
 179
 180   ; Make two sequences of overlapping stores with more gaps and irregularities.
 181   %overlap2.1.0.i8 = getelementptr [300 x i8]* %a, i64 0, i64 200
 182   %overlap2.1.1.i8 = getelementptr [300 x i8]* %a, i64 0, i64 201
 183   %overlap2.1.2.i8 = getelementptr [300 x i8]* %a, i64 0, i64 202
 184   %overlap2.1.3.i8 = getelementptr [300 x i8]* %a, i64 0, i64 203
 185
 186   %overlap2.2.0.i8 = getelementptr [300 x i8]* %a, i64 0, i64 208
 187   %overlap2.2.1.i8 = getelementptr [300 x i8]* %a, i64 0, i64 209
 188   %overlap2.2.2.i8 = getelementptr [300 x i8]* %a, i64 0, i64 210
 189   %overlap2.2.3.i8 = getelementptr [300 x i8]* %a, i64 0, i64 211
 190
 191   %overlap2.1.0.i16 = bitcast i8* %overlap2.1.0.i8 to i16*
 192   %overlap2.1.0.i32 = bitcast i8* %overlap2.1.0.i8 to i32*
 193   %overlap2.1.1.i32 = bitcast i8* %overlap2.1.1.i8 to i32*
 194   %overlap2.1.2.i32 = bitcast i8* %overlap2.1.2.i8 to i32*
 195   %overlap2.1.3.i32 = bitcast i8* %overlap2.1.3.i8 to i32*
 196   store i8 1,  i8*  %overlap2.1.0.i8
 197 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a5]], i64 0, i64 0
 198 ; CHECK-NEXT: store i8 1, i8* %[[gep]]
 199   store i16 1, i16* %overlap2.1.0.i16
 200 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast [7 x i8]* %[[test3_a5]] to i16*
 201 ; CHECK-NEXT: store i16 1, i16* %[[bitcast]]
 202   store i32 1, i32* %overlap2.1.0.i32
 203 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast [7 x i8]* %[[test3_a5]] to i32*
 204 ; CHECK-NEXT: store i32 1, i32* %[[bitcast]]
 205   store i32 2, i32* %overlap2.1.1.i32
 206 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a5]], i64 0, i64 1
 207 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i32*
 208 ; CHECK-NEXT: store i32 2, i32* %[[bitcast]]
 209   store i32 3, i32* %overlap2.1.2.i32
 210 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a5]], i64 0, i64 2
 211 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i32*
 212 ; CHECK-NEXT: store i32 3, i32* %[[bitcast]]
 213   store i32 4, i32* %overlap2.1.3.i32
 214 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a5]], i64 0, i64 3
 215 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i32*
 216 ; CHECK-NEXT: store i32 4, i32* %[[bitcast]]
 217
 218   %overlap2.2.0.i32 = bitcast i8* %overlap2.2.0.i8 to i32*
 219   %overlap2.2.1.i16 = bitcast i8* %overlap2.2.1.i8 to i16*
 220   %overlap2.2.1.i32 = bitcast i8* %overlap2.2.1.i8 to i32*
 221   %overlap2.2.2.i32 = bitcast i8* %overlap2.2.2.i8 to i32*
 222   %overlap2.2.3.i32 = bitcast i8* %overlap2.2.3.i8 to i32*
 223   store i32 1, i32* %overlap2.2.0.i32
 224 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast [7 x i8]* %[[test3_a6]] to i32*
 225 ; CHECK-NEXT: store i32 1, i32* %[[bitcast]]
 226   store i8 1,  i8*  %overlap2.2.1.i8
 227 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 1
 228 ; CHECK-NEXT: store i8 1, i8* %[[gep]]
 229   store i16 1, i16* %overlap2.2.1.i16
 230 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 1
 231 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i16*
 232 ; CHECK-NEXT: store i16 1, i16* %[[bitcast]]
 233   store i32 1, i32* %overlap2.2.1.i32
 234 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 1
 235 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i32*
 236 ; CHECK-NEXT: store i32 1, i32* %[[bitcast]]
 237   store i32 3, i32* %overlap2.2.2.i32
 238 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 2
 239 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i32*
 240 ; CHECK-NEXT: store i32 3, i32* %[[bitcast]]
 241   store i32 4, i32* %overlap2.2.3.i32
 242 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 3
 243 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i32*
 244 ; CHECK-NEXT: store i32 4, i32* %[[bitcast]]
 245
 246   %overlap2.prefix = getelementptr i8* %overlap2.1.1.i8, i64 -4
 247   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %overlap2.prefix, i8* %src, i32 8, i32 1, i1 false)
 248 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [42 x i8]* %[[test3_a4]], i64 0, i64 39
 249 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %src, i32 3
 250 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 3
 251 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a5]], i64 0, i64 0
 252 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 5
 253
 254   ; Bridge between the overlapping areas
 255   call void @llvm.memset.p0i8.i32(i8* %overlap2.1.2.i8, i8 42, i32 8, i32 1, i1 false)
 256 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a5]], i64 0, i64 2
 257 ; CHECK-NEXT: call void @llvm.memset.p0i8.i32(i8* %[[gep]], i8 42, i32 5
 258 ; ...promoted i8 store...
 259 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 0
 260 ; CHECK-NEXT: call void @llvm.memset.p0i8.i32(i8* %[[gep]], i8 42, i32 2
 261
 262   ; Entirely within the second overlap.
 263   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %overlap2.2.1.i8, i8* %src, i32 5, i32 1, i1 false)
 264 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 1
 265 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep]], i8* %src, i32 5
 266
 267   ; Trailing past the second overlap.
 268   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %overlap2.2.2.i8, i8* %src, i32 8, i32 1, i1 false)
 269 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 2
 270 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep]], i8* %src, i32 5
 271 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 5
 272 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [85 x i8]* %[[test3_a7]], i64 0, i64 0
 273 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 3
 274
 275   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %b, i32 300, i32 1, i1 false)
 276 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [42 x i8]* %[[test3_a1]], i64 0, i64 0
 277 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %[[gep]], i32 42
 278 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %dst, i64 42
 279 ; CHECK-NEXT: store i8 0, i8* %[[gep]]
 280 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 43
 281 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [99 x i8]* %[[test3_a2]], i64 0, i64 0
 282 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 99
 283 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 142
 284 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [16 x i8]* %[[test3_a3]], i64 0, i64 0
 285 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 16
 286 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 158
 287 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [42 x i8]* %[[test3_a4]], i64 0, i64 0
 288 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 42
 289 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 200
 290 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a5]], i64 0, i64 0
 291 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 292 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %dst, i64 207
 293 ; CHECK-NEXT: store i8 42, i8* %[[gep]]
 294 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 208
 295 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [7 x i8]* %[[test3_a6]], i64 0, i64 0
 296 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 297 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 215
 298 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [85 x i8]* %[[test3_a7]], i64 0, i64 0
 299 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 85
 300
 301   ret void
 302 }
 303
 304 define void @test4(i8* %dst, i8* %src) {
 305 ; CHECK: @test4
 306
 307 entry:
 308   %a = alloca [100 x i8]
 309 ; CHECK-NOT:  alloca
 310 ; CHECK:      %[[test4_a1:.*]] = alloca [20 x i8]
 311 ; CHECK-NEXT: %[[test4_a2:.*]] = alloca [7 x i8]
 312 ; CHECK-NEXT: %[[test4_a3:.*]] = alloca [10 x i8]
 313 ; CHECK-NEXT: %[[test4_a4:.*]] = alloca [7 x i8]
 314 ; CHECK-NEXT: %[[test4_a5:.*]] = alloca [7 x i8]
 315 ; CHECK-NEXT: %[[test4_a6:.*]] = alloca [40 x i8]
 316
 317   %b = getelementptr [100 x i8]* %a, i64 0, i64 0
 318   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %b, i8* %src, i32 100, i32 1, i1 false)
 319 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [20 x i8]* %[[test4_a1]], i64 0, i64 0
 320 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep]], i8* %src, i32 20
 321 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %src, i64 20
 322 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i16*
 323 ; CHECK-NEXT: %[[test4_r1:.*]] = load i16* %[[bitcast]]
 324 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %src, i64 22
 325 ; CHECK-NEXT: %[[test4_r2:.*]] = load i8* %[[gep]]
 326 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 23
 327 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a2]], i64 0, i64 0
 328 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 329 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 30
 330 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [10 x i8]* %[[test4_a3]], i64 0, i64 0
 331 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 10
 332 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %src, i64 40
 333 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i16*
 334 ; CHECK-NEXT: %[[test4_r3:.*]] = load i16* %[[bitcast]]
 335 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %src, i64 42
 336 ; CHECK-NEXT: %[[test4_r4:.*]] = load i8* %[[gep]]
 337 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 43
 338 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a4]], i64 0, i64 0
 339 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 340 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %src, i64 50
 341 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i16*
 342 ; CHECK-NEXT: %[[test4_r5:.*]] = load i16* %[[bitcast]]
 343 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %src, i64 52
 344 ; CHECK-NEXT: %[[test4_r6:.*]] = load i8* %[[gep]]
 345 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 53
 346 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a5]], i64 0, i64 0
 347 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 348 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds i8* %src, i64 60
 349 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [40 x i8]* %[[test4_a6]], i64 0, i64 0
 350 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 40
 351
 352   %a.src.1 = getelementptr [100 x i8]* %a, i64 0, i64 20
 353   %a.dst.1 = getelementptr [100 x i8]* %a, i64 0, i64 40
 354   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %a.dst.1, i8* %a.src.1, i32 10, i32 1, i1 false)
 355 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a4]], i64 0, i64 0
 356 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a2]], i64 0, i64 0
 357 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 358
 359   ; Clobber a single element of the array, this should be promotable, and be deleted.
 360   %c = getelementptr [100 x i8]* %a, i64 0, i64 42
 361   store i8 0, i8* %c
 362
 363   %a.src.2 = getelementptr [100 x i8]* %a, i64 0, i64 50
 364   call void @llvm.memmove.p0i8.p0i8.i32(i8* %a.dst.1, i8* %a.src.2, i32 10, i32 1, i1 false)
 365 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a4]], i64 0, i64 0
 366 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a5]], i64 0, i64 0
 367 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 368
 369   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %b, i32 100, i32 1, i1 false)
 370 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds [20 x i8]* %[[test4_a1]], i64 0, i64 0
 371 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %[[gep]], i32 20
 372 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %dst, i64 20
 373 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i16*
 374 ; CHECK-NEXT: store i16 %[[test4_r1]], i16* %[[bitcast]]
 375 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %dst, i64 22
 376 ; CHECK-NEXT: store i8 %[[test4_r2]], i8* %[[gep]]
 377 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 23
 378 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a2]], i64 0, i64 0
 379 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 380 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 30
 381 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [10 x i8]* %[[test4_a3]], i64 0, i64 0
 382 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 10
 383 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %dst, i64 40
 384 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i16*
 385 ; CHECK-NEXT: store i16 %[[test4_r5]], i16* %[[bitcast]]
 386 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %dst, i64 42
 387 ; CHECK-NEXT: store i8 %[[test4_r6]], i8* %[[gep]]
 388 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 43
 389 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a4]], i64 0, i64 0
 390 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 391 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %dst, i64 50
 392 ; CHECK-NEXT: %[[bitcast:.*]] = bitcast i8* %[[gep]] to i16*
 393 ; CHECK-NEXT: store i16 %[[test4_r5]], i16* %[[bitcast]]
 394 ; CHECK-NEXT: %[[gep:.*]] = getelementptr inbounds i8* %dst, i64 52
 395 ; CHECK-NEXT: store i8 %[[test4_r6]], i8* %[[gep]]
 396 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 53
 397 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [7 x i8]* %[[test4_a5]], i64 0, i64 0
 398 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 7
 399 ; CHECK-NEXT: %[[gep_dst:.*]] = getelementptr inbounds i8* %dst, i64 60
 400 ; CHECK-NEXT: %[[gep_src:.*]] = getelementptr inbounds [40 x i8]* %[[test4_a6]], i64 0, i64 0
 401 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[gep_dst]], i8* %[[gep_src]], i32 40
 402
 403   ret void
 404 }
 405
 406 declare void @llvm.memcpy.p0i8.p0i8.i32(i8* nocapture, i8* nocapture, i32, i32, i1) nounwind
 407 declare void @llvm.memmove.p0i8.p0i8.i32(i8* nocapture, i8* nocapture, i32, i32, i1) nounwind
 408 declare void @llvm.memset.p0i8.i32(i8* nocapture, i8, i32, i32, i1) nounwind
 409
 410 define i16 @test5() {
 411 ; CHECK: @test5
 412 ; CHECK-NOT: alloca float
 413 ; CHECK:      %[[cast:.*]] = bitcast float 0.0{{.*}} to i32
 414 ; CHECK-NEXT: %[[shr:.*]] = lshr i32 %[[cast]], 16
 415 ; CHECK-NEXT: %[[trunc:.*]] = trunc i32 %[[shr]] to i16
 416 ; CHECK-NEXT: ret i16 %[[trunc]]
 417
 418 entry:
 419   %a = alloca [4 x i8]
 420   %fptr = bitcast [4 x i8]* %a to float*
 421   store float 0.0, float* %fptr
 422   %ptr = getelementptr [4 x i8]* %a, i32 0, i32 2
 423   %iptr = bitcast i8* %ptr to i16*
 424   %val = load i16* %iptr
 425   ret i16 %val
 426 }
 427
 428 define i32 @test6() {
 429 ; CHECK: @test6
 430 ; CHECK: alloca i32
 431 ; CHECK-NEXT: store volatile i32
 432 ; CHECK-NEXT: load i32*
 433 ; CHECK-NEXT: ret i32
 434
 435 entry:
 436   %a = alloca [4 x i8]
 437   %ptr = getelementptr [4 x i8]* %a, i32 0, i32 0
 438   call void @llvm.memset.p0i8.i32(i8* %ptr, i8 42, i32 4, i32 1, i1 true)
 439   %iptr = bitcast i8* %ptr to i32*
 440   %val = load i32* %iptr
 441   ret i32 %val
 442 }
 443
 444 define void @test7(i8* %src, i8* %dst) {
 445 ; CHECK: @test7
 446 ; CHECK: alloca i32
 447 ; CHECK-NEXT: bitcast i8* %src to i32*
 448 ; CHECK-NEXT: load volatile i32*
 449 ; CHECK-NEXT: store volatile i32
 450 ; CHECK-NEXT: bitcast i8* %dst to i32*
 451 ; CHECK-NEXT: load volatile i32*
 452 ; CHECK-NEXT: store volatile i32
 453 ; CHECK-NEXT: ret
 454
 455 entry:
 456   %a = alloca [4 x i8]
 457   %ptr = getelementptr [4 x i8]* %a, i32 0, i32 0
 458   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %ptr, i8* %src, i32 4, i32 1, i1 true)
 459   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %ptr, i32 4, i32 1, i1 true)
 460   ret void
 461 }
 462
 463
 464 %S1 = type { i32, i32, [16 x i8] }
 465 %S2 = type { %S1*, %S2* }
 466
 467 define %S2 @test8(%S2* %s2) {
 468 ; CHECK: @test8
 469 entry:
 470   %new = alloca %S2
 471 ; CHECK-NOT: alloca
 472
 473   %s2.next.ptr = getelementptr %S2* %s2, i64 0, i32 1
 474   %s2.next = load %S2** %s2.next.ptr
 475 ; CHECK:      %[[gep:.*]] = getelementptr %S2* %s2, i64 0, i32 1
 476 ; CHECK-NEXT: %[[next:.*]] = load %S2** %[[gep]]
 477
 478   %s2.next.s1.ptr = getelementptr %S2* %s2.next, i64 0, i32 0
 479   %s2.next.s1 = load %S1** %s2.next.s1.ptr
 480   %new.s1.ptr = getelementptr %S2* %new, i64 0, i32 0
 481   store %S1* %s2.next.s1, %S1** %new.s1.ptr
 482   %s2.next.next.ptr = getelementptr %S2* %s2.next, i64 0, i32 1
 483   %s2.next.next = load %S2** %s2.next.next.ptr
 484   %new.next.ptr = getelementptr %S2* %new, i64 0, i32 1
 485   store %S2* %s2.next.next, %S2** %new.next.ptr
 486 ; CHECK-NEXT: %[[gep:.*]] = getelementptr %S2* %[[next]], i64 0, i32 0
 487 ; CHECK-NEXT: %[[next_s1:.*]] = load %S1** %[[gep]]
 488 ; CHECK-NEXT: %[[gep:.*]] = getelementptr %S2* %[[next]], i64 0, i32 1
 489 ; CHECK-NEXT: %[[next_next:.*]] = load %S2** %[[gep]]
 490
 491   %new.s1 = load %S1** %new.s1.ptr
 492   %result1 = insertvalue %S2 undef, %S1* %new.s1, 0
 493 ; CHECK-NEXT: %[[result1:.*]] = insertvalue %S2 undef, %S1* %[[next_s1]], 0
 494   %new.next = load %S2** %new.next.ptr
 495   %result2 = insertvalue %S2 %result1, %S2* %new.next, 1
 496 ; CHECK-NEXT: %[[result2:.*]] = insertvalue %S2 %[[result1]], %S2* %[[next_next]], 1
 497   ret %S2 %result2
 498 ; CHECK-NEXT: ret %S2 %[[result2]]
 499 }
 500
 501 define i64 @test9() {
 502 ; Ensure we can handle loads off the end of an alloca even when wrapped in
 503 ; weird bit casts and types. The result is undef, but this shouldn't crash
 504 ; anything.
 505 ; CHECK: @test9
 506 ; CHECK-NOT: alloca
 507 ; CHECK: ret i64 undef
 508
 509 entry:
 510   %a = alloca { [3 x i8] }
 511   %gep1 = getelementptr inbounds { [3 x i8] }* %a, i32 0, i32 0, i32 0
 512   store i8 0, i8* %gep1, align 1
 513   %gep2 = getelementptr inbounds { [3 x i8] }* %a, i32 0, i32 0, i32 1
 514   store i8 0, i8* %gep2, align 1
 515   %gep3 = getelementptr inbounds { [3 x i8] }* %a, i32 0, i32 0, i32 2
 516   store i8 26, i8* %gep3, align 1
 517   %cast = bitcast { [3 x i8] }* %a to { i64 }*
 518   %elt = getelementptr inbounds { i64 }* %cast, i32 0, i32 0
 519   %result = load i64* %elt
 520   ret i64 %result
 521 }
 522
 523 define %S2* @test10() {
 524 ; CHECK: @test10
 525 ; CHECK-NOT: alloca %S2*
 526 ; CHECK: ret %S2* null
 527
 528 entry:
 529   %a = alloca [8 x i8]
 530   %ptr = getelementptr [8 x i8]* %a, i32 0, i32 0
 531   call void @llvm.memset.p0i8.i32(i8* %ptr, i8 0, i32 8, i32 1, i1 false)
 532   %s2ptrptr = bitcast i8* %ptr to %S2**
 533   %s2ptr = load %S2** %s2ptrptr
 534   ret %S2* %s2ptr
 535 }
 536
 537 define i32 @test11() {
 538 ; CHECK: @test11
 539 ; CHECK-NOT: alloca
 540 ; CHECK: ret i32 0
 541
 542 entry:
 543   %X = alloca i32
 544   br i1 undef, label %good, label %bad
 545
 546 good:
 547   %Y = getelementptr i32* %X, i64 0
 548   store i32 0, i32* %Y
 549   %Z = load i32* %Y
 550   ret i32 %Z
 551
 552 bad:
 553   %Y2 = getelementptr i32* %X, i64 1
 554   store i32 0, i32* %Y2
 555   %Z2 = load i32* %Y2
 556   ret i32 %Z2
 557 }
 558
 559 define i8 @test12() {
 560 ; We fully promote these to the i24 load or store size, resulting in just masks
 561 ; and other operations that instcombine will fold, but no alloca.
 562 ;
 563 ; CHECK: @test12
 564
 565 entry:
 566   %a = alloca [3 x i8]
 567   %b = alloca [3 x i8]
 568 ; CHECK-NOT: alloca
 569
 570   %a0ptr = getelementptr [3 x i8]* %a, i64 0, i32 0
 571   store i8 0, i8* %a0ptr
 572   %a1ptr = getelementptr [3 x i8]* %a, i64 0, i32 1
 573   store i8 0, i8* %a1ptr
 574   %a2ptr = getelementptr [3 x i8]* %a, i64 0, i32 2
 575   store i8 0, i8* %a2ptr
 576   %aiptr = bitcast [3 x i8]* %a to i24*
 577   %ai = load i24* %aiptr
 578 ; CHCEK-NOT: store
 579 ; CHCEK-NOT: load
 580 ; CHECK:      %[[mask0:.*]] = and i24 undef, -256
 581 ; CHECK-NEXT: %[[mask1:.*]] = and i24 %[[mask0]], -65281
 582 ; CHECK-NEXT: %[[mask2:.*]] = and i24 %[[mask1]], 65535
 583
 584   %biptr = bitcast [3 x i8]* %b to i24*
 585   store i24 %ai, i24* %biptr
 586   %b0ptr = getelementptr [3 x i8]* %b, i64 0, i32 0
 587   %b0 = load i8* %b0ptr
 588   %b1ptr = getelementptr [3 x i8]* %b, i64 0, i32 1
 589   %b1 = load i8* %b1ptr
 590   %b2ptr = getelementptr [3 x i8]* %b, i64 0, i32 2
 591   %b2 = load i8* %b2ptr
 592 ; CHCEK-NOT: store
 593 ; CHCEK-NOT: load
 594 ; CHECK:      %[[trunc0:.*]] = trunc i24 %[[mask2]] to i8
 595 ; CHECK-NEXT: %[[shift1:.*]] = lshr i24 %[[mask2]], 8
 596 ; CHECK-NEXT: %[[trunc1:.*]] = trunc i24 %[[shift1]] to i8
 597 ; CHECK-NEXT: %[[shift2:.*]] = lshr i24 %[[mask2]], 16
 598 ; CHECK-NEXT: %[[trunc2:.*]] = trunc i24 %[[shift2]] to i8
 599
 600   %bsum0 = add i8 %b0, %b1
 601   %bsum1 = add i8 %bsum0, %b2
 602   ret i8 %bsum1
 603 ; CHECK:      %[[sum0:.*]] = add i8 %[[trunc0]], %[[trunc1]]
 604 ; CHECK-NEXT: %[[sum1:.*]] = add i8 %[[sum0]], %[[trunc2]]
 605 ; CHECK-NEXT: ret i8 %[[sum1]]
 606 }
 607
 608 define i32 @test13() {
 609 ; Ensure we don't crash and handle undefined loads that straddle the end of the
 610 ; allocation.
 611 ; CHECK: @test13
 612 ; CHECK: %[[ret:.*]] = zext i16 undef to i32
 613 ; CHECK: ret i32 %[[ret]]
 614
 615 entry:
 616   %a = alloca [3 x i8]
 617   %b0ptr = getelementptr [3 x i8]* %a, i64 0, i32 0
 618   store i8 0, i8* %b0ptr
 619   %b1ptr = getelementptr [3 x i8]* %a, i64 0, i32 1
 620   store i8 0, i8* %b1ptr
 621   %b2ptr = getelementptr [3 x i8]* %a, i64 0, i32 2
 622   store i8 0, i8* %b2ptr
 623   %iptrcast = bitcast [3 x i8]* %a to i16*
 624   %iptrgep = getelementptr i16* %iptrcast, i64 1
 625   %i = load i16* %iptrgep
 626   %ret = zext i16 %i to i32
 627   ret i32 %ret
 628 }
 629
 630 %test14.struct = type { [3 x i32] }
 631
 632 define void @test14(...) nounwind uwtable {
 633 ; This is a strange case where we split allocas into promotable partitions, but
 634 ; also gain enough data to prove they must be dead allocas due to GEPs that walk
 635 ; across two adjacent allocas. Test that we don't try to promote or otherwise
 636 ; do bad things to these dead allocas, they should just be removed.
 637 ; CHECK: @test14
 638 ; CHECK-NEXT: entry:
 639 ; CHECK-NEXT: ret void
 640
 641 entry:
 642   %a = alloca %test14.struct
 643   %p = alloca %test14.struct*
 644   %0 = bitcast %test14.struct* %a to i8*
 645   %1 = getelementptr i8* %0, i64 12
 646   %2 = bitcast i8* %1 to %test14.struct*
 647   %3 = getelementptr inbounds %test14.struct* %2, i32 0, i32 0
 648   %4 = getelementptr inbounds %test14.struct* %a, i32 0, i32 0
 649   %5 = bitcast [3 x i32]* %3 to i32*
 650   %6 = bitcast [3 x i32]* %4 to i32*
 651   %7 = load i32* %6, align 4
 652   store i32 %7, i32* %5, align 4
 653   %8 = getelementptr inbounds i32* %5, i32 1
 654   %9 = getelementptr inbounds i32* %6, i32 1
 655   %10 = load i32* %9, align 4
 656   store i32 %10, i32* %8, align 4
 657   %11 = getelementptr inbounds i32* %5, i32 2
 658   %12 = getelementptr inbounds i32* %6, i32 2
 659   %13 = load i32* %12, align 4
 660   store i32 %13, i32* %11, align 4
 661   ret void
 662 }
 663
 664 define i32 @test15(i1 %flag) nounwind uwtable {
 665 ; Ensure that when there are dead instructions using an alloca that are not
 666 ; loads or stores we still delete them during partitioning and rewriting.
 667 ; Otherwise we'll go to promote them while thy still have unpromotable uses.
 668 ; CHECK: @test15
 669 ; CHECK-NEXT: entry:
 670 ; CHECK-NEXT:   br label %loop
 671 ; CHECK:      loop:
 672 ; CHECK-NEXT:   br label %loop
 673
 674 entry:
 675   %l0 = alloca i64
 676   %l1 = alloca i64
 677   %l2 = alloca i64
 678   %l3 = alloca i64
 679   br label %loop
 680
 681 loop:
 682   %dead3 = phi i8* [ %gep3, %loop ], [ null, %entry ]
 683
 684   store i64 1879048192, i64* %l0, align 8
 685   %bc0 = bitcast i64* %l0 to i8*
 686   %gep0 = getelementptr i8* %bc0, i64 3
 687   %dead0 = bitcast i8* %gep0 to i64*
 688
 689   store i64 1879048192, i64* %l1, align 8
 690   %bc1 = bitcast i64* %l1 to i8*
 691   %gep1 = getelementptr i8* %bc1, i64 3
 692   %dead1 = getelementptr i8* %gep1, i64 1
 693
 694   store i64 1879048192, i64* %l2, align 8
 695   %bc2 = bitcast i64* %l2 to i8*
 696   %gep2.1 = getelementptr i8* %bc2, i64 1
 697   %gep2.2 = getelementptr i8* %bc2, i64 3
 698   ; Note that this select should get visited multiple times due to using two
 699   ; different GEPs off the same alloca. We should only delete it once.
 700   %dead2 = select i1 %flag, i8* %gep2.1, i8* %gep2.2
 701
 702   store i64 1879048192, i64* %l3, align 8
 703   %bc3 = bitcast i64* %l3 to i8*
 704   %gep3 = getelementptr i8* %bc3, i64 3
 705
 706   br label %loop
 707 }
 708
 709 define void @test16(i8* %src, i8* %dst) {
 710 ; Ensure that we can promote an alloca of [3 x i8] to an i24 SSA value.
 711 ; CHECK: @test16
 712 ; CHECK-NOT: alloca
 713 ; CHECK:      %[[srccast:.*]] = bitcast i8* %src to i24*
 714 ; CHECK-NEXT: load i24* %[[srccast]]
 715 ; CHECK-NEXT: %[[dstcast:.*]] = bitcast i8* %dst to i24*
 716 ; CHECK-NEXT: store i24 0, i24* %[[dstcast]]
 717 ; CHECK-NEXT: ret void
 718
 719 entry:
 720   %a = alloca [3 x i8]
 721   %ptr = getelementptr [3 x i8]* %a, i32 0, i32 0
 722   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %ptr, i8* %src, i32 4, i32 1, i1 false)
 723   %cast = bitcast i8* %ptr to i24*
 724   store i24 0, i24* %cast
 725   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %ptr, i32 4, i32 1, i1 false)
 726   ret void
 727 }
 728
 729 define void @test17(i8* %src, i8* %dst) {
 730 ; Ensure that we can rewrite unpromotable memcpys which extend past the end of
 731 ; the alloca.
 732 ; CHECK: @test17
 733 ; CHECK:      %[[a:.*]] = alloca [3 x i8]
 734 ; CHECK-NEXT: %[[ptr:.*]] = getelementptr [3 x i8]* %[[a]], i32 0, i32 0
 735 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[ptr]], i8* %src,
 736 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %[[ptr]],
 737 ; CHECK-NEXT: ret void
 738
 739 entry:
 740   %a = alloca [3 x i8]
 741   %ptr = getelementptr [3 x i8]* %a, i32 0, i32 0
 742   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %ptr, i8* %src, i32 4, i32 1, i1 true)
 743   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %ptr, i32 4, i32 1, i1 true)
 744   ret void
 745 }
 746
 747 define void @test18(i8* %src, i8* %dst, i32 %size) {
 748 ; Preserve transfer instrinsics with a variable size, even if they overlap with
 749 ; fixed size operations. Further, continue to split and promote allocas preceding
 750 ; the variable sized intrinsic.
 751 ; CHECK: @test18
 752 ; CHECK:      %[[a:.*]] = alloca [34 x i8]
 753 ; CHECK:      %[[srcgep1:.*]] = getelementptr inbounds i8* %src, i64 4
 754 ; CHECK-NEXT: %[[srccast1:.*]] = bitcast i8* %[[srcgep1]] to i32*
 755 ; CHECK-NEXT: %[[srcload:.*]] = load i32* %[[srccast1]]
 756 ; CHECK-NEXT: %[[agep1:.*]] = getelementptr inbounds [34 x i8]* %[[a]], i64 0, i64 0
 757 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %[[agep1]], i8* %src, i32 %size,
 758 ; CHECK-NEXT: %[[agep2:.*]] = getelementptr inbounds [34 x i8]* %[[a]], i64 0, i64 0
 759 ; CHECK-NEXT: call void @llvm.memset.p0i8.i32(i8* %[[agep2]], i8 42, i32 %size,
 760 ; CHECK-NEXT: %[[dstcast1:.*]] = bitcast i8* %dst to i32*
 761 ; CHECK-NEXT: store i32 42, i32* %[[dstcast1]]
 762 ; CHECK-NEXT: %[[dstgep1:.*]] = getelementptr inbounds i8* %dst, i64 4
 763 ; CHECK-NEXT: %[[dstcast2:.*]] = bitcast i8* %[[dstgep1]] to i32*
 764 ; CHECK-NEXT: store i32 %[[srcload]], i32* %[[dstcast2]]
 765 ; CHECK-NEXT: %[[agep3:.*]] = getelementptr inbounds [34 x i8]* %[[a]], i64 0, i64 0
 766 ; CHECK-NEXT: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %[[agep3]], i32 %size,
 767 ; CHECK-NEXT: ret void
 768
 769 entry:
 770   %a = alloca [42 x i8]
 771   %ptr = getelementptr [42 x i8]* %a, i32 0, i32 0
 772   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %ptr, i8* %src, i32 8, i32 1, i1 false)
 773   %ptr2 = getelementptr [42 x i8]* %a, i32 0, i32 8
 774   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %ptr2, i8* %src, i32 %size, i32 1, i1 false)
 775   call void @llvm.memset.p0i8.i32(i8* %ptr2, i8 42, i32 %size, i32 1, i1 false)
 776   %cast = bitcast i8* %ptr to i32*
 777   store i32 42, i32* %cast
 778   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %ptr, i32 8, i32 1, i1 false)
 779   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst, i8* %ptr2, i32 %size, i32 1, i1 false)
 780   ret void
 781 }
 782
 783 %opaque = type opaque
 784
 785 define i32 @test19(%opaque* %x) {
 786 ; This input will cause us to try to compute a natural GEP when rewriting
 787 ; pointers in such a way that we try to GEP through the opaque type. Previously,
 788 ; a check for an unsized type was missing and this crashed. Ensure it behaves
 789 ; reasonably now.
 790 ; CHECK: @test19
 791 ; CHECK-NOT: alloca
 792 ; CHECK: ret i32 undef
 793
 794 entry:
 795   %a = alloca { i64, i8* }
 796   %cast1 = bitcast %opaque* %x to i8*
 797   %cast2 = bitcast { i64, i8* }* %a to i8*
 798   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %cast2, i8* %cast1, i32 16, i32 1, i1 false)
 799   %gep = getelementptr inbounds { i64, i8* }* %a, i32 0, i32 0
 800   %val = load i64* %gep
 801   ret i32 undef
 802 }
 803
 804 define i32 @test20() {
 805 ; Ensure we can track negative offsets (before the beginning of the alloca) and
 806 ; negative relative offsets from offsets starting past the end of the alloca.
 807 ; CHECK: @test20
 808 ; CHECK-NOT: alloca
 809 ; CHECK: %[[sum1:.*]] = add i32 1, 2
 810 ; CHECK: %[[sum2:.*]] = add i32 %[[sum1]], 3
 811 ; CHECK: ret i32 %[[sum2]]
 812
 813 entry:
 814   %a = alloca [3 x i32]
 815   %gep1 = getelementptr [3 x i32]* %a, i32 0, i32 0
 816   store i32 1, i32* %gep1
 817   %gep2.1 = getelementptr [3 x i32]* %a, i32 0, i32 -2
 818   %gep2.2 = getelementptr i32* %gep2.1, i32 3
 819   store i32 2, i32* %gep2.2
 820   %gep3.1 = getelementptr [3 x i32]* %a, i32 0, i32 14
 821   %gep3.2 = getelementptr i32* %gep3.1, i32 -12
 822   store i32 3, i32* %gep3.2
 823
 824   %load1 = load i32* %gep1
 825   %load2 = load i32* %gep2.2
 826   %load3 = load i32* %gep3.2
 827   %sum1 = add i32 %load1, %load2
 828   %sum2 = add i32 %sum1, %load3
 829   ret i32 %sum2
 830 }
 831
 832 declare void @llvm.memset.p0i8.i64(i8* nocapture, i8, i64, i32, i1) nounwind
 833
 834 define i8 @test21() {
 835 ; Test allocations and offsets which border on overflow of the int64_t used
 836 ; internally. This is really awkward to really test as LLVM doesn't really
 837 ; support such extreme constructs cleanly.
 838 ; CHECK: @test21
 839 ; CHECK-NOT: alloca
 840 ; CHECK: or i8 -1, -1
 841
 842 entry:
 843   %a = alloca [2305843009213693951 x i8]
 844   %gep0 = getelementptr [2305843009213693951 x i8]* %a, i64 0, i64 2305843009213693949
 845   store i8 255, i8* %gep0
 846   %gep1 = getelementptr [2305843009213693951 x i8]* %a, i64 0, i64 -9223372036854775807
 847   %gep2 = getelementptr i8* %gep1, i64 -1
 848   call void @llvm.memset.p0i8.i64(i8* %gep2, i8 0, i64 18446744073709551615, i32 1, i1 false)
 849   %gep3 = getelementptr i8* %gep1, i64 9223372036854775807
 850   %gep4 = getelementptr i8* %gep3, i64 9223372036854775807
 851   %gep5 = getelementptr i8* %gep4, i64 -6917529027641081857
 852   store i8 255, i8* %gep5
 853   %cast1 = bitcast i8* %gep4 to i32*
 854   store i32 0, i32* %cast1
 855   %load = load i8* %gep0
 856   %gep6 = getelementptr i8* %gep0, i32 1
 857   %load2 = load i8* %gep6
 858   %result = or i8 %load, %load2
 859   ret i8 %result
 860 }
 861
 862 %PR13916.struct = type { i8 }
 863
 864 define void @PR13916.1() {
 865 ; Ensure that we handle overlapping memcpy intrinsics correctly, especially in
 866 ; the case where there is a directly identical value for both source and dest.
 867 ; CHECK: @PR13916.1
 868 ; CHECK-NOT: alloca
 869 ; CHECK: ret void
 870
 871 entry:
 872   %a = alloca i8
 873   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %a, i8* %a, i32 1, i32 1, i1 false)
 874   %tmp2 = load i8* %a
 875   ret void
 876 }
 877
 878 define void @PR13916.2() {
 879 ; Check whether we continue to handle them correctly when they start off with
 880 ; different pointer value chains, but during rewriting we coalesce them into the
 881 ; same value.
 882 ; CHECK: @PR13916.2
 883 ; CHECK-NOT: alloca
 884 ; CHECK: ret void
 885
 886 entry:
 887   %a = alloca %PR13916.struct, align 1
 888   br i1 undef, label %if.then, label %if.end
 889
 890 if.then:
 891   %tmp0 = bitcast %PR13916.struct* %a to i8*
 892   %tmp1 = bitcast %PR13916.struct* %a to i8*
 893   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %tmp0, i8* %tmp1, i32 1, i32 1, i1 false)
 894   br label %if.end
 895
 896 if.end:
 897   %gep = getelementptr %PR13916.struct* %a, i32 0, i32 0
 898   %tmp2 = load i8* %gep
 899   ret void
 900 }
 901
 902 define void @PR13990() {
 903 ; Ensure we can handle cases where processing one alloca causes the other
 904 ; alloca to become dead and get deleted. This might crash or fail under
 905 ; Valgrind if we regress.
 906 ; CHECK: @PR13990
 907 ; CHECK-NOT: alloca
 908 ; CHECK: unreachable
 909 ; CHECK: unreachable
 910
 911 entry:
 912   %tmp1 = alloca i8*
 913   %tmp2 = alloca i8*
 914   br i1 undef, label %bb1, label %bb2
 915
 916 bb1:
 917   store i8* undef, i8** %tmp2
 918   br i1 undef, label %bb2, label %bb3
 919
 920 bb2:
 921   %tmp50 = select i1 undef, i8** %tmp2, i8** %tmp1
 922   br i1 undef, label %bb3, label %bb4
 923
 924 bb3:
 925   unreachable
 926
 927 bb4:
 928   unreachable
 929 }
 930
 931 define double @PR13969(double %x) {
 932 ; Check that we detect when promotion will un-escape an alloca and iterate to
 933 ; re-try running SROA over that alloca. Without that, the two allocas that are
 934 ; stored into a dead alloca don't get rewritten and promoted.
 935 ; CHECK: @PR13969
 936
 937 entry:
 938   %a = alloca double
 939   %b = alloca double*
 940   %c = alloca double
 941 ; CHECK-NOT: alloca
 942
 943   store double %x, double* %a
 944   store double* %c, double** %b
 945   store double* %a, double** %b
 946   store double %x, double* %c
 947   %ret = load double* %a
 948 ; CHECK-NOT: store
 949 ; CHECK-NOT: load
 950
 951   ret double %ret
 952 ; CHECK: ret double %x
 953 }
 954
 955 %PR14034.struct = type { { {} }, i32, %PR14034.list }
 956 %PR14034.list = type { %PR14034.list*, %PR14034.list* }
 957
 958 define void @PR14034() {
 959 ; This test case tries to form GEPs into the empty leading struct members, and
 960 ; subsequently crashed (under valgrind) before we fixed the PR. The important
 961 ; thing is to handle empty structs gracefully.
 962 ; CHECK: @PR14034
 963
 964 entry:
 965   %a = alloca %PR14034.struct
 966   %list = getelementptr %PR14034.struct* %a, i32 0, i32 2
 967   %prev = getelementptr %PR14034.list* %list, i32 0, i32 1
 968   store %PR14034.list* undef, %PR14034.list** %prev
 969   %cast0 = bitcast %PR14034.struct* undef to i8*
 970   %cast1 = bitcast %PR14034.struct* %a to i8*
 971   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %cast0, i8* %cast1, i32 12, i32 0, i1 false)
 972   ret void
 973 }
 974
 975 define i32 @test22(i32 %x) {
 976 ; Test that SROA and promotion is not confused by a grab bax mixture of pointer
 977 ; types involving wrapper aggregates and zero-length aggregate members.
 978 ; CHECK: @test22
 979
 980 entry:
 981   %a1 = alloca { { [1 x { i32 }] } }
 982   %a2 = alloca { {}, { float }, [0 x i8] }
 983   %a3 = alloca { [0 x i8], { [0 x double], [1 x [1 x <4 x i8>]], {} }, { { {} } } }
 984 ; CHECK-NOT: alloca
 985
 986   %wrap1 = insertvalue [1 x { i32 }] undef, i32 %x, 0, 0
 987   %gep1 = getelementptr { { [1 x { i32 }] } }* %a1, i32 0, i32 0, i32 0
 988   store [1 x { i32 }] %wrap1, [1 x { i32 }]* %gep1
 989
 990   %gep2 = getelementptr { { [1 x { i32 }] } }* %a1, i32 0, i32 0
 991   %ptrcast1 = bitcast { [1 x { i32 }] }* %gep2 to { [1 x { float }] }*
 992   %load1 = load { [1 x { float }] }* %ptrcast1
 993   %unwrap1 = extractvalue { [1 x { float }] } %load1, 0, 0
 994
 995   %wrap2 = insertvalue { {}, { float }, [0 x i8] } undef, { float } %unwrap1, 1
 996   store { {}, { float }, [0 x i8] } %wrap2, { {}, { float }, [0 x i8] }* %a2
 997
 998   %gep3 = getelementptr { {}, { float }, [0 x i8] }* %a2, i32 0, i32 1, i32 0
 999   %ptrcast2 = bitcast float* %gep3 to <4 x i8>*
1000   %load3 = load <4 x i8>* %ptrcast2
1001   %valcast1 = bitcast <4 x i8> %load3 to i32
1002
1003   %wrap3 = insertvalue [1 x [1 x i32]] undef, i32 %valcast1, 0, 0
1004   %wrap4 = insertvalue { [1 x [1 x i32]], {} } undef, [1 x [1 x i32]] %wrap3, 0
1005   %gep4 = getelementptr { [0 x i8], { [0 x double], [1 x [1 x <4 x i8>]], {} }, { { {} } } }* %a3, i32 0, i32 1
1006   %ptrcast3 = bitcast { [0 x double], [1 x [1 x <4 x i8>]], {} }* %gep4 to { [1 x [1 x i32]], {} }*
1007   store { [1 x [1 x i32]], {} } %wrap4, { [1 x [1 x i32]], {} }* %ptrcast3
1008
1009   %gep5 = getelementptr { [0 x i8], { [0 x double], [1 x [1 x <4 x i8>]], {} }, { { {} } } }* %a3, i32 0, i32 1, i32 1, i32 0
1010   %ptrcast4 = bitcast [1 x <4 x i8>]* %gep5 to { {}, float, {} }*
1011   %load4 = load { {}, float, {} }* %ptrcast4
1012   %unwrap2 = extractvalue { {}, float, {} } %load4, 1
1013   %valcast2 = bitcast float %unwrap2 to i32
1014
1015   ret i32 %valcast2
1016 ; CHECK: ret i32
1017 }
1018
1019 define void @PR14059.1(double* %d) {
1020 ; In PR14059 a peculiar construct was identified as something that is used
1021 ; pervasively in ARM's ABI-calling-convention lowering: the passing of a struct
1022 ; of doubles via an array of i32 in order to place the data into integer
1023 ; registers. This in turn was missed as an optimization by SROA due to the
1024 ; partial loads and stores of integers to the double alloca we were trying to
1025 ; form and promote. The solution is to widen the integer operations to be
1026 ; whole-alloca operations, and perform the appropriate bitcasting on the
1027 ; *values* rather than the pointers. When this works, partial reads and writes
1028 ; via integers can be promoted away.
1029 ; CHECK: @PR14059.1
1030 ; CHECK-NOT: alloca
1031 ; CHECK: ret void
1032
1033 entry:
1034   %X.sroa.0.i = alloca double, align 8
1035   %0 = bitcast double* %X.sroa.0.i to i8*
1036   call void @llvm.lifetime.start(i64 -1, i8* %0)
1037
1038   ; Store to the low 32-bits...
1039   %X.sroa.0.0.cast2.i = bitcast double* %X.sroa.0.i to i32*
1040   store i32 0, i32* %X.sroa.0.0.cast2.i, align 8
1041
1042   ; Also use a memset to the middle 32-bits for fun.
1043   %X.sroa.0.2.raw_idx2.i = getelementptr inbounds i8* %0, i32 2
1044   call void @llvm.memset.p0i8.i64(i8* %X.sroa.0.2.raw_idx2.i, i8 0, i64 4, i32 1, i1 false)
1045
1046   ; Or a memset of the whole thing.
1047   call void @llvm.memset.p0i8.i64(i8* %0, i8 0, i64 8, i32 1, i1 false)
1048
1049   ; Store to the high 32-bits...
1050   %X.sroa.0.4.raw_idx4.i = getelementptr inbounds i8* %0, i32 4
1051   %X.sroa.0.4.cast5.i = bitcast i8* %X.sroa.0.4.raw_idx4.i to i32*
1052   store i32 1072693248, i32* %X.sroa.0.4.cast5.i, align 4
1053
1054   ; Do the actual math...
1055   %X.sroa.0.0.load1.i = load double* %X.sroa.0.i, align 8
1056   %accum.real.i = load double* %d, align 8
1057   %add.r.i = fadd double %accum.real.i, %X.sroa.0.0.load1.i
1058   store double %add.r.i, double* %d, align 8
1059   call void @llvm.lifetime.end(i64 -1, i8* %0)
1060   ret void
1061 }