projects/sample/autoconf/configure.ac

   1 dnl **************************************************************************
   2 dnl * Initialize
   3 dnl **************************************************************************
   4 AC_INIT([[[SAMPLE]]],[[[x.xx]]],[bugs@yourdomain])
   5
   6 dnl Identify where LLVM source tree is
   7 LLVM_SRC_ROOT="../.."
   8 LLVM_OBJ_ROOT="../.."
   9
  10 dnl Find absolute paths to LLVM source and object trees
  11 LLVM_ABS_SRC_ROOT="`cd $srcdir ; cd $LLVM_SRC_ROOT ; pwd`"
  12 LLVM_ABS_OBJ_ROOT="`cd $LLVM_OBJ_ROOT ; pwd`"
  13
  14 dnl Tell autoconf that this is an LLVM project being configured
  15 dnl This provides the --with-llvmsrc and --with-llvmobj options
  16 LLVM_CONFIG_PROJECT($LLVM_ABS_SRC_ROOT,$LLVM_ABS_OBJ_ROOT)
  17
  18 dnl Try and find an llvm-config in the build directory. We are only using this
  19 dnl to detect the package level LLVM information (currently just the version),
  20 dnl so we just whatever one we find regardless of build mode.
  21 AC_MSG_CHECKING([llvm-config])
  22 llvm_config_path="`ls -1 $llvm_obj/*/bin/llvm-config 2> /dev/null | head -1`"
  23 if ! test -f "$llvm_config_path" ; then
  24    llvm_config_path="no"
  25 fi
  26 AC_MSG_RESULT([$llvm_config_path])
  27
  28 dnl Determine the LLVM version, which may be required by the current Makefile
  29 dnl rules.
  30 AC_MSG_CHECKING([LLVM package version])
  31 if test "$llvm_config_path" != no ; then
  32   llvm_package_version=`$llvm_config_path --version`
  33 else
  34   llvm_package_version="unknown";
  35 fi
  36 AC_MSG_RESULT([$llvm_package_version])
  37 AC_SUBST(LLVM_VERSION, [$llvm_package_version])
  38
  39 dnl Verify that the source directory is valid
  40 AC_CONFIG_SRCDIR(["Makefile.common.in"])
  41
  42 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  43 dnl various tools where the m4 autoconf macros are.
  44 AC_CONFIG_AUX_DIR([autoconf])
  45
  46 dnl **************************************************************************
  47 dnl Begin LLVM configure.ac Import
  48 dnl **************************************************************************
  49 dnl
  50 dnl Derived from LLVM's configure.ac. This was imported directly here so that we
  51 dnl could reuse LLVM's build infrastructure without introducing a direct source
  52 dnl dependency on the LLVM files.
  53
  54 dnl We need to check for the compiler up here to avoid anything else
  55 dnl starting with a different one.
  56 AC_PROG_CC(clang llvm-gcc gcc)
  57 AC_PROG_CXX(clang++ llvm-g++ g++)
  58 AC_PROG_CPP
  59
  60 dnl Configure all of the projects present in our source tree. While we could
  61 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  62 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  63 dnl Instead we match on the known projects.
  64
  65 dnl
  66 dnl One tricky part of doing this is that some projects depend upon other
  67 dnl projects.  For example, several projects rely upon the LLVM test suite.
  68 dnl We want to configure those projects first so that their object trees are
  69 dnl created before running the configure scripts of projects that depend upon
  70 dnl them.
  71 dnl
  72
  73 dnl Disable the build of polly, even if it is checked out into tools/polly.
  74 AC_ARG_ENABLE(polly,
  75               AS_HELP_STRING([--enable-polly],
  76                              [Use polly if available (default is YES)]),,
  77                              enableval=default)
  78 case "$enableval" in
  79   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
  80   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
  81   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
  82   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
  83 esac
  84
  85
  86 dnl Check if polly is checked out into tools/polly and configure it if
  87 dnl available.
  88 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
  89   AC_SUBST(LLVM_HAS_POLLY,1)
  90   AC_CONFIG_SUBDIRS([tools/polly])
  91 fi
  92
  93 dnl===-----------------------------------------------------------------------===
  94 dnl===
  95 dnl=== SECTION 2: Architecture, target, and host checks
  96 dnl===
  97 dnl===-----------------------------------------------------------------------===
  98
  99 dnl Check the target for which we're compiling and the host that will do the
 100 dnl compilations. This will tell us which LLVM compiler will be used for
 101 dnl compiling SSA into object code. This needs to be done early because
 102 dnl following tests depend on it.
 103 AC_CANONICAL_TARGET
 104
 105 dnl Determine the platform type and cache its value. This helps us configure
 106 dnl the System library to the correct build platform.
 107 AC_CACHE_CHECK([type of operating system we're going to host on],
 108                [llvm_cv_os_type],
 109 [case $host in
 110   *-*-aix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="AIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-irix*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="IRIX"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-cygwin*)
 121     llvm_cv_link_all_option="-Wl,--whole-archive"
 122     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 123     llvm_cv_os_type="Cygwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-darwin*)
 126     llvm_cv_link_all_option="-Wl,-all_load"
 127     llvm_cv_no_link_all_option="-Wl,-noall_load"
 128     llvm_cv_os_type="Darwin"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-minix*)
 131     llvm_cv_link_all_option="-Wl,-all_load"
 132     llvm_cv_no_link_all_option="-Wl,-noall_load"
 133     llvm_cv_os_type="Minix"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-freebsd* | *-*-kfreebsd-gnu)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="FreeBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-openbsd*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="OpenBSD"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-netbsd*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="NetBSD"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-dragonfly*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="DragonFly"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-hpux*)
 156     llvm_cv_link_all_option="-Wl,--whole-archive"
 157     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 158     llvm_cv_os_type="HP-UX"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-interix*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Interix"
 164     llvm_cv_platform_type="Unix" ;;
 165   *-*-linux*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="Linux"
 169     llvm_cv_platform_type="Unix" ;;
 170   *-*-gnu*)
 171     llvm_cv_link_all_option="-Wl,--whole-archive"
 172     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 173     llvm_cv_os_type="GNU"
 174     llvm_cv_platform_type="Unix" ;;
 175   *-*-solaris*)
 176     llvm_cv_link_all_option="-Wl,-z,allextract"
 177     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 178     llvm_cv_os_type="SunOS"
 179     llvm_cv_platform_type="Unix" ;;
 180   *-*-auroraux*)
 181     llvm_cv_link_all_option="-Wl,-z,allextract"
 182     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 183     llvm_cv_os_type="AuroraUX"
 184     llvm_cv_platform_type="Unix" ;;
 185   *-*-win32*)
 186     llvm_cv_link_all_option="-Wl,--whole-archive"
 187     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 188     llvm_cv_os_type="Win32"
 189     llvm_cv_platform_type="Win32" ;;
 190   *-*-mingw*)
 191     llvm_cv_link_all_option="-Wl,--whole-archive"
 192     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 193     llvm_cv_os_type="MingW"
 194     llvm_cv_platform_type="Win32" ;;
 195   *-*-haiku*)
 196     llvm_cv_link_all_option="-Wl,--whole-archive"
 197     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 198     llvm_cv_os_type="Haiku"
 199     llvm_cv_platform_type="Unix" ;;
 200   *-unknown-eabi*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="Freestanding"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-unknown-elf*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="Freestanding"
 209     llvm_cv_platform_type="Unix" ;;
 210   *)
 211     llvm_cv_link_all_option=""
 212     llvm_cv_no_link_all_option=""
 213     llvm_cv_os_type="Unknown"
 214     llvm_cv_platform_type="Unknown" ;;
 215 esac])
 216
 217 AC_CACHE_CHECK([type of operating system we're going to target],
 218                [llvm_cv_target_os_type],
 219 [case $target in
 220   *-*-aix*)
 221     llvm_cv_target_os_type="AIX" ;;
 222   *-*-irix*)
 223     llvm_cv_target_os_type="IRIX" ;;
 224   *-*-cygwin*)
 225     llvm_cv_target_os_type="Cygwin" ;;
 226   *-*-darwin*)
 227     llvm_cv_target_os_type="Darwin" ;;
 228   *-*-minix*)
 229     llvm_cv_target_os_type="Minix" ;;
 230   *-*-freebsd* | *-*-kfreebsd-gnu)
 231     llvm_cv_target_os_type="FreeBSD" ;;
 232   *-*-openbsd*)
 233     llvm_cv_target_os_type="OpenBSD" ;;
 234   *-*-netbsd*)
 235     llvm_cv_target_os_type="NetBSD" ;;
 236   *-*-dragonfly*)
 237     llvm_cv_target_os_type="DragonFly" ;;
 238   *-*-hpux*)
 239     llvm_cv_target_os_type="HP-UX" ;;
 240   *-*-interix*)
 241     llvm_cv_target_os_type="Interix" ;;
 242   *-*-linux*)
 243     llvm_cv_target_os_type="Linux" ;;
 244   *-*-gnu*)
 245     llvm_cv_target_os_type="GNU" ;;
 246   *-*-solaris*)
 247     llvm_cv_target_os_type="SunOS" ;;
 248   *-*-auroraux*)
 249     llvm_cv_target_os_type="AuroraUX" ;;
 250   *-*-win32*)
 251     llvm_cv_target_os_type="Win32" ;;
 252   *-*-mingw*)
 253     llvm_cv_target_os_type="MingW" ;;
 254   *-*-haiku*)
 255     llvm_cv_target_os_type="Haiku" ;;
 256   *-*-rtems*)
 257     llvm_cv_target_os_type="RTEMS" ;;
 258   *-*-nacl*)
 259     llvm_cv_target_os_type="NativeClient" ;;
 260   *-unknown-eabi*)
 261     llvm_cv_target_os_type="Freestanding" ;;
 262   *)
 263     llvm_cv_target_os_type="Unknown" ;;
 264 esac])
 265
 266 dnl Make sure we aren't attempting to configure for an unknown system
 267 if test "$llvm_cv_os_type" = "Unknown" ; then
 268   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 269 fi
 270
 271 dnl Set the "OS" Makefile variable based on the platform type so the
 272 dnl makefile can configure itself to specific build hosts
 273 AC_SUBST(OS,$llvm_cv_os_type)
 274 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 275 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 276
 277 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 278 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 279 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 280
 281 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 282 dnl This is used by lib/Support to determine the basic kind of implementation
 283 dnl to use.
 284 case $llvm_cv_platform_type in
 285   Unix)
 286     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 287     AC_SUBST(LLVM_ON_UNIX,[1])
 288     AC_SUBST(LLVM_ON_WIN32,[0])
 289     ;;
 290   Win32)
 291     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 292     AC_SUBST(LLVM_ON_UNIX,[0])
 293     AC_SUBST(LLVM_ON_WIN32,[1])
 294     ;;
 295 esac
 296
 297 dnl Determine what our target architecture is and configure accordingly.
 298 dnl This will allow Makefiles to make a distinction between the hardware and
 299 dnl the OS.
 300 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 301 [case $target in
 302   i?86-*)                 llvm_cv_target_arch="x86" ;;
 303   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 304   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 305   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 306   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 307   mips-*)                 llvm_cv_target_arch="Mips" ;;
 308   mipsel-*)               llvm_cv_target_arch="Mips" ;;
 309   xcore-*)                llvm_cv_target_arch="XCore" ;;
 310   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 311   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 312   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 313   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 314   *)                      llvm_cv_target_arch="Unknown" ;;
 315 esac])
 316
 317 if test "$llvm_cv_target_arch" = "Unknown" ; then
 318   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 319 fi
 320
 321 # Determine the LLVM native architecture for the target
 322 case "$llvm_cv_target_arch" in
 323     x86)     LLVM_NATIVE_ARCH="X86" ;;
 324     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 325     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 326 esac
 327
 328 dnl Define a substitution, ARCH, for the target architecture
 329 AC_SUBST(ARCH,$llvm_cv_target_arch)
 330
 331 dnl Check for the endianness of the target
 332 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 333
 334 dnl Check for build platform executable suffix if we're crosscompiling
 335 if test "$cross_compiling" = yes; then
 336   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 337   AC_BUILD_EXEEXT
 338   ac_build_prefix=${build_alias}-
 339   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 340   if test -z "$BUILD_CXX"; then
 341      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 342      if test -z "$BUILD_CXX"; then
 343        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 344      fi
 345   fi
 346 else
 347   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 348 fi
 349
 350 dnl Check to see if there's a .svn or .git directory indicating that this
 351 dnl build is being done from a checkout. This sets up several defaults for
 352 dnl the command line switches. When we build with a checkout directory,
 353 dnl we get a debug with assertions turned on. Without, we assume a source
 354 dnl release and we get an optimized build without assertions.
 355 dnl See --enable-optimized and --enable-assertions below
 356 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 357   cvsbuild="yes"
 358   optimize="no"
 359   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 360 else
 361   cvsbuild="no"
 362   optimize="yes"
 363 fi
 364
 365 dnl===-----------------------------------------------------------------------===
 366 dnl===
 367 dnl=== SECTION 3: Command line arguments for the configure script.
 368 dnl===
 369 dnl===-----------------------------------------------------------------------===
 370
 371 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 372 AC_ARG_ENABLE(libcpp,
 373               AS_HELP_STRING([--enable-libcpp],
 374                              [Use libc++ if available (default is NO)]),,
 375                              enableval=default)
 376 case "$enableval" in
 377   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 378   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 379   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 380   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 381 esac
 382
 383 dnl --enable-optimized : check whether they want to do an optimized build:
 384 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 385  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 386 if test ${enableval} = "no" ; then
 387   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 388 else
 389   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 390 fi
 391
 392 dnl --enable-profiling : check whether they want to do a profile build:
 393 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 394  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 395 if test ${enableval} = "no" ; then
 396   AC_SUBST(ENABLE_PROFILING,[[]])
 397 else
 398   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 399 fi
 400
 401 dnl --enable-assertions : check whether they want to turn on assertions or not:
 402 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 403   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 404 if test ${enableval} = "yes" ; then
 405   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 406 else
 407   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 408 fi
 409
 410 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 411 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 412   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 413 if test ${enableval} = "yes" ; then
 414   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 415   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 416 else
 417   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 418   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 419 fi
 420
 421 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 422 AC_ARG_ENABLE(debug-runtime,
 423    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 424 if test ${enableval} = "no" ; then
 425   AC_SUBST(DEBUG_RUNTIME,[[]])
 426 else
 427   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 428 fi
 429
 430 dnl --enable-debug-symbols : should even optimized compiler libraries
 431 dnl have debug symbols?
 432 AC_ARG_ENABLE(debug-symbols,
 433    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 434 if test ${enableval} = "no" ; then
 435   AC_SUBST(DEBUG_SYMBOLS,[[]])
 436 else
 437   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 438 fi
 439
 440 dnl --enable-jit: check whether they want to enable the jit
 441 AC_ARG_ENABLE(jit,
 442   AS_HELP_STRING(--enable-jit,
 443                  [Enable Just In Time Compiling (default is YES)]),,
 444   enableval=default)
 445 if test ${enableval} = "no"
 446 then
 447   AC_SUBST(JIT,[[]])
 448 else
 449   case "$llvm_cv_target_arch" in
 450     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 451     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 452     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 453     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 454     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 455     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 456     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 457     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 458     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 459     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 460     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 461     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 462   esac
 463 fi
 464
 465 dnl Allow enablement of building and installing docs
 466 AC_ARG_ENABLE(docs,
 467               AS_HELP_STRING([--enable-docs],
 468                              [Build documents (default is YES)]),,
 469                              enableval=default)
 470 case "$enableval" in
 471   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 472   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 473   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 474   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 475 esac
 476
 477 dnl Allow enablement of doxygen generated documentation
 478 AC_ARG_ENABLE(doxygen,
 479               AS_HELP_STRING([--enable-doxygen],
 480                              [Build doxygen documentation (default is NO)]),,
 481                              enableval=default)
 482 case "$enableval" in
 483   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 484   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 485   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 486   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 487 esac
 488
 489 dnl Allow disablement of threads
 490 AC_ARG_ENABLE(threads,
 491               AS_HELP_STRING([--enable-threads],
 492                              [Use threads if available (default is YES)]),,
 493                              enableval=default)
 494 case "$enableval" in
 495   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 496   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 497   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 498   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 499 esac
 500 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 501
 502 dnl Allow disablement of pthread.h
 503 AC_ARG_ENABLE(pthreads,
 504               AS_HELP_STRING([--enable-pthreads],
 505                              [Use pthreads if available (default is YES)]),,
 506                              enableval=default)
 507 case "$enableval" in
 508   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 509   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 510   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 511   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 512 esac
 513
 514 dnl Allow building without position independent code
 515 AC_ARG_ENABLE(pic,
 516   AS_HELP_STRING([--enable-pic],
 517                  [Build LLVM with Position Independent Code (default is YES)]),,
 518                  enableval=default)
 519 case "$enableval" in
 520   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 521   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 522   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 523   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 524 esac
 525 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 526                    [Define if position independent code is enabled])
 527
 528 dnl Allow building a shared library and linking tools against it.
 529 AC_ARG_ENABLE(shared,
 530   AS_HELP_STRING([--enable-shared],
 531                  [Build a shared library and link tools against it (default is NO)]),,
 532                  enableval=default)
 533 case "$enableval" in
 534   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 535   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 536   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 537   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 538 esac
 539
 540 dnl Allow libstdc++ is embedded in LLVM.dll.
 541 AC_ARG_ENABLE(embed-stdcxx,
 542   AS_HELP_STRING([--enable-embed-stdcxx],
 543                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is YES)]),,
 544                  enableval=default)
 545 case "$enableval" in
 546   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 547   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 548   default) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 549   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 550 esac
 551
 552 dnl Enable embedding timestamp information into build.
 553 AC_ARG_ENABLE(timestamps,
 554   AS_HELP_STRING([--enable-timestamps],
 555                  [Enable embedding timestamp information in build (default is YES)]),,
 556                  enableval=default)
 557 case "$enableval" in
 558   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 559   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 560   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 561   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 562 esac
 563 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 564                    [Define if timestamp information (e.g., __DATE___) is allowed])
 565
 566 dnl Allow specific targets to be specified for building (or not)
 567 TARGETS_TO_BUILD=""
 568 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 569     [Build specific host targets: all or target1,target2,... Valid targets are:
 570      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 571      xcore, msp430, nvptx, cbe, r600, and cpp (default=all)]),,
 572     enableval=all)
 573 if test "$enableval" = host-only ; then
 574   enableval=host
 575 fi
 576 case "$enableval" in
 577   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 Hexagon CppBackend MBlaze NVPTX AMDGPU" ;;
 578   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 579       case "$a_target" in
 580         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 581         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 582         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 583         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 584         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 585         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 586         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 587         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 588         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 589         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 590         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 591         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 592         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 593         r600)     TARGETS_TO_BUILD="AMDGPU $TARGETS_TO_BUILD" ;;
 594         host) case "$llvm_cv_target_arch" in
 595             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 596             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 597             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 598             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 599             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 600             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 601             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 602             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 603             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 604             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 605             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 606             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 607             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 608           esac ;;
 609         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 610       esac
 611   done
 612   ;;
 613 esac
 614 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 615
 616 # Determine whether we are building LLVM support for the native architecture.
 617 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 618 for a_target in $TARGETS_TO_BUILD; do
 619   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 620     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 621       [LLVM architecture name for the native architecture, if available])
 622     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 623     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 624     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 625     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 626     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 627       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 628     fi
 629     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 630       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 631     fi
 632     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 633       [LLVM name for the native Target init function, if available])
 634     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 635       [LLVM name for the native TargetInfo init function, if available])
 636     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 637       [LLVM name for the native target MC init function, if available])
 638     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 639       [LLVM name for the native AsmPrinter init function, if available])
 640     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 641       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 642        [LLVM name for the native AsmParser init function, if available])
 643     fi
 644     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 645       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 646        [LLVM name for the native Disassembler init function, if available])
 647     fi
 648   fi
 649 done
 650
 651 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 652 # target feature def files.
 653 LLVM_ENUM_TARGETS=""
 654 LLVM_ENUM_ASM_PRINTERS=""
 655 LLVM_ENUM_ASM_PARSERS=""
 656 LLVM_ENUM_DISASSEMBLERS=""
 657 for target_to_build in $TARGETS_TO_BUILD; do
 658   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 659   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 660     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 661   fi
 662   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 663     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 664   fi
 665   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 666     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 667   fi
 668 done
 669 AC_SUBST(LLVM_ENUM_TARGETS)
 670 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 671 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 672 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 673
 674 dnl Override the option to use for optimized builds.
 675 AC_ARG_WITH(optimize-option,
 676   AS_HELP_STRING([--with-optimize-option],
 677                  [Select the compiler options to use for optimized builds]),,
 678                  withval=default)
 679 AC_MSG_CHECKING([optimization flags])
 680 case "$withval" in
 681   default)
 682     case "$llvm_cv_os_type" in
 683     FreeBSD) optimize_option=-O2 ;;
 684     MingW) optimize_option=-O2 ;;
 685     *)     optimize_option=-O3 ;;
 686     esac ;;
 687   *) optimize_option="$withval" ;;
 688 esac
 689 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 690 AC_MSG_RESULT([$optimize_option])
 691
 692 dnl Specify extra build options
 693 AC_ARG_WITH(extra-options,
 694   AS_HELP_STRING([--with-extra-options],
 695                  [Specify additional options to compile LLVM with]),,
 696                  withval=default)
 697 case "$withval" in
 698   default) EXTRA_OPTIONS= ;;
 699   *) EXTRA_OPTIONS=$withval ;;
 700 esac
 701 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 702
 703 dnl Specify extra linker build options
 704 AC_ARG_WITH(extra-ld-options,
 705   AS_HELP_STRING([--with-extra-ld-options],
 706                  [Specify additional options to link LLVM with]),,
 707                  withval=default)
 708 case "$withval" in
 709   default) EXTRA_LD_OPTIONS= ;;
 710   *) EXTRA_LD_OPTIONS=$withval ;;
 711 esac
 712 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 713
 714 dnl Allow specific bindings to be specified for building (or not)
 715 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 716     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 717     enableval=default)
 718 BINDINGS_TO_BUILD=""
 719 case "$enableval" in
 720   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 721   all ) BINDINGS_TO_BUILD="ocaml" ;;
 722   none | no) BINDINGS_TO_BUILD="" ;;
 723   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 724       case "$a_binding" in
 725         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 726         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 727       esac
 728   done
 729   ;;
 730 esac
 731
 732 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 733 dnl script for bindings/ocaml/configure, except that its auto value depends on
 734 dnl OCAMLC, which is found here to support tests.
 735 AC_ARG_WITH([ocaml-libdir],
 736   [AS_HELP_STRING([--with-ocaml-libdir],
 737     [Specify install location for ocaml bindings (default is stdlib)])],
 738   [],
 739   [withval=auto])
 740 case "$withval" in
 741   auto) with_ocaml_libdir="$withval" ;;
 742   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 743   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 744 esac
 745
 746 AC_ARG_WITH(clang-resource-dir,
 747   AS_HELP_STRING([--with-clang-resource-dir],
 748     [Relative directory from the Clang binary for resource files]),,
 749     withval="")
 750 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 751                    [Relative directory for resource files])
 752
 753 AC_ARG_WITH(c-include-dirs,
 754   AS_HELP_STRING([--with-c-include-dirs],
 755     [Colon separated list of directories clang will search for headers]),,
 756     withval="")
 757 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 758                    [Directories clang will search for headers])
 759
 760 # Clang normally uses the system c++ headers and libraries. With this option,
 761 # clang will use the ones provided by a gcc installation instead. This option should
 762 # be passed the same value that was used with --prefix when configuring gcc.
 763 AC_ARG_WITH(gcc-toolchain,
 764   AS_HELP_STRING([--with-gcc-toolchain],
 765     [Directory where gcc is installed.]),,
 766     withval="")
 767 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 768                    [Directory where gcc is installed.])
 769
 770 dnl Allow linking of LLVM with GPLv3 binutils code.
 771 AC_ARG_WITH(binutils-include,
 772   AS_HELP_STRING([--with-binutils-include],
 773     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 774   withval=default)
 775 case "$withval" in
 776   default) WITH_BINUTILS_INCDIR=default ;;
 777   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 778   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 779 esac
 780 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 781   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 782   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 783      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 784      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 785   fi
 786 fi
 787
 788 dnl Specify the URL where bug reports should be submitted.
 789 AC_ARG_WITH(bug-report-url,
 790   AS_HELP_STRING([--with-bug-report-url],
 791     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 792     withval="http://llvm.org/bugs/")
 793 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 794                    [Bug report URL.])
 795
 796 dnl --enable-libffi : check whether the user wants to turn off libffi:
 797 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 798   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 799   [case "$enableval" in
 800     yes) llvm_cv_enable_libffi="yes" ;;
 801     no)  llvm_cv_enable_libffi="no"  ;;
 802     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 803   esac],
 804   llvm_cv_enable_libffi=no)
 805
 806 dnl===-----------------------------------------------------------------------===
 807 dnl===
 808 dnl=== SECTION 4: Check for programs we need and that they are the right version
 809 dnl===
 810 dnl===-----------------------------------------------------------------------===
 811
 812 AC_PROG_NM
 813 AC_SUBST(NM)
 814
 815 dnl Check for the tools that the makefiles require
 816 AC_CHECK_GNU_MAKE
 817 AC_PROG_LN_S
 818 AC_PATH_PROG(CMP, [cmp], [cmp])
 819 AC_PATH_PROG(CP, [cp], [cp])
 820 AC_PATH_PROG(DATE, [date], [date])
 821 AC_PATH_PROG(FIND, [find], [find])
 822 AC_PATH_PROG(GREP, [grep], [grep])
 823 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 824 AC_PATH_PROG(MV,   [mv],   [mv])
 825 AC_PROG_RANLIB
 826 AC_CHECK_TOOL(AR, ar, false)
 827 AC_PATH_PROG(RM,   [rm],   [rm])
 828 AC_PATH_PROG(SED,  [sed],  [sed])
 829 AC_PATH_PROG(TAR,  [tar],  [gtar])
 830 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 831
 832 dnl Looking for misc. graph plotting software
 833 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 834 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 835   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 836   dnl If we're targeting for mingw we should emit windows paths, not msys
 837   if test "$llvm_cv_os_type" = "MingW" ; then
 838     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 839   fi
 840   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 841    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 842 fi
 843 AC_PATH_PROG(DOT, [dot], [echo dot])
 844 if test "$DOT" != "echo dot" ; then
 845   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 846   dnl If we're targeting for mingw we should emit windows paths, not msys
 847   if test "$llvm_cv_os_type" = "MingW" ; then
 848     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 849   fi
 850   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 851    [Define to path to dot program if found or 'echo dot' otherwise])
 852 fi
 853 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 854 if test "$FDP" != "echo fdp" ; then
 855   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 856   dnl If we're targeting for mingw we should emit windows paths, not msys
 857   if test "$llvm_cv_os_type" = "MingW" ; then
 858     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 859   fi
 860   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 861    [Define to path to fdp program if found or 'echo fdp' otherwise])
 862 fi
 863 AC_PATH_PROG(NEATO, [neato], [echo neato])
 864 if test "$NEATO" != "echo neato" ; then
 865   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 866   dnl If we're targeting for mingw we should emit windows paths, not msys
 867   if test "$llvm_cv_os_type" = "MingW" ; then
 868     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 869   fi
 870   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 871    [Define to path to neato program if found or 'echo neato' otherwise])
 872 fi
 873 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 874 if test "$TWOPI" != "echo twopi" ; then
 875   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 876   dnl If we're targeting for mingw we should emit windows paths, not msys
 877   if test "$llvm_cv_os_type" = "MingW" ; then
 878     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 879   fi
 880   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 881    [Define to path to twopi program if found or 'echo twopi' otherwise])
 882 fi
 883 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 884 if test "$CIRCO" != "echo circo" ; then
 885   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 886   dnl If we're targeting for mingw we should emit windows paths, not msys
 887   if test "$llvm_cv_os_type" = "MingW" ; then
 888     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 889   fi
 890   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 891    [Define to path to circo program if found or 'echo circo' otherwise])
 892 fi
 893 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 894 if test "$GV" != "echo gv" ; then
 895   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 896   dnl If we're targeting for mingw we should emit windows paths, not msys
 897   if test "$llvm_cv_os_type" = "MingW" ; then
 898     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 899   fi
 900   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 901    [Define to path to gv program if found or 'echo gv' otherwise])
 902 fi
 903 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 904 if test "$DOTTY" != "echo dotty" ; then
 905   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 906   dnl If we're targeting for mingw we should emit windows paths, not msys
 907   if test "$llvm_cv_os_type" = "MingW" ; then
 908     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 909   fi
 910   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 911    [Define to path to dotty program if found or 'echo dotty' otherwise])
 912 fi
 913 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 914 if test "$XDOT_PY" != "echo xdot.py" ; then
 915   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 916   dnl If we're targeting for mingw we should emit windows paths, not msys
 917   if test "$llvm_cv_os_type" = "MingW" ; then
 918     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 919   fi
 920   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 921    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 922 fi
 923
 924 dnl Find the install program
 925 AC_PROG_INSTALL
 926 dnl Prepend src dir to install path dir if it's a relative path
 927 dnl This is a hack for installs that take place in something other
 928 dnl than the top level.
 929 case "$INSTALL" in
 930  [[\\/$]]* | ?:[[\\/]]* ) ;;
 931  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 932 esac
 933
 934 dnl Checks for documentation and testing tools that we can do without. If these
 935 dnl are not found then they are set to "true" which always succeeds but does
 936 dnl nothing. This just lets the build output show that we could have done
 937 dnl something if the tool was available.
 938 AC_PATH_PROG(BZIP2, [bzip2])
 939 AC_PATH_PROG(CAT, [cat])
 940 AC_PATH_PROG(DOXYGEN, [doxygen])
 941 AC_PATH_PROG(GROFF, [groff])
 942 AC_PATH_PROG(GZIPBIN, [gzip])
 943 AC_PATH_PROG(POD2HTML, [pod2html])
 944 AC_PATH_PROG(POD2MAN, [pod2man])
 945 AC_PATH_PROG(PDFROFF, [pdfroff])
 946 AC_PATH_PROG(RUNTEST, [runtest])
 947 DJ_AC_PATH_TCLSH
 948 AC_PATH_PROG(ZIP, [zip])
 949 AC_PATH_PROGS(OCAMLC, [ocamlc])
 950 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 951 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 952 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 953 AC_PATH_PROGS(GAS, [gas as])
 954
 955 dnl Get the version of the linker in use.
 956 AC_LINK_GET_VERSION
 957
 958 dnl Determine whether the linker supports the -R option.
 959 AC_LINK_USE_R
 960
 961 dnl Determine whether the linker supports the -export-dynamic option.
 962 AC_LINK_EXPORT_DYNAMIC
 963
 964 dnl Determine whether the linker supports the --version-script option.
 965 AC_LINK_VERSION_SCRIPT
 966
 967 dnl Check for libtool and the library that has dlopen function (which must come
 968 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 969 dnl libtool).
 970 AC_LIBTOOL_DLOPEN
 971 AC_LIB_LTDL
 972
 973 AC_MSG_CHECKING([tool compatibility])
 974
 975 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 976 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 977 dnl to support those options.
 978 dnl "icc" emits gcc signatures
 979 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 980 ICC=no
 981 IXX=no
 982 case $CC in
 983   icc*|icpc*)
 984     ICC=yes
 985     IXX=yes
 986     ;;
 987    *)
 988     ;;
 989 esac
 990
 991 if test "$GCC" != "yes" && test "$ICC" != "yes"
 992 then
 993   AC_MSG_ERROR([gcc|icc required but not found])
 994 fi
 995
 996 dnl Ensure that compilation tools are compatible with GCC extensions
 997 if test "$GXX" != "yes" && test "$IXX" != "yes"
 998 then
 999   AC_MSG_ERROR([g++|clang++|icc required but not found])
1000 fi
1001
1002 dnl Verify that GCC is version 3.0 or higher
1003 if test "$GCC" = "yes"
1004 then
1005   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1006 #error Unsupported GCC version
1007 #endif
1008 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1009 fi
1010
1011 dnl Check for GNU Make.  We use its extensions, so don't build without it
1012 if test -z "$llvm_cv_gnu_make_command"
1013 then
1014   AC_MSG_ERROR([GNU Make required but not found])
1015 fi
1016
1017 dnl Tool compatibility is okay if we make it here.
1018 AC_MSG_RESULT([ok])
1019
1020 dnl Check optional compiler flags.
1021 AC_MSG_CHECKING([optional compiler flags])
1022 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1023 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1024 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1025 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1026
1027 dnl===-----------------------------------------------------------------------===
1028 dnl===
1029 dnl=== SECTION 5: Check for libraries
1030 dnl===
1031 dnl===-----------------------------------------------------------------------===
1032
1033 AC_CHECK_LIB(m,sin)
1034 if test "$llvm_cv_os_type" = "MingW" ; then
1035   AC_CHECK_LIB(imagehlp, main)
1036   AC_CHECK_LIB(psapi, main)
1037 fi
1038
1039 dnl dlopen() is required for plugin support.
1040 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1041                [Define if dlopen() is available on this platform.]),
1042                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1043
1044 dnl libffi is optional; used to call external functions from the interpreter
1045 if test "$llvm_cv_enable_libffi" = "yes" ; then
1046   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1047                  [Define if libffi is available on this platform.]),
1048                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1049 fi
1050
1051 dnl mallinfo is optional; the code can compile (minus features) without it
1052 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1053                [Define if mallinfo() is available on this platform.]))
1054
1055 dnl pthread locking functions are optional - but llvm will not be thread-safe
1056 dnl without locks.
1057 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1058   AC_CHECK_LIB(pthread, pthread_mutex_init)
1059   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1060                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1061                            [Have pthread_mutex_lock]))
1062   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1063                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1064                  [Have pthread_rwlock_init]))
1065   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1066                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1067                  [Have pthread_getspecific]))
1068 fi
1069
1070 dnl Allow extra x86-disassembler library
1071 AC_ARG_WITH(udis86,
1072   AS_HELP_STRING([--with-udis86=<path>],
1073     [Use udis86 external x86 disassembler library]),
1074     [
1075       AC_SUBST(USE_UDIS86, [1])
1076       case "$withval" in
1077         /usr/lib|yes) ;;
1078         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1079       esac
1080       AC_CHECK_LIB(udis86, ud_init, [], [
1081         echo "Error! You need to have libudis86 around."
1082         exit -1
1083       ])
1084     ],
1085     AC_SUBST(USE_UDIS86, [0]))
1086 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1087                    [Define if use udis86 library])
1088
1089 dnl Allow OProfile support for JIT output.
1090 AC_ARG_WITH(oprofile,
1091   AS_HELP_STRING([--with-oprofile=<prefix>],
1092     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1093     [
1094       AC_SUBST(USE_OPROFILE, [1])
1095       case "$withval" in
1096         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1097         no) llvm_cv_oppath=
1098             AC_SUBST(USE_OPROFILE, [0]) ;;
1099         *) llvm_cv_oppath="${withval}/lib/oprofile"
1100            CPPFLAGS="-I${withval}/include";;
1101       esac
1102       if test -n "$llvm_cv_oppath" ; then
1103         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1104         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1105         dnl libbfd is not included properly in libopagent in some Debian
1106         dnl versions.  If libbfd isn't found at all, we assume opagent works
1107         dnl anyway.
1108         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1109         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1110           echo "Error! You need to have libopagent around."
1111           exit -1
1112         ])
1113         AC_CHECK_HEADER([opagent.h], [], [
1114           echo "Error! You need to have opagent.h around."
1115           exit -1
1116           ])
1117       fi
1118     ],
1119     [
1120       AC_SUBST(USE_OPROFILE, [0])
1121     ])
1122 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1123                    [Define if we have the oprofile JIT-support library])
1124
1125 dnl===-----------------------------------------------------------------------===
1126 dnl===
1127 dnl=== SECTION 6: Check for header files
1128 dnl===
1129 dnl===-----------------------------------------------------------------------===
1130
1131 dnl First, use autoconf provided macros for specific headers that we need
1132 dnl We don't check for ancient stuff or things that are guaranteed to be there
1133 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1134 dnl Generally we're looking for POSIX headers.
1135 AC_HEADER_DIRENT
1136 AC_HEADER_MMAP_ANONYMOUS
1137 AC_HEADER_STAT
1138 AC_HEADER_SYS_WAIT
1139 AC_HEADER_TIME
1140
1141 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1142 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1143 AC_CHECK_HEADERS([utime.h windows.h])
1144 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1145 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1146 AC_CHECK_HEADERS([valgrind/valgrind.h])
1147 AC_CHECK_HEADERS([fenv.h])
1148 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1149   AC_CHECK_HEADERS(pthread.h,
1150                    AC_SUBST(HAVE_PTHREAD, 1),
1151                    AC_SUBST(HAVE_PTHREAD, 0))
1152 else
1153   AC_SUBST(HAVE_PTHREAD, 0)
1154 fi
1155
1156 dnl Try to find ffi.h.
1157 if test "$llvm_cv_enable_libffi" = "yes" ; then
1158   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1159 fi
1160
1161 dnl Try to find Darwin specific crash reporting libraries.
1162 AC_CHECK_HEADERS([CrashReporterClient.h])
1163
1164 dnl Try to find Darwin specific crash reporting global.
1165 AC_MSG_CHECKING([__crashreporter_info__])
1166 AC_LINK_IFELSE(
1167   AC_LANG_SOURCE(
1168     [[extern const char *__crashreporter_info__;
1169       int main() {
1170         __crashreporter_info__ = "test";
1171         return 0;
1172       }
1173     ]]),
1174   AC_MSG_RESULT(yes)
1175   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1176   AC_MSG_RESULT(no)
1177   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1178             Define if __crashreporter_info__ exists.))
1179
1180 dnl===-----------------------------------------------------------------------===
1181 dnl===
1182 dnl=== SECTION 7: Check for types and structures
1183 dnl===
1184 dnl===-----------------------------------------------------------------------===
1185
1186 AC_HUGE_VAL_CHECK
1187 AC_TYPE_PID_T
1188 AC_TYPE_SIZE_T
1189 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1190 AC_STRUCT_TM
1191 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1192 AC_CHECK_TYPES([uint64_t],,
1193          AC_CHECK_TYPES([u_int64_t],,
1194          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1195
1196 dnl===-----------------------------------------------------------------------===
1197 dnl===
1198 dnl=== SECTION 8: Check for specific functions needed
1199 dnl===
1200 dnl===-----------------------------------------------------------------------===
1201
1202 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1203 AC_CHECK_FUNCS([powf fmodf strtof round ])
1204 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1205 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1206 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1207 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1208 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1209 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1210 AC_C_PRINTF_A
1211 AC_FUNC_RAND48
1212
1213 dnl Check the declaration "Secure API" on Windows environments.
1214 AC_CHECK_DECLS([strerror_s])
1215
1216 dnl Check symbols in libgcc.a for JIT on Mingw.
1217 if test "$llvm_cv_os_type" = "MingW" ; then
1218   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1219   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1220   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1221   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1222
1223   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1224   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1225   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1226   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1227   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1228   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1229   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1230   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1231   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1232   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1233
1234   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1235   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1236 fi
1237
1238 dnl Check Win32 API EnumerateLoadedModules.
1239 if test "$llvm_cv_os_type" = "MingW" ; then
1240   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1241   AC_COMPILE_IFELSE([[#include <windows.h>
1242 #include <imagehlp.h>
1243 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1244 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1245 [
1246   AC_MSG_RESULT([yes])
1247   llvm_cv_win32_elmcb_pcstr="PCSTR"
1248 ],
1249 [
1250   AC_MSG_RESULT([no])
1251   llvm_cv_win32_elmcb_pcstr="PSTR"
1252 ])
1253   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1254 fi
1255
1256 dnl Check for variations in the Standard C++ library and STL. These macros are
1257 dnl provided by LLVM in the autoconf/m4 directory.
1258 AC_FUNC_ISNAN
1259 AC_FUNC_ISINF
1260
1261 dnl Check for mmap support.We also need to know if /dev/zero is required to
1262 dnl be opened for allocating RWX memory.
1263 dnl Make sure we aren't attempting to configure for an unknown system
1264 if test "$llvm_cv_platform_type" = "Unix" ; then
1265   AC_FUNC_MMAP
1266   AC_FUNC_MMAP_FILE
1267   AC_NEED_DEV_ZERO_FOR_MMAP
1268
1269   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1270   then
1271     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1272   fi
1273   if test "$ac_cv_func_mmap_file" = "no"
1274   then
1275     AC_MSG_WARN([mmap() of files required but not found])
1276   fi
1277 fi
1278
1279 dnl atomic builtins are required for threading support.
1280 AC_MSG_CHECKING(for GCC atomic builtins)
1281 dnl Since we'll be using these atomic builtins in C++ files we should test
1282 dnl the C++ compiler.
1283 AC_LANG_PUSH([C++])
1284 AC_LINK_IFELSE(
1285   AC_LANG_SOURCE(
1286     [[int main() {
1287         volatile unsigned long val = 1;
1288         __sync_synchronize();
1289         __sync_val_compare_and_swap(&val, 1, 0);
1290         __sync_add_and_fetch(&val, 1);
1291         __sync_sub_and_fetch(&val, 1);
1292         return 0;
1293       }
1294     ]]),
1295   AC_LANG_POP([C++])
1296   AC_MSG_RESULT(yes)
1297   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1298   AC_MSG_RESULT(no)
1299   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1300   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1301
1302 dnl===-----------------------------------------------------------------------===
1303 dnl===
1304 dnl=== SECTION 9: Additional checks, variables, etc.
1305 dnl===
1306 dnl===-----------------------------------------------------------------------===
1307
1308 dnl Handle 32-bit linux systems running a 64-bit kernel.
1309 dnl This has to come after section 4 because it invokes the compiler.
1310 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1311   AC_IS_LINUX_MIXED
1312   if test "$llvm_cv_linux_mixed" = "yes"; then
1313     llvm_cv_target_arch="x86"
1314     ARCH="x86"
1315   fi
1316 fi
1317
1318 dnl Check whether __dso_handle is present
1319 AC_CHECK_FUNCS([__dso_handle])
1320
1321 dnl Propagate the shared library extension that the libltdl checks did to
1322 dnl the Makefiles so we can use it there too
1323 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1324
1325 dnl Propagate the run-time library path variable that the libltdl
1326 dnl checks found to the Makefiles so we can use it there too
1327 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1328
1329 # Translate the various configuration directories and other basic
1330 # information into substitutions that will end up in Makefile.config.in
1331 # that these configured values can be used by the makefiles
1332 if test "${prefix}" = "NONE" ; then
1333   prefix="/usr/local"
1334 fi
1335 eval LLVM_PREFIX="${prefix}";
1336 eval LLVM_BINDIR="${prefix}/bin";
1337 eval LLVM_LIBDIR="${prefix}/lib";
1338 eval LLVM_DATADIR="${prefix}/share/llvm";
1339 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1340 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1341 eval LLVM_INCLUDEDIR="${prefix}/include";
1342 eval LLVM_INFODIR="${prefix}/info";
1343 eval LLVM_MANDIR="${prefix}/man";
1344 LLVM_CONFIGTIME=`date`
1345 AC_SUBST(LLVM_PREFIX)
1346 AC_SUBST(LLVM_BINDIR)
1347 AC_SUBST(LLVM_LIBDIR)
1348 AC_SUBST(LLVM_DATADIR)
1349 AC_SUBST(LLVM_DOCSDIR)
1350 AC_SUBST(LLVM_ETCDIR)
1351 AC_SUBST(LLVM_INCLUDEDIR)
1352 AC_SUBST(LLVM_INFODIR)
1353 AC_SUBST(LLVM_MANDIR)
1354 AC_SUBST(LLVM_CONFIGTIME)
1355
1356 # Place the various directores into the config.h file as #defines so that we
1357 # can know about the installation paths within LLVM.
1358 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1359                    [Installation prefix directory])
1360 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1361                    [Installation directory for binary executables])
1362 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1363                    [Installation directory for libraries])
1364 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1365                    [Installation directory for data files])
1366 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1367                    [Installation directory for documentation])
1368 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1369                    [Installation directory for config files])
1370 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1371                    [Installation directory for include files])
1372 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1373                    [Installation directory for .info files])
1374 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1375                    [Installation directory for man pages])
1376 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1377                    [Time at which LLVM was configured])
1378 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1379                    [Target triple LLVM will generate code for by default])
1380
1381 # Determine which bindings to build.
1382 if test "$BINDINGS_TO_BUILD" = auto ; then
1383   BINDINGS_TO_BUILD=""
1384   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1385     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1386   fi
1387 fi
1388 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1389
1390 # This isn't really configurey, but it avoids having to repeat the list in
1391 # other files.
1392 AC_SUBST(ALL_BINDINGS,ocaml)
1393
1394 # Do any work necessary to ensure that bindings have what they need.
1395 binding_prereqs_failed=0
1396 for a_binding in $BINDINGS_TO_BUILD ; do
1397   case "$a_binding" in
1398   ocaml)
1399     if test "x$OCAMLC" = x ; then
1400       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1401       binding_prereqs_failed=1
1402     fi
1403     if test "x$OCAMLDEP" = x ; then
1404       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1405       binding_prereqs_failed=1
1406     fi
1407     if test "x$OCAMLOPT" = x ; then
1408       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1409       dnl ocamlopt is optional!
1410     fi
1411     if test "x$with_ocaml_libdir" != xauto ; then
1412       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1413     else
1414       ocaml_stdlib="`"$OCAMLC" -where`"
1415       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1416       then
1417         # ocaml stdlib is beneath our prefix; use stdlib
1418         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1419       else
1420         # ocaml stdlib is outside our prefix; use libdir/ocaml
1421         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1422       fi
1423     fi
1424     ;;
1425   esac
1426 done
1427 if test "$binding_prereqs_failed" = 1 ; then
1428   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1429 fi
1430
1431 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1432 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1433
1434 dnl Determine linker rpath flag
1435 if test "$llvm_cv_link_use_r" = "yes" ; then
1436   RPATH="-Wl,-R"
1437 else
1438   RPATH="-Wl,-rpath"
1439 fi
1440 AC_SUBST(RPATH)
1441
1442 dnl Determine linker rdynamic flag
1443 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1444   RDYNAMIC="-Wl,-export-dynamic"
1445 else
1446   RDYNAMIC=""
1447 fi
1448 AC_SUBST(RDYNAMIC)
1449
1450 dnl===-----------------------------------------------------------------------===
1451 dnl===
1452 dnl=== SECTION 10: Specify the output files and generate it
1453 dnl===
1454 dnl===-----------------------------------------------------------------------===
1455
1456 dnl **************************************************************************
1457 dnl End LLVM configure.ac Import
1458 dnl **************************************************************************
1459
1460 dnl Configure a common Makefile
1461 AC_CONFIG_FILES(Makefile.common)
1462 AC_CONFIG_FILES(Makefile.llvm.config)
1463
1464 dnl Configure project makefiles
1465 dnl List every Makefile that exists within your source tree
1466 AC_CONFIG_MAKEFILE(Makefile)
1467 AC_CONFIG_MAKEFILE(lib/Makefile)
1468 AC_CONFIG_MAKEFILE(lib/sample/Makefile)
1469 AC_CONFIG_MAKEFILE(tools/Makefile)
1470 AC_CONFIG_MAKEFILE(tools/sample/Makefile)
1471
1472 dnl This must be last
1473 AC_OUTPUT