lib/Target/X86/X86CallingConv.td

   1 //===- X86CallingConv.td - Calling Conventions X86 32/64 ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This describes the calling conventions for the X86-32 and X86-64
  11 // architectures.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  16 class CCIfSubtarget<string F, CCAction A>
  17  : CCIf<!strconcat("State.getTarget().getSubtarget<X86Subtarget>().", F), A>;
  18
  19 //===----------------------------------------------------------------------===//
  20 // Return Value Calling Conventions
  21 //===----------------------------------------------------------------------===//
  22
  23 // Return-value conventions common to all X86 CC's.
  24 def RetCC_X86Common : CallingConv<[
  25   // Scalar values are returned in AX first, then DX.  For i8, the ABI
  26   // requires the values to be in AL and AH, however this code uses AL and DL
  27   // instead. This is because using AH for the second register conflicts with
  28   // the way LLVM does multiple return values -- a return of {i16,i8} would end
  29   // up in AX and AH, which overlap. Front-ends wishing to conform to the ABI
  30   // for functions that return two i8 values are currently expected to pack the
  31   // values into an i16 (which uses AX, and thus AL:AH).
  32   CCIfType<[i8] , CCAssignToReg<[AL, DL]>>,
  33   CCIfType<[i16], CCAssignToReg<[AX, DX]>>,
  34   CCIfType<[i32], CCAssignToReg<[EAX, EDX]>>,
  35   CCIfType<[i64], CCAssignToReg<[RAX, RDX]>>,
  36
  37   // Vector types are returned in XMM0 and XMM1, when they fit.  XMM2 and XMM3
  38   // can only be used by ABI non-compliant code. If the target doesn't have XMM
  39   // registers, it won't have vector types.
  40   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
  41             CCAssignToReg<[XMM0,XMM1,XMM2,XMM3]>>,
  42
  43   // 256-bit vectors are returned in YMM0 and XMM1, when they fit. YMM2 and YMM3
  44   // can only be used by ABI non-compliant code. This vector type is only
  45   // supported while using the AVX target feature.
  46   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
  47             CCIfSubtarget<"hasAVX()", CCAssignToReg<[YMM0,YMM1,YMM2,YMM3]>>>,
  48
  49   // MMX vector types are always returned in MM0. If the target doesn't have
  50   // MM0, it doesn't support these vector types.
  51   CCIfType<[x86mmx, v1i64], CCAssignToReg<[MM0]>>,
  52
  53   // Long double types are always returned in ST0 (even with SSE).
  54   CCIfType<[f80], CCAssignToReg<[ST0, ST1]>>
  55 ]>;
  56
  57 // X86-32 C return-value convention.
  58 def RetCC_X86_32_C : CallingConv<[
  59   // The X86-32 calling convention returns FP values in ST0, unless marked
  60   // with "inreg" (used here to distinguish one kind of reg from another,
  61   // weirdly; this is really the sse-regparm calling convention) in which
  62   // case they use XMM0, otherwise it is the same as the common X86 calling
  63   // conv.
  64   CCIfInReg<CCIfSubtarget<"hasXMMInt()",
  65     CCIfType<[f32, f64], CCAssignToReg<[XMM0,XMM1,XMM2]>>>>,
  66   CCIfType<[f32,f64], CCAssignToReg<[ST0, ST1]>>,
  67   CCDelegateTo<RetCC_X86Common>
  68 ]>;
  69
  70 // X86-32 FastCC return-value convention.
  71 def RetCC_X86_32_Fast : CallingConv<[
  72   // The X86-32 fastcc returns 1, 2, or 3 FP values in XMM0-2 if the target has
  73   // SSE2.
  74   // This can happen when a float, 2 x float, or 3 x float vector is split by
  75   // target lowering, and is returned in 1-3 sse regs.
  76   CCIfType<[f32], CCIfSubtarget<"hasXMMInt()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  77   CCIfType<[f64], CCIfSubtarget<"hasXMMInt()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  78
  79   // For integers, ECX can be used as an extra return register
  80   CCIfType<[i8],  CCAssignToReg<[AL, DL, CL]>>,
  81   CCIfType<[i16], CCAssignToReg<[AX, DX, CX]>>,
  82   CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>,
  83
  84   // Otherwise, it is the same as the common X86 calling convention.
  85   CCDelegateTo<RetCC_X86Common>
  86 ]>;
  87
  88 // X86-64 C return-value convention.
  89 def RetCC_X86_64_C : CallingConv<[
  90   // The X86-64 calling convention always returns FP values in XMM0.
  91   CCIfType<[f32], CCAssignToReg<[XMM0, XMM1]>>,
  92   CCIfType<[f64], CCAssignToReg<[XMM0, XMM1]>>,
  93
  94   // MMX vector types are always returned in XMM0 except for v1i64 which is
  95   // returned in RAX. This disagrees with ABI documentation but is bug
  96   // compatible with gcc.
  97   CCIfType<[v1i64], CCAssignToReg<[RAX]>>,
  98   CCIfType<[x86mmx], CCAssignToReg<[XMM0, XMM1]>>,
  99   CCDelegateTo<RetCC_X86Common>
 100 ]>;
 101
 102 // X86-Win64 C return-value convention.
 103 def RetCC_X86_Win64_C : CallingConv<[
 104   // The X86-Win64 calling convention always returns __m64 values in RAX.
 105   CCIfType<[x86mmx, v1i64], CCBitConvertToType<i64>>,
 106
 107   // And FP in XMM0 only.
 108   CCIfType<[f32], CCAssignToReg<[XMM0]>>,
 109   CCIfType<[f64], CCAssignToReg<[XMM0]>>,
 110
 111   // Otherwise, everything is the same as 'normal' X86-64 C CC.
 112   CCDelegateTo<RetCC_X86_64_C>
 113 ]>;
 114
 115
 116 // This is the root return-value convention for the X86-32 backend.
 117 def RetCC_X86_32 : CallingConv<[
 118   // If FastCC, use RetCC_X86_32_Fast.
 119   CCIfCC<"CallingConv::Fast", CCDelegateTo<RetCC_X86_32_Fast>>,
 120   // Otherwise, use RetCC_X86_32_C.
 121   CCDelegateTo<RetCC_X86_32_C>
 122 ]>;
 123
 124 // This is the root return-value convention for the X86-64 backend.
 125 def RetCC_X86_64 : CallingConv<[
 126   // Mingw64 and native Win64 use Win64 CC
 127   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<RetCC_X86_Win64_C>>,
 128
 129   // Otherwise, drop to normal X86-64 CC
 130   CCDelegateTo<RetCC_X86_64_C>
 131 ]>;
 132
 133 // This is the return-value convention used for the entire X86 backend.
 134 def RetCC_X86 : CallingConv<[
 135   CCIfSubtarget<"is64Bit()", CCDelegateTo<RetCC_X86_64>>,
 136   CCDelegateTo<RetCC_X86_32>
 137 ]>;
 138
 139 //===----------------------------------------------------------------------===//
 140 // X86-64 Argument Calling Conventions
 141 //===----------------------------------------------------------------------===//
 142
 143 def CC_X86_64_C : CallingConv<[
 144   // Handles byval parameters.
 145   CCIfByVal<CCPassByVal<8, 8>>,
 146
 147   // Promote i8/i16 arguments to i32.
 148   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 149
 150   // The 'nest' parameter, if any, is passed in R10.
 151   CCIfNest<CCAssignToReg<[R10]>>,
 152
 153   // The first 6 v1i64 vector arguments are passed in GPRs on Darwin.
 154   CCIfType<[v1i64],
 155             CCIfSubtarget<"isTargetDarwin()",
 156             CCBitConvertToType<i64>>>,
 157
 158   // The first 6 integer arguments are passed in integer registers.
 159   CCIfType<[i32], CCAssignToReg<[EDI, ESI, EDX, ECX, R8D, R9D]>>,
 160   CCIfType<[i64], CCAssignToReg<[RDI, RSI, RDX, RCX, R8 , R9 ]>>,
 161
 162   // The first 8 MMX (except for v1i64) vector arguments are passed in XMM
 163   // registers on Darwin.
 164   CCIfType<[x86mmx],
 165             CCIfSubtarget<"isTargetDarwin()",
 166             CCIfSubtarget<"hasXMMInt()",
 167             CCPromoteToType<v2i64>>>>,
 168
 169   // The first 8 FP/Vector arguments are passed in XMM registers.
 170   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 171             CCIfSubtarget<"hasXMM()",
 172             CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>>,
 173
 174   // The first 8 256-bit vector arguments are passed in YMM registers.
 175   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 176             CCIfSubtarget<"hasAVX()",
 177             CCAssignToReg<[YMM0, YMM1, YMM2, YMM3, YMM4, YMM5, YMM6, YMM7]>>>,
 178
 179   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 180   // 8-byte aligned if there are no more registers to hold them.
 181   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 182
 183   // Long doubles get stack slots whose size and alignment depends on the
 184   // subtarget.
 185   CCIfType<[f80], CCAssignToStack<0, 0>>,
 186
 187   // Vectors get 16-byte stack slots that are 16-byte aligned.
 188   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 189
 190   // 256-bit vectors get 32-byte stack slots that are 32-byte aligned.
 191   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 192            CCAssignToStack<32, 32>>,
 193
 194   // __m64 vectors get 8-byte stack slots that are 8-byte aligned.
 195   CCIfType<[x86mmx,v1i64], CCAssignToStack<8, 8>>
 196 ]>;
 197
 198 // Calling convention used on Win64
 199 def CC_X86_Win64_C : CallingConv<[
 200   // FIXME: Handle byval stuff.
 201   // FIXME: Handle varargs.
 202
 203   // Promote i8/i16 arguments to i32.
 204   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 205
 206   // The 'nest' parameter, if any, is passed in R10.
 207   CCIfNest<CCAssignToReg<[R10]>>,
 208
 209   // 128 bit vectors are passed by pointer
 210   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCPassIndirect<i64>>,
 211
 212   // The first 4 MMX vector arguments are passed in GPRs.
 213   CCIfType<[x86mmx, v1i64], CCBitConvertToType<i64>>,
 214
 215   // The first 4 integer arguments are passed in integer registers.
 216   CCIfType<[i32], CCAssignToRegWithShadow<[ECX , EDX , R8D , R9D ],
 217                                           [XMM0, XMM1, XMM2, XMM3]>>,
 218
 219   // Do not pass the sret argument in RCX, the Win64 thiscall calling
 220   // convention requires "this" to be passed in RCX.
 221   CCIfCC<"CallingConv::Win64_ThisCall",
 222     CCIfSRet<CCIfType<[i64], CCAssignToRegWithShadow<[RDX , R8  , R9  ],
 223                                                      [XMM1, XMM2, XMM3]>>>>,
 224
 225   CCIfType<[i64], CCAssignToRegWithShadow<[RCX , RDX , R8  , R9  ],
 226                                           [XMM0, XMM1, XMM2, XMM3]>>,
 227
 228   // The first 4 FP/Vector arguments are passed in XMM registers.
 229   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 230            CCAssignToRegWithShadow<[XMM0, XMM1, XMM2, XMM3],
 231                                    [RCX , RDX , R8  , R9  ]>>,
 232
 233   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 234   // 8-byte aligned if there are no more registers to hold them.
 235   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 236
 237   // Long doubles get stack slots whose size and alignment depends on the
 238   // subtarget.
 239   CCIfType<[f80], CCAssignToStack<0, 0>>,
 240
 241   // __m64 vectors get 8-byte stack slots that are 8-byte aligned.
 242   CCIfType<[x86mmx,v1i64], CCAssignToStack<8, 8>>
 243 ]>;
 244
 245 def CC_X86_64_GHC : CallingConv<[
 246   // Promote i8/i16/i32 arguments to i64.
 247   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 248
 249   // Pass in STG registers: Base, Sp, Hp, R1, R2, R3, R4, R5, R6, SpLim
 250   CCIfType<[i64],
 251             CCAssignToReg<[R13, RBP, R12, RBX, R14, RSI, RDI, R8, R9, R15]>>,
 252
 253   // Pass in STG registers: F1, F2, F3, F4, D1, D2
 254   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 255             CCIfSubtarget<"hasXMM()",
 256             CCAssignToReg<[XMM1, XMM2, XMM3, XMM4, XMM5, XMM6]>>>
 257 ]>;
 258
 259 //===----------------------------------------------------------------------===//
 260 // X86 C Calling Convention
 261 //===----------------------------------------------------------------------===//
 262
 263 /// CC_X86_32_Common - In all X86-32 calling conventions, extra integers and FP
 264 /// values are spilled on the stack, and the first 4 vector values go in XMM
 265 /// regs.
 266 def CC_X86_32_Common : CallingConv<[
 267   // Handles byval parameters.
 268   CCIfByVal<CCPassByVal<4, 4>>,
 269
 270   // The first 3 float or double arguments, if marked 'inreg' and if the call
 271   // is not a vararg call and if SSE2 is available, are passed in SSE registers.
 272   CCIfNotVarArg<CCIfInReg<CCIfType<[f32,f64],
 273                 CCIfSubtarget<"hasXMMInt()",
 274                 CCAssignToReg<[XMM0,XMM1,XMM2]>>>>>,
 275
 276   // The first 3 __m64 (except for v1i64) vector arguments are passed in mmx
 277   // registers if the call is not a vararg call.
 278   CCIfNotVarArg<CCIfType<[x86mmx],
 279                 CCAssignToReg<[MM0, MM1, MM2]>>>,
 280
 281   // Integer/Float values get stored in stack slots that are 4 bytes in
 282   // size and 4-byte aligned.
 283   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 284
 285   // Doubles get 8-byte slots that are 4-byte aligned.
 286   CCIfType<[f64], CCAssignToStack<8, 4>>,
 287
 288   // Long doubles get slots whose size depends on the subtarget.
 289   CCIfType<[f80], CCAssignToStack<0, 4>>,
 290
 291   // The first 4 SSE vector arguments are passed in XMM registers.
 292   CCIfNotVarArg<CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 293                 CCAssignToReg<[XMM0, XMM1, XMM2, XMM3]>>>,
 294
 295   // The first 4 AVX 256-bit vector arguments are passed in YMM registers.
 296   CCIfNotVarArg<CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 297                 CCIfSubtarget<"hasAVX()",
 298                 CCAssignToReg<[YMM0, YMM1, YMM2, YMM3]>>>>,
 299
 300   // Other SSE vectors get 16-byte stack slots that are 16-byte aligned.
 301   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 302
 303   // 256-bit AVX vectors get 32-byte stack slots that are 32-byte aligned.
 304   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 305            CCAssignToStack<32, 32>>,
 306
 307   // __m64 vectors get 8-byte stack slots that are 4-byte aligned. They are
 308   // passed in the parameter area.
 309   CCIfType<[x86mmx,v1i64], CCAssignToStack<8, 4>>]>;
 310
 311 def CC_X86_32_C : CallingConv<[
 312   // Promote i8/i16 arguments to i32.
 313   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 314
 315   // The 'nest' parameter, if any, is passed in ECX.
 316   CCIfNest<CCAssignToReg<[ECX]>>,
 317
 318   // The first 3 integer arguments, if marked 'inreg' and if the call is not
 319   // a vararg call, are passed in integer registers.
 320   CCIfNotVarArg<CCIfInReg<CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>>>,
 321
 322   // Otherwise, same as everything else.
 323   CCDelegateTo<CC_X86_32_Common>
 324 ]>;
 325
 326 def CC_X86_32_FastCall : CallingConv<[
 327   // Promote i8/i16 arguments to i32.
 328   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 329
 330   // The 'nest' parameter, if any, is passed in EAX.
 331   CCIfNest<CCAssignToReg<[EAX]>>,
 332
 333   // The first 2 integer arguments are passed in ECX/EDX
 334   CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>,
 335
 336   // Otherwise, same as everything else.
 337   CCDelegateTo<CC_X86_32_Common>
 338 ]>;
 339
 340 def CC_X86_32_ThisCall : CallingConv<[
 341   // Promote i8/i16 arguments to i32.
 342   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 343
 344   // The 'nest' parameter, if any, is passed in EAX.
 345   CCIfNest<CCAssignToReg<[EAX]>>,
 346
 347   // The first integer argument is passed in ECX
 348   CCIfType<[i32], CCAssignToReg<[ECX]>>,
 349
 350   // Otherwise, same as everything else.
 351   CCDelegateTo<CC_X86_32_Common>
 352 ]>;
 353
 354 def CC_X86_32_FastCC : CallingConv<[
 355   // Handles byval parameters.  Note that we can't rely on the delegation
 356   // to CC_X86_32_Common for this because that happens after code that
 357   // puts arguments in registers.
 358   CCIfByVal<CCPassByVal<4, 4>>,
 359
 360   // Promote i8/i16 arguments to i32.
 361   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 362
 363   // The 'nest' parameter, if any, is passed in EAX.
 364   CCIfNest<CCAssignToReg<[EAX]>>,
 365
 366   // The first 2 integer arguments are passed in ECX/EDX
 367   CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>,
 368
 369   // The first 3 float or double arguments, if the call is not a vararg
 370   // call and if SSE2 is available, are passed in SSE registers.
 371   CCIfNotVarArg<CCIfType<[f32,f64],
 372                 CCIfSubtarget<"hasXMMInt()",
 373                 CCAssignToReg<[XMM0,XMM1,XMM2]>>>>,
 374
 375   // Doubles get 8-byte slots that are 8-byte aligned.
 376   CCIfType<[f64], CCAssignToStack<8, 8>>,
 377
 378   // Otherwise, same as everything else.
 379   CCDelegateTo<CC_X86_32_Common>
 380 ]>;
 381
 382 def CC_X86_32_GHC : CallingConv<[
 383   // Promote i8/i16 arguments to i32.
 384   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 385
 386   // Pass in STG registers: Base, Sp, Hp, R1
 387   CCIfType<[i32], CCAssignToReg<[EBX, EBP, EDI, ESI]>>
 388 ]>;
 389
 390 //===----------------------------------------------------------------------===//
 391 // X86 Root Argument Calling Conventions
 392 //===----------------------------------------------------------------------===//
 393
 394 // This is the root argument convention for the X86-32 backend.
 395 def CC_X86_32 : CallingConv<[
 396   CCIfCC<"CallingConv::X86_FastCall", CCDelegateTo<CC_X86_32_FastCall>>,
 397   CCIfCC<"CallingConv::X86_ThisCall", CCDelegateTo<CC_X86_32_ThisCall>>,
 398   CCIfCC<"CallingConv::Fast", CCDelegateTo<CC_X86_32_FastCC>>,
 399   CCIfCC<"CallingConv::GHC", CCDelegateTo<CC_X86_32_GHC>>,
 400
 401   // Otherwise, drop to normal X86-32 CC
 402   CCDelegateTo<CC_X86_32_C>
 403 ]>;
 404
 405 // This is the root argument convention for the X86-64 backend.
 406 def CC_X86_64 : CallingConv<[
 407   CCIfCC<"CallingConv::GHC", CCDelegateTo<CC_X86_64_GHC>>,
 408
 409   // Mingw64 and native Win64 use Win64 CC
 410   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<CC_X86_Win64_C>>,
 411
 412   // Otherwise, drop to normal X86-64 CC
 413   CCDelegateTo<CC_X86_64_C>
 414 ]>;
 415
 416 // This is the argument convention used for the entire X86 backend.
 417 def CC_X86 : CallingConv<[
 418   CCIfSubtarget<"is64Bit()", CCDelegateTo<CC_X86_64>>,
 419   CCDelegateTo<CC_X86_32>
 420 ]>;