test/Transforms/LoopVectorize/induction.ll

   1 ; RUN: opt < %s -loop-vectorize -force-vector-interleave=1 -force-vector-width=2 -S | FileCheck %s
   2
   3 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   4
   5 ; Make sure that we can handle multiple integer induction variables.
   6 ; CHECK-LABEL: @multi_int_induction(
   7 ; CHECK: vector.body:
   8 ; CHECK:  %index = phi i64 [ 0, %vector.ph ], [ %index.next, %vector.body ]
   9 ; CHECK:  %[[VAR:.*]] = trunc i64 %index to i32
  10 ; CHECK:  %offset.idx = add i32 190, %[[VAR]]
  11 define void @multi_int_induction(i32* %A, i32 %N) {
  12 for.body.lr.ph:
  13   br label %for.body
  14
  15 for.body:
  16   %indvars.iv = phi i64 [ 0, %for.body.lr.ph ], [ %indvars.iv.next, %for.body ]
  17   %count.09 = phi i32 [ 190, %for.body.lr.ph ], [ %inc, %for.body ]
  18   %arrayidx2 = getelementptr inbounds i32, i32* %A, i64 %indvars.iv
  19   store i32 %count.09, i32* %arrayidx2, align 4
  20   %inc = add nsw i32 %count.09, 1
  21   %indvars.iv.next = add i64 %indvars.iv, 1
  22   %lftr.wideiv = trunc i64 %indvars.iv.next to i32
  23   %exitcond = icmp ne i32 %lftr.wideiv, %N
  24   br i1 %exitcond, label %for.body, label %for.end
  25
  26 for.end:
  27   ret void
  28 }
  29
  30 ; RUN: opt < %s -loop-vectorize -force-vector-interleave=1 -force-vector-width=2 -instcombine -S | FileCheck %s --check-prefix=IND
  31
  32 ; Make sure we remove unneeded vectorization of induction variables.
  33 ; In order for instcombine to cleanup the vectorized induction variables that we
  34 ; create in the loop vectorizer we need to perform some form of redundancy
  35 ; elimination to get rid of multiple uses.
  36
  37 ; IND-LABEL: scalar_use
  38
  39 ; IND:     br label %vector.body
  40 ; IND:     vector.body:
  41 ;   Vectorized induction variable.
  42 ; IND-NOT:  insertelement <2 x i64>
  43 ; IND-NOT:  shufflevector <2 x i64>
  44 ; IND:     br {{.*}}, label %vector.body
  45
  46 define void @scalar_use(float* %a, float %b, i64 %offset, i64 %offset2, i64 %n) {
  47 entry:
  48   br label %for.body
  49
  50 for.body:
  51   %iv = phi i64 [ 0, %entry ], [ %iv.next, %for.body ]
  52   %ind.sum = add i64 %iv, %offset
  53   %arr.idx = getelementptr inbounds float, float* %a, i64 %ind.sum
  54   %l1 = load float, float* %arr.idx, align 4
  55   %ind.sum2 = add i64 %iv, %offset2
  56   %arr.idx2 = getelementptr inbounds float, float* %a, i64 %ind.sum2
  57   %l2 = load float, float* %arr.idx2, align 4
  58   %m = fmul fast float %b, %l2
  59   %ad = fadd fast float %l1, %m
  60   store float %ad, float* %arr.idx, align 4
  61   %iv.next = add nuw nsw i64 %iv, 1
  62   %exitcond = icmp eq i64 %iv.next, %n
  63   br i1 %exitcond, label %loopexit, label %for.body
  64
  65 loopexit:
  66   ret void
  67 }
  68
  69
  70 ; Make sure that the loop exit count computation does not overflow for i8 and
  71 ; i16. The exit count of these loops is i8/i16 max + 1. If we don't cast the
  72 ; induction variable to a bigger type the exit count computation will overflow
  73 ; to 0.
  74 ; PR17532
  75
  76 ; CHECK-LABEL: i8_loop
  77 ; CHECK: icmp eq i32 {{.*}}, 256
  78 define i32 @i8_loop() nounwind readnone ssp uwtable {
  79   br label %1
  80
  81 ; <label>:1                                       ; preds = %1, %0
  82   %a.0 = phi i32 [ 1, %0 ], [ %2, %1 ]
  83   %b.0 = phi i8 [ 0, %0 ], [ %3, %1 ]
  84   %2 = and i32 %a.0, 4
  85   %3 = add i8 %b.0, -1
  86   %4 = icmp eq i8 %3, 0
  87   br i1 %4, label %5, label %1
  88
  89 ; <label>:5                                       ; preds = %1
  90   ret i32 %2
  91 }
  92
  93 ; CHECK-LABEL: i16_loop
  94 ; CHECK: icmp eq i32 {{.*}}, 65536
  95
  96 define i32 @i16_loop() nounwind readnone ssp uwtable {
  97   br label %1
  98
  99 ; <label>:1                                       ; preds = %1, %0
 100   %a.0 = phi i32 [ 1, %0 ], [ %2, %1 ]
 101   %b.0 = phi i16 [ 0, %0 ], [ %3, %1 ]
 102   %2 = and i32 %a.0, 4
 103   %3 = add i16 %b.0, -1
 104   %4 = icmp eq i16 %3, 0
 105   br i1 %4, label %5, label %1
 106
 107 ; <label>:5                                       ; preds = %1
 108   ret i32 %2
 109 }
 110
 111 ; This loop has a backedge taken count of i32_max. We need to check for this
 112 ; condition and branch directly to the scalar loop.
 113
 114 ; CHECK-LABEL: max_i32_backedgetaken
 115 ; CHECK:  br i1 true, label %scalar.ph, label %min.iters.checked
 116
 117 ; CHECK: scalar.ph:
 118 ; CHECK:  %bc.resume.val = phi i32 [ 0, %middle.block ], [ 0, %0 ]
 119 ; CHECK:  %bc.merge.rdx = phi i32 [ 1, %0 ], [ 1, %min.iters.checked ], [ %5, %middle.block ]
 120
 121 define i32 @max_i32_backedgetaken() nounwind readnone ssp uwtable {
 122
 123   br label %1
 124
 125 ; <label>:1                                       ; preds = %1, %0
 126   %a.0 = phi i32 [ 1, %0 ], [ %2, %1 ]
 127   %b.0 = phi i32 [ 0, %0 ], [ %3, %1 ]
 128   %2 = and i32 %a.0, 4
 129   %3 = add i32 %b.0, -1
 130   %4 = icmp eq i32 %3, 0
 131   br i1 %4, label %5, label %1
 132
 133 ; <label>:5                                       ; preds = %1
 134   ret i32 %2
 135 }
 136
 137 ; When generating the overflow check we must sure that the induction start value
 138 ; is defined before the branch to the scalar preheader.
 139
 140 ; CHECK-LABEL: testoverflowcheck
 141 ; CHECK: entry
 142 ; CHECK: %[[LOAD:.*]] = load i8
 143 ; CHECK: br
 144
 145 ; CHECK: scalar.ph
 146 ; CHECK: phi i8 [ %{{.*}}, %middle.block ], [ %[[LOAD]], %entry ]
 147
 148 @e = global i8 1, align 1
 149 @d = common global i32 0, align 4
 150 @c = common global i32 0, align 4
 151 define i32 @testoverflowcheck() {
 152 entry:
 153   %.pr.i = load i8, i8* @e, align 1
 154   %0 = load i32, i32* @d, align 4
 155   %c.promoted.i = load i32, i32* @c, align 4
 156   br label %cond.end.i
 157
 158 cond.end.i:
 159   %inc4.i = phi i8 [ %.pr.i, %entry ], [ %inc.i, %cond.end.i ]
 160   %and3.i = phi i32 [ %c.promoted.i, %entry ], [ %and.i, %cond.end.i ]
 161   %and.i = and i32 %0, %and3.i
 162   %inc.i = add i8 %inc4.i, 1
 163   %tobool.i = icmp eq i8 %inc.i, 0
 164   br i1 %tobool.i, label %loopexit, label %cond.end.i
 165
 166 loopexit:
 167   ret i32 %and.i
 168 }