test/Transforms/LoopDistribute/outside-use.ll

   1 ; RUN: opt -loop-distribute -verify-loop-info -verify-dom-info -S < %s \
   2 ; RUN:   | FileCheck %s
   3
   4 ; Check that definitions used outside the loop are handled correctly: (1) they
   5 ; are not dropped (2) when version the loop, a phi is added to merge the value
   6 ; from the non-distributed loop and the distributed loop.
   7 ;
   8 ;   for (i = 0; i < n; i++) {
   9 ;     A[i + 1] = A[i] * B[i];
  10 ;   ==========================
  11 ;     sum += C[i];
  12 ;   }
  13
  14 target datalayout = "e-m:o-i64:64-f80:128-n8:16:32:64-S128"
  15 target triple = "x86_64-apple-macosx10.10.0"
  16
  17 @B = common global i32* null, align 8
  18 @A = common global i32* null, align 8
  19 @C = common global i32* null, align 8
  20 @D = common global i32* null, align 8
  21 @E = common global i32* null, align 8
  22 @SUM = common global i32 0, align 8
  23
  24 define void @f() {
  25 entry:
  26   %a = load i32*, i32** @A, align 8
  27   %b = load i32*, i32** @B, align 8
  28   %c = load i32*, i32** @C, align 8
  29   %d = load i32*, i32** @D, align 8
  30   %e = load i32*, i32** @E, align 8
  31
  32   br label %for.body
  33
  34 ; CHECK: for.body.ldist1:
  35 ; CHECK:   %mulA.ldist1 = mul i32 %loadB.ldist1, %loadA.ldist1
  36 ; CHECK: for.body.ph:
  37 ; CHECK: for.body:
  38 ; CHECK:   %sum_add = add nuw nsw i32 %sum, %loadC
  39 ; CHECK: for.end:
  40 ; CHECK:   %sum_add.lver = phi i32 [ %sum_add, %for.body ], [ %sum_add.lver.orig, %for.body.lver.orig ]
  41
  42 for.body:                                         ; preds = %for.body, %entry
  43   %ind = phi i64 [ 0, %entry ], [ %add, %for.body ]
  44   %sum = phi i32 [ 0, %entry ], [ %sum_add, %for.body ]
  45
  46   %arrayidxA = getelementptr inbounds i32, i32* %a, i64 %ind
  47   %loadA = load i32, i32* %arrayidxA, align 4
  48
  49   %arrayidxB = getelementptr inbounds i32, i32* %b, i64 %ind
  50   %loadB = load i32, i32* %arrayidxB, align 4
  51
  52   %mulA = mul i32 %loadB, %loadA
  53
  54   %add = add nuw nsw i64 %ind, 1
  55   %arrayidxA_plus_4 = getelementptr inbounds i32, i32* %a, i64 %add
  56   store i32 %mulA, i32* %arrayidxA_plus_4, align 4
  57
  58   %arrayidxC = getelementptr inbounds i32, i32* %c, i64 %ind
  59   %loadC = load i32, i32* %arrayidxC, align 4
  60
  61   %sum_add = add nuw nsw i32 %sum, %loadC
  62
  63   %exitcond = icmp eq i64 %add, 20
  64   br i1 %exitcond, label %for.end, label %for.body
  65
  66 for.end:                                          ; preds = %for.body
  67   store i32 %sum_add, i32* @SUM, align 4
  68   ret void
  69 }