lib/Target/X86/X86InstrFMA.td

   1 //===-- X86InstrFMA.td - FMA Instruction Set ---------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes FMA (Fused Multiply-Add) instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // FMA3 - Intel 3 operand Fused Multiply-Add instructions
  16 //===----------------------------------------------------------------------===//
  17
  18 let Constraints = "$src1 = $dst" in {
  19 multiclass fma3p_rm<bits<8> opc, string OpcodeStr,
  20                     PatFrag MemFrag128, PatFrag MemFrag256,
  21                     ValueType OpVT128, ValueType OpVT256,
  22                     SDPatternOperator Op = null_frag> {
  23   let isCommutable = 1 in
  24   def r     : FMA3<opc, MRMSrcReg, (outs VR128:$dst),
  25                    (ins VR128:$src1, VR128:$src2, VR128:$src3),
  26                    !strconcat(OpcodeStr,
  27                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
  28                    [(set VR128:$dst, (OpVT128 (Op VR128:$src2,
  29                                                VR128:$src1, VR128:$src3)))]>;
  30
  31   let mayLoad = 1 in
  32   def m     : FMA3<opc, MRMSrcMem, (outs VR128:$dst),
  33                    (ins VR128:$src1, VR128:$src2, f128mem:$src3),
  34                    !strconcat(OpcodeStr,
  35                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
  36                    [(set VR128:$dst, (OpVT128 (Op VR128:$src2, VR128:$src1,
  37                                                (MemFrag128 addr:$src3))))]>;
  38
  39   let isCommutable = 1 in
  40   def rY    : FMA3<opc, MRMSrcReg, (outs VR256:$dst),
  41                    (ins VR256:$src1, VR256:$src2, VR256:$src3),
  42                    !strconcat(OpcodeStr,
  43                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
  44                    [(set VR256:$dst, (OpVT256 (Op VR256:$src2, VR256:$src1,
  45                                                VR256:$src3)))]>, VEX_L;
  46
  47   let mayLoad = 1 in
  48   def mY    : FMA3<opc, MRMSrcMem, (outs VR256:$dst),
  49                    (ins VR256:$src1, VR256:$src2, f256mem:$src3),
  50                    !strconcat(OpcodeStr,
  51                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
  52                    [(set VR256:$dst,
  53                      (OpVT256 (Op VR256:$src2, VR256:$src1,
  54                                (MemFrag256 addr:$src3))))]>, VEX_L;
  55 }
  56 } // Constraints = "$src1 = $dst"
  57
  58 multiclass fma3p_forms<bits<8> opc132, bits<8> opc213, bits<8> opc231,
  59                        string OpcodeStr, string PackTy,
  60                        PatFrag MemFrag128, PatFrag MemFrag256,
  61                        SDNode Op, ValueType OpTy128, ValueType OpTy256> {
  62   defm r213 : fma3p_rm<opc213,
  63                        !strconcat(OpcodeStr, "213", PackTy),
  64                        MemFrag128, MemFrag256, OpTy128, OpTy256, Op>;
  65 let neverHasSideEffects = 1 in {
  66   defm r132 : fma3p_rm<opc132,
  67                        !strconcat(OpcodeStr, "132", PackTy),
  68                        MemFrag128, MemFrag256, OpTy128, OpTy256>;
  69   defm r231 : fma3p_rm<opc231,
  70                        !strconcat(OpcodeStr, "231", PackTy),
  71                        MemFrag128, MemFrag256, OpTy128, OpTy256>;
  72 } // neverHasSideEffects = 1
  73 }
  74
  75 // Fused Multiply-Add
  76 let ExeDomain = SSEPackedSingle in {
  77   defm VFMADDPS    : fma3p_forms<0x98, 0xA8, 0xB8, "vfmadd", "ps", loadv4f32,
  78                                  loadv8f32, X86Fmadd, v4f32, v8f32>;
  79   defm VFMSUBPS    : fma3p_forms<0x9A, 0xAA, 0xBA, "vfmsub", "ps", loadv4f32,
  80                                  loadv8f32, X86Fmsub, v4f32, v8f32>;
  81   defm VFMADDSUBPS : fma3p_forms<0x96, 0xA6, 0xB6, "vfmaddsub", "ps",
  82                                  loadv4f32, loadv8f32, X86Fmaddsub,
  83                                  v4f32, v8f32>;
  84   defm VFMSUBADDPS : fma3p_forms<0x97, 0xA7, 0xB7, "vfmsubadd", "ps",
  85                                  loadv4f32, loadv8f32, X86Fmsubadd,
  86                                  v4f32, v8f32>;
  87 }
  88
  89 let ExeDomain = SSEPackedDouble in {
  90   defm VFMADDPD    : fma3p_forms<0x98, 0xA8, 0xB8, "vfmadd", "pd", loadv2f64,
  91                                  loadv4f64, X86Fmadd, v2f64, v4f64>, VEX_W;
  92   defm VFMSUBPD    : fma3p_forms<0x9A, 0xAA, 0xBA, "vfmsub", "pd", loadv2f64,
  93                                  loadv4f64, X86Fmsub, v2f64, v4f64>, VEX_W;
  94   defm VFMADDSUBPD : fma3p_forms<0x96, 0xA6, 0xB6, "vfmaddsub", "pd",
  95                                  loadv2f64, loadv4f64, X86Fmaddsub,
  96                                  v2f64, v4f64>, VEX_W;
  97   defm VFMSUBADDPD : fma3p_forms<0x97, 0xA7, 0xB7, "vfmsubadd", "pd",
  98                                  loadv2f64, loadv4f64, X86Fmsubadd,
  99                                  v2f64, v4f64>, VEX_W;
 100 }
 101
 102 // Fused Negative Multiply-Add
 103 let ExeDomain = SSEPackedSingle in {
 104   defm VFNMADDPS : fma3p_forms<0x9C, 0xAC, 0xBC, "vfnmadd", "ps",  loadv4f32,
 105                                loadv8f32, X86Fnmadd, v4f32, v8f32>;
 106   defm VFNMSUBPS : fma3p_forms<0x9E, 0xAE, 0xBE, "vfnmsub", "ps",  loadv4f32,
 107                                loadv8f32, X86Fnmsub, v4f32, v8f32>;
 108 }
 109 let ExeDomain = SSEPackedDouble in {
 110   defm VFNMADDPD : fma3p_forms<0x9C, 0xAC, 0xBC, "vfnmadd", "pd", loadv2f64,
 111                                loadv4f64, X86Fnmadd, v2f64, v4f64>, VEX_W;
 112   defm VFNMSUBPD : fma3p_forms<0x9E, 0xAE, 0xBE, "vfnmsub", "pd",
 113                                loadv2f64, loadv4f64, X86Fnmsub, v2f64,
 114                                v4f64>, VEX_W;
 115 }
 116
 117 let Constraints = "$src1 = $dst" in {
 118 multiclass fma3s_rm<bits<8> opc, string OpcodeStr, X86MemOperand x86memop,
 119                     RegisterClass RC, ValueType OpVT, PatFrag mem_frag,
 120                     SDPatternOperator OpNode = null_frag> {
 121   let isCommutable = 1 in
 122   def r     : FMA3<opc, MRMSrcReg, (outs RC:$dst),
 123                    (ins RC:$src1, RC:$src2, RC:$src3),
 124                    !strconcat(OpcodeStr,
 125                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
 126                    [(set RC:$dst,
 127                      (OpVT (OpNode RC:$src2, RC:$src1, RC:$src3)))]>;
 128   let mayLoad = 1 in
 129   def m     : FMA3<opc, MRMSrcMem, (outs RC:$dst),
 130                    (ins RC:$src1, RC:$src2, x86memop:$src3),
 131                    !strconcat(OpcodeStr,
 132                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
 133                    [(set RC:$dst,
 134                      (OpVT (OpNode RC:$src2, RC:$src1,
 135                             (mem_frag addr:$src3))))]>;
 136 }
 137
 138 multiclass fma3s_rm_int<bits<8> opc, string OpcodeStr, Operand memop,
 139                         ComplexPattern mem_cpat, Intrinsic IntId,
 140                         RegisterClass RC> {
 141   let isCodeGenOnly = 1 in {
 142     let isCommutable = 1 in
 143     def r_Int : FMA3<opc, MRMSrcReg, (outs VR128:$dst),
 144                      (ins VR128:$src1, VR128:$src2, VR128:$src3),
 145                      !strconcat(OpcodeStr,
 146                                 "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
 147                      [(set VR128:$dst, (IntId VR128:$src2, VR128:$src1,
 148                        VR128:$src3))]>;
 149     def m_Int : FMA3<opc, MRMSrcMem, (outs VR128:$dst),
 150                      (ins VR128:$src1, VR128:$src2, memop:$src3),
 151                      !strconcat(OpcodeStr,
 152                                 "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
 153                      [(set VR128:$dst,
 154                        (IntId VR128:$src2, VR128:$src1, mem_cpat:$src3))]>;
 155   } // isCodeGenOnly
 156 }
 157 } // Constraints = "$src1 = $dst"
 158
 159 multiclass fma3s_forms<bits<8> opc132, bits<8> opc213, bits<8> opc231,
 160                        string OpStr, string PackTy, Intrinsic Int,
 161                        SDNode OpNode, RegisterClass RC, ValueType OpVT,
 162                        X86MemOperand x86memop, Operand memop, PatFrag mem_frag,
 163                        ComplexPattern mem_cpat> {
 164 let neverHasSideEffects = 1 in {
 165   defm r132 : fma3s_rm<opc132, !strconcat(OpStr, "132", PackTy),
 166                        x86memop, RC, OpVT, mem_frag>;
 167   defm r231 : fma3s_rm<opc231, !strconcat(OpStr, "231", PackTy),
 168                        x86memop, RC, OpVT, mem_frag>;
 169 }
 170
 171 defm r213 : fma3s_rm<opc213, !strconcat(OpStr, "213", PackTy),
 172                      x86memop, RC, OpVT, mem_frag, OpNode>,
 173             fma3s_rm_int<opc213, !strconcat(OpStr, "213", PackTy),
 174                          memop, mem_cpat, Int, RC>;
 175 }
 176
 177 multiclass fma3s<bits<8> opc132, bits<8> opc213, bits<8> opc231,
 178                  string OpStr, Intrinsic IntF32, Intrinsic IntF64,
 179                  SDNode OpNode> {
 180   defm SS : fma3s_forms<opc132, opc213, opc231, OpStr, "ss", IntF32, OpNode,
 181                         FR32, f32, f32mem, ssmem, loadf32, sse_load_f32>;
 182   defm SD : fma3s_forms<opc132, opc213, opc231, OpStr, "sd", IntF64, OpNode,
 183                         FR64, f64, f64mem, sdmem, loadf64, sse_load_f64>, VEX_W;
 184 }
 185
 186 defm VFMADD : fma3s<0x99, 0xA9, 0xB9, "vfmadd", int_x86_fma_vfmadd_ss,
 187                     int_x86_fma_vfmadd_sd, X86Fmadd>, VEX_LIG;
 188 defm VFMSUB : fma3s<0x9B, 0xAB, 0xBB, "vfmsub", int_x86_fma_vfmsub_ss,
 189                     int_x86_fma_vfmsub_sd, X86Fmsub>, VEX_LIG;
 190
 191 defm VFNMADD : fma3s<0x9D, 0xAD, 0xBD, "vfnmadd", int_x86_fma_vfnmadd_ss,
 192                      int_x86_fma_vfnmadd_sd, X86Fnmadd>, VEX_LIG;
 193 defm VFNMSUB : fma3s<0x9F, 0xAF, 0xBF, "vfnmsub", int_x86_fma_vfnmsub_ss,
 194                      int_x86_fma_vfnmsub_sd, X86Fnmsub>, VEX_LIG;
 195
 196
 197 //===----------------------------------------------------------------------===//
 198 // FMA4 - AMD 4 operand Fused Multiply-Add instructions
 199 //===----------------------------------------------------------------------===//
 200
 201
 202 multiclass fma4s<bits<8> opc, string OpcodeStr, RegisterClass RC,
 203                  X86MemOperand x86memop, ValueType OpVT, SDNode OpNode,
 204                  PatFrag mem_frag> {
 205   let isCommutable = 1 in
 206   def rr : FMA4<opc, MRMSrcReg, (outs RC:$dst),
 207            (ins RC:$src1, RC:$src2, RC:$src3),
 208            !strconcat(OpcodeStr,
 209            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 210            [(set RC:$dst,
 211              (OpVT (OpNode RC:$src1, RC:$src2, RC:$src3)))]>, VEX_W, VEX_LIG, MemOp4;
 212   def rm : FMA4<opc, MRMSrcMem, (outs RC:$dst),
 213            (ins RC:$src1, RC:$src2, x86memop:$src3),
 214            !strconcat(OpcodeStr,
 215            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 216            [(set RC:$dst, (OpNode RC:$src1, RC:$src2,
 217                            (mem_frag addr:$src3)))]>, VEX_W, VEX_LIG, MemOp4;
 218   def mr : FMA4<opc, MRMSrcMem, (outs RC:$dst),
 219            (ins RC:$src1, x86memop:$src2, RC:$src3),
 220            !strconcat(OpcodeStr,
 221            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 222            [(set RC:$dst,
 223              (OpNode RC:$src1, (mem_frag addr:$src2), RC:$src3))]>, VEX_LIG;
 224 // For disassembler
 225 let isCodeGenOnly = 1, ForceDisassemble = 1, hasSideEffects = 0 in
 226   def rr_REV : FMA4<opc, MRMSrcReg, (outs RC:$dst),
 227                (ins RC:$src1, RC:$src2, RC:$src3),
 228                !strconcat(OpcodeStr,
 229                "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"), []>,
 230                VEX_LIG;
 231 }
 232
 233 multiclass fma4s_int<bits<8> opc, string OpcodeStr, Operand memop,
 234                      ComplexPattern mem_cpat, Intrinsic Int> {
 235 let isCodeGenOnly = 1 in {
 236   let isCommutable = 1 in
 237   def rr_Int : FMA4<opc, MRMSrcReg, (outs VR128:$dst),
 238                (ins VR128:$src1, VR128:$src2, VR128:$src3),
 239                !strconcat(OpcodeStr,
 240                "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 241                [(set VR128:$dst,
 242                  (Int VR128:$src1, VR128:$src2, VR128:$src3))]>, VEX_W, VEX_LIG, MemOp4;
 243   def rm_Int : FMA4<opc, MRMSrcMem, (outs VR128:$dst),
 244                (ins VR128:$src1, VR128:$src2, memop:$src3),
 245                !strconcat(OpcodeStr,
 246                "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 247                [(set VR128:$dst, (Int VR128:$src1, VR128:$src2,
 248                                   mem_cpat:$src3))]>, VEX_W, VEX_LIG, MemOp4;
 249   def mr_Int : FMA4<opc, MRMSrcMem, (outs VR128:$dst),
 250                (ins VR128:$src1, memop:$src2, VR128:$src3),
 251                !strconcat(OpcodeStr,
 252                "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 253                [(set VR128:$dst,
 254                  (Int VR128:$src1, mem_cpat:$src2, VR128:$src3))]>, VEX_LIG;
 255 } // isCodeGenOnly = 1
 256 }
 257
 258 multiclass fma4p<bits<8> opc, string OpcodeStr, SDNode OpNode,
 259                  ValueType OpVT128, ValueType OpVT256,
 260                  PatFrag ld_frag128, PatFrag ld_frag256> {
 261   let isCommutable = 1 in
 262   def rr : FMA4<opc, MRMSrcReg, (outs VR128:$dst),
 263            (ins VR128:$src1, VR128:$src2, VR128:$src3),
 264            !strconcat(OpcodeStr,
 265            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 266            [(set VR128:$dst,
 267              (OpVT128 (OpNode VR128:$src1, VR128:$src2, VR128:$src3)))]>,
 268            VEX_W, MemOp4;
 269   def rm : FMA4<opc, MRMSrcMem, (outs VR128:$dst),
 270            (ins VR128:$src1, VR128:$src2, f128mem:$src3),
 271            !strconcat(OpcodeStr,
 272            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 273            [(set VR128:$dst, (OpNode VR128:$src1, VR128:$src2,
 274                               (ld_frag128 addr:$src3)))]>, VEX_W, MemOp4;
 275   def mr : FMA4<opc, MRMSrcMem, (outs VR128:$dst),
 276            (ins VR128:$src1, f128mem:$src2, VR128:$src3),
 277            !strconcat(OpcodeStr,
 278            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 279            [(set VR128:$dst,
 280              (OpNode VR128:$src1, (ld_frag128 addr:$src2), VR128:$src3))]>;
 281   let isCommutable = 1 in
 282   def rrY : FMA4<opc, MRMSrcReg, (outs VR256:$dst),
 283            (ins VR256:$src1, VR256:$src2, VR256:$src3),
 284            !strconcat(OpcodeStr,
 285            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 286            [(set VR256:$dst,
 287              (OpVT256 (OpNode VR256:$src1, VR256:$src2, VR256:$src3)))]>,
 288            VEX_W, MemOp4, VEX_L;
 289   def rmY : FMA4<opc, MRMSrcMem, (outs VR256:$dst),
 290            (ins VR256:$src1, VR256:$src2, f256mem:$src3),
 291            !strconcat(OpcodeStr,
 292            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 293            [(set VR256:$dst, (OpNode VR256:$src1, VR256:$src2,
 294                               (ld_frag256 addr:$src3)))]>, VEX_W, MemOp4, VEX_L;
 295   def mrY : FMA4<opc, MRMSrcMem, (outs VR256:$dst),
 296            (ins VR256:$src1, f256mem:$src2, VR256:$src3),
 297            !strconcat(OpcodeStr,
 298            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 299            [(set VR256:$dst, (OpNode VR256:$src1,
 300                               (ld_frag256 addr:$src2), VR256:$src3))]>, VEX_L;
 301 // For disassembler
 302 let isCodeGenOnly = 1, ForceDisassemble = 1, hasSideEffects = 0 in {
 303   def rr_REV : FMA4<opc, MRMSrcReg, (outs VR128:$dst),
 304                (ins VR128:$src1, VR128:$src2, VR128:$src3),
 305                !strconcat(OpcodeStr,
 306                "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"), []>;
 307   def rrY_REV : FMA4<opc, MRMSrcReg, (outs VR256:$dst),
 308                 (ins VR256:$src1, VR256:$src2, VR256:$src3),
 309                 !strconcat(OpcodeStr,
 310                 "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"), []>,
 311                 VEX_L;
 312 } // isCodeGenOnly = 1
 313 }
 314
 315 defm VFMADDSS4  : fma4s<0x6A, "vfmaddss", FR32, f32mem, f32, X86Fmadd, loadf32>,
 316                   fma4s_int<0x6A, "vfmaddss", ssmem, sse_load_f32,
 317                             int_x86_fma_vfmadd_ss>;
 318 defm VFMADDSD4  : fma4s<0x6B, "vfmaddsd", FR64, f64mem, f64, X86Fmadd, loadf64>,
 319                   fma4s_int<0x6B, "vfmaddsd", sdmem, sse_load_f64,
 320                             int_x86_fma_vfmadd_sd>;
 321 defm VFMSUBSS4  : fma4s<0x6E, "vfmsubss", FR32, f32mem, f32, X86Fmsub, loadf32>,
 322                   fma4s_int<0x6E, "vfmsubss", ssmem, sse_load_f32,
 323                             int_x86_fma_vfmsub_ss>;
 324 defm VFMSUBSD4  : fma4s<0x6F, "vfmsubsd", FR64, f64mem, f64, X86Fmsub, loadf64>,
 325                   fma4s_int<0x6F, "vfmsubsd", sdmem, sse_load_f64,
 326                             int_x86_fma_vfmsub_sd>;
 327 defm VFNMADDSS4 : fma4s<0x7A, "vfnmaddss", FR32, f32mem, f32,
 328                         X86Fnmadd, loadf32>,
 329                   fma4s_int<0x7A, "vfnmaddss", ssmem, sse_load_f32,
 330                             int_x86_fma_vfnmadd_ss>;
 331 defm VFNMADDSD4 : fma4s<0x7B, "vfnmaddsd", FR64, f64mem, f64,
 332                         X86Fnmadd, loadf64>,
 333                   fma4s_int<0x7B, "vfnmaddsd", sdmem, sse_load_f64,
 334                             int_x86_fma_vfnmadd_sd>;
 335 defm VFNMSUBSS4 : fma4s<0x7E, "vfnmsubss", FR32, f32mem, f32,
 336                         X86Fnmsub, loadf32>,
 337                   fma4s_int<0x7E, "vfnmsubss", ssmem, sse_load_f32,
 338                             int_x86_fma_vfnmsub_ss>;
 339 defm VFNMSUBSD4 : fma4s<0x7F, "vfnmsubsd", FR64, f64mem, f64,
 340                         X86Fnmsub, loadf64>,
 341                   fma4s_int<0x7F, "vfnmsubsd", sdmem, sse_load_f64,
 342                             int_x86_fma_vfnmsub_sd>;
 343
 344 let ExeDomain = SSEPackedSingle in {
 345   defm VFMADDPS4    : fma4p<0x68, "vfmaddps", X86Fmadd, v4f32, v8f32,
 346                             loadv4f32, loadv8f32>;
 347   defm VFMSUBPS4    : fma4p<0x6C, "vfmsubps", X86Fmsub, v4f32, v8f32,
 348                             loadv4f32, loadv8f32>;
 349   defm VFNMADDPS4   : fma4p<0x78, "vfnmaddps", X86Fnmadd, v4f32, v8f32,
 350                             loadv4f32, loadv8f32>;
 351   defm VFNMSUBPS4   : fma4p<0x7C, "vfnmsubps", X86Fnmsub, v4f32, v8f32,
 352                             loadv4f32, loadv8f32>;
 353   defm VFMADDSUBPS4 : fma4p<0x5C, "vfmaddsubps", X86Fmaddsub, v4f32, v8f32,
 354                             loadv4f32, loadv8f32>;
 355   defm VFMSUBADDPS4 : fma4p<0x5E, "vfmsubaddps", X86Fmsubadd, v4f32, v8f32,
 356                             loadv4f32, loadv8f32>;
 357 }
 358
 359 let ExeDomain = SSEPackedDouble in {
 360   defm VFMADDPD4    : fma4p<0x69, "vfmaddpd", X86Fmadd, v2f64, v4f64,
 361                             loadv2f64, loadv4f64>;
 362   defm VFMSUBPD4    : fma4p<0x6D, "vfmsubpd", X86Fmsub, v2f64, v4f64,
 363                             loadv2f64, loadv4f64>;
 364   defm VFNMADDPD4   : fma4p<0x79, "vfnmaddpd", X86Fnmadd, v2f64, v4f64,
 365                             loadv2f64, loadv4f64>;
 366   defm VFNMSUBPD4   : fma4p<0x7D, "vfnmsubpd", X86Fnmsub, v2f64, v4f64,
 367                             loadv2f64, loadv4f64>;
 368   defm VFMADDSUBPD4 : fma4p<0x5D, "vfmaddsubpd", X86Fmaddsub, v2f64, v4f64,
 369                             loadv2f64, loadv4f64>;
 370   defm VFMSUBADDPD4 : fma4p<0x5F, "vfmsubaddpd", X86Fmsubadd, v2f64, v4f64,
 371                             loadv2f64, loadv4f64>;
 372 }
 373