test/CMakeLists.txt

   1 configure_lit_site_cfg(
   2   ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
   3   ${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
   4   )
   5 configure_lit_site_cfg(
   6   ${CMAKE_CURRENT_SOURCE_DIR}/Unit/lit.site.cfg.in
   7   ${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg
   8   )
   9
  10 # Don't include check-llvm into check-all without LLVM_BUILD_TOOLS.
  11 if(NOT LLVM_BUILD_TOOLS)
  12   set(EXCLUDE_FROM_ALL ON)
  13 endif()
  14
  15 # Set the depends list as a variable so that it can grow conditionally.
  16 # NOTE: Sync the substitutions in test/lit.cfg when adding to this list.
  17 set(LLVM_TEST_DEPENDS
  18           llvm-config
  19           UnitTests
  20           BugpointPasses
  21           LLVMHello
  22           bugpoint
  23           llc
  24           lli
  25           lli-child-target
  26           llvm-ar
  27           llvm-as
  28           llvm-bcanalyzer
  29           llvm-c-test
  30           llvm-cov
  31           llvm-diff
  32           llvm-dis
  33           llvm-extract
  34           llvm-dwarfdump
  35           llvm-link
  36           llvm-lto
  37           llvm-mc
  38           llvm-mcmarkup
  39           llvm-nm
  40           llvm-size
  41           llvm-objdump
  42           llvm-profdata
  43           llvm-readobj
  44           llvm-rtdyld
  45           llvm-symbolizer
  46           llvm-tblgen
  47           macho-dump
  48           opt
  49           FileCheck
  50           count
  51           not
  52           yaml2obj
  53           obj2yaml
  54         )
  55
  56 # If Intel JIT events are supported, depend on a tool that tests the listener.
  57 if( LLVM_USE_INTEL_JITEVENTS )
  58   set(LLVM_TEST_DEPENDS ${LLVM_TEST_DEPENDS} llvm-jitlistener)
  59 endif( LLVM_USE_INTEL_JITEVENTS )
  60
  61 add_lit_testsuite(check-llvm "Running the LLVM regression tests"
  62   ${CMAKE_CURRENT_BINARY_DIR}
  63   PARAMS llvm_site_config=${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
  64          llvm_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg
  65   DEPENDS ${LLVM_TEST_DEPENDS}
  66   )
  67 set_target_properties(check-llvm PROPERTIES FOLDER "Tests")
  68
  69 # Setup a legacy alias for 'check-llvm'. This will likely change to be an
  70 # alias for 'check-all' at some point in the future.
  71 add_custom_target(check)
  72 add_dependencies(check check-llvm)
  73 set_target_properties(check PROPERTIES FOLDER "Tests")