test/CodeGen/X86/x86-setcc-int-to-fp-combine.ll

   1 ; RUN: llc < %s -mtriple=x86_64-apple-darwin | FileCheck %s
   2
   3 define <4 x float> @foo(<4 x float> %val, <4 x float> %test) nounwind {
   4 ; CHECK-LABEL: LCPI0_0:
   5 ; CHECK-NEXT: .long 1065353216              ## 0x3f800000
   6 ; CHECK-NEXT: .long 1065353216              ## 0x3f800000
   7 ; CHECK-NEXT: .long 1065353216              ## 0x3f800000
   8 ; CHECK-NEXT: .long 1065353216              ## 0x3f800000
   9 ; CHECK-LABEL: foo:
  10 ; CHECK: cmpeqps %xmm1, %xmm0
  11 ; CHECK-NEXT: andps LCPI0_0(%rip), %xmm0
  12 ; CHECK-NEXT: retq
  13
  14   %cmp = fcmp oeq <4 x float> %val, %test
  15   %ext = zext <4 x i1> %cmp to <4 x i32>
  16   %result = sitofp <4 x i32> %ext to <4 x float>
  17   ret <4 x float> %result
  18 }
  19
  20 ; Make sure the operation doesn't try to get folded when the sizes don't match,
  21 ; as that ends up crashing later when trying to form a bitcast operation for
  22 ; the folded nodes.
  23 define void @foo1(<4 x float> %val, <4 x float> %test, <4 x double>* %p) nounwind {
  24 ; CHECK-LABEL: LCPI1_0:
  25 ; CHECK-NEXT: .long 1                       ## 0x1
  26 ; CHECK-NEXT: .long 1                       ## 0x1
  27 ; CHECK-NEXT: .long 1                       ## 0x1
  28 ; CHECK-NEXT: .long 1                       ## 0x1
  29 ; CHECK-LABEL: foo1:
  30 ;   FIXME: The operation gets scalarized. If/when the compiler learns to better
  31 ;          use [V]CVTDQ2PD, this will need updated.
  32 ; CHECK: cvtsi2sdq
  33 ; CHECK: cvtsi2sdq
  34 ; CHECK: cvtsi2sdq
  35 ; CHECK: cvtsi2sdq
  36   %cmp = fcmp oeq <4 x float> %val, %test
  37   %ext = zext <4 x i1> %cmp to <4 x i32>
  38   %result = sitofp <4 x i32> %ext to <4 x double>
  39   store <4 x double> %result, <4 x double>* %p
  40   ret void
  41 }
  42
  43 ; Also test the general purpose constant folding of int->fp.
  44 define void @foo2(<4 x float>* noalias %result) nounwind {
  45 ; CHECK-LABEL: LCPI2_0:
  46 ; CHECK-NEXT: .long 1082130432              ## float 4.000000e+00
  47 ; CHECK-NEXT: .long 1084227584              ## float 5.000000e+00
  48 ; CHECK-NEXT: .long 1086324736              ## float 6.000000e+00
  49 ; CHECK-NEXT: .long 1088421888              ## float 7.000000e+00
  50 ; CHECK-LABEL: foo2:
  51 ; CHECK:  movaps LCPI2_0(%rip), %xmm0
  52
  53   %val = uitofp <4 x i32> <i32 4, i32 5, i32 6, i32 7> to <4 x float>
  54   store <4 x float> %val, <4 x float>* %result
  55   ret void
  56 }
  57
  58 ; Fold explicit AND operations when the constant isn't a splat of a single
  59 ; scalar value like what the zext creates.
  60 define <4 x float> @foo3(<4 x float> %val, <4 x float> %test) nounwind {
  61 ; CHECK-LABEL: LCPI3_0:
  62 ; CHECK-NEXT: .long 1065353216              ## 0x3f800000
  63 ; CHECK-NEXT: .long 0                       ## 0x0
  64 ; CHECK-NEXT: .long 1065353216              ## 0x3f800000
  65 ; CHECK-NEXT: .long 0                       ## 0x0
  66 ; CHECK-LABEL: foo3:
  67 ; CHECK: cmpeqps %xmm1, %xmm0
  68 ; CHECK-NEXT: andps LCPI3_0(%rip), %xmm0
  69   %cmp = fcmp oeq <4 x float> %val, %test
  70   %ext = zext <4 x i1> %cmp to <4 x i32>
  71   %and = and <4 x i32> %ext, <i32 255, i32 256, i32 257, i32 258>
  72   %result = sitofp <4 x i32> %and to <4 x float>
  73   ret <4 x float> %result
  74 }
  75
  76 ; Test the general purpose constant folding of uint->fp.
  77 define void @foo4(<4 x float>* noalias %result) nounwind {
  78 ; CHECK-LABEL: LCPI4_0:
  79 ; CHECK-NEXT: .long 1065353216              ## float 1.000000e+00
  80 ; CHECK-NEXT: .long 1123942400              ## float 1.270000e+02
  81 ; CHECK-NEXT: .long 1124073472              ## float 1.280000e+02
  82 ; CHECK-NEXT: .long 1132396544              ## float 2.550000e+02
  83 ; CHECK-LABEL: foo4:
  84 ; CHECK:  movaps LCPI4_0(%rip), %xmm0
  85
  86   %val = uitofp <4 x i8> <i8 1, i8 127, i8 -128, i8 -1> to <4 x float>
  87   store <4 x float> %val, <4 x float>* %result
  88   ret void
  89 }