lib/Target/X86/X86InstrFragmentsSIMD.td

   1 //======- X86InstrFragmentsSIMD.td - x86 ISA -------------*- tablegen -*-=====//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file provides pattern fragments useful for SIMD instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // MMX Pattern Fragments
  16 //===----------------------------------------------------------------------===//
  17
  18 def load_mmx : PatFrag<(ops node:$ptr), (x86mmx (load node:$ptr))>;
  19 def bc_mmx  : PatFrag<(ops node:$in), (x86mmx  (bitconvert node:$in))>;
  20
  21 //===----------------------------------------------------------------------===//
  22 // SSE specific DAG Nodes.
  23 //===----------------------------------------------------------------------===//
  24
  25 def SDTX86FPShiftOp : SDTypeProfile<1, 2, [ SDTCisSameAs<0, 1>,
  26                                             SDTCisFP<0>, SDTCisInt<2> ]>;
  27 def SDTX86VFCMP : SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<1, 2>,
  28                                        SDTCisFP<1>, SDTCisVT<3, i8>]>;
  29
  30 def X86fmin    : SDNode<"X86ISD::FMIN",      SDTFPBinOp>;
  31 def X86fmax    : SDNode<"X86ISD::FMAX",      SDTFPBinOp>;
  32 def X86fand    : SDNode<"X86ISD::FAND",      SDTFPBinOp,
  33                         [SDNPCommutative, SDNPAssociative]>;
  34 def X86for     : SDNode<"X86ISD::FOR",       SDTFPBinOp,
  35                         [SDNPCommutative, SDNPAssociative]>;
  36 def X86fxor    : SDNode<"X86ISD::FXOR",      SDTFPBinOp,
  37                         [SDNPCommutative, SDNPAssociative]>;
  38 def X86frsqrt  : SDNode<"X86ISD::FRSQRT",    SDTFPUnaryOp>;
  39 def X86frcp    : SDNode<"X86ISD::FRCP",      SDTFPUnaryOp>;
  40 def X86fsrl    : SDNode<"X86ISD::FSRL",      SDTX86FPShiftOp>;
  41 def X86fgetsign: SDNode<"X86ISD::FGETSIGNx86",SDTFPToIntOp>;
  42 def X86comi    : SDNode<"X86ISD::COMI",      SDTX86CmpTest>;
  43 def X86ucomi   : SDNode<"X86ISD::UCOMI",     SDTX86CmpTest>;
  44 def X86cmpss   : SDNode<"X86ISD::FSETCCss",    SDTX86Cmpss>;
  45 def X86cmpsd   : SDNode<"X86ISD::FSETCCsd",    SDTX86Cmpsd>;
  46 def X86pshufb  : SDNode<"X86ISD::PSHUFB",
  47                  SDTypeProfile<1, 2, [SDTCisVT<0, v16i8>, SDTCisSameAs<0,1>,
  48                                       SDTCisSameAs<0,2>]>>;
  49 def X86andnp   : SDNode<"X86ISD::ANDNP",
  50                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  51                                       SDTCisSameAs<0,2>]>>;
  52 def X86psignb  : SDNode<"X86ISD::PSIGNB",
  53                  SDTypeProfile<1, 2, [SDTCisVT<0, v16i8>, SDTCisSameAs<0,1>,
  54                                       SDTCisSameAs<0,2>]>>;
  55 def X86psignw  : SDNode<"X86ISD::PSIGNW",
  56                  SDTypeProfile<1, 2, [SDTCisVT<0, v8i16>, SDTCisSameAs<0,1>,
  57                                       SDTCisSameAs<0,2>]>>;
  58 def X86psignd  : SDNode<"X86ISD::PSIGND",
  59                  SDTypeProfile<1, 2, [SDTCisVT<0, v4i32>, SDTCisSameAs<0,1>,
  60                                       SDTCisSameAs<0,2>]>>;
  61 def X86pblendv : SDNode<"X86ISD::PBLENDVB",
  62                  SDTypeProfile<1, 3, [SDTCisVT<0, v16i8>, SDTCisSameAs<0,1>,
  63                                       SDTCisSameAs<0,2>, SDTCisSameAs<0,3>]>>;
  64 def X86pextrb  : SDNode<"X86ISD::PEXTRB",
  65                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  66 def X86pextrw  : SDNode<"X86ISD::PEXTRW",
  67                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  68 def X86pinsrb  : SDNode<"X86ISD::PINSRB",
  69                  SDTypeProfile<1, 3, [SDTCisVT<0, v16i8>, SDTCisSameAs<0,1>,
  70                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
  71 def X86pinsrw  : SDNode<"X86ISD::PINSRW",
  72                  SDTypeProfile<1, 3, [SDTCisVT<0, v8i16>, SDTCisSameAs<0,1>,
  73                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
  74 def X86insrtps : SDNode<"X86ISD::INSERTPS",
  75                  SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisSameAs<0,1>,
  76                                       SDTCisVT<2, v4f32>, SDTCisPtrTy<3>]>>;
  77 def X86vzmovl  : SDNode<"X86ISD::VZEXT_MOVL",
  78                  SDTypeProfile<1, 1, [SDTCisSameAs<0,1>]>>;
  79 def X86vzload  : SDNode<"X86ISD::VZEXT_LOAD", SDTLoad,
  80                         [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
  81 def X86vshl    : SDNode<"X86ISD::VSHL",      SDTIntShiftOp>;
  82 def X86vshr    : SDNode<"X86ISD::VSRL",      SDTIntShiftOp>;
  83 def X86cmpps   : SDNode<"X86ISD::CMPPS",     SDTX86VFCMP>;
  84 def X86cmppd   : SDNode<"X86ISD::CMPPD",     SDTX86VFCMP>;
  85 def X86pcmpeqb : SDNode<"X86ISD::PCMPEQB", SDTIntBinOp, [SDNPCommutative]>;
  86 def X86pcmpeqw : SDNode<"X86ISD::PCMPEQW", SDTIntBinOp, [SDNPCommutative]>;
  87 def X86pcmpeqd : SDNode<"X86ISD::PCMPEQD", SDTIntBinOp, [SDNPCommutative]>;
  88 def X86pcmpeqq : SDNode<"X86ISD::PCMPEQQ", SDTIntBinOp, [SDNPCommutative]>;
  89 def X86pcmpgtb : SDNode<"X86ISD::PCMPGTB", SDTIntBinOp>;
  90 def X86pcmpgtw : SDNode<"X86ISD::PCMPGTW", SDTIntBinOp>;
  91 def X86pcmpgtd : SDNode<"X86ISD::PCMPGTD", SDTIntBinOp>;
  92 def X86pcmpgtq : SDNode<"X86ISD::PCMPGTQ", SDTIntBinOp>;
  93
  94 def SDTX86CmpPTest : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
  95                                           SDTCisVec<1>,
  96                                           SDTCisSameAs<2, 1>]>;
  97 def X86ptest   : SDNode<"X86ISD::PTEST", SDTX86CmpPTest>;
  98 def X86testp   : SDNode<"X86ISD::TESTP", SDTX86CmpPTest>;
  99
 100 // Specific shuffle nodes - At some point ISD::VECTOR_SHUFFLE will always get
 101 // translated into one of the target nodes below during lowering.
 102 // Note: this is a work in progress...
 103 def SDTShuff1Op : SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisSameAs<0,1>]>;
 104 def SDTShuff2Op : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 105                                 SDTCisSameAs<0,2>]>;
 106
 107 def SDTShuff2OpI : SDTypeProfile<1, 2, [SDTCisVec<0>,
 108                                  SDTCisSameAs<0,1>, SDTCisInt<2>]>;
 109 def SDTShuff3OpI : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 110                                  SDTCisSameAs<0,2>, SDTCisInt<3>]>;
 111
 112 def X86PAlign : SDNode<"X86ISD::PALIGN", SDTShuff3OpI>;
 113
 114 def X86PShufd  : SDNode<"X86ISD::PSHUFD", SDTShuff2OpI>;
 115 def X86PShufhw : SDNode<"X86ISD::PSHUFHW", SDTShuff2OpI>;
 116 def X86PShuflw : SDNode<"X86ISD::PSHUFLW", SDTShuff2OpI>;
 117
 118 def X86Shufpd : SDNode<"X86ISD::SHUFPD", SDTShuff3OpI>;
 119 def X86Shufps : SDNode<"X86ISD::SHUFPS", SDTShuff3OpI>;
 120
 121 def X86Movddup  : SDNode<"X86ISD::MOVDDUP", SDTShuff1Op>;
 122 def X86Movshdup : SDNode<"X86ISD::MOVSHDUP", SDTShuff1Op>;
 123 def X86Movsldup : SDNode<"X86ISD::MOVSLDUP", SDTShuff1Op>;
 124
 125 def X86Movsd : SDNode<"X86ISD::MOVSD", SDTShuff2Op>;
 126 def X86Movss : SDNode<"X86ISD::MOVSS", SDTShuff2Op>;
 127
 128 def X86Movlhps : SDNode<"X86ISD::MOVLHPS", SDTShuff2Op>;
 129 def X86Movlhpd : SDNode<"X86ISD::MOVLHPD", SDTShuff2Op>;
 130 def X86Movhlps : SDNode<"X86ISD::MOVHLPS", SDTShuff2Op>;
 131 def X86Movhlpd : SDNode<"X86ISD::MOVHLPD", SDTShuff2Op>;
 132
 133 def X86Movlps : SDNode<"X86ISD::MOVLPS", SDTShuff2Op>;
 134 def X86Movlpd : SDNode<"X86ISD::MOVLPD", SDTShuff2Op>;
 135
 136 def X86Unpcklps  : SDNode<"X86ISD::UNPCKLPS", SDTShuff2Op>;
 137 def X86Unpcklpd  : SDNode<"X86ISD::UNPCKLPD", SDTShuff2Op>;
 138 def X86Unpcklpsy : SDNode<"X86ISD::VUNPCKLPSY", SDTShuff2Op>;
 139 def X86Unpcklpdy : SDNode<"X86ISD::VUNPCKLPDY", SDTShuff2Op>;
 140
 141 def X86Unpckhps  : SDNode<"X86ISD::UNPCKHPS", SDTShuff2Op>;
 142 def X86Unpckhpd  : SDNode<"X86ISD::UNPCKHPD", SDTShuff2Op>;
 143 def X86Unpckhpsy : SDNode<"X86ISD::VUNPCKHPSY", SDTShuff2Op>;
 144 def X86Unpckhpdy : SDNode<"X86ISD::VUNPCKHPDY", SDTShuff2Op>;
 145
 146 def X86Punpcklbw  : SDNode<"X86ISD::PUNPCKLBW", SDTShuff2Op>;
 147 def X86Punpcklwd  : SDNode<"X86ISD::PUNPCKLWD", SDTShuff2Op>;
 148 def X86Punpckldq  : SDNode<"X86ISD::PUNPCKLDQ", SDTShuff2Op>;
 149 def X86Punpcklqdq : SDNode<"X86ISD::PUNPCKLQDQ", SDTShuff2Op>;
 150
 151 def X86Punpckhbw  : SDNode<"X86ISD::PUNPCKHBW", SDTShuff2Op>;
 152 def X86Punpckhwd  : SDNode<"X86ISD::PUNPCKHWD", SDTShuff2Op>;
 153 def X86Punpckhdq  : SDNode<"X86ISD::PUNPCKHDQ", SDTShuff2Op>;
 154 def X86Punpckhqdq : SDNode<"X86ISD::PUNPCKHQDQ", SDTShuff2Op>;
 155
 156 def X86VPermilps  : SDNode<"X86ISD::VPERMILPS", SDTShuff2OpI>;
 157 def X86VPermilpsy : SDNode<"X86ISD::VPERMILPSY", SDTShuff2OpI>;
 158 def X86VPermilpd  : SDNode<"X86ISD::VPERMILPD", SDTShuff2OpI>;
 159 def X86VPermilpdy : SDNode<"X86ISD::VPERMILPDY", SDTShuff2OpI>;
 160
 161 //===----------------------------------------------------------------------===//
 162 // SSE Complex Patterns
 163 //===----------------------------------------------------------------------===//
 164
 165 // These are 'extloads' from a scalar to the low element of a vector, zeroing
 166 // the top elements.  These are used for the SSE 'ss' and 'sd' instruction
 167 // forms.
 168 def sse_load_f32 : ComplexPattern<v4f32, 5, "SelectScalarSSELoad", [],
 169                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 170                                    SDNPWantRoot]>;
 171 def sse_load_f64 : ComplexPattern<v2f64, 5, "SelectScalarSSELoad", [],
 172                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 173                                    SDNPWantRoot]>;
 174
 175 def ssmem : Operand<v4f32> {
 176   let PrintMethod = "printf32mem";
 177   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 178   let ParserMatchClass = X86MemAsmOperand;
 179   let OperandType = "OPERAND_MEMORY";
 180 }
 181 def sdmem : Operand<v2f64> {
 182   let PrintMethod = "printf64mem";
 183   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 184   let ParserMatchClass = X86MemAsmOperand;
 185   let OperandType = "OPERAND_MEMORY";
 186 }
 187
 188 //===----------------------------------------------------------------------===//
 189 // SSE pattern fragments
 190 //===----------------------------------------------------------------------===//
 191
 192 // 128-bit load pattern fragments
 193 def loadv4f32    : PatFrag<(ops node:$ptr), (v4f32 (load node:$ptr))>;
 194 def loadv2f64    : PatFrag<(ops node:$ptr), (v2f64 (load node:$ptr))>;
 195 def loadv4i32    : PatFrag<(ops node:$ptr), (v4i32 (load node:$ptr))>;
 196 def loadv2i64    : PatFrag<(ops node:$ptr), (v2i64 (load node:$ptr))>;
 197
 198 // 256-bit load pattern fragments
 199 def loadv8f32    : PatFrag<(ops node:$ptr), (v8f32 (load node:$ptr))>;
 200 def loadv4f64    : PatFrag<(ops node:$ptr), (v4f64 (load node:$ptr))>;
 201 def loadv8i32    : PatFrag<(ops node:$ptr), (v8i32 (load node:$ptr))>;
 202 def loadv4i64    : PatFrag<(ops node:$ptr), (v4i64 (load node:$ptr))>;
 203
 204 // Like 'store', but always requires vector alignment.
 205 def alignedstore : PatFrag<(ops node:$val, node:$ptr),
 206                            (store node:$val, node:$ptr), [{
 207   return cast<StoreSDNode>(N)->getAlignment() >= 16;
 208 }]>;
 209
 210 // Like 'load', but always requires vector alignment.
 211 def alignedload : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 212   return cast<LoadSDNode>(N)->getAlignment() >= 16;
 213 }]>;
 214
 215 def alignedloadfsf32 : PatFrag<(ops node:$ptr),
 216                                (f32 (alignedload node:$ptr))>;
 217 def alignedloadfsf64 : PatFrag<(ops node:$ptr),
 218                                (f64 (alignedload node:$ptr))>;
 219
 220 // 128-bit aligned load pattern fragments
 221 def alignedloadv4f32 : PatFrag<(ops node:$ptr),
 222                                (v4f32 (alignedload node:$ptr))>;
 223 def alignedloadv2f64 : PatFrag<(ops node:$ptr),
 224                                (v2f64 (alignedload node:$ptr))>;
 225 def alignedloadv4i32 : PatFrag<(ops node:$ptr),
 226                                (v4i32 (alignedload node:$ptr))>;
 227 def alignedloadv2i64 : PatFrag<(ops node:$ptr),
 228                                (v2i64 (alignedload node:$ptr))>;
 229
 230 // 256-bit aligned load pattern fragments
 231 def alignedloadv8f32 : PatFrag<(ops node:$ptr),
 232                                (v8f32 (alignedload node:$ptr))>;
 233 def alignedloadv4f64 : PatFrag<(ops node:$ptr),
 234                                (v4f64 (alignedload node:$ptr))>;
 235 def alignedloadv8i32 : PatFrag<(ops node:$ptr),
 236                                (v8i32 (alignedload node:$ptr))>;
 237 def alignedloadv4i64 : PatFrag<(ops node:$ptr),
 238                                (v4i64 (alignedload node:$ptr))>;
 239
 240 // Like 'load', but uses special alignment checks suitable for use in
 241 // memory operands in most SSE instructions, which are required to
 242 // be naturally aligned on some targets but not on others.  If the subtarget
 243 // allows unaligned accesses, match any load, though this may require
 244 // setting a feature bit in the processor (on startup, for example).
 245 // Opteron 10h and later implement such a feature.
 246 def memop : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 247   return    Subtarget->hasVectorUAMem()
 248          || cast<LoadSDNode>(N)->getAlignment() >= 16;
 249 }]>;
 250
 251 def memopfsf32 : PatFrag<(ops node:$ptr), (f32   (memop node:$ptr))>;
 252 def memopfsf64 : PatFrag<(ops node:$ptr), (f64   (memop node:$ptr))>;
 253
 254 // 128-bit memop pattern fragments
 255 def memopv4f32 : PatFrag<(ops node:$ptr), (v4f32 (memop node:$ptr))>;
 256 def memopv2f64 : PatFrag<(ops node:$ptr), (v2f64 (memop node:$ptr))>;
 257 def memopv4i32 : PatFrag<(ops node:$ptr), (v4i32 (memop node:$ptr))>;
 258 def memopv2i64 : PatFrag<(ops node:$ptr), (v2i64 (memop node:$ptr))>;
 259 def memopv8i16 : PatFrag<(ops node:$ptr), (v8i16 (memop node:$ptr))>;
 260 def memopv16i8 : PatFrag<(ops node:$ptr), (v16i8 (memop node:$ptr))>;
 261
 262 // 256-bit memop pattern fragments
 263 def memopv32i8 : PatFrag<(ops node:$ptr), (v32i8 (memop node:$ptr))>;
 264 def memopv8f32 : PatFrag<(ops node:$ptr), (v8f32 (memop node:$ptr))>;
 265 def memopv4f64 : PatFrag<(ops node:$ptr), (v4f64 (memop node:$ptr))>;
 266 def memopv4i64 : PatFrag<(ops node:$ptr), (v4i64 (memop node:$ptr))>;
 267 def memopv8i32 : PatFrag<(ops node:$ptr), (v8i32 (memop node:$ptr))>;
 268
 269 // SSSE3 uses MMX registers for some instructions. They aren't aligned on a
 270 // 16-byte boundary.
 271 // FIXME: 8 byte alignment for mmx reads is not required
 272 def memop64 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 273   return cast<LoadSDNode>(N)->getAlignment() >= 8;
 274 }]>;
 275
 276 def memopmmx  : PatFrag<(ops node:$ptr), (x86mmx  (memop64 node:$ptr))>;
 277
 278 // MOVNT Support
 279 // Like 'store', but requires the non-temporal bit to be set
 280 def nontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 281                            (st node:$val, node:$ptr), [{
 282   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 283     return ST->isNonTemporal();
 284   return false;
 285 }]>;
 286
 287 def alignednontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 288                                    (st node:$val, node:$ptr), [{
 289   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 290     return ST->isNonTemporal() && !ST->isTruncatingStore() &&
 291            ST->getAddressingMode() == ISD::UNINDEXED &&
 292            ST->getAlignment() >= 16;
 293   return false;
 294 }]>;
 295
 296 def unalignednontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 297                                    (st node:$val, node:$ptr), [{
 298   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 299     return ST->isNonTemporal() &&
 300            ST->getAlignment() < 16;
 301   return false;
 302 }]>;
 303
 304 // 128-bit bitconvert pattern fragments
 305 def bc_v4f32 : PatFrag<(ops node:$in), (v4f32 (bitconvert node:$in))>;
 306 def bc_v2f64 : PatFrag<(ops node:$in), (v2f64 (bitconvert node:$in))>;
 307 def bc_v16i8 : PatFrag<(ops node:$in), (v16i8 (bitconvert node:$in))>;
 308 def bc_v8i16 : PatFrag<(ops node:$in), (v8i16 (bitconvert node:$in))>;
 309 def bc_v4i32 : PatFrag<(ops node:$in), (v4i32 (bitconvert node:$in))>;
 310 def bc_v2i64 : PatFrag<(ops node:$in), (v2i64 (bitconvert node:$in))>;
 311
 312 // 256-bit bitconvert pattern fragments
 313 def bc_v8i32 : PatFrag<(ops node:$in), (v8i32 (bitconvert node:$in))>;
 314 def bc_v4i64 : PatFrag<(ops node:$in), (v4i64 (bitconvert node:$in))>;
 315
 316 def vzmovl_v2i64 : PatFrag<(ops node:$src),
 317                            (bitconvert (v2i64 (X86vzmovl
 318                              (v2i64 (scalar_to_vector (loadi64 node:$src))))))>;
 319 def vzmovl_v4i32 : PatFrag<(ops node:$src),
 320                            (bitconvert (v4i32 (X86vzmovl
 321                              (v4i32 (scalar_to_vector (loadi32 node:$src))))))>;
 322
 323 def vzload_v2i64 : PatFrag<(ops node:$src),
 324                            (bitconvert (v2i64 (X86vzload node:$src)))>;
 325
 326
 327 def fp32imm0 : PatLeaf<(f32 fpimm), [{
 328   return N->isExactlyValue(+0.0);
 329 }]>;
 330
 331 // BYTE_imm - Transform bit immediates into byte immediates.
 332 def BYTE_imm  : SDNodeXForm<imm, [{
 333   // Transformation function: imm >> 3
 334   return getI32Imm(N->getZExtValue() >> 3);
 335 }]>;
 336
 337 // SHUFFLE_get_shuf_imm xform function: convert vector_shuffle mask to PSHUF*,
 338 // SHUFP* etc. imm.
 339 def SHUFFLE_get_shuf_imm : SDNodeXForm<vector_shuffle, [{
 340   return getI8Imm(X86::getShuffleSHUFImmediate(N));
 341 }]>;
 342
 343 // SHUFFLE_get_pshufhw_imm xform function: convert vector_shuffle mask to
 344 // PSHUFHW imm.
 345 def SHUFFLE_get_pshufhw_imm : SDNodeXForm<vector_shuffle, [{
 346   return getI8Imm(X86::getShufflePSHUFHWImmediate(N));
 347 }]>;
 348
 349 // SHUFFLE_get_pshuflw_imm xform function: convert vector_shuffle mask to
 350 // PSHUFLW imm.
 351 def SHUFFLE_get_pshuflw_imm : SDNodeXForm<vector_shuffle, [{
 352   return getI8Imm(X86::getShufflePSHUFLWImmediate(N));
 353 }]>;
 354
 355 // SHUFFLE_get_palign_imm xform function: convert vector_shuffle mask to
 356 // a PALIGNR imm.
 357 def SHUFFLE_get_palign_imm : SDNodeXForm<vector_shuffle, [{
 358   return getI8Imm(X86::getShufflePALIGNRImmediate(N));
 359 }]>;
 360
 361 // EXTRACT_get_vextractf128_imm xform function: convert extract_subvector index
 362 // to VEXTRACTF128 imm.
 363 def EXTRACT_get_vextractf128_imm : SDNodeXForm<extract_subvector, [{
 364   return getI8Imm(X86::getExtractVEXTRACTF128Immediate(N));
 365 }]>;
 366
 367 // INSERT_get_vinsertf128_imm xform function: convert insert_subvector index to
 368 // VINSERTF128 imm.
 369 def INSERT_get_vinsertf128_imm : SDNodeXForm<insert_subvector, [{
 370   return getI8Imm(X86::getInsertVINSERTF128Immediate(N));
 371 }]>;
 372
 373 def splat_lo : PatFrag<(ops node:$lhs, node:$rhs),
 374                        (vector_shuffle node:$lhs, node:$rhs), [{
 375   ShuffleVectorSDNode *SVOp = cast<ShuffleVectorSDNode>(N);
 376   return SVOp->isSplat() && SVOp->getSplatIndex() == 0;
 377 }]>;
 378
 379 def movddup : PatFrag<(ops node:$lhs, node:$rhs),
 380                       (vector_shuffle node:$lhs, node:$rhs), [{
 381   return X86::isMOVDDUPMask(cast<ShuffleVectorSDNode>(N));
 382 }]>;
 383
 384 def movhlps : PatFrag<(ops node:$lhs, node:$rhs),
 385                       (vector_shuffle node:$lhs, node:$rhs), [{
 386   return X86::isMOVHLPSMask(cast<ShuffleVectorSDNode>(N));
 387 }]>;
 388
 389 def movhlps_undef : PatFrag<(ops node:$lhs, node:$rhs),
 390                             (vector_shuffle node:$lhs, node:$rhs), [{
 391   return X86::isMOVHLPS_v_undef_Mask(cast<ShuffleVectorSDNode>(N));
 392 }]>;
 393
 394 def movlhps : PatFrag<(ops node:$lhs, node:$rhs),
 395                       (vector_shuffle node:$lhs, node:$rhs), [{
 396   return X86::isMOVLHPSMask(cast<ShuffleVectorSDNode>(N));
 397 }]>;
 398
 399 def movlp : PatFrag<(ops node:$lhs, node:$rhs),
 400                     (vector_shuffle node:$lhs, node:$rhs), [{
 401   return X86::isMOVLPMask(cast<ShuffleVectorSDNode>(N));
 402 }]>;
 403
 404 def movl : PatFrag<(ops node:$lhs, node:$rhs),
 405                    (vector_shuffle node:$lhs, node:$rhs), [{
 406   return X86::isMOVLMask(cast<ShuffleVectorSDNode>(N));
 407 }]>;
 408
 409 def unpckl : PatFrag<(ops node:$lhs, node:$rhs),
 410                      (vector_shuffle node:$lhs, node:$rhs), [{
 411   return X86::isUNPCKLMask(cast<ShuffleVectorSDNode>(N));
 412 }]>;
 413
 414 def unpckh : PatFrag<(ops node:$lhs, node:$rhs),
 415                      (vector_shuffle node:$lhs, node:$rhs), [{
 416   return X86::isUNPCKHMask(cast<ShuffleVectorSDNode>(N));
 417 }]>;
 418
 419 def pshufd : PatFrag<(ops node:$lhs, node:$rhs),
 420                      (vector_shuffle node:$lhs, node:$rhs), [{
 421   return X86::isPSHUFDMask(cast<ShuffleVectorSDNode>(N));
 422 }], SHUFFLE_get_shuf_imm>;
 423
 424 def shufp : PatFrag<(ops node:$lhs, node:$rhs),
 425                     (vector_shuffle node:$lhs, node:$rhs), [{
 426   return X86::isSHUFPMask(cast<ShuffleVectorSDNode>(N));
 427 }], SHUFFLE_get_shuf_imm>;
 428
 429 def pshufhw : PatFrag<(ops node:$lhs, node:$rhs),
 430                       (vector_shuffle node:$lhs, node:$rhs), [{
 431   return X86::isPSHUFHWMask(cast<ShuffleVectorSDNode>(N));
 432 }], SHUFFLE_get_pshufhw_imm>;
 433
 434 def pshuflw : PatFrag<(ops node:$lhs, node:$rhs),
 435                       (vector_shuffle node:$lhs, node:$rhs), [{
 436   return X86::isPSHUFLWMask(cast<ShuffleVectorSDNode>(N));
 437 }], SHUFFLE_get_pshuflw_imm>;
 438
 439 def palign : PatFrag<(ops node:$lhs, node:$rhs),
 440                      (vector_shuffle node:$lhs, node:$rhs), [{
 441   return X86::isPALIGNRMask(cast<ShuffleVectorSDNode>(N));
 442 }], SHUFFLE_get_palign_imm>;
 443
 444 def vextractf128_extract : PatFrag<(ops node:$bigvec, node:$index),
 445                                    (extract_subvector node:$bigvec,
 446                                                       node:$index), [{
 447   return X86::isVEXTRACTF128Index(N);
 448 }], EXTRACT_get_vextractf128_imm>;
 449
 450 def vinsertf128_insert : PatFrag<(ops node:$bigvec, node:$smallvec,
 451                                       node:$index),
 452                                  (insert_subvector node:$bigvec, node:$smallvec,
 453                                                    node:$index), [{
 454   return X86::isVINSERTF128Index(N);
 455 }], INSERT_get_vinsertf128_imm>;
 456