lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 //===----------------------------------------------------------------------===//
  55 // Selection DAG Type Profile definitions.
  56 //
  57 // These use the constraints defined above to describe the type requirements of
  58 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  59 // add their own if needed.
  60 //
  61
  62 // SDTypeProfile - This profile describes the type requirements of a Selection
  63 // DAG node.
  64 class SDTypeProfile<int numresults, int numoperands,
  65                     list<SDTypeConstraint> constraints> {
  66   int NumResults = numresults;
  67   int NumOperands = numoperands;
  68   list<SDTypeConstraint> Constraints = constraints;
  69 }
  70
  71 // Builtin profiles.
  72 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  73 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  74 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  75 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  76 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  77   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  78 ]>;
  79 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  80   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  81 ]>;
  82 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  83   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  84 ]>;
  85 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
  86   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
  87 ]>;
  88 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  89   SDTCisSameAs<0, 1>, SDTCisInt<0>
  90 ]>;
  91 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
  92   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
  93 ]>;
  94 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
  95   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
  96 ]>;
  97 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
  98   SDTCisSameAs<0, 1>, SDTCisFP<0>
  99 ]>;
 100 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 101   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 102 ]>;
 103 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 104   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 105 ]>;
 106 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 107   SDTCisFP<0>, SDTCisInt<1>
 108 ]>;
 109 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 110   SDTCisInt<0>, SDTCisFP<1>
 111 ]>;
 112 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 113   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 114   SDTCisVTSmallerThanOp<2, 1>
 115 ]>;
 116
 117 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 118   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 119 ]>;
 120
 121 def SDTSelect : SDTypeProfile<1, 3, [ // select
 122   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 123 ]>;
 124
 125 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 126   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 127   SDTCisVT<5, OtherVT>
 128 ]>;
 129
 130 def SDTBr : SDTypeProfile<0, 1, [ // br
 131   SDTCisVT<0, OtherVT>
 132 ]>;
 133
 134 def SDTBrCond : SDTypeProfile<0, 2, [ // brcond
 135   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 136 ]>;
 137
 138 def SDTRet : SDTypeProfile<0, 0, [ // ret
 139 ]>;
 140
 141 def SDTWritePort : SDTypeProfile<0, 2, [ // writeport
 142   SDTCisInt<0>, SDTCisInt<1>
 143 ]>;
 144
 145 def SDTLoad : SDTypeProfile<1, 1, [ // load
 146   SDTCisPtrTy<1>
 147 ]>;
 148
 149 def SDTStore : SDTypeProfile<0, 2, [ // store
 150   SDTCisPtrTy<1>
 151 ]>;
 152
 153 def SDTIntExtLoad : SDTypeProfile<1, 3, [  // sextload, zextload
 154   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 155 ]>;
 156
 157
 158 //===----------------------------------------------------------------------===//
 159 // Selection DAG Node Properties.
 160 //
 161 // Note: These are hard coded into tblgen.
 162 //
 163 class SDNodeProperty;
 164 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 165 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 166 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 167
 168 //===----------------------------------------------------------------------===//
 169 // Selection DAG Node definitions.
 170 //
 171 class SDNode<string opcode, SDTypeProfile typeprof,
 172              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 173   string Opcode  = opcode;
 174   string SDClass = sdclass;
 175   list<SDNodeProperty> Properties = props;
 176   SDTypeProfile TypeProfile = typeprof;
 177 }
 178
 179 def set;
 180 def node;
 181 def srcvalue;
 182
 183 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 184 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 185 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 186 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 187 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 188 def globaladdr : SDNode<"ISD::GlobalAddress", SDTPtrLeaf, [],
 189                         "GlobalAddressSDNode">;
 190 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress", SDTPtrLeaf, [],
 191                         "GlobalAddressSDNode">;
 192 def tconstpool  : SDNode<"ISD::TargetConstantPool", SDTPtrLeaf, [],
 193                         "ConstantPoolSDNode">;
 194 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 195                         [SDNPCommutative, SDNPAssociative]>;
 196 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 197 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 198                         [SDNPCommutative, SDNPAssociative]>;
 199 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 200 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 201 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 202 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 203 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 204 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 205 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 206 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 207 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 208 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 209                         [SDNPCommutative, SDNPAssociative]>;
 210 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 211                         [SDNPCommutative, SDNPAssociative]>;
 212 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 213                         [SDNPCommutative, SDNPAssociative]>;
 214
 215 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 216 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 217 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 218 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 219 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 220 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 221 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 222 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 223
 224 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 225 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 226 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 227 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 228 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 229 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 230 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 231 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 232
 233 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 234 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 235
 236 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 237 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 238 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 239 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 240
 241 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 242 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 243 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 244
 245 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 246 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrCond, [SDNPHasChain]>;
 247 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 248
 249 def writeport  : SDNode<"ISD::WRITEPORT"  , SDTWritePort, [SDNPHasChain]>;
 250
 251 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 252 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 253
 254 // Do not use sextld and zextld directly. Use sextload and zextload (see
 255 // below) which pass in a dummy srcvalue node which tblgen will skip over.
 256 def sextld     : SDNode<"ISD::SEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 257 def zextld     : SDNode<"ISD::ZEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 258
 259 //===----------------------------------------------------------------------===//
 260 // Selection DAG Condition Codes
 261
 262 class CondCode; // ISD::CondCode enums
 263 def SETOEQ : CondCode; def SETOGT : CondCode;
 264 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 265 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 266 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 267 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 268
 269 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 270 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 271
 272
 273 //===----------------------------------------------------------------------===//
 274 // Selection DAG Node Transformation Functions.
 275 //
 276 // This mechanism allows targets to manipulate nodes in the output DAG once a
 277 // match has been formed.  This is typically used to manipulate immediate
 278 // values.
 279 //
 280 class SDNodeXForm<SDNode opc, code xformFunction> {
 281   SDNode Opcode = opc;
 282   code XFormFunction = xformFunction;
 283 }
 284
 285 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 286
 287
 288 //===----------------------------------------------------------------------===//
 289 // Selection DAG Pattern Fragments.
 290 //
 291 // Pattern fragments are reusable chunks of dags that match specific things.
 292 // They can take arguments and have C++ predicates that control whether they
 293 // match.  They are intended to make the patterns for common instructions more
 294 // compact and readable.
 295 //
 296
 297 /// PatFrag - Represents a pattern fragment.  This can match something on the
 298 /// DAG, frame a single node to multiply nested other fragments.
 299 ///
 300 class PatFrag<dag ops, dag frag, code pred = [{}],
 301               SDNodeXForm xform = NOOP_SDNodeXForm> {
 302   dag Operands = ops;
 303   dag Fragment = frag;
 304   code Predicate = pred;
 305   SDNodeXForm OperandTransform = xform;
 306 }
 307
 308 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 309 // to define immediates and other common things concisely.
 310 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 311  : PatFrag<(ops), frag, pred, xform>;
 312
 313 // Leaf fragments.
 314
 315 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 316
 317 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 318 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 319
 320 // Other helper fragments.
 321
 322 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 323 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 324
 325 // extending load fragments.
 326 def sextload      : PatFrag<(ops node:$ptr, node:$vt),
 327                             (sextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 328 def zextload      : PatFrag<(ops node:$ptr, node:$vt),
 329                             (zextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 330
 331 // setcc convenience fragments.
 332 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 333                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 334 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 335                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 336 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 337                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 338 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 339                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 340 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 341                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 342 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 343                      (setcc node:$lhs, node:$rhs, SETONE)>;
 344 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 345                      (setcc node:$lhs, node:$rhs, SETO)>;
 346 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 347                      (setcc node:$lhs, node:$rhs, SETUO)>;
 348 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 349                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 350 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 351                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 352 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 353                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 354 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 355                      (setcc node:$lhs, node:$rhs, SETULT)>;
 356 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 357                      (setcc node:$lhs, node:$rhs, SETULE)>;
 358 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 359                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 360 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 361                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 362 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 363                      (setcc node:$lhs, node:$rhs, SETGT)>;
 364 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 365                      (setcc node:$lhs, node:$rhs, SETGE)>;
 366 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 367                      (setcc node:$lhs, node:$rhs, SETLT)>;
 368 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 369                      (setcc node:$lhs, node:$rhs, SETLE)>;
 370 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 371                      (setcc node:$lhs, node:$rhs, SETNE)>;
 372
 373 //===----------------------------------------------------------------------===//
 374 // Selection DAG Pattern Support.
 375 //
 376 // Patterns are what are actually matched against the target-flavored
 377 // instruction selection DAG.  Instructions defined by the target implicitly
 378 // define patterns in most cases, but patterns can also be explicitly added when
 379 // an operation is defined by a sequence of instructions (e.g. loading a large
 380 // immediate value on RISC targets that do not support immediates as large as
 381 // their GPRs).
 382 //
 383
 384 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 385   dag       PatternToMatch = patternToMatch;
 386   list<dag> ResultInstrs   = resultInstrs;
 387 }
 388
 389 // Pat - A simple (but common) form of a pattern, which produces a simple result
 390 // not needing a full list.
 391 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 392
 393 //===----------------------------------------------------------------------===//
 394 // Complex pattern definitions.
 395 //
 396 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 397 // in C++. NumOperands is the number of operands returned by the select function;
 398 // SelectFunc is the name of the function used to pattern match the max. pattern;
 399 // RootNodes are the list of possible root nodes of the sub-dags to match.
 400 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 401 //
 402 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 403   ValueType Ty = ty;
 404   int NumOperands = numops;
 405   string SelectFunc = fn;
 406   list<SDNode> RootNodes = roots;
 407 }