lib/Target/X86/X86SchedHaswell.td

   1 //=- X86SchedHaswell.td - X86 Haswell Scheduling -------------*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the machine model for Haswell to support instruction
  11 // scheduling and other instruction cost heuristics.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 def HaswellModel : SchedMachineModel {
  16   // All x86 instructions are modeled as a single micro-op, and HW can decode 4
  17   // instructions per cycle.
  18   let IssueWidth = 4;
  19   let MinLatency = 0; // 0 = Out-of-order execution.
  20   let LoadLatency = 4;
  21   let MispredictPenalty = 16;
  22 }
  23
  24 let SchedModel = HaswellModel in {
  25
  26 // Haswell can issue micro-ops to 8 different ports in one cycle.
  27
  28 // Ports 0, 1, 5, 6 and 7 handle all computation.
  29 // Port 4 gets the data half of stores. Store data can be available later than
  30 // the store address, but since we don't model the latency of stores, we can
  31 // ignore that.
  32 // Ports 2 and 3 are identical. They handle loads and the address half of
  33 // stores. Port 7 can handle address calculations.
  34 def HWPort0 : ProcResource<1>;
  35 def HWPort1 : ProcResource<1>;
  36 def HWPort2 : ProcResource<1>;
  37 def HWPort3 : ProcResource<1>;
  38 def HWPort4 : ProcResource<1>;
  39 def HWPort5 : ProcResource<1>;
  40 def HWPort6 : ProcResource<1>;
  41 def HWPort7 : ProcResource<1>;
  42
  43 // Many micro-ops are capable of issuing on multiple ports.
  44 def HWPort23  : ProcResGroup<[HWPort2, HWPort3]>;
  45 def HWPort237 : ProcResGroup<[HWPort2, HWPort3, HWPort7]>;
  46 def HWPort05  : ProcResGroup<[HWPort0, HWPort5]>;
  47 def HWPort056 : ProcResGroup<[HWPort0, HWPort5, HWPort6]>;
  48 def HWPort15  : ProcResGroup<[HWPort1, HWPort5]>;
  49 def HWPort015 : ProcResGroup<[HWPort0, HWPort1, HWPort5]>;
  50 def HWPort0156: ProcResGroup<[HWPort0, HWPort1, HWPort5, HWPort6]>;
  51
  52 // Integer division issued on port 0.
  53 def HWDivider : ProcResource<1>;
  54
  55 // Loads are 4 cycles, so ReadAfterLd registers needn't be available until 4
  56 // cycles after the memory operand.
  57 def : ReadAdvance<ReadAfterLd, 4>;
  58
  59 // Many SchedWrites are defined in pairs with and without a folded load.
  60 // Instructions with folded loads are usually micro-fused, so they only appear
  61 // as two micro-ops when queued in the reservation station.
  62 // This multiclass defines the resource usage for variants with and without
  63 // folded loads.
  64 multiclass HWWriteResPair<X86FoldableSchedWrite SchedRW,
  65                           ProcResourceKind ExePort,
  66                           int Lat> {
  67   // Register variant is using a single cycle on ExePort.
  68   def : WriteRes<SchedRW, [ExePort]> { let Latency = Lat; }
  69
  70   // Memory variant also uses a cycle on port 2/3 and adds 4 cycles to the
  71   // latency.
  72   def : WriteRes<SchedRW.Folded, [HWPort23, ExePort]> {
  73      let Latency = !add(Lat, 4);
  74   }
  75 }
  76
  77 // A folded store needs a cycle on port 4 for the store data, but it does not
  78 // need an extra port 2/3 cycle to recompute the address.
  79 def : WriteRes<WriteRMW, [HWPort4]>;
  80
  81 def : WriteRes<WriteStore, [HWPort237, HWPort4]>;
  82 def : WriteRes<WriteLoad,  [HWPort23]> { let Latency = 4; }
  83 def : WriteRes<WriteMove,  [HWPort0156]>;
  84 def : WriteRes<WriteZero,  []>;
  85
  86 defm : HWWriteResPair<WriteALU,   HWPort0156, 1>;
  87 defm : HWWriteResPair<WriteIMul,  HWPort1,   3>;
  88 defm : HWWriteResPair<WriteShift, HWPort056,  1>;
  89 defm : HWWriteResPair<WriteJump,  HWPort5,   1>;
  90
  91 // This is for simple LEAs with one or two input operands.
  92 // The complex ones can only execute on port 1, and they require two cycles on
  93 // the port to read all inputs. We don't model that.
  94 def : WriteRes<WriteLEA, [HWPort15]>;
  95
  96 // This is quite rough, latency depends on the dividend.
  97 def : WriteRes<WriteIDiv, [HWPort0, HWDivider]> {
  98   let Latency = 25;
  99   let ResourceCycles = [1, 10];
 100 }
 101 def : WriteRes<WriteIDivLd, [HWPort23, HWPort0, HWDivider]> {
 102   let Latency = 29;
 103   let ResourceCycles = [1, 1, 10];
 104 }
 105
 106 // Scalar and vector floating point.
 107 defm : HWWriteResPair<WriteFAdd,   HWPort1, 3>;
 108 defm : HWWriteResPair<WriteFMul,   HWPort0, 5>;
 109 defm : HWWriteResPair<WriteFDiv,   HWPort0, 12>; // 10-14 cycles.
 110 defm : HWWriteResPair<WriteFRcp,   HWPort0, 5>;
 111 defm : HWWriteResPair<WriteFSqrt,  HWPort0, 15>;
 112 defm : HWWriteResPair<WriteCvtF2I, HWPort1, 3>;
 113 defm : HWWriteResPair<WriteCvtI2F, HWPort1, 4>;
 114 defm : HWWriteResPair<WriteCvtF2F, HWPort1, 3>;
 115
 116 // Vector integer operations.
 117 defm : HWWriteResPair<WriteVecShift, HWPort05,  1>;
 118 defm : HWWriteResPair<WriteVecLogic, HWPort015, 1>;
 119 defm : HWWriteResPair<WriteVecALU,   HWPort15,  1>;
 120 defm : HWWriteResPair<WriteVecIMul,  HWPort0,   5>;
 121 defm : HWWriteResPair<WriteShuffle,  HWPort15,  1>;
 122
 123 def : WriteRes<WriteSystem,     [HWPort0156]> { let Latency = 100; }
 124 def : WriteRes<WriteMicrocoded, [HWPort0156]> { let Latency = 100; }
 125 } // SchedModel