lib/Target/X86/X86InstrFPStack.td

   1 //==- X86InstrFPStack.td - Describe the X86 Instruction Set --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 x87 FPU instruction set, defining the
  11 // instructions, and properties of the instructions which are needed for code
  12 // generation, machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // FPStack specific DAG Nodes.
  18 //===----------------------------------------------------------------------===//
  19
  20 def SDTX86FpGet2    : SDTypeProfile<2, 0, [SDTCisVT<0, f80>,
  21                                            SDTCisVT<1, f80>]>;
  22 def SDTX86Fld       : SDTypeProfile<1, 2, [SDTCisFP<0>,
  23                                            SDTCisPtrTy<1>,
  24                                            SDTCisVT<2, OtherVT>]>;
  25 def SDTX86Fst       : SDTypeProfile<0, 3, [SDTCisFP<0>,
  26                                            SDTCisPtrTy<1>,
  27                                            SDTCisVT<2, OtherVT>]>;
  28 def SDTX86Fild      : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisPtrTy<1>,
  29                                            SDTCisVT<2, OtherVT>]>;
  30 def SDTX86FpToIMem  : SDTypeProfile<0, 2, [SDTCisFP<0>, SDTCisPtrTy<1>]>;
  31
  32 def SDTX86CwdStore  : SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>;
  33
  34 def X86fld          : SDNode<"X86ISD::FLD", SDTX86Fld,
  35                              [SDNPHasChain, SDNPMayLoad]>;
  36 def X86fst          : SDNode<"X86ISD::FST", SDTX86Fst,
  37                              [SDNPHasChain, SDNPInFlag, SDNPMayStore]>;
  38 def X86fild         : SDNode<"X86ISD::FILD", SDTX86Fild,
  39                              [SDNPHasChain, SDNPMayLoad]>;
  40 def X86fildflag     : SDNode<"X86ISD::FILD_FLAG", SDTX86Fild,
  41                              [SDNPHasChain, SDNPOutFlag, SDNPMayLoad]>;
  42 def X86fp_to_i16mem : SDNode<"X86ISD::FP_TO_INT16_IN_MEM", SDTX86FpToIMem,
  43                              [SDNPHasChain, SDNPMayStore]>;
  44 def X86fp_to_i32mem : SDNode<"X86ISD::FP_TO_INT32_IN_MEM", SDTX86FpToIMem,
  45                              [SDNPHasChain, SDNPMayStore]>;
  46 def X86fp_to_i64mem : SDNode<"X86ISD::FP_TO_INT64_IN_MEM", SDTX86FpToIMem,
  47                              [SDNPHasChain, SDNPMayStore]>;
  48 def X86fp_cwd_get16 : SDNode<"X86ISD::FNSTCW16m",          SDTX86CwdStore,
  49                              [SDNPHasChain, SDNPMayStore, SDNPSideEffect]>;
  50
  51 //===----------------------------------------------------------------------===//
  52 // FPStack pattern fragments
  53 //===----------------------------------------------------------------------===//
  54
  55 def fpimm0 : PatLeaf<(fpimm), [{
  56   return N->isExactlyValue(+0.0);
  57 }]>;
  58
  59 def fpimmneg0 : PatLeaf<(fpimm), [{
  60   return N->isExactlyValue(-0.0);
  61 }]>;
  62
  63 def fpimm1 : PatLeaf<(fpimm), [{
  64   return N->isExactlyValue(+1.0);
  65 }]>;
  66
  67 def fpimmneg1 : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(-1.0);
  69 }]>;
  70
  71 // Some 'special' instructions
  72 let usesCustomInserter = 1 in {  // Expanded after instruction selection.
  73   def FP32_TO_INT16_IN_MEM : I<0, Pseudo,
  74                               (outs), (ins i16mem:$dst, RFP32:$src),
  75                               "##FP32_TO_INT16_IN_MEM PSEUDO!",
  76                               [(X86fp_to_i16mem RFP32:$src, addr:$dst)]>;
  77   def FP32_TO_INT32_IN_MEM : I<0, Pseudo,
  78                               (outs), (ins i32mem:$dst, RFP32:$src),
  79                               "##FP32_TO_INT32_IN_MEM PSEUDO!",
  80                               [(X86fp_to_i32mem RFP32:$src, addr:$dst)]>;
  81   def FP32_TO_INT64_IN_MEM : I<0, Pseudo,
  82                               (outs), (ins i64mem:$dst, RFP32:$src),
  83                               "##FP32_TO_INT64_IN_MEM PSEUDO!",
  84                               [(X86fp_to_i64mem RFP32:$src, addr:$dst)]>;
  85   def FP64_TO_INT16_IN_MEM : I<0, Pseudo,
  86                               (outs), (ins i16mem:$dst, RFP64:$src),
  87                               "##FP64_TO_INT16_IN_MEM PSEUDO!",
  88                               [(X86fp_to_i16mem RFP64:$src, addr:$dst)]>;
  89   def FP64_TO_INT32_IN_MEM : I<0, Pseudo,
  90                               (outs), (ins i32mem:$dst, RFP64:$src),
  91                               "##FP64_TO_INT32_IN_MEM PSEUDO!",
  92                               [(X86fp_to_i32mem RFP64:$src, addr:$dst)]>;
  93   def FP64_TO_INT64_IN_MEM : I<0, Pseudo,
  94                               (outs), (ins i64mem:$dst, RFP64:$src),
  95                               "##FP64_TO_INT64_IN_MEM PSEUDO!",
  96                               [(X86fp_to_i64mem RFP64:$src, addr:$dst)]>;
  97   def FP80_TO_INT16_IN_MEM : I<0, Pseudo,
  98                               (outs), (ins i16mem:$dst, RFP80:$src),
  99                               "##FP80_TO_INT16_IN_MEM PSEUDO!",
 100                               [(X86fp_to_i16mem RFP80:$src, addr:$dst)]>;
 101   def FP80_TO_INT32_IN_MEM : I<0, Pseudo,
 102                               (outs), (ins i32mem:$dst, RFP80:$src),
 103                               "##FP80_TO_INT32_IN_MEM PSEUDO!",
 104                               [(X86fp_to_i32mem RFP80:$src, addr:$dst)]>;
 105   def FP80_TO_INT64_IN_MEM : I<0, Pseudo,
 106                               (outs), (ins i64mem:$dst, RFP80:$src),
 107                               "##FP80_TO_INT64_IN_MEM PSEUDO!",
 108                               [(X86fp_to_i64mem RFP80:$src, addr:$dst)]>;
 109 }
 110
 111 // All FP Stack operations are represented with four instructions here.  The
 112 // first three instructions, generated by the instruction selector, use "RFP32"
 113 // "RFP64" or "RFP80" registers: traditional register files to reference 32-bit,
 114 // 64-bit or 80-bit floating point values.  These sizes apply to the values,
 115 // not the registers, which are always 80 bits; RFP32, RFP64 and RFP80 can be
 116 // copied to each other without losing information.  These instructions are all
 117 // pseudo instructions and use the "_Fp" suffix.
 118 // In some cases there are additional variants with a mixture of different
 119 // register sizes.
 120 // The second instruction is defined with FPI, which is the actual instruction
 121 // emitted by the assembler.  These use "RST" registers, although frequently
 122 // the actual register(s) used are implicit.  These are always 80 bits.
 123 // The FP stackifier pass converts one to the other after register allocation
 124 // occurs.
 125 //
 126 // Note that the FpI instruction should have instruction selection info (e.g.
 127 // a pattern) and the FPI instruction should have emission info (e.g. opcode
 128 // encoding and asm printing info).
 129
 130 // Pseudo Instructions for FP stack return values.
 131 def FpGET_ST0_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 132 def FpGET_ST0_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 133 def FpGET_ST0_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 134
 135 // FpGET_ST1* should only be issued *after* an FpGET_ST0* has been issued when
 136 // there are two values live out on the stack from a call or inlineasm.  This
 137 // magic is handled by the stackifier.  It is not valid to emit FpGET_ST1* and
 138 // then FpGET_ST0*.  In addition, it is invalid for any FP-using operations to
 139 // occur between them.
 140 def FpGET_ST1_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 141 def FpGET_ST1_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 142 def FpGET_ST1_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 143
 144 let Defs = [ST0] in {
 145 def FpSET_ST0_32 : FpI_<(outs), (ins RFP32:$src), SpecialFP, []>; // ST(0) = FPR
 146 def FpSET_ST0_64 : FpI_<(outs), (ins RFP64:$src), SpecialFP, []>; // ST(0) = FPR
 147 def FpSET_ST0_80 : FpI_<(outs), (ins RFP80:$src), SpecialFP, []>; // ST(0) = FPR
 148 }
 149
 150 let Defs = [ST1] in {
 151 def FpSET_ST1_32 : FpI_<(outs), (ins RFP32:$src), SpecialFP, []>; // ST(1) = FPR
 152 def FpSET_ST1_64 : FpI_<(outs), (ins RFP64:$src), SpecialFP, []>; // ST(1) = FPR
 153 def FpSET_ST1_80 : FpI_<(outs), (ins RFP80:$src), SpecialFP, []>; // ST(1) = FPR
 154 }
 155
 156 // FpIf32, FpIf64 - Floating Point Pseudo Instruction template.
 157 // f32 instructions can use SSE1 and are predicated on FPStackf32 == !SSE1.
 158 // f64 instructions can use SSE2 and are predicated on FPStackf64 == !SSE2.
 159 // f80 instructions cannot use SSE and use neither of these.
 160 class FpIf32<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 161   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf32]>;
 162 class FpIf64<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 163   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf64]>;
 164
 165 // Register copies.  Just copies, the shortening ones do not truncate.
 166 let neverHasSideEffects = 1 in {
 167   def MOV_Fp3232 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), SpecialFP, []>;
 168   def MOV_Fp3264 : FpIf32<(outs RFP64:$dst), (ins RFP32:$src), SpecialFP, []>;
 169   def MOV_Fp6432 : FpIf32<(outs RFP32:$dst), (ins RFP64:$src), SpecialFP, []>;
 170   def MOV_Fp6464 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), SpecialFP, []>;
 171   def MOV_Fp8032 : FpIf32<(outs RFP32:$dst), (ins RFP80:$src), SpecialFP, []>;
 172   def MOV_Fp3280 : FpIf32<(outs RFP80:$dst), (ins RFP32:$src), SpecialFP, []>;
 173   def MOV_Fp8064 : FpIf64<(outs RFP64:$dst), (ins RFP80:$src), SpecialFP, []>;
 174   def MOV_Fp6480 : FpIf64<(outs RFP80:$dst), (ins RFP64:$src), SpecialFP, []>;
 175   def MOV_Fp8080 : FpI_  <(outs RFP80:$dst), (ins RFP80:$src), SpecialFP, []>;
 176 }
 177
 178 // Factoring for arithmetic.
 179 multiclass FPBinary_rr<SDNode OpNode> {
 180 // Register op register -> register
 181 // These are separated out because they have no reversed form.
 182 def _Fp32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), TwoArgFP,
 183                 [(set RFP32:$dst, (OpNode RFP32:$src1, RFP32:$src2))]>;
 184 def _Fp64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), TwoArgFP,
 185                 [(set RFP64:$dst, (OpNode RFP64:$src1, RFP64:$src2))]>;
 186 def _Fp80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2), TwoArgFP,
 187                 [(set RFP80:$dst, (OpNode RFP80:$src1, RFP80:$src2))]>;
 188 }
 189 // The FopST0 series are not included here because of the irregularities
 190 // in where the 'r' goes in assembly output.
 191 // These instructions cannot address 80-bit memory.
 192 multiclass FPBinary<SDNode OpNode, Format fp, string asmstring> {
 193 // ST(0) = ST(0) + [mem]
 194 def _Fp32m  : FpIf32<(outs RFP32:$dst),
 195                      (ins RFP32:$src1, f32mem:$src2), OneArgFPRW,
 196                   [(set RFP32:$dst,
 197                     (OpNode RFP32:$src1, (loadf32 addr:$src2)))]>;
 198 def _Fp64m  : FpIf64<(outs RFP64:$dst),
 199                      (ins RFP64:$src1, f64mem:$src2), OneArgFPRW,
 200                   [(set RFP64:$dst,
 201                     (OpNode RFP64:$src1, (loadf64 addr:$src2)))]>;
 202 def _Fp64m32: FpIf64<(outs RFP64:$dst),
 203                      (ins RFP64:$src1, f32mem:$src2), OneArgFPRW,
 204                   [(set RFP64:$dst,
 205                     (OpNode RFP64:$src1, (f64 (extloadf32 addr:$src2))))]>;
 206 def _Fp80m32: FpI_<(outs RFP80:$dst),
 207                    (ins RFP80:$src1, f32mem:$src2), OneArgFPRW,
 208                   [(set RFP80:$dst,
 209                     (OpNode RFP80:$src1, (f80 (extloadf32 addr:$src2))))]>;
 210 def _Fp80m64: FpI_<(outs RFP80:$dst),
 211                    (ins RFP80:$src1, f64mem:$src2), OneArgFPRW,
 212                   [(set RFP80:$dst,
 213                     (OpNode RFP80:$src1, (f80 (extloadf64 addr:$src2))))]>;
 214 def _F32m  : FPI<0xD8, fp, (outs), (ins f32mem:$src),
 215                  !strconcat("f", !strconcat(asmstring, "{s}\t$src"))> {
 216   let mayLoad = 1;
 217 }
 218 def _F64m  : FPI<0xDC, fp, (outs), (ins f64mem:$src),
 219                  !strconcat("f", !strconcat(asmstring, "{l}\t$src"))> {
 220   let mayLoad = 1;
 221 }
 222 // ST(0) = ST(0) + [memint]
 223 def _FpI16m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i16mem:$src2),
 224                        OneArgFPRW,
 225                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 226                                        (X86fild addr:$src2, i16)))]>;
 227 def _FpI32m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i32mem:$src2),
 228                        OneArgFPRW,
 229                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 230                                        (X86fild addr:$src2, i32)))]>;
 231 def _FpI16m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i16mem:$src2),
 232                        OneArgFPRW,
 233                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 234                                        (X86fild addr:$src2, i16)))]>;
 235 def _FpI32m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i32mem:$src2),
 236                        OneArgFPRW,
 237                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 238                                        (X86fild addr:$src2, i32)))]>;
 239 def _FpI16m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i16mem:$src2),
 240                        OneArgFPRW,
 241                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 242                                        (X86fild addr:$src2, i16)))]>;
 243 def _FpI32m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i32mem:$src2),
 244                        OneArgFPRW,
 245                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 246                                        (X86fild addr:$src2, i32)))]>;
 247 def _FI16m  : FPI<0xDE, fp, (outs), (ins i16mem:$src),
 248                   !strconcat("fi", !strconcat(asmstring, "{s}\t$src"))> {
 249   let mayLoad = 1;
 250 }
 251 def _FI32m  : FPI<0xDA, fp, (outs), (ins i32mem:$src),
 252                   !strconcat("fi", !strconcat(asmstring, "{l}\t$src"))> {
 253   let mayLoad = 1;
 254 }
 255 }
 256
 257 defm ADD : FPBinary_rr<fadd>;
 258 defm SUB : FPBinary_rr<fsub>;
 259 defm MUL : FPBinary_rr<fmul>;
 260 defm DIV : FPBinary_rr<fdiv>;
 261 defm ADD : FPBinary<fadd, MRM0m, "add">;
 262 defm SUB : FPBinary<fsub, MRM4m, "sub">;
 263 defm SUBR: FPBinary<fsub ,MRM5m, "subr">;
 264 defm MUL : FPBinary<fmul, MRM1m, "mul">;
 265 defm DIV : FPBinary<fdiv, MRM6m, "div">;
 266 defm DIVR: FPBinary<fdiv, MRM7m, "divr">;
 267
 268 class FPST0rInst<bits<8> o, string asm>
 269   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, D8;
 270 class FPrST0Inst<bits<8> o, string asm>
 271   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DC;
 272 class FPrST0PInst<bits<8> o, string asm>
 273   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DE;
 274
 275 // NOTE: GAS and apparently all other AT&T style assemblers have a broken notion
 276 // of some of the 'reverse' forms of the fsub and fdiv instructions.  As such,
 277 // we have to put some 'r's in and take them out of weird places.
 278 def ADD_FST0r   : FPST0rInst <0xC0, "fadd\t$op">;
 279 def ADD_FrST0   : FPrST0Inst <0xC0, "fadd\t{%st(0), $op|$op, %ST(0)}">;
 280 def ADD_FPrST0  : FPrST0PInst<0xC0, "faddp\t$op">;
 281 def SUBR_FST0r  : FPST0rInst <0xE8, "fsubr\t$op">;
 282 def SUB_FrST0   : FPrST0Inst <0xE8, "fsub{r}\t{%st(0), $op|$op, %ST(0)}">;
 283 def SUB_FPrST0  : FPrST0PInst<0xE8, "fsub{r}p\t$op">;
 284 def SUB_FST0r   : FPST0rInst <0xE0, "fsub\t$op">;
 285 def SUBR_FrST0  : FPrST0Inst <0xE0, "fsub{|r}\t{%st(0), $op|$op, %ST(0)}">;
 286 def SUBR_FPrST0 : FPrST0PInst<0xE0, "fsub{|r}p\t$op">;
 287 def MUL_FST0r   : FPST0rInst <0xC8, "fmul\t$op">;
 288 def MUL_FrST0   : FPrST0Inst <0xC8, "fmul\t{%st(0), $op|$op, %ST(0)}">;
 289 def MUL_FPrST0  : FPrST0PInst<0xC8, "fmulp\t$op">;
 290 def DIVR_FST0r  : FPST0rInst <0xF8, "fdivr\t$op">;
 291 def DIV_FrST0   : FPrST0Inst <0xF8, "fdiv{r}\t{%st(0), $op|$op, %ST(0)}">;
 292 def DIV_FPrST0  : FPrST0PInst<0xF8, "fdiv{r}p\t$op">;
 293 def DIV_FST0r   : FPST0rInst <0xF0, "fdiv\t$op">;
 294 def DIVR_FrST0  : FPrST0Inst <0xF0, "fdiv{|r}\t{%st(0), $op|$op, %ST(0)}">;
 295 def DIVR_FPrST0 : FPrST0PInst<0xF0, "fdiv{|r}p\t$op">;
 296
 297 def COM_FST0r   : FPST0rInst <0xD0, "fcom\t$op">;
 298 def COMP_FST0r  : FPST0rInst <0xD8, "fcomp\t$op">;
 299
 300 // Unary operations.
 301 multiclass FPUnary<SDNode OpNode, bits<8> opcode, string asmstring> {
 302 def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), OneArgFPRW,
 303                  [(set RFP32:$dst, (OpNode RFP32:$src))]>;
 304 def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), OneArgFPRW,
 305                  [(set RFP64:$dst, (OpNode RFP64:$src))]>;
 306 def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src), OneArgFPRW,
 307                  [(set RFP80:$dst, (OpNode RFP80:$src))]>;
 308 def _F     : FPI<opcode, RawFrm, (outs), (ins), asmstring>, D9;
 309 }
 310
 311 defm CHS : FPUnary<fneg, 0xE0, "fchs">;
 312 defm ABS : FPUnary<fabs, 0xE1, "fabs">;
 313 defm SQRT: FPUnary<fsqrt,0xFA, "fsqrt">;
 314 defm SIN : FPUnary<fsin, 0xFE, "fsin">;
 315 defm COS : FPUnary<fcos, 0xFF, "fcos">;
 316
 317 let neverHasSideEffects = 1 in {
 318 def TST_Fp32  : FpIf32<(outs), (ins RFP32:$src), OneArgFP, []>;
 319 def TST_Fp64  : FpIf64<(outs), (ins RFP64:$src), OneArgFP, []>;
 320 def TST_Fp80  : FpI_<(outs), (ins RFP80:$src), OneArgFP, []>;
 321 }
 322 def TST_F  : FPI<0xE4, RawFrm, (outs), (ins), "ftst">, D9;
 323
 324 // Versions of FP instructions that take a single memory operand.  Added for the
 325 //   disassembler; remove as they are included with patterns elsewhere.
 326 def FCOM32m  : FPI<0xD8, MRM2m, (outs), (ins f32mem:$src), "fcom{s}\t$src">;
 327 def FCOMP32m : FPI<0xD8, MRM3m, (outs), (ins f32mem:$src), "fcomp{s}\t$src">;
 328
 329 def FLDENVm  : FPI<0xD9, MRM4m, (outs), (ins f32mem:$src), "fldenv\t$src">;
 330 def FSTENVm  : FPI<0xD9, MRM6m, (outs f32mem:$dst), (ins), "fnstenv\t$dst">;
 331
 332 def FICOM32m : FPI<0xDA, MRM2m, (outs), (ins i32mem:$src), "ficom{l}\t$src">;
 333 def FICOMP32m: FPI<0xDA, MRM3m, (outs), (ins i32mem:$src), "ficomp{l}\t$src">;
 334
 335 def FCOM64m  : FPI<0xDC, MRM2m, (outs), (ins f64mem:$src), "fcom{l}\t$src">;
 336 def FCOMP64m : FPI<0xDC, MRM3m, (outs), (ins f64mem:$src), "fcomp{l}\t$src">;
 337
 338 def FRSTORm  : FPI<0xDD, MRM4m, (outs f32mem:$dst), (ins), "frstor\t$dst">;
 339 def FSAVEm   : FPI<0xDD, MRM6m, (outs f32mem:$dst), (ins), "fnsave\t$dst">;
 340 def FNSTSWm  : FPI<0xDD, MRM7m, (outs f32mem:$dst), (ins), "fnstsw\t$dst">;
 341
 342 def FICOM16m : FPI<0xDE, MRM2m, (outs), (ins i16mem:$src), "ficom{s}\t$src">;
 343 def FICOMP16m: FPI<0xDE, MRM3m, (outs), (ins i16mem:$src), "ficomp{s}\t$src">;
 344
 345 def FBLDm    : FPI<0xDF, MRM4m, (outs), (ins f32mem:$src), "fbld\t$src">;
 346 def FBSTPm   : FPI<0xDF, MRM6m, (outs f32mem:$dst), (ins), "fbstp\t$dst">;
 347
 348 // Floating point cmovs.
 349 class FpIf32CMov<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 350   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf32, HasCMov]>;
 351 class FpIf64CMov<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 352   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf64, HasCMov]>;
 353
 354 multiclass FPCMov<PatLeaf cc> {
 355   def _Fp32  : FpIf32CMov<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2),
 356                        CondMovFP,
 357                      [(set RFP32:$dst, (X86cmov RFP32:$src1, RFP32:$src2,
 358                                         cc, EFLAGS))]>;
 359   def _Fp64  : FpIf64CMov<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2),
 360                        CondMovFP,
 361                      [(set RFP64:$dst, (X86cmov RFP64:$src1, RFP64:$src2,
 362                                         cc, EFLAGS))]>;
 363   def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2),
 364                      CondMovFP,
 365                      [(set RFP80:$dst, (X86cmov RFP80:$src1, RFP80:$src2,
 366                                         cc, EFLAGS))]>,
 367                                         Requires<[HasCMov]>;
 368 }
 369
 370 let Uses = [EFLAGS], Constraints = "$src1 = $dst" in {
 371 defm CMOVB  : FPCMov<X86_COND_B>;
 372 defm CMOVBE : FPCMov<X86_COND_BE>;
 373 defm CMOVE  : FPCMov<X86_COND_E>;
 374 defm CMOVP  : FPCMov<X86_COND_P>;
 375 defm CMOVNB : FPCMov<X86_COND_AE>;
 376 defm CMOVNBE: FPCMov<X86_COND_A>;
 377 defm CMOVNE : FPCMov<X86_COND_NE>;
 378 defm CMOVNP : FPCMov<X86_COND_NP>;
 379 } // Uses = [EFLAGS], Constraints = "$src1 = $dst"
 380
 381 let Predicates = [HasCMov] in {
 382 // These are not factored because there's no clean way to pass DA/DB.
 383 def CMOVB_F  : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 384                   "fcmovb\t{$op, %st(0)|%ST(0), $op}">, DA;
 385 def CMOVBE_F : FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 386                   "fcmovbe\t{$op, %st(0)|%ST(0), $op}">, DA;
 387 def CMOVE_F  : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 388                   "fcmove\t{$op, %st(0)|%ST(0), $op}">, DA;
 389 def CMOVP_F  : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 390                   "fcmovu\t {$op, %st(0)|%ST(0), $op}">, DA;
 391 def CMOVNB_F : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 392                   "fcmovnb\t{$op, %st(0)|%ST(0), $op}">, DB;
 393 def CMOVNBE_F: FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 394                   "fcmovnbe\t{$op, %st(0)|%ST(0), $op}">, DB;
 395 def CMOVNE_F : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 396                   "fcmovne\t{$op, %st(0)|%ST(0), $op}">, DB;
 397 def CMOVNP_F : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 398                   "fcmovnu\t{$op, %st(0)|%ST(0), $op}">, DB;
 399 } // Predicates = [HasCMov]
 400
 401 // Floating point loads & stores.
 402 let canFoldAsLoad = 1 in {
 403 def LD_Fp32m   : FpIf32<(outs RFP32:$dst), (ins f32mem:$src), ZeroArgFP,
 404                   [(set RFP32:$dst, (loadf32 addr:$src))]>;
 405 let isReMaterializable = 1 in
 406   def LD_Fp64m : FpIf64<(outs RFP64:$dst), (ins f64mem:$src), ZeroArgFP,
 407                   [(set RFP64:$dst, (loadf64 addr:$src))]>;
 408 def LD_Fp80m   : FpI_<(outs RFP80:$dst), (ins f80mem:$src), ZeroArgFP,
 409                   [(set RFP80:$dst, (loadf80 addr:$src))]>;
 410 }
 411 def LD_Fp32m64 : FpIf64<(outs RFP64:$dst), (ins f32mem:$src), ZeroArgFP,
 412                   [(set RFP64:$dst, (f64 (extloadf32 addr:$src)))]>;
 413 def LD_Fp64m80 : FpI_<(outs RFP80:$dst), (ins f64mem:$src), ZeroArgFP,
 414                   [(set RFP80:$dst, (f80 (extloadf64 addr:$src)))]>;
 415 def LD_Fp32m80 : FpI_<(outs RFP80:$dst), (ins f32mem:$src), ZeroArgFP,
 416                   [(set RFP80:$dst, (f80 (extloadf32 addr:$src)))]>;
 417 def ILD_Fp16m32: FpIf32<(outs RFP32:$dst), (ins i16mem:$src), ZeroArgFP,
 418                   [(set RFP32:$dst, (X86fild addr:$src, i16))]>;
 419 def ILD_Fp32m32: FpIf32<(outs RFP32:$dst), (ins i32mem:$src), ZeroArgFP,
 420                   [(set RFP32:$dst, (X86fild addr:$src, i32))]>;
 421 def ILD_Fp64m32: FpIf32<(outs RFP32:$dst), (ins i64mem:$src), ZeroArgFP,
 422                   [(set RFP32:$dst, (X86fild addr:$src, i64))]>;
 423 def ILD_Fp16m64: FpIf64<(outs RFP64:$dst), (ins i16mem:$src), ZeroArgFP,
 424                   [(set RFP64:$dst, (X86fild addr:$src, i16))]>;
 425 def ILD_Fp32m64: FpIf64<(outs RFP64:$dst), (ins i32mem:$src), ZeroArgFP,
 426                   [(set RFP64:$dst, (X86fild addr:$src, i32))]>;
 427 def ILD_Fp64m64: FpIf64<(outs RFP64:$dst), (ins i64mem:$src), ZeroArgFP,
 428                   [(set RFP64:$dst, (X86fild addr:$src, i64))]>;
 429 def ILD_Fp16m80: FpI_<(outs RFP80:$dst), (ins i16mem:$src), ZeroArgFP,
 430                   [(set RFP80:$dst, (X86fild addr:$src, i16))]>;
 431 def ILD_Fp32m80: FpI_<(outs RFP80:$dst), (ins i32mem:$src), ZeroArgFP,
 432                   [(set RFP80:$dst, (X86fild addr:$src, i32))]>;
 433 def ILD_Fp64m80: FpI_<(outs RFP80:$dst), (ins i64mem:$src), ZeroArgFP,
 434                   [(set RFP80:$dst, (X86fild addr:$src, i64))]>;
 435
 436 def ST_Fp32m   : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP,
 437                   [(store RFP32:$src, addr:$op)]>;
 438 def ST_Fp64m32 : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP,
 439                   [(truncstoref32 RFP64:$src, addr:$op)]>;
 440 def ST_Fp64m   : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP,
 441                   [(store RFP64:$src, addr:$op)]>;
 442 def ST_Fp80m32 : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP,
 443                   [(truncstoref32 RFP80:$src, addr:$op)]>;
 444 def ST_Fp80m64 : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP,
 445                   [(truncstoref64 RFP80:$src, addr:$op)]>;
 446 // FST does not support 80-bit memory target; FSTP must be used.
 447
 448 let mayStore = 1, neverHasSideEffects = 1 in {
 449 def ST_FpP32m    : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP, []>;
 450 def ST_FpP64m32  : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP, []>;
 451 def ST_FpP64m    : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP, []>;
 452 def ST_FpP80m32  : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP, []>;
 453 def ST_FpP80m64  : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP, []>;
 454 }
 455 def ST_FpP80m    : FpI_<(outs), (ins f80mem:$op, RFP80:$src), OneArgFP,
 456                     [(store RFP80:$src, addr:$op)]>;
 457 let mayStore = 1, neverHasSideEffects = 1 in {
 458 def IST_Fp16m32  : FpIf32<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP, []>;
 459 def IST_Fp32m32  : FpIf32<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP, []>;
 460 def IST_Fp64m32  : FpIf32<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP, []>;
 461 def IST_Fp16m64  : FpIf64<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP, []>;
 462 def IST_Fp32m64  : FpIf64<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP, []>;
 463 def IST_Fp64m64  : FpIf64<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP, []>;
 464 def IST_Fp16m80  : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP, []>;
 465 def IST_Fp32m80  : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP, []>;
 466 def IST_Fp64m80  : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP, []>;
 467 }
 468
 469 let mayLoad = 1 in {
 470 def LD_F32m   : FPI<0xD9, MRM0m, (outs), (ins f32mem:$src), "fld{s}\t$src">;
 471 def LD_F64m   : FPI<0xDD, MRM0m, (outs), (ins f64mem:$src), "fld{l}\t$src">;
 472 def LD_F80m   : FPI<0xDB, MRM5m, (outs), (ins f80mem:$src), "fld{t}\t$src">;
 473 def ILD_F16m  : FPI<0xDF, MRM0m, (outs), (ins i16mem:$src), "fild{s}\t$src">;
 474 def ILD_F32m  : FPI<0xDB, MRM0m, (outs), (ins i32mem:$src), "fild{l}\t$src">;
 475 def ILD_F64m  : FPI<0xDF, MRM5m, (outs), (ins i64mem:$src), "fild{ll}\t$src">;
 476 }
 477 let mayStore = 1 in {
 478 def ST_F32m   : FPI<0xD9, MRM2m, (outs), (ins f32mem:$dst), "fst{s}\t$dst">;
 479 def ST_F64m   : FPI<0xDD, MRM2m, (outs), (ins f64mem:$dst), "fst{l}\t$dst">;
 480 def ST_FP32m  : FPI<0xD9, MRM3m, (outs), (ins f32mem:$dst), "fstp{s}\t$dst">;
 481 def ST_FP64m  : FPI<0xDD, MRM3m, (outs), (ins f64mem:$dst), "fstp{l}\t$dst">;
 482 def ST_FP80m  : FPI<0xDB, MRM7m, (outs), (ins f80mem:$dst), "fstp{t}\t$dst">;
 483 def IST_F16m  : FPI<0xDF, MRM2m, (outs), (ins i16mem:$dst), "fist{s}\t$dst">;
 484 def IST_F32m  : FPI<0xDB, MRM2m, (outs), (ins i32mem:$dst), "fist{l}\t$dst">;
 485 def IST_FP16m : FPI<0xDF, MRM3m, (outs), (ins i16mem:$dst), "fistp{s}\t$dst">;
 486 def IST_FP32m : FPI<0xDB, MRM3m, (outs), (ins i32mem:$dst), "fistp{l}\t$dst">;
 487 def IST_FP64m : FPI<0xDF, MRM7m, (outs), (ins i64mem:$dst), "fistp{ll}\t$dst">;
 488 }
 489
 490 // FISTTP requires SSE3 even though it's a FPStack op.
 491 def ISTT_Fp16m32 : FpI_<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP,
 492                     [(X86fp_to_i16mem RFP32:$src, addr:$op)]>,
 493                     Requires<[HasSSE3]>;
 494 def ISTT_Fp32m32 : FpI_<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP,
 495                     [(X86fp_to_i32mem RFP32:$src, addr:$op)]>,
 496                     Requires<[HasSSE3]>;
 497 def ISTT_Fp64m32 : FpI_<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP,
 498                     [(X86fp_to_i64mem RFP32:$src, addr:$op)]>,
 499                     Requires<[HasSSE3]>;
 500 def ISTT_Fp16m64 : FpI_<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP,
 501                     [(X86fp_to_i16mem RFP64:$src, addr:$op)]>,
 502                     Requires<[HasSSE3]>;
 503 def ISTT_Fp32m64 : FpI_<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP,
 504                     [(X86fp_to_i32mem RFP64:$src, addr:$op)]>,
 505                     Requires<[HasSSE3]>;
 506 def ISTT_Fp64m64 : FpI_<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP,
 507                     [(X86fp_to_i64mem RFP64:$src, addr:$op)]>,
 508                     Requires<[HasSSE3]>;
 509 def ISTT_Fp16m80 : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP,
 510                     [(X86fp_to_i16mem RFP80:$src, addr:$op)]>,
 511                     Requires<[HasSSE3]>;
 512 def ISTT_Fp32m80 : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP,
 513                     [(X86fp_to_i32mem RFP80:$src, addr:$op)]>,
 514                     Requires<[HasSSE3]>;
 515 def ISTT_Fp64m80 : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP,
 516                     [(X86fp_to_i64mem RFP80:$src, addr:$op)]>,
 517                     Requires<[HasSSE3]>;
 518
 519 let mayStore = 1 in {
 520 def ISTT_FP16m : FPI<0xDF, MRM1m, (outs), (ins i16mem:$dst), "fisttp{s}\t$dst">;
 521 def ISTT_FP32m : FPI<0xDB, MRM1m, (outs), (ins i32mem:$dst), "fisttp{l}\t$dst">;
 522 def ISTT_FP64m : FPI<0xDD, MRM1m, (outs), (ins i64mem:$dst),
 523   "fisttp{ll}\t$dst">;
 524 }
 525
 526 // FP Stack manipulation instructions.
 527 def LD_Frr   : FPI<0xC0, AddRegFrm, (outs), (ins RST:$op), "fld\t$op">, D9;
 528 def ST_Frr   : FPI<0xD0, AddRegFrm, (outs), (ins RST:$op), "fst\t$op">, DD;
 529 def ST_FPrr  : FPI<0xD8, AddRegFrm, (outs), (ins RST:$op), "fstp\t$op">, DD;
 530 def XCH_F    : FPI<0xC8, AddRegFrm, (outs), (ins RST:$op), "fxch\t$op">, D9;
 531
 532 // Floating point constant loads.
 533 let isReMaterializable = 1 in {
 534 def LD_Fp032 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 535                 [(set RFP32:$dst, fpimm0)]>;
 536 def LD_Fp132 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 537                 [(set RFP32:$dst, fpimm1)]>;
 538 def LD_Fp064 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 539                 [(set RFP64:$dst, fpimm0)]>;
 540 def LD_Fp164 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 541                 [(set RFP64:$dst, fpimm1)]>;
 542 def LD_Fp080 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 543                 [(set RFP80:$dst, fpimm0)]>;
 544 def LD_Fp180 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 545                 [(set RFP80:$dst, fpimm1)]>;
 546 }
 547
 548 def LD_F0 : FPI<0xEE, RawFrm, (outs), (ins), "fldz">, D9;
 549 def LD_F1 : FPI<0xE8, RawFrm, (outs), (ins), "fld1">, D9;
 550
 551
 552 // Floating point compares.
 553 let Defs = [EFLAGS] in {
 554 def UCOM_Fpr32 : FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 555                         []>;  // FPSW = cmp ST(0) with ST(i)
 556 def UCOM_Fpr64 : FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 557                         []>;  // FPSW = cmp ST(0) with ST(i)
 558 def UCOM_Fpr80 : FpI_  <(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 559                         []>;  // FPSW = cmp ST(0) with ST(i)
 560
 561 // CC = ST(0) cmp ST(i)
 562 def UCOM_FpIr32: FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 563                   [(set EFLAGS, (X86cmp RFP32:$lhs, RFP32:$rhs))]>;
 564 def UCOM_FpIr64: FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 565                   [(set EFLAGS, (X86cmp RFP64:$lhs, RFP64:$rhs))]>;
 566 def UCOM_FpIr80: FpI_<(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 567                   [(set EFLAGS, (X86cmp RFP80:$lhs, RFP80:$rhs))]>;
 568 }
 569
 570 let Defs = [EFLAGS], Uses = [ST0] in {
 571 def UCOM_Fr    : FPI<0xE0, AddRegFrm,    // FPSW = cmp ST(0) with ST(i)
 572                     (outs), (ins RST:$reg),
 573                     "fucom\t$reg">, DD;
 574 def UCOM_FPr   : FPI<0xE8, AddRegFrm,    // FPSW = cmp ST(0) with ST(i), pop
 575                     (outs), (ins RST:$reg),
 576                     "fucomp\t$reg">, DD;
 577 def UCOM_FPPr  : FPI<0xE9, RawFrm,       // cmp ST(0) with ST(1), pop, pop
 578                     (outs), (ins),
 579                     "fucompp">, DA;
 580
 581 def UCOM_FIr   : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i)
 582                     (outs), (ins RST:$reg),
 583                     "fucomi\t{$reg, %st(0)|%ST(0), $reg}">, DB;
 584 def UCOM_FIPr  : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i), pop
 585                     (outs), (ins RST:$reg),
 586                     "fucomip\t{$reg, %st(0)|%ST(0), $reg}">, DF;
 587 }
 588
 589 def COM_FIr : FPI<0xF0, AddRegFrm, (outs), (ins RST:$reg),
 590                   "fcomi\t{$reg, %st(0)|%ST(0), $reg}">, DB;
 591 def COM_FIPr : FPI<0xF0, AddRegFrm, (outs), (ins RST:$reg),
 592                    "fcomip\t{$reg, %st(0)|%ST(0), $reg}">, DF;
 593
 594 // Floating point flag ops.
 595 let Defs = [AX] in
 596 def FNSTSW8r  : I<0xE0, RawFrm,                  // AX = fp flags
 597                   (outs), (ins), "fnstsw %ax", []>, DF;
 598
 599 def FNSTCW16m : I<0xD9, MRM7m,                   // [mem16] = X87 control world
 600                   (outs), (ins i16mem:$dst), "fnstcw\t$dst",
 601                   [(X86fp_cwd_get16 addr:$dst)]>;
 602
 603 let mayLoad = 1 in
 604 def FLDCW16m  : I<0xD9, MRM5m,                   // X87 control world = [mem16]
 605                   (outs), (ins i16mem:$dst), "fldcw\t$dst", []>;
 606
 607 // Register free
 608
 609 def FFREE : FPI<0xC0, AddRegFrm, (outs), (ins RST:$reg),
 610                 "ffree\t$reg">, DD;
 611
 612 // Clear exceptions
 613
 614 def FNCLEX : I<0xE2, RawFrm, (outs), (ins), "fnclex", []>, DB;
 615
 616 // Operandless floating-point instructions for the disassembler
 617
 618 def FNOP : I<0xD0, RawFrm, (outs), (ins), "fnop", []>, D9;
 619 def FXAM : I<0xE5, RawFrm, (outs), (ins), "fxam", []>, D9;
 620 def FLDL2T : I<0xE9, RawFrm, (outs), (ins), "fldl2t", []>, D9;
 621 def FLDL2E : I<0xEA, RawFrm, (outs), (ins), "fldl2e", []>, D9;
 622 def FLDPI : I<0xEB, RawFrm, (outs), (ins), "fldpi", []>, D9;
 623 def FLDLG2 : I<0xEC, RawFrm, (outs), (ins), "fldlg2", []>, D9;
 624 def FLDLN2 : I<0xED, RawFrm, (outs), (ins), "fldln2", []>, D9;
 625 def F2XM1 : I<0xF0, RawFrm, (outs), (ins), "f2xm1", []>, D9;
 626 def FYL2X : I<0xF1, RawFrm, (outs), (ins), "fyl2x", []>, D9;
 627 def FPTAN : I<0xF2, RawFrm, (outs), (ins), "fptan", []>, D9;
 628 def FPATAN : I<0xF3, RawFrm, (outs), (ins), "fpatan", []>, D9;
 629 def FXTRACT : I<0xF4, RawFrm, (outs), (ins), "fxtract", []>, D9;
 630 def FPREM1 : I<0xF5, RawFrm, (outs), (ins), "fprem1", []>, D9;
 631 def FDECSTP : I<0xF6, RawFrm, (outs), (ins), "fdecstp", []>, D9;
 632 def FINCSTP : I<0xF7, RawFrm, (outs), (ins), "fincstp", []>, D9;
 633 def FPREM : I<0xF8, RawFrm, (outs), (ins), "fprem", []>, D9;
 634 def FYL2XP1 : I<0xF9, RawFrm, (outs), (ins), "fyl2xp1", []>, D9;
 635 def FSINCOS : I<0xFB, RawFrm, (outs), (ins), "fsincos", []>, D9;
 636 def FRNDINT : I<0xFC, RawFrm, (outs), (ins), "frndint", []>, D9;
 637 def FSCALE : I<0xFD, RawFrm, (outs), (ins), "fscale", []>, D9;
 638 def FCOMPP : I<0xD9, RawFrm, (outs), (ins), "fcompp", []>, DE;
 639
 640 def FXSAVE : I<0xAE, MRM0m, (outs opaque512mem:$dst), (ins),
 641                "fxsave\t$dst", []>, TB;
 642 def FXRSTOR : I<0xAE, MRM1m, (outs), (ins opaque512mem:$src),
 643                 "fxrstor\t$src", []>, TB;
 644
 645 //===----------------------------------------------------------------------===//
 646 // Non-Instruction Patterns
 647 //===----------------------------------------------------------------------===//
 648
 649 // Required for RET of f32 / f64 / f80 values.
 650 def : Pat<(X86fld addr:$src, f32), (LD_Fp32m addr:$src)>;
 651 def : Pat<(X86fld addr:$src, f64), (LD_Fp64m addr:$src)>;
 652 def : Pat<(X86fld addr:$src, f80), (LD_Fp80m addr:$src)>;
 653
 654 // Required for CALL which return f32 / f64 / f80 values.
 655 def : Pat<(X86fst RFP32:$src, addr:$op, f32), (ST_Fp32m addr:$op, RFP32:$src)>;
 656 def : Pat<(X86fst RFP64:$src, addr:$op, f32), (ST_Fp64m32 addr:$op,
 657                                                           RFP64:$src)>;
 658 def : Pat<(X86fst RFP64:$src, addr:$op, f64), (ST_Fp64m addr:$op, RFP64:$src)>;
 659 def : Pat<(X86fst RFP80:$src, addr:$op, f32), (ST_Fp80m32 addr:$op,
 660                                                           RFP80:$src)>;
 661 def : Pat<(X86fst RFP80:$src, addr:$op, f64), (ST_Fp80m64 addr:$op,
 662                                                           RFP80:$src)>;
 663 def : Pat<(X86fst RFP80:$src, addr:$op, f80), (ST_FpP80m addr:$op,
 664                                                          RFP80:$src)>;
 665
 666 // Floating point constant -0.0 and -1.0
 667 def : Pat<(f32 fpimmneg0), (CHS_Fp32 (LD_Fp032))>, Requires<[FPStackf32]>;
 668 def : Pat<(f32 fpimmneg1), (CHS_Fp32 (LD_Fp132))>, Requires<[FPStackf32]>;
 669 def : Pat<(f64 fpimmneg0), (CHS_Fp64 (LD_Fp064))>, Requires<[FPStackf64]>;
 670 def : Pat<(f64 fpimmneg1), (CHS_Fp64 (LD_Fp164))>, Requires<[FPStackf64]>;
 671 def : Pat<(f80 fpimmneg0), (CHS_Fp80 (LD_Fp080))>;
 672 def : Pat<(f80 fpimmneg1), (CHS_Fp80 (LD_Fp180))>;
 673
 674 // Used to conv. i64 to f64 since there isn't a SSE version.
 675 def : Pat<(X86fildflag addr:$src, i64), (ILD_Fp64m64 addr:$src)>;
 676
 677 // FP extensions map onto simple pseudo-value conversions if they are to/from
 678 // the FP stack.
 679 def : Pat<(f64 (fextend RFP32:$src)), (COPY_TO_REGCLASS RFP32:$src, RFP64)>,
 680           Requires<[FPStackf32]>;
 681 def : Pat<(f80 (fextend RFP32:$src)), (COPY_TO_REGCLASS RFP32:$src, RFP80)>,
 682            Requires<[FPStackf32]>;
 683 def : Pat<(f80 (fextend RFP64:$src)), (COPY_TO_REGCLASS RFP64:$src, RFP80)>,
 684            Requires<[FPStackf64]>;
 685
 686 // FP truncations map onto simple pseudo-value conversions if they are to/from
 687 // the FP stack.  We have validated that only value-preserving truncations make
 688 // it through isel.
 689 def : Pat<(f32 (fround RFP64:$src)), (COPY_TO_REGCLASS RFP64:$src, RFP32)>,
 690           Requires<[FPStackf32]>;
 691 def : Pat<(f32 (fround RFP80:$src)), (COPY_TO_REGCLASS RFP80:$src, RFP32)>,
 692            Requires<[FPStackf32]>;
 693 def : Pat<(f64 (fround RFP80:$src)), (COPY_TO_REGCLASS RFP80:$src, RFP64)>,
 694            Requires<[FPStackf64]>;