test/Analysis/ValueTracking/memory-dereferenceable.ll

   1 ; RUN: opt -print-memderefs -analyze -S <%s | FileCheck %s
   2
   3 ; Uses the print-deref (+ analyze to print) pass to run
   4 ; isDereferenceablePointer() on many load instruction operands
   5
   6 target datalayout = "e"
   7
   8 declare zeroext i1 @return_i1()
   9
  10 declare i32* @foo()
  11 @globalstr = global [6 x i8] c"hello\00"
  12 @globali32ptr = external global i32*
  13
  14 %struct.A = type { [8 x i8], [5 x i8] }
  15 @globalstruct = external global %struct.A
  16
  17 @globalptr.align1 = external global i8, align 1
  18 @globalptr.align16 = external global i8, align 16
  19
  20 define void @test(i32 addrspace(1)* dereferenceable(8) %dparam,
  21                   i8 addrspace(1)* dereferenceable(32) align 1 %dparam.align1,
  22                   i8 addrspace(1)* dereferenceable(32) align 16 %dparam.align16)
  23     gc "statepoint-example" {
  24 ; CHECK: The following are dereferenceable:
  25 entry:
  26 ; CHECK: %globalptr{{.*}}(aligned)
  27     %globalptr = getelementptr inbounds [6 x i8], [6 x i8]* @globalstr, i32 0, i32 0
  28     %load1 = load i8, i8* %globalptr
  29
  30 ; CHECK: %alloca{{.*}}(aligned)
  31     %alloca = alloca i1
  32     %load2 = load i1, i1* %alloca
  33
  34 ; CHECK: %dparam{{.*}}(aligned)
  35     %load3 = load i32, i32 addrspace(1)* %dparam
  36
  37 ; CHECK: %relocate{{.*}}(aligned)
  38     %tok = tail call i32 (i64, i32, i1 ()*, i32, i32, ...) @llvm.experimental.gc.statepoint.p0f_i1f(i64 0, i32 0, i1 ()* @return_i1, i32 0, i32 0, i32 0, i32 0, i32 addrspace(1)* %dparam)
  39     %relocate = call i32 addrspace(1)* @llvm.experimental.gc.relocate.p1i32(i32 %tok, i32 7, i32 7)
  40     %load4 = load i32, i32 addrspace(1)* %relocate
  41
  42 ; CHECK-NOT: %nparam
  43     %nparam = getelementptr i32, i32 addrspace(1)* %dparam, i32 5
  44     %load5 = load i32, i32 addrspace(1)* %nparam
  45
  46     ; Load from a non-dereferenceable load
  47 ; CHECK-NOT: %nd_load
  48     %nd_load = load i32*, i32** @globali32ptr
  49     %load6 = load i32, i32* %nd_load
  50
  51     ; Load from a dereferenceable load
  52 ; CHECK: %d4_load{{.*}}(aligned)
  53     %d4_load = load i32*, i32** @globali32ptr, !dereferenceable !0
  54     %load7 = load i32, i32* %d4_load
  55
  56     ; Load from an offset not covered by the dereferenceable portion
  57 ; CHECK-NOT: %d2_load
  58     %d2_load = load i32*, i32** @globali32ptr, !dereferenceable !1
  59     %load8 = load i32, i32* %d2_load
  60
  61     ; Load from a potentially null pointer with dereferenceable_or_null
  62 ; CHECK-NOT: %d_or_null_load
  63     %d_or_null_load = load i32*, i32** @globali32ptr, !dereferenceable_or_null !0
  64     %load9 = load i32, i32* %d_or_null_load
  65
  66     ; Load from a non-null pointer with dereferenceable_or_null
  67 ; CHECK: %d_or_null_non_null_load{{.*}}(aligned)
  68     %d_or_null_non_null_load = load i32*, i32** @globali32ptr, !nonnull !2, !dereferenceable_or_null !0
  69     %load10 = load i32, i32* %d_or_null_non_null_load
  70
  71     ; It's OK to overrun static array size as long as we stay within underlying object size
  72 ; CHECK: %within_allocation{{.*}}(aligned)
  73     %within_allocation = getelementptr inbounds %struct.A, %struct.A* @globalstruct, i64 0, i32 0, i64 10
  74     %load11 = load i8, i8* %within_allocation
  75
  76     ; GEP is outside the underlying object size
  77 ; CHECK-NOT: %outside_allocation
  78     %outside_allocation = getelementptr inbounds %struct.A, %struct.A* @globalstruct, i64 0, i32 1, i64 10
  79     %load12 = load i8, i8* %outside_allocation
  80
  81     ; Loads from aligned globals
  82 ; CHECK: @globalptr.align1{{.*}}(unaligned)
  83 ; CHECK: @globalptr.align16{{.*}}(aligned)
  84     %load13 = load i8, i8* @globalptr.align1, align 16
  85     %load14 = load i8, i8* @globalptr.align16, align 16
  86
  87     ; Loads from aligned arguments
  88 ; CHECK: %dparam.align1{{.*}}(unaligned)
  89 ; CHECK: %dparam.align16{{.*}}(aligned)
  90     %load15 = load i8, i8 addrspace(1)* %dparam.align1, align 16
  91     %load16 = load i8, i8 addrspace(1)* %dparam.align16, align 16
  92
  93     ; Loads from aligned allocas
  94 ; CHECK: %alloca.align1{{.*}}(unaligned)
  95 ; CHECK: %alloca.align16{{.*}}(aligned)
  96     %alloca.align1 = alloca i1, align 1
  97     %alloca.align16 = alloca i1, align 16
  98     %load17 = load i1, i1* %alloca.align1, align 16
  99     %load18 = load i1, i1* %alloca.align16, align 16
 100
 101     ; Loads from GEPs
 102 ; CHECK: %gep.align1.offset1{{.*}}(unaligned)
 103 ; CHECK: %gep.align16.offset1{{.*}}(unaligned)
 104 ; CHECK: %gep.align1.offset16{{.*}}(unaligned)
 105 ; CHECK: %gep.align16.offset16{{.*}}(aligned)
 106     %gep.align1.offset1 = getelementptr inbounds i8, i8 addrspace(1)* %dparam.align1, i32 1
 107     %gep.align16.offset1 = getelementptr inbounds i8, i8 addrspace(1)* %dparam.align16, i32 1
 108     %gep.align1.offset16 = getelementptr inbounds i8, i8 addrspace(1)* %dparam.align1, i32 16
 109     %gep.align16.offset16 = getelementptr inbounds i8, i8 addrspace(1)* %dparam.align16, i32 16
 110     %load19 = load i8, i8 addrspace(1)* %gep.align1.offset1, align 16
 111     %load20 = load i8, i8 addrspace(1)* %gep.align16.offset1, align 16
 112     %load21 = load i8, i8 addrspace(1)* %gep.align1.offset16, align 16
 113     %load22 = load i8, i8 addrspace(1)* %gep.align16.offset16, align 16
 114
 115 ; CHECK-NOT: %no_deref_return
 116 ; CHECK: %deref_return{{.*}}(unaligned)
 117 ; CHECK: %deref_and_aligned_return{{.*}}(aligned)
 118     %no_deref_return = call i32* @foo()
 119     %deref_return = call dereferenceable(32) i32* @foo()
 120     %deref_and_aligned_return = call dereferenceable(32) align 16 i32* @foo()
 121     %load23 = load i32, i32* %no_deref_return
 122     %load24 = load i32, i32* %deref_return, align 16
 123     %load25 = load i32, i32* %deref_and_aligned_return, align 16
 124
 125     ; Load from a dereferenceable and aligned load
 126 ; CHECK: %d4_unaligned_load{{.*}}(unaligned)
 127 ; CHECK: %d4_aligned_load{{.*}}(aligned)
 128     %d4_unaligned_load = load i32*, i32** @globali32ptr, !dereferenceable !0
 129     %d4_aligned_load = load i32*, i32** @globali32ptr, !dereferenceable !0, !align !{i64 16}
 130     %load26 = load i32, i32* %d4_unaligned_load, align 16
 131     %load27 = load i32, i32* %d4_aligned_load, align 16
 132
 133     ret void
 134 }
 135
 136 declare i32 @llvm.experimental.gc.statepoint.p0f_i1f(i64, i32, i1 ()*, i32, i32, ...)
 137 declare i32 addrspace(1)* @llvm.experimental.gc.relocate.p1i32(i32, i32, i32)
 138
 139 !0 = !{i64 4}
 140 !1 = !{i64 2}
 141 !2 = !{}