lib/Target/X86/X86InstrFragmentsSIMD.td

   1 //===-- X86InstrFragmentsSIMD.td - x86 SIMD ISA ------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file provides pattern fragments useful for SIMD instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // MMX specific DAG Nodes.
  16 //===----------------------------------------------------------------------===//
  17
  18 // Low word of MMX to GPR.
  19 def MMX_X86movd2w : SDNode<"X86ISD::MMX_MOVD2W", SDTypeProfile<1, 1,
  20                             [SDTCisVT<0, i32>, SDTCisVT<1, x86mmx>]>>;
  21 // GPR to low word of MMX.
  22 def MMX_X86movw2d : SDNode<"X86ISD::MMX_MOVW2D", SDTypeProfile<1, 1,
  23                             [SDTCisVT<0, x86mmx>, SDTCisVT<1, i32>]>>;
  24
  25 //===----------------------------------------------------------------------===//
  26 // MMX Pattern Fragments
  27 //===----------------------------------------------------------------------===//
  28
  29 def load_mmx : PatFrag<(ops node:$ptr), (x86mmx (load node:$ptr))>;
  30 def load_mvmmx : PatFrag<(ops node:$ptr),
  31                          (x86mmx (MMX_X86movw2d (load node:$ptr)))>;
  32 def bc_mmx  : PatFrag<(ops node:$in), (x86mmx  (bitconvert node:$in))>;
  33
  34 //===----------------------------------------------------------------------===//
  35 // SSE specific DAG Nodes.
  36 //===----------------------------------------------------------------------===//
  37
  38 def SDTX86VFCMP : SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<1, 2>,
  39                                        SDTCisFP<1>, SDTCisVT<3, i8>,
  40                                        SDTCisVec<1>]>;
  41
  42 def X86fmin    : SDNode<"X86ISD::FMIN",      SDTFPBinOp>;
  43 def X86fmax    : SDNode<"X86ISD::FMAX",      SDTFPBinOp>;
  44
  45 // Commutative and Associative FMIN and FMAX.
  46 def X86fminc    : SDNode<"X86ISD::FMINC", SDTFPBinOp,
  47     [SDNPCommutative, SDNPAssociative]>;
  48 def X86fmaxc    : SDNode<"X86ISD::FMAXC", SDTFPBinOp,
  49     [SDNPCommutative, SDNPAssociative]>;
  50
  51 def X86fand    : SDNode<"X86ISD::FAND",      SDTFPBinOp,
  52                         [SDNPCommutative, SDNPAssociative]>;
  53 def X86for     : SDNode<"X86ISD::FOR",       SDTFPBinOp,
  54                         [SDNPCommutative, SDNPAssociative]>;
  55 def X86fxor    : SDNode<"X86ISD::FXOR",      SDTFPBinOp,
  56                         [SDNPCommutative, SDNPAssociative]>;
  57 def X86fandn   : SDNode<"X86ISD::FANDN",     SDTFPBinOp,
  58                         [SDNPCommutative, SDNPAssociative]>;
  59 def X86frsqrt  : SDNode<"X86ISD::FRSQRT",    SDTFPUnaryOp>;
  60 def X86frcp    : SDNode<"X86ISD::FRCP",      SDTFPUnaryOp>;
  61 def X86fgetsign: SDNode<"X86ISD::FGETSIGNx86",SDTFPToIntOp>;
  62 def X86fhadd   : SDNode<"X86ISD::FHADD",     SDTFPBinOp>;
  63 def X86fhsub   : SDNode<"X86ISD::FHSUB",     SDTFPBinOp>;
  64 def X86hadd    : SDNode<"X86ISD::HADD",      SDTIntBinOp>;
  65 def X86hsub    : SDNode<"X86ISD::HSUB",      SDTIntBinOp>;
  66 def X86comi    : SDNode<"X86ISD::COMI",      SDTX86CmpTest>;
  67 def X86ucomi   : SDNode<"X86ISD::UCOMI",     SDTX86CmpTest>;
  68 def X86cmps    : SDNode<"X86ISD::FSETCC",     SDTX86Cmps>;
  69 //def X86cmpsd   : SDNode<"X86ISD::FSETCCsd",    SDTX86Cmpsd>;
  70 def X86cvtdq2pd: SDNode<"X86ISD::CVTDQ2PD",
  71                  SDTypeProfile<1, 1, [SDTCisVT<0, v2f64>,
  72                                       SDTCisVT<1, v4i32>]>>;
  73 def X86cvtudq2pd: SDNode<"X86ISD::CVTUDQ2PD",
  74                  SDTypeProfile<1, 1, [SDTCisVT<0, v2f64>,
  75                                       SDTCisVT<1, v4i32>]>>;
  76 def X86pshufb  : SDNode<"X86ISD::PSHUFB",
  77                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  78                                       SDTCisSameAs<0,2>]>>;
  79 def X86psadbw  : SDNode<"X86ISD::PSADBW",
  80                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  81                                       SDTCisSameAs<0,2>]>>;
  82 def X86andnp   : SDNode<"X86ISD::ANDNP",
  83                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  84                                       SDTCisSameAs<0,2>]>>;
  85 def X86psign   : SDNode<"X86ISD::PSIGN",
  86                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  87                                       SDTCisSameAs<0,2>]>>;
  88 def X86pextrb  : SDNode<"X86ISD::PEXTRB",
  89                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  90 def X86pextrw  : SDNode<"X86ISD::PEXTRW",
  91                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  92 def X86pinsrb  : SDNode<"X86ISD::PINSRB",
  93                  SDTypeProfile<1, 3, [SDTCisVT<0, v16i8>, SDTCisSameAs<0,1>,
  94                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
  95 def X86pinsrw  : SDNode<"X86ISD::PINSRW",
  96                  SDTypeProfile<1, 3, [SDTCisVT<0, v8i16>, SDTCisSameAs<0,1>,
  97                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
  98 def X86insertps : SDNode<"X86ISD::INSERTPS",
  99                  SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisSameAs<0,1>,
 100                                       SDTCisVT<2, v4f32>, SDTCisVT<3, i8>]>>;
 101 def X86vzmovl  : SDNode<"X86ISD::VZEXT_MOVL",
 102                  SDTypeProfile<1, 1, [SDTCisSameAs<0,1>]>>;
 103
 104 def X86vzload  : SDNode<"X86ISD::VZEXT_LOAD", SDTLoad,
 105                         [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 106
 107 def X86vzext   : SDNode<"X86ISD::VZEXT",
 108                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 109                                               SDTCisInt<0>, SDTCisInt<1>,
 110                                               SDTCisOpSmallerThanOp<1, 0>]>>;
 111
 112 def X86vsext   : SDNode<"X86ISD::VSEXT",
 113                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 114                                               SDTCisInt<0>, SDTCisInt<1>,
 115                                               SDTCisOpSmallerThanOp<1, 0>]>>;
 116
 117 def X86vtrunc   : SDNode<"X86ISD::VTRUNC",
 118                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 119                                               SDTCisInt<0>, SDTCisInt<1>,
 120                                               SDTCisOpSmallerThanOp<0, 1>]>>;
 121 def X86trunc    : SDNode<"X86ISD::TRUNC",
 122                          SDTypeProfile<1, 1, [SDTCisInt<0>, SDTCisInt<1>,
 123                                               SDTCisOpSmallerThanOp<0, 1>]>>;
 124
 125 def X86vtruncm   : SDNode<"X86ISD::VTRUNCM",
 126                          SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 127                                               SDTCisInt<0>, SDTCisInt<1>,
 128                                               SDTCisVec<2>, SDTCisInt<2>,
 129                                               SDTCisOpSmallerThanOp<0, 2>]>>;
 130 def X86vfpext  : SDNode<"X86ISD::VFPEXT",
 131                         SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 132                                              SDTCisFP<0>, SDTCisFP<1>,
 133                                              SDTCisOpSmallerThanOp<1, 0>]>>;
 134 def X86vfpround: SDNode<"X86ISD::VFPROUND",
 135                         SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 136                                              SDTCisFP<0>, SDTCisFP<1>,
 137                                              SDTCisOpSmallerThanOp<0, 1>]>>;
 138
 139 def X86vshldq  : SDNode<"X86ISD::VSHLDQ",    SDTIntShiftOp>;
 140 def X86vshrdq  : SDNode<"X86ISD::VSRLDQ",    SDTIntShiftOp>;
 141 def X86cmpp    : SDNode<"X86ISD::CMPP",      SDTX86VFCMP>;
 142 def X86pcmpeq  : SDNode<"X86ISD::PCMPEQ", SDTIntBinOp, [SDNPCommutative]>;
 143 def X86pcmpgt  : SDNode<"X86ISD::PCMPGT", SDTIntBinOp>;
 144
 145 def X86IntCmpMask : SDTypeProfile<1, 2,
 146     [SDTCisVec<0>, SDTCisSameAs<1, 2>, SDTCisInt<1>]>;
 147 def X86pcmpeqm  : SDNode<"X86ISD::PCMPEQM", X86IntCmpMask, [SDNPCommutative]>;
 148 def X86pcmpgtm  : SDNode<"X86ISD::PCMPGTM", X86IntCmpMask>;
 149
 150 def X86CmpMaskCC :
 151       SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCVecEltisVT<0, i1>,
 152                        SDTCisVec<1>, SDTCisSameAs<2, 1>,
 153                        SDTCisSameNumEltsAs<0, 1>, SDTCisVT<3, i8>]>;
 154 def X86CmpMaskCCRound :
 155       SDTypeProfile<1, 4, [SDTCisVec<0>,SDTCVecEltisVT<0, i1>,
 156                        SDTCisVec<1>, SDTCisSameAs<2, 1>,
 157                        SDTCisSameNumEltsAs<0, 1>, SDTCisVT<3, i8>,
 158                        SDTCisInt<4>]>;
 159 def X86CmpMaskCCScalar :
 160       SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, i8>]>;
 161
 162 def X86cmpm    : SDNode<"X86ISD::CMPM",     X86CmpMaskCC>;
 163 def X86cmpmRnd : SDNode<"X86ISD::CMPM_RND", X86CmpMaskCCRound>;
 164 def X86cmpmu   : SDNode<"X86ISD::CMPMU",    X86CmpMaskCC>;
 165 def X86cmpms   : SDNode<"X86ISD::FSETCC",   X86CmpMaskCCScalar>;
 166
 167 def X86vshl    : SDNode<"X86ISD::VSHL",
 168                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 169                                       SDTCisVec<2>]>>;
 170 def X86vsrl    : SDNode<"X86ISD::VSRL",
 171                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 172                                       SDTCisVec<2>]>>;
 173 def X86vsra    : SDNode<"X86ISD::VSRA",
 174                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 175                                       SDTCisVec<2>]>>;
 176
 177 def X86vshli   : SDNode<"X86ISD::VSHLI", SDTIntShiftOp>;
 178 def X86vsrli   : SDNode<"X86ISD::VSRLI", SDTIntShiftOp>;
 179 def X86vsrai   : SDNode<"X86ISD::VSRAI", SDTIntShiftOp>;
 180
 181 def SDTX86CmpPTest : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
 182                                           SDTCisVec<1>,
 183                                           SDTCisSameAs<2, 1>]>;
 184 def X86addus   : SDNode<"X86ISD::ADDUS", SDTIntBinOp>;
 185 def X86subus   : SDNode<"X86ISD::SUBUS", SDTIntBinOp>;
 186 def X86adds    : SDNode<"X86ISD::ADDS", SDTIntBinOp>;
 187 def X86subs    : SDNode<"X86ISD::SUBS", SDTIntBinOp>;
 188 def X86mulhrs  : SDNode<"X86ISD::MULHRS" , SDTIntBinOp>;
 189 def X86avg     : SDNode<"X86ISD::AVG" , SDTIntBinOp>;
 190 def X86ptest   : SDNode<"X86ISD::PTEST", SDTX86CmpPTest>;
 191 def X86testp   : SDNode<"X86ISD::TESTP", SDTX86CmpPTest>;
 192 def X86kortest : SDNode<"X86ISD::KORTEST", SDTX86CmpPTest>;
 193 def X86testm   : SDNode<"X86ISD::TESTM", SDTypeProfile<1, 2, [SDTCisVec<0>,
 194                                           SDTCisVec<1>, SDTCisSameAs<2, 1>,
 195                                           SDTCVecEltisVT<0, i1>,
 196                                           SDTCisSameNumEltsAs<0, 1>]>>;
 197 def X86testnm  : SDNode<"X86ISD::TESTNM", SDTypeProfile<1, 2, [SDTCisVec<0>,
 198                                           SDTCisVec<1>, SDTCisSameAs<2, 1>,
 199                                           SDTCVecEltisVT<0, i1>,
 200                                           SDTCisSameNumEltsAs<0, 1>]>>;
 201 def X86select  : SDNode<"X86ISD::SELECT"     , SDTSelect>;
 202
 203 def X86pmuludq : SDNode<"X86ISD::PMULUDQ",
 204                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 205                                       SDTCisSameAs<1,2>]>>;
 206 def X86pmuldq  : SDNode<"X86ISD::PMULDQ",
 207                          SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 208                                        SDTCisSameAs<1,2>]>>;
 209
 210 def X86extrqi : SDNode<"X86ISD::EXTRQI",
 211                   SDTypeProfile<1, 3, [SDTCisVT<0, v2i64>, SDTCisSameAs<0,1>,
 212                                        SDTCisVT<2, i8>, SDTCisVT<3, i8>]>>;
 213 def X86insertqi : SDNode<"X86ISD::INSERTQI",
 214                     SDTypeProfile<1, 4, [SDTCisVT<0, v2i64>, SDTCisSameAs<0,1>,
 215                                          SDTCisSameAs<1,2>, SDTCisVT<3, i8>,
 216                                          SDTCisVT<4, i8>]>>;
 217
 218 // Specific shuffle nodes - At some point ISD::VECTOR_SHUFFLE will always get
 219 // translated into one of the target nodes below during lowering.
 220 // Note: this is a work in progress...
 221 def SDTShuff1Op : SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisSameAs<0,1>]>;
 222 def SDTShuff2Op : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 223                                 SDTCisSameAs<0,2>]>;
 224 def SDTShuff3Op : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 225                                 SDTCisSameAs<0,2>, SDTCisSameAs<0,3>]>;
 226
 227 def SDTShuff2OpM : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 228                                         SDTCisVec<2>]>;
 229 def SDTShuff2OpI : SDTypeProfile<1, 2, [SDTCisVec<0>,
 230                                  SDTCisSameAs<0,1>, SDTCisInt<2>]>;
 231 def SDTShuff3OpI : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 232                                  SDTCisSameAs<0,2>, SDTCisInt<3>]>;
 233 def SDTFPBinOpImmRound: SDTypeProfile<1, 4, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 234                              SDTCisSameAs<0,2>, SDTCisInt<3>, SDTCisInt<4>]>;
 235
 236 def SDTVBroadcast  : SDTypeProfile<1, 1, [SDTCisVec<0>]>;
 237 def SDTVBroadcastm : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>]>;
 238
 239 def SDTBlend : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 240                              SDTCisSameAs<1,2>, SDTCisVT<3, i8>]>;
 241
 242 def SDTFPBinOpRound : SDTypeProfile<1, 3, [      // fadd_round, fmul_round, etc.
 243   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>, SDTCisInt<3>]>;
 244
 245 def SDTFPUnaryOpRound : SDTypeProfile<1, 2, [      // fsqrt_round, fgetexp_round, etc.
 246   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisInt<2>]>;
 247
 248 def SDTFma : SDTypeProfile<1, 3, [SDTCisSameAs<0,1>,
 249                            SDTCisSameAs<1,2>, SDTCisSameAs<1,3>]>;
 250 def SDTFmaRound : SDTypeProfile<1, 4, [SDTCisSameAs<0,1>,
 251                            SDTCisSameAs<1,2>, SDTCisSameAs<1,3>, SDTCisInt<4>]>;
 252 def STDFp1SrcRm : SDTypeProfile<1, 2, [SDTCisSameAs<0,1>,
 253                            SDTCisVec<0>, SDTCisInt<2>]>;
 254 def STDFp2SrcRm : SDTypeProfile<1, 3, [SDTCisSameAs<0,1>,
 255                            SDTCisVec<0>, SDTCisInt<3>]>;
 256 def STDFp3SrcRm : SDTypeProfile<1, 4, [SDTCisSameAs<0,1>,
 257                            SDTCisVec<0>, SDTCisInt<3>, SDTCisInt<4>]>;
 258
 259 def X86PAlignr : SDNode<"X86ISD::PALIGNR", SDTShuff3OpI>;
 260 def X86VAlign  : SDNode<"X86ISD::VALIGN", SDTShuff3OpI>;
 261 def X86Abs     : SDNode<"X86ISD::ABS", SDTIntUnaryOp>;
 262
 263 def X86PShufd  : SDNode<"X86ISD::PSHUFD", SDTShuff2OpI>;
 264 def X86PShufhw : SDNode<"X86ISD::PSHUFHW", SDTShuff2OpI>;
 265 def X86PShuflw : SDNode<"X86ISD::PSHUFLW", SDTShuff2OpI>;
 266
 267 def X86Shufp   : SDNode<"X86ISD::SHUFP", SDTShuff3OpI>;
 268 def X86Shuf128 : SDNode<"X86ISD::SHUF128", SDTShuff3OpI>;
 269
 270 def X86Movddup  : SDNode<"X86ISD::MOVDDUP", SDTShuff1Op>;
 271 def X86Movshdup : SDNode<"X86ISD::MOVSHDUP", SDTShuff1Op>;
 272 def X86Movsldup : SDNode<"X86ISD::MOVSLDUP", SDTShuff1Op>;
 273
 274 def X86Movsd : SDNode<"X86ISD::MOVSD", SDTShuff2Op>;
 275 def X86Movss : SDNode<"X86ISD::MOVSS", SDTShuff2Op>;
 276
 277 def X86Movlhps : SDNode<"X86ISD::MOVLHPS", SDTShuff2Op>;
 278 def X86Movlhpd : SDNode<"X86ISD::MOVLHPD", SDTShuff2Op>;
 279 def X86Movhlps : SDNode<"X86ISD::MOVHLPS", SDTShuff2Op>;
 280
 281 def X86Movlps : SDNode<"X86ISD::MOVLPS", SDTShuff2Op>;
 282 def X86Movlpd : SDNode<"X86ISD::MOVLPD", SDTShuff2Op>;
 283
 284 def SDTPack : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>, SDTCisSameAs<2, 1>]>;
 285 def X86Packss : SDNode<"X86ISD::PACKSS", SDTPack>;
 286 def X86Packus : SDNode<"X86ISD::PACKUS", SDTPack>;
 287
 288 def X86Unpckl : SDNode<"X86ISD::UNPCKL", SDTShuff2Op>;
 289 def X86Unpckh : SDNode<"X86ISD::UNPCKH", SDTShuff2Op>;
 290
 291 def X86vpmaddubsw  : SDNode<"X86ISD::VPMADDUBSW" , SDTPack>;
 292 def X86vpmaddwd    : SDNode<"X86ISD::VPMADDWD"   , SDTPack>;
 293
 294 def X86VPermilpv  : SDNode<"X86ISD::VPERMILPV", SDTShuff2OpM>;
 295 def X86VPermilpi  : SDNode<"X86ISD::VPERMILPI", SDTShuff2OpI>;
 296 def X86VPermv     : SDNode<"X86ISD::VPERMV",    SDTShuff2Op>;
 297 def X86VPermi     : SDNode<"X86ISD::VPERMI",    SDTShuff2OpI>;
 298 def X86VPermv3    : SDNode<"X86ISD::VPERMV3",   SDTShuff3Op>;
 299 def X86VPermiv3   : SDNode<"X86ISD::VPERMIV3",  SDTShuff3Op>;
 300
 301 def X86VPerm2x128 : SDNode<"X86ISD::VPERM2X128", SDTShuff3OpI>;
 302
 303 def X86VFixupimm       : SDNode<"X86ISD::VFIXUPIMM", SDTFPBinOpImmRound>;
 304 def X86VRange          : SDNode<"X86ISD::VRANGE", SDTFPBinOpImmRound>;
 305
 306 def X86SubVBroadcast : SDNode<"X86ISD::SUBV_BROADCAST",
 307                     SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 308                                          SDTCisSubVecOfVec<1, 0>]>, []>;
 309 def X86VBroadcast : SDNode<"X86ISD::VBROADCAST", SDTVBroadcast>;
 310 def X86Vinsert   : SDNode<"X86ISD::VINSERT",  SDTypeProfile<1, 3,
 311                               [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 312 def X86Vextract   : SDNode<"X86ISD::VEXTRACT",  SDTypeProfile<1, 2,
 313                               [SDTCisVec<1>, SDTCisPtrTy<2>]>, []>;
 314
 315 def X86Blendi    : SDNode<"X86ISD::BLENDI",   SDTBlend>;
 316
 317 def X86Addsub    : SDNode<"X86ISD::ADDSUB", SDTFPBinOp>;
 318
 319 def X86faddRnd   : SDNode<"X86ISD::FADD_RND",  SDTFPBinOpRound>;
 320 def X86fsubRnd   : SDNode<"X86ISD::FSUB_RND",  SDTFPBinOpRound>;
 321 def X86fmulRnd   : SDNode<"X86ISD::FMUL_RND",  SDTFPBinOpRound>;
 322 def X86fdivRnd   : SDNode<"X86ISD::FDIV_RND",  SDTFPBinOpRound>;
 323 def X86fmaxRnd   : SDNode<"X86ISD::FMAX_RND",      SDTFPBinOpRound>;
 324 def X86scalef    : SDNode<"X86ISD::SCALEF",    SDTFPBinOpRound>;
 325 def X86fminRnd   : SDNode<"X86ISD::FMIN_RND",      SDTFPBinOpRound>;
 326 def X86fsqrtRnd     : SDNode<"X86ISD::FSQRT_RND",  SDTFPUnaryOpRound>;
 327 def X86fgetexpRnd   : SDNode<"X86ISD::FGETEXP_RND",  SDTFPUnaryOpRound>;
 328
 329 def X86Fmadd     : SDNode<"X86ISD::FMADD",     SDTFma>;
 330 def X86Fnmadd    : SDNode<"X86ISD::FNMADD",    SDTFma>;
 331 def X86Fmsub     : SDNode<"X86ISD::FMSUB",     SDTFma>;
 332 def X86Fnmsub    : SDNode<"X86ISD::FNMSUB",    SDTFma>;
 333 def X86Fmaddsub  : SDNode<"X86ISD::FMADDSUB",  SDTFma>;
 334 def X86Fmsubadd  : SDNode<"X86ISD::FMSUBADD",  SDTFma>;
 335
 336 def X86FmaddRnd     : SDNode<"X86ISD::FMADD_RND",     SDTFmaRound>;
 337 def X86FnmaddRnd    : SDNode<"X86ISD::FNMADD_RND",    SDTFmaRound>;
 338 def X86FmsubRnd     : SDNode<"X86ISD::FMSUB_RND",     SDTFmaRound>;
 339 def X86FnmsubRnd    : SDNode<"X86ISD::FNMSUB_RND",    SDTFmaRound>;
 340 def X86FmaddsubRnd  : SDNode<"X86ISD::FMADDSUB_RND",  SDTFmaRound>;
 341 def X86FmsubaddRnd  : SDNode<"X86ISD::FMSUBADD_RND",  SDTFmaRound>;
 342
 343 def X86rsqrt28   : SDNode<"X86ISD::RSQRT28",  STDFp1SrcRm>;
 344 def X86rcp28     : SDNode<"X86ISD::RCP28",    STDFp1SrcRm>;
 345 def X86exp2      : SDNode<"X86ISD::EXP2",     STDFp1SrcRm>;
 346
 347 def X86rsqrt28s  : SDNode<"X86ISD::RSQRT28",  STDFp2SrcRm>;
 348 def X86rcp28s    : SDNode<"X86ISD::RCP28",    STDFp2SrcRm>;
 349 def X86RndScale  : SDNode<"X86ISD::RNDSCALE", STDFp3SrcRm>;
 350
 351 def SDT_PCMPISTRI : SDTypeProfile<2, 3, [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
 352                                          SDTCisVT<2, v16i8>, SDTCisVT<3, v16i8>,
 353                                          SDTCisVT<4, i8>]>;
 354 def SDT_PCMPESTRI : SDTypeProfile<2, 5, [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
 355                                          SDTCisVT<2, v16i8>, SDTCisVT<3, i32>,
 356                                          SDTCisVT<4, v16i8>, SDTCisVT<5, i32>,
 357                                          SDTCisVT<6, i8>]>;
 358
 359 def X86pcmpistri : SDNode<"X86ISD::PCMPISTRI", SDT_PCMPISTRI>;
 360 def X86pcmpestri : SDNode<"X86ISD::PCMPESTRI", SDT_PCMPESTRI>;
 361
 362 def X86compress: SDNode<"X86ISD::COMPRESS", SDTypeProfile<1, 1,
 363                               [SDTCisSameAs<0, 1>, SDTCisVec<1>]>, []>;
 364 def X86expand  : SDNode<"X86ISD::EXPAND", SDTypeProfile<1, 1,
 365                               [SDTCisSameAs<0, 1>, SDTCisVec<1>]>, []>;
 366
 367 def SDTintToFPRound: SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisFP<0>,
 368                                SDTCisSameAs<0,1>, SDTCisInt<2>, SDTCisInt<3>]>;
 369
 370 def SDTDoubleToInt: SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 371                                          SDTCisInt<0>, SDTCVecEltisVT<1, f64>]>;
 372 def SDTFloatToInt: SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 373                                          SDTCisInt<0>, SDTCVecEltisVT<1, f32>]>;
 374
 375 def SDTDoubleToIntRnd: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 376                                          SDTCisInt<0>, SDTCVecEltisVT<1, f64>]>;
 377 def SDTFloatToIntRnd: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 378                                          SDTCisInt<0>, SDTCVecEltisVT<1, f32>]>;
 379
 380 def SDTVintToFPRound: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 381                                            SDTCisFP<0>, SDTCVecEltisVT<1, i32>,
 382                                            SDTCisInt<2>]>;
 383 def SDTVlongToFPRound: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 384                                            SDTCisFP<0>, SDTCVecEltisVT<1, i64>,
 385                                            SDTCisInt<2>]>;
 386
 387 def SDTVFPToIntRound: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 388                                            SDTCisFP<1>, SDTCVecEltisVT<0, i32>,
 389                                            SDTCisInt<2>]>;
 390 def SDTVFPToLongRound: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 391                                            SDTCisFP<1>, SDTCVecEltisVT<0, i64>,
 392                                            SDTCisInt<2>]>;
 393
 394 // Scalar
 395 def X86SintToFpRnd  : SDNode<"X86ISD::SINT_TO_FP_RND",  SDTintToFPRound>;
 396 def X86UintToFpRnd  : SDNode<"X86ISD::UINT_TO_FP_RND",  SDTintToFPRound>;
 397
 398 // Vector with rounding mode
 399
 400 // cvtt fp-to-int staff
 401 def X86VFpToSintRnd   : SDNode<"ISD::FP_TO_SINT",  SDTVFPToIntRound>;
 402 def X86VFpToUintRnd   : SDNode<"ISD::FP_TO_UINT",  SDTVFPToIntRound>;
 403 def X86VFpToSlongRnd  : SDNode<"ISD::FP_TO_SINT",  SDTVFPToLongRound>;
 404 def X86VFpToUlongRnd  : SDNode<"ISD::FP_TO_UINT",  SDTVFPToLongRound>;
 405
 406 def X86VSintToFpRnd   : SDNode<"ISD::SINT_TO_FP",  SDTVintToFPRound>;
 407 def X86VUintToFpRnd   : SDNode<"ISD::UINT_TO_FP",  SDTVintToFPRound>;
 408 def X86VSlongToFpRnd  : SDNode<"ISD::SINT_TO_FP",  SDTVlongToFPRound>;
 409 def X86VUlongToFpRnd  : SDNode<"ISD::UINT_TO_FP",  SDTVlongToFPRound>;
 410
 411 // cvt fp-to-int staff
 412 def X86cvtps2IntRnd      : SDNode<"X86ISD::FP_TO_SINT_RND",  SDTFloatToIntRnd>;
 413 def X86cvtps2UIntRnd     : SDNode<"X86ISD::FP_TO_UINT_RND",  SDTFloatToIntRnd>;
 414 def X86cvtpd2IntRnd      : SDNode<"X86ISD::FP_TO_SINT_RND",  SDTDoubleToIntRnd>;
 415 def X86cvtpd2UIntRnd     : SDNode<"X86ISD::FP_TO_UINT_RND",  SDTDoubleToIntRnd>;
 416
 417 // Vector without rounding mode
 418 def X86cvtps2Int      : SDNode<"X86ISD::FP_TO_SINT_RND",  SDTFloatToInt>;
 419 def X86cvtps2UInt     : SDNode<"X86ISD::FP_TO_UINT_RND",  SDTFloatToInt>;
 420 def X86cvtpd2Int      : SDNode<"X86ISD::FP_TO_SINT_RND",  SDTDoubleToInt>;
 421 def X86cvtpd2UInt     : SDNode<"X86ISD::FP_TO_UINT_RND",  SDTDoubleToInt>;
 422
 423 def X86vfpextRnd  : SDNode<"X86ISD::VFPEXT",
 424                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 425                                              SDTCisFP<0>, SDTCisFP<1>,
 426                                              SDTCisOpSmallerThanOp<1, 0>,
 427                                              SDTCisInt<2>]>>;
 428 def X86vfproundRnd: SDNode<"X86ISD::VFPROUND",
 429                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 430                                              SDTCisFP<0>, SDTCisFP<1>,
 431                                              SDTCVecEltisVT<0, f32>,
 432                                              SDTCVecEltisVT<1, f64>,
 433                                              SDTCisInt<2>]>>;
 434
 435 //===----------------------------------------------------------------------===//
 436 // SSE Complex Patterns
 437 //===----------------------------------------------------------------------===//
 438
 439 // These are 'extloads' from a scalar to the low element of a vector, zeroing
 440 // the top elements.  These are used for the SSE 'ss' and 'sd' instruction
 441 // forms.
 442 def sse_load_f32 : ComplexPattern<v4f32, 5, "SelectScalarSSELoad", [],
 443                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 444                                    SDNPWantRoot]>;
 445 def sse_load_f64 : ComplexPattern<v2f64, 5, "SelectScalarSSELoad", [],
 446                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 447                                    SDNPWantRoot]>;
 448
 449 def ssmem : Operand<v4f32> {
 450   let PrintMethod = "printf32mem";
 451   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 452   let ParserMatchClass = X86Mem32AsmOperand;
 453   let OperandType = "OPERAND_MEMORY";
 454 }
 455 def sdmem : Operand<v2f64> {
 456   let PrintMethod = "printf64mem";
 457   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 458   let ParserMatchClass = X86Mem64AsmOperand;
 459   let OperandType = "OPERAND_MEMORY";
 460 }
 461
 462 //===----------------------------------------------------------------------===//
 463 // SSE pattern fragments
 464 //===----------------------------------------------------------------------===//
 465
 466 // 128-bit load pattern fragments
 467 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 468 def loadv4f32    : PatFrag<(ops node:$ptr), (v4f32 (load node:$ptr))>;
 469 def loadv2f64    : PatFrag<(ops node:$ptr), (v2f64 (load node:$ptr))>;
 470 def loadv2i64    : PatFrag<(ops node:$ptr), (v2i64 (load node:$ptr))>;
 471
 472 // 256-bit load pattern fragments
 473 // NOTE: all 256-bit integer vector loads are promoted to v4i64
 474 def loadv8f32    : PatFrag<(ops node:$ptr), (v8f32 (load node:$ptr))>;
 475 def loadv4f64    : PatFrag<(ops node:$ptr), (v4f64 (load node:$ptr))>;
 476 def loadv4i64    : PatFrag<(ops node:$ptr), (v4i64 (load node:$ptr))>;
 477
 478 // 512-bit load pattern fragments
 479 def loadv16f32   : PatFrag<(ops node:$ptr), (v16f32 (load node:$ptr))>;
 480 def loadv8f64    : PatFrag<(ops node:$ptr), (v8f64 (load node:$ptr))>;
 481 def loadv64i8    : PatFrag<(ops node:$ptr), (v64i8 (load node:$ptr))>;
 482 def loadv32i16   : PatFrag<(ops node:$ptr), (v32i16 (load node:$ptr))>;
 483 def loadv16i32   : PatFrag<(ops node:$ptr), (v16i32 (load node:$ptr))>;
 484 def loadv8i64    : PatFrag<(ops node:$ptr), (v8i64 (load node:$ptr))>;
 485
 486 // 128-/256-/512-bit extload pattern fragments
 487 def extloadv2f32 : PatFrag<(ops node:$ptr), (v2f64 (extloadvf32 node:$ptr))>;
 488 def extloadv4f32 : PatFrag<(ops node:$ptr), (v4f64 (extloadvf32 node:$ptr))>;
 489 def extloadv8f32 : PatFrag<(ops node:$ptr), (v8f64 (extloadvf32 node:$ptr))>;
 490
 491 // These are needed to match a scalar load that is used in a vector-only
 492 // math instruction such as the FP logical ops: andps, andnps, orps, xorps.
 493 // The memory operand is required to be a 128-bit load, so it must be converted
 494 // from a vector to a scalar.
 495 def loadf32_128 : PatFrag<(ops node:$ptr),
 496   (f32 (vector_extract (loadv4f32 node:$ptr), (iPTR 0)))>;
 497 def loadf64_128 : PatFrag<(ops node:$ptr),
 498   (f64 (vector_extract (loadv2f64 node:$ptr), (iPTR 0)))>;
 499
 500 // Like 'store', but always requires 128-bit vector alignment.
 501 def alignedstore : PatFrag<(ops node:$val, node:$ptr),
 502                            (store node:$val, node:$ptr), [{
 503   return cast<StoreSDNode>(N)->getAlignment() >= 16;
 504 }]>;
 505
 506 // Like 'store', but always requires 256-bit vector alignment.
 507 def alignedstore256 : PatFrag<(ops node:$val, node:$ptr),
 508                               (store node:$val, node:$ptr), [{
 509   return cast<StoreSDNode>(N)->getAlignment() >= 32;
 510 }]>;
 511
 512 // Like 'store', but always requires 512-bit vector alignment.
 513 def alignedstore512 : PatFrag<(ops node:$val, node:$ptr),
 514                               (store node:$val, node:$ptr), [{
 515   return cast<StoreSDNode>(N)->getAlignment() >= 64;
 516 }]>;
 517
 518 // Like 'load', but always requires 128-bit vector alignment.
 519 def alignedload : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 520   return cast<LoadSDNode>(N)->getAlignment() >= 16;
 521 }]>;
 522
 523 // Like 'X86vzload', but always requires 128-bit vector alignment.
 524 def alignedX86vzload : PatFrag<(ops node:$ptr), (X86vzload node:$ptr), [{
 525   return cast<MemSDNode>(N)->getAlignment() >= 16;
 526 }]>;
 527
 528 // Like 'load', but always requires 256-bit vector alignment.
 529 def alignedload256 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 530   return cast<LoadSDNode>(N)->getAlignment() >= 32;
 531 }]>;
 532
 533 // Like 'load', but always requires 512-bit vector alignment.
 534 def alignedload512 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 535   return cast<LoadSDNode>(N)->getAlignment() >= 64;
 536 }]>;
 537
 538 def alignedloadfsf32 : PatFrag<(ops node:$ptr),
 539                                (f32 (alignedload node:$ptr))>;
 540 def alignedloadfsf64 : PatFrag<(ops node:$ptr),
 541                                (f64 (alignedload node:$ptr))>;
 542
 543 // 128-bit aligned load pattern fragments
 544 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 545 def alignedloadv4f32 : PatFrag<(ops node:$ptr),
 546                                (v4f32 (alignedload node:$ptr))>;
 547 def alignedloadv2f64 : PatFrag<(ops node:$ptr),
 548                                (v2f64 (alignedload node:$ptr))>;
 549 def alignedloadv2i64 : PatFrag<(ops node:$ptr),
 550                                (v2i64 (alignedload node:$ptr))>;
 551
 552 // 256-bit aligned load pattern fragments
 553 // NOTE: all 256-bit integer vector loads are promoted to v4i64
 554 def alignedloadv8f32 : PatFrag<(ops node:$ptr),
 555                                (v8f32 (alignedload256 node:$ptr))>;
 556 def alignedloadv4f64 : PatFrag<(ops node:$ptr),
 557                                (v4f64 (alignedload256 node:$ptr))>;
 558 def alignedloadv4i64 : PatFrag<(ops node:$ptr),
 559                                (v4i64 (alignedload256 node:$ptr))>;
 560
 561 // 512-bit aligned load pattern fragments
 562 def alignedloadv16f32 : PatFrag<(ops node:$ptr),
 563                                 (v16f32 (alignedload512 node:$ptr))>;
 564 def alignedloadv16i32 : PatFrag<(ops node:$ptr),
 565                                 (v16i32 (alignedload512 node:$ptr))>;
 566 def alignedloadv8f64  : PatFrag<(ops node:$ptr),
 567                                 (v8f64  (alignedload512 node:$ptr))>;
 568 def alignedloadv8i64  : PatFrag<(ops node:$ptr),
 569                                 (v8i64  (alignedload512 node:$ptr))>;
 570
 571 // Like 'load', but uses special alignment checks suitable for use in
 572 // memory operands in most SSE instructions, which are required to
 573 // be naturally aligned on some targets but not on others.  If the subtarget
 574 // allows unaligned accesses, match any load, though this may require
 575 // setting a feature bit in the processor (on startup, for example).
 576 // Opteron 10h and later implement such a feature.
 577 def memop : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 578   return    Subtarget->hasSSEUnalignedMem()
 579          || cast<LoadSDNode>(N)->getAlignment() >= 16;
 580 }]>;
 581
 582 def memopfsf32 : PatFrag<(ops node:$ptr), (f32   (memop node:$ptr))>;
 583 def memopfsf64 : PatFrag<(ops node:$ptr), (f64   (memop node:$ptr))>;
 584
 585 // 128-bit memop pattern fragments
 586 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 587 def memopv4f32 : PatFrag<(ops node:$ptr), (v4f32 (memop node:$ptr))>;
 588 def memopv2f64 : PatFrag<(ops node:$ptr), (v2f64 (memop node:$ptr))>;
 589 def memopv2i64 : PatFrag<(ops node:$ptr), (v2i64 (memop node:$ptr))>;
 590
 591 // These are needed to match a scalar memop that is used in a vector-only
 592 // math instruction such as the FP logical ops: andps, andnps, orps, xorps.
 593 // The memory operand is required to be a 128-bit load, so it must be converted
 594 // from a vector to a scalar.
 595 def memopfsf32_128 : PatFrag<(ops node:$ptr),
 596   (f32 (vector_extract (memopv4f32 node:$ptr), (iPTR 0)))>;
 597 def memopfsf64_128 : PatFrag<(ops node:$ptr),
 598   (f64 (vector_extract (memopv2f64 node:$ptr), (iPTR 0)))>;
 599
 600
 601 // SSSE3 uses MMX registers for some instructions. They aren't aligned on a
 602 // 16-byte boundary.
 603 // FIXME: 8 byte alignment for mmx reads is not required
 604 def memop64 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 605   return cast<LoadSDNode>(N)->getAlignment() >= 8;
 606 }]>;
 607
 608 def memopmmx  : PatFrag<(ops node:$ptr), (x86mmx  (memop64 node:$ptr))>;
 609
 610 // MOVNT Support
 611 // Like 'store', but requires the non-temporal bit to be set
 612 def nontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 613                            (st node:$val, node:$ptr), [{
 614   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 615     return ST->isNonTemporal();
 616   return false;
 617 }]>;
 618
 619 def alignednontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 620                                     (st node:$val, node:$ptr), [{
 621   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 622     return ST->isNonTemporal() && !ST->isTruncatingStore() &&
 623            ST->getAddressingMode() == ISD::UNINDEXED &&
 624            ST->getAlignment() >= 16;
 625   return false;
 626 }]>;
 627
 628 def unalignednontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 629                                       (st node:$val, node:$ptr), [{
 630   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 631     return ST->isNonTemporal() &&
 632            ST->getAlignment() < 16;
 633   return false;
 634 }]>;
 635
 636 def mgatherv4i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 637   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 638   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 639     return (Mgt->getIndex().getValueType() == MVT::v4i32 ||
 640             Mgt->getBasePtr().getValueType() == MVT::v4i32);
 641   return false;
 642 }]>;
 643
 644 def mgatherv8i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 645   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 646   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 647     return (Mgt->getIndex().getValueType() == MVT::v8i32 ||
 648             Mgt->getBasePtr().getValueType() == MVT::v8i32);
 649   return false;
 650 }]>;
 651
 652 def mgatherv2i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 653   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 654   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 655     return (Mgt->getIndex().getValueType() == MVT::v2i64 ||
 656             Mgt->getBasePtr().getValueType() == MVT::v2i64);
 657   return false;
 658 }]>;
 659 def mgatherv4i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 660   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 661   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 662     return (Mgt->getIndex().getValueType() == MVT::v4i64 ||
 663             Mgt->getBasePtr().getValueType() == MVT::v4i64);
 664   return false;
 665 }]>;
 666 def mgatherv8i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 667   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 668   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 669     return (Mgt->getIndex().getValueType() == MVT::v8i64 ||
 670             Mgt->getBasePtr().getValueType() == MVT::v8i64);
 671   return false;
 672 }]>;
 673 def mgatherv16i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 674   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 675   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 676     return (Mgt->getIndex().getValueType() == MVT::v16i32 ||
 677             Mgt->getBasePtr().getValueType() == MVT::v16i32);
 678   return false;
 679 }]>;
 680
 681 def mscatterv2i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 682   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 683   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 684     return (Sc->getIndex().getValueType() == MVT::v2i64 ||
 685             Sc->getBasePtr().getValueType() == MVT::v2i64);
 686   return false;
 687 }]>;
 688
 689 def mscatterv4i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 690   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 691   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 692     return (Sc->getIndex().getValueType() == MVT::v4i32 ||
 693             Sc->getBasePtr().getValueType() == MVT::v4i32);
 694   return false;
 695 }]>;
 696
 697 def mscatterv4i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 698   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 699   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 700     return (Sc->getIndex().getValueType() == MVT::v4i64 ||
 701             Sc->getBasePtr().getValueType() == MVT::v4i64);
 702   return false;
 703 }]>;
 704
 705 def mscatterv8i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 706   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 707   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 708     return (Sc->getIndex().getValueType() == MVT::v8i32 ||
 709             Sc->getBasePtr().getValueType() == MVT::v8i32);
 710   return false;
 711 }]>;
 712
 713 def mscatterv8i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 714   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 715   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 716     return (Sc->getIndex().getValueType() == MVT::v8i64 ||
 717             Sc->getBasePtr().getValueType() == MVT::v8i64);
 718   return false;
 719 }]>;
 720 def mscatterv16i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 721   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 722   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 723     return (Sc->getIndex().getValueType() == MVT::v16i32 ||
 724             Sc->getBasePtr().getValueType() == MVT::v16i32);
 725   return false;
 726 }]>;
 727
 728 // 128-bit bitconvert pattern fragments
 729 def bc_v4f32 : PatFrag<(ops node:$in), (v4f32 (bitconvert node:$in))>;
 730 def bc_v2f64 : PatFrag<(ops node:$in), (v2f64 (bitconvert node:$in))>;
 731 def bc_v16i8 : PatFrag<(ops node:$in), (v16i8 (bitconvert node:$in))>;
 732 def bc_v8i16 : PatFrag<(ops node:$in), (v8i16 (bitconvert node:$in))>;
 733 def bc_v4i32 : PatFrag<(ops node:$in), (v4i32 (bitconvert node:$in))>;
 734 def bc_v2i64 : PatFrag<(ops node:$in), (v2i64 (bitconvert node:$in))>;
 735
 736 // 256-bit bitconvert pattern fragments
 737 def bc_v32i8 : PatFrag<(ops node:$in), (v32i8 (bitconvert node:$in))>;
 738 def bc_v16i16 : PatFrag<(ops node:$in), (v16i16 (bitconvert node:$in))>;
 739 def bc_v8i32 : PatFrag<(ops node:$in), (v8i32 (bitconvert node:$in))>;
 740 def bc_v4i64 : PatFrag<(ops node:$in), (v4i64 (bitconvert node:$in))>;
 741 def bc_v8f32 : PatFrag<(ops node:$in), (v8f32 (bitconvert node:$in))>;
 742
 743 // 512-bit bitconvert pattern fragments
 744 def bc_v16i32 : PatFrag<(ops node:$in), (v16i32 (bitconvert node:$in))>;
 745 def bc_v8i64 : PatFrag<(ops node:$in), (v8i64 (bitconvert node:$in))>;
 746 def bc_v8f64 : PatFrag<(ops node:$in), (v8f64 (bitconvert node:$in))>;
 747 def bc_v16f32 : PatFrag<(ops node:$in), (v16f32 (bitconvert node:$in))>;
 748
 749 def vzmovl_v2i64 : PatFrag<(ops node:$src),
 750                            (bitconvert (v2i64 (X86vzmovl
 751                              (v2i64 (scalar_to_vector (loadi64 node:$src))))))>;
 752 def vzmovl_v4i32 : PatFrag<(ops node:$src),
 753                            (bitconvert (v4i32 (X86vzmovl
 754                              (v4i32 (scalar_to_vector (loadi32 node:$src))))))>;
 755
 756 def vzload_v2i64 : PatFrag<(ops node:$src),
 757                            (bitconvert (v2i64 (X86vzload node:$src)))>;
 758
 759
 760 def fp32imm0 : PatLeaf<(f32 fpimm), [{
 761   return N->isExactlyValue(+0.0);
 762 }]>;
 763
 764 def I8Imm : SDNodeXForm<imm, [{
 765   // Transformation function: get the low 8 bits.
 766   return getI8Imm((uint8_t)N->getZExtValue(), SDLoc(N));
 767 }]>;
 768
 769 def FROUND_NO_EXC : ImmLeaf<i32, [{ return Imm == 8; }]>;
 770 def FROUND_CURRENT : ImmLeaf<i32, [{
 771   return Imm == X86::STATIC_ROUNDING::CUR_DIRECTION;
 772 }]>;
 773
 774 // BYTE_imm - Transform bit immediates into byte immediates.
 775 def BYTE_imm  : SDNodeXForm<imm, [{
 776   // Transformation function: imm >> 3
 777   return getI32Imm(N->getZExtValue() >> 3, SDLoc(N));
 778 }]>;
 779
 780 // EXTRACT_get_vextract128_imm xform function: convert extract_subvector index
 781 // to VEXTRACTF128/VEXTRACTI128 imm.
 782 def EXTRACT_get_vextract128_imm : SDNodeXForm<extract_subvector, [{
 783   return getI8Imm(X86::getExtractVEXTRACT128Immediate(N), SDLoc(N));
 784 }]>;
 785
 786 // INSERT_get_vinsert128_imm xform function: convert insert_subvector index to
 787 // VINSERTF128/VINSERTI128 imm.
 788 def INSERT_get_vinsert128_imm : SDNodeXForm<insert_subvector, [{
 789   return getI8Imm(X86::getInsertVINSERT128Immediate(N), SDLoc(N));
 790 }]>;
 791
 792 // EXTRACT_get_vextract256_imm xform function: convert extract_subvector index
 793 // to VEXTRACTF64x4 imm.
 794 def EXTRACT_get_vextract256_imm : SDNodeXForm<extract_subvector, [{
 795   return getI8Imm(X86::getExtractVEXTRACT256Immediate(N), SDLoc(N));
 796 }]>;
 797
 798 // INSERT_get_vinsert256_imm xform function: convert insert_subvector index to
 799 // VINSERTF64x4 imm.
 800 def INSERT_get_vinsert256_imm : SDNodeXForm<insert_subvector, [{
 801   return getI8Imm(X86::getInsertVINSERT256Immediate(N), SDLoc(N));
 802 }]>;
 803
 804 def vextract128_extract : PatFrag<(ops node:$bigvec, node:$index),
 805                                    (extract_subvector node:$bigvec,
 806                                                       node:$index), [{
 807   return X86::isVEXTRACT128Index(N);
 808 }], EXTRACT_get_vextract128_imm>;
 809
 810 def vinsert128_insert : PatFrag<(ops node:$bigvec, node:$smallvec,
 811                                       node:$index),
 812                                  (insert_subvector node:$bigvec, node:$smallvec,
 813                                                    node:$index), [{
 814   return X86::isVINSERT128Index(N);
 815 }], INSERT_get_vinsert128_imm>;
 816
 817
 818 def vextract256_extract : PatFrag<(ops node:$bigvec, node:$index),
 819                                    (extract_subvector node:$bigvec,
 820                                                       node:$index), [{
 821   return X86::isVEXTRACT256Index(N);
 822 }], EXTRACT_get_vextract256_imm>;
 823
 824 def vinsert256_insert : PatFrag<(ops node:$bigvec, node:$smallvec,
 825                                       node:$index),
 826                                  (insert_subvector node:$bigvec, node:$smallvec,
 827                                                    node:$index), [{
 828   return X86::isVINSERT256Index(N);
 829 }], INSERT_get_vinsert256_imm>;
 830
 831 def masked_load_aligned128 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 832                          (masked_load node:$src1, node:$src2, node:$src3), [{
 833   if (auto *Load = dyn_cast<MaskedLoadSDNode>(N))
 834     return Load->getAlignment() >= 16;
 835   return false;
 836 }]>;
 837
 838 def masked_load_aligned256 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 839                          (masked_load node:$src1, node:$src2, node:$src3), [{
 840   if (auto *Load = dyn_cast<MaskedLoadSDNode>(N))
 841     return Load->getAlignment() >= 32;
 842   return false;
 843 }]>;
 844
 845 def masked_load_aligned512 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 846                          (masked_load node:$src1, node:$src2, node:$src3), [{
 847   if (auto *Load = dyn_cast<MaskedLoadSDNode>(N))
 848     return Load->getAlignment() >= 64;
 849   return false;
 850 }]>;
 851
 852 def masked_load_unaligned : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 853                          (masked_load node:$src1, node:$src2, node:$src3), [{
 854   return isa<MaskedLoadSDNode>(N);
 855 }]>;
 856
 857 def masked_store_aligned128 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 858                          (masked_store node:$src1, node:$src2, node:$src3), [{
 859   if (auto *Store = dyn_cast<MaskedStoreSDNode>(N))
 860     return Store->getAlignment() >= 16;
 861   return false;
 862 }]>;
 863
 864 def masked_store_aligned256 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 865                          (masked_store node:$src1, node:$src2, node:$src3), [{
 866   if (auto *Store = dyn_cast<MaskedStoreSDNode>(N))
 867     return Store->getAlignment() >= 32;
 868   return false;
 869 }]>;
 870
 871 def masked_store_aligned512 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 872                          (masked_store node:$src1, node:$src2, node:$src3), [{
 873   if (auto *Store = dyn_cast<MaskedStoreSDNode>(N))
 874     return Store->getAlignment() >= 64;
 875   return false;
 876 }]>;
 877
 878 def masked_store_unaligned : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 879                          (masked_store node:$src1, node:$src2, node:$src3), [{
 880   return isa<MaskedStoreSDNode>(N);
 881 }]>;
 882