test/Transforms/InstSimplify/fast-math.ll

   1 ; RUN: opt < %s -instsimplify -S | FileCheck %s
   2
   3 ;; x * 0 ==> 0 when no-nans and no-signed-zero
   4 ; CHECK: mul_zero_1
   5 define float @mul_zero_1(float %a) {
   6   %b = fmul nsz nnan float %a, 0.0
   7 ; CHECK: ret float 0.0
   8   ret float %b
   9 }
  10 ; CHECK: mul_zero_2
  11 define float @mul_zero_2(float %a) {
  12   %b = fmul fast float 0.0, %a
  13 ; CHECK: ret float 0.0
  14   ret float %b
  15 }
  16
  17 ;; x * 0 =/=> 0 when there could be nans or -0
  18 ; CHECK: no_mul_zero_1
  19 define float @no_mul_zero_1(float %a) {
  20   %b = fmul nsz float %a, 0.0
  21 ; CHECK: ret float %b
  22   ret float %b
  23 }
  24 ; CHECK: no_mul_zero_2
  25 define float @no_mul_zero_2(float %a) {
  26   %b = fmul nnan float %a, 0.0
  27 ; CHECK: ret float %b
  28   ret float %b
  29 }
  30 ; CHECK: no_mul_zero_3
  31 define float @no_mul_zero_3(float %a) {
  32   %b = fmul float %a, 0.0
  33 ; CHECK: ret float %b
  34   ret float %b
  35 }
  36
  37 ; fadd [nnan ninf] X, (fsub [nnan ninf] 0, X) ==> 0
  38 ;   where nnan and ninf have to occur at least once somewhere in this
  39 ;   expression
  40 ; CHECK: fadd_fsub_0
  41 define float @fadd_fsub_0(float %a) {
  42 ; X + -X ==> 0
  43   %t1 = fsub nnan ninf float 0.0, %a
  44   %zero1 = fadd nnan ninf float %t1, %a
  45
  46   %t2 = fsub nnan float 0.0, %a
  47   %zero2 = fadd ninf float %t2, %a
  48
  49   %t3 = fsub nnan ninf float 0.0, %a
  50   %zero3 = fadd float %t3, %a
  51
  52   %t4 = fsub float 0.0, %a
  53   %zero4 = fadd nnan ninf float %t4, %a
  54
  55 ; Dont fold this
  56 ; CHECK: %nofold = fsub float 0.0
  57   %nofold = fsub float 0.0, %a
  58 ; CHECK: %no_zero = fadd nnan float %nofold, %a
  59   %no_zero = fadd nnan float %nofold, %a
  60
  61 ; Coalesce the folded zeros
  62   %zero5 = fadd float %zero1, %zero2
  63   %zero6 = fadd float %zero3, %zero4
  64   %zero7 = fadd float %zero5, %zero6
  65
  66 ; Should get folded
  67   %ret = fadd nsz float %no_zero, %zero7
  68
  69 ; CHECK: ret float %no_zero
  70   ret float %ret
  71 }
  72
  73 ; fsub nnan x, x ==> 0.0
  74 ; CHECK-LABEL: @fsub_x_x(
  75 define float @fsub_x_x(float %a) {
  76 ; X - X ==> 0
  77   %zero1 = fsub nnan float %a, %a
  78
  79 ; Dont fold
  80 ; CHECK: %no_zero1 = fsub
  81   %no_zero1 = fsub ninf float %a, %a
  82 ; CHECK: %no_zero2 = fsub
  83   %no_zero2 = fsub float %a, %a
  84 ; CHECK: %no_zero = fadd
  85   %no_zero = fadd float %no_zero1, %no_zero2
  86
  87 ; Should get folded
  88   %ret = fadd nsz float %no_zero, %zero1
  89
  90 ; CHECK: ret float %no_zero
  91   ret float %ret
  92 }
  93
  94 ; fadd nsz X, 0 ==> X
  95 ; CHECK-LABEL: @nofold_fadd_x_0(
  96 define float @nofold_fadd_x_0(float %a) {
  97 ; Dont fold
  98 ; CHECK: %no_zero1 = fadd
  99   %no_zero1 = fadd ninf float %a, 0.0
 100 ; CHECK: %no_zero2 = fadd
 101   %no_zero2 = fadd nnan float %a, 0.0
 102 ; CHECK: %no_zero = fadd
 103   %no_zero = fadd float %no_zero1, %no_zero2
 104
 105 ; CHECK: ret float %no_zero
 106   ret float %no_zero
 107 }
 108
 109 ; fdiv nsz nnan 0, X ==> 0
 110 define double @fdiv_zero_by_x(double %X) {
 111 ; CHECK-LABEL: @fdiv_zero_by_x(
 112 ; 0 / X -> 0
 113   %r = fdiv nnan nsz double 0.0, %X
 114   ret double %r
 115 ; CHECK: ret double 0
 116 }
 117
 118 define float @fdiv_self(float %f) {
 119   %div = fdiv nnan float %f, %f
 120   ret float %div
 121 ; CHECK-LABEL: fdiv_self
 122 ; CHECK: ret float 1.000000e+00
 123 }
 124
 125 define float @fdiv_self_invalid(float %f) {
 126   %div = fdiv float %f, %f
 127   ret float %div
 128 ; CHECK-LABEL: fdiv_self_invalid
 129 ; CHECK: %div = fdiv float %f, %f
 130 ; CHECK-NEXT: ret float %div
 131 }
 132
 133 define float @fdiv_neg1(float %f) {
 134   %neg = fsub fast float -0.000000e+00, %f
 135   %div = fdiv nnan float %neg, %f
 136   ret float %div
 137 ; CHECK-LABEL: fdiv_neg1
 138 ; CHECK: ret float -1.000000e+00
 139 }
 140
 141 define float @fdiv_neg2(float %f) {
 142   %neg = fsub fast float 0.000000e+00, %f
 143   %div = fdiv nnan float %neg, %f
 144   ret float %div
 145 ; CHECK-LABEL: fdiv_neg2
 146 ; CHECK: ret float -1.000000e+00
 147 }
 148
 149 define float @fdiv_neg_invalid(float %f) {
 150   %neg = fsub fast float -0.000000e+00, %f
 151   %div = fdiv float %neg, %f
 152   ret float %div
 153 ; CHECK-LABEL: fdiv_neg_invalid
 154 ; CHECK: %neg = fsub fast float -0.000000e+00, %f
 155 ; CHECK-NEXT: %div = fdiv float %neg, %f
 156 ; CHECK-NEXT: ret float %div
 157 }
 158
 159 define float @fdiv_neg_swapped1(float %f) {
 160   %neg = fsub float -0.000000e+00, %f
 161   %div = fdiv nnan float %f, %neg
 162   ret float %div
 163 ; CHECK-LABEL: fdiv_neg_swapped1
 164 ; CHECK: ret float -1.000000e+00
 165 }
 166
 167 define float @fdiv_neg_swapped2(float %f) {
 168   %neg = fsub float 0.000000e+00, %f
 169   %div = fdiv nnan float %f, %neg
 170   ret float %div
 171 ; CHECK-LABEL: fdiv_neg_swapped2
 172 ; CHECK: ret float -1.000000e+00
 173 }