test/Analysis/ValueTracking/memory-dereferenceable.ll

   1 ; RUN: opt -print-memderefs -analyze -S <%s | FileCheck %s
   2
   3 ; Uses the print-deref (+ analyze to print) pass to run
   4 ; isDereferenceablePointer() on many load instruction operands
   5
   6 target datalayout = "e"
   7
   8 declare zeroext i1 @return_i1()
   9
  10 @globalstr = global [6 x i8] c"hello\00"
  11 @globali32ptr = external global i32*
  12
  13 %struct.A = type { [8 x i8], [5 x i8] }
  14 @globalstruct = external global %struct.A
  15
  16 @globalptr.align1 = external global i8, align 1
  17 @globalptr.align16 = external global i8, align 16
  18
  19 define void @test(i32 addrspace(1)* dereferenceable(8) %dparam,
  20                   i8 addrspace(1)* dereferenceable(32) align 1 %dparam.align1,
  21                   i8 addrspace(1)* dereferenceable(32) align 16 %dparam.align16)
  22     gc "statepoint-example" {
  23 ; CHECK: The following are dereferenceable:
  24 entry:
  25 ; CHECK: %globalptr{{.*}}(aligned)
  26     %globalptr = getelementptr inbounds [6 x i8], [6 x i8]* @globalstr, i32 0, i32 0
  27     %load1 = load i8, i8* %globalptr
  28
  29 ; CHECK: %alloca{{.*}}(aligned)
  30     %alloca = alloca i1
  31     %load2 = load i1, i1* %alloca
  32
  33 ; CHECK: %dparam{{.*}}(aligned)
  34     %load3 = load i32, i32 addrspace(1)* %dparam
  35
  36 ; CHECK: %relocate{{.*}}(aligned)
  37     %tok = tail call i32 (i64, i32, i1 ()*, i32, i32, ...) @llvm.experimental.gc.statepoint.p0f_i1f(i64 0, i32 0, i1 ()* @return_i1, i32 0, i32 0, i32 0, i32 0, i32 addrspace(1)* %dparam)
  38     %relocate = call i32 addrspace(1)* @llvm.experimental.gc.relocate.p1i32(i32 %tok, i32 7, i32 7)
  39     %load4 = load i32, i32 addrspace(1)* %relocate
  40
  41 ; CHECK-NOT: %nparam
  42     %nparam = getelementptr i32, i32 addrspace(1)* %dparam, i32 5
  43     %load5 = load i32, i32 addrspace(1)* %nparam
  44
  45     ; Load from a non-dereferenceable load
  46 ; CHECK-NOT: %nd_load
  47     %nd_load = load i32*, i32** @globali32ptr
  48     %load6 = load i32, i32* %nd_load
  49
  50     ; Load from a dereferenceable load
  51 ; CHECK: %d4_load{{.*}}(aligned)
  52     %d4_load = load i32*, i32** @globali32ptr, !dereferenceable !0
  53     %load7 = load i32, i32* %d4_load
  54
  55     ; Load from an offset not covered by the dereferenceable portion
  56 ; CHECK-NOT: %d2_load
  57     %d2_load = load i32*, i32** @globali32ptr, !dereferenceable !1
  58     %load8 = load i32, i32* %d2_load
  59
  60     ; Load from a potentially null pointer with dereferenceable_or_null
  61 ; CHECK-NOT: %d_or_null_load
  62     %d_or_null_load = load i32*, i32** @globali32ptr, !dereferenceable_or_null !0
  63     %load9 = load i32, i32* %d_or_null_load
  64
  65     ; Load from a non-null pointer with dereferenceable_or_null
  66 ; CHECK: %d_or_null_non_null_load{{.*}}(aligned)
  67     %d_or_null_non_null_load = load i32*, i32** @globali32ptr, !nonnull !2, !dereferenceable_or_null !0
  68     %load10 = load i32, i32* %d_or_null_non_null_load
  69
  70     ; It's OK to overrun static array size as long as we stay within underlying object size
  71 ; CHECK: %within_allocation{{.*}}(aligned)
  72     %within_allocation = getelementptr inbounds %struct.A, %struct.A* @globalstruct, i64 0, i32 0, i64 10
  73     %load11 = load i8, i8* %within_allocation
  74
  75     ; GEP is outside the underlying object size
  76 ; CHECK-NOT: %outside_allocation
  77     %outside_allocation = getelementptr inbounds %struct.A, %struct.A* @globalstruct, i64 0, i32 1, i64 10
  78     %load12 = load i8, i8* %outside_allocation
  79
  80     ; Loads from aligned globals
  81 ; CHECK: @globalptr.align1{{.*}}(unaligned)
  82 ; CHECK: @globalptr.align16{{.*}}(aligned)
  83     %load13 = load i8, i8* @globalptr.align1, align 16
  84     %load14 = load i8, i8* @globalptr.align16, align 16
  85
  86     ; Loads from aligned arguments
  87 ; CHECK: %dparam.align1{{.*}}(unaligned)
  88 ; CHECK: %dparam.align16{{.*}}(aligned)
  89     %load15 = load i8, i8 addrspace(1)* %dparam.align1, align 16
  90     %load16 = load i8, i8 addrspace(1)* %dparam.align16, align 16
  91
  92     ; Loads from aligned allocas
  93 ; CHECK: %alloca.align1{{.*}}(unaligned)
  94 ; CHECK: %alloca.align16{{.*}}(aligned)
  95     %alloca.align1 = alloca i1, align 1
  96     %alloca.align16 = alloca i1, align 16
  97     %load17 = load i1, i1* %alloca.align1, align 16
  98     %load18 = load i1, i1* %alloca.align16, align 16
  99
 100     ; Loads from GEPs
 101 ; CHECK: %gep.align1.offset1{{.*}}(unaligned)
 102 ; CHECK: %gep.align16.offset1{{.*}}(unaligned)
 103 ; CHECK: %gep.align1.offset16{{.*}}(unaligned)
 104 ; CHECK: %gep.align16.offset16{{.*}}(aligned)
 105     %gep.align1.offset1 = getelementptr inbounds i8, i8 addrspace(1)* %dparam.align1, i32 1
 106     %gep.align16.offset1 = getelementptr inbounds i8, i8 addrspace(1)* %dparam.align16, i32 1
 107     %gep.align1.offset16 = getelementptr inbounds i8, i8 addrspace(1)* %dparam.align1, i32 16
 108     %gep.align16.offset16 = getelementptr inbounds i8, i8 addrspace(1)* %dparam.align16, i32 16
 109     %load19 = load i8, i8 addrspace(1)* %gep.align1.offset1, align 16
 110     %load20 = load i8, i8 addrspace(1)* %gep.align16.offset1, align 16
 111     %load21 = load i8, i8 addrspace(1)* %gep.align1.offset16, align 16
 112     %load22 = load i8, i8 addrspace(1)* %gep.align16.offset16, align 16
 113
 114     ret void
 115 }
 116
 117 declare i32 @llvm.experimental.gc.statepoint.p0f_i1f(i64, i32, i1 ()*, i32, i32, ...)
 118 declare i32 addrspace(1)* @llvm.experimental.gc.relocate.p1i32(i32, i32, i32)
 119
 120 !0 = !{i64 4}
 121 !1 = !{i64 2}
 122 !2 = !{}