test/CodeGen/WinEH/cppeh-catch-scalar.ll

   1 ; RUN: opt -mtriple=x86_64-pc-windows-msvc -winehprepare -S -o - < %s | FileCheck %s
   2
   3 ; This test is based on the following code:
   4 ;
   5 ; void test()
   6 ; {
   7 ;   try {
   8 ;     may_throw();
   9 ;   } catch (int i) {
  10 ;     handle_int(i);
  11 ;   }
  12 ; }
  13 ;
  14 ; Parts of the IR have been hand-edited to simplify the test case.
  15 ; The full IR will be restored when Windows C++ EH support is complete.
  16
  17 ;ModuleID = 'cppeh-catch-scalar.cpp'
  18 target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
  19 target triple = "x86_64-pc-windows-msvc"
  20
  21 @_ZTIi = external constant i8*
  22
  23 ; The function entry will be rewritten like this.
  24 ; CHECK: define void @_Z4testv() #0 {
  25 ; CHECK: entry:
  26 ; CHECK:   [[I_PTR:\%.+]] = alloca i32, align 4
  27 ; CHECK:   call void (...)* @llvm.frameescape(i32* [[I_PTR]])
  28 ; CHECK:   invoke void @_Z9may_throwv()
  29 ; CHECK:           to label %invoke.cont unwind label %[[LPAD_LABEL:lpad[0-9]+]]
  30
  31 ; Function Attrs: uwtable
  32 define void @_Z4testv() #0 {
  33 entry:
  34   %exn.slot = alloca i8*
  35   %ehselector.slot = alloca i32
  36   %i = alloca i32, align 4
  37   invoke void @_Z9may_throwv()
  38           to label %invoke.cont unwind label %lpad
  39
  40 invoke.cont:                                      ; preds = %entry
  41   br label %try.cont
  42
  43 ; CHECK: [[LPAD_LABEL]]:{{[ ]+}}; preds = %entry
  44 ; CHECK:   [[LPAD_VAL:\%.+]] = landingpad { i8*, i32 } personality i8* bitcast (i32 (...)* @__CxxFrameHandler3 to i8*)
  45 ; CHECK:           catch i8* bitcast (i8** @_ZTIi to i8*)
  46 ; CHECK-NOT:   extractvalue { i8*, i32 }
  47 ; CHECK-NOT:   store i8*
  48 ; CHECK-NOT:   store i32
  49 ; CHECK-NOT:   br label
  50 ; CHECK:   [[RECOVER:\%.+]] = call i8* (...)* @llvm.eh.actions({ i8*, i32 } [[LPAD_VAL]], i32 0, i8* bitcast (i8** @_ZTIi to i8*), i32* %i, i8* bitcast (i8* (i8*, i8*)* @_Z4testv.catch to i8*))
  51 ; CHECK:   indirectbr i8* [[RECOVER]], [label %try.cont]
  52
  53 lpad:                                             ; preds = %entry
  54   %tmp = landingpad { i8*, i32 } personality i8* bitcast (i32 (...)* @__CxxFrameHandler3 to i8*)
  55           catch i8* bitcast (i8** @_ZTIi to i8*)
  56   %tmp1 = extractvalue { i8*, i32 } %tmp, 0
  57   store i8* %tmp1, i8** %exn.slot
  58   %tmp2 = extractvalue { i8*, i32 } %tmp, 1
  59   store i32 %tmp2, i32* %ehselector.slot
  60   br label %catch.dispatch
  61
  62 ; CHECK-NOT: catch-dispatch:
  63
  64 catch.dispatch:                                   ; preds = %lpad
  65   %sel = load i32, i32* %ehselector.slot
  66   %tmp3 = call i32 @llvm.eh.typeid.for(i8* bitcast (i8** @_ZTIi to i8*)) #3
  67   %matches = icmp eq i32 %sel, %tmp3
  68   br i1 %matches, label %catch, label %eh.resume
  69
  70 ; CHECK-NOT: catch:
  71
  72 catch:                                            ; preds = %catch.dispatch
  73   %exn11 = load i8*, i8** %exn.slot
  74   %i.i8 = bitcast i32* %i to i8*
  75   call void @llvm.eh.begincatch(i8* %exn11, i8* %i.i8) #3
  76   %tmp7 = load i32, i32* %i, align 4
  77   call void @_Z10handle_inti(i32 %tmp7)
  78   br label %invoke.cont2
  79
  80 ; CHECK-NOT: invoke.cont2:
  81
  82 invoke.cont2:                                     ; preds = %catch
  83   call void @llvm.eh.endcatch() #3
  84   br label %try.cont
  85
  86 try.cont:                                         ; preds = %invoke.cont2, %invoke.cont
  87   ret void
  88
  89 ; CHECK-NOT: eh.resume:
  90
  91 eh.resume:                                        ; preds = %catch.dispatch
  92   %exn3 = load i8*, i8** %exn.slot
  93   %sel4 = load i32, i32* %ehselector.slot
  94   %lpad.val = insertvalue { i8*, i32 } undef, i8* %exn3, 0
  95   %lpad.val5 = insertvalue { i8*, i32 } %lpad.val, i32 %sel4, 1
  96   resume { i8*, i32 } %lpad.val5
  97
  98 ; CHECK: }
  99 }
 100
 101 ; CHECK: define internal i8* @_Z4testv.catch(i8*, i8*) {
 102 ; CHECK: entry:
 103 ; CHECK:   [[RECOVER_I:\%.+]] = call i8* @llvm.framerecover(i8* bitcast (void ()* @_Z4testv to i8*), i8* %1, i32 0)
 104 ; CHECK:   [[I_PTR1:\%.+]] = bitcast i8* [[RECOVER_I]] to i32*
 105 ; CHECK:   [[TMP:\%.+]] = load i32, i32* [[I_PTR1]], align 4
 106 ; CHECK:   call void @_Z10handle_inti(i32 [[TMP]])
 107 ; CHECK:   ret i8* blockaddress(@_Z4testv, %try.cont)
 108 ; CHECK: }
 109
 110 declare void @_Z9may_throwv() #1
 111
 112 declare i32 @__CxxFrameHandler3(...)
 113
 114 ; Function Attrs: nounwind readnone
 115 declare i32 @llvm.eh.typeid.for(i8*) #2
 116
 117 declare void @llvm.eh.begincatch(i8*, i8*)
 118
 119 declare void @llvm.eh.endcatch()
 120
 121 declare void @_Z10handle_inti(i32) #1
 122
 123 attributes #0 = { uwtable "less-precise-fpmad"="false" "no-frame-pointer-elim"="true" "no-frame-pointer-elim-non-leaf" "no-infs-fp-math"="false" "no-nans-fp-math"="false" "stack-protector-buffer-size"="8" "unsafe-fp-math"="false" "use-soft-float"="false" }
 124 attributes #1 = { "less-precise-fpmad"="false" "no-frame-pointer-elim"="true" "no-frame-pointer-elim-non-leaf" "no-infs-fp-math"="false" "no-nans-fp-math"="false" "stack-protector-buffer-size"="8" "unsafe-fp-math"="false" "use-soft-float"="false" }
 125 attributes #2 = { nounwind readnone }
 126 attributes #3 = { nounwind }
 127
 128 !llvm.ident = !{!0}
 129
 130 !0 = !{!"clang version 3.7.0 (trunk 227474) (llvm/trunk 227508)"}