lib/Target/X86/X86InstrFragmentsSIMD.td

   1 //===-- X86InstrFragmentsSIMD.td - x86 SIMD ISA ------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file provides pattern fragments useful for SIMD instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // MMX specific DAG Nodes.
  16 //===----------------------------------------------------------------------===//
  17
  18 // Low word of MMX to GPR.
  19 def MMX_X86movd2w : SDNode<"X86ISD::MMX_MOVD2W", SDTypeProfile<1, 1,
  20                             [SDTCisVT<0, i32>, SDTCisVT<1, x86mmx>]>>;
  21 // GPR to low word of MMX.
  22 def MMX_X86movw2d : SDNode<"X86ISD::MMX_MOVW2D", SDTypeProfile<1, 1,
  23                             [SDTCisVT<0, x86mmx>, SDTCisVT<1, i32>]>>;
  24
  25 //===----------------------------------------------------------------------===//
  26 // MMX Pattern Fragments
  27 //===----------------------------------------------------------------------===//
  28
  29 def load_mmx : PatFrag<(ops node:$ptr), (x86mmx (load node:$ptr))>;
  30 def load_mvmmx : PatFrag<(ops node:$ptr),
  31                          (x86mmx (MMX_X86movw2d (load node:$ptr)))>;
  32 def bc_mmx  : PatFrag<(ops node:$in), (x86mmx  (bitconvert node:$in))>;
  33
  34 //===----------------------------------------------------------------------===//
  35 // SSE specific DAG Nodes.
  36 //===----------------------------------------------------------------------===//
  37
  38 def SDTX86VFCMP : SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<1, 2>,
  39                                        SDTCisFP<1>, SDTCisVT<3, i8>,
  40                                        SDTCisVec<1>]>;
  41
  42 def X86fmin    : SDNode<"X86ISD::FMIN",      SDTFPBinOp>;
  43 def X86fmax    : SDNode<"X86ISD::FMAX",      SDTFPBinOp>;
  44
  45 // Commutative and Associative FMIN and FMAX.
  46 def X86fminc    : SDNode<"X86ISD::FMINC", SDTFPBinOp,
  47     [SDNPCommutative, SDNPAssociative]>;
  48 def X86fmaxc    : SDNode<"X86ISD::FMAXC", SDTFPBinOp,
  49     [SDNPCommutative, SDNPAssociative]>;
  50
  51 def X86fand    : SDNode<"X86ISD::FAND",      SDTFPBinOp,
  52                         [SDNPCommutative, SDNPAssociative]>;
  53 def X86for     : SDNode<"X86ISD::FOR",       SDTFPBinOp,
  54                         [SDNPCommutative, SDNPAssociative]>;
  55 def X86fxor    : SDNode<"X86ISD::FXOR",      SDTFPBinOp,
  56                         [SDNPCommutative, SDNPAssociative]>;
  57 def X86fandn   : SDNode<"X86ISD::FANDN",     SDTFPBinOp,
  58                         [SDNPCommutative, SDNPAssociative]>;
  59 def X86frsqrt  : SDNode<"X86ISD::FRSQRT",    SDTFPUnaryOp>;
  60 def X86frcp    : SDNode<"X86ISD::FRCP",      SDTFPUnaryOp>;
  61 def X86fgetsign: SDNode<"X86ISD::FGETSIGNx86",SDTFPToIntOp>;
  62 def X86fhadd   : SDNode<"X86ISD::FHADD",     SDTFPBinOp>;
  63 def X86fhsub   : SDNode<"X86ISD::FHSUB",     SDTFPBinOp>;
  64 def X86hadd    : SDNode<"X86ISD::HADD",      SDTIntBinOp>;
  65 def X86hsub    : SDNode<"X86ISD::HSUB",      SDTIntBinOp>;
  66 def X86comi    : SDNode<"X86ISD::COMI",      SDTX86CmpTest>;
  67 def X86ucomi   : SDNode<"X86ISD::UCOMI",     SDTX86CmpTest>;
  68 def X86cmps    : SDNode<"X86ISD::FSETCC",     SDTX86Cmps>;
  69 //def X86cmpsd   : SDNode<"X86ISD::FSETCCsd",    SDTX86Cmpsd>;
  70 def X86cvtdq2pd: SDNode<"X86ISD::CVTDQ2PD",
  71                  SDTypeProfile<1, 1, [SDTCisVT<0, v2f64>,
  72                                       SDTCisVT<1, v4i32>]>>;
  73 def X86cvtudq2pd: SDNode<"X86ISD::CVTUDQ2PD",
  74                  SDTypeProfile<1, 1, [SDTCisVT<0, v2f64>,
  75                                       SDTCisVT<1, v4i32>]>>;
  76 def X86pshufb  : SDNode<"X86ISD::PSHUFB",
  77                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  78                                       SDTCisSameAs<0,2>]>>;
  79 def X86psadbw  : SDNode<"X86ISD::PSADBW",
  80                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  81                                       SDTCisSameAs<0,2>]>>;
  82 def X86dbpsadbw : SDNode<"X86ISD::DBPSADBW",
  83                   SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisVec<1>,
  84                                        SDTCisSameAs<1,2>, SDTCisInt<3>]>>;
  85 def X86andnp   : SDNode<"X86ISD::ANDNP",
  86                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  87                                       SDTCisSameAs<0,2>]>>;
  88 def X86psign   : SDNode<"X86ISD::PSIGN",
  89                  SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
  90                                       SDTCisSameAs<0,2>]>>;
  91 def X86pextrb  : SDNode<"X86ISD::PEXTRB",
  92                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  93 def X86pextrw  : SDNode<"X86ISD::PEXTRW",
  94                  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisPtrTy<2>]>>;
  95 def X86pinsrb  : SDNode<"X86ISD::PINSRB",
  96                  SDTypeProfile<1, 3, [SDTCisVT<0, v16i8>, SDTCisSameAs<0,1>,
  97                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
  98 def X86pinsrw  : SDNode<"X86ISD::PINSRW",
  99                  SDTypeProfile<1, 3, [SDTCisVT<0, v8i16>, SDTCisSameAs<0,1>,
 100                                       SDTCisVT<2, i32>, SDTCisPtrTy<3>]>>;
 101 def X86insertps : SDNode<"X86ISD::INSERTPS",
 102                  SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisSameAs<0,1>,
 103                                       SDTCisVT<2, v4f32>, SDTCisVT<3, i8>]>>;
 104 def X86vzmovl  : SDNode<"X86ISD::VZEXT_MOVL",
 105                  SDTypeProfile<1, 1, [SDTCisSameAs<0,1>]>>;
 106
 107 def X86vzload  : SDNode<"X86ISD::VZEXT_LOAD", SDTLoad,
 108                         [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 109
 110 def X86vzext   : SDNode<"X86ISD::VZEXT",
 111                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 112                                               SDTCisInt<0>, SDTCisInt<1>,
 113                                               SDTCisOpSmallerThanOp<1, 0>]>>;
 114
 115 def X86vsext   : SDNode<"X86ISD::VSEXT",
 116                          SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 117                                               SDTCisInt<0>, SDTCisInt<1>,
 118                                               SDTCisOpSmallerThanOp<1, 0>]>>;
 119
 120 def SDTVtrunc    : SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 121                                        SDTCisInt<0>, SDTCisInt<1>,
 122                                        SDTCisOpSmallerThanOp<0, 1>]>;
 123
 124 def X86vtrunc    : SDNode<"X86ISD::VTRUNC",   SDTVtrunc>;
 125 def X86vtruncs   : SDNode<"X86ISD::VTRUNCS",  SDTVtrunc>;
 126 def X86vtruncus  : SDNode<"X86ISD::VTRUNCUS", SDTVtrunc>;
 127
 128 def X86trunc    : SDNode<"X86ISD::TRUNC",
 129                          SDTypeProfile<1, 1, [SDTCisInt<0>, SDTCisInt<1>,
 130                                               SDTCisOpSmallerThanOp<0, 1>]>>;
 131 def X86vfpext  : SDNode<"X86ISD::VFPEXT",
 132                         SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 133                                              SDTCisFP<0>, SDTCisFP<1>,
 134                                              SDTCisOpSmallerThanOp<1, 0>]>>;
 135 def X86vfpround: SDNode<"X86ISD::VFPROUND",
 136                         SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 137                                              SDTCisFP<0>, SDTCisFP<1>,
 138                                              SDTCisOpSmallerThanOp<0, 1>]>>;
 139
 140 def X86vshldq  : SDNode<"X86ISD::VSHLDQ",    SDTIntShiftOp>;
 141 def X86vshrdq  : SDNode<"X86ISD::VSRLDQ",    SDTIntShiftOp>;
 142 def X86cmpp    : SDNode<"X86ISD::CMPP",      SDTX86VFCMP>;
 143 def X86pcmpeq  : SDNode<"X86ISD::PCMPEQ", SDTIntBinOp, [SDNPCommutative]>;
 144 def X86pcmpgt  : SDNode<"X86ISD::PCMPGT", SDTIntBinOp>;
 145
 146 def X86IntCmpMask : SDTypeProfile<1, 2,
 147     [SDTCisVec<0>, SDTCisSameAs<1, 2>, SDTCisInt<1>]>;
 148 def X86pcmpeqm  : SDNode<"X86ISD::PCMPEQM", X86IntCmpMask, [SDNPCommutative]>;
 149 def X86pcmpgtm  : SDNode<"X86ISD::PCMPGTM", X86IntCmpMask>;
 150
 151 def X86CmpMaskCC :
 152       SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCVecEltisVT<0, i1>,
 153                        SDTCisVec<1>, SDTCisSameAs<2, 1>,
 154                        SDTCisSameNumEltsAs<0, 1>, SDTCisVT<3, i8>]>;
 155 def X86CmpMaskCCRound :
 156       SDTypeProfile<1, 4, [SDTCisVec<0>,SDTCVecEltisVT<0, i1>,
 157                        SDTCisVec<1>, SDTCisSameAs<2, 1>,
 158                        SDTCisSameNumEltsAs<0, 1>, SDTCisVT<3, i8>,
 159                        SDTCisInt<4>]>;
 160 def X86CmpMaskCCScalar :
 161       SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, i8>]>;
 162
 163 def X86cmpm    : SDNode<"X86ISD::CMPM",     X86CmpMaskCC>;
 164 def X86cmpmRnd : SDNode<"X86ISD::CMPM_RND", X86CmpMaskCCRound>;
 165 def X86cmpmu   : SDNode<"X86ISD::CMPMU",    X86CmpMaskCC>;
 166 def X86cmpms   : SDNode<"X86ISD::FSETCC",   X86CmpMaskCCScalar>;
 167
 168 def X86vshl    : SDNode<"X86ISD::VSHL",
 169                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 170                                       SDTCisVec<2>]>>;
 171 def X86vsrl    : SDNode<"X86ISD::VSRL",
 172                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 173                                       SDTCisVec<2>]>>;
 174 def X86vsra    : SDNode<"X86ISD::VSRA",
 175                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 176                                       SDTCisVec<2>]>>;
 177
 178 def X86vshli   : SDNode<"X86ISD::VSHLI", SDTIntShiftOp>;
 179 def X86vsrli   : SDNode<"X86ISD::VSRLI", SDTIntShiftOp>;
 180 def X86vsrai   : SDNode<"X86ISD::VSRAI", SDTIntShiftOp>;
 181
 182 def SDTX86CmpPTest : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
 183                                           SDTCisVec<1>,
 184                                           SDTCisSameAs<2, 1>]>;
 185 def X86addus   : SDNode<"X86ISD::ADDUS", SDTIntBinOp>;
 186 def X86subus   : SDNode<"X86ISD::SUBUS", SDTIntBinOp>;
 187 def X86adds    : SDNode<"X86ISD::ADDS", SDTIntBinOp>;
 188 def X86subs    : SDNode<"X86ISD::SUBS", SDTIntBinOp>;
 189 def X86mulhrs  : SDNode<"X86ISD::MULHRS" , SDTIntBinOp>;
 190 def X86avg     : SDNode<"X86ISD::AVG" , SDTIntBinOp>;
 191 def X86ptest   : SDNode<"X86ISD::PTEST", SDTX86CmpPTest>;
 192 def X86testp   : SDNode<"X86ISD::TESTP", SDTX86CmpPTest>;
 193 def X86kortest : SDNode<"X86ISD::KORTEST", SDTX86CmpPTest>;
 194 def X86ktest   : SDNode<"X86ISD::KTEST", SDTX86CmpPTest>;
 195 def X86testm   : SDNode<"X86ISD::TESTM", SDTypeProfile<1, 2, [SDTCisVec<0>,
 196                                           SDTCisVec<1>, SDTCisSameAs<2, 1>,
 197                                           SDTCVecEltisVT<0, i1>,
 198                                           SDTCisSameNumEltsAs<0, 1>]>>;
 199 def X86testnm  : SDNode<"X86ISD::TESTNM", SDTypeProfile<1, 2, [SDTCisVec<0>,
 200                                           SDTCisVec<1>, SDTCisSameAs<2, 1>,
 201                                           SDTCVecEltisVT<0, i1>,
 202                                           SDTCisSameNumEltsAs<0, 1>]>>;
 203 def X86select  : SDNode<"X86ISD::SELECT"     , SDTSelect>;
 204
 205 def X86pmuludq : SDNode<"X86ISD::PMULUDQ",
 206                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 207                                       SDTCisSameAs<1,2>]>>;
 208 def X86pmuldq  : SDNode<"X86ISD::PMULDQ",
 209                          SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 210                                        SDTCisSameAs<1,2>]>>;
 211
 212 def X86extrqi : SDNode<"X86ISD::EXTRQI",
 213                   SDTypeProfile<1, 3, [SDTCisVT<0, v2i64>, SDTCisSameAs<0,1>,
 214                                        SDTCisVT<2, i8>, SDTCisVT<3, i8>]>>;
 215 def X86insertqi : SDNode<"X86ISD::INSERTQI",
 216                     SDTypeProfile<1, 4, [SDTCisVT<0, v2i64>, SDTCisSameAs<0,1>,
 217                                          SDTCisSameAs<1,2>, SDTCisVT<3, i8>,
 218                                          SDTCisVT<4, i8>]>>;
 219
 220 // Specific shuffle nodes - At some point ISD::VECTOR_SHUFFLE will always get
 221 // translated into one of the target nodes below during lowering.
 222 // Note: this is a work in progress...
 223 def SDTShuff1Op : SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisSameAs<0,1>]>;
 224 def SDTShuff2Op : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 225                                 SDTCisSameAs<0,2>]>;
 226 def SDTShuff3Op : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 227                                 SDTCisSameAs<0,2>, SDTCisSameAs<0,3>]>;
 228
 229 def SDTShuff2OpM : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 230                                         SDTCisVec<2>]>;
 231 def SDTShuff2OpI : SDTypeProfile<1, 2, [SDTCisVec<0>,
 232                                  SDTCisSameAs<0,1>, SDTCisInt<2>]>;
 233 def SDTShuff3OpI : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 234                                  SDTCisSameAs<0,2>, SDTCisInt<3>]>;
 235 def SDTFPBinOpImmRound: SDTypeProfile<1, 4, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 236                              SDTCisSameAs<0,2>, SDTCisInt<3>, SDTCisInt<4>]>;
 237 def SDTFPUnaryOpImmRound: SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 238                               SDTCisInt<2>, SDTCisInt<3>]>;
 239
 240 def SDTVBroadcast  : SDTypeProfile<1, 1, [SDTCisVec<0>]>;
 241 def SDTVBroadcastm : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>]>;
 242
 243 def SDTBlend : SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisSameAs<0,1>,
 244                              SDTCisSameAs<1,2>, SDTCisVT<3, i8>]>;
 245
 246 def SDTFPBinOpRound : SDTypeProfile<1, 3, [      // fadd_round, fmul_round, etc.
 247   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>, SDTCisInt<3>]>;
 248
 249 def SDTFPUnaryOpRound : SDTypeProfile<1, 2, [      // fsqrt_round, fgetexp_round, etc.
 250   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisInt<2>]>;
 251
 252 def SDTFma : SDTypeProfile<1, 3, [SDTCisSameAs<0,1>,
 253                            SDTCisSameAs<1,2>, SDTCisSameAs<1,3>]>;
 254 def SDTFmaRound : SDTypeProfile<1, 4, [SDTCisSameAs<0,1>,
 255                            SDTCisSameAs<1,2>, SDTCisSameAs<1,3>, SDTCisInt<4>]>;
 256 def STDFp1SrcRm : SDTypeProfile<1, 2, [SDTCisSameAs<0,1>,
 257                            SDTCisVec<0>, SDTCisInt<2>]>;
 258 def STDFp2SrcRm : SDTypeProfile<1, 3, [SDTCisSameAs<0,1>,
 259                            SDTCisVec<0>, SDTCisInt<3>]>;
 260 def STDFp3SrcRm : SDTypeProfile<1, 4, [SDTCisSameAs<0,1>,
 261                            SDTCisVec<0>, SDTCisInt<3>, SDTCisInt<4>]>;
 262
 263 def X86PAlignr : SDNode<"X86ISD::PALIGNR", SDTShuff3OpI>;
 264 def X86VAlign  : SDNode<"X86ISD::VALIGN", SDTShuff3OpI>;
 265
 266 def X86Abs      : SDNode<"X86ISD::ABS", SDTIntUnaryOp>;
 267 def X86Conflict : SDNode<"X86ISD::CONFLICT", SDTIntUnaryOp>;
 268
 269 def X86PShufd  : SDNode<"X86ISD::PSHUFD", SDTShuff2OpI>;
 270 def X86PShufhw : SDNode<"X86ISD::PSHUFHW", SDTShuff2OpI>;
 271 def X86PShuflw : SDNode<"X86ISD::PSHUFLW", SDTShuff2OpI>;
 272
 273 def X86Shufp   : SDNode<"X86ISD::SHUFP", SDTShuff3OpI>;
 274 def X86Shuf128 : SDNode<"X86ISD::SHUF128", SDTShuff3OpI>;
 275
 276 def X86Movddup  : SDNode<"X86ISD::MOVDDUP", SDTShuff1Op>;
 277 def X86Movshdup : SDNode<"X86ISD::MOVSHDUP", SDTShuff1Op>;
 278 def X86Movsldup : SDNode<"X86ISD::MOVSLDUP", SDTShuff1Op>;
 279
 280 def X86Movsd : SDNode<"X86ISD::MOVSD", SDTShuff2Op>;
 281 def X86Movss : SDNode<"X86ISD::MOVSS", SDTShuff2Op>;
 282
 283 def X86Movlhps : SDNode<"X86ISD::MOVLHPS", SDTShuff2Op>;
 284 def X86Movlhpd : SDNode<"X86ISD::MOVLHPD", SDTShuff2Op>;
 285 def X86Movhlps : SDNode<"X86ISD::MOVHLPS", SDTShuff2Op>;
 286
 287 def X86Movlps : SDNode<"X86ISD::MOVLPS", SDTShuff2Op>;
 288 def X86Movlpd : SDNode<"X86ISD::MOVLPD", SDTShuff2Op>;
 289
 290 def SDTPack : SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>, SDTCisSameAs<2, 1>]>;
 291 def X86Packss : SDNode<"X86ISD::PACKSS", SDTPack>;
 292 def X86Packus : SDNode<"X86ISD::PACKUS", SDTPack>;
 293
 294 def X86Unpckl : SDNode<"X86ISD::UNPCKL", SDTShuff2Op>;
 295 def X86Unpckh : SDNode<"X86ISD::UNPCKH", SDTShuff2Op>;
 296
 297 def X86vpmaddubsw  : SDNode<"X86ISD::VPMADDUBSW" , SDTPack>;
 298 def X86vpmaddwd    : SDNode<"X86ISD::VPMADDWD"   , SDTPack>;
 299
 300 def X86VPermilpv  : SDNode<"X86ISD::VPERMILPV", SDTShuff2OpM>;
 301 def X86VPermilpi  : SDNode<"X86ISD::VPERMILPI", SDTShuff2OpI>;
 302 def X86VPermv     : SDNode<"X86ISD::VPERMV",    SDTShuff2Op>;
 303 def X86VPermi     : SDNode<"X86ISD::VPERMI",    SDTShuff2OpI>;
 304 def X86VPermv3    : SDNode<"X86ISD::VPERMV3",   SDTShuff3Op>;
 305 def X86VPermiv3   : SDNode<"X86ISD::VPERMIV3",  SDTShuff3Op>;
 306
 307 def X86VPerm2x128 : SDNode<"X86ISD::VPERM2X128", SDTShuff3OpI>;
 308
 309 def X86VFixupimm   : SDNode<"X86ISD::VFIXUPIMM", SDTFPBinOpImmRound>;
 310 def X86VRange      : SDNode<"X86ISD::VRANGE",    SDTFPBinOpImmRound>;
 311 def X86VReduce     : SDNode<"X86ISD::VREDUCE",   SDTFPUnaryOpImmRound>;
 312 def X86VRndScale   : SDNode<"X86ISD::VRNDSCALE", SDTFPUnaryOpImmRound>;
 313 def X86VGetMant    : SDNode<"X86ISD::VGETMANT",  SDTFPUnaryOpImmRound>;
 314 def X86Vfpclass    : SDNode<"X86ISD::VFPCLASS",
 315                        SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCVecEltisVT<0, i1>,
 316                                             SDTCisVec<1>, SDTCisInt<2>]>, []>;
 317
 318 def X86SubVBroadcast : SDNode<"X86ISD::SUBV_BROADCAST",
 319                     SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 320                                          SDTCisSubVecOfVec<1, 0>]>, []>;
 321 def X86VBroadcast : SDNode<"X86ISD::VBROADCAST", SDTVBroadcast>;
 322 def X86Vinsert   : SDNode<"X86ISD::VINSERT",  SDTypeProfile<1, 3,
 323                               [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 324 def X86Vextract   : SDNode<"X86ISD::VEXTRACT",  SDTypeProfile<1, 2,
 325                               [SDTCisVec<1>, SDTCisPtrTy<2>]>, []>;
 326
 327 def X86Blendi    : SDNode<"X86ISD::BLENDI",   SDTBlend>;
 328
 329 def X86Addsub    : SDNode<"X86ISD::ADDSUB", SDTFPBinOp>;
 330
 331 def X86faddRnd   : SDNode<"X86ISD::FADD_RND",  SDTFPBinOpRound>;
 332 def X86fsubRnd   : SDNode<"X86ISD::FSUB_RND",  SDTFPBinOpRound>;
 333 def X86fmulRnd   : SDNode<"X86ISD::FMUL_RND",  SDTFPBinOpRound>;
 334 def X86fdivRnd   : SDNode<"X86ISD::FDIV_RND",  SDTFPBinOpRound>;
 335 def X86fmaxRnd   : SDNode<"X86ISD::FMAX_RND",       SDTFPBinOpRound>;
 336 def X86scalef    : SDNode<"X86ISD::SCALEF",         SDTFPBinOpRound>;
 337 def X86fminRnd   : SDNode<"X86ISD::FMIN_RND",       SDTFPBinOpRound>;
 338 def X86fsqrtRnd     : SDNode<"X86ISD::FSQRT_RND",   SDTFPUnaryOpRound>;
 339 def X86fsqrtRnds    : SDNode<"X86ISD::FSQRT_RND",   STDFp2SrcRm>;
 340 def X86fgetexpRnd   : SDNode<"X86ISD::FGETEXP_RND", SDTFPUnaryOpRound>;
 341 def X86fgetexpRnds  : SDNode<"X86ISD::FGETEXP_RND", STDFp2SrcRm>;
 342
 343 def X86Fmadd     : SDNode<"X86ISD::FMADD",     SDTFma>;
 344 def X86Fnmadd    : SDNode<"X86ISD::FNMADD",    SDTFma>;
 345 def X86Fmsub     : SDNode<"X86ISD::FMSUB",     SDTFma>;
 346 def X86Fnmsub    : SDNode<"X86ISD::FNMSUB",    SDTFma>;
 347 def X86Fmaddsub  : SDNode<"X86ISD::FMADDSUB",  SDTFma>;
 348 def X86Fmsubadd  : SDNode<"X86ISD::FMSUBADD",  SDTFma>;
 349
 350 def X86FmaddRnd     : SDNode<"X86ISD::FMADD_RND",     SDTFmaRound>;
 351 def X86FnmaddRnd    : SDNode<"X86ISD::FNMADD_RND",    SDTFmaRound>;
 352 def X86FmsubRnd     : SDNode<"X86ISD::FMSUB_RND",     SDTFmaRound>;
 353 def X86FnmsubRnd    : SDNode<"X86ISD::FNMSUB_RND",    SDTFmaRound>;
 354 def X86FmaddsubRnd  : SDNode<"X86ISD::FMADDSUB_RND",  SDTFmaRound>;
 355 def X86FmsubaddRnd  : SDNode<"X86ISD::FMSUBADD_RND",  SDTFmaRound>;
 356
 357 def X86rsqrt28   : SDNode<"X86ISD::RSQRT28",  STDFp1SrcRm>;
 358 def X86rcp28     : SDNode<"X86ISD::RCP28",    STDFp1SrcRm>;
 359 def X86exp2      : SDNode<"X86ISD::EXP2",     STDFp1SrcRm>;
 360
 361 def X86rsqrt28s  : SDNode<"X86ISD::RSQRT28",   STDFp2SrcRm>;
 362 def X86rcp28s    : SDNode<"X86ISD::RCP28",     STDFp2SrcRm>;
 363 def X86RndScales : SDNode<"X86ISD::VRNDSCALE", STDFp3SrcRm>;
 364 def X86Reduces   : SDNode<"X86ISD::VREDUCE",   STDFp3SrcRm>;
 365 def X86GetMants  : SDNode<"X86ISD::VGETMANT",  STDFp3SrcRm>;
 366
 367 def SDT_PCMPISTRI : SDTypeProfile<2, 3, [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
 368                                          SDTCisVT<2, v16i8>, SDTCisVT<3, v16i8>,
 369                                          SDTCisVT<4, i8>]>;
 370 def SDT_PCMPESTRI : SDTypeProfile<2, 5, [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
 371                                          SDTCisVT<2, v16i8>, SDTCisVT<3, i32>,
 372                                          SDTCisVT<4, v16i8>, SDTCisVT<5, i32>,
 373                                          SDTCisVT<6, i8>]>;
 374
 375 def X86pcmpistri : SDNode<"X86ISD::PCMPISTRI", SDT_PCMPISTRI>;
 376 def X86pcmpestri : SDNode<"X86ISD::PCMPESTRI", SDT_PCMPESTRI>;
 377
 378 def X86compress: SDNode<"X86ISD::COMPRESS", SDTypeProfile<1, 1,
 379                               [SDTCisSameAs<0, 1>, SDTCisVec<1>]>, []>;
 380 def X86expand  : SDNode<"X86ISD::EXPAND", SDTypeProfile<1, 1,
 381                               [SDTCisSameAs<0, 1>, SDTCisVec<1>]>, []>;
 382
 383 def SDTintToFPRound: SDTypeProfile<1, 3, [SDTCisVec<0>, SDTCisFP<0>,
 384                                SDTCisSameAs<0,1>, SDTCisInt<2>, SDTCisInt<3>]>;
 385
 386 def SDTDoubleToInt: SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 387                                          SDTCisInt<0>, SDTCVecEltisVT<1, f64>]>;
 388 def SDTFloatToInt: SDTypeProfile<1, 1, [SDTCisVec<0>, SDTCisVec<1>,
 389                                          SDTCisInt<0>, SDTCVecEltisVT<1, f32>]>;
 390
 391 def SDTDoubleToIntRnd: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 392                                          SDTCisInt<0>, SDTCVecEltisVT<1, f64>]>;
 393 def SDTFloatToIntRnd: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 394                                          SDTCisInt<0>, SDTCVecEltisVT<1, f32>]>;
 395
 396 def SDTVintToFPRound: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 397                                            SDTCisFP<0>, SDTCVecEltisVT<1, i32>,
 398                                            SDTCisInt<2>]>;
 399 def SDTVlongToFPRound: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 400                                            SDTCisFP<0>, SDTCVecEltisVT<1, i64>,
 401                                            SDTCisInt<2>]>;
 402
 403 def SDTVFPToIntRound: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 404                                            SDTCisFP<1>, SDTCVecEltisVT<0, i32>,
 405                                            SDTCisInt<2>]>;
 406 def SDTVFPToLongRound: SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 407                                            SDTCisFP<1>, SDTCVecEltisVT<0, i64>,
 408                                            SDTCisInt<2>]>;
 409
 410 // Scalar
 411 def X86SintToFpRnd  : SDNode<"X86ISD::SINT_TO_FP_RND",  SDTintToFPRound>;
 412 def X86UintToFpRnd  : SDNode<"X86ISD::UINT_TO_FP_RND",  SDTintToFPRound>;
 413
 414 // Vector with rounding mode
 415
 416 // cvtt fp-to-int staff
 417 def X86VFpToSintRnd   : SDNode<"ISD::FP_TO_SINT",  SDTVFPToIntRound>;
 418 def X86VFpToUintRnd   : SDNode<"ISD::FP_TO_UINT",  SDTVFPToIntRound>;
 419 def X86VFpToSlongRnd  : SDNode<"ISD::FP_TO_SINT",  SDTVFPToLongRound>;
 420 def X86VFpToUlongRnd  : SDNode<"ISD::FP_TO_UINT",  SDTVFPToLongRound>;
 421
 422 def X86VSintToFpRnd   : SDNode<"ISD::SINT_TO_FP",  SDTVintToFPRound>;
 423 def X86VUintToFpRnd   : SDNode<"ISD::UINT_TO_FP",  SDTVintToFPRound>;
 424 def X86VSlongToFpRnd  : SDNode<"ISD::SINT_TO_FP",  SDTVlongToFPRound>;
 425 def X86VUlongToFpRnd  : SDNode<"ISD::UINT_TO_FP",  SDTVlongToFPRound>;
 426
 427 // cvt fp-to-int staff
 428 def X86cvtps2IntRnd      : SDNode<"X86ISD::FP_TO_SINT_RND",  SDTFloatToIntRnd>;
 429 def X86cvtps2UIntRnd     : SDNode<"X86ISD::FP_TO_UINT_RND",  SDTFloatToIntRnd>;
 430 def X86cvtpd2IntRnd      : SDNode<"X86ISD::FP_TO_SINT_RND",  SDTDoubleToIntRnd>;
 431 def X86cvtpd2UIntRnd     : SDNode<"X86ISD::FP_TO_UINT_RND",  SDTDoubleToIntRnd>;
 432
 433 // Vector without rounding mode
 434 def X86cvtps2Int      : SDNode<"X86ISD::FP_TO_SINT_RND",  SDTFloatToInt>;
 435 def X86cvtps2UInt     : SDNode<"X86ISD::FP_TO_UINT_RND",  SDTFloatToInt>;
 436 def X86cvtpd2Int      : SDNode<"X86ISD::FP_TO_SINT_RND",  SDTDoubleToInt>;
 437 def X86cvtpd2UInt     : SDNode<"X86ISD::FP_TO_UINT_RND",  SDTDoubleToInt>;
 438
 439 def X86vfpextRnd  : SDNode<"X86ISD::VFPEXT",
 440                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 441                                              SDTCisFP<0>, SDTCisFP<1>,
 442                                              SDTCisOpSmallerThanOp<1, 0>,
 443                                              SDTCisInt<2>]>>;
 444 def X86vfproundRnd: SDNode<"X86ISD::VFPROUND",
 445                         SDTypeProfile<1, 2, [SDTCisVec<0>, SDTCisVec<1>,
 446                                              SDTCisFP<0>, SDTCisFP<1>,
 447                                              SDTCVecEltisVT<0, f32>,
 448                                              SDTCVecEltisVT<1, f64>,
 449                                              SDTCisInt<2>]>>;
 450
 451 //===----------------------------------------------------------------------===//
 452 // SSE Complex Patterns
 453 //===----------------------------------------------------------------------===//
 454
 455 // These are 'extloads' from a scalar to the low element of a vector, zeroing
 456 // the top elements.  These are used for the SSE 'ss' and 'sd' instruction
 457 // forms.
 458 def sse_load_f32 : ComplexPattern<v4f32, 5, "SelectScalarSSELoad", [],
 459                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 460                                    SDNPWantRoot]>;
 461 def sse_load_f64 : ComplexPattern<v2f64, 5, "SelectScalarSSELoad", [],
 462                                   [SDNPHasChain, SDNPMayLoad, SDNPMemOperand,
 463                                    SDNPWantRoot]>;
 464
 465 def ssmem : Operand<v4f32> {
 466   let PrintMethod = "printf32mem";
 467   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 468   let ParserMatchClass = X86Mem32AsmOperand;
 469   let OperandType = "OPERAND_MEMORY";
 470 }
 471 def sdmem : Operand<v2f64> {
 472   let PrintMethod = "printf64mem";
 473   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 474   let ParserMatchClass = X86Mem64AsmOperand;
 475   let OperandType = "OPERAND_MEMORY";
 476 }
 477
 478 //===----------------------------------------------------------------------===//
 479 // SSE pattern fragments
 480 //===----------------------------------------------------------------------===//
 481
 482 // 128-bit load pattern fragments
 483 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 484 def loadv4f32    : PatFrag<(ops node:$ptr), (v4f32 (load node:$ptr))>;
 485 def loadv2f64    : PatFrag<(ops node:$ptr), (v2f64 (load node:$ptr))>;
 486 def loadv2i64    : PatFrag<(ops node:$ptr), (v2i64 (load node:$ptr))>;
 487
 488 // 256-bit load pattern fragments
 489 // NOTE: all 256-bit integer vector loads are promoted to v4i64
 490 def loadv8f32    : PatFrag<(ops node:$ptr), (v8f32 (load node:$ptr))>;
 491 def loadv4f64    : PatFrag<(ops node:$ptr), (v4f64 (load node:$ptr))>;
 492 def loadv4i64    : PatFrag<(ops node:$ptr), (v4i64 (load node:$ptr))>;
 493
 494 // 512-bit load pattern fragments
 495 def loadv16f32   : PatFrag<(ops node:$ptr), (v16f32 (load node:$ptr))>;
 496 def loadv8f64    : PatFrag<(ops node:$ptr), (v8f64 (load node:$ptr))>;
 497 def loadv64i8    : PatFrag<(ops node:$ptr), (v64i8 (load node:$ptr))>;
 498 def loadv32i16   : PatFrag<(ops node:$ptr), (v32i16 (load node:$ptr))>;
 499 def loadv16i32   : PatFrag<(ops node:$ptr), (v16i32 (load node:$ptr))>;
 500 def loadv8i64    : PatFrag<(ops node:$ptr), (v8i64 (load node:$ptr))>;
 501
 502 // 128-/256-/512-bit extload pattern fragments
 503 def extloadv2f32 : PatFrag<(ops node:$ptr), (v2f64 (extloadvf32 node:$ptr))>;
 504 def extloadv4f32 : PatFrag<(ops node:$ptr), (v4f64 (extloadvf32 node:$ptr))>;
 505 def extloadv8f32 : PatFrag<(ops node:$ptr), (v8f64 (extloadvf32 node:$ptr))>;
 506
 507 // These are needed to match a scalar load that is used in a vector-only
 508 // math instruction such as the FP logical ops: andps, andnps, orps, xorps.
 509 // The memory operand is required to be a 128-bit load, so it must be converted
 510 // from a vector to a scalar.
 511 def loadf32_128 : PatFrag<(ops node:$ptr),
 512   (f32 (vector_extract (loadv4f32 node:$ptr), (iPTR 0)))>;
 513 def loadf64_128 : PatFrag<(ops node:$ptr),
 514   (f64 (vector_extract (loadv2f64 node:$ptr), (iPTR 0)))>;
 515
 516 // Like 'store', but always requires 128-bit vector alignment.
 517 def alignedstore : PatFrag<(ops node:$val, node:$ptr),
 518                            (store node:$val, node:$ptr), [{
 519   return cast<StoreSDNode>(N)->getAlignment() >= 16;
 520 }]>;
 521
 522 // Like 'store', but always requires 256-bit vector alignment.
 523 def alignedstore256 : PatFrag<(ops node:$val, node:$ptr),
 524                               (store node:$val, node:$ptr), [{
 525   return cast<StoreSDNode>(N)->getAlignment() >= 32;
 526 }]>;
 527
 528 // Like 'store', but always requires 512-bit vector alignment.
 529 def alignedstore512 : PatFrag<(ops node:$val, node:$ptr),
 530                               (store node:$val, node:$ptr), [{
 531   return cast<StoreSDNode>(N)->getAlignment() >= 64;
 532 }]>;
 533
 534 // Like 'load', but always requires 128-bit vector alignment.
 535 def alignedload : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 536   return cast<LoadSDNode>(N)->getAlignment() >= 16;
 537 }]>;
 538
 539 // Like 'X86vzload', but always requires 128-bit vector alignment.
 540 def alignedX86vzload : PatFrag<(ops node:$ptr), (X86vzload node:$ptr), [{
 541   return cast<MemSDNode>(N)->getAlignment() >= 16;
 542 }]>;
 543
 544 // Like 'load', but always requires 256-bit vector alignment.
 545 def alignedload256 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 546   return cast<LoadSDNode>(N)->getAlignment() >= 32;
 547 }]>;
 548
 549 // Like 'load', but always requires 512-bit vector alignment.
 550 def alignedload512 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 551   return cast<LoadSDNode>(N)->getAlignment() >= 64;
 552 }]>;
 553
 554 def alignedloadfsf32 : PatFrag<(ops node:$ptr),
 555                                (f32 (alignedload node:$ptr))>;
 556 def alignedloadfsf64 : PatFrag<(ops node:$ptr),
 557                                (f64 (alignedload node:$ptr))>;
 558
 559 // 128-bit aligned load pattern fragments
 560 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 561 def alignedloadv4f32 : PatFrag<(ops node:$ptr),
 562                                (v4f32 (alignedload node:$ptr))>;
 563 def alignedloadv2f64 : PatFrag<(ops node:$ptr),
 564                                (v2f64 (alignedload node:$ptr))>;
 565 def alignedloadv2i64 : PatFrag<(ops node:$ptr),
 566                                (v2i64 (alignedload node:$ptr))>;
 567
 568 // 256-bit aligned load pattern fragments
 569 // NOTE: all 256-bit integer vector loads are promoted to v4i64
 570 def alignedloadv8f32 : PatFrag<(ops node:$ptr),
 571                                (v8f32 (alignedload256 node:$ptr))>;
 572 def alignedloadv4f64 : PatFrag<(ops node:$ptr),
 573                                (v4f64 (alignedload256 node:$ptr))>;
 574 def alignedloadv4i64 : PatFrag<(ops node:$ptr),
 575                                (v4i64 (alignedload256 node:$ptr))>;
 576
 577 // 512-bit aligned load pattern fragments
 578 def alignedloadv16f32 : PatFrag<(ops node:$ptr),
 579                                 (v16f32 (alignedload512 node:$ptr))>;
 580 def alignedloadv16i32 : PatFrag<(ops node:$ptr),
 581                                 (v16i32 (alignedload512 node:$ptr))>;
 582 def alignedloadv8f64  : PatFrag<(ops node:$ptr),
 583                                 (v8f64  (alignedload512 node:$ptr))>;
 584 def alignedloadv8i64  : PatFrag<(ops node:$ptr),
 585                                 (v8i64  (alignedload512 node:$ptr))>;
 586
 587 // Like 'load', but uses special alignment checks suitable for use in
 588 // memory operands in most SSE instructions, which are required to
 589 // be naturally aligned on some targets but not on others.  If the subtarget
 590 // allows unaligned accesses, match any load, though this may require
 591 // setting a feature bit in the processor (on startup, for example).
 592 // Opteron 10h and later implement such a feature.
 593 def memop : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 594   return    Subtarget->hasSSEUnalignedMem()
 595          || cast<LoadSDNode>(N)->getAlignment() >= 16;
 596 }]>;
 597
 598 def memopfsf32 : PatFrag<(ops node:$ptr), (f32   (memop node:$ptr))>;
 599 def memopfsf64 : PatFrag<(ops node:$ptr), (f64   (memop node:$ptr))>;
 600
 601 // 128-bit memop pattern fragments
 602 // NOTE: all 128-bit integer vector loads are promoted to v2i64
 603 def memopv4f32 : PatFrag<(ops node:$ptr), (v4f32 (memop node:$ptr))>;
 604 def memopv2f64 : PatFrag<(ops node:$ptr), (v2f64 (memop node:$ptr))>;
 605 def memopv2i64 : PatFrag<(ops node:$ptr), (v2i64 (memop node:$ptr))>;
 606
 607 // These are needed to match a scalar memop that is used in a vector-only
 608 // math instruction such as the FP logical ops: andps, andnps, orps, xorps.
 609 // The memory operand is required to be a 128-bit load, so it must be converted
 610 // from a vector to a scalar.
 611 def memopfsf32_128 : PatFrag<(ops node:$ptr),
 612   (f32 (vector_extract (memopv4f32 node:$ptr), (iPTR 0)))>;
 613 def memopfsf64_128 : PatFrag<(ops node:$ptr),
 614   (f64 (vector_extract (memopv2f64 node:$ptr), (iPTR 0)))>;
 615
 616
 617 // SSSE3 uses MMX registers for some instructions. They aren't aligned on a
 618 // 16-byte boundary.
 619 // FIXME: 8 byte alignment for mmx reads is not required
 620 def memop64 : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 621   return cast<LoadSDNode>(N)->getAlignment() >= 8;
 622 }]>;
 623
 624 def memopmmx  : PatFrag<(ops node:$ptr), (x86mmx  (memop64 node:$ptr))>;
 625
 626 def mgatherv4i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 627   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 628   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 629     return (Mgt->getIndex().getValueType() == MVT::v4i32 ||
 630             Mgt->getBasePtr().getValueType() == MVT::v4i32);
 631   return false;
 632 }]>;
 633
 634 def mgatherv8i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 635   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 636   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 637     return (Mgt->getIndex().getValueType() == MVT::v8i32 ||
 638             Mgt->getBasePtr().getValueType() == MVT::v8i32);
 639   return false;
 640 }]>;
 641
 642 def mgatherv2i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 643   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 644   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 645     return (Mgt->getIndex().getValueType() == MVT::v2i64 ||
 646             Mgt->getBasePtr().getValueType() == MVT::v2i64);
 647   return false;
 648 }]>;
 649 def mgatherv4i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 650   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 651   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 652     return (Mgt->getIndex().getValueType() == MVT::v4i64 ||
 653             Mgt->getBasePtr().getValueType() == MVT::v4i64);
 654   return false;
 655 }]>;
 656 def mgatherv8i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 657   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 658   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 659     return (Mgt->getIndex().getValueType() == MVT::v8i64 ||
 660             Mgt->getBasePtr().getValueType() == MVT::v8i64);
 661   return false;
 662 }]>;
 663 def mgatherv16i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 664   (masked_gather node:$src1, node:$src2, node:$src3) , [{
 665   if (MaskedGatherSDNode *Mgt = dyn_cast<MaskedGatherSDNode>(N))
 666     return (Mgt->getIndex().getValueType() == MVT::v16i32 ||
 667             Mgt->getBasePtr().getValueType() == MVT::v16i32);
 668   return false;
 669 }]>;
 670
 671 def mscatterv2i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 672   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 673   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 674     return (Sc->getIndex().getValueType() == MVT::v2i64 ||
 675             Sc->getBasePtr().getValueType() == MVT::v2i64);
 676   return false;
 677 }]>;
 678
 679 def mscatterv4i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 680   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 681   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 682     return (Sc->getIndex().getValueType() == MVT::v4i32 ||
 683             Sc->getBasePtr().getValueType() == MVT::v4i32);
 684   return false;
 685 }]>;
 686
 687 def mscatterv4i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 688   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 689   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 690     return (Sc->getIndex().getValueType() == MVT::v4i64 ||
 691             Sc->getBasePtr().getValueType() == MVT::v4i64);
 692   return false;
 693 }]>;
 694
 695 def mscatterv8i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 696   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 697   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 698     return (Sc->getIndex().getValueType() == MVT::v8i32 ||
 699             Sc->getBasePtr().getValueType() == MVT::v8i32);
 700   return false;
 701 }]>;
 702
 703 def mscatterv8i64 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 704   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 705   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 706     return (Sc->getIndex().getValueType() == MVT::v8i64 ||
 707             Sc->getBasePtr().getValueType() == MVT::v8i64);
 708   return false;
 709 }]>;
 710 def mscatterv16i32 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 711   (masked_scatter node:$src1, node:$src2, node:$src3) , [{
 712   if (MaskedScatterSDNode *Sc = dyn_cast<MaskedScatterSDNode>(N))
 713     return (Sc->getIndex().getValueType() == MVT::v16i32 ||
 714             Sc->getBasePtr().getValueType() == MVT::v16i32);
 715   return false;
 716 }]>;
 717
 718 // 128-bit bitconvert pattern fragments
 719 def bc_v4f32 : PatFrag<(ops node:$in), (v4f32 (bitconvert node:$in))>;
 720 def bc_v2f64 : PatFrag<(ops node:$in), (v2f64 (bitconvert node:$in))>;
 721 def bc_v16i8 : PatFrag<(ops node:$in), (v16i8 (bitconvert node:$in))>;
 722 def bc_v8i16 : PatFrag<(ops node:$in), (v8i16 (bitconvert node:$in))>;
 723 def bc_v4i32 : PatFrag<(ops node:$in), (v4i32 (bitconvert node:$in))>;
 724 def bc_v2i64 : PatFrag<(ops node:$in), (v2i64 (bitconvert node:$in))>;
 725
 726 // 256-bit bitconvert pattern fragments
 727 def bc_v32i8 : PatFrag<(ops node:$in), (v32i8 (bitconvert node:$in))>;
 728 def bc_v16i16 : PatFrag<(ops node:$in), (v16i16 (bitconvert node:$in))>;
 729 def bc_v8i32 : PatFrag<(ops node:$in), (v8i32 (bitconvert node:$in))>;
 730 def bc_v4i64 : PatFrag<(ops node:$in), (v4i64 (bitconvert node:$in))>;
 731 def bc_v8f32 : PatFrag<(ops node:$in), (v8f32 (bitconvert node:$in))>;
 732
 733 // 512-bit bitconvert pattern fragments
 734 def bc_v16i32 : PatFrag<(ops node:$in), (v16i32 (bitconvert node:$in))>;
 735 def bc_v8i64 : PatFrag<(ops node:$in), (v8i64 (bitconvert node:$in))>;
 736 def bc_v8f64 : PatFrag<(ops node:$in), (v8f64 (bitconvert node:$in))>;
 737 def bc_v16f32 : PatFrag<(ops node:$in), (v16f32 (bitconvert node:$in))>;
 738
 739 def vzmovl_v2i64 : PatFrag<(ops node:$src),
 740                            (bitconvert (v2i64 (X86vzmovl
 741                              (v2i64 (scalar_to_vector (loadi64 node:$src))))))>;
 742 def vzmovl_v4i32 : PatFrag<(ops node:$src),
 743                            (bitconvert (v4i32 (X86vzmovl
 744                              (v4i32 (scalar_to_vector (loadi32 node:$src))))))>;
 745
 746 def vzload_v2i64 : PatFrag<(ops node:$src),
 747                            (bitconvert (v2i64 (X86vzload node:$src)))>;
 748
 749
 750 def fp32imm0 : PatLeaf<(f32 fpimm), [{
 751   return N->isExactlyValue(+0.0);
 752 }]>;
 753
 754 def I8Imm : SDNodeXForm<imm, [{
 755   // Transformation function: get the low 8 bits.
 756   return getI8Imm((uint8_t)N->getZExtValue(), SDLoc(N));
 757 }]>;
 758
 759 def FROUND_NO_EXC : ImmLeaf<i32, [{ return Imm == 8; }]>;
 760 def FROUND_CURRENT : ImmLeaf<i32, [{
 761   return Imm == X86::STATIC_ROUNDING::CUR_DIRECTION;
 762 }]>;
 763
 764 // BYTE_imm - Transform bit immediates into byte immediates.
 765 def BYTE_imm  : SDNodeXForm<imm, [{
 766   // Transformation function: imm >> 3
 767   return getI32Imm(N->getZExtValue() >> 3, SDLoc(N));
 768 }]>;
 769
 770 // EXTRACT_get_vextract128_imm xform function: convert extract_subvector index
 771 // to VEXTRACTF128/VEXTRACTI128 imm.
 772 def EXTRACT_get_vextract128_imm : SDNodeXForm<extract_subvector, [{
 773   return getI8Imm(X86::getExtractVEXTRACT128Immediate(N), SDLoc(N));
 774 }]>;
 775
 776 // INSERT_get_vinsert128_imm xform function: convert insert_subvector index to
 777 // VINSERTF128/VINSERTI128 imm.
 778 def INSERT_get_vinsert128_imm : SDNodeXForm<insert_subvector, [{
 779   return getI8Imm(X86::getInsertVINSERT128Immediate(N), SDLoc(N));
 780 }]>;
 781
 782 // EXTRACT_get_vextract256_imm xform function: convert extract_subvector index
 783 // to VEXTRACTF64x4 imm.
 784 def EXTRACT_get_vextract256_imm : SDNodeXForm<extract_subvector, [{
 785   return getI8Imm(X86::getExtractVEXTRACT256Immediate(N), SDLoc(N));
 786 }]>;
 787
 788 // INSERT_get_vinsert256_imm xform function: convert insert_subvector index to
 789 // VINSERTF64x4 imm.
 790 def INSERT_get_vinsert256_imm : SDNodeXForm<insert_subvector, [{
 791   return getI8Imm(X86::getInsertVINSERT256Immediate(N), SDLoc(N));
 792 }]>;
 793
 794 def vextract128_extract : PatFrag<(ops node:$bigvec, node:$index),
 795                                    (extract_subvector node:$bigvec,
 796                                                       node:$index), [{
 797   return X86::isVEXTRACT128Index(N);
 798 }], EXTRACT_get_vextract128_imm>;
 799
 800 def vinsert128_insert : PatFrag<(ops node:$bigvec, node:$smallvec,
 801                                       node:$index),
 802                                  (insert_subvector node:$bigvec, node:$smallvec,
 803                                                    node:$index), [{
 804   return X86::isVINSERT128Index(N);
 805 }], INSERT_get_vinsert128_imm>;
 806
 807
 808 def vextract256_extract : PatFrag<(ops node:$bigvec, node:$index),
 809                                    (extract_subvector node:$bigvec,
 810                                                       node:$index), [{
 811   return X86::isVEXTRACT256Index(N);
 812 }], EXTRACT_get_vextract256_imm>;
 813
 814 def vinsert256_insert : PatFrag<(ops node:$bigvec, node:$smallvec,
 815                                       node:$index),
 816                                  (insert_subvector node:$bigvec, node:$smallvec,
 817                                                    node:$index), [{
 818   return X86::isVINSERT256Index(N);
 819 }], INSERT_get_vinsert256_imm>;
 820
 821 def masked_load_aligned128 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 822                          (masked_load node:$src1, node:$src2, node:$src3), [{
 823   if (auto *Load = dyn_cast<MaskedLoadSDNode>(N))
 824     return Load->getAlignment() >= 16;
 825   return false;
 826 }]>;
 827
 828 def masked_load_aligned256 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 829                          (masked_load node:$src1, node:$src2, node:$src3), [{
 830   if (auto *Load = dyn_cast<MaskedLoadSDNode>(N))
 831     return Load->getAlignment() >= 32;
 832   return false;
 833 }]>;
 834
 835 def masked_load_aligned512 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 836                          (masked_load node:$src1, node:$src2, node:$src3), [{
 837   if (auto *Load = dyn_cast<MaskedLoadSDNode>(N))
 838     return Load->getAlignment() >= 64;
 839   return false;
 840 }]>;
 841
 842 def masked_load_unaligned : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 843                          (masked_load node:$src1, node:$src2, node:$src3), [{
 844   return isa<MaskedLoadSDNode>(N);
 845 }]>;
 846
 847 // masked store fragments.
 848 // X86mstore can't be implemented in core DAG files because some targets
 849 // doesn't support vector type ( llvm-tblgen will fail)
 850 def X86mstore : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 851                         (masked_store node:$src1, node:$src2, node:$src3), [{
 852   return !cast<MaskedStoreSDNode>(N)->isTruncatingStore();
 853 }]>;
 854
 855 def masked_store_aligned128 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 856                          (X86mstore node:$src1, node:$src2, node:$src3), [{
 857   if (auto *Store = dyn_cast<MaskedStoreSDNode>(N))
 858     return Store->getAlignment() >= 16;
 859   return false;
 860 }]>;
 861
 862 def masked_store_aligned256 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 863                          (X86mstore node:$src1, node:$src2, node:$src3), [{
 864   if (auto *Store = dyn_cast<MaskedStoreSDNode>(N))
 865     return Store->getAlignment() >= 32;
 866   return false;
 867 }]>;
 868
 869 def masked_store_aligned512 : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 870                          (X86mstore node:$src1, node:$src2, node:$src3), [{
 871   if (auto *Store = dyn_cast<MaskedStoreSDNode>(N))
 872     return Store->getAlignment() >= 64;
 873   return false;
 874 }]>;
 875
 876 def masked_store_unaligned : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 877                          (X86mstore node:$src1, node:$src2, node:$src3), [{
 878   return isa<MaskedStoreSDNode>(N);
 879 }]>;
 880
 881 // masked truncstore fragments
 882 // X86mtruncstore can't be implemented in core DAG files because some targets
 883 // doesn't support vector type ( llvm-tblgen will fail)
 884 def X86mtruncstore : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 885                              (masked_store node:$src1, node:$src2, node:$src3), [{
 886     return cast<MaskedStoreSDNode>(N)->isTruncatingStore();
 887 }]>;
 888 def masked_truncstorevi8 :
 889   PatFrag<(ops node:$src1, node:$src2, node:$src3),
 890           (X86mtruncstore node:$src1, node:$src2, node:$src3), [{
 891   return cast<MaskedStoreSDNode>(N)->getMemoryVT().getScalarType() == MVT::i8;
 892 }]>;
 893 def masked_truncstorevi16 :
 894   PatFrag<(ops node:$src1, node:$src2, node:$src3),
 895           (X86mtruncstore node:$src1, node:$src2, node:$src3), [{
 896   return cast<MaskedStoreSDNode>(N)->getMemoryVT().getScalarType() == MVT::i16;
 897 }]>;
 898 def masked_truncstorevi32 :
 899   PatFrag<(ops node:$src1, node:$src2, node:$src3),
 900           (X86mtruncstore node:$src1, node:$src2, node:$src3), [{
 901   return cast<MaskedStoreSDNode>(N)->getMemoryVT().getScalarType() == MVT::i32;
 902 }]>;