lib/Target/X86/X86InstrMMX.td

   1 //====- X86InstrMMX.td - Describe the X86 Instruction Set --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 MMX instruction set, defining the instructions,
  11 // and properties of the instructions which are needed for code generation,
  12 // machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // MMX Pattern Fragments
  18 //===----------------------------------------------------------------------===//
  19
  20 def load_mmx : PatFrag<(ops node:$ptr), (v1i64 (load node:$ptr))>;
  21
  22 def bc_v8i8  : PatFrag<(ops node:$in), (v8i8  (bitconvert node:$in))>;
  23 def bc_v4i16 : PatFrag<(ops node:$in), (v4i16 (bitconvert node:$in))>;
  24 def bc_v2i32 : PatFrag<(ops node:$in), (v2i32 (bitconvert node:$in))>;
  25 def bc_v1i64 : PatFrag<(ops node:$in), (v1i64 (bitconvert node:$in))>;
  26
  27 //===----------------------------------------------------------------------===//
  28 // MMX Masks
  29 //===----------------------------------------------------------------------===//
  30
  31 // MMX_SHUFFLE_get_shuf_imm xform function: convert vector_shuffle mask to
  32 // PSHUFW imm.
  33 def MMX_SHUFFLE_get_shuf_imm : SDNodeXForm<build_vector, [{
  34   return getI8Imm(X86::getShuffleSHUFImmediate(N));
  35 }]>;
  36
  37 // Patterns for: vector_shuffle v1, v2, <2, 6, 3, 7, ...>
  38 def MMX_UNPCKH_shuffle_mask : PatLeaf<(build_vector), [{
  39   return X86::isUNPCKHMask(N);
  40 }]>;
  41
  42 // Patterns for: vector_shuffle v1, v2, <0, 4, 2, 5, ...>
  43 def MMX_UNPCKL_shuffle_mask : PatLeaf<(build_vector), [{
  44   return X86::isUNPCKLMask(N);
  45 }]>;
  46
  47 // Patterns for: vector_shuffle v1, <undef>, <0, 0, 1, 1, ...>
  48 def MMX_UNPCKH_v_undef_shuffle_mask : PatLeaf<(build_vector), [{
  49   return X86::isUNPCKH_v_undef_Mask(N);
  50 }]>;
  51
  52 // Patterns for: vector_shuffle v1, <undef>, <2, 2, 3, 3, ...>
  53 def MMX_UNPCKL_v_undef_shuffle_mask : PatLeaf<(build_vector), [{
  54   return X86::isUNPCKL_v_undef_Mask(N);
  55 }]>;
  56
  57 // Patterns for shuffling.
  58 def MMX_PSHUFW_shuffle_mask : PatLeaf<(build_vector), [{
  59   return X86::isPSHUFDMask(N);
  60 }], MMX_SHUFFLE_get_shuf_imm>;
  61
  62 // Patterns for: vector_shuffle v1, v2, <4, 5, 2, 3>; etc.
  63 def MMX_MOVL_shuffle_mask : PatLeaf<(build_vector), [{
  64   return X86::isMOVLMask(N);
  65 }]>;
  66
  67 //===----------------------------------------------------------------------===//
  68 // MMX Multiclasses
  69 //===----------------------------------------------------------------------===//
  70
  71 let isTwoAddress = 1 in {
  72   // MMXI_binop_rm - Simple MMX binary operator.
  73   multiclass MMXI_binop_rm<bits<8> opc, string OpcodeStr, SDNode OpNode,
  74                            ValueType OpVT, bit Commutable = 0> {
  75     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
  76                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  77                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1, VR64:$src2)))]> {
  78       let isCommutable = Commutable;
  79     }
  80     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
  81                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  82                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1,
  83                                          (bitconvert
  84                                           (load_mmx addr:$src2)))))]>;
  85   }
  86
  87   multiclass MMXI_binop_rm_int<bits<8> opc, string OpcodeStr, Intrinsic IntId,
  88                                bit Commutable = 0> {
  89     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
  90                  !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  91                  [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]> {
  92       let isCommutable = Commutable;
  93     }
  94     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
  95                  !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  96                  [(set VR64:$dst, (IntId VR64:$src1,
  97                                    (bitconvert (load_mmx addr:$src2))))]>;
  98   }
  99
 100   // MMXI_binop_rm_v1i64 - Simple MMX binary operator whose type is v1i64.
 101   //
 102   // FIXME: we could eliminate this and use MMXI_binop_rm instead if tblgen knew
 103   // to collapse (bitconvert VT to VT) into its operand.
 104   //
 105   multiclass MMXI_binop_rm_v1i64<bits<8> opc, string OpcodeStr, SDNode OpNode,
 106                                  bit Commutable = 0> {
 107     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
 108                                   (ins VR64:$src1, VR64:$src2),
 109                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 110                   [(set VR64:$dst, (v1i64 (OpNode VR64:$src1, VR64:$src2)))]> {
 111       let isCommutable = Commutable;
 112     }
 113     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
 114                                   (ins VR64:$src1, i64mem:$src2),
 115                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 116                   [(set VR64:$dst,
 117                     (OpNode VR64:$src1,(load_mmx addr:$src2)))]>;
 118   }
 119
 120   multiclass MMXI_binop_rmi_int<bits<8> opc, bits<8> opc2, Format ImmForm,
 121                                 string OpcodeStr, Intrinsic IntId,
 122                                 Intrinsic IntId2> {
 123     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
 124                                   (ins VR64:$src1, VR64:$src2),
 125                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 126                   [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]>;
 127     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
 128                                   (ins VR64:$src1, i64mem:$src2),
 129                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 130                   [(set VR64:$dst, (IntId VR64:$src1,
 131                                     (bitconvert (load_mmx addr:$src2))))]>;
 132     def ri : MMXIi8<opc2, ImmForm, (outs VR64:$dst),
 133                                    (ins VR64:$src1, i32i8imm:$src2),
 134                     !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 135            [(set VR64:$dst, (IntId2 VR64:$src1, (i32 imm:$src2)))]>;
 136   }
 137 }
 138
 139 //===----------------------------------------------------------------------===//
 140 // MMX EMMS & FEMMS Instructions
 141 //===----------------------------------------------------------------------===//
 142
 143 def MMX_EMMS  : MMXI<0x77, RawFrm, (outs), (ins), "emms",  [(int_x86_mmx_emms)]>;
 144 def MMX_FEMMS : MMXI<0x0E, RawFrm, (outs), (ins), "femms", [(int_x86_mmx_femms)]>;
 145
 146 //===----------------------------------------------------------------------===//
 147 // MMX Scalar Instructions
 148 //===----------------------------------------------------------------------===//
 149
 150 // Data Transfer Instructions
 151 def MMX_MOVD64rr : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR32:$src),
 152                         "movd\t{$src, $dst|$dst, $src}",
 153                         [(set VR64:$dst, (v2i32 (scalar_to_vector GR32:$src)))]>;
 154 let isSimpleLoad = 1, isReMaterializable = 1 in
 155 def MMX_MOVD64rm : MMXI<0x6E, MRMSrcMem, (outs VR64:$dst), (ins i32mem:$src),
 156                         "movd\t{$src, $dst|$dst, $src}",
 157               [(set VR64:$dst, (v2i32 (scalar_to_vector (loadi32 addr:$src))))]>;
 158 let mayStore = 1 in
 159 def MMX_MOVD64mr : MMXI<0x7E, MRMDestMem, (outs), (ins i32mem:$dst, VR64:$src),
 160                         "movd\t{$src, $dst|$dst, $src}", []>;
 161
 162 let neverHasSideEffects = 1 in
 163 def MMX_MOVD64to64rr : MMXRI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR64:$src),
 164                              "movd\t{$src, $dst|$dst, $src}", []>;
 165
 166 let neverHasSideEffects = 1 in
 167 def MMX_MOVD64from64rr : MMXRI<0x7E, MRMSrcReg, (outs GR64:$dst), (ins VR64:$src),
 168                                "movd\t{$src, $dst|$dst, $src}", []>;
 169
 170 let neverHasSideEffects = 1 in
 171 def MMX_MOVQ64rr : MMXI<0x6F, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src),
 172                         "movq\t{$src, $dst|$dst, $src}", []>;
 173 let isSimpleLoad = 1, isReMaterializable = 1, mayHaveSideEffects = 1 in
 174 def MMX_MOVQ64rm : MMXI<0x6F, MRMSrcMem, (outs VR64:$dst), (ins i64mem:$src),
 175                         "movq\t{$src, $dst|$dst, $src}",
 176                         [(set VR64:$dst, (load_mmx addr:$src))]>;
 177 def MMX_MOVQ64mr : MMXI<0x7F, MRMDestMem, (outs), (ins i64mem:$dst, VR64:$src),
 178                         "movq\t{$src, $dst|$dst, $src}",
 179                         [(store (v1i64 VR64:$src), addr:$dst)]>;
 180
 181 def MMX_MOVDQ2Qrr : MMXID<0xD6, MRMDestMem, (outs VR64:$dst), (ins VR128:$src),
 182                           "movdq2q\t{$src, $dst|$dst, $src}",
 183                           [(set VR64:$dst,
 184                             (v1i64 (bitconvert
 185                             (i64 (vector_extract (v2i64 VR128:$src),
 186                                   (iPTR 0))))))]>;
 187
 188 def MMX_MOVQ2DQrr : MMXIS<0xD6, MRMDestMem, (outs VR128:$dst), (ins VR64:$src),
 189                           "movq2dq\t{$src, $dst|$dst, $src}",
 190           [(set VR128:$dst,
 191                 (v2i64 (vector_shuffle immAllZerosV,
 192                         (v2i64 (scalar_to_vector (i64 (bitconvert VR64:$src)))),
 193                         MOVL_shuffle_mask)))]>;
 194
 195 def MMX_MOVNTQmr  : MMXI<0xE7, MRMDestMem, (outs), (ins i64mem:$dst, VR64:$src),
 196                          "movntq\t{$src, $dst|$dst, $src}",
 197                          [(int_x86_mmx_movnt_dq addr:$dst, VR64:$src)]>;
 198
 199 let AddedComplexity = 15 in
 200 // movd to MMX register zero-extends
 201 def MMX_MOVZDI2PDIrr : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR32:$src),
 202                              "movd\t{$src, $dst|$dst, $src}",
 203                              [(set VR64:$dst,
 204                                (v2i32 (vector_shuffle immAllZerosV,
 205                                        (v2i32 (scalar_to_vector GR32:$src)),
 206                                        MMX_MOVL_shuffle_mask)))]>;
 207 let AddedComplexity = 20 in
 208 def MMX_MOVZDI2PDIrm : MMXI<0x6E, MRMSrcMem, (outs VR64:$dst), (ins i32mem:$src),
 209                              "movd\t{$src, $dst|$dst, $src}",
 210                              [(set VR64:$dst,
 211                                (v2i32 (vector_shuffle immAllZerosV,
 212                                        (v2i32 (scalar_to_vector
 213                                                (loadi32 addr:$src))),
 214                                        MMX_MOVL_shuffle_mask)))]>;
 215
 216 // Arithmetic Instructions
 217
 218 // -- Addition
 219 defm MMX_PADDB : MMXI_binop_rm<0xFC, "paddb", add, v8i8,  1>;
 220 defm MMX_PADDW : MMXI_binop_rm<0xFD, "paddw", add, v4i16, 1>;
 221 defm MMX_PADDD : MMXI_binop_rm<0xFE, "paddd", add, v2i32, 1>;
 222 defm MMX_PADDQ : MMXI_binop_rm<0xD4, "paddq", add, v1i64, 1>;
 223
 224 defm MMX_PADDSB  : MMXI_binop_rm_int<0xEC, "paddsb" , int_x86_mmx_padds_b, 1>;
 225 defm MMX_PADDSW  : MMXI_binop_rm_int<0xED, "paddsw" , int_x86_mmx_padds_w, 1>;
 226
 227 defm MMX_PADDUSB : MMXI_binop_rm_int<0xDC, "paddusb", int_x86_mmx_paddus_b, 1>;
 228 defm MMX_PADDUSW : MMXI_binop_rm_int<0xDD, "paddusw", int_x86_mmx_paddus_w, 1>;
 229
 230 // -- Subtraction
 231 defm MMX_PSUBB : MMXI_binop_rm<0xF8, "psubb", sub, v8i8>;
 232 defm MMX_PSUBW : MMXI_binop_rm<0xF9, "psubw", sub, v4i16>;
 233 defm MMX_PSUBD : MMXI_binop_rm<0xFA, "psubd", sub, v2i32>;
 234 defm MMX_PSUBQ : MMXI_binop_rm<0xFB, "psubq", sub, v1i64>;
 235
 236 defm MMX_PSUBSB  : MMXI_binop_rm_int<0xE8, "psubsb" , int_x86_mmx_psubs_b>;
 237 defm MMX_PSUBSW  : MMXI_binop_rm_int<0xE9, "psubsw" , int_x86_mmx_psubs_w>;
 238
 239 defm MMX_PSUBUSB : MMXI_binop_rm_int<0xD8, "psubusb", int_x86_mmx_psubus_b>;
 240 defm MMX_PSUBUSW : MMXI_binop_rm_int<0xD9, "psubusw", int_x86_mmx_psubus_w>;
 241
 242 // -- Multiplication
 243 defm MMX_PMULLW  : MMXI_binop_rm<0xD5, "pmullw", mul, v4i16, 1>;
 244
 245 defm MMX_PMULHW  : MMXI_binop_rm_int<0xE5, "pmulhw",  int_x86_mmx_pmulh_w,  1>;
 246 defm MMX_PMULHUW : MMXI_binop_rm_int<0xE4, "pmulhuw", int_x86_mmx_pmulhu_w, 1>;
 247 defm MMX_PMULUDQ : MMXI_binop_rm_int<0xF4, "pmuludq", int_x86_mmx_pmulu_dq, 1>;
 248
 249 // -- Miscellanea
 250 defm MMX_PMADDWD : MMXI_binop_rm_int<0xF5, "pmaddwd", int_x86_mmx_pmadd_wd, 1>;
 251
 252 defm MMX_PAVGB   : MMXI_binop_rm_int<0xE0, "pavgb", int_x86_mmx_pavg_b, 1>;
 253 defm MMX_PAVGW   : MMXI_binop_rm_int<0xE3, "pavgw", int_x86_mmx_pavg_w, 1>;
 254
 255 defm MMX_PMINUB  : MMXI_binop_rm_int<0xDA, "pminub", int_x86_mmx_pminu_b, 1>;
 256 defm MMX_PMINSW  : MMXI_binop_rm_int<0xEA, "pminsw", int_x86_mmx_pmins_w, 1>;
 257
 258 defm MMX_PMAXUB  : MMXI_binop_rm_int<0xDE, "pmaxub", int_x86_mmx_pmaxu_b, 1>;
 259 defm MMX_PMAXSW  : MMXI_binop_rm_int<0xEE, "pmaxsw", int_x86_mmx_pmaxs_w, 1>;
 260
 261 defm MMX_PSADBW  : MMXI_binop_rm_int<0xE0, "psadbw", int_x86_mmx_psad_bw, 1>;
 262
 263 // Logical Instructions
 264 defm MMX_PAND : MMXI_binop_rm_v1i64<0xDB, "pand", and, 1>;
 265 defm MMX_POR  : MMXI_binop_rm_v1i64<0xEB, "por" , or,  1>;
 266 defm MMX_PXOR : MMXI_binop_rm_v1i64<0xEF, "pxor", xor, 1>;
 267
 268 let isTwoAddress = 1 in {
 269   def MMX_PANDNrr : MMXI<0xDF, MRMSrcReg,
 270                          (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 271                          "pandn\t{$src2, $dst|$dst, $src2}",
 272                          [(set VR64:$dst, (v1i64 (and (vnot VR64:$src1),
 273                                                   VR64:$src2)))]>;
 274   def MMX_PANDNrm : MMXI<0xDF, MRMSrcMem,
 275                          (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 276                          "pandn\t{$src2, $dst|$dst, $src2}",
 277                          [(set VR64:$dst, (v1i64 (and (vnot VR64:$src1),
 278                                                   (load addr:$src2))))]>;
 279 }
 280
 281 // Shift Instructions
 282 defm MMX_PSRLW : MMXI_binop_rmi_int<0xD1, 0x71, MRM2r, "psrlw",
 283                                     int_x86_mmx_psrl_w, int_x86_mmx_psrli_w>;
 284 defm MMX_PSRLD : MMXI_binop_rmi_int<0xD2, 0x72, MRM2r, "psrld",
 285                                     int_x86_mmx_psrl_d, int_x86_mmx_psrli_d>;
 286 defm MMX_PSRLQ : MMXI_binop_rmi_int<0xD3, 0x73, MRM2r, "psrlq",
 287                                     int_x86_mmx_psrl_q, int_x86_mmx_psrli_q>;
 288
 289 defm MMX_PSLLW : MMXI_binop_rmi_int<0xF1, 0x71, MRM6r, "psllw",
 290                                     int_x86_mmx_psll_w, int_x86_mmx_pslli_w>;
 291 defm MMX_PSLLD : MMXI_binop_rmi_int<0xF2, 0x72, MRM6r, "pslld",
 292                                     int_x86_mmx_psll_d, int_x86_mmx_pslli_d>;
 293 defm MMX_PSLLQ : MMXI_binop_rmi_int<0xF3, 0x73, MRM6r, "psllq",
 294                                     int_x86_mmx_psll_q, int_x86_mmx_pslli_q>;
 295
 296 defm MMX_PSRAW : MMXI_binop_rmi_int<0xE1, 0x71, MRM4r, "psraw",
 297                                     int_x86_mmx_psra_w, int_x86_mmx_psrai_w>;
 298 defm MMX_PSRAD : MMXI_binop_rmi_int<0xE2, 0x72, MRM4r, "psrad",
 299                                     int_x86_mmx_psra_d, int_x86_mmx_psrai_d>;
 300
 301 // Comparison Instructions
 302 defm MMX_PCMPEQB : MMXI_binop_rm_int<0x74, "pcmpeqb", int_x86_mmx_pcmpeq_b>;
 303 defm MMX_PCMPEQW : MMXI_binop_rm_int<0x75, "pcmpeqw", int_x86_mmx_pcmpeq_w>;
 304 defm MMX_PCMPEQD : MMXI_binop_rm_int<0x76, "pcmpeqd", int_x86_mmx_pcmpeq_d>;
 305
 306 defm MMX_PCMPGTB : MMXI_binop_rm_int<0x64, "pcmpgtb", int_x86_mmx_pcmpgt_b>;
 307 defm MMX_PCMPGTW : MMXI_binop_rm_int<0x65, "pcmpgtw", int_x86_mmx_pcmpgt_w>;
 308 defm MMX_PCMPGTD : MMXI_binop_rm_int<0x66, "pcmpgtd", int_x86_mmx_pcmpgt_d>;
 309
 310 // Conversion Instructions
 311
 312 // -- Unpack Instructions
 313 let isTwoAddress = 1 in {
 314   // Unpack High Packed Data Instructions
 315   def MMX_PUNPCKHBWrr : MMXI<0x68, MRMSrcReg,
 316                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 317                              "punpckhbw\t{$src2, $dst|$dst, $src2}",
 318                              [(set VR64:$dst,
 319                                (v8i8 (vector_shuffle VR64:$src1, VR64:$src2,
 320                                       MMX_UNPCKH_shuffle_mask)))]>;
 321   def MMX_PUNPCKHBWrm : MMXI<0x68, MRMSrcMem,
 322                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 323                              "punpckhbw\t{$src2, $dst|$dst, $src2}",
 324                              [(set VR64:$dst,
 325                                (v8i8 (vector_shuffle VR64:$src1,
 326                                       (bc_v8i8 (load_mmx addr:$src2)),
 327                                       MMX_UNPCKH_shuffle_mask)))]>;
 328
 329   def MMX_PUNPCKHWDrr : MMXI<0x69, MRMSrcReg,
 330                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 331                              "punpckhwd\t{$src2, $dst|$dst, $src2}",
 332                              [(set VR64:$dst,
 333                                (v4i16 (vector_shuffle VR64:$src1, VR64:$src2,
 334                                        MMX_UNPCKH_shuffle_mask)))]>;
 335   def MMX_PUNPCKHWDrm : MMXI<0x69, MRMSrcMem,
 336                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 337                              "punpckhwd\t{$src2, $dst|$dst, $src2}",
 338                              [(set VR64:$dst,
 339                                (v4i16 (vector_shuffle VR64:$src1,
 340                                        (bc_v4i16 (load_mmx addr:$src2)),
 341                                        MMX_UNPCKH_shuffle_mask)))]>;
 342
 343   def MMX_PUNPCKHDQrr : MMXI<0x6A, MRMSrcReg,
 344                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 345                              "punpckhdq\t{$src2, $dst|$dst, $src2}",
 346                              [(set VR64:$dst,
 347                                (v2i32 (vector_shuffle VR64:$src1, VR64:$src2,
 348                                        MMX_UNPCKH_shuffle_mask)))]>;
 349   def MMX_PUNPCKHDQrm : MMXI<0x6A, MRMSrcMem,
 350                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 351                              "punpckhdq\t{$src2, $dst|$dst, $src2}",
 352                              [(set VR64:$dst,
 353                                (v2i32 (vector_shuffle VR64:$src1,
 354                                        (bc_v2i32 (load_mmx addr:$src2)),
 355                                        MMX_UNPCKH_shuffle_mask)))]>;
 356
 357   // Unpack Low Packed Data Instructions
 358   def MMX_PUNPCKLBWrr : MMXI<0x60, MRMSrcReg,
 359                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 360                              "punpcklbw\t{$src2, $dst|$dst, $src2}",
 361                              [(set VR64:$dst,
 362                                (v8i8 (vector_shuffle VR64:$src1, VR64:$src2,
 363                                       MMX_UNPCKL_shuffle_mask)))]>;
 364   def MMX_PUNPCKLBWrm : MMXI<0x60, MRMSrcMem,
 365                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 366                              "punpcklbw\t{$src2, $dst|$dst, $src2}",
 367                              [(set VR64:$dst,
 368                                (v8i8 (vector_shuffle VR64:$src1,
 369                                       (bc_v8i8 (load_mmx addr:$src2)),
 370                                       MMX_UNPCKL_shuffle_mask)))]>;
 371
 372   def MMX_PUNPCKLWDrr : MMXI<0x61, MRMSrcReg,
 373                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 374                              "punpcklwd\t{$src2, $dst|$dst, $src2}",
 375                              [(set VR64:$dst,
 376                                (v4i16 (vector_shuffle VR64:$src1, VR64:$src2,
 377                                        MMX_UNPCKL_shuffle_mask)))]>;
 378   def MMX_PUNPCKLWDrm : MMXI<0x61, MRMSrcMem,
 379                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 380                              "punpcklwd\t{$src2, $dst|$dst, $src2}",
 381                              [(set VR64:$dst,
 382                                (v4i16 (vector_shuffle VR64:$src1,
 383                                        (bc_v4i16 (load_mmx addr:$src2)),
 384                                        MMX_UNPCKL_shuffle_mask)))]>;
 385
 386   def MMX_PUNPCKLDQrr : MMXI<0x62, MRMSrcReg,
 387                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 388                              "punpckldq\t{$src2, $dst|$dst, $src2}",
 389                              [(set VR64:$dst,
 390                                (v2i32 (vector_shuffle VR64:$src1, VR64:$src2,
 391                                        MMX_UNPCKL_shuffle_mask)))]>;
 392   def MMX_PUNPCKLDQrm : MMXI<0x62, MRMSrcMem,
 393                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 394                              "punpckldq\t{$src2, $dst|$dst, $src2}",
 395                              [(set VR64:$dst,
 396                                (v2i32 (vector_shuffle VR64:$src1,
 397                                        (bc_v2i32 (load_mmx addr:$src2)),
 398                                        MMX_UNPCKL_shuffle_mask)))]>;
 399 }
 400
 401 // -- Pack Instructions
 402 defm MMX_PACKSSWB : MMXI_binop_rm_int<0x63, "packsswb", int_x86_mmx_packsswb>;
 403 defm MMX_PACKSSDW : MMXI_binop_rm_int<0x6B, "packssdw", int_x86_mmx_packssdw>;
 404 defm MMX_PACKUSWB : MMXI_binop_rm_int<0x67, "packuswb", int_x86_mmx_packuswb>;
 405
 406 // -- Shuffle Instructions
 407 def MMX_PSHUFWri : MMXIi8<0x70, MRMSrcReg,
 408                           (outs VR64:$dst), (ins VR64:$src1, i8imm:$src2),
 409                           "pshufw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 410                           [(set VR64:$dst,
 411                             (v4i16 (vector_shuffle
 412                                     VR64:$src1, (undef),
 413                                     MMX_PSHUFW_shuffle_mask:$src2)))]>;
 414 def MMX_PSHUFWmi : MMXIi8<0x70, MRMSrcMem,
 415                           (outs VR64:$dst), (ins i64mem:$src1, i8imm:$src2),
 416                           "pshufw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 417                           [(set VR64:$dst,
 418                             (v4i16 (vector_shuffle
 419                                     (bc_v4i16 (load_mmx addr:$src1)),
 420                                     (undef),
 421                                     MMX_PSHUFW_shuffle_mask:$src2)))]>;
 422
 423 // -- Conversion Instructions
 424 let neverHasSideEffects = 1 in {
 425 def MMX_CVTPD2PIrr  : MMX2I<0x2D, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 426                             "cvtpd2pi\t{$src, $dst|$dst, $src}", []>;
 427 let mayLoad = 1 in
 428 def MMX_CVTPD2PIrm  : MMX2I<0x2D, MRMSrcMem, (outs VR64:$dst), (ins f128mem:$src),
 429                             "cvtpd2pi\t{$src, $dst|$dst, $src}", []>;
 430
 431 def MMX_CVTPI2PDrr  : MMX2I<0x2A, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 432                             "cvtpi2pd\t{$src, $dst|$dst, $src}", []>;
 433 let mayLoad = 1 in
 434 def MMX_CVTPI2PDrm  : MMX2I<0x2A, MRMSrcMem, (outs VR128:$dst), (ins i64mem:$src),
 435                             "cvtpi2pd\t{$src, $dst|$dst, $src}", []>;
 436
 437 def MMX_CVTPI2PSrr  : MMXI<0x2A, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 438                            "cvtpi2ps\t{$src, $dst|$dst, $src}", []>;
 439 let mayLoad = 1 in
 440 def MMX_CVTPI2PSrm  : MMXI<0x2A, MRMSrcMem, (outs VR128:$dst), (ins i64mem:$src),
 441                            "cvtpi2ps\t{$src, $dst|$dst, $src}", []>;
 442
 443 def MMX_CVTPS2PIrr  : MMXI<0x2D, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 444                            "cvtps2pi\t{$src, $dst|$dst, $src}", []>;
 445 let mayLoad = 1 in
 446 def MMX_CVTPS2PIrm  : MMXI<0x2D, MRMSrcMem, (outs VR64:$dst), (ins f64mem:$src),
 447                            "cvtps2pi\t{$src, $dst|$dst, $src}", []>;
 448
 449 def MMX_CVTTPD2PIrr : MMX2I<0x2C, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 450                             "cvttpd2pi\t{$src, $dst|$dst, $src}", []>;
 451 let mayLoad = 1 in
 452 def MMX_CVTTPD2PIrm : MMX2I<0x2C, MRMSrcMem, (outs VR64:$dst), (ins f128mem:$src),
 453                             "cvttpd2pi\t{$src, $dst|$dst, $src}", []>;
 454
 455 def MMX_CVTTPS2PIrr : MMXI<0x2C, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 456                            "cvttps2pi\t{$src, $dst|$dst, $src}", []>;
 457 let mayLoad = 1 in
 458 def MMX_CVTTPS2PIrm : MMXI<0x2C, MRMSrcMem, (outs VR64:$dst), (ins f64mem:$src),
 459                            "cvttps2pi\t{$src, $dst|$dst, $src}", []>;
 460 } // end neverHasSideEffects
 461
 462
 463 // Extract / Insert
 464 def MMX_X86pextrw : SDNode<"X86ISD::PEXTRW", SDTypeProfile<1, 2, []>, []>;
 465 def MMX_X86pinsrw : SDNode<"X86ISD::PINSRW", SDTypeProfile<1, 3, []>, []>;
 466
 467 def MMX_PEXTRWri  : MMXIi8<0xC5, MRMSrcReg,
 468                            (outs GR32:$dst), (ins VR64:$src1, i16i8imm:$src2),
 469                            "pextrw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 470                            [(set GR32:$dst, (MMX_X86pextrw (v4i16 VR64:$src1),
 471                                              (iPTR imm:$src2)))]>;
 472 let isTwoAddress = 1 in {
 473   def MMX_PINSRWrri : MMXIi8<0xC4, MRMSrcReg,
 474                       (outs VR64:$dst), (ins VR64:$src1, GR32:$src2, i16i8imm:$src3),
 475                       "pinsrw\t{$src3, $src2, $dst|$dst, $src2, $src3}",
 476                       [(set VR64:$dst, (v4i16 (MMX_X86pinsrw (v4i16 VR64:$src1),
 477                                                GR32:$src2, (iPTR imm:$src3))))]>;
 478   def MMX_PINSRWrmi : MMXIi8<0xC4, MRMSrcMem,
 479                      (outs VR64:$dst), (ins VR64:$src1, i16mem:$src2, i16i8imm:$src3),
 480                      "pinsrw\t{$src3, $src2, $dst|$dst, $src2, $src3}",
 481                      [(set VR64:$dst,
 482                        (v4i16 (MMX_X86pinsrw (v4i16 VR64:$src1),
 483                                (i32 (anyext (loadi16 addr:$src2))),
 484                                (iPTR imm:$src3))))]>;
 485 }
 486
 487 // Mask creation
 488 def MMX_PMOVMSKBrr : MMXI<0xD7, MRMSrcReg, (outs GR32:$dst), (ins VR64:$src),
 489                           "pmovmskb\t{$src, $dst|$dst, $src}",
 490                           [(set GR32:$dst, (int_x86_mmx_pmovmskb VR64:$src))]>;
 491
 492 // Misc.
 493 let Uses = [EDI] in
 494 def MMX_MASKMOVQ : MMXI<0xF7, MRMDestMem, (outs), (ins VR64:$src, VR64:$mask),
 495                         "maskmovq\t{$mask, $src|$src, $mask}",
 496                         [(int_x86_mmx_maskmovq VR64:$src, VR64:$mask, EDI)]>;
 497
 498 //===----------------------------------------------------------------------===//
 499 // Alias Instructions
 500 //===----------------------------------------------------------------------===//
 501
 502 // Alias instructions that map zero vector to pxor.
 503 let isReMaterializable = 1 in {
 504   def MMX_V_SET0       : MMXI<0xEF, MRMInitReg, (outs VR64:$dst), (ins),
 505                               "pxor\t$dst, $dst",
 506                               [(set VR64:$dst, (v2i32 immAllZerosV))]>;
 507   def MMX_V_SETALLONES : MMXI<0x76, MRMInitReg, (outs VR64:$dst), (ins),
 508                               "pcmpeqd\t$dst, $dst",
 509                               [(set VR64:$dst, (v2i32 immAllOnesV))]>;
 510 }
 511
 512 let Predicates = [HasMMX] in {
 513   def : Pat<(v1i64 immAllZerosV), (MMX_V_SET0)>;
 514   def : Pat<(v4i16 immAllZerosV), (MMX_V_SET0)>;
 515   def : Pat<(v8i8  immAllZerosV), (MMX_V_SET0)>;
 516 }
 517
 518 //===----------------------------------------------------------------------===//
 519 // Non-Instruction Patterns
 520 //===----------------------------------------------------------------------===//
 521
 522 // Store 64-bit integer vector values.
 523 def : Pat<(store (v8i8  VR64:$src), addr:$dst),
 524           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 525 def : Pat<(store (v4i16 VR64:$src), addr:$dst),
 526           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 527 def : Pat<(store (v2i32 VR64:$src), addr:$dst),
 528           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 529 def : Pat<(store (v1i64 VR64:$src), addr:$dst),
 530           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 531
 532 // Bit convert.
 533 def : Pat<(v8i8  (bitconvert (v1i64 VR64:$src))), (v8i8  VR64:$src)>;
 534 def : Pat<(v8i8  (bitconvert (v2i32 VR64:$src))), (v8i8  VR64:$src)>;
 535 def : Pat<(v8i8  (bitconvert (v4i16 VR64:$src))), (v8i8  VR64:$src)>;
 536 def : Pat<(v4i16 (bitconvert (v1i64 VR64:$src))), (v4i16 VR64:$src)>;
 537 def : Pat<(v4i16 (bitconvert (v2i32 VR64:$src))), (v4i16 VR64:$src)>;
 538 def : Pat<(v4i16 (bitconvert (v8i8  VR64:$src))), (v4i16 VR64:$src)>;
 539 def : Pat<(v2i32 (bitconvert (v1i64 VR64:$src))), (v2i32 VR64:$src)>;
 540 def : Pat<(v2i32 (bitconvert (v4i16 VR64:$src))), (v2i32 VR64:$src)>;
 541 def : Pat<(v2i32 (bitconvert (v8i8  VR64:$src))), (v2i32 VR64:$src)>;
 542 def : Pat<(v1i64 (bitconvert (v2i32 VR64:$src))), (v1i64 VR64:$src)>;
 543 def : Pat<(v1i64 (bitconvert (v4i16 VR64:$src))), (v1i64 VR64:$src)>;
 544 def : Pat<(v1i64 (bitconvert (v8i8  VR64:$src))), (v1i64 VR64:$src)>;
 545
 546 // 64-bit bit convert.
 547 def : Pat<(v1i64 (bitconvert (i64 GR64:$src))),
 548           (MMX_MOVD64to64rr GR64:$src)>;
 549 def : Pat<(v2i32 (bitconvert (i64 GR64:$src))),
 550           (MMX_MOVD64to64rr GR64:$src)>;
 551 def : Pat<(v4i16 (bitconvert (i64 GR64:$src))),
 552           (MMX_MOVD64to64rr GR64:$src)>;
 553 def : Pat<(v8i8  (bitconvert (i64 GR64:$src))),
 554           (MMX_MOVD64to64rr GR64:$src)>;
 555 def : Pat<(i64 (bitconvert (v1i64 VR64:$src))),
 556           (MMX_MOVD64from64rr VR64:$src)>;
 557 def : Pat<(i64 (bitconvert (v2i32 VR64:$src))),
 558           (MMX_MOVD64from64rr VR64:$src)>;
 559 def : Pat<(i64 (bitconvert (v4i16 VR64:$src))),
 560           (MMX_MOVD64from64rr VR64:$src)>;
 561 def : Pat<(i64  (bitconvert (v8i8 VR64:$src))),
 562           (MMX_MOVD64from64rr VR64:$src)>;
 563
 564 // Move scalar to XMM zero-extended
 565 // movd to XMM register zero-extends
 566 let AddedComplexity = 15 in {
 567   def : Pat<(v8i8 (vector_shuffle immAllZerosV_bc,
 568                     (bc_v8i8 (v2i32 (scalar_to_vector GR32:$src))),
 569                     MMX_MOVL_shuffle_mask)),
 570             (MMX_MOVZDI2PDIrr GR32:$src)>;
 571   def : Pat<(v4i16 (vector_shuffle immAllZerosV_bc,
 572                     (bc_v4i16 (v2i32 (scalar_to_vector GR32:$src))),
 573                     MMX_MOVL_shuffle_mask)),
 574             (MMX_MOVZDI2PDIrr GR32:$src)>;
 575 }
 576
 577 // Scalar to v4i16 / v8i8. The source may be a GR32, but only the lower
 578 // 8 or 16-bits matter.
 579 def : Pat<(bc_v8i8  (v2i32 (scalar_to_vector GR32:$src))),
 580           (MMX_MOVD64rr GR32:$src)>;
 581 def : Pat<(bc_v4i16 (v2i32 (scalar_to_vector GR32:$src))),
 582           (MMX_MOVD64rr GR32:$src)>;
 583
 584 // Patterns to perform canonical versions of vector shuffling.
 585 let AddedComplexity = 10 in {
 586   def : Pat<(v8i8  (vector_shuffle VR64:$src, (undef),
 587                     MMX_UNPCKL_v_undef_shuffle_mask)),
 588             (MMX_PUNPCKLBWrr VR64:$src, VR64:$src)>;
 589   def : Pat<(v4i16 (vector_shuffle VR64:$src, (undef),
 590                     MMX_UNPCKL_v_undef_shuffle_mask)),
 591             (MMX_PUNPCKLWDrr VR64:$src, VR64:$src)>;
 592   def : Pat<(v2i32 (vector_shuffle VR64:$src, (undef),
 593                     MMX_UNPCKL_v_undef_shuffle_mask)),
 594             (MMX_PUNPCKLDQrr VR64:$src, VR64:$src)>;
 595 }
 596
 597 let AddedComplexity = 10 in {
 598   def : Pat<(v8i8  (vector_shuffle VR64:$src, (undef),
 599                     MMX_UNPCKH_v_undef_shuffle_mask)),
 600             (MMX_PUNPCKHBWrr VR64:$src, VR64:$src)>;
 601   def : Pat<(v4i16 (vector_shuffle VR64:$src, (undef),
 602                     MMX_UNPCKH_v_undef_shuffle_mask)),
 603             (MMX_PUNPCKHWDrr VR64:$src, VR64:$src)>;
 604   def : Pat<(v2i32 (vector_shuffle VR64:$src, (undef),
 605                     MMX_UNPCKH_v_undef_shuffle_mask)),
 606             (MMX_PUNPCKHDQrr VR64:$src, VR64:$src)>;
 607 }
 608
 609 // Patterns to perform vector shuffling with a zeroed out vector.
 610 let AddedComplexity = 20 in {
 611   def : Pat<(bc_v2i32 (vector_shuffle immAllZerosV,
 612                        (v2i32 (scalar_to_vector (load_mmx addr:$src))),
 613                        MMX_UNPCKL_shuffle_mask)),
 614             (MMX_PUNPCKLDQrm VR64:$src, VR64:$src)>;
 615 }
 616
 617 // Some special case PANDN patterns.
 618 // FIXME: Get rid of these.
 619 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v2i32 immAllOnesV))),
 620                   VR64:$src2)),
 621           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 622 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v4i16 immAllOnesV_bc))),
 623                   VR64:$src2)),
 624           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 625 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v8i8  immAllOnesV_bc))),
 626                   VR64:$src2)),
 627           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 628
 629 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v2i32 immAllOnesV))),
 630                   (load addr:$src2))),
 631           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 632 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v4i16 immAllOnesV_bc))),
 633                   (load addr:$src2))),
 634           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 635 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v8i8  immAllOnesV_bc))),
 636                   (load addr:$src2))),
 637           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 638
 639 // Move MMX to lower 64-bit of XMM
 640 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert VR64:$src)))),
 641           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 642
 643 // Move lower 64-bit of XMM to MMX.
 644 def : Pat<(v2i32 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 645                                                   (iPTR 0))))),
 646           (v2i32 (MMX_MOVDQ2Qrr VR128:$src))>;
 647 def : Pat<(v4i16 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 648                                                   (iPTR 0))))),
 649           (v4i16 (MMX_MOVDQ2Qrr VR128:$src))>;
 650 def : Pat<(v8i8 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 651                                                   (iPTR 0))))),
 652           (v8i8 (MMX_MOVDQ2Qrr VR128:$src))>;
 653