lib/Target/X86/X86InstrFragmentsSIMD.td

   1 //===-- X86InstrFragmentsSIMD.td - x86 SIMD ISA ------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file provides pattern fragments useful for SIMD instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // MMX specific DAG Nodes.
  16 //===----------------------------------------------------------------------===//
  17
  18 // Low word of MMX to GPR.
  19 def MMX_X86movd2w : SDNode<"X86ISD::MMX_MOVD2W", SDTypeProfile<1, 1,
  20                             [SDTCisVT<0, i32>, SDTCisVT<1, x86mmx>]>>;
  21 // GPR to low word of MMX.
  22 def MMX_X86movw2d : SDNode<"X86ISD::MMX_MOVW2D", SDTypeProfile<1, 1,
  23                             [SDTCisVT<0, x86mmx>, SDTCisVT<1, i32>]>>;
  24
  25 //===----------------------------------------------------------------------===//
  26 // MMX Pattern Fragments
  27 //===----------------------------------------------------------------------===//
  28
  29 def load_mmx : PatFrag<(ops node:$ptr), (x86mmx (load node:$ptr))>;
  30 def load_mvmmx : PatFrag<(ops node:$ptr),
  31                          (x86mmx (MMX_X86movw2d (load node:$ptr)))>;
  32 def bc_mmx  : PatFrag<(ops node:$in), (x86mmx  (bitconvert node:$in))>;
  33
  34 //===----------------------------------------------------------------------===//
  35 // SSE specific DAG Nodes.
  36 //===----------------------------------------------------------------------===//
  37
  38 def SDTX86FPShiftOp : SDTypeProfile<1, 2, [ SDTCisSameAs<0, 1>,
  39                                             SDTCisFP<0>, SDTCisInt<2> ]>;
  40 def SDTX86VFCMP : SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<1, 2>,
  41                                        SDTCisFP<1>, SDTCisVT<3, i8>,
  42                                        SDTCisVec<1>]>;
  43
  44 def X86umin    : SDNode<"X86ISD::UMIN",      SDTIntBinOp>;
  45 def X86umax    : SDNode<"X86ISD::UMAX",      SDTIntBinOp>;
  46 def X86smin    : SDNode<"X86ISD::SMIN",      SDTIntBinOp>;
  47 def X86smax    : SDNode<"X86ISD::SMAX",      SDTIntBinOp>;
  48
  49 def X86fmin    : SDNode<"X86ISD::FMIN",      SDTFPBinOp>;
  50 def X86fmax    : SDNode<"X86ISD::FMAX",      SDTFPBinOp>;
  51
  52 // Commutative and Associative FMIN and FMAX.
  53 def X86fminc    : SDNode<"X86ISD::FMINC", SDTFPBinOp,
  54     [SDNPCommutative, SDNPAssociative]>;
  55 def X86fmaxc    : SDNode<"X86ISD::FMAXC", SDTFPBinOp,
  56     [SDNPCommutative, SDNPAssociative]>;
  57
  58 def X86fand    : SDNode<"X86ISD::FAND",      SDTFPBinOp,
  59                         [SDNPCommutative, SDNPAssociative]>;
  60 def X86for     : SDNode<"X86ISD::FOR",       SDTFPBinOp,
  61                         [SDNPCommutative, SDNPAssociative]>;
  62 def X86fxor    : SDNode<"X86ISD::FXOR",      SDTFPBinOp,
  63                         [SDNPCommutative, SDNPAssociative]>;
  64 def X86fandn   : SDNode<"X86ISD::FANDN",     SDTFPBinOp,
  65                         [SDNPCommutative, SDNPAssociative]>;
  66 def X86frsqrt  : SDNode<"X86ISD::FRSQRT",    SDTFPUnaryOp>;
  67 def X86frcp    : SDNode<"X86ISD::FRCP",      SDTFPUnaryOp>;
  68 def X86fsrl    : SDNode<"X86ISD::FSRL",      SDTX86FPShiftOp>;
  69 def X86fgetsign: SDNode<"X86ISD::FGETSIGNx86",SDTFPToIntOp>;
  70 def X86fhadd   : SDNode<"X86ISD::FHADD",     SDTFPBinOp>;
  71 def X86fhsub   : SDNode<"X86ISD::FHSUB",     SDTFPBinOp>;
  72 def X86hadd    : SDNode<"X86ISD::HADD",      SDTIntBinOp>;
  73 def X86hsub    : SDNode<"X86ISD::HSUB",      SDTIntBinOp>;
  74 def X86comi    : SDNode<"X86ISD::COMI",      SDTX86CmpTest>;
  75 def X86ucomi   : SDNode<"X86ISD::UCOMI",     SDTX86CmpTest>;
  76 def X86cmps    : SDNode<"X86ISD::FSETCC",     SDTX86Cmps>;
  77 //def X86cmpsd   : SDNode<"X86ISD::FSETCCsd",    SDTX86Cmpsd>;
  78 def X86pshufb  : SDNode<"X86ISD::PSHUFB",
  79                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  80                                       SDTCisSameAs<0,2>]>>;
  81 def X86andnp   : SDNode<"X86ISD::ANDNP",
  82                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  83                                       SDTCisSameAs<0,2>]>>;
  84 def X86psign   : SDNode<"X86ISD::PSIGN",
  85                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  86                                       SDTCisSameAs<0,2>]>>;
  87 def X86pextrb  : SDNode<"X86ISD::PEXTRB",
  88                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  89 def X86pextrw  : SDNode<"X86ISD::PEXTRW",
  90                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  91 def X86pinsrb  : SDNode<"X86ISD::PINSRB",
  92                  SDTypeProfile<1, 3, [SDTCisVT<0, v16i8>, SDTCisSameAs<0,1>,
  93                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
  94 def X86pinsrw  : SDNode<"X86ISD::PINSRW",
  95                  SDTypeProfile<1, 3, [SDTCisVT<0, v8i16>, SDTCisSameAs<0,1>,
  96                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
  97 def X86insertps : SDNode<"X86ISD::INSERTPS",
  98                  SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisSameAs<0,1>,
  99                                       SDTCisVT<2, v4f32>, SDTCisVT<3, i8>]>>;
 100 def X86vzmovl  : SDNode<"X86ISD::VZEXT_MOVL",
 101                  SDTypeProfile<1, 1, [SDTCisSameAs<0,1>]>>;
 102
 103 def X86vzload  : SDNode<"X86ISD::VZEXT_LOAD", SDTLoad,
 104                         [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 105
 106 def X86vzext   : SDNode<"X86ISD::VZEXT",
 107                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 108                                               SDTCisInt<0>, SDTCisInt<1>,
 109                                               SDTCisOpSmallerThanOp<1, 0>]>>;
 110
 111 def X86vsext   : SDNode<"X86ISD::VSEXT",
 112                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 113                                               SDTCisInt<0>, SDTCisInt<1>,
 114                                               SDTCisOpSmallerThanOp<1, 0>]>>;
 115
 116 def X86vtrunc   : SDNode<"X86ISD::VTRUNC",
 117                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 118                                               SDTCisInt<0>, SDTCisInt<1>,
 119                                               SDTCisOpSmallerThanOp<0, 1>]>>;
 120 def X86trunc    : SDNode<"X86ISD::TRUNC",
 121                          SDTypeProfile<1, 1, [SDTCisInt<0>, SDTCisInt<1>,
 122                                               SDTCisOpSmallerThanOp<0, 1>]>>;
 123
 124 def X86vtruncm   : SDNode<"X86ISD::VTRUNCM",
 125                          SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 126                                               SDTCisInt<0>, SDTCisInt<1>,
 127                                               SDTCisVec<2>, SDTCisInt<2>,
 128                                               SDTCisOpSmallerThanOp<0, 2>]>>;
 129 def X86vfpext  : SDNode<"X86ISD::VFPEXT",
 130                         SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 131                                              SDTCisFP<0>, SDTCisFP<1>,
 132                                              SDTCisOpSmallerThanOp<1, 0>]>>;
 133 def X86vfpround: SDNode<"X86ISD::VFPROUND",
 134                         SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 135                                              SDTCisFP<0>, SDTCisFP<1>,
 136                                              SDTCisOpSmallerThanOp<0, 1>]>>;
 137
 138 def X86vshldq  : SDNode<"X86ISD::VSHLDQ",    SDTIntShiftOp>;
 139 def X86vshrdq  : SDNode<"X86ISD::VSRLDQ",    SDTIntShiftOp>;
 140 def X86cmpp    : SDNode<"X86ISD::CMPP",      SDTX86VFCMP>;
 141 def X86pcmpeq  : SDNode<"X86ISD::PCMPEQ", SDTIntBinOp, [SDNPCommutative]>;
 142 def X86pcmpgt  : SDNode<"X86ISD::PCMPGT", SDTIntBinOp>;
 143
 144 def X86IntCmpMask : SDTypeProfile<1, 2,
 145     [SDTCisVec<0>, SDTCisSameAs<1, 2>, SDTCisInt<1>]>;
 146 def X86pcmpeqm  : SDNode<"X86ISD::PCMPEQM", X86IntCmpMask, [SDNPCommutative]>;
 147 def X86pcmpgtm  : SDNode<"X86ISD::PCMPGTM", X86IntCmpMask>;
 148
 149 def X86CmpMaskCC :
 150       SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisInt<0>, SDTCisVec<1>,
 151                            SDTCisSameAs<1, 2>, SDTCisVT<3, i8>]>;
 152 def X86CmpMaskCCScalar :
 153       SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, i8>]>;
 154
 155 def X86cmpm   : SDNode<"X86ISD::CMPM",    X86CmpMaskCC>;
 156 def X86cmpmu  : SDNode<"X86ISD::CMPMU",   X86CmpMaskCC>;
 157 def X86cmpms  : SDNode<"X86ISD::FSETCC",  X86CmpMaskCCScalar>;
 158
 159 def X86vshl    : SDNode<"X86ISD::VSHL",
 160                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 161                                       SDTCisVec<2>]>>;
 162 def X86vsrl    : SDNode<"X86ISD::VSRL",
 163                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 164                                       SDTCisVec<2>]>>;
 165 def X86vsra    : SDNode<"X86ISD::VSRA",
 166                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 167                                       SDTCisVec<2>]>>;
 168
 169 def X86vshli   : SDNode<"X86ISD::VSHLI", SDTIntShiftOp>;
 170 def X86vsrli   : SDNode<"X86ISD::VSRLI", SDTIntShiftOp>;
 171 def X86vsrai   : SDNode<"X86ISD::VSRAI", SDTIntShiftOp>;
 172
 173 def SDTX86CmpPTest : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
 174                                           SDTCisVec<1>,
 175                                           SDTCisSameAs<2, 1>]>;
 176 def X86addus   : SDNode<"X86ISD::ADDUS", SDTIntBinOp>;
 177 def X86subus   : SDNode<"X86ISD::SUBUS", SDTIntBinOp>;
 178 def X86adds    : SDNode<"X86ISD::ADDS", SDTIntBinOp>;
 179 def X86subs    : SDNode<"X86ISD::SUBS", SDTIntBinOp>;
 180 def X86ptest   : SDNode<"X86ISD::PTEST", SDTX86CmpPTest>;
 181 def X86testp   : SDNode<"X86ISD::TESTP", SDTX86CmpPTest>;
 182 def X86kortest : SDNode<"X86ISD::KORTEST", SDTX86CmpPTest>;
 183 def X86testm   : SDNode<"X86ISD::TESTM", SDTypeProfile<1, 2, [SDTCisVec<0>,
 184                                           SDTCisVec<1>, SDTCisSameAs<2, 1>,
 185                                           SDTCVecEltisVT<0, i1>,
 186                                           SDTCisSameNumEltsAs<0, 1>]>>;
 187 def X86testnm  : SDNode<"X86ISD::TESTNM", SDTypeProfile<1, 2, [SDTCisVec<0>,
 188                                           SDTCisVec<1>, SDTCisSameAs<2, 1>,
 189                                           SDTCVecEltisVT<0, i1>,
 190                                           SDTCisSameNumEltsAs<0, 1>]>>;
 191 def X86select  : SDNode<"X86ISD::SELECT"     , SDTSelect>;
 192
 193 def X86pmuludq : SDNode<"X86ISD::PMULUDQ",
 194                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 195                                       SDTCisSameAs<1,2>]>>;
 196 def X86pmuldq  : SDNode<"X86ISD::PMULDQ",
 197                          SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 198                                        SDTCisSameAs<1,2>]>>;
 199
 200 // Specific shuffle nodes - At some point ISD::VECTOR_SHUFFLE will always get
 201 // translated into one of the target nodes below during lowering.
 202 // Note: this is a work in progress...
 203 def SDTShuff1Op : SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisSameAs<0,1>]>;
 204 def SDTShuff2Op : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 205                                 SDTCisSameAs<0,2>]>;
 206 def SDTShuff3Op : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 207                                 SDTCisSameAs<0,2>, SDTCisSameAs<0,3>]>;
 208
 209 def SDTShuff2OpM : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 210                                         SDTCisVec<2>]>;
 211 def SDTShuff2OpI : SDTypeProfile<1, 2, [SDTCisVec<0>,
 212                                  SDTCisSameAs<0,1>, SDTCisInt<2>]>;
 213 def SDTShuff3OpI : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 214                                  SDTCisSameAs<0,2>, SDTCisInt<3>]>;
 215
 216 def SDTVBroadcast  : SDTypeProfile<1, 1, [SDTCisVec<0>]>;
 217 def SDTVBroadcastm : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>]>;
 218
 219 def SDTBlend : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 220                              SDTCisSameAs<1,2>, SDTCisVT<3, i8>]>;
 221
 222 def SDTFPBinOpRound : SDTypeProfile<1, 3, [      // fadd_round, fmul_round, etc.
 223   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>, SDTCisInt<3>]>;
 224
 225 def SDTFma : SDTypeProfile<1, 3, [SDTCisSameAs<0,1>,
 226                            SDTCisSameAs<1,2>, SDTCisSameAs<1,3>]>;
 227 def SDTFmaRound : SDTypeProfile<1, 4, [SDTCisSameAs<0,1>,
 228                            SDTCisSameAs<1,2>, SDTCisSameAs<1,3>, SDTCisInt<4>]>;
 229 def STDFp1SrcRm : SDTypeProfile<1, 2, [SDTCisSameAs<0,1>,
 230                            SDTCisVec<0>, SDTCisInt<2>]>;
 231 def STDFp2SrcRm : SDTypeProfile<1, 3, [SDTCisSameAs<0,1>,
 232                            SDTCisVec<0>, SDTCisInt<3>]>;
 233 def STDFp3SrcRm : SDTypeProfile<1, 4, [SDTCisSameAs<0,1>,
 234                            SDTCisVec<0>, SDTCisInt<3>, SDTCisInt<4>]>;
 235
 236 def X86PAlignr : SDNode<"X86ISD::PALIGNR", SDTShuff3OpI>;
 237 def X86VAlign  : SDNode<"X86ISD::VALIGN", SDTShuff3OpI>;
 238
 239 def X86PShufd  : SDNode<"X86ISD::PSHUFD", SDTShuff2OpI>;
 240 def X86PShufhw : SDNode<"X86ISD::PSHUFHW", SDTShuff2OpI>;
 241 def X86PShuflw : SDNode<"X86ISD::PSHUFLW", SDTShuff2OpI>;
 242
 243 def X86Shufp : SDNode<"X86ISD::SHUFP", SDTShuff3OpI>;
 244
 245 def X86Movddup  : SDNode<"X86ISD::MOVDDUP", SDTShuff1Op>;
 246 def X86Movshdup : SDNode<"X86ISD::MOVSHDUP", SDTShuff1Op>;
 247 def X86Movsldup : SDNode<"X86ISD::MOVSLDUP", SDTShuff1Op>;
 248
 249 def X86Movsd : SDNode<"X86ISD::MOVSD", SDTShuff2Op>;
 250 def X86Movss : SDNode<"X86ISD::MOVSS", SDTShuff2Op>;
 251
 252 def X86Movlhps : SDNode<"X86ISD::MOVLHPS", SDTShuff2Op>;
 253 def X86Movlhpd : SDNode<"X86ISD::MOVLHPD", SDTShuff2Op>;
 254 def X86Movhlps : SDNode<"X86ISD::MOVHLPS", SDTShuff2Op>;
 255
 256 def X86Movlps : SDNode<"X86ISD::MOVLPS", SDTShuff2Op>;
 257 def X86Movlpd : SDNode<"X86ISD::MOVLPD", SDTShuff2Op>;
 258
 259 def SDTPack : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>, SDTCisSameAs<2, 1>]>;
 260 def X86Packss : SDNode<"X86ISD::PACKSS", SDTPack>;
 261 def X86Packus : SDNode<"X86ISD::PACKUS", SDTPack>;
 262
 263 def X86Unpckl : SDNode<"X86ISD::UNPCKL", SDTShuff2Op>;
 264 def X86Unpckh : SDNode<"X86ISD::UNPCKH", SDTShuff2Op>;
 265
 266 def X86VPermilpv  : SDNode<"X86ISD::VPERMILPV", SDTShuff2OpM>;
 267 def X86VPermilpi  : SDNode<"X86ISD::VPERMILPI", SDTShuff2OpI>;
 268 def X86VPermv     : SDNode<"X86ISD::VPERMV",    SDTShuff2Op>;
 269 def X86VPermi     : SDNode<"X86ISD::VPERMI",    SDTShuff2OpI>;
 270 def X86VPermv3    : SDNode<"X86ISD::VPERMV3",   SDTShuff3Op>;
 271 def X86VPermiv3   : SDNode<"X86ISD::VPERMIV3",  SDTShuff3Op>;
 272
 273 def X86VPerm2x128 : SDNode<"X86ISD::VPERM2X128", SDTShuff3OpI>;
 274
 275 def X86VBroadcast : SDNode<"X86ISD::VBROADCAST", SDTVBroadcast>;
 276 def X86Vinsert   : SDNode<"X86ISD::VINSERT",  SDTypeProfile<1, 3,
 277                               [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 278 def X86Vextract   : SDNode<"X86ISD::VEXTRACT",  SDTypeProfile<1, 2,
 279                               [SDTCisVec<1>, SDTCisPtrTy<2>]>, []>;
 280
 281 def X86Blendi    : SDNode<"X86ISD::BLENDI",   SDTBlend>;
 282
 283 def X86Addsub    : SDNode<"X86ISD::ADDSUB", SDTFPBinOp>;
 284
 285 def X86faddRnd   : SDNode<"X86ISD::FADD_RND",  SDTFPBinOpRound>;
 286 def X86fsubRnd   : SDNode<"X86ISD::FSUB_RND",  SDTFPBinOpRound>;
 287 def X86fmulRnd   : SDNode<"X86ISD::FMUL_RND",  SDTFPBinOpRound>;
 288 def X86fdivRnd   : SDNode<"X86ISD::FDIV_RND",  SDTFPBinOpRound>;
 289 def X86fmaxRnd   : SDNode<"X86ISD::FMAX",      SDTFPBinOpRound>;
 290 def X86fminRnd   : SDNode<"X86ISD::FMIN",      SDTFPBinOpRound>;
 291
 292 def X86Fmadd     : SDNode<"X86ISD::FMADD",     SDTFma>;
 293 def X86Fnmadd    : SDNode<"X86ISD::FNMADD",    SDTFma>;
 294 def X86Fmsub     : SDNode<"X86ISD::FMSUB",     SDTFma>;
 295 def X86Fnmsub    : SDNode<"X86ISD::FNMSUB",    SDTFma>;
 296 def X86Fmaddsub  : SDNode<"X86ISD::FMADDSUB",  SDTFma>;
 297 def X86Fmsubadd  : SDNode<"X86ISD::FMSUBADD",  SDTFma>;
 298
 299 def X86FmaddRnd     : SDNode<"X86ISD::FMADD_RND",     SDTFmaRound>;
 300 def X86FnmaddRnd    : SDNode<"X86ISD::FNMADD_RND",    SDTFmaRound>;
 301 def X86FmsubRnd     : SDNode<"X86ISD::FMSUB_RND",     SDTFmaRound>;
 302 def X86FnmsubRnd    : SDNode<"X86ISD::FNMSUB_RND",    SDTFmaRound>;
 303 def X86FmaddsubRnd  : SDNode<"X86ISD::FMADDSUB_RND",  SDTFmaRound>;
 304 def X86FmsubaddRnd  : SDNode<"X86ISD::FMSUBADD_RND",  SDTFmaRound>;
 305
 306 def X86rsqrt28   : SDNode<"X86ISD::RSQRT28",  STDFp1SrcRm>;
 307 def X86rcp28     : SDNode<"X86ISD::RCP28",    STDFp1SrcRm>;
 308 def X86exp2      : SDNode<"X86ISD::EXP2",     STDFp1SrcRm>;
 309
 310 def X86rsqrt28s  : SDNode<"X86ISD::RSQRT28",  STDFp2SrcRm>;
 311 def X86rcp28s    : SDNode<"X86ISD::RCP28",    STDFp2SrcRm>;
 312 def X86RndScale  : SDNode<"X86ISD::RNDSCALE", STDFp3SrcRm>;
 313
 314 def SDT_PCMPISTRI : SDTypeProfile<2, 3, [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
 315                                          SDTCisVT<2, v16i8>, SDTCisVT<3, v16i8>,
 316                                          SDTCisVT<4, i8>]>;
 317 def SDT_PCMPESTRI : SDTypeProfile<2, 5, [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
 318                                          SDTCisVT<2, v16i8>, SDTCisVT<3, i32>,
 319                                          SDTCisVT<4, v16i8>, SDTCisVT<5, i32>,
 320                                          SDTCisVT<6, i8>]>;
 321
 322 def X86pcmpistri : SDNode<"X86ISD::PCMPISTRI", SDT_PCMPISTRI>;
 323 def X86pcmpestri : SDNode<"X86ISD::PCMPESTRI", SDT_PCMPESTRI>;
 324
 325 def X86compress: SDNode<"X86ISD::COMPRESS", SDTypeProfile<1, 3,
 326                               [SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>,
 327                                SDTCisVec<3>, SDTCisVec<1>, SDTCisInt<1>]>, []>;
 328 def X86expand  : SDNode<"X86ISD::EXPAND", SDTypeProfile<1, 3,
 329                               [SDTCisSameAs<0, 3>,
 330                                SDTCisVec<3>, SDTCisVec<1>, SDTCisInt<1>]>, []>;
 331
 332 //===----------------------------------------------------------------------===//
 333 // SSE Complex Patterns
 334 //===----------------------------------------------------------------------===//
 335
 336 // These are 'extloads' from a scalar to the low element of a vector, zeroing
 337 // the top elements.  These are used for the SSE 'ss' and 'sd' instruction
 338 // forms.
 339 def sse_load_f32 : ComplexPattern<v4f32, 5, "SelectScalarSSELoad", [],
 340                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 341                                    SDNPWantRoot]>;
 342 def sse_load_f64 : ComplexPattern<v2f64, 5, "SelectScalarSSELoad", [],
 343                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 344                                    SDNPWantRoot]>;
 345
 346 def ssmem : Operand<v4f32> {
 347   let PrintMethod = "printf32mem";
 348   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 349   let ParserMatchClass = X86Mem32AsmOperand;
 350   let OperandType = "OPERAND_MEMORY";
 351 }
 352 def sdmem : Operand<v2f64> {
 353   let PrintMethod = "printf64mem";
 354   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 355   let ParserMatchClass = X86Mem64AsmOperand;
 356   let OperandType = "OPERAND_MEMORY";
 357 }
 358
 359 //===----------------------------------------------------------------------===//
 360 // SSE pattern fragments
 361 //===----------------------------------------------------------------------===//
 362
 363 // 128-bit load pattern fragments
 364 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 365 def loadv4f32    : PatFrag<(ops node:$ptr), (v4f32 (load node:$ptr))>;
 366 def loadv2f64    : PatFrag<(ops node:$ptr), (v2f64 (load node:$ptr))>;
 367 def loadv2i64    : PatFrag<(ops node:$ptr), (v2i64 (load node:$ptr))>;
 368
 369 // 256-bit load pattern fragments
 370 // NOTE: all 256-bit integer vector loads are promoted to v4i64
 371 def loadv8f32    : PatFrag<(ops node:$ptr), (v8f32 (load node:$ptr))>;
 372 def loadv4f64    : PatFrag<(ops node:$ptr), (v4f64 (load node:$ptr))>;
 373 def loadv4i64    : PatFrag<(ops node:$ptr), (v4i64 (load node:$ptr))>;
 374
 375 // 512-bit load pattern fragments
 376 def loadv16f32   : PatFrag<(ops node:$ptr), (v16f32 (load node:$ptr))>;
 377 def loadv8f64    : PatFrag<(ops node:$ptr), (v8f64 (load node:$ptr))>;
 378 def loadv64i8    : PatFrag<(ops node:$ptr), (v64i8 (load node:$ptr))>;
 379 def loadv32i16   : PatFrag<(ops node:$ptr), (v32i16 (load node:$ptr))>;
 380 def loadv16i32   : PatFrag<(ops node:$ptr), (v16i32 (load node:$ptr))>;
 381 def loadv8i64    : PatFrag<(ops node:$ptr), (v8i64 (load node:$ptr))>;
 382
 383 // 128-/256-/512-bit extload pattern fragments
 384 def extloadv2f32 : PatFrag<(ops node:$ptr), (v2f64 (extloadvf32 node:$ptr))>;
 385 def extloadv4f32 : PatFrag<(ops node:$ptr), (v4f64 (extloadvf32 node:$ptr))>;
 386 def extloadv8f32 : PatFrag<(ops node:$ptr), (v8f64 (extloadvf32 node:$ptr))>;
 387
 388 // These are needed to match a scalar load that is used in a vector-only
 389 // math instruction such as the FP logical ops: andps, andnps, orps, xorps.
 390 // The memory operand is required to be a 128-bit load, so it must be converted
 391 // from a vector to a scalar.
 392 def loadf32_128 : PatFrag<(ops node:$ptr),
 393   (f32 (vector_extract (loadv4f32 node:$ptr), (iPTR 0)))>;
 394 def loadf64_128 : PatFrag<(ops node:$ptr),
 395   (f64 (vector_extract (loadv2f64 node:$ptr), (iPTR 0)))>;
 396
 397 // Like 'store', but always requires 128-bit vector alignment.
 398 def alignedstore : PatFrag<(ops node:$val, node:$ptr),
 399                            (store node:$val, node:$ptr), [{
 400   return cast<StoreSDNode>(N)->getAlignment() >= 16;
 401 }]>;
 402
 403 // Like 'store', but always requires 256-bit vector alignment.
 404 def alignedstore256 : PatFrag<(ops node:$val, node:$ptr),
 405                               (store node:$val, node:$ptr), [{
 406   return cast<StoreSDNode>(N)->getAlignment() >= 32;
 407 }]>;
 408
 409 // Like 'store', but always requires 512-bit vector alignment.
 410 def alignedstore512 : PatFrag<(ops node:$val, node:$ptr),
 411                               (store node:$val, node:$ptr), [{
 412   return cast<StoreSDNode>(N)->getAlignment() >= 64;
 413 }]>;
 414
 415 // Like 'load', but always requires 128-bit vector alignment.
 416 def alignedload : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 417   return cast<LoadSDNode>(N)->getAlignment() >= 16;
 418 }]>;
 419
 420 // Like 'X86vzload', but always requires 128-bit vector alignment.
 421 def alignedX86vzload : PatFrag<(ops node:$ptr), (X86vzload node:$ptr), [{
 422   return cast<MemSDNode>(N)->getAlignment() >= 16;
 423 }]>;
 424
 425 // Like 'load', but always requires 256-bit vector alignment.
 426 def alignedload256 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 427   return cast<LoadSDNode>(N)->getAlignment() >= 32;
 428 }]>;
 429
 430 // Like 'load', but always requires 512-bit vector alignment.
 431 def alignedload512 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 432   return cast<LoadSDNode>(N)->getAlignment() >= 64;
 433 }]>;
 434
 435 def alignedloadfsf32 : PatFrag<(ops node:$ptr),
 436                                (f32 (alignedload node:$ptr))>;
 437 def alignedloadfsf64 : PatFrag<(ops node:$ptr),
 438                                (f64 (alignedload node:$ptr))>;
 439
 440 // 128-bit aligned load pattern fragments
 441 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 442 def alignedloadv4f32 : PatFrag<(ops node:$ptr),
 443                                (v4f32 (alignedload node:$ptr))>;
 444 def alignedloadv2f64 : PatFrag<(ops node:$ptr),
 445                                (v2f64 (alignedload node:$ptr))>;
 446 def alignedloadv2i64 : PatFrag<(ops node:$ptr),
 447                                (v2i64 (alignedload node:$ptr))>;
 448
 449 // 256-bit aligned load pattern fragments
 450 // NOTE: all 256-bit integer vector loads are promoted to v4i64
 451 def alignedloadv8f32 : PatFrag<(ops node:$ptr),
 452                                (v8f32 (alignedload256 node:$ptr))>;
 453 def alignedloadv4f64 : PatFrag<(ops node:$ptr),
 454                                (v4f64 (alignedload256 node:$ptr))>;
 455 def alignedloadv4i64 : PatFrag<(ops node:$ptr),
 456                                (v4i64 (alignedload256 node:$ptr))>;
 457
 458 // 512-bit aligned load pattern fragments
 459 def alignedloadv16f32 : PatFrag<(ops node:$ptr),
 460                                 (v16f32 (alignedload512 node:$ptr))>;
 461 def alignedloadv16i32 : PatFrag<(ops node:$ptr),
 462                                 (v16i32 (alignedload512 node:$ptr))>;
 463 def alignedloadv8f64  : PatFrag<(ops node:$ptr),
 464                                 (v8f64  (alignedload512 node:$ptr))>;
 465 def alignedloadv8i64  : PatFrag<(ops node:$ptr),
 466                                 (v8i64  (alignedload512 node:$ptr))>;
 467
 468 // Like 'load', but uses special alignment checks suitable for use in
 469 // memory operands in most SSE instructions, which are required to
 470 // be naturally aligned on some targets but not on others.  If the subtarget
 471 // allows unaligned accesses, match any load, though this may require
 472 // setting a feature bit in the processor (on startup, for example).
 473 // Opteron 10h and later implement such a feature.
 474 def memop : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 475   return    Subtarget->hasSSEUnalignedMem()
 476          || cast<LoadSDNode>(N)->getAlignment() >= 16;
 477 }]>;
 478
 479 def memopfsf32 : PatFrag<(ops node:$ptr), (f32   (memop node:$ptr))>;
 480 def memopfsf64 : PatFrag<(ops node:$ptr), (f64   (memop node:$ptr))>;
 481
 482 // 128-bit memop pattern fragments
 483 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 484 def memopv4f32 : PatFrag<(ops node:$ptr), (v4f32 (memop node:$ptr))>;
 485 def memopv2f64 : PatFrag<(ops node:$ptr), (v2f64 (memop node:$ptr))>;
 486 def memopv2i64 : PatFrag<(ops node:$ptr), (v2i64 (memop node:$ptr))>;
 487
 488 // These are needed to match a scalar memop that is used in a vector-only
 489 // math instruction such as the FP logical ops: andps, andnps, orps, xorps.
 490 // The memory operand is required to be a 128-bit load, so it must be converted
 491 // from a vector to a scalar.
 492 def memopfsf32_128 : PatFrag<(ops node:$ptr),
 493   (f32 (vector_extract (memopv4f32 node:$ptr), (iPTR 0)))>;
 494 def memopfsf64_128 : PatFrag<(ops node:$ptr),
 495   (f64 (vector_extract (memopv2f64 node:$ptr), (iPTR 0)))>;
 496
 497
 498 // SSSE3 uses MMX registers for some instructions. They aren't aligned on a
 499 // 16-byte boundary.
 500 // FIXME: 8 byte alignment for mmx reads is not required
 501 def memop64 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 502   return cast<LoadSDNode>(N)->getAlignment() >= 8;
 503 }]>;
 504
 505 def memopmmx  : PatFrag<(ops node:$ptr), (x86mmx  (memop64 node:$ptr))>;
 506
 507 // MOVNT Support
 508 // Like 'store', but requires the non-temporal bit to be set
 509 def nontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 510                            (st node:$val, node:$ptr), [{
 511   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 512     return ST->isNonTemporal();
 513   return false;
 514 }]>;
 515
 516 def alignednontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 517                                     (st node:$val, node:$ptr), [{
 518   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 519     return ST->isNonTemporal() && !ST->isTruncatingStore() &&
 520            ST->getAddressingMode() == ISD::UNINDEXED &&
 521            ST->getAlignment() >= 16;
 522   return false;
 523 }]>;
 524
 525 def unalignednontemporalstore : PatFrag<(ops node:$val, node:$ptr),
 526                                       (st node:$val, node:$ptr), [{
 527   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 528     return ST->isNonTemporal() &&
 529            ST->getAlignment() < 16;
 530   return false;
 531 }]>;
 532
 533 def mgatherv8i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 534   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 535   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 536     return (Mgt->getIndex().getValueType() == MVT::v8i32 ||
 537             Mgt->getBasePtr().getValueType() == MVT::v8i32);
 538   return false;
 539 }]>;
 540
 541 def mgatherv8i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 542   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 543   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 544     return (Mgt->getIndex().getValueType() == MVT::v8i64 ||
 545             Mgt->getBasePtr().getValueType() == MVT::v8i64);
 546   return false;
 547 }]>;
 548 def mgatherv16i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 549   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 550   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 551     return (Mgt->getIndex().getValueType() == MVT::v16i32 ||
 552             Mgt->getBasePtr().getValueType() == MVT::v16i32);
 553   return false;
 554 }]>;
 555
 556 def mscatterv8i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 557   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 558   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 559     return (Sc->getIndex().getValueType() == MVT::v8i32 ||
 560             Sc->getBasePtr().getValueType() == MVT::v8i32);
 561   return false;
 562 }]>;
 563
 564 def mscatterv8i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 565   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 566   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 567     return (Sc->getIndex().getValueType() == MVT::v8i64 ||
 568             Sc->getBasePtr().getValueType() == MVT::v8i64);
 569   return false;
 570 }]>;
 571 def mscatterv16i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 572   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 573   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 574     return (Sc->getIndex().getValueType() == MVT::v16i32 ||
 575             Sc->getBasePtr().getValueType() == MVT::v16i32);
 576   return false;
 577 }]>;
 578
 579 // 128-bit bitconvert pattern fragments
 580 def bc_v4f32 : PatFrag<(ops node:$in), (v4f32 (bitconvert node:$in))>;
 581 def bc_v2f64 : PatFrag<(ops node:$in), (v2f64 (bitconvert node:$in))>;
 582 def bc_v16i8 : PatFrag<(ops node:$in), (v16i8 (bitconvert node:$in))>;
 583 def bc_v8i16 : PatFrag<(ops node:$in), (v8i16 (bitconvert node:$in))>;
 584 def bc_v4i32 : PatFrag<(ops node:$in), (v4i32 (bitconvert node:$in))>;
 585 def bc_v2i64 : PatFrag<(ops node:$in), (v2i64 (bitconvert node:$in))>;
 586
 587 // 256-bit bitconvert pattern fragments
 588 def bc_v32i8 : PatFrag<(ops node:$in), (v32i8 (bitconvert node:$in))>;
 589 def bc_v16i16 : PatFrag<(ops node:$in), (v16i16 (bitconvert node:$in))>;
 590 def bc_v8i32 : PatFrag<(ops node:$in), (v8i32 (bitconvert node:$in))>;
 591 def bc_v4i64 : PatFrag<(ops node:$in), (v4i64 (bitconvert node:$in))>;
 592 def bc_v8f32 : PatFrag<(ops node:$in), (v8f32 (bitconvert node:$in))>;
 593
 594 // 512-bit bitconvert pattern fragments
 595 def bc_v16i32 : PatFrag<(ops node:$in), (v16i32 (bitconvert node:$in))>;
 596 def bc_v8i64 : PatFrag<(ops node:$in), (v8i64 (bitconvert node:$in))>;
 597 def bc_v8f64 : PatFrag<(ops node:$in), (v8f64 (bitconvert node:$in))>;
 598 def bc_v16f32 : PatFrag<(ops node:$in), (v16f32 (bitconvert node:$in))>;
 599
 600 def vzmovl_v2i64 : PatFrag<(ops node:$src),
 601                            (bitconvert (v2i64 (X86vzmovl
 602                              (v2i64 (scalar_to_vector (loadi64 node:$src))))))>;
 603 def vzmovl_v4i32 : PatFrag<(ops node:$src),
 604                            (bitconvert (v4i32 (X86vzmovl
 605                              (v4i32 (scalar_to_vector (loadi32 node:$src))))))>;
 606
 607 def vzload_v2i64 : PatFrag<(ops node:$src),
 608                            (bitconvert (v2i64 (X86vzload node:$src)))>;
 609
 610
 611 def fp32imm0 : PatLeaf<(f32 fpimm), [{
 612   return N->isExactlyValue(+0.0);
 613 }]>;
 614
 615 def I8Imm : SDNodeXForm<imm, [{
 616   // Transformation function: get the low 8 bits.
 617   return getI8Imm((uint8_t)N->getZExtValue(), SDLoc(N));
 618 }]>;
 619
 620 def FROUND_NO_EXC : ImmLeaf<i32, [{ return Imm == 8; }]>;
 621 def FROUND_CURRENT : ImmLeaf<i32, [{
 622   return Imm == X86::STATIC_ROUNDING::CUR_DIRECTION;
 623 }]>;
 624
 625 // BYTE_imm - Transform bit immediates into byte immediates.
 626 def BYTE_imm  : SDNodeXForm<imm, [{
 627   // Transformation function: imm >> 3
 628   return getI32Imm(N->getZExtValue() >> 3, SDLoc(N));
 629 }]>;
 630
 631 // EXTRACT_get_vextract128_imm xform function: convert extract_subvector index
 632 // to VEXTRACTF128/VEXTRACTI128 imm.
 633 def EXTRACT_get_vextract128_imm : SDNodeXForm<extract_subvector, [{
 634   return getI8Imm(X86::getExtractVEXTRACT128Immediate(N), SDLoc(N));
 635 }]>;
 636
 637 // INSERT_get_vinsert128_imm xform function: convert insert_subvector index to
 638 // VINSERTF128/VINSERTI128 imm.
 639 def INSERT_get_vinsert128_imm : SDNodeXForm<insert_subvector, [{
 640   return getI8Imm(X86::getInsertVINSERT128Immediate(N), SDLoc(N));
 641 }]>;
 642
 643 // EXTRACT_get_vextract256_imm xform function: convert extract_subvector index
 644 // to VEXTRACTF64x4 imm.
 645 def EXTRACT_get_vextract256_imm : SDNodeXForm<extract_subvector, [{
 646   return getI8Imm(X86::getExtractVEXTRACT256Immediate(N), SDLoc(N));
 647 }]>;
 648
 649 // INSERT_get_vinsert256_imm xform function: convert insert_subvector index to
 650 // VINSERTF64x4 imm.
 651 def INSERT_get_vinsert256_imm : SDNodeXForm<insert_subvector, [{
 652   return getI8Imm(X86::getInsertVINSERT256Immediate(N), SDLoc(N));
 653 }]>;
 654
 655 def vextract128_extract : PatFrag<(ops node:$bigvec, node:$index),
 656                                    (extract_subvector node:$bigvec,
 657                                                       node:$index), [{
 658   return X86::isVEXTRACT128Index(N);
 659 }], EXTRACT_get_vextract128_imm>;
 660
 661 def vinsert128_insert : PatFrag<(ops node:$bigvec, node:$smallvec,
 662                                       node:$index),
 663                                  (insert_subvector node:$bigvec, node:$smallvec,
 664                                                    node:$index), [{
 665   return X86::isVINSERT128Index(N);
 666 }], INSERT_get_vinsert128_imm>;
 667
 668
 669 def vextract256_extract : PatFrag<(ops node:$bigvec, node:$index),
 670                                    (extract_subvector node:$bigvec,
 671                                                       node:$index), [{
 672   return X86::isVEXTRACT256Index(N);
 673 }], EXTRACT_get_vextract256_imm>;
 674
 675 def vinsert256_insert : PatFrag<(ops node:$bigvec, node:$smallvec,
 676                                       node:$index),
 677                                  (insert_subvector node:$bigvec, node:$smallvec,
 678                                                    node:$index), [{
 679   return X86::isVINSERT256Index(N);
 680 }], INSERT_get_vinsert256_imm>;
 681
 682 def masked_load_aligned128 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 683                          (masked_load node:$src1, node:$src2, node:$src3), [{
 684   if (auto *Load = dyn_cast<MaskedLoadSDNode>(N))
 685     return Load->getAlignment() >= 16;
 686   return false;
 687 }]>;
 688
 689 def masked_load_aligned256 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 690                          (masked_load node:$src1, node:$src2, node:$src3), [{
 691   if (auto *Load = dyn_cast<MaskedLoadSDNode>(N))
 692     return Load->getAlignment() >= 32;
 693   return false;
 694 }]>;
 695
 696 def masked_load_aligned512 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 697                          (masked_load node:$src1, node:$src2, node:$src3), [{
 698   if (auto *Load = dyn_cast<MaskedLoadSDNode>(N))
 699     return Load->getAlignment() >= 64;
 700   return false;
 701 }]>;
 702
 703 def masked_load_unaligned : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 704                          (masked_load node:$src1, node:$src2, node:$src3), [{
 705   return isa<MaskedLoadSDNode>(N);
 706 }]>;
 707
 708 def masked_store_aligned128 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 709                          (masked_store node:$src1, node:$src2, node:$src3), [{
 710   if (auto *Store = dyn_cast<MaskedStoreSDNode>(N))
 711     return Store->getAlignment() >= 16;
 712   return false;
 713 }]>;
 714
 715 def masked_store_aligned256 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 716                          (masked_store node:$src1, node:$src2, node:$src3), [{
 717   if (auto *Store = dyn_cast<MaskedStoreSDNode>(N))
 718     return Store->getAlignment() >= 32;
 719   return false;
 720 }]>;
 721
 722 def masked_store_aligned512 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 723                          (masked_store node:$src1, node:$src2, node:$src3), [{
 724   if (auto *Store = dyn_cast<MaskedStoreSDNode>(N))
 725     return Store->getAlignment() >= 64;
 726   return false;
 727 }]>;
 728
 729 def masked_store_unaligned : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 730                          (masked_store node:$src1, node:$src2, node:$src3), [{
 731   return isa<MaskedStoreSDNode>(N);
 732 }]>;
 733