test/Transforms/InstCombine/select.ll

   1 ; This test makes sure that these instructions are properly eliminated.
   2 ; PR1822
   3
   4 ; RUN: opt < %s -instcombine -S | FileCheck %s
   5
   6 define i32 @test1(i32 %A, i32 %B) {
   7         %C = select i1 false, i32 %A, i32 %B
   8         ret i32 %C
   9 ; CHECK: @test1
  10 ; CHECK: ret i32 %B
  11 }
  12
  13 define i32 @test2(i32 %A, i32 %B) {
  14         %C = select i1 true, i32 %A, i32 %B
  15         ret i32 %C
  16 ; CHECK: @test2
  17 ; CHECK: ret i32 %A
  18 }
  19
  20
  21 define i32 @test3(i1 %C, i32 %I) {
  22         ; V = I
  23         %V = select i1 %C, i32 %I, i32 %I
  24         ret i32 %V
  25 ; CHECK: @test3
  26 ; CHECK: ret i32 %I
  27 }
  28
  29 define i1 @test4(i1 %C) {
  30         ; V = C
  31         %V = select i1 %C, i1 true, i1 false
  32         ret i1 %V
  33 ; CHECK: @test4
  34 ; CHECK: ret i1 %C
  35 }
  36
  37 define i1 @test5(i1 %C) {
  38         ; V = !C
  39         %V = select i1 %C, i1 false, i1 true
  40         ret i1 %V
  41 ; CHECK: @test5
  42 ; CHECK: xor i1 %C, true
  43 ; CHECK: ret i1
  44 }
  45
  46 define i32 @test6(i1 %C) {
  47         ; V = cast C to int
  48         %V = select i1 %C, i32 1, i32 0
  49         ret i32 %V
  50 ; CHECK: @test6
  51 ; CHECK: %V = zext i1 %C to i32
  52 ; CHECK: ret i32 %V
  53 }
  54
  55 define i1 @test7(i1 %C, i1 %X) {
  56         ; R = or C, X
  57         %R = select i1 %C, i1 true, i1 %X
  58         ret i1 %R
  59 ; CHECK: @test7
  60 ; CHECK: %R = or i1 %C, %X
  61 ; CHECK: ret i1 %R
  62 }
  63
  64 define i1 @test8(i1 %C, i1 %X) {
  65         ; R = and C, X
  66         %R = select i1 %C, i1 %X, i1 false
  67         ret i1 %R
  68 ; CHECK: @test8
  69 ; CHECK: %R = and i1 %C, %X
  70 ; CHECK: ret i1 %R
  71 }
  72
  73 define i1 @test9(i1 %C, i1 %X) {
  74         ; R = and !C, X
  75         %R = select i1 %C, i1 false, i1 %X
  76         ret i1 %R
  77 ; CHECK: @test9
  78 ; CHECK: xor i1 %C, true
  79 ; CHECK: %R = and i1
  80 ; CHECK: ret i1 %R
  81 }
  82
  83 define i1 @test10(i1 %C, i1 %X) {
  84         ; R = or !C, X
  85         %R = select i1 %C, i1 %X, i1 true
  86         ret i1 %R
  87 ; CHECK: @test10
  88 ; CHECK: xor i1 %C, true
  89 ; CHECK: %R = or i1
  90 ; CHECK: ret i1 %R
  91 }
  92
  93 define i32 @test11(i32 %a) {
  94         %C = icmp eq i32 %a, 0
  95         %R = select i1 %C, i32 0, i32 1
  96         ret i32 %R
  97 ; CHECK: @test11
  98 ; CHECK: icmp ne i32 %a, 0
  99 ; CHECK: %R = zext i1
 100 ; CHECK: ret i32 %R
 101 }
 102
 103 define i32 @test12(i1 %cond, i32 %a) {
 104         %b = or i32 %a, 1
 105         %c = select i1 %cond, i32 %b, i32 %a
 106         ret i32 %c
 107 ; CHECK: @test12
 108 ; CHECK: %b = zext i1 %cond to i32
 109 ; CHECK: %c = or i32 %b, %a
 110 ; CHECK: ret i32 %c
 111 }
 112
 113 define i32 @test12a(i1 %cond, i32 %a) {
 114         %b = ashr i32 %a, 1
 115         %c = select i1 %cond, i32 %b, i32 %a
 116         ret i32 %c
 117 ; CHECK: @test12a
 118 ; CHECK: %b = zext i1 %cond to i32
 119 ; CHECK: %c = ashr i32 %a, %b
 120 ; CHECK: ret i32 %c
 121 }
 122
 123 define i32 @test12b(i1 %cond, i32 %a) {
 124         %b = ashr i32 %a, 1
 125         %c = select i1 %cond, i32 %a, i32 %b
 126         ret i32 %c
 127 ; CHECK: @test12b
 128 ; CHECK: zext i1 %cond to i32
 129 ; CHECK: %b = xor i32
 130 ; CHECK: %c = ashr i32 %a, %b
 131 ; CHECK: ret i32 %c
 132 }
 133
 134 define i32 @test13(i32 %a, i32 %b) {
 135         %C = icmp eq i32 %a, %b
 136         %V = select i1 %C, i32 %a, i32 %b
 137         ret i32 %V
 138 ; CHECK: @test13
 139 ; CHECK: ret i32 %b
 140 }
 141
 142 define i32 @test13a(i32 %a, i32 %b) {
 143         %C = icmp ne i32 %a, %b
 144         %V = select i1 %C, i32 %a, i32 %b
 145         ret i32 %V
 146 ; CHECK: @test13a
 147 ; CHECK: ret i32 %a
 148 }
 149
 150 define i32 @test13b(i32 %a, i32 %b) {
 151         %C = icmp eq i32 %a, %b
 152         %V = select i1 %C, i32 %b, i32 %a
 153         ret i32 %V
 154 ; CHECK: @test13b
 155 ; CHECK: ret i32 %a
 156 }
 157
 158 define i1 @test14a(i1 %C, i32 %X) {
 159         %V = select i1 %C, i32 %X, i32 0
 160         ; (X < 1) | !C
 161         %R = icmp slt i32 %V, 1
 162         ret i1 %R
 163 ; CHECK: @test14a
 164 ; CHECK: icmp slt i32 %X, 1
 165 ; CHECK: xor i1 %C, true
 166 ; CHECK: or i1
 167 ; CHECK: ret i1 %R
 168 }
 169
 170 define i1 @test14b(i1 %C, i32 %X) {
 171         %V = select i1 %C, i32 0, i32 %X
 172         ; (X < 1) | C
 173         %R = icmp slt i32 %V, 1
 174         ret i1 %R
 175 ; CHECK: @test14b
 176 ; CHECK: icmp slt i32 %X, 1
 177 ; CHECK: or i1
 178 ; CHECK: ret i1 %R
 179 }
 180
 181 ;; Code sequence for (X & 16) ? 16 : 0
 182 define i32 @test15a(i32 %X) {
 183         %t1 = and i32 %X, 16
 184         %t2 = icmp eq i32 %t1, 0
 185         %t3 = select i1 %t2, i32 0, i32 16
 186         ret i32 %t3
 187 ; CHECK: @test15a
 188 ; CHECK: %t1 = and i32 %X, 16
 189 ; CHECK: ret i32 %t1
 190 }
 191
 192 ;; Code sequence for (X & 32) ? 0 : 24
 193 define i32 @test15b(i32 %X) {
 194         %t1 = and i32 %X, 32
 195         %t2 = icmp eq i32 %t1, 0
 196         %t3 = select i1 %t2, i32 32, i32 0
 197         ret i32 %t3
 198 ; CHECK: @test15b
 199 ; CHECK: %t1 = and i32 %X, 32
 200 ; CHECK: xor i32 %t1, 32
 201 ; CHECK: ret i32
 202 }
 203
 204 ;; Alternate code sequence for (X & 16) ? 16 : 0
 205 define i32 @test15c(i32 %X) {
 206         %t1 = and i32 %X, 16
 207         %t2 = icmp eq i32 %t1, 16
 208         %t3 = select i1 %t2, i32 16, i32 0
 209         ret i32 %t3
 210 ; CHECK: @test15c
 211 ; CHECK: %t1 = and i32 %X, 16
 212 ; CHECK: ret i32 %t1
 213 }
 214
 215 ;; Alternate code sequence for (X & 16) ? 16 : 0
 216 define i32 @test15d(i32 %X) {
 217         %t1 = and i32 %X, 16
 218         %t2 = icmp ne i32 %t1, 0
 219         %t3 = select i1 %t2, i32 16, i32 0
 220         ret i32 %t3
 221 ; CHECK: @test15d
 222 ; CHECK: %t1 = and i32 %X, 16
 223 ; CHECK: ret i32 %t1
 224 }
 225
 226 ;; (a & 128) ? 256 : 0
 227 define i32 @test15e(i32 %X) {
 228         %t1 = and i32 %X, 128
 229         %t2 = icmp ne i32 %t1, 0
 230         %t3 = select i1 %t2, i32 256, i32 0
 231         ret i32 %t3
 232 ; CHECK: @test15e
 233 ; CHECK: %t1 = shl i32 %X, 1
 234 ; CHECK: and i32 %t1, 256
 235 ; CHECK: ret i32
 236 }
 237
 238 ;; (a & 128) ? 0 : 256
 239 define i32 @test15f(i32 %X) {
 240         %t1 = and i32 %X, 128
 241         %t2 = icmp ne i32 %t1, 0
 242         %t3 = select i1 %t2, i32 0, i32 256
 243         ret i32 %t3
 244 ; CHECK: @test15f
 245 ; CHECK: %t1 = shl i32 %X, 1
 246 ; CHECK: and i32 %t1, 256
 247 ; CHECK: xor i32 %{{.*}}, 256
 248 ; CHECK: ret i32
 249 }
 250
 251 define i32 @test16(i1 %C, i32* %P) {
 252         %P2 = select i1 %C, i32* %P, i32* null
 253         %V = load i32* %P2
 254         ret i32 %V
 255 ; CHECK: @test16
 256 ; CHECK-NEXT: %V = load i32* %P
 257 ; CHECK: ret i32 %V
 258 }
 259
 260 define i1 @test17(i32* %X, i1 %C) {
 261         %R = select i1 %C, i32* %X, i32* null
 262         %RV = icmp eq i32* %R, null
 263         ret i1 %RV
 264 ; CHECK: @test17
 265 ; CHECK: icmp eq i32* %X, null
 266 ; CHECK: xor i1 %C, true
 267 ; CHECK: %RV = or i1
 268 ; CHECK: ret i1 %RV
 269 }
 270
 271 define i32 @test18(i32 %X, i32 %Y, i1 %C) {
 272         %R = select i1 %C, i32 %X, i32 0
 273         %V = sdiv i32 %Y, %R
 274         ret i32 %V
 275 ; CHECK: @test18
 276 ; CHECK: %V = sdiv i32 %Y, %X
 277 ; CHECK: ret i32 %V
 278 }
 279
 280 define i32 @test19(i32 %x) {
 281         %tmp = icmp ugt i32 %x, 2147483647
 282         %retval = select i1 %tmp, i32 -1, i32 0
 283         ret i32 %retval
 284 ; CHECK: @test19
 285 ; CHECK-NEXT: ashr i32 %x, 31
 286 ; CHECK-NEXT: ret i32
 287 }
 288
 289 define i32 @test20(i32 %x) {
 290         %tmp = icmp slt i32 %x, 0
 291         %retval = select i1 %tmp, i32 -1, i32 0
 292         ret i32 %retval
 293 ; CHECK: @test20
 294 ; CHECK-NEXT: ashr i32 %x, 31
 295 ; CHECK-NEXT: ret i32
 296 }
 297
 298 define i64 @test21(i32 %x) {
 299         %tmp = icmp slt i32 %x, 0
 300         %retval = select i1 %tmp, i64 -1, i64 0
 301         ret i64 %retval
 302 ; CHECK: @test21
 303 ; CHECK-NEXT: ashr i32 %x, 31
 304 ; CHECK-NEXT: sext i32
 305 ; CHECK-NEXT: ret i64
 306 }
 307
 308 define i16 @test22(i32 %x) {
 309         %tmp = icmp slt i32 %x, 0
 310         %retval = select i1 %tmp, i16 -1, i16 0
 311         ret i16 %retval
 312 ; CHECK: @test22
 313 ; CHECK-NEXT: ashr i32 %x, 31
 314 ; CHECK-NEXT: trunc i32
 315 ; CHECK-NEXT: ret i16
 316 }
 317
 318 define i1 @test23(i1 %a, i1 %b) {
 319         %c = select i1 %a, i1 %b, i1 %a
 320         ret i1 %c
 321 ; CHECK: @test23
 322 ; CHECK-NEXT: %c = and i1 %a, %b
 323 ; CHECK-NEXT: ret i1 %c
 324 }
 325
 326 define i1 @test24(i1 %a, i1 %b) {
 327         %c = select i1 %a, i1 %a, i1 %b
 328         ret i1 %c
 329 ; CHECK: @test24
 330 ; CHECK-NEXT: %c = or i1 %a, %b
 331 ; CHECK-NEXT: ret i1 %c
 332 }
 333
 334 define i32 @test25(i1 %c)  {
 335 entry:
 336   br i1 %c, label %jump, label %ret
 337 jump:
 338   br label %ret
 339 ret:
 340   %a = phi i1 [true, %jump], [false, %entry]
 341   %b = select i1 %a, i32 10, i32 20
 342   ret i32 %b
 343 ; CHECK: @test25
 344 ; CHECK: %a = phi i32 [ 10, %jump ], [ 20, %entry ]
 345 ; CHECK-NEXT: ret i32 %a
 346 }
 347
 348 define i32 @test26(i1 %cond)  {
 349 entry:
 350   br i1 %cond, label %jump, label %ret
 351 jump:
 352   %c = or i1 false, false
 353   br label %ret
 354 ret:
 355   %a = phi i1 [true, %jump], [%c, %entry]
 356   %b = select i1 %a, i32 10, i32 20
 357   ret i32 %b
 358 ; CHECK: @test26
 359 ; CHECK: %a = phi i32 [ 10, %jump ], [ 20, %entry ]
 360 ; CHECK-NEXT: ret i32 %a
 361 }
 362
 363 define i32 @test27(i1 %c, i32 %A, i32 %B)  {
 364 entry:
 365   br i1 %c, label %jump, label %ret
 366 jump:
 367   br label %ret
 368 ret:
 369   %a = phi i1 [true, %jump], [false, %entry]
 370   %b = select i1 %a, i32 %A, i32 %B
 371   ret i32 %b
 372 ; CHECK: @test27
 373 ; CHECK: %a = phi i32 [ %A, %jump ], [ %B, %entry ]
 374 ; CHECK-NEXT: ret i32 %a
 375 }
 376
 377 define i32 @test28(i1 %cond, i32 %A, i32 %B)  {
 378 entry:
 379   br i1 %cond, label %jump, label %ret
 380 jump:
 381   br label %ret
 382 ret:
 383   %c = phi i32 [%A, %jump], [%B, %entry]
 384   %a = phi i1 [true, %jump], [false, %entry]
 385   %b = select i1 %a, i32 %A, i32 %c
 386   ret i32 %b
 387 ; CHECK: @test28
 388 ; CHECK: %a = phi i32 [ %A, %jump ], [ %B, %entry ]
 389 ; CHECK-NEXT: ret i32 %a
 390 }
 391
 392 define i32 @test29(i1 %cond, i32 %A, i32 %B)  {
 393 entry:
 394   br i1 %cond, label %jump, label %ret
 395 jump:
 396   br label %ret
 397 ret:
 398   %c = phi i32 [%A, %jump], [%B, %entry]
 399   %a = phi i1 [true, %jump], [false, %entry]
 400   br label %next
 401
 402 next:
 403   %b = select i1 %a, i32 %A, i32 %c
 404   ret i32 %b
 405 ; CHECK: @test29
 406 ; CHECK: %a = phi i32 [ %A, %jump ], [ %B, %entry ]
 407 ; CHECK: ret i32 %a
 408 }
 409
 410
 411 ; SMAX(SMAX(x, y), x) -> SMAX(x, y)
 412 define i32 @test30(i32 %x, i32 %y) {
 413   %cmp = icmp sgt i32 %x, %y
 414   %cond = select i1 %cmp, i32 %x, i32 %y
 415
 416   %cmp5 = icmp sgt i32 %cond, %x
 417   %retval = select i1 %cmp5, i32 %cond, i32 %x
 418   ret i32 %retval
 419 ; CHECK: @test30
 420 ; CHECK: ret i32 %cond
 421 }
 422
 423 ; UMAX(UMAX(x, y), x) -> UMAX(x, y)
 424 define i32 @test31(i32 %x, i32 %y) {
 425   %cmp = icmp ugt i32 %x, %y
 426   %cond = select i1 %cmp, i32 %x, i32 %y
 427   %cmp5 = icmp ugt i32 %cond, %x
 428   %retval = select i1 %cmp5, i32 %cond, i32 %x
 429   ret i32 %retval
 430 ; CHECK: @test31
 431 ; CHECK: ret i32 %cond
 432 }
 433
 434 ; SMIN(SMIN(x, y), x) -> SMIN(x, y)
 435 define i32 @test32(i32 %x, i32 %y) {
 436   %cmp = icmp sgt i32 %x, %y
 437   %cond = select i1 %cmp, i32 %y, i32 %x
 438   %cmp5 = icmp sgt i32 %cond, %x
 439   %retval = select i1 %cmp5, i32 %x, i32 %cond
 440   ret i32 %retval
 441 ; CHECK: @test32
 442 ; CHECK: ret i32 %cond
 443 }
 444
 445 ; MAX(MIN(x, y), x) -> x
 446 define i32 @test33(i32 %x, i32 %y) {
 447   %cmp = icmp sgt i32 %x, %y
 448   %cond = select i1 %cmp, i32 %y, i32 %x
 449   %cmp5 = icmp sgt i32 %cond, %x
 450   %retval = select i1 %cmp5, i32 %cond, i32 %x
 451   ret i32 %retval
 452 ; CHECK: @test33
 453 ; CHECK: ret i32 %x
 454 }
 455
 456 ; MIN(MAX(x, y), x) -> x
 457 define i32 @test34(i32 %x, i32 %y) {
 458   %cmp = icmp sgt i32 %x, %y
 459   %cond = select i1 %cmp, i32 %x, i32 %y
 460   %cmp5 = icmp sgt i32 %cond, %x
 461   %retval = select i1 %cmp5, i32 %x, i32 %cond
 462   ret i32 %retval
 463 ; CHECK: @test34
 464 ; CHECK: ret i32 %x
 465 }
 466
 467 define i32 @test35(i32 %x) {
 468   %cmp = icmp sge i32 %x, 0
 469   %cond = select i1 %cmp, i32 60, i32 100
 470   ret i32 %cond
 471 ; CHECK: @test35
 472 ; CHECK: ashr i32 %x, 31
 473 ; CHECK: and i32 {{.*}}, 40
 474 ; CHECK: add i32 {{.*}}, 60
 475 ; CHECK: ret
 476 }
 477
 478 define i32 @test36(i32 %x) {
 479   %cmp = icmp slt i32 %x, 0
 480   %cond = select i1 %cmp, i32 60, i32 100
 481   ret i32 %cond
 482 ; CHECK: @test36
 483 ; CHECK: ashr i32 %x, 31
 484 ; CHECK: and i32 {{.*}}, -40
 485 ; CHECK: add i32 {{.*}}, 100
 486 ; CHECK: ret
 487 }
 488
 489 define i32 @test37(i32 %x) {
 490   %cmp = icmp sgt i32 %x, -1
 491   %cond = select i1 %cmp, i32 1, i32 -1
 492   ret i32 %cond
 493 ; CHECK: @test37
 494 ; CHECK: ashr i32 %x, 31
 495 ; CHECK: or i32 {{.*}}, 1
 496 ; CHECK: ret
 497 }
 498
 499 define i1 @test38(i1 %cond) {
 500   %zero = alloca i32
 501   %one = alloca i32
 502   %ptr = select i1 %cond, i32* %zero, i32* %one
 503   %isnull = icmp eq i32* %ptr, null
 504   ret i1 %isnull
 505 ; CHECK: @test38
 506 ; CHECK: ret i1 false
 507 }
 508
 509 define i1 @test39(i1 %cond, double %x) {
 510   %s = select i1 %cond, double %x, double 0x7FF0000000000000 ; RHS = +infty
 511   %cmp = fcmp ule double %x, %s
 512   ret i1 %cmp
 513 ; CHECK: @test39
 514 ; CHECK: ret i1 true
 515 }
 516
 517 define i1 @test40(i1 %cond) {
 518   %a = alloca i32
 519   %b = alloca i32
 520   %c = alloca i32
 521   %s = select i1 %cond, i32* %a, i32* %b
 522   %r = icmp eq i32* %s, %c
 523   ret i1 %r
 524 ; CHECK: @test40
 525 ; CHECK: ret i1 false
 526 }
 527
 528 define i32 @test41(i1 %cond, i32 %x, i32 %y) {
 529   %z = and i32 %x, %y
 530   %s = select i1 %cond, i32 %y, i32 %z
 531   %r = and i32 %x, %s
 532   ret i32 %r
 533 ; CHECK: @test41
 534 ; CHECK: %r = and i32 %x, %y
 535 ; CHECK: ret i32 %r
 536 }