test/Transforms/Reassociate/basictest.ll

   1 ; With reassociation, constant folding can eliminate the 12 and -12 constants.
   2 ;
   3 ; RUN: opt < %s -reassociate  -gvn -instcombine -S | FileCheck %s
   4
   5 define i32 @test1(i32 %arg) {
   6         %tmp1 = sub i32 -12, %arg
   7         %tmp2 = add i32 %tmp1, 12
   8         ret i32 %tmp2
   9 ; CHECK: @test1
  10 ; CHECK-NEXT: sub i32 0, %arg
  11 ; CHECK-NEXT: ret i32
  12 }
  13
  14 define i32 @test2(i32 %reg109, i32 %reg1111) {
  15         %reg115 = add i32 %reg109, -30          ; <i32> [#uses=1]
  16         %reg116 = add i32 %reg115, %reg1111             ; <i32> [#uses=1]
  17         %reg117 = add i32 %reg116, 30           ; <i32> [#uses=1]
  18         ret i32 %reg117
  19 ; CHECK: @test2
  20 ; CHECK-NEXT: add i32 %reg1111, %reg109
  21 ; CHECK-NEXT: ret i32
  22 }
  23
  24 @e = external global i32                ; <i32*> [#uses=3]
  25 @a = external global i32                ; <i32*> [#uses=3]
  26 @b = external global i32                ; <i32*> [#uses=3]
  27 @c = external global i32                ; <i32*> [#uses=3]
  28 @f = external global i32                ; <i32*> [#uses=3]
  29
  30 define void @test3() {
  31         %A = load i32* @a               ; <i32> [#uses=2]
  32         %B = load i32* @b               ; <i32> [#uses=2]
  33         %C = load i32* @c               ; <i32> [#uses=2]
  34         %t1 = add i32 %A, %B            ; <i32> [#uses=1]
  35         %t2 = add i32 %t1, %C           ; <i32> [#uses=1]
  36         %t3 = add i32 %C, %A            ; <i32> [#uses=1]
  37         %t4 = add i32 %t3, %B           ; <i32> [#uses=1]
  38         ; e = (a+b)+c;
  39         store i32 %t2, i32* @e
  40         ; f = (a+c)+b
  41         store i32 %t4, i32* @f
  42         ret void
  43 ; CHECK: @test3
  44 ; CHECK: add i32
  45 ; CHECK: add i32
  46 ; CHECK-NOT: add i32
  47 ; CHECK: ret void
  48 }
  49
  50 define void @test4() {
  51         %A = load i32* @a               ; <i32> [#uses=2]
  52         %B = load i32* @b               ; <i32> [#uses=2]
  53         %C = load i32* @c               ; <i32> [#uses=2]
  54         %t1 = add i32 %A, %B            ; <i32> [#uses=1]
  55         %t2 = add i32 %t1, %C           ; <i32> [#uses=1]
  56         %t3 = add i32 %C, %A            ; <i32> [#uses=1]
  57         %t4 = add i32 %t3, %B           ; <i32> [#uses=1]
  58         ; e = c+(a+b)
  59         store i32 %t2, i32* @e
  60         ; f = (c+a)+b
  61         store i32 %t4, i32* @f
  62         ret void
  63 ; CHECK: @test4
  64 ; CHECK: add i32
  65 ; CHECK: add i32
  66 ; CHECK-NOT: add i32
  67 ; CHECK: ret void
  68 }
  69
  70 define void @test5() {
  71         %A = load i32* @a               ; <i32> [#uses=2]
  72         %B = load i32* @b               ; <i32> [#uses=2]
  73         %C = load i32* @c               ; <i32> [#uses=2]
  74         %t1 = add i32 %B, %A            ; <i32> [#uses=1]
  75         %t2 = add i32 %t1, %C           ; <i32> [#uses=1]
  76         %t3 = add i32 %C, %A            ; <i32> [#uses=1]
  77         %t4 = add i32 %t3, %B           ; <i32> [#uses=1]
  78         ; e = c+(b+a)
  79         store i32 %t2, i32* @e
  80         ; f = (c+a)+b
  81         store i32 %t4, i32* @f
  82         ret void
  83 ; CHECK: @test5
  84 ; CHECK: add i32
  85 ; CHECK: add i32
  86 ; CHECK-NOT: add i32
  87 ; CHECK: ret void
  88 }
  89
  90 define i32 @test6() {
  91         %tmp.0 = load i32* @a           ; <i32> [#uses=2]
  92         %tmp.1 = load i32* @b           ; <i32> [#uses=2]
  93         ; (a+b)
  94         %tmp.2 = add i32 %tmp.0, %tmp.1         ; <i32> [#uses=1]
  95         %tmp.4 = load i32* @c           ; <i32> [#uses=2]
  96         ; (a+b)+c
  97         %tmp.5 = add i32 %tmp.2, %tmp.4         ; <i32> [#uses=1]
  98         ; (a+c)
  99         %tmp.8 = add i32 %tmp.0, %tmp.4         ; <i32> [#uses=1]
 100         ; (a+c)+b
 101         %tmp.11 = add i32 %tmp.8, %tmp.1                ; <i32> [#uses=1]
 102         ; X ^ X = 0
 103         %RV = xor i32 %tmp.5, %tmp.11           ; <i32> [#uses=1]
 104         ret i32 %RV
 105 ; CHECK: @test6
 106 ; CHECK: ret i32 0
 107 }
 108
 109 ; This should be one add and two multiplies.
 110 define i32 @test7(i32 %A, i32 %B, i32 %C) {
 111         %aa = mul i32 %A, %A
 112         %aab = mul i32 %aa, %B
 113         %ac = mul i32 %A, %C
 114         %aac = mul i32 %ac, %A
 115         %r = add i32 %aab, %aac
 116         ret i32 %r
 117 ; CHECK: @test7
 118 ; CHECK-NEXT: add i32 %C, %B
 119 ; CHECK-NEXT: mul i32
 120 ; CHECK-NEXT: mul i32
 121 ; CHECK-NEXT: ret i32
 122 }
 123
 124
 125 define i32 @test8(i32 %X, i32 %Y, i32 %Z) {
 126         %A = sub i32 0, %X
 127         %B = mul i32 %A, %Y
 128         ; (-X)*Y + Z -> Z-X*Y
 129         %C = add i32 %B, %Z
 130         ret i32 %C
 131 ; CHECK: @test8
 132 ; CHECK-NEXT: %A = mul i32 %Y, %X
 133 ; CHECK-NEXT: %C = sub i32 %Z, %A
 134 ; CHECK-NEXT: ret i32 %C
 135 }