lib/Target/X86/X86InstrFragmentsSIMD.td

   1 //===-- X86InstrFragmentsSIMD.td - x86 SIMD ISA ------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file provides pattern fragments useful for SIMD instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // MMX Pattern Fragments
  16 //===----------------------------------------------------------------------===//
  17
  18 def load_mmx : PatFrag<(ops node:$ptr), (x86mmx (load node:$ptr))>;
  19 def bc_mmx  : PatFrag<(ops node:$in), (x86mmx  (bitconvert node:$in))>;
  20
  21 //===----------------------------------------------------------------------===//
  22 // SSE specific DAG Nodes.
  23 //===----------------------------------------------------------------------===//
  24
  25 def SDTX86FPShiftOp : SDTypeProfile<1, 2, [ SDTCisSameAs<0, 1>,
  26                                             SDTCisFP<0>, SDTCisInt<2> ]>;
  27 def SDTX86VFCMP : SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<1, 2>,
  28                                        SDTCisFP<1>, SDTCisVT<3, i8>,
  29                                        SDTCisVec<1>]>;
  30
  31 def X86umin    : SDNode<"X86ISD::UMIN",      SDTIntBinOp>;
  32 def X86umax    : SDNode<"X86ISD::UMAX",      SDTIntBinOp>;
  33 def X86smin    : SDNode<"X86ISD::SMIN",      SDTIntBinOp>;
  34 def X86smax    : SDNode<"X86ISD::SMAX",      SDTIntBinOp>;
  35
  36 def X86fmin    : SDNode<"X86ISD::FMIN",      SDTFPBinOp>;
  37 def X86fmax    : SDNode<"X86ISD::FMAX",      SDTFPBinOp>;
  38
  39 // Commutative and Associative FMIN and FMAX.
  40 def X86fminc    : SDNode<"X86ISD::FMINC", SDTFPBinOp,
  41     [SDNPCommutative, SDNPAssociative]>;
  42 def X86fmaxc    : SDNode<"X86ISD::FMAXC", SDTFPBinOp,
  43     [SDNPCommutative, SDNPAssociative]>;
  44
  45 def X86fand    : SDNode<"X86ISD::FAND",      SDTFPBinOp,
  46                         [SDNPCommutative, SDNPAssociative]>;
  47 def X86for     : SDNode<"X86ISD::FOR",       SDTFPBinOp,
  48                         [SDNPCommutative, SDNPAssociative]>;
  49 def X86fxor    : SDNode<"X86ISD::FXOR",      SDTFPBinOp,
  50                         [SDNPCommutative, SDNPAssociative]>;
  51 def X86fandn   : SDNode<"X86ISD::FANDN",     SDTFPBinOp,
  52                         [SDNPCommutative, SDNPAssociative]>;
  53 def X86frsqrt  : SDNode<"X86ISD::FRSQRT",    SDTFPUnaryOp>;
  54 def X86frcp    : SDNode<"X86ISD::FRCP",      SDTFPUnaryOp>;
  55 def X86fsrl    : SDNode<"X86ISD::FSRL",      SDTX86FPShiftOp>;
  56 def X86fgetsign: SDNode<"X86ISD::FGETSIGNx86",SDTFPToIntOp>;
  57 def X86fhadd   : SDNode<"X86ISD::FHADD",     SDTFPBinOp>;
  58 def X86fhsub   : SDNode<"X86ISD::FHSUB",     SDTFPBinOp>;
  59 def X86hadd    : SDNode<"X86ISD::HADD",      SDTIntBinOp>;
  60 def X86hsub    : SDNode<"X86ISD::HSUB",      SDTIntBinOp>;
  61 def X86comi    : SDNode<"X86ISD::COMI",      SDTX86CmpTest>;
  62 def X86ucomi   : SDNode<"X86ISD::UCOMI",     SDTX86CmpTest>;
  63 def X86cmps    : SDNode<"X86ISD::FSETCC",     SDTX86Cmps>;
  64 //def X86cmpsd   : SDNode<"X86ISD::FSETCCsd",    SDTX86Cmpsd>;
  65 def X86pshufb  : SDNode<"X86ISD::PSHUFB",
  66                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  67                                       SDTCisSameAs<0,2>]>>;
  68 def X86andnp   : SDNode<"X86ISD::ANDNP",
  69                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  70                                       SDTCisSameAs<0,2>]>>;
  71 def X86psign   : SDNode<"X86ISD::PSIGN",
  72                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  73                                       SDTCisSameAs<0,2>]>>;
  74 def X86pextrb  : SDNode<"X86ISD::PEXTRB",
  75                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  76 def X86pextrw  : SDNode<"X86ISD::PEXTRW",
  77                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  78 def X86pinsrb  : SDNode<"X86ISD::PINSRB",
  79                  SDTypeProfile<1, 3, [SDTCisVT<0, v16i8>, SDTCisSameAs<0,1>,
  80                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
  81 def X86pinsrw  : SDNode<"X86ISD::PINSRW",
  82                  SDTypeProfile<1, 3, [SDTCisVT<0, v8i16>, SDTCisSameAs<0,1>,
  83                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
  84 def X86insrtps : SDNode<"X86ISD::INSERTPS",
  85                  SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisSameAs<0,1>,
  86                                       SDTCisVT<2, v4f32>, SDTCisPtrTy<3>]>>;
  87 def X86vzmovl  : SDNode<"X86ISD::VZEXT_MOVL",
  88                  SDTypeProfile<1, 1, [SDTCisSameAs<0,1>]>>;
  89
  90 def X86vzmovly  : SDNode<"X86ISD::VZEXT_MOVL",
  91                  SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
  92                                       SDTCisInt<0>, SDTCisInt<1>,
  93                                       SDTCisOpSmallerThanOp<1, 0> ]>>;
  94
  95 def X86vsmovl  : SDNode<"X86ISD::VSEXT_MOVL",
  96                  SDTypeProfile<1, 1,
  97                  [SDTCisVec<0>, SDTCisVec<1>, SDTCisInt<0>, SDTCisInt<1>,
  98                   SDTCisOpSmallerThanOp<1, 0>]>>;
  99
 100 def X86vzload  : SDNode<"X86ISD::VZEXT_LOAD", SDTLoad,
 101                         [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 102
 103 def X86vzext   : SDNode<"X86ISD::VZEXT",
 104                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 105                                               SDTCisInt<0>, SDTCisInt<1>,
 106                                               SDTCisOpSmallerThanOp<1, 0>]>>;
 107
 108 def X86vsext   : SDNode<"X86ISD::VSEXT",
 109                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 110                                               SDTCisInt<0>, SDTCisInt<1>,
 111                                               SDTCisOpSmallerThanOp<1, 0>]>>;
 112
 113 def X86vtrunc   : SDNode<"X86ISD::VTRUNC",
 114                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 115                                               SDTCisInt<0>, SDTCisInt<1>,
 116                                               SDTCisOpSmallerThanOp<0, 1>]>>;
 117 def X86trunc    : SDNode<"X86ISD::TRUNC",
 118                          SDTypeProfile<1, 1, [SDTCisInt<0>, SDTCisInt<1>,
 119                                               SDTCisOpSmallerThanOp<0, 1>]>>;
 120
 121 def X86vtruncm   : SDNode<"X86ISD::VTRUNCM",
 122                          SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 123                                               SDTCisInt<0>, SDTCisInt<1>,
 124                                               SDTCisVec<2>, SDTCisInt<2>,
 125                                               SDTCisOpSmallerThanOp<0, 2>]>>;
 126 def X86vfpext  : SDNode<"X86ISD::VFPEXT",
 127                         SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 128                                              SDTCisFP<0>, SDTCisFP<1>,
 129                                              SDTCisOpSmallerThanOp<1, 0>]>>;
 130 def X86vfpround: SDNode<"X86ISD::VFPROUND",
 131                         SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 132                                              SDTCisFP<0>, SDTCisFP<1>,
 133                                              SDTCisOpSmallerThanOp<0, 1>]>>;
 134
 135 def X86vshldq  : SDNode<"X86ISD::VSHLDQ",    SDTIntShiftOp>;
 136 def X86vshrdq  : SDNode<"X86ISD::VSRLDQ",    SDTIntShiftOp>;
 137 def X86cmpp    : SDNode<"X86ISD::CMPP",      SDTX86VFCMP>;
 138 def X86pcmpeq  : SDNode<"X86ISD::PCMPEQ", SDTIntBinOp, [SDNPCommutative]>;
 139 def X86pcmpgt  : SDNode<"X86ISD::PCMPGT", SDTIntBinOp>;
 140
 141 def X86IntCmpMask : SDTypeProfile<1, 2,
 142     [SDTCisVec<0>, SDTCisSameAs<1, 2>, SDTCisInt<1>]>;
 143 def X86pcmpeqm  : SDNode<"X86ISD::PCMPEQM", X86IntCmpMask, [SDNPCommutative]>;
 144 def X86pcmpgtm  : SDNode<"X86ISD::PCMPGTM", X86IntCmpMask>;
 145
 146 def X86CmpMaskCC :
 147       SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisInt<0>, SDTCisVec<1>,
 148                            SDTCisSameAs<1, 2>, SDTCisVT<3, i8>]>;
 149 def X86CmpMaskCCScalar :
 150       SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, i8>]>;
 151
 152 def X86cmpm   : SDNode<"X86ISD::CMPM",    X86CmpMaskCC>;
 153 def X86cmpmu  : SDNode<"X86ISD::CMPMU",   X86CmpMaskCC>;
 154 def X86cmpms  : SDNode<"X86ISD::FSETCC",  X86CmpMaskCCScalar>;
 155
 156 def X86vshl    : SDNode<"X86ISD::VSHL",
 157                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 158                                       SDTCisVec<2>]>>;
 159 def X86vsrl    : SDNode<"X86ISD::VSRL",
 160                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 161                                       SDTCisVec<2>]>>;
 162 def X86vsra    : SDNode<"X86ISD::VSRA",
 163                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 164                                       SDTCisVec<2>]>>;
 165
 166 def X86vshli   : SDNode<"X86ISD::VSHLI", SDTIntShiftOp>;
 167 def X86vsrli   : SDNode<"X86ISD::VSRLI", SDTIntShiftOp>;
 168 def X86vsrai   : SDNode<"X86ISD::VSRAI", SDTIntShiftOp>;
 169
 170 def SDTX86CmpPTest : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
 171                                           SDTCisVec<1>,
 172                                           SDTCisSameAs<2, 1>]>;
 173 def X86subus   : SDNode<"X86ISD::SUBUS", SDTIntBinOp>;
 174 def X86ptest   : SDNode<"X86ISD::PTEST", SDTX86CmpPTest>;
 175 def X86testp   : SDNode<"X86ISD::TESTP", SDTX86CmpPTest>;
 176 def X86kortest : SDNode<"X86ISD::KORTEST", SDTX86CmpPTest>;
 177 def X86testm   : SDNode<"X86ISD::TESTM", SDTypeProfile<1, 2, [SDTCisVec<0>,
 178                                           SDTCisVec<1>,
 179                                           SDTCisSameAs<2, 1>]>>;
 180 def X86select  : SDNode<"X86ISD::SELECT"     , SDTSelect>;
 181
 182 def X86pmuludq : SDNode<"X86ISD::PMULUDQ",
 183                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 184                                       SDTCisSameAs<1,2>]>>;
 185
 186 // Specific shuffle nodes - At some point ISD::VECTOR_SHUFFLE will always get
 187 // translated into one of the target nodes below during lowering.
 188 // Note: this is a work in progress...
 189 def SDTShuff1Op : SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisSameAs<0,1>]>;
 190 def SDTShuff2Op : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 191                                 SDTCisSameAs<0,2>]>;
 192 def SDTShuff3Op : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 193                                 SDTCisSameAs<0,2>, SDTCisSameAs<0,3>]>;
 194
 195 def SDTShuff2OpI : SDTypeProfile<1, 2, [SDTCisVec<0>,
 196                                  SDTCisSameAs<0,1>, SDTCisInt<2>]>;
 197 def SDTShuff3OpI : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 198                                  SDTCisSameAs<0,2>, SDTCisInt<3>]>;
 199
 200 def SDTVBroadcast  : SDTypeProfile<1, 1, [SDTCisVec<0>]>;
 201 def SDTVBroadcastm : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>]>;
 202
 203 def SDTBlend : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 204                              SDTCisSameAs<1,2>, SDTCisVT<3, i32>]>;
 205
 206 def SDTFma : SDTypeProfile<1, 3, [SDTCisSameAs<0,1>,
 207                            SDTCisSameAs<1,2>, SDTCisSameAs<1,3>]>;
 208
 209 def X86PAlignr : SDNode<"X86ISD::PALIGNR", SDTShuff3OpI>;
 210
 211 def X86PShufd  : SDNode<"X86ISD::PSHUFD", SDTShuff2OpI>;
 212 def X86PShufhw : SDNode<"X86ISD::PSHUFHW", SDTShuff2OpI>;
 213 def X86PShuflw : SDNode<"X86ISD::PSHUFLW", SDTShuff2OpI>;
 214
 215 def X86Shufp : SDNode<"X86ISD::SHUFP", SDTShuff3OpI>;
 216
 217 def X86Movddup  : SDNode<"X86ISD::MOVDDUP", SDTShuff1Op>;
 218 def X86Movshdup : SDNode<"X86ISD::MOVSHDUP", SDTShuff1Op>;
 219 def X86Movsldup : SDNode<"X86ISD::MOVSLDUP", SDTShuff1Op>;
 220
 221 def X86Movsd : SDNode<"X86ISD::MOVSD", SDTShuff2Op>;
 222 def X86Movss : SDNode<"X86ISD::MOVSS", SDTShuff2Op>;
 223
 224 def X86Movlhps : SDNode<"X86ISD::MOVLHPS", SDTShuff2Op>;
 225 def X86Movlhpd : SDNode<"X86ISD::MOVLHPD", SDTShuff2Op>;
 226 def X86Movhlps : SDNode<"X86ISD::MOVHLPS", SDTShuff2Op>;
 227
 228 def X86Movlps : SDNode<"X86ISD::MOVLPS", SDTShuff2Op>;
 229 def X86Movlpd : SDNode<"X86ISD::MOVLPD", SDTShuff2Op>;
 230
 231 def X86Unpckl : SDNode<"X86ISD::UNPCKL", SDTShuff2Op>;
 232 def X86Unpckh : SDNode<"X86ISD::UNPCKH", SDTShuff2Op>;
 233
 234 def X86VPermilp  : SDNode<"X86ISD::VPERMILP", SDTShuff2OpI>;
 235 def X86VPermv    : SDNode<"X86ISD::VPERMV",   SDTShuff2Op>;
 236 def X86VPermi    : SDNode<"X86ISD::VPERMI",   SDTShuff2OpI>;
 237 def X86VPermv3   : SDNode<"X86ISD::VPERMV3",  SDTShuff3Op>;
 238 def X86VPermiv3   : SDNode<"X86ISD::VPERMIV3",  SDTShuff3Op>;
 239
 240 def X86VPerm2x128 : SDNode<"X86ISD::VPERM2X128", SDTShuff3OpI>;
 241
 242 def X86VBroadcast : SDNode<"X86ISD::VBROADCAST", SDTVBroadcast>;
 243 def X86VBroadcastm : SDNode<"X86ISD::VBROADCASTM", SDTVBroadcastm>;
 244 def X86Vinsert   : SDNode<"X86ISD::VINSERT",  SDTypeProfile<1, 3,
 245                               [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 246
 247 def X86Blendi    : SDNode<"X86ISD::BLENDI",   SDTBlend>;
 248 def X86Fmadd     : SDNode<"X86ISD::FMADD",     SDTFma>;
 249 def X86Fnmadd    : SDNode<"X86ISD::FNMADD",    SDTFma>;
 250 def X86Fmsub     : SDNode<"X86ISD::FMSUB",     SDTFma>;
 251 def X86Fnmsub    : SDNode<"X86ISD::FNMSUB",    SDTFma>;
 252 def X86Fmaddsub  : SDNode<"X86ISD::FMADDSUB",  SDTFma>;
 253 def X86Fmsubadd  : SDNode<"X86ISD::FMSUBADD",  SDTFma>;
 254
 255 def SDT_PCMPISTRI : SDTypeProfile<2, 3, [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
 256                                          SDTCisVT<2, v16i8>, SDTCisVT<3, v16i8>,
 257                                          SDTCisVT<4, i8>]>;
 258 def SDT_PCMPESTRI : SDTypeProfile<2, 5, [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
 259                                          SDTCisVT<2, v16i8>, SDTCisVT<3, i32>,
 260                                          SDTCisVT<4, v16i8>, SDTCisVT<5, i32>,
 261                                          SDTCisVT<6, i8>]>;
 262
 263 def X86pcmpistri : SDNode<"X86ISD::PCMPISTRI", SDT_PCMPISTRI>;
 264 def X86pcmpestri : SDNode<"X86ISD::PCMPESTRI", SDT_PCMPESTRI>;
 265
 266 //===----------------------------------------------------------------------===//
 267 // SSE Complex Patterns
 268 //===----------------------------------------------------------------------===//
 269
 270 // These are 'extloads' from a scalar to the low element of a vector, zeroing
 271 // the top elements.  These are used for the SSE 'ss' and 'sd' instruction
 272 // forms.
 273 def sse_load_f32 : ComplexPattern<v4f32, 5, "SelectScalarSSELoad", [],
 274                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 275                                    SDNPWantRoot]>;
 276 def sse_load_f64 : ComplexPattern<v2f64, 5, "SelectScalarSSELoad", [],
 277                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 278                                    SDNPWantRoot]>;
 279
 280 def ssmem : Operand<v4f32> {
 281   let PrintMethod = "printf32mem";
 282   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 283   let ParserMatchClass = X86Mem32AsmOperand;
 284   let OperandType = "OPERAND_MEMORY";
 285 }
 286 def sdmem : Operand<v2f64> {
 287   let PrintMethod = "printf64mem";
 288   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 289   let ParserMatchClass = X86Mem64AsmOperand;
 290   let OperandType = "OPERAND_MEMORY";
 291 }
 292
 293 //===----------------------------------------------------------------------===//
 294 // SSE pattern fragments
 295 //===----------------------------------------------------------------------===//
 296
 297 // 128-bit load pattern fragments
 298 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 299 def loadv4f32    : PatFrag<(ops node:$ptr), (v4f32 (load node:$ptr))>;
 300 def loadv2f64    : PatFrag<(ops node:$ptr), (v2f64 (load node:$ptr))>;
 301 def loadv2i64    : PatFrag<(ops node:$ptr), (v2i64 (load node:$ptr))>;
 302
 303 // 256-bit load pattern fragments
 304 // NOTE: all 256-bit integer vector loads are promoted to v4i64
 305 def loadv8f32    : PatFrag<(ops node:$ptr), (v8f32 (load node:$ptr))>;
 306 def loadv4f64    : PatFrag<(ops node:$ptr), (v4f64 (load node:$ptr))>;
 307 def loadv4i64    : PatFrag<(ops node:$ptr), (v4i64 (load node:$ptr))>;
 308
 309 // 512-bit load pattern fragments
 310 def loadv16f32   : PatFrag<(ops node:$ptr), (v16f32 (load node:$ptr))>;
 311 def loadv8f64    : PatFrag<(ops node:$ptr), (v8f64 (load node:$ptr))>;
 312 def loadv16i32   : PatFrag<(ops node:$ptr), (v16i32 (load node:$ptr))>;
 313 def loadv8i64    : PatFrag<(ops node:$ptr), (v8i64 (load node:$ptr))>;
 314
 315 // 128-/256-/512-bit extload pattern fragments
 316 def extloadv2f32 : PatFrag<(ops node:$ptr), (v2f64 (extloadvf32 node:$ptr))>;
 317 def extloadv4f32 : PatFrag<(ops node:$ptr), (v4f64 (extloadvf32 node:$ptr))>;
 318 def extloadv8f32 : PatFrag<(ops node:$ptr), (v8f64 (extloadvf32 node:$ptr))>;
 319
 320 // Like 'store', but always requires 128-bit vector alignment.
 321 def alignedstore : PatFrag<(ops node:$val, node:$ptr),
 322                            (store node:$val, node:$ptr), [{
 323   return cast<StoreSDNode>(N)->getAlignment() >= 16;
 324 }]>;
 325
 326 // Like 'store', but always requires 256-bit vector alignment.
 327 def alignedstore256 : PatFrag<(ops node:$val, node:$ptr),
 328                               (store node:$val, node:$ptr), [{
 329   return cast<StoreSDNode>(N)->getAlignment() >= 32;
 330 }]>;
 331
 332 // Like 'store', but always requires 512-bit vector alignment.
 333 def alignedstore512 : PatFrag<(ops node:$val, node:$ptr),
 334                               (store node:$val, node:$ptr), [{
 335   return cast<StoreSDNode>(N)->getAlignment() >= 64;
 336 }]>;
 337
 338 // Like 'load', but always requires 128-bit vector alignment.
 339 def alignedload : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 340   return cast<LoadSDNode>(N)->getAlignment() >= 16;
 341 }]>;
 342
 343 // Like 'X86vzload', but always requires 128-bit vector alignment.
 344 def alignedX86vzload : PatFrag<(ops node:$ptr), (X86vzload node:$ptr), [{
 345   return cast<MemSDNode>(N)->getAlignment() >= 16;
 346 }]>;
 347
 348 // Like 'load', but always requires 256-bit vector alignment.
 349 def alignedload256 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 350   return cast<LoadSDNode>(N)->getAlignment() >= 32;
 351 }]>;
 352
 353 // Like 'load', but always requires 512-bit vector alignment.
 354 def alignedload512 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 355   return cast<LoadSDNode>(N)->getAlignment() >= 64;
 356 }]>;
 357
 358 def alignedloadfsf32 : PatFrag<(ops node:$ptr),
 359                                (f32 (alignedload node:$ptr))>;
 360 def alignedloadfsf64 : PatFrag<(ops node:$ptr),
 361                                (f64 (alignedload node:$ptr))>;
 362
 363 // 128-bit aligned load pattern fragments
 364 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 365 def alignedloadv4f32 : PatFrag<(ops node:$ptr),
 366                                (v4f32 (alignedload node:$ptr))>;
 367 def alignedloadv2f64 : PatFrag<(ops node:$ptr),
 368                                (v2f64 (alignedload node:$ptr))>;
 369 def alignedloadv2i64 : PatFrag<(ops node:$ptr),
 370                                (v2i64 (alignedload node:$ptr))>;
 371
 372 // 256-bit aligned load pattern fragments
 373 // NOTE: all 256-bit integer vector loads are promoted to v4i64
 374 def alignedloadv8f32 : PatFrag<(ops node:$ptr),
 375                                (v8f32 (alignedload256 node:$ptr))>;
 376 def alignedloadv4f64 : PatFrag<(ops node:$ptr),
 377                                (v4f64 (alignedload256 node:$ptr))>;
 378 def alignedloadv4i64 : PatFrag<(ops node:$ptr),
 379                                (v4i64 (alignedload256 node:$ptr))>;
 380
 381 // 512-bit aligned load pattern fragments
 382 def alignedloadv16f32 : PatFrag<(ops node:$ptr),
 383                                 (v16f32 (alignedload512 node:$ptr))>;
 384 def alignedloadv16i32 : PatFrag<(ops node:$ptr),
 385                                 (v16i32 (alignedload512 node:$ptr))>;
 386 def alignedloadv8f64  : PatFrag<(ops node:$ptr),
 387                                 (v8f64  (alignedload512 node:$ptr))>;
 388 def alignedloadv8i64  : PatFrag<(ops node:$ptr),
 389                                 (v8i64  (alignedload512 node:$ptr))>;
 390
 391 // Like 'load', but uses special alignment checks suitable for use in
 392 // memory operands in most SSE instructions, which are required to
 393 // be naturally aligned on some targets but not on others.  If the subtarget
 394 // allows unaligned accesses, match any load, though this may require
 395 // setting a feature bit in the processor (on startup, for example).
 396 // Opteron 10h and later implement such a feature.
 397 def memop : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 398   return    Subtarget->hasVectorUAMem()
 399          || cast<LoadSDNode>(N)->getAlignment() >= 16;
 400 }]>;
 401
 402 def memop4 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 403   return    Subtarget->hasVectorUAMem()
 404          || cast<LoadSDNode>(N)->getAlignment() >= 4;
 405 }]>;
 406
 407 def memop8 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 408   return    Subtarget->hasVectorUAMem()
 409          || cast<LoadSDNode>(N)->getAlignment() >= 8;
 410 }]>;
 411
 412 def memopfsf32 : PatFrag<(ops node:$ptr), (f32   (memop node:$ptr))>;
 413 def memopfsf64 : PatFrag<(ops node:$ptr), (f64   (memop node:$ptr))>;
 414
 415 // 128-bit memop pattern fragments
 416 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 417 def memopv4f32 : PatFrag<(ops node:$ptr), (v4f32 (memop node:$ptr))>;
 418 def memopv2f64 : PatFrag<(ops node:$ptr), (v2f64 (memop node:$ptr))>;
 419 def memopv2i64 : PatFrag<(ops node:$ptr), (v2i64 (memop node:$ptr))>;
 420
 421 // 256-bit memop pattern fragments
 422 // NOTE: all 256-bit integer vector loads are promoted to v4i64
 423 def memopv8f32 : PatFrag<(ops node:$ptr), (v8f32 (memop node:$ptr))>;
 424 def memopv4f64 : PatFrag<(ops node:$ptr), (v4f64 (memop node:$ptr))>;
 425 def memopv4i64 : PatFrag<(ops node:$ptr), (v4i64 (memop node:$ptr))>;
 426
 427 // 512-bit memop pattern fragments
 428 def memopv16f32 : PatFrag<(ops node:$ptr), (v16f32 (memop4 node:$ptr))>;
 429 def memopv8f64  : PatFrag<(ops node:$ptr), (v8f64  (memop8 node:$ptr))>;
 430 def memopv16i32 : PatFrag<(ops node:$ptr), (v16i32 (memop4 node:$ptr))>;
 431 def memopv8i64  : PatFrag<(ops node:$ptr), (v8i64  (memop8 node:$ptr))>;
 432
 433 // SSSE3 uses MMX registers for some instructions. They aren't aligned on a
 434 // 16-byte boundary.
 435 // FIXME: 8 byte alignment for mmx reads is not required
 436 def memop64 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 437   return cast<LoadSDNode>(N)->getAlignment() >= 8;
 438 }]>;
 439
 440 def memopmmx  : PatFrag<(ops node:$ptr), (x86mmx  (memop64 node:$ptr))>;
 441
 442 // MOVNT Support
 443 // Like 'store', but requires the non-temporal bit to be set
 444 def nontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 445                            (st node:$val, node:$ptr), [{
 446   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 447     return ST->isNonTemporal();
 448   return false;
 449 }]>;
 450
 451 def alignednontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 452                                     (st node:$val, node:$ptr), [{
 453   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 454     return ST->isNonTemporal() && !ST->isTruncatingStore() &&
 455            ST->getAddressingMode() == ISD::UNINDEXED &&
 456            ST->getAlignment() >= 16;
 457   return false;
 458 }]>;
 459
 460 def unalignednontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 461                                       (st node:$val, node:$ptr), [{
 462   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 463     return ST->isNonTemporal() &&
 464            ST->getAlignment() < 16;
 465   return false;
 466 }]>;
 467
 468 // 128-bit bitconvert pattern fragments
 469 def bc_v4f32 : PatFrag<(ops node:$in), (v4f32 (bitconvert node:$in))>;
 470 def bc_v2f64 : PatFrag<(ops node:$in), (v2f64 (bitconvert node:$in))>;
 471 def bc_v16i8 : PatFrag<(ops node:$in), (v16i8 (bitconvert node:$in))>;
 472 def bc_v8i16 : PatFrag<(ops node:$in), (v8i16 (bitconvert node:$in))>;
 473 def bc_v4i32 : PatFrag<(ops node:$in), (v4i32 (bitconvert node:$in))>;
 474 def bc_v2i64 : PatFrag<(ops node:$in), (v2i64 (bitconvert node:$in))>;
 475
 476 // 256-bit bitconvert pattern fragments
 477 def bc_v32i8 : PatFrag<(ops node:$in), (v32i8 (bitconvert node:$in))>;
 478 def bc_v16i16 : PatFrag<(ops node:$in), (v16i16 (bitconvert node:$in))>;
 479 def bc_v8i32 : PatFrag<(ops node:$in), (v8i32 (bitconvert node:$in))>;
 480 def bc_v4i64 : PatFrag<(ops node:$in), (v4i64 (bitconvert node:$in))>;
 481 def bc_v8f32 : PatFrag<(ops node:$in), (v8f32 (bitconvert node:$in))>;
 482
 483 // 512-bit bitconvert pattern fragments
 484 def bc_v16i32 : PatFrag<(ops node:$in), (v16i32 (bitconvert node:$in))>;
 485 def bc_v8i64 : PatFrag<(ops node:$in), (v8i64 (bitconvert node:$in))>;
 486 def bc_v8f64 : PatFrag<(ops node:$in), (v8f64 (bitconvert node:$in))>;
 487 def bc_v16f32 : PatFrag<(ops node:$in), (v16f32 (bitconvert node:$in))>;
 488
 489 def vzmovl_v2i64 : PatFrag<(ops node:$src),
 490                            (bitconvert (v2i64 (X86vzmovl
 491                              (v2i64 (scalar_to_vector (loadi64 node:$src))))))>;
 492 def vzmovl_v4i32 : PatFrag<(ops node:$src),
 493                            (bitconvert (v4i32 (X86vzmovl
 494                              (v4i32 (scalar_to_vector (loadi32 node:$src))))))>;
 495
 496 def vzload_v2i64 : PatFrag<(ops node:$src),
 497                            (bitconvert (v2i64 (X86vzload node:$src)))>;
 498
 499
 500 def fp32imm0 : PatLeaf<(f32 fpimm), [{
 501   return N->isExactlyValue(+0.0);
 502 }]>;
 503
 504 def I8Imm : SDNodeXForm<imm, [{
 505   // Transformation function: get the low 8 bits.
 506   return getI8Imm((uint8_t)N->getZExtValue());
 507 }]>;
 508
 509 def FROUND_NO_EXC : ImmLeaf<i32, [{ return Imm == 8; }]>;
 510 def FROUND_CURRENT : ImmLeaf<i32, [{ return Imm == 4; }]>;
 511
 512 // BYTE_imm - Transform bit immediates into byte immediates.
 513 def BYTE_imm  : SDNodeXForm<imm, [{
 514   // Transformation function: imm >> 3
 515   return getI32Imm(N->getZExtValue() >> 3);
 516 }]>;
 517
 518 // EXTRACT_get_vextract128_imm xform function: convert extract_subvector index
 519 // to VEXTRACTF128/VEXTRACTI128 imm.
 520 def EXTRACT_get_vextract128_imm : SDNodeXForm<extract_subvector, [{
 521   return getI8Imm(X86::getExtractVEXTRACT128Immediate(N));
 522 }]>;
 523
 524 // INSERT_get_vinsert128_imm xform function: convert insert_subvector index to
 525 // VINSERTF128/VINSERTI128 imm.
 526 def INSERT_get_vinsert128_imm : SDNodeXForm<insert_subvector, [{
 527   return getI8Imm(X86::getInsertVINSERT128Immediate(N));
 528 }]>;
 529
 530 // EXTRACT_get_vextract256_imm xform function: convert extract_subvector index
 531 // to VEXTRACTF64x4 imm.
 532 def EXTRACT_get_vextract256_imm : SDNodeXForm<extract_subvector, [{
 533   return getI8Imm(X86::getExtractVEXTRACT256Immediate(N));
 534 }]>;
 535
 536 // INSERT_get_vinsert256_imm xform function: convert insert_subvector index to
 537 // VINSERTF64x4 imm.
 538 def INSERT_get_vinsert256_imm : SDNodeXForm<insert_subvector, [{
 539   return getI8Imm(X86::getInsertVINSERT256Immediate(N));
 540 }]>;
 541
 542 def vextract128_extract : PatFrag<(ops node:$bigvec, node:$index),
 543                                    (extract_subvector node:$bigvec,
 544                                                       node:$index), [{
 545   return X86::isVEXTRACT128Index(N);
 546 }], EXTRACT_get_vextract128_imm>;
 547
 548 def vinsert128_insert : PatFrag<(ops node:$bigvec, node:$smallvec,
 549                                       node:$index),
 550                                  (insert_subvector node:$bigvec, node:$smallvec,
 551                                                    node:$index), [{
 552   return X86::isVINSERT128Index(N);
 553 }], INSERT_get_vinsert128_imm>;
 554
 555
 556 def vextract256_extract : PatFrag<(ops node:$bigvec, node:$index),
 557                                    (extract_subvector node:$bigvec,
 558                                                       node:$index), [{
 559   return X86::isVEXTRACT256Index(N);
 560 }], EXTRACT_get_vextract256_imm>;
 561
 562 def vinsert256_insert : PatFrag<(ops node:$bigvec, node:$smallvec,
 563                                       node:$index),
 564                                  (insert_subvector node:$bigvec, node:$smallvec,
 565                                                    node:$index), [{
 566   return X86::isVINSERT256Index(N);
 567 }], INSERT_get_vinsert256_imm>;
 568