test/CMakeLists.txt

   1 foreach(c ${LLVM_TARGETS_TO_BUILD})
   2   set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
   3 endforeach(c)
   4 set(TARGETS_TO_BUILD ${TARGETS_BUILT})
   5
   6 # FIXME: This won't work for project files, we need to use a --param.
   7 set(LLVM_LIBS_DIR "${LLVM_BINARY_DIR}/lib/${CMAKE_CFG_INTDIR}")
   8 set(SHLIBEXT "${LTDL_SHLIB_EXT}")
   9
  10 if(BUILD_SHARED_LIBS)
  11   set(LLVM_SHARED_LIBS_ENABLED "1")
  12 else()
  13   set(LLVM_SHARED_LIBS_ENABLED "0")
  14 endif(BUILD_SHARED_LIBS)
  15
  16 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  17   set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
  18 else() # Default for all other unix like systems.
  19   # CMake hardcodes the library locaction using rpath.
  20   # Therefore LD_LIBRARY_PATH is not required to run binaries in the
  21   # build dir. We pass it anyways.
  22   set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
  23 endif()
  24
  25 include(FindPythonInterp)
  26 if(PYTHONINTERP_FOUND)
  27   get_directory_property(DEFINITIONS COMPILE_DEFINITIONS)
  28   foreach(DEF ${DEFINITIONS})
  29     set(DEFS "${DEFS} -D${DEF}")
  30   endforeach()
  31   get_directory_property(INC_DIRS INCLUDE_DIRECTORIES)
  32   foreach(INC_DIR ${INC_DIRS})
  33     set(IDIRS "${IDIRS} -I${INC_DIR}")
  34   endforeach()
  35   string(REPLACE "<CMAKE_CXX_COMPILER>" "${CMAKE_CXX_COMPILER}" TEST_COMPILE_CXX_CMD ${CMAKE_CXX_COMPILE_OBJECT})
  36   string(REPLACE "<DEFINES>"            "${DEFS}"               TEST_COMPILE_CXX_CMD ${TEST_COMPILE_CXX_CMD})
  37   string(REPLACE "<FLAGS>"              "${CMAKE_CXX_FLAGS}"    TEST_COMPILE_CXX_CMD ${TEST_COMPILE_CXX_CMD})
  38   string(REPLACE "-o"                   ""                      TEST_COMPILE_CXX_CMD ${TEST_COMPILE_CXX_CMD})
  39   string(REGEX REPLACE "<[^>]+>"        ""                      TEST_COMPILE_CXX_CMD ${TEST_COMPILE_CXX_CMD})
  40   set(TEST_COMPILE_CXX_CMD "${TEST_COMPILE_CXX_CMD} ${IDIRS}")
  41   if(NOT MSVC)
  42     set(TEST_COMPILE_CXX_CMD "${TEST_COMPILE_CXX_CMD} -x c++")
  43   endif()
  44   configure_file(
  45     ${CMAKE_CURRENT_SOURCE_DIR}/site.exp.in
  46     ${CMAKE_CURRENT_BINARY_DIR}/site.exp)
  47
  48   MAKE_DIRECTORY(${CMAKE_CURRENT_BINARY_DIR}/Unit)
  49
  50   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
  51   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
  52   set(LLVM_TOOLS_DIR "${LLVM_TOOLS_BINARY_DIR}/${CMAKE_CFG_INTDIR}")
  53   set(LLVMGCCDIR "")
  54   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
  55   set(LLVM_BUILD_MODE ${CMAKE_CFG_INTDIR})
  56   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
  57   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
  58
  59   configure_file(
  60     ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
  61     ${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
  62     @ONLY)
  63   configure_file(
  64     ${CMAKE_CURRENT_SOURCE_DIR}/Unit/lit.site.cfg.in
  65     ${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg
  66     @ONLY)
  67
  68   add_custom_target(check
  69     COMMAND ${PYTHON_EXECUTABLE}
  70                 ${LLVM_SOURCE_DIR}/utils/lit/lit.py
  71                 --param llvm_site_config=${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
  72                 --param llvm_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg
  73                 -sv
  74                 ${CMAKE_CURRENT_BINARY_DIR}
  75                 DEPENDS
  76                 COMMENT "Running LLVM regression tests")
  77
  78 endif()