test/Transforms/InstCombine/select.ll

   1 ; This test makes sure that these instructions are properly eliminated.
   2 ; PR1822
   3
   4 ; RUN: opt < %s -instcombine -S | FileCheck %s
   5
   6 define i32 @test1(i32 %A, i32 %B) {
   7         %C = select i1 false, i32 %A, i32 %B
   8         ret i32 %C
   9 ; CHECK: @test1
  10 ; CHECK: ret i32 %B
  11 }
  12
  13 define i32 @test2(i32 %A, i32 %B) {
  14         %C = select i1 true, i32 %A, i32 %B
  15         ret i32 %C
  16 ; CHECK: @test2
  17 ; CHECK: ret i32 %A
  18 }
  19
  20
  21 define i32 @test3(i1 %C, i32 %I) {
  22         ; V = I
  23         %V = select i1 %C, i32 %I, i32 %I
  24         ret i32 %V
  25 ; CHECK: @test3
  26 ; CHECK: ret i32 %I
  27 }
  28
  29 define i1 @test4(i1 %C) {
  30         ; V = C
  31         %V = select i1 %C, i1 true, i1 false
  32         ret i1 %V
  33 ; CHECK: @test4
  34 ; CHECK: ret i1 %C
  35 }
  36
  37 define i1 @test5(i1 %C) {
  38         ; V = !C
  39         %V = select i1 %C, i1 false, i1 true
  40         ret i1 %V
  41 ; CHECK: @test5
  42 ; CHECK: xor i1 %C, true
  43 ; CHECK: ret i1
  44 }
  45
  46 define i32 @test6(i1 %C) {
  47         ; V = cast C to int
  48         %V = select i1 %C, i32 1, i32 0
  49         ret i32 %V
  50 ; CHECK: @test6
  51 ; CHECK: %V = zext i1 %C to i32
  52 ; CHECK: ret i32 %V
  53 }
  54
  55 define i1 @test7(i1 %C, i1 %X) {
  56         ; R = or C, X
  57         %R = select i1 %C, i1 true, i1 %X
  58         ret i1 %R
  59 ; CHECK: @test7
  60 ; CHECK: %R = or i1 %C, %X
  61 ; CHECK: ret i1 %R
  62 }
  63
  64 define i1 @test8(i1 %C, i1 %X) {
  65         ; R = and C, X
  66         %R = select i1 %C, i1 %X, i1 false
  67         ret i1 %R
  68 ; CHECK: @test8
  69 ; CHECK: %R = and i1 %C, %X
  70 ; CHECK: ret i1 %R
  71 }
  72
  73 define i1 @test9(i1 %C, i1 %X) {
  74         ; R = and !C, X
  75         %R = select i1 %C, i1 false, i1 %X
  76         ret i1 %R
  77 ; CHECK: @test9
  78 ; CHECK: xor i1 %C, true
  79 ; CHECK: %R = and i1
  80 ; CHECK: ret i1 %R
  81 }
  82
  83 define i1 @test10(i1 %C, i1 %X) {
  84         ; R = or !C, X
  85         %R = select i1 %C, i1 %X, i1 true
  86         ret i1 %R
  87 ; CHECK: @test10
  88 ; CHECK: xor i1 %C, true
  89 ; CHECK: %R = or i1
  90 ; CHECK: ret i1 %R
  91 }
  92
  93 define i32 @test11(i32 %a) {
  94         %C = icmp eq i32 %a, 0
  95         %R = select i1 %C, i32 0, i32 1
  96         ret i32 %R
  97 ; CHECK: @test11
  98 ; CHECK: icmp ne i32 %a, 0
  99 ; CHECK: %R = zext i1
 100 ; CHECK: ret i32 %R
 101 }
 102
 103 define i32 @test12(i1 %cond, i32 %a) {
 104         %b = or i32 %a, 1
 105         %c = select i1 %cond, i32 %b, i32 %a
 106         ret i32 %c
 107 ; CHECK: @test12
 108 ; CHECK: %b = zext i1 %cond to i32
 109 ; CHECK: %c = or i32 %b, %a
 110 ; CHECK: ret i32 %c
 111 }
 112
 113 define i32 @test12a(i1 %cond, i32 %a) {
 114         %b = ashr i32 %a, 1
 115         %c = select i1 %cond, i32 %b, i32 %a
 116         ret i32 %c
 117 ; CHECK: @test12a
 118 ; CHECK: %b = zext i1 %cond to i32
 119 ; CHECK: %c = ashr i32 %a, %b
 120 ; CHECK: ret i32 %c
 121 }
 122
 123 define i32 @test12b(i1 %cond, i32 %a) {
 124         %b = ashr i32 %a, 1
 125         %c = select i1 %cond, i32 %a, i32 %b
 126         ret i32 %c
 127 ; CHECK: @test12b
 128 ; CHECK: zext i1 %cond to i32
 129 ; CHECK: %b = xor i32
 130 ; CHECK: %c = ashr i32 %a, %b
 131 ; CHECK: ret i32 %c
 132 }
 133
 134 define i32 @test13(i32 %a, i32 %b) {
 135         %C = icmp eq i32 %a, %b
 136         %V = select i1 %C, i32 %a, i32 %b
 137         ret i32 %V
 138 ; CHECK: @test13
 139 ; CHECK: ret i32 %b
 140 }
 141
 142 define i32 @test13a(i32 %a, i32 %b) {
 143         %C = icmp ne i32 %a, %b
 144         %V = select i1 %C, i32 %a, i32 %b
 145         ret i32 %V
 146 ; CHECK: @test13a
 147 ; CHECK: ret i32 %a
 148 }
 149
 150 define i32 @test13b(i32 %a, i32 %b) {
 151         %C = icmp eq i32 %a, %b
 152         %V = select i1 %C, i32 %b, i32 %a
 153         ret i32 %V
 154 ; CHECK: @test13b
 155 ; CHECK: ret i32 %a
 156 }
 157
 158 define i1 @test14a(i1 %C, i32 %X) {
 159         %V = select i1 %C, i32 %X, i32 0
 160         ; (X < 1) | !C
 161         %R = icmp slt i32 %V, 1
 162         ret i1 %R
 163 ; CHECK: @test14a
 164 ; CHECK: icmp slt i32 %X, 1
 165 ; CHECK: xor i1 %C, true
 166 ; CHECK: or i1
 167 ; CHECK: ret i1 %R
 168 }
 169
 170 define i1 @test14b(i1 %C, i32 %X) {
 171         %V = select i1 %C, i32 0, i32 %X
 172         ; (X < 1) | C
 173         %R = icmp slt i32 %V, 1
 174         ret i1 %R
 175 ; CHECK: @test14b
 176 ; CHECK: icmp slt i32 %X, 1
 177 ; CHECK: or i1
 178 ; CHECK: ret i1 %R
 179 }
 180
 181 ;; Code sequence for (X & 16) ? 16 : 0
 182 define i32 @test15a(i32 %X) {
 183         %t1 = and i32 %X, 16
 184         %t2 = icmp eq i32 %t1, 0
 185         %t3 = select i1 %t2, i32 0, i32 16
 186         ret i32 %t3
 187 ; CHECK: @test15a
 188 ; CHECK: %t1 = and i32 %X, 16
 189 ; CHECK: ret i32 %t1
 190 }
 191
 192 ;; Code sequence for (X & 32) ? 0 : 24
 193 define i32 @test15b(i32 %X) {
 194         %t1 = and i32 %X, 32
 195         %t2 = icmp eq i32 %t1, 0
 196         %t3 = select i1 %t2, i32 32, i32 0
 197         ret i32 %t3
 198 ; CHECK: @test15b
 199 ; CHECK: %t1 = and i32 %X, 32
 200 ; CHECK: xor i32 %t1, 32
 201 ; CHECK: ret i32
 202 }
 203
 204 ;; Alternate code sequence for (X & 16) ? 16 : 0
 205 define i32 @test15c(i32 %X) {
 206         %t1 = and i32 %X, 16
 207         %t2 = icmp eq i32 %t1, 16
 208         %t3 = select i1 %t2, i32 16, i32 0
 209         ret i32 %t3
 210 ; CHECK: @test15c
 211 ; CHECK: %t1 = and i32 %X, 16
 212 ; CHECK: ret i32 %t1
 213 }
 214
 215 ;; Alternate code sequence for (X & 16) ? 16 : 0
 216 define i32 @test15d(i32 %X) {
 217         %t1 = and i32 %X, 16
 218         %t2 = icmp ne i32 %t1, 0
 219         %t3 = select i1 %t2, i32 16, i32 0
 220         ret i32 %t3
 221 ; CHECK: @test15d
 222 ; CHECK: %t1 = and i32 %X, 16
 223 ; CHECK: ret i32 %t1
 224 }
 225
 226 define i32 @test16(i1 %C, i32* %P) {
 227         %P2 = select i1 %C, i32* %P, i32* null
 228         %V = load i32* %P2
 229         ret i32 %V
 230 ; CHECK: @test16
 231 ; CHECK-NEXT: %V = load i32* %P
 232 ; CHECK: ret i32 %V
 233 }
 234
 235 define i1 @test17(i32* %X, i1 %C) {
 236         %R = select i1 %C, i32* %X, i32* null
 237         %RV = icmp eq i32* %R, null
 238         ret i1 %RV
 239 ; CHECK: @test17
 240 ; CHECK: icmp eq i32* %X, null
 241 ; CHECK: xor i1 %C, true
 242 ; CHECK: %RV = or i1
 243 ; CHECK: ret i1 %RV
 244 }
 245
 246 define i32 @test18(i32 %X, i32 %Y, i1 %C) {
 247         %R = select i1 %C, i32 %X, i32 0
 248         %V = sdiv i32 %Y, %R
 249         ret i32 %V
 250 ; CHECK: @test18
 251 ; CHECK: %V = sdiv i32 %Y, %X
 252 ; CHECK: ret i32 %V
 253 }
 254
 255 define i32 @test19(i32 %x) {
 256         %tmp = icmp ugt i32 %x, 2147483647
 257         %retval = select i1 %tmp, i32 -1, i32 0
 258         ret i32 %retval
 259 ; CHECK: @test19
 260 ; CHECK-NEXT: ashr i32 %x, 31
 261 ; CHECK-NEXT: ret i32
 262 }
 263
 264 define i32 @test20(i32 %x) {
 265         %tmp = icmp slt i32 %x, 0
 266         %retval = select i1 %tmp, i32 -1, i32 0
 267         ret i32 %retval
 268 ; CHECK: @test20
 269 ; CHECK-NEXT: ashr i32 %x, 31
 270 ; CHECK-NEXT: ret i32
 271 }
 272
 273 define i64 @test21(i32 %x) {
 274         %tmp = icmp slt i32 %x, 0
 275         %retval = select i1 %tmp, i64 -1, i64 0
 276         ret i64 %retval
 277 ; CHECK: @test21
 278 ; CHECK-NEXT: ashr i32 %x, 31
 279 ; CHECK-NEXT: sext i32
 280 ; CHECK-NEXT: ret i64
 281 }
 282
 283 define i16 @test22(i32 %x) {
 284         %tmp = icmp slt i32 %x, 0
 285         %retval = select i1 %tmp, i16 -1, i16 0
 286         ret i16 %retval
 287 ; CHECK: @test22
 288 ; CHECK-NEXT: ashr i32 %x, 31
 289 ; CHECK-NEXT: trunc i32
 290 ; CHECK-NEXT: ret i16
 291 }
 292
 293 define i1 @test23(i1 %a, i1 %b) {
 294         %c = select i1 %a, i1 %b, i1 %a
 295         ret i1 %c
 296 ; CHECK: @test23
 297 ; CHECK-NEXT: %c = and i1 %a, %b
 298 ; CHECK-NEXT: ret i1 %c
 299 }
 300
 301 define i1 @test24(i1 %a, i1 %b) {
 302         %c = select i1 %a, i1 %a, i1 %b
 303         ret i1 %c
 304 ; CHECK: @test24
 305 ; CHECK-NEXT: %c = or i1 %a, %b
 306 ; CHECK-NEXT: ret i1 %c
 307 }
 308
 309 define i32 @test25(i1 %c)  {
 310 entry:
 311   br i1 %c, label %jump, label %ret
 312 jump:
 313   br label %ret
 314 ret:
 315   %a = phi i1 [true, %jump], [false, %entry]
 316   %b = select i1 %a, i32 10, i32 20
 317   ret i32 %b
 318 ; CHECK: @test25
 319 ; CHECK: %a = phi i32 [ 10, %jump ], [ 20, %entry ]
 320 ; CHECK-NEXT: ret i32 %a
 321 }
 322
 323 define i32 @test26(i1 %cond)  {
 324 entry:
 325   br i1 %cond, label %jump, label %ret
 326 jump:
 327   %c = or i1 false, false
 328   br label %ret
 329 ret:
 330   %a = phi i1 [true, %jump], [%c, %entry]
 331   %b = select i1 %a, i32 10, i32 20
 332   ret i32 %b
 333 ; CHECK: @test26
 334 ; CHECK: %a = phi i32 [ 10, %jump ], [ 20, %entry ]
 335 ; CHECK-NEXT: ret i32 %a
 336 }
 337
 338 define i32 @test27(i1 %c, i32 %A, i32 %B)  {
 339 entry:
 340   br i1 %c, label %jump, label %ret
 341 jump:
 342   br label %ret
 343 ret:
 344   %a = phi i1 [true, %jump], [false, %entry]
 345   %b = select i1 %a, i32 %A, i32 %B
 346   ret i32 %b
 347 ; CHECK: @test27
 348 ; CHECK: %a = phi i32 [ %A, %jump ], [ %B, %entry ]
 349 ; CHECK-NEXT: ret i32 %a
 350 }
 351
 352 define i32 @test28(i1 %cond, i32 %A, i32 %B)  {
 353 entry:
 354   br i1 %cond, label %jump, label %ret
 355 jump:
 356   br label %ret
 357 ret:
 358   %c = phi i32 [%A, %jump], [%B, %entry]
 359   %a = phi i1 [true, %jump], [false, %entry]
 360   %b = select i1 %a, i32 %A, i32 %c
 361   ret i32 %b
 362 ; CHECK: @test28
 363 ; CHECK: %a = phi i32 [ %A, %jump ], [ %B, %entry ]
 364 ; CHECK-NEXT: ret i32 %a
 365 }
 366
 367 define i32 @test29(i1 %cond, i32 %A, i32 %B)  {
 368 entry:
 369   br i1 %cond, label %jump, label %ret
 370 jump:
 371   br label %ret
 372 ret:
 373   %c = phi i32 [%A, %jump], [%B, %entry]
 374   %a = phi i1 [true, %jump], [false, %entry]
 375   br label %next
 376
 377 next:
 378   %b = select i1 %a, i32 %A, i32 %c
 379   ret i32 %b
 380 ; CHECK: @test29
 381 ; CHECK: %a = phi i32 [ %A, %jump ], [ %B, %entry ]
 382 ; CHECK: ret i32 %a
 383 }
 384
 385
 386 ; SMAX(SMAX(x, y), x) -> SMAX(x, y)
 387 define i32 @test30(i32 %x, i32 %y) {
 388   %cmp = icmp sgt i32 %x, %y
 389   %cond = select i1 %cmp, i32 %x, i32 %y
 390
 391   %cmp5 = icmp sgt i32 %cond, %x
 392   %retval = select i1 %cmp5, i32 %cond, i32 %x
 393   ret i32 %retval
 394 ; CHECK: @test30
 395 ; CHECK: ret i32 %cond
 396 }
 397
 398 ; UMAX(UMAX(x, y), x) -> UMAX(x, y)
 399 define i32 @test31(i32 %x, i32 %y) {
 400   %cmp = icmp ugt i32 %x, %y
 401   %cond = select i1 %cmp, i32 %x, i32 %y
 402   %cmp5 = icmp ugt i32 %cond, %x
 403   %retval = select i1 %cmp5, i32 %cond, i32 %x
 404   ret i32 %retval
 405 ; CHECK: @test31
 406 ; CHECK: ret i32 %cond
 407 }
 408
 409 ; SMIN(SMIN(x, y), x) -> SMIN(x, y)
 410 define i32 @test32(i32 %x, i32 %y) {
 411   %cmp = icmp sgt i32 %x, %y
 412   %cond = select i1 %cmp, i32 %y, i32 %x
 413   %cmp5 = icmp sgt i32 %cond, %x
 414   %retval = select i1 %cmp5, i32 %x, i32 %cond
 415   ret i32 %retval
 416 ; CHECK: @test32
 417 ; CHECK: ret i32 %cond
 418 }
 419
 420 ; MAX(MIN(x, y), x) -> x
 421 define i32 @test33(i32 %x, i32 %y) {
 422   %cmp = icmp sgt i32 %x, %y
 423   %cond = select i1 %cmp, i32 %y, i32 %x
 424   %cmp5 = icmp sgt i32 %cond, %x
 425   %retval = select i1 %cmp5, i32 %cond, i32 %x
 426   ret i32 %retval
 427 ; CHECK: @test33
 428 ; CHECK: ret i32 %x
 429 }
 430
 431 ; MIN(MAX(x, y), x) -> x
 432 define i32 @test34(i32 %x, i32 %y) {
 433   %cmp = icmp sgt i32 %x, %y
 434   %cond = select i1 %cmp, i32 %x, i32 %y
 435   %cmp5 = icmp sgt i32 %cond, %x
 436   %retval = select i1 %cmp5, i32 %x, i32 %cond
 437   ret i32 %retval
 438 ; CHECK: @test34
 439 ; CHECK: ret i32 %x
 440 }
 441
 442 define i32 @test35(i32 %x) {
 443   %cmp = icmp sge i32 %x, 0
 444   %cond = select i1 %cmp, i32 60, i32 100
 445   ret i32 %cond
 446 ; CHECK: @test35
 447 ; CHECK: ashr i32 %x, 31
 448 ; CHECK: and i32 {{.*}}, 40
 449 ; CHECK: add i32 {{.*}}, 60
 450 ; CHECK: ret
 451 }
 452
 453 define i32 @test36(i32 %x) {
 454   %cmp = icmp slt i32 %x, 0
 455   %cond = select i1 %cmp, i32 60, i32 100
 456   ret i32 %cond
 457 ; CHECK: @test36
 458 ; CHECK: ashr i32 %x, 31
 459 ; CHECK: and i32 {{.*}}, -40
 460 ; CHECK: add i32 {{.*}}, 100
 461 ; CHECK: ret
 462 }
 463
 464 define i32 @test37(i32 %x) {
 465   %cmp = icmp sgt i32 %x, -1
 466   %cond = select i1 %cmp, i32 1, i32 -1
 467   ret i32 %cond
 468 ; CHECK: @test37
 469 ; CHECK: ashr i32 %x, 31
 470 ; CHECK: or i32 {{.*}}, 1
 471 ; CHECK: ret
 472 }
 473
 474 define i1 @test38(i1 %cond) {
 475   %zero = alloca i32
 476   %one = alloca i32
 477   %ptr = select i1 %cond, i32* %zero, i32* %one
 478   %isnull = icmp eq i32* %ptr, null
 479   ret i1 %isnull
 480 ; CHECK: @test38
 481 ; CHECK: ret i1 false
 482 }
 483
 484 define i1 @test39(i1 %cond, double %x) {
 485   %s = select i1 %cond, double %x, double 0x7FF0000000000000 ; RHS = +infty
 486   %cmp = fcmp ule double %x, %s
 487   ret i1 %cmp
 488 ; CHECK: @test39
 489 ; CHECK: ret i1 true
 490 }