test/Transforms/InstCombine/bitcast.ll

   1 ; RUN: opt < %s -instcombine -S | FileCheck %s
   2
   3 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64"
   4 target triple = "x86_64-apple-darwin10.0.0"
   5
   6 ; Bitcasts between vectors and scalars are valid.
   7 ; PR4487
   8 define i32 @test1(i64 %a) {
   9         %t1 = bitcast i64 %a to <2 x i32>
  10         %t2 = bitcast i64 %a to <2 x i32>
  11         %t3 = xor <2 x i32> %t1, %t2
  12         %t4 = extractelement <2 x i32> %t3, i32 0
  13         ret i32 %t4
  14
  15 ; CHECK-LABEL: @test1(
  16 ; CHECK: ret i32 0
  17 }
  18
  19 ; Optimize bitcasts that are extracting low element of vector.  This happens
  20 ; because of SRoA.
  21 ; rdar://7892780
  22 define float @test2(<2 x float> %A, <2 x i32> %B) {
  23   %tmp28 = bitcast <2 x float> %A to i64  ; <i64> [#uses=2]
  24   %tmp23 = trunc i64 %tmp28 to i32                ; <i32> [#uses=1]
  25   %tmp24 = bitcast i32 %tmp23 to float            ; <float> [#uses=1]
  26
  27   %tmp = bitcast <2 x i32> %B to i64
  28   %tmp2 = trunc i64 %tmp to i32                ; <i32> [#uses=1]
  29   %tmp4 = bitcast i32 %tmp2 to float            ; <float> [#uses=1]
  30
  31   %add = fadd float %tmp24, %tmp4
  32   ret float %add
  33
  34 ; CHECK-LABEL: @test2(
  35 ; CHECK-NEXT:  %tmp24 = extractelement <2 x float> %A, i32 0
  36 ; CHECK-NEXT:  bitcast <2 x i32> %B to <2 x float>
  37 ; CHECK-NEXT:  %tmp4 = extractelement <2 x float> {{.*}}, i32 0
  38 ; CHECK-NEXT:  %add = fadd float %tmp24, %tmp4
  39 ; CHECK-NEXT:  ret float %add
  40 }
  41
  42 ; Optimize bitcasts that are extracting other elements of a vector.  This
  43 ; happens because of SRoA.
  44 ; rdar://7892780
  45 define float @test3(<2 x float> %A, <2 x i64> %B) {
  46   %tmp28 = bitcast <2 x float> %A to i64
  47   %tmp29 = lshr i64 %tmp28, 32
  48   %tmp23 = trunc i64 %tmp29 to i32
  49   %tmp24 = bitcast i32 %tmp23 to float
  50
  51   %tmp = bitcast <2 x i64> %B to i128
  52   %tmp1 = lshr i128 %tmp, 64
  53   %tmp2 = trunc i128 %tmp1 to i32
  54   %tmp4 = bitcast i32 %tmp2 to float
  55
  56   %add = fadd float %tmp24, %tmp4
  57   ret float %add
  58
  59 ; CHECK-LABEL: @test3(
  60 ; CHECK-NEXT:  %tmp24 = extractelement <2 x float> %A, i32 1
  61 ; CHECK-NEXT:  bitcast <2 x i64> %B to <4 x float>
  62 ; CHECK-NEXT:  %tmp4 = extractelement <4 x float> {{.*}}, i32 2
  63 ; CHECK-NEXT:  %add = fadd float %tmp24, %tmp4
  64 ; CHECK-NEXT:  ret float %add
  65 }
  66
  67 ; Both bitcasts are unnecessary; change the extractelement.
  68
  69 define float @bitcast_extelt1(<2 x float> %A) {
  70   %bc1 = bitcast <2 x float> %A to <2 x i32>
  71   %ext = extractelement <2 x i32> %bc1, i32 0
  72   %bc2 = bitcast i32 %ext to float
  73   ret float %bc2
  74
  75 ; CHECK-LABEL: @bitcast_extelt1(
  76 ; CHECK-NEXT:  %bc2 = extractelement <2 x float> %A, i32 0
  77 ; CHECK-NEXT:  ret float %bc2
  78 }
  79
  80 ; Second bitcast can be folded into the first.
  81
  82 define i64 @bitcast_extelt2(<4 x float> %A) {
  83   %bc1 = bitcast <4 x float> %A to <2 x double>
  84   %ext = extractelement <2 x double> %bc1, i32 1
  85   %bc2 = bitcast double %ext to i64
  86   ret i64 %bc2
  87
  88 ; CHECK-LABEL: @bitcast_extelt2(
  89 ; CHECK-NEXT:  %bc = bitcast <4 x float> %A to <2 x i64>
  90 ; CHECK-NEXT:  %bc2 = extractelement <2 x i64> %bc, i32 1
  91 ; CHECK-NEXT:  ret i64 %bc2
  92 }
  93
  94 define <2 x i32> @test4(i32 %A, i32 %B){
  95   %tmp38 = zext i32 %A to i64
  96   %tmp32 = zext i32 %B to i64
  97   %tmp33 = shl i64 %tmp32, 32
  98   %ins35 = or i64 %tmp33, %tmp38
  99   %tmp43 = bitcast i64 %ins35 to <2 x i32>
 100   ret <2 x i32> %tmp43
 101   ; CHECK-LABEL: @test4(
 102   ; CHECK-NEXT: insertelement <2 x i32> undef, i32 %A, i32 0
 103   ; CHECK-NEXT: insertelement <2 x i32> {{.*}}, i32 %B, i32 1
 104   ; CHECK-NEXT: ret <2 x i32>
 105
 106 }
 107
 108 ; rdar://8360454
 109 define <2 x float> @test5(float %A, float %B) {
 110   %tmp37 = bitcast float %A to i32
 111   %tmp38 = zext i32 %tmp37 to i64
 112   %tmp31 = bitcast float %B to i32
 113   %tmp32 = zext i32 %tmp31 to i64
 114   %tmp33 = shl i64 %tmp32, 32
 115   %ins35 = or i64 %tmp33, %tmp38
 116   %tmp43 = bitcast i64 %ins35 to <2 x float>
 117   ret <2 x float> %tmp43
 118   ; CHECK-LABEL: @test5(
 119   ; CHECK-NEXT: insertelement <2 x float> undef, float %A, i32 0
 120   ; CHECK-NEXT: insertelement <2 x float> {{.*}}, float %B, i32 1
 121   ; CHECK-NEXT: ret <2 x float>
 122 }
 123
 124 define <2 x float> @test6(float %A){
 125   %tmp23 = bitcast float %A to i32              ; <i32> [#uses=1]
 126   %tmp24 = zext i32 %tmp23 to i64                 ; <i64> [#uses=1]
 127   %tmp25 = shl i64 %tmp24, 32                     ; <i64> [#uses=1]
 128   %mask20 = or i64 %tmp25, 1109917696             ; <i64> [#uses=1]
 129   %tmp35 = bitcast i64 %mask20 to <2 x float>     ; <<2 x float>> [#uses=1]
 130   ret <2 x float> %tmp35
 131 ; CHECK-LABEL: @test6(
 132 ; CHECK-NEXT: insertelement <2 x float> <float 4.200000e+01, float undef>, float %A, i32 1
 133 ; CHECK: ret
 134 }
 135
 136 define i64 @ISPC0(i64 %in) {
 137   %out = and i64 %in, xor (i64 bitcast (<4 x i16> <i16 -1, i16 -1, i16 -1, i16 -1> to i64), i64 -1)
 138   ret i64 %out
 139 ; CHECK-LABEL: @ISPC0(
 140 ; CHECK: ret i64 0
 141 }
 142
 143
 144 define i64 @Vec2(i64 %in) {
 145   %out = and i64 %in, xor (i64 bitcast (<4 x i16> <i16 0, i16 0, i16 0, i16 0> to i64), i64 0)
 146   ret i64 %out
 147 ; CHECK-LABEL: @Vec2(
 148 ; CHECK: ret i64 0
 149 }
 150
 151 define i64 @All11(i64 %in) {
 152   %out = and i64 %in, xor (i64 bitcast (<2 x float> bitcast (i64 -1 to <2 x float>) to i64), i64 -1)
 153   ret i64 %out
 154 ; CHECK-LABEL: @All11(
 155 ; CHECK: ret i64 0
 156 }
 157
 158
 159 define i32 @All111(i32 %in) {
 160   %out = and i32 %in, xor (i32 bitcast (<1 x float> bitcast (i32 -1 to <1 x float>) to i32), i32 -1)
 161   ret i32 %out
 162 ; CHECK-LABEL: @All111(
 163 ; CHECK: ret i32 0
 164 }
 165
 166 define <2 x i16> @BitcastInsert(i32 %a) {
 167   %v = insertelement <1 x i32> undef, i32 %a, i32 0
 168   %r = bitcast <1 x i32> %v to <2 x i16>
 169   ret <2 x i16> %r
 170 ; CHECK-LABEL: @BitcastInsert(
 171 ; CHECK: bitcast i32 %a to <2 x i16>
 172 }
 173
 174 ; PR17293
 175 define <2 x i64> @test7(<2 x i8*>* %arg) nounwind {
 176   %cast = bitcast <2 x i8*>* %arg to <2 x i64>*
 177   %load = load <2 x i64>, <2 x i64>* %cast, align 16
 178   ret <2 x i64> %load
 179 ; CHECK: @test7
 180 ; CHECK: bitcast
 181 ; CHECK: load
 182 }