test/CMakeLists.txt

   1 foreach(c ${LLVM_TARGETS_TO_BUILD})
   2   set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
   3 endforeach(c)
   4 set(TARGETS_TO_BUILD ${TARGETS_BUILT})
   5
   6 # FIXME: This won't work for project files, we need to use a --param.
   7 set(LLVM_LIBS_DIR "${LLVM_BINARY_DIR}/lib/${CMAKE_CFG_INTDIR}")
   8 set(SHLIBEXT "${LTDL_SHLIB_EXT}")
   9
  10 if(BUILD_SHARED_LIBS)
  11   set(LLVM_SHARED_LIBS_ENABLED "1")
  12 else()
  13   set(LLVM_SHARED_LIBS_ENABLED "0")
  14 endif(BUILD_SHARED_LIBS)
  15
  16 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  17   set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
  18 else() # Default for all other unix like systems.
  19   # CMake hardcodes the library locaction using rpath.
  20   # Therefore LD_LIBRARY_PATH is not required to run binaries in the
  21   # build dir. We pass it anyways.
  22   set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
  23 endif()
  24
  25 include(FindPythonInterp)
  26 if(PYTHONINTERP_FOUND)
  27   set(LIT_ARGS "${LLVM_LIT_ARGS}")
  28   separate_arguments(LIT_ARGS)
  29
  30   get_directory_property(DEFINITIONS COMPILE_DEFINITIONS)
  31   foreach(DEF ${DEFINITIONS})
  32     set(DEFS "${DEFS} -D${DEF}")
  33   endforeach()
  34   get_directory_property(INC_DIRS INCLUDE_DIRECTORIES)
  35   foreach(INC_DIR ${INC_DIRS})
  36     set(IDIRS "${IDIRS} -I${INC_DIR}")
  37   endforeach()
  38   string(REPLACE "<CMAKE_CXX_COMPILER>" "${CMAKE_CXX_COMPILER}" TEST_COMPILE_CXX_CMD ${CMAKE_CXX_COMPILE_OBJECT})
  39   string(REPLACE "<DEFINES>"            "${DEFS}"               TEST_COMPILE_CXX_CMD ${TEST_COMPILE_CXX_CMD})
  40   string(REPLACE "<FLAGS>"              "${CMAKE_CXX_FLAGS}"    TEST_COMPILE_CXX_CMD ${TEST_COMPILE_CXX_CMD})
  41   string(REPLACE "-o"                   ""                      TEST_COMPILE_CXX_CMD ${TEST_COMPILE_CXX_CMD})
  42   string(REGEX REPLACE "<[^>]+>"        ""                      TEST_COMPILE_CXX_CMD ${TEST_COMPILE_CXX_CMD})
  43   set(TEST_COMPILE_CXX_CMD "${TEST_COMPILE_CXX_CMD} ${IDIRS}")
  44   if(NOT MSVC)
  45     set(TEST_COMPILE_CXX_CMD "${TEST_COMPILE_CXX_CMD} -x c++")
  46   endif()
  47   configure_file(
  48     ${CMAKE_CURRENT_SOURCE_DIR}/site.exp.in
  49     ${CMAKE_CURRENT_BINARY_DIR}/site.exp)
  50
  51   MAKE_DIRECTORY(${CMAKE_CURRENT_BINARY_DIR}/Unit)
  52
  53   # Configuration-time: See Unit/lit.site.cfg.in
  54   set(LLVM_BUILD_MODE "%(build_mode)s")
  55
  56   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
  57   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
  58   set(LLVM_TOOLS_DIR "${LLVM_TOOLS_BINARY_DIR}/%(build_config)s")
  59   set(LLVMGCCDIR "")
  60   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
  61   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
  62   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
  63
  64   configure_file(
  65     ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
  66     ${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
  67     @ONLY)
  68   configure_file(
  69     ${CMAKE_CURRENT_SOURCE_DIR}/Unit/lit.site.cfg.in
  70     ${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg
  71     @ONLY)
  72
  73   add_custom_target(check
  74     COMMAND ${PYTHON_EXECUTABLE}
  75                 ${LLVM_SOURCE_DIR}/utils/lit/lit.py
  76                 --param llvm_site_config=${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
  77                 --param llvm_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg
  78                 --param build_config=${CMAKE_CFG_INTDIR}
  79                 --param build_mode=${RUNTIME_BUILD_MODE}
  80                 ${LIT_ARGS}
  81                 ${CMAKE_CURRENT_BINARY_DIR}
  82                 DEPENDS
  83                 COMMENT "Running LLVM regression tests")
  84
  85 endif()