lib/Target/X86/X86.td

   1 //===-- X86.td - Target definition file for the Intel X86 --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This is a target description file for the Intel i386 architecture, referred
  11 // to here as the "X86" architecture.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 // Get the target-independent interfaces which we are implementing...
  16 //
  17 include "llvm/Target/Target.td"
  18
  19 //===----------------------------------------------------------------------===//
  20 // X86 Subtarget state
  21 //
  22
  23 def Mode64Bit : SubtargetFeature<"64bit-mode", "In64BitMode", "true",
  24                                   "64-bit mode (x86_64)">;
  25 def Mode32Bit : SubtargetFeature<"32bit-mode", "In32BitMode", "true",
  26                                   "32-bit mode (80386)">;
  27 def Mode16Bit : SubtargetFeature<"16bit-mode", "In16BitMode", "true",
  28                                   "16-bit mode (i8086)">;
  29
  30 //===----------------------------------------------------------------------===//
  31 // X86 Subtarget features
  32 //===----------------------------------------------------------------------===//
  33
  34 def FeatureCMOV    : SubtargetFeature<"cmov","HasCMov", "true",
  35                                       "Enable conditional move instructions">;
  36
  37 def FeaturePOPCNT   : SubtargetFeature<"popcnt", "HasPOPCNT", "true",
  38                                        "Support POPCNT instruction">;
  39
  40
  41 def FeatureMMX     : SubtargetFeature<"mmx","X86SSELevel", "MMX",
  42                                       "Enable MMX instructions">;
  43 def FeatureSSE1    : SubtargetFeature<"sse", "X86SSELevel", "SSE1",
  44                                       "Enable SSE instructions",
  45                                       // SSE codegen depends on cmovs, and all
  46                                       // SSE1+ processors support them.
  47                                       [FeatureMMX, FeatureCMOV]>;
  48 def FeatureSSE2    : SubtargetFeature<"sse2", "X86SSELevel", "SSE2",
  49                                       "Enable SSE2 instructions",
  50                                       [FeatureSSE1]>;
  51 def FeatureSSE3    : SubtargetFeature<"sse3", "X86SSELevel", "SSE3",
  52                                       "Enable SSE3 instructions",
  53                                       [FeatureSSE2]>;
  54 def FeatureSSSE3   : SubtargetFeature<"ssse3", "X86SSELevel", "SSSE3",
  55                                       "Enable SSSE3 instructions",
  56                                       [FeatureSSE3]>;
  57 def FeatureSSE41   : SubtargetFeature<"sse4.1", "X86SSELevel", "SSE41",
  58                                       "Enable SSE 4.1 instructions",
  59                                       [FeatureSSSE3]>;
  60 def FeatureSSE42   : SubtargetFeature<"sse4.2", "X86SSELevel", "SSE42",
  61                                       "Enable SSE 4.2 instructions",
  62                                       [FeatureSSE41]>;
  63 def Feature3DNow   : SubtargetFeature<"3dnow", "X863DNowLevel", "ThreeDNow",
  64                                       "Enable 3DNow! instructions",
  65                                       [FeatureMMX]>;
  66 def Feature3DNowA  : SubtargetFeature<"3dnowa", "X863DNowLevel", "ThreeDNowA",
  67                                       "Enable 3DNow! Athlon instructions",
  68                                       [Feature3DNow]>;
  69 // All x86-64 hardware has SSE2, but we don't mark SSE2 as an implied
  70 // feature, because SSE2 can be disabled (e.g. for compiling OS kernels)
  71 // without disabling 64-bit mode.
  72 def Feature64Bit   : SubtargetFeature<"64bit", "HasX86_64", "true",
  73                                       "Support 64-bit instructions",
  74                                       [FeatureCMOV]>;
  75 def FeatureCMPXCHG16B : SubtargetFeature<"cx16", "HasCmpxchg16b", "true",
  76                                       "64-bit with cmpxchg16b",
  77                                       [Feature64Bit]>;
  78 def FeatureSlowBTMem : SubtargetFeature<"slow-bt-mem", "IsBTMemSlow", "true",
  79                                        "Bit testing of memory is slow">;
  80 def FeatureSlowSHLD : SubtargetFeature<"slow-shld", "IsSHLDSlow", "true",
  81                                        "SHLD instruction is slow">;
  82 def FeatureFastUAMem : SubtargetFeature<"fast-unaligned-mem",
  83                                         "IsUAMemFast", "true",
  84                                         "Fast unaligned memory access">;
  85 def FeatureSSE4A   : SubtargetFeature<"sse4a", "HasSSE4A", "true",
  86                                       "Support SSE 4a instructions",
  87                                       [FeatureSSE3]>;
  88
  89 def FeatureAVX     : SubtargetFeature<"avx", "X86SSELevel", "AVX",
  90                                       "Enable AVX instructions",
  91                                       [FeatureSSE42]>;
  92 def FeatureAVX2    : SubtargetFeature<"avx2", "X86SSELevel", "AVX2",
  93                                       "Enable AVX2 instructions",
  94                                       [FeatureAVX]>;
  95 def FeatureAVX512   : SubtargetFeature<"avx512f", "X86SSELevel", "AVX512F",
  96                                       "Enable AVX-512 instructions",
  97                                       [FeatureAVX2]>;
  98 def FeatureERI      : SubtargetFeature<"avx512er", "HasERI", "true",
  99                       "Enable AVX-512 Exponential and Reciprocal Instructions",
 100                                       [FeatureAVX512]>;
 101 def FeatureCDI      : SubtargetFeature<"avx512cd", "HasCDI", "true",
 102                       "Enable AVX-512 Conflict Detection Instructions",
 103                                       [FeatureAVX512]>;
 104 def FeaturePFI      : SubtargetFeature<"avx512pf", "HasPFI", "true",
 105                       "Enable AVX-512 PreFetch Instructions",
 106                                       [FeatureAVX512]>;
 107
 108 def FeaturePCLMUL  : SubtargetFeature<"pclmul", "HasPCLMUL", "true",
 109                          "Enable packed carry-less multiplication instructions",
 110                                [FeatureSSE2]>;
 111 def FeatureFMA     : SubtargetFeature<"fma", "HasFMA", "true",
 112                                       "Enable three-operand fused multiple-add",
 113                                       [FeatureAVX]>;
 114 def FeatureFMA4    : SubtargetFeature<"fma4", "HasFMA4", "true",
 115                                       "Enable four-operand fused multiple-add",
 116                                       [FeatureAVX, FeatureSSE4A]>;
 117 def FeatureXOP     : SubtargetFeature<"xop", "HasXOP", "true",
 118                                       "Enable XOP instructions",
 119                                       [FeatureFMA4]>;
 120 def FeatureVectorUAMem : SubtargetFeature<"vector-unaligned-mem",
 121                                           "HasVectorUAMem", "true",
 122                  "Allow unaligned memory operands on vector/SIMD instructions">;
 123 def FeatureAES     : SubtargetFeature<"aes", "HasAES", "true",
 124                                       "Enable AES instructions",
 125                                       [FeatureSSE2]>;
 126 def FeatureTBM     : SubtargetFeature<"tbm", "HasTBM", "true",
 127                                       "Enable TBM instructions">;
 128 def FeatureMOVBE   : SubtargetFeature<"movbe", "HasMOVBE", "true",
 129                                       "Support MOVBE instruction">;
 130 def FeatureRDRAND  : SubtargetFeature<"rdrnd", "HasRDRAND", "true",
 131                                       "Support RDRAND instruction">;
 132 def FeatureF16C    : SubtargetFeature<"f16c", "HasF16C", "true",
 133                        "Support 16-bit floating point conversion instructions",
 134                        [FeatureAVX]>;
 135 def FeatureFSGSBase : SubtargetFeature<"fsgsbase", "HasFSGSBase", "true",
 136                                        "Support FS/GS Base instructions">;
 137 def FeatureLZCNT   : SubtargetFeature<"lzcnt", "HasLZCNT", "true",
 138                                       "Support LZCNT instruction">;
 139 def FeatureBMI     : SubtargetFeature<"bmi", "HasBMI", "true",
 140                                       "Support BMI instructions">;
 141 def FeatureBMI2    : SubtargetFeature<"bmi2", "HasBMI2", "true",
 142                                       "Support BMI2 instructions">;
 143 def FeatureRTM     : SubtargetFeature<"rtm", "HasRTM", "true",
 144                                       "Support RTM instructions">;
 145 def FeatureHLE     : SubtargetFeature<"hle", "HasHLE", "true",
 146                                       "Support HLE">;
 147 def FeatureADX     : SubtargetFeature<"adx", "HasADX", "true",
 148                                       "Support ADX instructions">;
 149 def FeatureSHA     : SubtargetFeature<"sha", "HasSHA", "true",
 150                                       "Enable SHA instructions",
 151                                       [FeatureSSE2]>;
 152 def FeaturePRFCHW  : SubtargetFeature<"prfchw", "HasPRFCHW", "true",
 153                                       "Support PRFCHW instructions">;
 154 def FeatureRDSEED  : SubtargetFeature<"rdseed", "HasRDSEED", "true",
 155                                       "Support RDSEED instruction">;
 156 def FeatureLeaForSP : SubtargetFeature<"lea-sp", "UseLeaForSP", "true",
 157                                      "Use LEA for adjusting the stack pointer">;
 158 def FeatureSlowDivide : SubtargetFeature<"idiv-to-divb",
 159                                      "HasSlowDivide", "true",
 160                                      "Use small divide for positive values less than 256">;
 161 def FeaturePadShortFunctions : SubtargetFeature<"pad-short-functions",
 162                                      "PadShortFunctions", "true",
 163                                      "Pad short functions">;
 164 def FeatureCallRegIndirect : SubtargetFeature<"call-reg-indirect",
 165                                      "CallRegIndirect", "true",
 166                                      "Call register indirect">;
 167 def FeatureLEAUsesAG : SubtargetFeature<"lea-uses-ag", "LEAUsesAG", "true",
 168                                    "LEA instruction needs inputs at AG stage">;
 169
 170 //===----------------------------------------------------------------------===//
 171 // X86 processors supported.
 172 //===----------------------------------------------------------------------===//
 173
 174 include "X86Schedule.td"
 175
 176 def ProcIntelAtom : SubtargetFeature<"atom", "X86ProcFamily", "IntelAtom",
 177                     "Intel Atom processors">;
 178 def ProcIntelSLM  : SubtargetFeature<"slm", "X86ProcFamily", "IntelSLM",
 179                     "Intel Silvermont processors">;
 180
 181 class Proc<string Name, list<SubtargetFeature> Features>
 182  : ProcessorModel<Name, GenericModel, Features>;
 183
 184 def : Proc<"generic",         []>;
 185 def : Proc<"i386",            []>;
 186 def : Proc<"i486",            []>;
 187 def : Proc<"i586",            []>;
 188 def : Proc<"pentium",         []>;
 189 def : Proc<"pentium-mmx",     [FeatureMMX]>;
 190 def : Proc<"i686",            []>;
 191 def : Proc<"pentiumpro",      [FeatureCMOV]>;
 192 def : Proc<"pentium2",        [FeatureMMX, FeatureCMOV]>;
 193 def : Proc<"pentium3",        [FeatureSSE1]>;
 194 def : Proc<"pentium3m",       [FeatureSSE1, FeatureSlowBTMem]>;
 195 def : Proc<"pentium-m",       [FeatureSSE2, FeatureSlowBTMem]>;
 196 def : Proc<"pentium4",        [FeatureSSE2]>;
 197 def : Proc<"pentium4m",       [FeatureSSE2, FeatureSlowBTMem]>;
 198 def : Proc<"x86-64",          [FeatureSSE2, Feature64Bit, FeatureSlowBTMem,
 199                                FeatureFastUAMem]>;
 200 // Intel Core Duo.
 201 def : ProcessorModel<"yonah", SandyBridgeModel,
 202                      [FeatureSSE3, FeatureSlowBTMem]>;
 203
 204 // NetBurst.
 205 def : Proc<"prescott", [FeatureSSE3, FeatureSlowBTMem]>;
 206 def : Proc<"nocona",   [FeatureSSE3, FeatureCMPXCHG16B, FeatureSlowBTMem]>;
 207
 208 // Intel Core 2 Solo/Duo.
 209 def : ProcessorModel<"core2", SandyBridgeModel,
 210                      [FeatureSSSE3, FeatureCMPXCHG16B, FeatureSlowBTMem]>;
 211 def : ProcessorModel<"penryn", SandyBridgeModel,
 212                      [FeatureSSE41, FeatureCMPXCHG16B, FeatureSlowBTMem]>;
 213
 214 // Atom.
 215 def : ProcessorModel<"atom", AtomModel,
 216                      [ProcIntelAtom, FeatureSSSE3, FeatureCMPXCHG16B,
 217                       FeatureMOVBE, FeatureSlowBTMem, FeatureLeaForSP,
 218                       FeatureSlowDivide,
 219                       FeatureCallRegIndirect,
 220                       FeatureLEAUsesAG,
 221                       FeaturePadShortFunctions]>;
 222
 223 // Atom Silvermont.
 224 def : ProcessorModel<"slm",  SLMModel, [ProcIntelSLM,
 225                                FeatureSSE42, FeatureCMPXCHG16B,
 226                                FeatureMOVBE, FeaturePOPCNT,
 227                                FeaturePCLMUL, FeatureAES,
 228                                FeatureCallRegIndirect,
 229                                FeaturePRFCHW,
 230                                FeatureSlowBTMem]>;
 231 // "Arrandale" along with corei3 and corei5
 232 def : ProcessorModel<"corei7", SandyBridgeModel,
 233                      [FeatureSSE42, FeatureCMPXCHG16B, FeatureSlowBTMem,
 234                       FeatureFastUAMem, FeaturePOPCNT, FeatureAES]>;
 235
 236 def : ProcessorModel<"nehalem", SandyBridgeModel,
 237                      [FeatureSSE42,  FeatureCMPXCHG16B, FeatureSlowBTMem,
 238                       FeatureFastUAMem, FeaturePOPCNT]>;
 239 // Westmere is a similar machine to nehalem with some additional features.
 240 // Westmere is the corei3/i5/i7 path from nehalem to sandybridge
 241 def : ProcessorModel<"westmere", SandyBridgeModel,
 242                      [FeatureSSE42, FeatureCMPXCHG16B, FeatureSlowBTMem,
 243                       FeatureFastUAMem, FeaturePOPCNT, FeatureAES,
 244                       FeaturePCLMUL]>;
 245 // Sandy Bridge
 246 // SSE is not listed here since llvm treats AVX as a reimplementation of SSE,
 247 // rather than a superset.
 248 def : ProcessorModel<"corei7-avx", SandyBridgeModel,
 249                      [FeatureAVX, FeatureCMPXCHG16B, FeatureFastUAMem,
 250                       FeaturePOPCNT, FeatureAES, FeaturePCLMUL]>;
 251 // Ivy Bridge
 252 def : ProcessorModel<"core-avx-i", SandyBridgeModel,
 253                      [FeatureAVX, FeatureCMPXCHG16B, FeatureFastUAMem,
 254                       FeaturePOPCNT, FeatureAES, FeaturePCLMUL, FeatureRDRAND,
 255                       FeatureF16C, FeatureFSGSBase]>;
 256
 257 // Haswell
 258 def : ProcessorModel<"core-avx2", HaswellModel,
 259                      [FeatureAVX2, FeatureCMPXCHG16B, FeatureFastUAMem,
 260                       FeaturePOPCNT, FeatureAES, FeaturePCLMUL, FeatureRDRAND,
 261                       FeatureF16C, FeatureFSGSBase, FeatureMOVBE, FeatureLZCNT,
 262                       FeatureBMI, FeatureBMI2, FeatureFMA, FeatureRTM,
 263                       FeatureHLE]>;
 264
 265 // KNL
 266 // FIXME: define KNL model
 267 def : ProcessorModel<"knl", HaswellModel,
 268                      [FeatureAVX512, FeatureERI, FeatureCDI, FeaturePFI,
 269                       FeatureCMPXCHG16B, FeatureFastUAMem, FeaturePOPCNT,
 270                       FeatureAES, FeaturePCLMUL, FeatureRDRAND, FeatureF16C,
 271                       FeatureFSGSBase, FeatureMOVBE, FeatureLZCNT, FeatureBMI,
 272                       FeatureBMI2, FeatureFMA, FeatureRTM, FeatureHLE]>;
 273
 274 def : Proc<"k6",              [FeatureMMX]>;
 275 def : Proc<"k6-2",            [Feature3DNow]>;
 276 def : Proc<"k6-3",            [Feature3DNow]>;
 277 def : Proc<"athlon",          [Feature3DNowA, FeatureSlowBTMem,
 278                                FeatureSlowSHLD]>;
 279 def : Proc<"athlon-tbird",    [Feature3DNowA, FeatureSlowBTMem,
 280                                FeatureSlowSHLD]>;
 281 def : Proc<"athlon-4",        [FeatureSSE1,   Feature3DNowA, FeatureSlowBTMem,
 282                                FeatureSlowSHLD]>;
 283 def : Proc<"athlon-xp",       [FeatureSSE1,   Feature3DNowA, FeatureSlowBTMem,
 284                                FeatureSlowSHLD]>;
 285 def : Proc<"athlon-mp",       [FeatureSSE1,   Feature3DNowA, FeatureSlowBTMem,
 286                                FeatureSlowSHLD]>;
 287 def : Proc<"k8",              [FeatureSSE2,   Feature3DNowA, Feature64Bit,
 288                                FeatureSlowBTMem, FeatureSlowSHLD]>;
 289 def : Proc<"opteron",         [FeatureSSE2,   Feature3DNowA, Feature64Bit,
 290                                FeatureSlowBTMem, FeatureSlowSHLD]>;
 291 def : Proc<"athlon64",        [FeatureSSE2,   Feature3DNowA, Feature64Bit,
 292                                FeatureSlowBTMem, FeatureSlowSHLD]>;
 293 def : Proc<"athlon-fx",       [FeatureSSE2,   Feature3DNowA, Feature64Bit,
 294                                FeatureSlowBTMem, FeatureSlowSHLD]>;
 295 def : Proc<"k8-sse3",         [FeatureSSE3,   Feature3DNowA, FeatureCMPXCHG16B,
 296                                FeatureSlowBTMem, FeatureSlowSHLD]>;
 297 def : Proc<"opteron-sse3",    [FeatureSSE3,   Feature3DNowA, FeatureCMPXCHG16B,
 298                                FeatureSlowBTMem, FeatureSlowSHLD]>;
 299 def : Proc<"athlon64-sse3",   [FeatureSSE3,   Feature3DNowA, FeatureCMPXCHG16B,
 300                                FeatureSlowBTMem, FeatureSlowSHLD]>;
 301 def : Proc<"amdfam10",        [FeatureSSE4A,
 302                                Feature3DNowA, FeatureCMPXCHG16B, FeatureLZCNT,
 303                                FeaturePOPCNT, FeatureSlowBTMem,
 304                                FeatureSlowSHLD]>;
 305 // Bobcat
 306 def : Proc<"btver1",          [FeatureSSSE3, FeatureSSE4A, FeatureCMPXCHG16B,
 307                                FeaturePRFCHW, FeatureLZCNT, FeaturePOPCNT,
 308                                FeatureSlowSHLD]>;
 309 // Jaguar
 310 def : Proc<"btver2",          [FeatureAVX, FeatureSSE4A, FeatureCMPXCHG16B,
 311                                FeaturePRFCHW, FeatureAES, FeaturePCLMUL,
 312                                FeatureBMI, FeatureF16C, FeatureMOVBE,
 313                                FeatureLZCNT, FeaturePOPCNT, FeatureSlowSHLD]>;
 314 // Bulldozer
 315 def : Proc<"bdver1",          [FeatureXOP, FeatureFMA4, FeatureCMPXCHG16B,
 316                                FeatureAES, FeaturePRFCHW, FeaturePCLMUL,
 317                                FeatureLZCNT, FeaturePOPCNT, FeatureSlowSHLD]>;
 318 // Piledriver
 319 def : Proc<"bdver2",          [FeatureXOP, FeatureFMA4, FeatureCMPXCHG16B,
 320                                FeatureAES, FeaturePRFCHW, FeaturePCLMUL,
 321                                FeatureF16C, FeatureLZCNT,
 322                                FeaturePOPCNT, FeatureBMI, FeatureTBM,
 323                                FeatureFMA, FeatureSlowSHLD]>;
 324
 325 // Steamroller
 326 def : Proc<"bdver3",          [FeatureXOP, FeatureFMA4, FeatureCMPXCHG16B,
 327                                FeatureAES, FeaturePRFCHW, FeaturePCLMUL,
 328                                FeatureF16C, FeatureLZCNT,
 329                                FeaturePOPCNT, FeatureBMI,  FeatureTBM,
 330                                FeatureFMA, FeatureFSGSBase]>;
 331
 332 def : Proc<"geode",           [Feature3DNowA]>;
 333
 334 def : Proc<"winchip-c6",      [FeatureMMX]>;
 335 def : Proc<"winchip2",        [Feature3DNow]>;
 336 def : Proc<"c3",              [Feature3DNow]>;
 337 def : Proc<"c3-2",            [FeatureSSE1]>;
 338
 339 //===----------------------------------------------------------------------===//
 340 // Register File Description
 341 //===----------------------------------------------------------------------===//
 342
 343 include "X86RegisterInfo.td"
 344
 345 //===----------------------------------------------------------------------===//
 346 // Instruction Descriptions
 347 //===----------------------------------------------------------------------===//
 348
 349 include "X86InstrInfo.td"
 350
 351 def X86InstrInfo : InstrInfo;
 352
 353 //===----------------------------------------------------------------------===//
 354 // Calling Conventions
 355 //===----------------------------------------------------------------------===//
 356
 357 include "X86CallingConv.td"
 358
 359
 360 //===----------------------------------------------------------------------===//
 361 // Assembly Parser
 362 //===----------------------------------------------------------------------===//
 363
 364 def ATTAsmParser : AsmParser {
 365   string AsmParserClassName = "AsmParser";
 366 }
 367
 368 def ATTAsmParserVariant : AsmParserVariant {
 369   int Variant = 0;
 370
 371   // Variant name.
 372   string Name = "att";
 373
 374   // Discard comments in assembly strings.
 375   string CommentDelimiter = "#";
 376
 377   // Recognize hard coded registers.
 378   string RegisterPrefix = "%";
 379 }
 380
 381 def IntelAsmParserVariant : AsmParserVariant {
 382   int Variant = 1;
 383
 384   // Variant name.
 385   string Name = "intel";
 386
 387   // Discard comments in assembly strings.
 388   string CommentDelimiter = ";";
 389
 390   // Recognize hard coded registers.
 391   string RegisterPrefix = "";
 392 }
 393
 394 //===----------------------------------------------------------------------===//
 395 // Assembly Printers
 396 //===----------------------------------------------------------------------===//
 397
 398 // The X86 target supports two different syntaxes for emitting machine code.
 399 // This is controlled by the -x86-asm-syntax={att|intel}
 400 def ATTAsmWriter : AsmWriter {
 401   string AsmWriterClassName  = "ATTInstPrinter";
 402   int Variant = 0;
 403 }
 404 def IntelAsmWriter : AsmWriter {
 405   string AsmWriterClassName  = "IntelInstPrinter";
 406   int Variant = 1;
 407 }
 408
 409 def X86 : Target {
 410   // Information about the instructions...
 411   let InstructionSet = X86InstrInfo;
 412   let AssemblyParsers = [ATTAsmParser];
 413   let AssemblyParserVariants = [ATTAsmParserVariant, IntelAsmParserVariant];
 414   let AssemblyWriters = [ATTAsmWriter, IntelAsmWriter];
 415 }