projects/sample/autoconf/configure.ac

   1 dnl **************************************************************************
   2 dnl * Initialize
   3 dnl **************************************************************************
   4 AC_INIT([[[SAMPLE]]],[[[x.xx]]],[bugs@yourdomain])
   5
   6 dnl Identify where LLVM source tree is
   7 LLVM_SRC_ROOT="../.."
   8 LLVM_OBJ_ROOT="../.."
   9
  10 dnl Find absolute paths to LLVM source and object trees
  11 LLVM_ABS_SRC_ROOT="`cd $srcdir ; cd $LLVM_SRC_ROOT ; pwd`"
  12 LLVM_ABS_OBJ_ROOT="`cd $LLVM_OBJ_ROOT ; pwd`"
  13
  14 dnl Tell autoconf that this is an LLVM project being configured
  15 dnl This provides the --with-llvmsrc and --with-llvmobj options
  16 LLVM_CONFIG_PROJECT($LLVM_ABS_SRC_ROOT,$LLVM_ABS_OBJ_ROOT)
  17
  18 dnl Try and find an llvm-config in the build directory. We are only using this
  19 dnl to detect the package level LLVM information (currently just the version),
  20 dnl so we just whatever one we find regardless of build mode.
  21 AC_MSG_CHECKING([llvm-config])
  22 llvm_config_path="`ls -1 $llvm_obj/*/bin/llvm-config 2> /dev/null | head -1`"
  23 if ! test -f "$llvm_config_path" ; then
  24    llvm_config_path="no"
  25 fi
  26 AC_MSG_RESULT([$llvm_config_path])
  27
  28 dnl Determine the LLVM version, which may be required by the current Makefile
  29 dnl rules.
  30 AC_MSG_CHECKING([LLVM package version])
  31 if test "$llvm_config_path" != no ; then
  32   llvm_package_version=`$llvm_config_path --version`
  33 else
  34   llvm_package_version="unknown";
  35 fi
  36 AC_MSG_RESULT([$llvm_package_version])
  37 AC_SUBST(LLVM_VERSION, [$llvm_package_version])
  38
  39 dnl Verify that the source directory is valid
  40 AC_CONFIG_SRCDIR(["Makefile.common.in"])
  41
  42 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  43 dnl various tools where the m4 autoconf macros are.
  44 AC_CONFIG_AUX_DIR([autoconf])
  45
  46 dnl **************************************************************************
  47 dnl Begin LLVM configure.ac Import
  48 dnl **************************************************************************
  49 dnl
  50 dnl Derived from LLVM's configure.ac. This was imported directly here so that we
  51 dnl could reuse LLVM's build infrastructure without introducing a direct source
  52 dnl dependency on the LLVM files.
  53
  54 dnl We need to check for the compiler up here to avoid anything else
  55 dnl starting with a different one.
  56 AC_PROG_CC(clang llvm-gcc gcc)
  57 AC_PROG_CXX(clang++ llvm-g++ g++)
  58 AC_PROG_CPP
  59
  60 dnl Configure all of the projects present in our source tree. While we could
  61 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  62 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  63 dnl Instead we match on the known projects.
  64
  65 dnl
  66 dnl One tricky part of doing this is that some projects depend upon other
  67 dnl projects.  For example, several projects rely upon the LLVM test suite.
  68 dnl We want to configure those projects first so that their object trees are
  69 dnl created before running the configure scripts of projects that depend upon
  70 dnl them.
  71 dnl
  72
  73 dnl Disable the build of polly, even if it is checked out into tools/polly.
  74 AC_ARG_ENABLE(polly,
  75               AS_HELP_STRING([--enable-polly],
  76                              [Use polly if available (default is YES)]),,
  77                              enableval=default)
  78 case "$enableval" in
  79   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
  80   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
  81   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
  82   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
  83 esac
  84
  85
  86 dnl Check if polly is checked out into tools/polly and configure it if
  87 dnl available.
  88 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
  89   AC_SUBST(LLVM_HAS_POLLY,1)
  90   AC_CONFIG_SUBDIRS([tools/polly])
  91 fi
  92
  93 dnl===-----------------------------------------------------------------------===
  94 dnl===
  95 dnl=== SECTION 2: Architecture, target, and host checks
  96 dnl===
  97 dnl===-----------------------------------------------------------------------===
  98
  99 dnl Check the target for which we're compiling and the host that will do the
 100 dnl compilations. This will tell us which LLVM compiler will be used for
 101 dnl compiling SSA into object code. This needs to be done early because
 102 dnl following tests depend on it.
 103 AC_CANONICAL_TARGET
 104
 105 dnl Determine the platform type and cache its value. This helps us configure
 106 dnl the System library to the correct build platform.
 107 AC_CACHE_CHECK([type of operating system we're going to host on],
 108                [llvm_cv_os_type],
 109 [case $host in
 110   *-*-aix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="AIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-irix*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="IRIX"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-cygwin*)
 121     llvm_cv_link_all_option="-Wl,--whole-archive"
 122     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 123     llvm_cv_os_type="Cygwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-darwin*)
 126     llvm_cv_link_all_option="-Wl,-all_load"
 127     llvm_cv_no_link_all_option="-Wl,-noall_load"
 128     llvm_cv_os_type="Darwin"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-minix*)
 131     llvm_cv_link_all_option="-Wl,-all_load"
 132     llvm_cv_no_link_all_option="-Wl,-noall_load"
 133     llvm_cv_os_type="Minix"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-freebsd* | *-*-kfreebsd-gnu)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="FreeBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-openbsd*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="OpenBSD"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-netbsd*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="NetBSD"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-dragonfly*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="DragonFly"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-hpux*)
 156     llvm_cv_link_all_option="-Wl,--whole-archive"
 157     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 158     llvm_cv_os_type="HP-UX"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-interix*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Interix"
 164     llvm_cv_platform_type="Unix" ;;
 165   *-*-linux*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="Linux"
 169     llvm_cv_platform_type="Unix" ;;
 170   *-*-gnu*)
 171     llvm_cv_link_all_option="-Wl,--whole-archive"
 172     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 173     llvm_cv_os_type="GNU"
 174     llvm_cv_platform_type="Unix" ;;
 175   *-*-solaris*)
 176     llvm_cv_link_all_option="-Wl,-z,allextract"
 177     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 178     llvm_cv_os_type="SunOS"
 179     llvm_cv_platform_type="Unix" ;;
 180   *-*-auroraux*)
 181     llvm_cv_link_all_option="-Wl,-z,allextract"
 182     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 183     llvm_cv_os_type="AuroraUX"
 184     llvm_cv_platform_type="Unix" ;;
 185   *-*-win32*)
 186     llvm_cv_link_all_option="-Wl,--whole-archive"
 187     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 188     llvm_cv_os_type="Win32"
 189     llvm_cv_platform_type="Win32" ;;
 190   *-*-mingw*)
 191     llvm_cv_link_all_option="-Wl,--whole-archive"
 192     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 193     llvm_cv_os_type="MingW"
 194     llvm_cv_platform_type="Win32" ;;
 195   *-*-haiku*)
 196     llvm_cv_link_all_option="-Wl,--whole-archive"
 197     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 198     llvm_cv_os_type="Haiku"
 199     llvm_cv_platform_type="Unix" ;;
 200   *-unknown-eabi*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="Freestanding"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-unknown-elf*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="Freestanding"
 209     llvm_cv_platform_type="Unix" ;;
 210   *)
 211     llvm_cv_link_all_option=""
 212     llvm_cv_no_link_all_option=""
 213     llvm_cv_os_type="Unknown"
 214     llvm_cv_platform_type="Unknown" ;;
 215 esac])
 216
 217 AC_CACHE_CHECK([type of operating system we're going to target],
 218                [llvm_cv_target_os_type],
 219 [case $target in
 220   *-*-aix*)
 221     llvm_cv_target_os_type="AIX" ;;
 222   *-*-irix*)
 223     llvm_cv_target_os_type="IRIX" ;;
 224   *-*-cygwin*)
 225     llvm_cv_target_os_type="Cygwin" ;;
 226   *-*-darwin*)
 227     llvm_cv_target_os_type="Darwin" ;;
 228   *-*-minix*)
 229     llvm_cv_target_os_type="Minix" ;;
 230   *-*-freebsd* | *-*-kfreebsd-gnu)
 231     llvm_cv_target_os_type="FreeBSD" ;;
 232   *-*-openbsd*)
 233     llvm_cv_target_os_type="OpenBSD" ;;
 234   *-*-netbsd*)
 235     llvm_cv_target_os_type="NetBSD" ;;
 236   *-*-dragonfly*)
 237     llvm_cv_target_os_type="DragonFly" ;;
 238   *-*-hpux*)
 239     llvm_cv_target_os_type="HP-UX" ;;
 240   *-*-interix*)
 241     llvm_cv_target_os_type="Interix" ;;
 242   *-*-linux*)
 243     llvm_cv_target_os_type="Linux" ;;
 244   *-*-gnu*)
 245     llvm_cv_target_os_type="GNU" ;;
 246   *-*-solaris*)
 247     llvm_cv_target_os_type="SunOS" ;;
 248   *-*-auroraux*)
 249     llvm_cv_target_os_type="AuroraUX" ;;
 250   *-*-win32*)
 251     llvm_cv_target_os_type="Win32" ;;
 252   *-*-mingw*)
 253     llvm_cv_target_os_type="MingW" ;;
 254   *-*-haiku*)
 255     llvm_cv_target_os_type="Haiku" ;;
 256   *-*-rtems*)
 257     llvm_cv_target_os_type="RTEMS" ;;
 258   *-*-nacl*)
 259     llvm_cv_target_os_type="NativeClient" ;;
 260   *-unknown-eabi*)
 261     llvm_cv_target_os_type="Freestanding" ;;
 262   *)
 263     llvm_cv_target_os_type="Unknown" ;;
 264 esac])
 265
 266 dnl Make sure we aren't attempting to configure for an unknown system
 267 if test "$llvm_cv_os_type" = "Unknown" ; then
 268   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 269 fi
 270
 271 dnl Set the "OS" Makefile variable based on the platform type so the
 272 dnl makefile can configure itself to specific build hosts
 273 AC_SUBST(OS,$llvm_cv_os_type)
 274 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 275 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 276
 277 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 278 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 279 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 280
 281 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 282 dnl This is used by lib/Support to determine the basic kind of implementation
 283 dnl to use.
 284 case $llvm_cv_platform_type in
 285   Unix)
 286     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 287     AC_SUBST(LLVM_ON_UNIX,[1])
 288     AC_SUBST(LLVM_ON_WIN32,[0])
 289     ;;
 290   Win32)
 291     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 292     AC_SUBST(LLVM_ON_UNIX,[0])
 293     AC_SUBST(LLVM_ON_WIN32,[1])
 294     ;;
 295 esac
 296
 297 dnl Determine what our target architecture is and configure accordingly.
 298 dnl This will allow Makefiles to make a distinction between the hardware and
 299 dnl the OS.
 300 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 301 [case $target in
 302   i?86-*)                 llvm_cv_target_arch="x86" ;;
 303   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 304   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 305   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 306   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 307   mips-*)                 llvm_cv_target_arch="Mips" ;;
 308   xcore-*)                llvm_cv_target_arch="XCore" ;;
 309   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 310   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 311   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 312   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 313   *)                      llvm_cv_target_arch="Unknown" ;;
 314 esac])
 315
 316 if test "$llvm_cv_target_arch" = "Unknown" ; then
 317   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 318 fi
 319
 320 # Determine the LLVM native architecture for the target
 321 case "$llvm_cv_target_arch" in
 322     x86)     LLVM_NATIVE_ARCH="X86" ;;
 323     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 324     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 325 esac
 326
 327 dnl Define a substitution, ARCH, for the target architecture
 328 AC_SUBST(ARCH,$llvm_cv_target_arch)
 329
 330 dnl Check for the endianness of the target
 331 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 332
 333 dnl Check for build platform executable suffix if we're crosscompiling
 334 if test "$cross_compiling" = yes; then
 335   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 336   AC_BUILD_EXEEXT
 337   ac_build_prefix=${build_alias}-
 338   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 339   if test -z "$BUILD_CXX"; then
 340      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 341      if test -z "$BUILD_CXX"; then
 342        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 343      fi
 344   fi
 345 else
 346   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 347 fi
 348
 349 dnl Check to see if there's a .svn or .git directory indicating that this
 350 dnl build is being done from a checkout. This sets up several defaults for
 351 dnl the command line switches. When we build with a checkout directory,
 352 dnl we get a debug with assertions turned on. Without, we assume a source
 353 dnl release and we get an optimized build without assertions.
 354 dnl See --enable-optimized and --enable-assertions below
 355 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 356   cvsbuild="yes"
 357   optimize="no"
 358   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 359 else
 360   cvsbuild="no"
 361   optimize="yes"
 362 fi
 363
 364 dnl===-----------------------------------------------------------------------===
 365 dnl===
 366 dnl=== SECTION 3: Command line arguments for the configure script.
 367 dnl===
 368 dnl===-----------------------------------------------------------------------===
 369
 370 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 371 AC_ARG_ENABLE(libcpp,
 372               AS_HELP_STRING([--enable-libcpp],
 373                              [Use libc++ if available (default is NO)]),,
 374                              enableval=default)
 375 case "$enableval" in
 376   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 377   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 378   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 379   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 380 esac
 381
 382 dnl --enable-optimized : check whether they want to do an optimized build:
 383 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 384  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 385 if test ${enableval} = "no" ; then
 386   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 387 else
 388   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 389 fi
 390
 391 dnl --enable-profiling : check whether they want to do a profile build:
 392 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 393  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 394 if test ${enableval} = "no" ; then
 395   AC_SUBST(ENABLE_PROFILING,[[]])
 396 else
 397   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 398 fi
 399
 400 dnl --enable-assertions : check whether they want to turn on assertions or not:
 401 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 402   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 403 if test ${enableval} = "yes" ; then
 404   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 405 else
 406   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 407 fi
 408
 409 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 410 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 411   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 412 if test ${enableval} = "yes" ; then
 413   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 414   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 415 else
 416   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 417   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 418 fi
 419
 420 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 421 AC_ARG_ENABLE(debug-runtime,
 422    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 423 if test ${enableval} = "no" ; then
 424   AC_SUBST(DEBUG_RUNTIME,[[]])
 425 else
 426   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 427 fi
 428
 429 dnl --enable-debug-symbols : should even optimized compiler libraries
 430 dnl have debug symbols?
 431 AC_ARG_ENABLE(debug-symbols,
 432    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 433 if test ${enableval} = "no" ; then
 434   AC_SUBST(DEBUG_SYMBOLS,[[]])
 435 else
 436   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 437 fi
 438
 439 dnl --enable-jit: check whether they want to enable the jit
 440 AC_ARG_ENABLE(jit,
 441   AS_HELP_STRING(--enable-jit,
 442                  [Enable Just In Time Compiling (default is YES)]),,
 443   enableval=default)
 444 if test ${enableval} = "no"
 445 then
 446   AC_SUBST(JIT,[[]])
 447 else
 448   case "$llvm_cv_target_arch" in
 449     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 450     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 451     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 452     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 453     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 454     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 455     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 456     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 457     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 458     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 459     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 460     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 461   esac
 462 fi
 463
 464 dnl Allow enablement of building and installing docs
 465 AC_ARG_ENABLE(docs,
 466               AS_HELP_STRING([--enable-docs],
 467                              [Build documents (default is YES)]),,
 468                              enableval=default)
 469 case "$enableval" in
 470   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 471   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 472   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 473   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 474 esac
 475
 476 dnl Allow enablement of doxygen generated documentation
 477 AC_ARG_ENABLE(doxygen,
 478               AS_HELP_STRING([--enable-doxygen],
 479                              [Build doxygen documentation (default is NO)]),,
 480                              enableval=default)
 481 case "$enableval" in
 482   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 483   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 484   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 485   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 486 esac
 487
 488 dnl Allow disablement of threads
 489 AC_ARG_ENABLE(threads,
 490               AS_HELP_STRING([--enable-threads],
 491                              [Use threads if available (default is YES)]),,
 492                              enableval=default)
 493 case "$enableval" in
 494   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 495   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 496   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 497   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 498 esac
 499 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 500
 501 dnl Allow disablement of pthread.h
 502 AC_ARG_ENABLE(pthreads,
 503               AS_HELP_STRING([--enable-pthreads],
 504                              [Use pthreads if available (default is YES)]),,
 505                              enableval=default)
 506 case "$enableval" in
 507   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 508   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 509   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 510   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 511 esac
 512
 513 dnl Allow building without position independent code
 514 AC_ARG_ENABLE(pic,
 515   AS_HELP_STRING([--enable-pic],
 516                  [Build LLVM with Position Independent Code (default is YES)]),,
 517                  enableval=default)
 518 case "$enableval" in
 519   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 520   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 521   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 522   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 523 esac
 524 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 525                    [Define if position independent code is enabled])
 526
 527 dnl Allow building a shared library and linking tools against it.
 528 AC_ARG_ENABLE(shared,
 529   AS_HELP_STRING([--enable-shared],
 530                  [Build a shared library and link tools against it (default is NO)]),,
 531                  enableval=default)
 532 case "$enableval" in
 533   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 534   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 535   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 536   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 537 esac
 538
 539 dnl Allow libstdc++ is embedded in LLVM.dll.
 540 AC_ARG_ENABLE(embed-stdcxx,
 541   AS_HELP_STRING([--enable-embed-stdcxx],
 542                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is YES)]),,
 543                  enableval=default)
 544 case "$enableval" in
 545   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 546   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 547   default) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 548   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 549 esac
 550
 551 dnl Enable embedding timestamp information into build.
 552 AC_ARG_ENABLE(timestamps,
 553   AS_HELP_STRING([--enable-timestamps],
 554                  [Enable embedding timestamp information in build (default is YES)]),,
 555                  enableval=default)
 556 case "$enableval" in
 557   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 558   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 559   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 560   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 561 esac
 562 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 563                    [Define if timestamp information (e.g., __DATE___) is allowed])
 564
 565 dnl Allow specific targets to be specified for building (or not)
 566 TARGETS_TO_BUILD=""
 567 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 568     [Build specific host targets: all or target1,target2,... Valid targets are:
 569      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 570      xcore, msp430, ptx, cbe, and cpp (default=all)]),,
 571     enableval=all)
 572 if test "$enableval" = host-only ; then
 573   enableval=host
 574 fi
 575 case "$enableval" in
 576   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 Hexagon CppBackend MBlaze PTX" ;;
 577   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 578       case "$a_target" in
 579         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 580         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 581         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 582         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 583         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 584         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 585         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 586         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 587         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 588         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 589         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 590         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 591         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 592         host) case "$llvm_cv_target_arch" in
 593             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 594             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 595             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 596             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 597             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 598             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 599             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 600             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 601             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 602             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 603             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 604             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 605             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 606           esac ;;
 607         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 608       esac
 609   done
 610   ;;
 611 esac
 612 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 613
 614 # Determine whether we are building LLVM support for the native architecture.
 615 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 616 for a_target in $TARGETS_TO_BUILD; do
 617   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 618     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 619       [LLVM architecture name for the native architecture, if available])
 620     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 621     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 622     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 623     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 624     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 625       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 626     fi
 627     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 628       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 629     fi
 630     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 631       [LLVM name for the native Target init function, if available])
 632     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 633       [LLVM name for the native TargetInfo init function, if available])
 634     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 635       [LLVM name for the native target MC init function, if available])
 636     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 637       [LLVM name for the native AsmPrinter init function, if available])
 638     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 639       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 640        [LLVM name for the native AsmParser init function, if available])
 641     fi
 642     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 643       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 644        [LLVM name for the native Disassembler init function, if available])
 645     fi
 646   fi
 647 done
 648
 649 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 650 # target feature def files.
 651 LLVM_ENUM_TARGETS=""
 652 LLVM_ENUM_ASM_PRINTERS=""
 653 LLVM_ENUM_ASM_PARSERS=""
 654 LLVM_ENUM_DISASSEMBLERS=""
 655 for target_to_build in $TARGETS_TO_BUILD; do
 656   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 657   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 658     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 659   fi
 660   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 661     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 662   fi
 663   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 664     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 665   fi
 666 done
 667 AC_SUBST(LLVM_ENUM_TARGETS)
 668 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 669 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 670 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 671
 672 dnl Override the option to use for optimized builds.
 673 AC_ARG_WITH(optimize-option,
 674   AS_HELP_STRING([--with-optimize-option],
 675                  [Select the compiler options to use for optimized builds]),,
 676                  withval=default)
 677 AC_MSG_CHECKING([optimization flags])
 678 case "$withval" in
 679   default)
 680     case "$llvm_cv_os_type" in
 681     FreeBSD) optimize_option=-O2 ;;
 682     MingW) optimize_option=-O2 ;;
 683     *)     optimize_option=-O3 ;;
 684     esac ;;
 685   *) optimize_option="$withval" ;;
 686 esac
 687 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 688 AC_MSG_RESULT([$optimize_option])
 689
 690 dnl Specify extra build options
 691 AC_ARG_WITH(extra-options,
 692   AS_HELP_STRING([--with-extra-options],
 693                  [Specify additional options to compile LLVM with]),,
 694                  withval=default)
 695 case "$withval" in
 696   default) EXTRA_OPTIONS= ;;
 697   *) EXTRA_OPTIONS=$withval ;;
 698 esac
 699 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 700
 701 dnl Specify extra linker build options
 702 AC_ARG_WITH(extra-ld-options,
 703   AS_HELP_STRING([--with-extra-ld-options],
 704                  [Specify additional options to link LLVM with]),,
 705                  withval=default)
 706 case "$withval" in
 707   default) EXTRA_LD_OPTIONS= ;;
 708   *) EXTRA_LD_OPTIONS=$withval ;;
 709 esac
 710 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 711
 712 dnl Allow specific bindings to be specified for building (or not)
 713 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 714     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 715     enableval=default)
 716 BINDINGS_TO_BUILD=""
 717 case "$enableval" in
 718   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 719   all ) BINDINGS_TO_BUILD="ocaml" ;;
 720   none | no) BINDINGS_TO_BUILD="" ;;
 721   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 722       case "$a_binding" in
 723         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 724         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 725       esac
 726   done
 727   ;;
 728 esac
 729
 730 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 731 dnl script for bindings/ocaml/configure, except that its auto value depends on
 732 dnl OCAMLC, which is found here to support tests.
 733 AC_ARG_WITH([ocaml-libdir],
 734   [AS_HELP_STRING([--with-ocaml-libdir],
 735     [Specify install location for ocaml bindings (default is stdlib)])],
 736   [],
 737   [withval=auto])
 738 case "$withval" in
 739   auto) with_ocaml_libdir="$withval" ;;
 740   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 741   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 742 esac
 743
 744 AC_ARG_WITH(clang-resource-dir,
 745   AS_HELP_STRING([--with-clang-resource-dir],
 746     [Relative directory from the Clang binary for resource files]),,
 747     withval="")
 748 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 749                    [Relative directory for resource files])
 750
 751 AC_ARG_WITH(c-include-dirs,
 752   AS_HELP_STRING([--with-c-include-dirs],
 753     [Colon separated list of directories clang will search for headers]),,
 754     withval="")
 755 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 756                    [Directories clang will search for headers])
 757
 758 # Clang normally uses the system c++ headers and libraries. With this option,
 759 # clang will use the ones provided by a gcc installation instead. This option should
 760 # be passed the same value that was used with --prefix when configuring gcc.
 761 AC_ARG_WITH(gcc-toolchain,
 762   AS_HELP_STRING([--with-gcc-toolchain],
 763     [Directory where gcc is installed.]),,
 764     withval="")
 765 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 766                    [Directory where gcc is installed.])
 767
 768 dnl Allow linking of LLVM with GPLv3 binutils code.
 769 AC_ARG_WITH(binutils-include,
 770   AS_HELP_STRING([--with-binutils-include],
 771     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 772   withval=default)
 773 case "$withval" in
 774   default) WITH_BINUTILS_INCDIR=default ;;
 775   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 776   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 777 esac
 778 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 779   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 780   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 781      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 782      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 783   fi
 784 fi
 785
 786 dnl Specify the URL where bug reports should be submitted.
 787 AC_ARG_WITH(bug-report-url,
 788   AS_HELP_STRING([--with-bug-report-url],
 789     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 790     withval="http://llvm.org/bugs/")
 791 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 792                    [Bug report URL.])
 793
 794 dnl --enable-libffi : check whether the user wants to turn off libffi:
 795 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 796   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 797   [case "$enableval" in
 798     yes) llvm_cv_enable_libffi="yes" ;;
 799     no)  llvm_cv_enable_libffi="no"  ;;
 800     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 801   esac],
 802   llvm_cv_enable_libffi=no)
 803
 804 dnl===-----------------------------------------------------------------------===
 805 dnl===
 806 dnl=== SECTION 4: Check for programs we need and that they are the right version
 807 dnl===
 808 dnl===-----------------------------------------------------------------------===
 809
 810 AC_PROG_NM
 811 AC_SUBST(NM)
 812
 813 dnl Check for the tools that the makefiles require
 814 AC_CHECK_GNU_MAKE
 815 AC_PROG_LN_S
 816 AC_PATH_PROG(CMP, [cmp], [cmp])
 817 AC_PATH_PROG(CP, [cp], [cp])
 818 AC_PATH_PROG(DATE, [date], [date])
 819 AC_PATH_PROG(FIND, [find], [find])
 820 AC_PATH_PROG(GREP, [grep], [grep])
 821 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 822 AC_PATH_PROG(MV,   [mv],   [mv])
 823 AC_PROG_RANLIB
 824 AC_CHECK_TOOL(AR, ar, false)
 825 AC_PATH_PROG(RM,   [rm],   [rm])
 826 AC_PATH_PROG(SED,  [sed],  [sed])
 827 AC_PATH_PROG(TAR,  [tar],  [gtar])
 828 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 829
 830 dnl Looking for misc. graph plotting software
 831 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 832 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 833   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 834   dnl If we're targeting for mingw we should emit windows paths, not msys
 835   if test "$llvm_cv_os_type" = "MingW" ; then
 836     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 837   fi
 838   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 839    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 840 fi
 841 AC_PATH_PROG(DOT, [dot], [echo dot])
 842 if test "$DOT" != "echo dot" ; then
 843   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 844   dnl If we're targeting for mingw we should emit windows paths, not msys
 845   if test "$llvm_cv_os_type" = "MingW" ; then
 846     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 847   fi
 848   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 849    [Define to path to dot program if found or 'echo dot' otherwise])
 850 fi
 851 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 852 if test "$FDP" != "echo fdp" ; then
 853   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 854   dnl If we're targeting for mingw we should emit windows paths, not msys
 855   if test "$llvm_cv_os_type" = "MingW" ; then
 856     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 857   fi
 858   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 859    [Define to path to fdp program if found or 'echo fdp' otherwise])
 860 fi
 861 AC_PATH_PROG(NEATO, [neato], [echo neato])
 862 if test "$NEATO" != "echo neato" ; then
 863   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 864   dnl If we're targeting for mingw we should emit windows paths, not msys
 865   if test "$llvm_cv_os_type" = "MingW" ; then
 866     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 867   fi
 868   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 869    [Define to path to neato program if found or 'echo neato' otherwise])
 870 fi
 871 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 872 if test "$TWOPI" != "echo twopi" ; then
 873   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 874   dnl If we're targeting for mingw we should emit windows paths, not msys
 875   if test "$llvm_cv_os_type" = "MingW" ; then
 876     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 877   fi
 878   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 879    [Define to path to twopi program if found or 'echo twopi' otherwise])
 880 fi
 881 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 882 if test "$CIRCO" != "echo circo" ; then
 883   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 884   dnl If we're targeting for mingw we should emit windows paths, not msys
 885   if test "$llvm_cv_os_type" = "MingW" ; then
 886     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 887   fi
 888   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 889    [Define to path to circo program if found or 'echo circo' otherwise])
 890 fi
 891 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 892 if test "$GV" != "echo gv" ; then
 893   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 894   dnl If we're targeting for mingw we should emit windows paths, not msys
 895   if test "$llvm_cv_os_type" = "MingW" ; then
 896     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 897   fi
 898   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 899    [Define to path to gv program if found or 'echo gv' otherwise])
 900 fi
 901 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 902 if test "$DOTTY" != "echo dotty" ; then
 903   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 904   dnl If we're targeting for mingw we should emit windows paths, not msys
 905   if test "$llvm_cv_os_type" = "MingW" ; then
 906     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 907   fi
 908   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 909    [Define to path to dotty program if found or 'echo dotty' otherwise])
 910 fi
 911 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 912 if test "$XDOT_PY" != "echo xdot.py" ; then
 913   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 914   dnl If we're targeting for mingw we should emit windows paths, not msys
 915   if test "$llvm_cv_os_type" = "MingW" ; then
 916     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 917   fi
 918   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 919    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 920 fi
 921
 922 dnl Find the install program
 923 AC_PROG_INSTALL
 924 dnl Prepend src dir to install path dir if it's a relative path
 925 dnl This is a hack for installs that take place in something other
 926 dnl than the top level.
 927 case "$INSTALL" in
 928  [[\\/$]]* | ?:[[\\/]]* ) ;;
 929  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 930 esac
 931
 932 dnl Checks for documentation and testing tools that we can do without. If these
 933 dnl are not found then they are set to "true" which always succeeds but does
 934 dnl nothing. This just lets the build output show that we could have done
 935 dnl something if the tool was available.
 936 AC_PATH_PROG(BZIP2, [bzip2])
 937 AC_PATH_PROG(CAT, [cat])
 938 AC_PATH_PROG(DOXYGEN, [doxygen])
 939 AC_PATH_PROG(GROFF, [groff])
 940 AC_PATH_PROG(GZIPBIN, [gzip])
 941 AC_PATH_PROG(POD2HTML, [pod2html])
 942 AC_PATH_PROG(POD2MAN, [pod2man])
 943 AC_PATH_PROG(PDFROFF, [pdfroff])
 944 AC_PATH_PROG(RUNTEST, [runtest])
 945 DJ_AC_PATH_TCLSH
 946 AC_PATH_PROG(ZIP, [zip])
 947 AC_PATH_PROGS(OCAMLC, [ocamlc])
 948 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 949 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 950 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 951 AC_PATH_PROGS(GAS, [gas as])
 952
 953 dnl Get the version of the linker in use.
 954 AC_LINK_GET_VERSION
 955
 956 dnl Determine whether the linker supports the -R option.
 957 AC_LINK_USE_R
 958
 959 dnl Determine whether the linker supports the -export-dynamic option.
 960 AC_LINK_EXPORT_DYNAMIC
 961
 962 dnl Determine whether the linker supports the --version-script option.
 963 AC_LINK_VERSION_SCRIPT
 964
 965 dnl Check for libtool and the library that has dlopen function (which must come
 966 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 967 dnl libtool).
 968 AC_LIBTOOL_DLOPEN
 969 AC_LIB_LTDL
 970
 971 AC_MSG_CHECKING([tool compatibility])
 972
 973 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 974 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 975 dnl to support those options.
 976 dnl "icc" emits gcc signatures
 977 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 978 ICC=no
 979 IXX=no
 980 case $CC in
 981   icc*|icpc*)
 982     ICC=yes
 983     IXX=yes
 984     ;;
 985    *)
 986     ;;
 987 esac
 988
 989 if test "$GCC" != "yes" && test "$ICC" != "yes"
 990 then
 991   AC_MSG_ERROR([gcc|icc required but not found])
 992 fi
 993
 994 dnl Ensure that compilation tools are compatible with GCC extensions
 995 if test "$GXX" != "yes" && test "$IXX" != "yes"
 996 then
 997   AC_MSG_ERROR([g++|clang++|icc required but not found])
 998 fi
 999
1000 dnl Verify that GCC is version 3.0 or higher
1001 if test "$GCC" = "yes"
1002 then
1003   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1004 #error Unsupported GCC version
1005 #endif
1006 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1007 fi
1008
1009 dnl Check for GNU Make.  We use its extensions, so don't build without it
1010 if test -z "$llvm_cv_gnu_make_command"
1011 then
1012   AC_MSG_ERROR([GNU Make required but not found])
1013 fi
1014
1015 dnl Tool compatibility is okay if we make it here.
1016 AC_MSG_RESULT([ok])
1017
1018 dnl Check optional compiler flags.
1019 AC_MSG_CHECKING([optional compiler flags])
1020 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1021 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1022 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1023 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1024
1025 dnl===-----------------------------------------------------------------------===
1026 dnl===
1027 dnl=== SECTION 5: Check for libraries
1028 dnl===
1029 dnl===-----------------------------------------------------------------------===
1030
1031 AC_CHECK_LIB(m,sin)
1032 if test "$llvm_cv_os_type" = "MingW" ; then
1033   AC_CHECK_LIB(imagehlp, main)
1034   AC_CHECK_LIB(psapi, main)
1035 fi
1036
1037 dnl dlopen() is required for plugin support.
1038 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1039                [Define if dlopen() is available on this platform.]),
1040                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1041
1042 dnl libffi is optional; used to call external functions from the interpreter
1043 if test "$llvm_cv_enable_libffi" = "yes" ; then
1044   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1045                  [Define if libffi is available on this platform.]),
1046                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1047 fi
1048
1049 dnl mallinfo is optional; the code can compile (minus features) without it
1050 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1051                [Define if mallinfo() is available on this platform.]))
1052
1053 dnl pthread locking functions are optional - but llvm will not be thread-safe
1054 dnl without locks.
1055 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1056   AC_CHECK_LIB(pthread, pthread_mutex_init)
1057   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1058                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1059                            [Have pthread_mutex_lock]))
1060   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1061                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1062                  [Have pthread_rwlock_init]))
1063   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1064                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1065                  [Have pthread_getspecific]))
1066 fi
1067
1068 dnl Allow extra x86-disassembler library
1069 AC_ARG_WITH(udis86,
1070   AS_HELP_STRING([--with-udis86=<path>],
1071     [Use udis86 external x86 disassembler library]),
1072     [
1073       AC_SUBST(USE_UDIS86, [1])
1074       case "$withval" in
1075         /usr/lib|yes) ;;
1076         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1077       esac
1078       AC_CHECK_LIB(udis86, ud_init, [], [
1079         echo "Error! You need to have libudis86 around."
1080         exit -1
1081       ])
1082     ],
1083     AC_SUBST(USE_UDIS86, [0]))
1084 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1085                    [Define if use udis86 library])
1086
1087 dnl Allow OProfile support for JIT output.
1088 AC_ARG_WITH(oprofile,
1089   AS_HELP_STRING([--with-oprofile=<prefix>],
1090     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1091     [
1092       AC_SUBST(USE_OPROFILE, [1])
1093       case "$withval" in
1094         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1095         no) llvm_cv_oppath=
1096             AC_SUBST(USE_OPROFILE, [0]) ;;
1097         *) llvm_cv_oppath="${withval}/lib/oprofile"
1098            CPPFLAGS="-I${withval}/include";;
1099       esac
1100       if test -n "$llvm_cv_oppath" ; then
1101         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1102         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1103         dnl libbfd is not included properly in libopagent in some Debian
1104         dnl versions.  If libbfd isn't found at all, we assume opagent works
1105         dnl anyway.
1106         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1107         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1108           echo "Error! You need to have libopagent around."
1109           exit -1
1110         ])
1111         AC_CHECK_HEADER([opagent.h], [], [
1112           echo "Error! You need to have opagent.h around."
1113           exit -1
1114           ])
1115       fi
1116     ],
1117     [
1118       AC_SUBST(USE_OPROFILE, [0])
1119     ])
1120 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1121                    [Define if we have the oprofile JIT-support library])
1122
1123 dnl===-----------------------------------------------------------------------===
1124 dnl===
1125 dnl=== SECTION 6: Check for header files
1126 dnl===
1127 dnl===-----------------------------------------------------------------------===
1128
1129 dnl First, use autoconf provided macros for specific headers that we need
1130 dnl We don't check for ancient stuff or things that are guaranteed to be there
1131 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1132 dnl Generally we're looking for POSIX headers.
1133 AC_HEADER_DIRENT
1134 AC_HEADER_MMAP_ANONYMOUS
1135 AC_HEADER_STAT
1136 AC_HEADER_SYS_WAIT
1137 AC_HEADER_TIME
1138
1139 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1140 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1141 AC_CHECK_HEADERS([utime.h windows.h])
1142 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1143 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1144 AC_CHECK_HEADERS([valgrind/valgrind.h])
1145 AC_CHECK_HEADERS([fenv.h])
1146 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1147   AC_CHECK_HEADERS(pthread.h,
1148                    AC_SUBST(HAVE_PTHREAD, 1),
1149                    AC_SUBST(HAVE_PTHREAD, 0))
1150 else
1151   AC_SUBST(HAVE_PTHREAD, 0)
1152 fi
1153
1154 dnl Try to find ffi.h.
1155 if test "$llvm_cv_enable_libffi" = "yes" ; then
1156   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1157 fi
1158
1159 dnl Try to find Darwin specific crash reporting libraries.
1160 AC_CHECK_HEADERS([CrashReporterClient.h])
1161
1162 dnl Try to find Darwin specific crash reporting global.
1163 AC_MSG_CHECKING([__crashreporter_info__])
1164 AC_LINK_IFELSE(
1165   AC_LANG_SOURCE(
1166     [[extern const char *__crashreporter_info__;
1167       int main() {
1168         __crashreporter_info__ = "test";
1169         return 0;
1170       }
1171     ]]),
1172   AC_MSG_RESULT(yes)
1173   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1174   AC_MSG_RESULT(no)
1175   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1176             Define if __crashreporter_info__ exists.))
1177
1178 dnl===-----------------------------------------------------------------------===
1179 dnl===
1180 dnl=== SECTION 7: Check for types and structures
1181 dnl===
1182 dnl===-----------------------------------------------------------------------===
1183
1184 AC_HUGE_VAL_CHECK
1185 AC_TYPE_PID_T
1186 AC_TYPE_SIZE_T
1187 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1188 AC_STRUCT_TM
1189 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1190 AC_CHECK_TYPES([uint64_t],,
1191          AC_CHECK_TYPES([u_int64_t],,
1192          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1193
1194 dnl===-----------------------------------------------------------------------===
1195 dnl===
1196 dnl=== SECTION 8: Check for specific functions needed
1197 dnl===
1198 dnl===-----------------------------------------------------------------------===
1199
1200 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1201 AC_CHECK_FUNCS([powf fmodf strtof round ])
1202 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1203 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1204 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1205 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1206 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1207 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1208 AC_C_PRINTF_A
1209 AC_FUNC_RAND48
1210
1211 dnl Check the declaration "Secure API" on Windows environments.
1212 AC_CHECK_DECLS([strerror_s])
1213
1214 dnl Check symbols in libgcc.a for JIT on Mingw.
1215 if test "$llvm_cv_os_type" = "MingW" ; then
1216   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1217   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1218   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1219   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1220
1221   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1222   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1223   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1224   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1225   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1226   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1227   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1228   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1229   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1230   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1231
1232   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1233   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1234 fi
1235
1236 dnl Check Win32 API EnumerateLoadedModules.
1237 if test "$llvm_cv_os_type" = "MingW" ; then
1238   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1239   AC_COMPILE_IFELSE([[#include <windows.h>
1240 #include <imagehlp.h>
1241 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1242 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1243 [
1244   AC_MSG_RESULT([yes])
1245   llvm_cv_win32_elmcb_pcstr="PCSTR"
1246 ],
1247 [
1248   AC_MSG_RESULT([no])
1249   llvm_cv_win32_elmcb_pcstr="PSTR"
1250 ])
1251   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1252 fi
1253
1254 dnl Check for variations in the Standard C++ library and STL. These macros are
1255 dnl provided by LLVM in the autoconf/m4 directory.
1256 AC_FUNC_ISNAN
1257 AC_FUNC_ISINF
1258
1259 dnl Check for mmap support.We also need to know if /dev/zero is required to
1260 dnl be opened for allocating RWX memory.
1261 dnl Make sure we aren't attempting to configure for an unknown system
1262 if test "$llvm_cv_platform_type" = "Unix" ; then
1263   AC_FUNC_MMAP
1264   AC_FUNC_MMAP_FILE
1265   AC_NEED_DEV_ZERO_FOR_MMAP
1266
1267   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1268   then
1269     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1270   fi
1271   if test "$ac_cv_func_mmap_file" = "no"
1272   then
1273     AC_MSG_WARN([mmap() of files required but not found])
1274   fi
1275 fi
1276
1277 dnl atomic builtins are required for threading support.
1278 AC_MSG_CHECKING(for GCC atomic builtins)
1279 dnl Since we'll be using these atomic builtins in C++ files we should test
1280 dnl the C++ compiler.
1281 AC_LANG_PUSH([C++])
1282 AC_LINK_IFELSE(
1283   AC_LANG_SOURCE(
1284     [[int main() {
1285         volatile unsigned long val = 1;
1286         __sync_synchronize();
1287         __sync_val_compare_and_swap(&val, 1, 0);
1288         __sync_add_and_fetch(&val, 1);
1289         __sync_sub_and_fetch(&val, 1);
1290         return 0;
1291       }
1292     ]]),
1293   AC_LANG_POP([C++])
1294   AC_MSG_RESULT(yes)
1295   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1296   AC_MSG_RESULT(no)
1297   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1298   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1299
1300 dnl===-----------------------------------------------------------------------===
1301 dnl===
1302 dnl=== SECTION 9: Additional checks, variables, etc.
1303 dnl===
1304 dnl===-----------------------------------------------------------------------===
1305
1306 dnl Handle 32-bit linux systems running a 64-bit kernel.
1307 dnl This has to come after section 4 because it invokes the compiler.
1308 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1309   AC_IS_LINUX_MIXED
1310   if test "$llvm_cv_linux_mixed" = "yes"; then
1311     llvm_cv_target_arch="x86"
1312     ARCH="x86"
1313   fi
1314 fi
1315
1316 dnl Check whether __dso_handle is present
1317 AC_CHECK_FUNCS([__dso_handle])
1318
1319 dnl Propagate the shared library extension that the libltdl checks did to
1320 dnl the Makefiles so we can use it there too
1321 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1322
1323 dnl Propagate the run-time library path variable that the libltdl
1324 dnl checks found to the Makefiles so we can use it there too
1325 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1326
1327 # Translate the various configuration directories and other basic
1328 # information into substitutions that will end up in Makefile.config.in
1329 # that these configured values can be used by the makefiles
1330 if test "${prefix}" = "NONE" ; then
1331   prefix="/usr/local"
1332 fi
1333 eval LLVM_PREFIX="${prefix}";
1334 eval LLVM_BINDIR="${prefix}/bin";
1335 eval LLVM_LIBDIR="${prefix}/lib";
1336 eval LLVM_DATADIR="${prefix}/share/llvm";
1337 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1338 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1339 eval LLVM_INCLUDEDIR="${prefix}/include";
1340 eval LLVM_INFODIR="${prefix}/info";
1341 eval LLVM_MANDIR="${prefix}/man";
1342 LLVM_CONFIGTIME=`date`
1343 AC_SUBST(LLVM_PREFIX)
1344 AC_SUBST(LLVM_BINDIR)
1345 AC_SUBST(LLVM_LIBDIR)
1346 AC_SUBST(LLVM_DATADIR)
1347 AC_SUBST(LLVM_DOCSDIR)
1348 AC_SUBST(LLVM_ETCDIR)
1349 AC_SUBST(LLVM_INCLUDEDIR)
1350 AC_SUBST(LLVM_INFODIR)
1351 AC_SUBST(LLVM_MANDIR)
1352 AC_SUBST(LLVM_CONFIGTIME)
1353
1354 # Place the various directores into the config.h file as #defines so that we
1355 # can know about the installation paths within LLVM.
1356 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1357                    [Installation prefix directory])
1358 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1359                    [Installation directory for binary executables])
1360 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1361                    [Installation directory for libraries])
1362 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1363                    [Installation directory for data files])
1364 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1365                    [Installation directory for documentation])
1366 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1367                    [Installation directory for config files])
1368 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1369                    [Installation directory for include files])
1370 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1371                    [Installation directory for .info files])
1372 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1373                    [Installation directory for man pages])
1374 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1375                    [Time at which LLVM was configured])
1376 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1377                    [Target triple LLVM will generate code for by default])
1378
1379 # Determine which bindings to build.
1380 if test "$BINDINGS_TO_BUILD" = auto ; then
1381   BINDINGS_TO_BUILD=""
1382   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1383     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1384   fi
1385 fi
1386 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1387
1388 # This isn't really configurey, but it avoids having to repeat the list in
1389 # other files.
1390 AC_SUBST(ALL_BINDINGS,ocaml)
1391
1392 # Do any work necessary to ensure that bindings have what they need.
1393 binding_prereqs_failed=0
1394 for a_binding in $BINDINGS_TO_BUILD ; do
1395   case "$a_binding" in
1396   ocaml)
1397     if test "x$OCAMLC" = x ; then
1398       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1399       binding_prereqs_failed=1
1400     fi
1401     if test "x$OCAMLDEP" = x ; then
1402       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1403       binding_prereqs_failed=1
1404     fi
1405     if test "x$OCAMLOPT" = x ; then
1406       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1407       dnl ocamlopt is optional!
1408     fi
1409     if test "x$with_ocaml_libdir" != xauto ; then
1410       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1411     else
1412       ocaml_stdlib="`"$OCAMLC" -where`"
1413       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1414       then
1415         # ocaml stdlib is beneath our prefix; use stdlib
1416         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1417       else
1418         # ocaml stdlib is outside our prefix; use libdir/ocaml
1419         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1420       fi
1421     fi
1422     ;;
1423   esac
1424 done
1425 if test "$binding_prereqs_failed" = 1 ; then
1426   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1427 fi
1428
1429 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1430 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1431
1432 dnl Determine linker rpath flag
1433 if test "$llvm_cv_link_use_r" = "yes" ; then
1434   RPATH="-Wl,-R"
1435 else
1436   RPATH="-Wl,-rpath"
1437 fi
1438 AC_SUBST(RPATH)
1439
1440 dnl Determine linker rdynamic flag
1441 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1442   RDYNAMIC="-Wl,-export-dynamic"
1443 else
1444   RDYNAMIC=""
1445 fi
1446 AC_SUBST(RDYNAMIC)
1447
1448 dnl===-----------------------------------------------------------------------===
1449 dnl===
1450 dnl=== SECTION 10: Specify the output files and generate it
1451 dnl===
1452 dnl===-----------------------------------------------------------------------===
1453
1454 dnl **************************************************************************
1455 dnl End LLVM configure.ac Import
1456 dnl **************************************************************************
1457
1458 dnl Configure a common Makefile
1459 AC_CONFIG_FILES(Makefile.common)
1460 AC_CONFIG_FILES(Makefile.llvm.config)
1461
1462 dnl Configure project makefiles
1463 dnl List every Makefile that exists within your source tree
1464 AC_CONFIG_MAKEFILE(Makefile)
1465 AC_CONFIG_MAKEFILE(lib/Makefile)
1466 AC_CONFIG_MAKEFILE(lib/sample/Makefile)
1467 AC_CONFIG_MAKEFILE(tools/Makefile)
1468 AC_CONFIG_MAKEFILE(tools/sample/Makefile)
1469
1470 dnl This must be last
1471 AC_OUTPUT