lib/Target/X86/X86InstrXOP.td

   1 //===-- X86InstrXOP.td - XOP Instruction Set ---------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes XOP (eXtended OPerations)
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 multiclass xop2op<bits<8> opc, string OpcodeStr, Intrinsic Int, PatFrag memop> {
  15   def rr : IXOP<opc, MRMSrcReg, (outs VR128:$dst), (ins VR128:$src),
  16            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  17            [(set VR128:$dst, (Int VR128:$src))]>, XOP;
  18   def rm : IXOP<opc, MRMSrcMem, (outs VR128:$dst), (ins i128mem:$src),
  19            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  20            [(set VR128:$dst, (Int (bitconvert (memop addr:$src))))]>, XOP;
  21 }
  22
  23 let ExeDomain = SSEPackedInt in {
  24   defm VPHSUBWD  : xop2op<0xE2, "vphsubwd", int_x86_xop_vphsubwd, loadv2i64>;
  25   defm VPHSUBDQ  : xop2op<0xE3, "vphsubdq", int_x86_xop_vphsubdq, loadv2i64>;
  26   defm VPHSUBBW  : xop2op<0xE1, "vphsubbw", int_x86_xop_vphsubbw, loadv2i64>;
  27   defm VPHADDWQ  : xop2op<0xC7, "vphaddwq", int_x86_xop_vphaddwq, loadv2i64>;
  28   defm VPHADDWD  : xop2op<0xC6, "vphaddwd", int_x86_xop_vphaddwd, loadv2i64>;
  29   defm VPHADDUWQ : xop2op<0xD7, "vphadduwq", int_x86_xop_vphadduwq, loadv2i64>;
  30   defm VPHADDUWD : xop2op<0xD6, "vphadduwd", int_x86_xop_vphadduwd, loadv2i64>;
  31   defm VPHADDUDQ : xop2op<0xDB, "vphaddudq", int_x86_xop_vphaddudq, loadv2i64>;
  32   defm VPHADDUBW : xop2op<0xD1, "vphaddubw", int_x86_xop_vphaddubw, loadv2i64>;
  33   defm VPHADDUBQ : xop2op<0xD3, "vphaddubq", int_x86_xop_vphaddubq, loadv2i64>;
  34   defm VPHADDUBD : xop2op<0xD2, "vphaddubd", int_x86_xop_vphaddubd, loadv2i64>;
  35   defm VPHADDDQ  : xop2op<0xCB, "vphadddq", int_x86_xop_vphadddq, loadv2i64>;
  36   defm VPHADDBW  : xop2op<0xC1, "vphaddbw", int_x86_xop_vphaddbw, loadv2i64>;
  37   defm VPHADDBQ  : xop2op<0xC3, "vphaddbq", int_x86_xop_vphaddbq, loadv2i64>;
  38   defm VPHADDBD  : xop2op<0xC2, "vphaddbd", int_x86_xop_vphaddbd, loadv2i64>;
  39 }
  40
  41 // Scalar load 2 addr operand instructions
  42 multiclass xop2opsld<bits<8> opc, string OpcodeStr, Intrinsic Int,
  43                      Operand memop, ComplexPattern mem_cpat> {
  44   def rr : IXOP<opc, MRMSrcReg, (outs VR128:$dst), (ins VR128:$src),
  45            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  46            [(set VR128:$dst, (Int VR128:$src))]>, XOP;
  47   def rm : IXOP<opc, MRMSrcMem, (outs VR128:$dst), (ins memop:$src),
  48            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  49            [(set VR128:$dst, (Int (bitconvert mem_cpat:$src)))]>, XOP;
  50 }
  51
  52 multiclass xop2op128<bits<8> opc, string OpcodeStr, Intrinsic Int,
  53                      PatFrag memop> {
  54   def rr : IXOP<opc, MRMSrcReg, (outs VR128:$dst), (ins VR128:$src),
  55            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  56            [(set VR128:$dst, (Int VR128:$src))]>, XOP;
  57   def rm : IXOP<opc, MRMSrcMem, (outs VR128:$dst), (ins f128mem:$src),
  58            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  59            [(set VR128:$dst, (Int (bitconvert (memop addr:$src))))]>, XOP;
  60 }
  61
  62 multiclass xop2op256<bits<8> opc, string OpcodeStr, Intrinsic Int,
  63                      PatFrag memop> {
  64   def rrY : IXOP<opc, MRMSrcReg, (outs VR256:$dst), (ins VR256:$src),
  65            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  66            [(set VR256:$dst, (Int VR256:$src))]>, XOP, VEX_L;
  67   def rmY : IXOP<opc, MRMSrcMem, (outs VR256:$dst), (ins f256mem:$src),
  68            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  69            [(set VR256:$dst, (Int (bitconvert (memop addr:$src))))]>, XOP, VEX_L;
  70 }
  71
  72 let ExeDomain = SSEPackedSingle in {
  73   defm VFRCZSS : xop2opsld<0x82, "vfrczss", int_x86_xop_vfrcz_ss,
  74                            ssmem, sse_load_f32>;
  75   defm VFRCZPS : xop2op128<0x80, "vfrczps", int_x86_xop_vfrcz_ps, loadv4f32>;
  76   defm VFRCZPS : xop2op256<0x80, "vfrczps", int_x86_xop_vfrcz_ps_256, loadv8f32>;
  77 }
  78
  79 let ExeDomain = SSEPackedDouble in {
  80   defm VFRCZSD : xop2opsld<0x83, "vfrczsd", int_x86_xop_vfrcz_sd,
  81                            sdmem, sse_load_f64>;
  82   defm VFRCZPD : xop2op128<0x81, "vfrczpd", int_x86_xop_vfrcz_pd, loadv2f64>;
  83   defm VFRCZPD : xop2op256<0x81, "vfrczpd", int_x86_xop_vfrcz_pd_256, loadv4f64>;
  84 }
  85
  86 multiclass xop3op<bits<8> opc, string OpcodeStr, SDNode OpNode,
  87                   ValueType vt128> {
  88   def rr : IXOP<opc, MRMSrcReg, (outs VR128:$dst),
  89            (ins VR128:$src1, VR128:$src2),
  90            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
  91            [(set VR128:$dst,
  92               (vt128 (OpNode (vt128 VR128:$src1), (vt128 VR128:$src2))))]>,
  93            XOP_4VOp3, Sched<[WriteVarVecShift]>;
  94   def rm : IXOP<opc, MRMSrcMem, (outs VR128:$dst),
  95            (ins VR128:$src1, i128mem:$src2),
  96            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
  97            [(set VR128:$dst,
  98               (vt128 (OpNode (vt128 VR128:$src1),
  99                              (vt128 (bitconvert (loadv2i64 addr:$src2))))))]>,
 100            XOP_4V, VEX_W, Sched<[WriteVarVecShift, ReadAfterLd]>;
 101   def mr : IXOP<opc, MRMSrcMem, (outs VR128:$dst),
 102            (ins i128mem:$src1, VR128:$src2),
 103            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 104            [(set VR128:$dst,
 105               (vt128 (OpNode (vt128 (bitconvert (loadv2i64 addr:$src1))),
 106                              (vt128 VR128:$src2))))]>,
 107              XOP_4VOp3, Sched<[WriteVarVecShift, ReadAfterLd]>;
 108 }
 109
 110 let ExeDomain = SSEPackedInt in {
 111   defm VPSHAB : xop3op<0x98, "vpshab", X86vpsha, v16i8>;
 112   defm VPSHAD : xop3op<0x9A, "vpshad", X86vpsha, v4i32>;
 113   defm VPSHAQ : xop3op<0x9B, "vpshaq", X86vpsha, v2i64>;
 114   defm VPSHAW : xop3op<0x99, "vpshaw", X86vpsha, v8i16>;
 115   defm VPSHLB : xop3op<0x94, "vpshlb", X86vpshl, v16i8>;
 116   defm VPSHLD : xop3op<0x96, "vpshld", X86vpshl, v4i32>;
 117   defm VPSHLQ : xop3op<0x97, "vpshlq", X86vpshl, v2i64>;
 118   defm VPSHLW : xop3op<0x95, "vpshlw", X86vpshl, v8i16>;
 119 }
 120
 121 multiclass xop3op_int<bits<8> opc, string OpcodeStr, Intrinsic Int> {
 122   def rr : IXOP<opc, MRMSrcReg, (outs VR128:$dst),
 123            (ins VR128:$src1, VR128:$src2),
 124            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 125            [(set VR128:$dst, (Int VR128:$src1, VR128:$src2))]>, XOP_4VOp3;
 126   def rm : IXOP<opc, MRMSrcMem, (outs VR128:$dst),
 127            (ins VR128:$src1, i128mem:$src2),
 128            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 129            [(set VR128:$dst,
 130               (Int VR128:$src1, (bitconvert (loadv2i64 addr:$src2))))]>,
 131            XOP_4V, VEX_W;
 132   def mr : IXOP<opc, MRMSrcMem, (outs VR128:$dst),
 133            (ins i128mem:$src1, VR128:$src2),
 134            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 135            [(set VR128:$dst,
 136               (Int (bitconvert (loadv2i64 addr:$src1)), VR128:$src2))]>,
 137              XOP_4VOp3;
 138 }
 139
 140 let ExeDomain = SSEPackedInt in {
 141   defm VPROTW : xop3op_int<0x91, "vprotw", int_x86_xop_vprotw>;
 142   defm VPROTQ : xop3op_int<0x93, "vprotq", int_x86_xop_vprotq>;
 143   defm VPROTD : xop3op_int<0x92, "vprotd", int_x86_xop_vprotd>;
 144   defm VPROTB : xop3op_int<0x90, "vprotb", int_x86_xop_vprotb>;
 145 }
 146
 147 multiclass xop3opimm<bits<8> opc, string OpcodeStr, Intrinsic Int> {
 148   def ri : IXOPi8<opc, MRMSrcReg, (outs VR128:$dst),
 149            (ins VR128:$src1, i8imm:$src2),
 150            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 151            [(set VR128:$dst, (Int VR128:$src1, imm:$src2))]>, XOP;
 152   def mi : IXOPi8<opc, MRMSrcMem, (outs VR128:$dst),
 153            (ins i128mem:$src1, i8imm:$src2),
 154            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 155            [(set VR128:$dst,
 156              (Int (bitconvert (loadv2i64 addr:$src1)), imm:$src2))]>, XOP;
 157 }
 158
 159 let ExeDomain = SSEPackedInt in {
 160   defm VPROTW : xop3opimm<0xC1, "vprotw", int_x86_xop_vprotwi>;
 161   defm VPROTQ : xop3opimm<0xC3, "vprotq", int_x86_xop_vprotqi>;
 162   defm VPROTD : xop3opimm<0xC2, "vprotd", int_x86_xop_vprotdi>;
 163   defm VPROTB : xop3opimm<0xC0, "vprotb", int_x86_xop_vprotbi>;
 164 }
 165
 166 // Instruction where second source can be memory, but third must be register
 167 multiclass xop4opm2<bits<8> opc, string OpcodeStr, Intrinsic Int> {
 168   let isCommutable = 1 in
 169   def rr : IXOPi8<opc, MRMSrcReg, (outs VR128:$dst),
 170            (ins VR128:$src1, VR128:$src2, VR128:$src3),
 171            !strconcat(OpcodeStr,
 172            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 173            [(set VR128:$dst,
 174               (Int VR128:$src1, VR128:$src2, VR128:$src3))]>, XOP_4V, VEX_I8IMM;
 175   def rm : IXOPi8<opc, MRMSrcMem, (outs VR128:$dst),
 176            (ins VR128:$src1, i128mem:$src2, VR128:$src3),
 177            !strconcat(OpcodeStr,
 178            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 179            [(set VR128:$dst,
 180               (Int VR128:$src1, (bitconvert (loadv2i64 addr:$src2)),
 181               VR128:$src3))]>, XOP_4V, VEX_I8IMM;
 182 }
 183
 184 let ExeDomain = SSEPackedInt in {
 185   defm VPMADCSWD  : xop4opm2<0xB6, "vpmadcswd", int_x86_xop_vpmadcswd>;
 186   defm VPMADCSSWD : xop4opm2<0xA6, "vpmadcsswd", int_x86_xop_vpmadcsswd>;
 187   defm VPMACSWW   : xop4opm2<0x95, "vpmacsww", int_x86_xop_vpmacsww>;
 188   defm VPMACSWD   : xop4opm2<0x96, "vpmacswd", int_x86_xop_vpmacswd>;
 189   defm VPMACSSWW  : xop4opm2<0x85, "vpmacssww", int_x86_xop_vpmacssww>;
 190   defm VPMACSSWD  : xop4opm2<0x86, "vpmacsswd", int_x86_xop_vpmacsswd>;
 191   defm VPMACSSDQL : xop4opm2<0x87, "vpmacssdql", int_x86_xop_vpmacssdql>;
 192   defm VPMACSSDQH : xop4opm2<0x8F, "vpmacssdqh", int_x86_xop_vpmacssdqh>;
 193   defm VPMACSSDD  : xop4opm2<0x8E, "vpmacssdd", int_x86_xop_vpmacssdd>;
 194   defm VPMACSDQL  : xop4opm2<0x97, "vpmacsdql", int_x86_xop_vpmacsdql>;
 195   defm VPMACSDQH  : xop4opm2<0x9F, "vpmacsdqh", int_x86_xop_vpmacsdqh>;
 196   defm VPMACSDD   : xop4opm2<0x9E, "vpmacsdd", int_x86_xop_vpmacsdd>;
 197 }
 198
 199 // Instruction where second source can be memory, third must be imm8
 200 multiclass xopvpcom<bits<8> opc, string Suffix, SDNode OpNode, ValueType vt128> {
 201   let isCommutable = 1 in
 202   def ri : IXOPi8<opc, MRMSrcReg, (outs VR128:$dst),
 203            (ins VR128:$src1, VR128:$src2, XOPCC:$cc),
 204            !strconcat("vpcom${cc}", Suffix,
 205            "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 206            [(set VR128:$dst,
 207               (vt128 (OpNode (vt128 VR128:$src1), (vt128 VR128:$src2),
 208                              i8immZExt3:$cc)))]>,
 209            XOP_4V;
 210   def mi : IXOPi8<opc, MRMSrcMem, (outs VR128:$dst),
 211            (ins VR128:$src1, i128mem:$src2, XOPCC:$cc),
 212            !strconcat("vpcom${cc}", Suffix,
 213            "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 214            [(set VR128:$dst,
 215               (vt128 (OpNode (vt128 VR128:$src1),
 216                              (vt128 (bitconvert (loadv2i64 addr:$src2))),
 217                               i8immZExt3:$cc)))]>,
 218            XOP_4V;
 219   let isAsmParserOnly = 1, hasSideEffects = 0 in {
 220     def ri_alt : IXOPi8<opc, MRMSrcReg, (outs VR128:$dst),
 221                  (ins VR128:$src1, VR128:$src2, i8imm:$src3),
 222                  !strconcat("vpcom", Suffix,
 223                  "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 224                  []>, XOP_4V;
 225     let mayLoad = 1 in
 226     def mi_alt : IXOPi8<opc, MRMSrcMem, (outs VR128:$dst),
 227                  (ins VR128:$src1, i128mem:$src2, i8imm:$src3),
 228                  !strconcat("vpcom", Suffix,
 229                  "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 230                  []>, XOP_4V;
 231   }
 232 }
 233
 234 let ExeDomain = SSEPackedInt in { // SSE integer instructions
 235   defm VPCOMB  : xopvpcom<0xCC, "b", X86vpcom, v16i8>;
 236   defm VPCOMW  : xopvpcom<0xCD, "w", X86vpcom, v8i16>;
 237   defm VPCOMD  : xopvpcom<0xCE, "d", X86vpcom, v4i32>;
 238   defm VPCOMQ  : xopvpcom<0xCF, "q", X86vpcom, v2i64>;
 239   defm VPCOMUB : xopvpcom<0xEC, "ub", X86vpcomu, v16i8>;
 240   defm VPCOMUW : xopvpcom<0xED, "uw", X86vpcomu, v8i16>;
 241   defm VPCOMUD : xopvpcom<0xEE, "ud", X86vpcomu, v4i32>;
 242   defm VPCOMUQ : xopvpcom<0xEF, "uq", X86vpcomu, v2i64>;
 243 }
 244
 245 // Instruction where either second or third source can be memory
 246 multiclass xop4op<bits<8> opc, string OpcodeStr, Intrinsic Int> {
 247   def rr : IXOPi8<opc, MRMSrcReg, (outs VR128:$dst),
 248            (ins VR128:$src1, VR128:$src2, VR128:$src3),
 249            !strconcat(OpcodeStr,
 250            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 251            [(set VR128:$dst, (Int VR128:$src1, VR128:$src2, VR128:$src3))]>,
 252            XOP_4V, VEX_I8IMM;
 253   def rm : IXOPi8<opc, MRMSrcMem, (outs VR128:$dst),
 254            (ins VR128:$src1, VR128:$src2, i128mem:$src3),
 255            !strconcat(OpcodeStr,
 256            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 257            [(set VR128:$dst,
 258              (Int VR128:$src1, VR128:$src2,
 259               (bitconvert (loadv2i64 addr:$src3))))]>,
 260            XOP_4V, VEX_I8IMM, VEX_W, MemOp4;
 261   def mr : IXOPi8<opc, MRMSrcMem, (outs VR128:$dst),
 262            (ins VR128:$src1, i128mem:$src2, VR128:$src3),
 263            !strconcat(OpcodeStr,
 264            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 265            [(set VR128:$dst,
 266              (Int VR128:$src1, (bitconvert (loadv2i64 addr:$src2)),
 267               VR128:$src3))]>,
 268            XOP_4V, VEX_I8IMM;
 269 }
 270
 271 let ExeDomain = SSEPackedInt in {
 272   defm VPPERM : xop4op<0xA3, "vpperm", int_x86_xop_vpperm>;
 273   defm VPCMOV : xop4op<0xA2, "vpcmov", int_x86_xop_vpcmov>;
 274 }
 275
 276 multiclass xop4op256<bits<8> opc, string OpcodeStr, Intrinsic Int> {
 277   def rrY : IXOPi8<opc, MRMSrcReg, (outs VR256:$dst),
 278            (ins VR256:$src1, VR256:$src2, VR256:$src3),
 279            !strconcat(OpcodeStr,
 280            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 281            [(set VR256:$dst, (Int VR256:$src1, VR256:$src2, VR256:$src3))]>,
 282            XOP_4V, VEX_I8IMM, VEX_L;
 283   def rmY : IXOPi8<opc, MRMSrcMem, (outs VR256:$dst),
 284            (ins VR256:$src1, VR256:$src2, i256mem:$src3),
 285            !strconcat(OpcodeStr,
 286            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 287            [(set VR256:$dst,
 288              (Int VR256:$src1, VR256:$src2,
 289               (bitconvert (loadv4i64 addr:$src3))))]>,
 290            XOP_4V, VEX_I8IMM, VEX_W, MemOp4, VEX_L;
 291   def mrY : IXOPi8<opc, MRMSrcMem, (outs VR256:$dst),
 292            (ins VR256:$src1, f256mem:$src2, VR256:$src3),
 293            !strconcat(OpcodeStr,
 294            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 295            [(set VR256:$dst,
 296              (Int VR256:$src1, (bitconvert (loadv4i64 addr:$src2)),
 297               VR256:$src3))]>,
 298            XOP_4V, VEX_I8IMM, VEX_L;
 299 }
 300
 301 let ExeDomain = SSEPackedInt in
 302   defm VPCMOV : xop4op256<0xA2, "vpcmov", int_x86_xop_vpcmov_256>;
 303
 304 multiclass xop5op<bits<8> opc, string OpcodeStr, Intrinsic Int128,
 305                   Intrinsic Int256, PatFrag ld_128, PatFrag ld_256> {
 306   def rr : IXOP5<opc, MRMSrcReg, (outs VR128:$dst),
 307         (ins VR128:$src1, VR128:$src2, VR128:$src3, i8imm:$src4),
 308         !strconcat(OpcodeStr,
 309         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 310         [(set VR128:$dst,
 311            (Int128 VR128:$src1, VR128:$src2, VR128:$src3, imm:$src4))]>;
 312   def rm : IXOP5<opc, MRMSrcMem, (outs VR128:$dst),
 313         (ins VR128:$src1, VR128:$src2, f128mem:$src3, i8imm:$src4),
 314         !strconcat(OpcodeStr,
 315         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 316         [(set VR128:$dst,
 317            (Int128 VR128:$src1, VR128:$src2, (ld_128 addr:$src3), imm:$src4))]>,
 318         VEX_W, MemOp4;
 319   def mr : IXOP5<opc, MRMSrcMem, (outs VR128:$dst),
 320         (ins VR128:$src1, f128mem:$src2, VR128:$src3, i8imm:$src4),
 321         !strconcat(OpcodeStr,
 322         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 323         [(set VR128:$dst,
 324            (Int128 VR128:$src1, (ld_128 addr:$src2), VR128:$src3, imm:$src4))]>;
 325   def rrY : IXOP5<opc, MRMSrcReg, (outs VR256:$dst),
 326         (ins VR256:$src1, VR256:$src2, VR256:$src3, i8imm:$src4),
 327         !strconcat(OpcodeStr,
 328         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 329         [(set VR256:$dst,
 330           (Int256 VR256:$src1, VR256:$src2, VR256:$src3, imm:$src4))]>, VEX_L;
 331   def rmY : IXOP5<opc, MRMSrcMem, (outs VR256:$dst),
 332         (ins VR256:$src1, VR256:$src2, f256mem:$src3, i8imm:$src4),
 333         !strconcat(OpcodeStr,
 334         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 335         [(set VR256:$dst,
 336           (Int256 VR256:$src1, VR256:$src2, (ld_256 addr:$src3), imm:$src4))]>,
 337         VEX_W, MemOp4, VEX_L;
 338   def mrY : IXOP5<opc, MRMSrcMem, (outs VR256:$dst),
 339         (ins VR256:$src1, f256mem:$src2, VR256:$src3, i8imm:$src4),
 340         !strconcat(OpcodeStr,
 341         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 342         [(set VR256:$dst,
 343            (Int256 VR256:$src1, (ld_256 addr:$src2), VR256:$src3, imm:$src4))]>,
 344         VEX_L;
 345 }
 346
 347 let ExeDomain = SSEPackedDouble in
 348   defm VPERMIL2PD : xop5op<0x49, "vpermil2pd", int_x86_xop_vpermil2pd,
 349                            int_x86_xop_vpermil2pd_256, loadv2f64, loadv4f64>;
 350
 351 let ExeDomain = SSEPackedSingle in
 352   defm VPERMIL2PS : xop5op<0x48, "vpermil2ps", int_x86_xop_vpermil2ps,
 353                            int_x86_xop_vpermil2ps_256, loadv4f32, loadv8f32>;
 354