lib/Target/SystemZ/SystemZInstrInfo.td

   1 //===-- SystemZInstrInfo.td - General SystemZ instructions ----*- tblgen-*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // Stack allocation
  12 //===----------------------------------------------------------------------===//
  13
  14 def ADJCALLSTACKDOWN : Pseudo<(outs), (ins i64imm:$amt),
  15                               [(callseq_start timm:$amt)]>;
  16 def ADJCALLSTACKUP   : Pseudo<(outs), (ins i64imm:$amt1, i64imm:$amt2),
  17                               [(callseq_end timm:$amt1, timm:$amt2)]>;
  18
  19 let neverHasSideEffects = 1 in {
  20   // Takes as input the value of the stack pointer after a dynamic allocation
  21   // has been made.  Sets the output to the address of the dynamically-
  22   // allocated area itself, skipping the outgoing arguments.
  23   //
  24   // This expands to an LA or LAY instruction.  We restrict the offset
  25   // to the range of LA and keep the LAY range in reserve for when
  26   // the size of the outgoing arguments is added.
  27   def ADJDYNALLOC : Pseudo<(outs GR64:$dst), (ins dynalloc12only:$src),
  28                            [(set GR64:$dst, dynalloc12only:$src)]>;
  29 }
  30
  31 //===----------------------------------------------------------------------===//
  32 // Control flow instructions
  33 //===----------------------------------------------------------------------===//
  34
  35 // A return instruction (br %r14).
  36 let isReturn = 1, isTerminator = 1, isBarrier = 1, hasCtrlDep = 1 in
  37   def Return : Alias<2, (outs), (ins), [(z_retflag)]>;
  38
  39 // Unconditional branches.  R1 is the condition-code mask (all 1s).
  40 let isBranch = 1, isTerminator = 1, isBarrier = 1, R1 = 15 in {
  41   let isIndirectBranch = 1 in
  42     def BR : InstRR<0x07, (outs), (ins ADDR64:$R2),
  43                     "br\t$R2", [(brind ADDR64:$R2)]>;
  44
  45   // An assembler extended mnemonic for BRC.
  46   def J : InstRI<0xA74, (outs), (ins brtarget16:$I2), "j\t$I2",
  47                  [(br bb:$I2)]>;
  48
  49   // An assembler extended mnemonic for BRCL.  (The extension is "G"
  50   // rather than "L" because "JL" is "Jump if Less".)
  51   def JG : InstRIL<0xC04, (outs), (ins brtarget32:$I2), "jg\t$I2", []>;
  52 }
  53
  54 // Conditional branches.  It's easier for LLVM to handle these branches
  55 // in their raw BRC/BRCL form, with the 4-bit condition-code mask being
  56 // the first operand.  It seems friendlier to use mnemonic forms like
  57 // JE and JLH when writing out the assembly though.
  58 let isBranch = 1, isTerminator = 1, Uses = [CC] in {
  59   let isCodeGenOnly = 1, CCMaskFirst = 1 in {
  60     def BRC : InstRI<0xA74, (outs), (ins cond4:$valid, cond4:$R1,
  61                                          brtarget16:$I2), "j$R1\t$I2",
  62                      [(z_br_ccmask cond4:$valid, cond4:$R1, bb:$I2)]>;
  63     def BRCL : InstRIL<0xC04, (outs), (ins cond4:$valid, cond4:$R1,
  64                                            brtarget32:$I2), "jg$R1\t$I2", []>;
  65   }
  66   def AsmBRC : InstRI<0xA74, (outs), (ins uimm8zx4:$R1, brtarget16:$I2),
  67                       "brc\t$R1, $I2", []>;
  68   def AsmBRCL : InstRIL<0xC04, (outs), (ins uimm8zx4:$R1, brtarget32:$I2),
  69                         "brcl\t$R1, $I2", []>;
  70 }
  71
  72 // Fused compare-and-branch instructions.  As for normal branches,
  73 // we handle these instructions internally in their raw CRJ-like form,
  74 // but use assembly macros like CRJE when writing them out.
  75 //
  76 // These instructions do not use or clobber the condition codes.
  77 // We nevertheless pretend that they clobber CC, so that we can lower
  78 // them to separate comparisons and BRCLs if the branch ends up being
  79 // out of range.
  80 multiclass CompareBranches<Operand ccmask, string pos1, string pos2> {
  81   let isBranch = 1, isTerminator = 1, Defs = [CC] in {
  82     def RJ  : InstRIEb<0xEC76, (outs), (ins GR32:$R1, GR32:$R2, ccmask:$M3,
  83                                             brtarget16:$RI4),
  84                        "crj"##pos1##"\t$R1, $R2, "##pos2##"$RI4", []>;
  85     def GRJ : InstRIEb<0xEC64, (outs), (ins GR64:$R1, GR64:$R2, ccmask:$M3,
  86                                             brtarget16:$RI4),
  87                        "cgrj"##pos1##"\t$R1, $R2, "##pos2##"$RI4", []>;
  88     def IJ  : InstRIEc<0xEC7E, (outs), (ins GR32:$R1, imm32sx8:$I2, ccmask:$M3,
  89                                             brtarget16:$RI4),
  90                        "cij"##pos1##"\t$R1, $I2, "##pos2##"$RI4", []>;
  91     def GIJ : InstRIEc<0xEC7C, (outs), (ins GR64:$R1, imm64sx8:$I2, ccmask:$M3,
  92                                             brtarget16:$RI4),
  93                        "cgij"##pos1##"\t$R1, $I2, "##pos2##"$RI4", []>;
  94     def LRJ  : InstRIEb<0xEC77, (outs), (ins GR32:$R1, GR32:$R2, ccmask:$M3,
  95                                              brtarget16:$RI4),
  96                         "clrj"##pos1##"\t$R1, $R2, "##pos2##"$RI4", []>;
  97     def LGRJ : InstRIEb<0xEC65, (outs), (ins GR64:$R1, GR64:$R2, ccmask:$M3,
  98                                              brtarget16:$RI4),
  99                         "clgrj"##pos1##"\t$R1, $R2, "##pos2##"$RI4", []>;
 100     def LIJ  : InstRIEc<0xEC7F, (outs), (ins GR32:$R1, imm32zx8:$I2, ccmask:$M3,
 101                                              brtarget16:$RI4),
 102                         "clij"##pos1##"\t$R1, $I2, "##pos2##"$RI4", []>;
 103     def LGIJ : InstRIEc<0xEC7D, (outs), (ins GR64:$R1, imm64zx8:$I2, ccmask:$M3,
 104                                              brtarget16:$RI4),
 105                         "clgij"##pos1##"\t$R1, $I2, "##pos2##"$RI4", []>;
 106   }
 107 }
 108 let isCodeGenOnly = 1 in
 109   defm C : CompareBranches<cond4, "$M3", "">;
 110 defm AsmC : CompareBranches<uimm8zx4, "", "$M3, ">;
 111
 112 // Define AsmParser mnemonics for each general condition-code mask
 113 // (integer or floating-point)
 114 multiclass CondExtendedMnemonic<bits<4> ccmask, string name> {
 115   let R1 = ccmask in {
 116     def J : InstRI<0xA74, (outs), (ins brtarget16:$I2),
 117                    "j"##name##"\t$I2", []>;
 118     def JG : InstRIL<0xC04, (outs), (ins brtarget32:$I2),
 119                      "jg"##name##"\t$I2", []>;
 120   }
 121   def LOCR  : FixedCondUnaryRRF<"locr"##name,  0xB9F2, GR32, GR32, ccmask>;
 122   def LOCGR : FixedCondUnaryRRF<"locgr"##name, 0xB9E2, GR64, GR64, ccmask>;
 123   def LOC   : FixedCondUnaryRSY<"loc"##name,   0xEBF2, GR32, ccmask, 4>;
 124   def LOCG  : FixedCondUnaryRSY<"locg"##name,  0xEBE2, GR64, ccmask, 8>;
 125   def STOC  : FixedCondStoreRSY<"stoc"##name,  0xEBF3, GR32, ccmask, 4>;
 126   def STOCG : FixedCondStoreRSY<"stocg"##name, 0xEBE3, GR64, ccmask, 8>;
 127 }
 128 defm AsmO   : CondExtendedMnemonic<1,  "o">;
 129 defm AsmH   : CondExtendedMnemonic<2,  "h">;
 130 defm AsmNLE : CondExtendedMnemonic<3,  "nle">;
 131 defm AsmL   : CondExtendedMnemonic<4,  "l">;
 132 defm AsmNHE : CondExtendedMnemonic<5,  "nhe">;
 133 defm AsmLH  : CondExtendedMnemonic<6,  "lh">;
 134 defm AsmNE  : CondExtendedMnemonic<7,  "ne">;
 135 defm AsmE   : CondExtendedMnemonic<8,  "e">;
 136 defm AsmNLH : CondExtendedMnemonic<9,  "nlh">;
 137 defm AsmHE  : CondExtendedMnemonic<10, "he">;
 138 defm AsmNL  : CondExtendedMnemonic<11, "nl">;
 139 defm AsmLE  : CondExtendedMnemonic<12, "le">;
 140 defm AsmNH  : CondExtendedMnemonic<13, "nh">;
 141 defm AsmNO  : CondExtendedMnemonic<14, "no">;
 142
 143 // Define AsmParser mnemonics for each integer condition-code mask.
 144 // This is like the list above, except that condition 3 is not possible
 145 // and that the low bit of the mask is therefore always 0.  This means
 146 // that each condition has two names.  Conditions "o" and "no" are not used.
 147 //
 148 // We don't make one of the two names an alias of the other because
 149 // we need the custom parsing routines to select the correct register class.
 150 multiclass IntCondExtendedMnemonicA<bits<4> ccmask, string name> {
 151   let M3 = ccmask in {
 152     def CR  : InstRIEb<0xEC76, (outs), (ins GR32:$R1, GR32:$R2,
 153                                             brtarget16:$RI4),
 154                        "crj"##name##"\t$R1, $R2, $RI4", []>;
 155     def CGR : InstRIEb<0xEC64, (outs), (ins GR64:$R1, GR64:$R2,
 156                                             brtarget16:$RI4),
 157                        "cgrj"##name##"\t$R1, $R2, $RI4", []>;
 158     def CI  : InstRIEc<0xEC7E, (outs), (ins GR32:$R1, imm32sx8:$I2,
 159                                             brtarget16:$RI4),
 160                        "cij"##name##"\t$R1, $I2, $RI4", []>;
 161     def CGI : InstRIEc<0xEC7C, (outs), (ins GR64:$R1, imm64sx8:$I2,
 162                                             brtarget16:$RI4),
 163                        "cgij"##name##"\t$R1, $I2, $RI4", []>;
 164     def CLR  : InstRIEb<0xEC77, (outs), (ins GR32:$R1, GR32:$R2,
 165                                             brtarget16:$RI4),
 166                         "clrj"##name##"\t$R1, $R2, $RI4", []>;
 167     def CLGR : InstRIEb<0xEC65, (outs), (ins GR64:$R1, GR64:$R2,
 168                                              brtarget16:$RI4),
 169                         "clgrj"##name##"\t$R1, $R2, $RI4", []>;
 170     def CLI  : InstRIEc<0xEC7F, (outs), (ins GR32:$R1, imm32zx8:$I2,
 171                                              brtarget16:$RI4),
 172                         "clij"##name##"\t$R1, $I2, $RI4", []>;
 173     def CLGI : InstRIEc<0xEC7D, (outs), (ins GR64:$R1, imm64zx8:$I2,
 174                                              brtarget16:$RI4),
 175                         "clgij"##name##"\t$R1, $I2, $RI4", []>;
 176   }
 177 }
 178 multiclass IntCondExtendedMnemonic<bits<4> ccmask, string name1, string name2>
 179   : IntCondExtendedMnemonicA<ccmask, name1> {
 180   let isAsmParserOnly = 1 in
 181     defm Alt : IntCondExtendedMnemonicA<ccmask, name2>;
 182 }
 183 defm AsmJH   : IntCondExtendedMnemonic<2,  "h",  "nle">;
 184 defm AsmJL   : IntCondExtendedMnemonic<4,  "l",  "nhe">;
 185 defm AsmJLH  : IntCondExtendedMnemonic<6,  "lh", "ne">;
 186 defm AsmJE   : IntCondExtendedMnemonic<8,  "e",  "nlh">;
 187 defm AsmJHE  : IntCondExtendedMnemonic<10, "he", "nl">;
 188 defm AsmJLE  : IntCondExtendedMnemonic<12, "le", "nh">;
 189
 190 // Decrement a register and branch if it is nonzero.  These don't clobber CC,
 191 // but we might need to split long branches into sequences that do.
 192 let Defs = [CC] in {
 193   def BRCT  : BranchUnaryRI<"brct",  0xA76, GR32>;
 194   def BRCTG : BranchUnaryRI<"brctg", 0xA77, GR64>;
 195 }
 196
 197 //===----------------------------------------------------------------------===//
 198 // Select instructions
 199 //===----------------------------------------------------------------------===//
 200
 201 def Select32 : SelectWrapper<GR32>;
 202 def Select64 : SelectWrapper<GR64>;
 203
 204 defm CondStore8  : CondStores<GR32, nonvolatile_truncstorei8,
 205                               nonvolatile_anyextloadi8, bdxaddr20only>;
 206 defm CondStore16 : CondStores<GR32, nonvolatile_truncstorei16,
 207                               nonvolatile_anyextloadi16, bdxaddr20only>;
 208 defm CondStore32 : CondStores<GR32, nonvolatile_store,
 209                               nonvolatile_load, bdxaddr20only>;
 210
 211 defm : CondStores64<CondStore8, CondStore8Inv, nonvolatile_truncstorei8,
 212                     nonvolatile_anyextloadi8, bdxaddr20only>;
 213 defm : CondStores64<CondStore16, CondStore16Inv, nonvolatile_truncstorei16,
 214                     nonvolatile_anyextloadi16, bdxaddr20only>;
 215 defm : CondStores64<CondStore32, CondStore32Inv, nonvolatile_truncstorei32,
 216                     nonvolatile_anyextloadi32, bdxaddr20only>;
 217 defm CondStore64 : CondStores<GR64, nonvolatile_store,
 218                               nonvolatile_load, bdxaddr20only>;
 219
 220 //===----------------------------------------------------------------------===//
 221 // Call instructions
 222 //===----------------------------------------------------------------------===//
 223
 224 // The definitions here are for the call-clobbered registers.
 225 let isCall = 1, Defs = [R0D, R1D, R2D, R3D, R4D, R5D, R14D,
 226                         F0D, F1D, F2D, F3D, F4D, F5D, F6D, F7D, CC] in {
 227   def CallBRASL : Alias<6, (outs), (ins pcrel32:$I2, variable_ops),
 228                         [(z_call pcrel32:$I2)]>;
 229   def CallBASR  : Alias<2, (outs), (ins ADDR64:$R2, variable_ops),
 230                         [(z_call ADDR64:$R2)]>;
 231 }
 232
 233 // Sibling calls.  Indirect sibling calls must be via R1, since R2 upwards
 234 // are argument registers and since branching to R0 is a no-op.
 235 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1 in {
 236   def CallJG : Alias<6, (outs), (ins pcrel32:$I2),
 237                      [(z_sibcall pcrel32:$I2)]>;
 238   let Uses = [R1D] in
 239     def CallBR : Alias<2, (outs), (ins), [(z_sibcall R1D)]>;
 240 }
 241
 242 // Define the general form of the call instructions for the asm parser.
 243 // These instructions don't hard-code %r14 as the return address register.
 244 def BRAS  : InstRI<0xA75, (outs), (ins GR64:$R1, brtarget16:$I2),
 245                    "bras\t$R1, $I2", []>;
 246 def BRASL : InstRIL<0xC05, (outs), (ins GR64:$R1, brtarget32:$I2),
 247                     "brasl\t$R1, $I2", []>;
 248 def BASR  : InstRR<0x0D, (outs), (ins GR64:$R1, ADDR64:$R2),
 249                    "basr\t$R1, $R2", []>;
 250
 251 //===----------------------------------------------------------------------===//
 252 // Move instructions
 253 //===----------------------------------------------------------------------===//
 254
 255 // Register moves.
 256 let neverHasSideEffects = 1 in {
 257   def LR  : UnaryRR <"l",  0x18,   null_frag, GR32, GR32>;
 258   def LGR : UnaryRRE<"lg", 0xB904, null_frag, GR64, GR64>;
 259 }
 260 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in {
 261   def LTR  : UnaryRR <"lt",  0x12,   null_frag, GR32, GR32>;
 262   def LTGR : UnaryRRE<"ltg", 0xB902, null_frag, GR64, GR64>;
 263 }
 264
 265 // Move on condition.
 266 let isCodeGenOnly = 1, Uses = [CC] in {
 267   def LOCR  : CondUnaryRRF<"loc",  0xB9F2, GR32, GR32>;
 268   def LOCGR : CondUnaryRRF<"locg", 0xB9E2, GR64, GR64>;
 269 }
 270 let Uses = [CC] in {
 271   def AsmLOCR  : AsmCondUnaryRRF<"loc",  0xB9F2, GR32, GR32>;
 272   def AsmLOCGR : AsmCondUnaryRRF<"locg", 0xB9E2, GR64, GR64>;
 273 }
 274
 275 // Immediate moves.
 276 let neverHasSideEffects = 1, isAsCheapAsAMove = 1, isMoveImm = 1,
 277     isReMaterializable = 1 in {
 278   // 16-bit sign-extended immediates.
 279   def LHI  : UnaryRI<"lhi",  0xA78, bitconvert, GR32, imm32sx16>;
 280   def LGHI : UnaryRI<"lghi", 0xA79, bitconvert, GR64, imm64sx16>;
 281
 282   // Other 16-bit immediates.
 283   def LLILL : UnaryRI<"llill", 0xA5F, bitconvert, GR64, imm64ll16>;
 284   def LLILH : UnaryRI<"llilh", 0xA5E, bitconvert, GR64, imm64lh16>;
 285   def LLIHL : UnaryRI<"llihl", 0xA5D, bitconvert, GR64, imm64hl16>;
 286   def LLIHH : UnaryRI<"llihh", 0xA5C, bitconvert, GR64, imm64hh16>;
 287
 288   // 32-bit immediates.
 289   def LGFI  : UnaryRIL<"lgfi",  0xC01, bitconvert, GR64, imm64sx32>;
 290   def LLILF : UnaryRIL<"llilf", 0xC0F, bitconvert, GR64, imm64lf32>;
 291   def LLIHF : UnaryRIL<"llihf", 0xC0E, bitconvert, GR64, imm64hf32>;
 292 }
 293
 294 // Register loads.
 295 let canFoldAsLoad = 1, SimpleBDXLoad = 1 in {
 296   defm L : UnaryRXPair<"l", 0x58, 0xE358, load, GR32, 4>;
 297   def LG : UnaryRXY<"lg", 0xE304, load, GR64, 8>;
 298
 299   // These instructions are split after register allocation, so we don't
 300   // want a custom inserter.
 301   let Has20BitOffset = 1, HasIndex = 1, Is128Bit = 1 in {
 302     def L128 : Pseudo<(outs GR128:$dst), (ins bdxaddr20only128:$src),
 303                       [(set GR128:$dst, (load bdxaddr20only128:$src))]>;
 304   }
 305 }
 306 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in {
 307   def LT  : UnaryRXY<"lt",  0xE312, load, GR32, 4>;
 308   def LTG : UnaryRXY<"ltg", 0xE302, load, GR64, 8>;
 309 }
 310
 311 let canFoldAsLoad = 1 in {
 312   def LRL  : UnaryRILPC<"lrl",  0xC4D, aligned_load, GR32>;
 313   def LGRL : UnaryRILPC<"lgrl", 0xC48, aligned_load, GR64>;
 314 }
 315
 316 // Load on condition.
 317 let isCodeGenOnly = 1, Uses = [CC] in {
 318   def LOC  : CondUnaryRSY<"loc",  0xEBF2, nonvolatile_load, GR32, 4>;
 319   def LOCG : CondUnaryRSY<"locg", 0xEBE2, nonvolatile_load, GR64, 8>;
 320 }
 321 let Uses = [CC] in {
 322   def AsmLOC  : AsmCondUnaryRSY<"loc",  0xEBF2, GR32, 4>;
 323   def AsmLOCG : AsmCondUnaryRSY<"locg", 0xEBE2, GR64, 8>;
 324 }
 325
 326 // Register stores.
 327 let SimpleBDXStore = 1 in {
 328   defm ST : StoreRXPair<"st", 0x50, 0xE350, store, GR32, 4>;
 329   def STG : StoreRXY<"stg", 0xE324, store, GR64, 8>;
 330
 331   // These instructions are split after register allocation, so we don't
 332   // want a custom inserter.
 333   let Has20BitOffset = 1, HasIndex = 1, Is128Bit = 1 in {
 334     def ST128 : Pseudo<(outs), (ins GR128:$src, bdxaddr20only128:$dst),
 335                        [(store GR128:$src, bdxaddr20only128:$dst)]>;
 336   }
 337 }
 338 def STRL  : StoreRILPC<"strl", 0xC4F, aligned_store, GR32>;
 339 def STGRL : StoreRILPC<"stgrl", 0xC4B, aligned_store, GR64>;
 340
 341 // Store on condition.
 342 let isCodeGenOnly = 1, Uses = [CC] in {
 343   def STOC  : CondStoreRSY<"stoc",  0xEBF3, GR32, 4>;
 344   def STOCG : CondStoreRSY<"stocg", 0xEBE3, GR64, 8>;
 345 }
 346 let Uses = [CC] in {
 347   def AsmSTOC  : AsmCondStoreRSY<"stoc",  0xEBF3, GR32, 4>;
 348   def AsmSTOCG : AsmCondStoreRSY<"stocg", 0xEBE3, GR64, 8>;
 349 }
 350
 351 // 8-bit immediate stores to 8-bit fields.
 352 defm MVI : StoreSIPair<"mvi", 0x92, 0xEB52, truncstorei8, imm32zx8trunc>;
 353
 354 // 16-bit immediate stores to 16-, 32- or 64-bit fields.
 355 def MVHHI : StoreSIL<"mvhhi", 0xE544, truncstorei16, imm32sx16trunc>;
 356 def MVHI  : StoreSIL<"mvhi",  0xE54C, store,         imm32sx16>;
 357 def MVGHI : StoreSIL<"mvghi", 0xE548, store,         imm64sx16>;
 358
 359 // Memory-to-memory moves.
 360 let mayLoad = 1, mayStore = 1 in
 361   defm MVC : MemorySS<"mvc", 0xD2, z_mvc, z_mvc_loop>;
 362
 363 // String moves.
 364 let mayLoad = 1, mayStore = 1, Defs = [CC], Uses = [R0L] in
 365   defm MVST : StringRRE<"mvst", 0xB255, z_stpcpy>;
 366
 367 //===----------------------------------------------------------------------===//
 368 // Sign extensions
 369 //===----------------------------------------------------------------------===//
 370 //
 371 // Note that putting these before zero extensions mean that we will prefer
 372 // them for anyextload*.  There's not really much to choose between the two
 373 // either way, but signed-extending loads have a short LH and a long LHY,
 374 // while zero-extending loads have only the long LLH.
 375 //
 376 //===----------------------------------------------------------------------===//
 377
 378 // 32-bit extensions from registers.
 379 let neverHasSideEffects = 1 in {
 380   def LBR : UnaryRRE<"lb", 0xB926, sext8,  GR32, GR32>;
 381   def LHR : UnaryRRE<"lh", 0xB927, sext16, GR32, GR32>;
 382 }
 383
 384 // 64-bit extensions from registers.
 385 let neverHasSideEffects = 1 in {
 386   def LGBR : UnaryRRE<"lgb", 0xB906, sext8,  GR64, GR64>;
 387   def LGHR : UnaryRRE<"lgh", 0xB907, sext16, GR64, GR64>;
 388   def LGFR : UnaryRRE<"lgf", 0xB914, sext32, GR64, GR32>;
 389 }
 390 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in
 391   def LTGFR : UnaryRRE<"ltgf", 0xB912, null_frag, GR64, GR64>;
 392
 393 // Match 32-to-64-bit sign extensions in which the source is already
 394 // in a 64-bit register.
 395 def : Pat<(sext_inreg GR64:$src, i32),
 396           (LGFR (EXTRACT_SUBREG GR64:$src, subreg_l32))>;
 397
 398 // 32-bit extensions from memory.
 399 def  LB   : UnaryRXY<"lb", 0xE376, asextloadi8, GR32, 1>;
 400 defm LH   : UnaryRXPair<"lh", 0x48, 0xE378, asextloadi16, GR32, 2>;
 401 def  LHRL : UnaryRILPC<"lhrl", 0xC45, aligned_asextloadi16, GR32>;
 402
 403 // 64-bit extensions from memory.
 404 def LGB   : UnaryRXY<"lgb", 0xE377, asextloadi8,  GR64, 1>;
 405 def LGH   : UnaryRXY<"lgh", 0xE315, asextloadi16, GR64, 2>;
 406 def LGF   : UnaryRXY<"lgf", 0xE314, asextloadi32, GR64, 4>;
 407 def LGHRL : UnaryRILPC<"lghrl", 0xC44, aligned_asextloadi16, GR64>;
 408 def LGFRL : UnaryRILPC<"lgfrl", 0xC4C, aligned_asextloadi32, GR64>;
 409 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in
 410   def LTGF : UnaryRXY<"ltgf", 0xE332, asextloadi32, GR64, 4>;
 411
 412 //===----------------------------------------------------------------------===//
 413 // Zero extensions
 414 //===----------------------------------------------------------------------===//
 415
 416 // 32-bit extensions from registers.
 417 let neverHasSideEffects = 1 in {
 418   def LLCR : UnaryRRE<"llc", 0xB994, zext8,  GR32, GR32>;
 419   def LLHR : UnaryRRE<"llh", 0xB995, zext16, GR32, GR32>;
 420 }
 421
 422 // 64-bit extensions from registers.
 423 let neverHasSideEffects = 1 in {
 424   def LLGCR : UnaryRRE<"llgc", 0xB984, zext8,  GR64, GR64>;
 425   def LLGHR : UnaryRRE<"llgh", 0xB985, zext16, GR64, GR64>;
 426   def LLGFR : UnaryRRE<"llgf", 0xB916, zext32, GR64, GR32>;
 427 }
 428
 429 // Match 32-to-64-bit zero extensions in which the source is already
 430 // in a 64-bit register.
 431 def : Pat<(and GR64:$src, 0xffffffff),
 432           (LLGFR (EXTRACT_SUBREG GR64:$src, subreg_l32))>;
 433
 434 // 32-bit extensions from memory.
 435 def LLC   : UnaryRXY<"llc", 0xE394, azextloadi8,  GR32, 1>;
 436 def LLH   : UnaryRXY<"llh", 0xE395, azextloadi16, GR32, 2>;
 437 def LLHRL : UnaryRILPC<"llhrl", 0xC42, aligned_azextloadi16, GR32>;
 438
 439 // 64-bit extensions from memory.
 440 def LLGC   : UnaryRXY<"llgc", 0xE390, azextloadi8,  GR64, 1>;
 441 def LLGH   : UnaryRXY<"llgh", 0xE391, azextloadi16, GR64, 2>;
 442 def LLGF   : UnaryRXY<"llgf", 0xE316, azextloadi32, GR64, 4>;
 443 def LLGHRL : UnaryRILPC<"llghrl", 0xC46, aligned_azextloadi16, GR64>;
 444 def LLGFRL : UnaryRILPC<"llgfrl", 0xC4E, aligned_azextloadi32, GR64>;
 445
 446 //===----------------------------------------------------------------------===//
 447 // Truncations
 448 //===----------------------------------------------------------------------===//
 449
 450 // Truncations of 64-bit registers to 32-bit registers.
 451 def : Pat<(i32 (trunc GR64:$src)),
 452           (EXTRACT_SUBREG GR64:$src, subreg_l32)>;
 453
 454 // Truncations of 32-bit registers to memory.
 455 defm STC   : StoreRXPair<"stc", 0x42, 0xE372, truncstorei8,  GR32, 1>;
 456 defm STH   : StoreRXPair<"sth", 0x40, 0xE370, truncstorei16, GR32, 2>;
 457 def  STHRL : StoreRILPC<"sthrl", 0xC47, aligned_truncstorei16, GR32>;
 458
 459 // Truncations of 64-bit registers to memory.
 460 defm : StoreGR64Pair<STC, STCY, truncstorei8>;
 461 defm : StoreGR64Pair<STH, STHY, truncstorei16>;
 462 def  : StoreGR64PC<STHRL, aligned_truncstorei16>;
 463 defm : StoreGR64Pair<ST, STY, truncstorei32>;
 464 def  : StoreGR64PC<STRL, aligned_truncstorei32>;
 465
 466 //===----------------------------------------------------------------------===//
 467 // Multi-register moves
 468 //===----------------------------------------------------------------------===//
 469
 470 // Multi-register loads.
 471 def LMG : LoadMultipleRSY<"lmg", 0xEB04, GR64>;
 472
 473 // Multi-register stores.
 474 def STMG : StoreMultipleRSY<"stmg", 0xEB24, GR64>;
 475
 476 //===----------------------------------------------------------------------===//
 477 // Byte swaps
 478 //===----------------------------------------------------------------------===//
 479
 480 // Byte-swapping register moves.
 481 let neverHasSideEffects = 1 in {
 482   def LRVR  : UnaryRRE<"lrv",  0xB91F, bswap, GR32, GR32>;
 483   def LRVGR : UnaryRRE<"lrvg", 0xB90F, bswap, GR64, GR64>;
 484 }
 485
 486 // Byte-swapping loads.  Unlike normal loads, these instructions are
 487 // allowed to access storage more than once.
 488 def LRV  : UnaryRXY<"lrv",  0xE31E, loadu<bswap, nonvolatile_load>, GR32, 4>;
 489 def LRVG : UnaryRXY<"lrvg", 0xE30F, loadu<bswap, nonvolatile_load>, GR64, 8>;
 490
 491 // Likewise byte-swapping stores.
 492 def STRV  : StoreRXY<"strv", 0xE33E, storeu<bswap, nonvolatile_store>, GR32, 4>;
 493 def STRVG : StoreRXY<"strvg", 0xE32F, storeu<bswap, nonvolatile_store>,
 494                      GR64, 8>;
 495
 496 //===----------------------------------------------------------------------===//
 497 // Load address instructions
 498 //===----------------------------------------------------------------------===//
 499
 500 // Load BDX-style addresses.
 501 let neverHasSideEffects = 1, isAsCheapAsAMove = 1, isReMaterializable = 1,
 502     DispKey = "la" in {
 503   let DispSize = "12" in
 504     def LA : InstRX<0x41, (outs GR64:$R1), (ins laaddr12pair:$XBD2),
 505                     "la\t$R1, $XBD2",
 506                     [(set GR64:$R1, laaddr12pair:$XBD2)]>;
 507   let DispSize = "20" in
 508     def LAY : InstRXY<0xE371, (outs GR64:$R1), (ins laaddr20pair:$XBD2),
 509                       "lay\t$R1, $XBD2",
 510                       [(set GR64:$R1, laaddr20pair:$XBD2)]>;
 511 }
 512
 513 // Load a PC-relative address.  There's no version of this instruction
 514 // with a 16-bit offset, so there's no relaxation.
 515 let neverHasSideEffects = 1, isAsCheapAsAMove = 1, isMoveImm = 1,
 516     isReMaterializable = 1 in {
 517   def LARL : InstRIL<0xC00, (outs GR64:$R1), (ins pcrel32:$I2),
 518                      "larl\t$R1, $I2",
 519                      [(set GR64:$R1, pcrel32:$I2)]>;
 520 }
 521
 522 //===----------------------------------------------------------------------===//
 523 // Absolute and Negation
 524 //===----------------------------------------------------------------------===//
 525
 526 let Defs = [CC] in {
 527   let CCValues = 0xF, CompareZeroCCMask = 0x8 in {
 528     def LPR  : UnaryRR <"lp",  0x10,   z_iabs32, GR32, GR32>;
 529     def LPGR : UnaryRRE<"lpg", 0xB900, z_iabs64, GR64, GR64>;
 530   }
 531   let CCValues = 0xE, CompareZeroCCMask = 0xE in
 532     def LPGFR : UnaryRRE<"lpgf", 0xB910, null_frag, GR64, GR32>;
 533 }
 534 defm : SXU<z_iabs64, LPGFR>;
 535
 536 let Defs = [CC] in {
 537   let CCValues = 0xF, CompareZeroCCMask = 0x8 in {
 538     def LNR  : UnaryRR <"ln",  0x11,   z_inegabs32, GR32, GR32>;
 539     def LNGR : UnaryRRE<"lng", 0xB901, z_inegabs64, GR64, GR64>;
 540   }
 541   let CCValues = 0xE, CompareZeroCCMask = 0xE in
 542     def LNGFR : UnaryRRE<"lngf", 0xB911, null_frag, GR64, GR32>;
 543 }
 544 defm : SXU<z_inegabs64, LNGFR>;
 545
 546 let Defs = [CC] in {
 547   let CCValues = 0xF, CompareZeroCCMask = 0x8 in {
 548     def LCR  : UnaryRR <"lc",  0x13,   ineg, GR32, GR32>;
 549     def LCGR : UnaryRRE<"lcg", 0xB903, ineg, GR64, GR64>;
 550   }
 551   let CCValues = 0xE, CompareZeroCCMask = 0xE in
 552     def LCGFR : UnaryRRE<"lcgf", 0xB913, null_frag, GR64, GR32>;
 553 }
 554 defm : SXU<ineg, LCGFR>;
 555
 556 //===----------------------------------------------------------------------===//
 557 // Insertion
 558 //===----------------------------------------------------------------------===//
 559
 560 let isCodeGenOnly = 1 in
 561   defm IC32 : BinaryRXPair<"ic", 0x43, 0xE373, inserti8, GR32, azextloadi8, 1>;
 562 defm IC : BinaryRXPair<"ic", 0x43, 0xE373, inserti8, GR64, azextloadi8, 1>;
 563
 564 defm : InsertMem<"inserti8", IC32,  GR32, azextloadi8, bdxaddr12pair>;
 565 defm : InsertMem<"inserti8", IC32Y, GR32, azextloadi8, bdxaddr20pair>;
 566
 567 defm : InsertMem<"inserti8", IC,  GR64, azextloadi8, bdxaddr12pair>;
 568 defm : InsertMem<"inserti8", ICY, GR64, azextloadi8, bdxaddr20pair>;
 569
 570 // Insertions of a 16-bit immediate, leaving other bits unaffected.
 571 // We don't have or_as_insert equivalents of these operations because
 572 // OI is available instead.
 573 def IILL : BinaryRI<"iill", 0xA53, insertll, GR32, imm32ll16>;
 574 def IILH : BinaryRI<"iilh", 0xA52, insertlh, GR32, imm32lh16>;
 575 def IILL64 : BinaryAliasRI<insertll, GR64, imm64ll16>;
 576 def IILH64 : BinaryAliasRI<insertlh, GR64, imm64lh16>;
 577 def IIHL : BinaryRI<"iihl", 0xA51, inserthl, GR64, imm64hl16>;
 578 def IIHH : BinaryRI<"iihh", 0xA50, inserthh, GR64, imm64hh16>;
 579
 580 // ...likewise for 32-bit immediates.  For GR32s this is a general
 581 // full-width move.  (We use IILF rather than something like LLILF
 582 // for 32-bit moves because IILF leaves the upper 32 bits of the
 583 // GR64 unchanged.)
 584 let isAsCheapAsAMove = 1, isMoveImm = 1, isReMaterializable = 1 in
 585   def IILF : UnaryRIL<"iilf", 0xC09, bitconvert, GR32, uimm32>;
 586 def IILF64 : BinaryAliasRIL<insertlf, GR64, imm64lf32>;
 587 def IIHF : BinaryRIL<"iihf", 0xC08, inserthf, GR64, imm64hf32>;
 588
 589 // An alternative model of inserthf, with the first operand being
 590 // a zero-extended value.
 591 def : Pat<(or (zext32 GR32:$src), imm64hf32:$imm),
 592           (IIHF (INSERT_SUBREG (i64 (IMPLICIT_DEF)), GR32:$src, subreg_l32),
 593                 imm64hf32:$imm)>;
 594
 595 //===----------------------------------------------------------------------===//
 596 // Addition
 597 //===----------------------------------------------------------------------===//
 598
 599 // Plain addition.
 600 let Defs = [CC], CCValues = 0xF, CompareZeroCCMask = 0x8 in {
 601   // Addition of a register.
 602   let isCommutable = 1 in {
 603     defm AR : BinaryRRAndK<"a", 0x1A, 0xB9F8, add, GR32, GR32>;
 604     defm AGR : BinaryRREAndK<"ag", 0xB908, 0xB9E8, add, GR64, GR64>;
 605   }
 606   def AGFR : BinaryRRE<"agf", 0xB918, null_frag, GR64, GR32>;
 607
 608   // Addition of signed 16-bit immediates.
 609   defm AHI  : BinaryRIAndK<"ahi",  0xA7A, 0xECD8, add, GR32, imm32sx16>;
 610   defm AGHI : BinaryRIAndK<"aghi", 0xA7B, 0xECD9, add, GR64, imm64sx16>;
 611
 612   // Addition of signed 32-bit immediates.
 613   def AFI  : BinaryRIL<"afi",  0xC29, add, GR32, simm32>;
 614   def AGFI : BinaryRIL<"agfi", 0xC28, add, GR64, imm64sx32>;
 615
 616   // Addition of memory.
 617   defm AH  : BinaryRXPair<"ah", 0x4A, 0xE37A, add, GR32, asextloadi16, 2>;
 618   defm A   : BinaryRXPair<"a",  0x5A, 0xE35A, add, GR32, load, 4>;
 619   def  AGF : BinaryRXY<"agf", 0xE318, add, GR64, asextloadi32, 4>;
 620   def  AG  : BinaryRXY<"ag",  0xE308, add, GR64, load, 8>;
 621
 622   // Addition to memory.
 623   def ASI  : BinarySIY<"asi",  0xEB6A, add, imm32sx8>;
 624   def AGSI : BinarySIY<"agsi", 0xEB7A, add, imm64sx8>;
 625 }
 626 defm : SXB<add, GR64, AGFR>;
 627
 628 // Addition producing a carry.
 629 let Defs = [CC] in {
 630   // Addition of a register.
 631   let isCommutable = 1 in {
 632     defm ALR : BinaryRRAndK<"al", 0x1E, 0xB9FA, addc, GR32, GR32>;
 633     defm ALGR : BinaryRREAndK<"alg", 0xB90A, 0xB9EA, addc, GR64, GR64>;
 634   }
 635   def ALGFR : BinaryRRE<"algf", 0xB91A, null_frag, GR64, GR32>;
 636
 637   // Addition of signed 16-bit immediates.
 638   def ALHSIK  : BinaryRIE<"alhsik",  0xECDA, addc, GR32, imm32sx16>,
 639                 Requires<[FeatureDistinctOps]>;
 640   def ALGHSIK : BinaryRIE<"alghsik", 0xECDB, addc, GR64, imm64sx16>,
 641                 Requires<[FeatureDistinctOps]>;
 642
 643   // Addition of unsigned 32-bit immediates.
 644   def ALFI  : BinaryRIL<"alfi",  0xC2B, addc, GR32, uimm32>;
 645   def ALGFI : BinaryRIL<"algfi", 0xC2A, addc, GR64, imm64zx32>;
 646
 647   // Addition of memory.
 648   defm AL   : BinaryRXPair<"al", 0x5E, 0xE35E, addc, GR32, load, 4>;
 649   def  ALGF : BinaryRXY<"algf", 0xE31A, addc, GR64, azextloadi32, 4>;
 650   def  ALG  : BinaryRXY<"alg",  0xE30A, addc, GR64, load, 8>;
 651 }
 652 defm : ZXB<addc, GR64, ALGFR>;
 653
 654 // Addition producing and using a carry.
 655 let Defs = [CC], Uses = [CC] in {
 656   // Addition of a register.
 657   def ALCR  : BinaryRRE<"alc",  0xB998, adde, GR32, GR32>;
 658   def ALCGR : BinaryRRE<"alcg", 0xB988, adde, GR64, GR64>;
 659
 660   // Addition of memory.
 661   def ALC  : BinaryRXY<"alc",  0xE398, adde, GR32, load, 4>;
 662   def ALCG : BinaryRXY<"alcg", 0xE388, adde, GR64, load, 8>;
 663 }
 664
 665 //===----------------------------------------------------------------------===//
 666 // Subtraction
 667 //===----------------------------------------------------------------------===//
 668
 669 // Plain substraction.  Although immediate forms exist, we use the
 670 // add-immediate instruction instead.
 671 let Defs = [CC], CCValues = 0xF, CompareZeroCCMask = 0x8 in {
 672   // Subtraction of a register.
 673   defm SR : BinaryRRAndK<"s", 0x1B, 0xB9F9, sub, GR32, GR32>;
 674   def SGFR : BinaryRRE<"sgf", 0xB919, null_frag, GR64, GR32>;
 675   defm SGR : BinaryRREAndK<"sg", 0xB909, 0xB9E9, sub, GR64, GR64>;
 676
 677   // Subtraction of memory.
 678   defm SH  : BinaryRXPair<"sh", 0x4B, 0xE37B, sub, GR32, asextloadi16, 2>;
 679   defm S   : BinaryRXPair<"s", 0x5B, 0xE35B, sub, GR32, load, 4>;
 680   def  SGF : BinaryRXY<"sgf", 0xE319, sub, GR64, asextloadi32, 4>;
 681   def  SG  : BinaryRXY<"sg",  0xE309, sub, GR64, load, 8>;
 682 }
 683 defm : SXB<sub, GR64, SGFR>;
 684
 685 // Subtraction producing a carry.
 686 let Defs = [CC] in {
 687   // Subtraction of a register.
 688   defm SLR : BinaryRRAndK<"sl", 0x1F, 0xB9FB, subc, GR32, GR32>;
 689   def SLGFR : BinaryRRE<"slgf", 0xB91B, null_frag, GR64, GR32>;
 690   defm SLGR : BinaryRREAndK<"slg", 0xB90B, 0xB9EB, subc, GR64, GR64>;
 691
 692   // Subtraction of unsigned 32-bit immediates.  These don't match
 693   // subc because we prefer addc for constants.
 694   def SLFI  : BinaryRIL<"slfi",  0xC25, null_frag, GR32, uimm32>;
 695   def SLGFI : BinaryRIL<"slgfi", 0xC24, null_frag, GR64, imm64zx32>;
 696
 697   // Subtraction of memory.
 698   defm SL   : BinaryRXPair<"sl", 0x5F, 0xE35F, subc, GR32, load, 4>;
 699   def  SLGF : BinaryRXY<"slgf", 0xE31B, subc, GR64, azextloadi32, 4>;
 700   def  SLG  : BinaryRXY<"slg",  0xE30B, subc, GR64, load, 8>;
 701 }
 702 defm : ZXB<subc, GR64, SLGFR>;
 703
 704 // Subtraction producing and using a carry.
 705 let Defs = [CC], Uses = [CC] in {
 706   // Subtraction of a register.
 707   def SLBR  : BinaryRRE<"slb",  0xB999, sube, GR32, GR32>;
 708   def SLGBR : BinaryRRE<"slbg", 0xB989, sube, GR64, GR64>;
 709
 710   // Subtraction of memory.
 711   def SLB  : BinaryRXY<"slb",  0xE399, sube, GR32, load, 4>;
 712   def SLBG : BinaryRXY<"slbg", 0xE389, sube, GR64, load, 8>;
 713 }
 714
 715 //===----------------------------------------------------------------------===//
 716 // AND
 717 //===----------------------------------------------------------------------===//
 718
 719 let Defs = [CC] in {
 720   // ANDs of a register.
 721   let isCommutable = 1, CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 722     defm NR : BinaryRRAndK<"n", 0x14, 0xB9F4, and, GR32, GR32>;
 723     defm NGR : BinaryRREAndK<"ng", 0xB980, 0xB9E4, and, GR64, GR64>;
 724   }
 725
 726   let isConvertibleToThreeAddress = 1 in {
 727     // ANDs of a 16-bit immediate, leaving other bits unaffected.
 728     // The CC result only reflects the 16-bit field, not the full register.
 729     def NILL : BinaryRI<"nill", 0xA57, and, GR32, imm32ll16c>;
 730     def NILH : BinaryRI<"nilh", 0xA56, and, GR32, imm32lh16c>;
 731     def NILL64 : BinaryAliasRI<and, GR64, imm64ll16c>;
 732     def NILH64 : BinaryAliasRI<and, GR64, imm64lh16c>;
 733     def NIHL : BinaryRI<"nihl", 0xA55, and, GR64, imm64hl16c>;
 734     def NIHH : BinaryRI<"nihh", 0xA54, and, GR64, imm64hh16c>;
 735
 736     // ANDs of a 32-bit immediate, leaving other bits unaffected.
 737     // The CC result only reflects the 32-bit field, which means we can
 738     // use it as a zero indicator for i32 operations but not otherwise.
 739     let CCValues = 0xC, CompareZeroCCMask = 0x8 in
 740       def NILF : BinaryRIL<"nilf", 0xC0B, and, GR32, uimm32>;
 741     def NILF64 : BinaryAliasRIL<and, GR64, imm64lf32c>;
 742     def NIHF : BinaryRIL<"nihf", 0xC0A, and, GR64, imm64hf32c>;
 743   }
 744
 745   // ANDs of memory.
 746   let CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 747     defm N  : BinaryRXPair<"n", 0x54, 0xE354, and, GR32, load, 4>;
 748     def  NG : BinaryRXY<"ng", 0xE380, and, GR64, load, 8>;
 749   }
 750
 751   // AND to memory
 752   defm NI : BinarySIPair<"ni", 0x94, 0xEB54, null_frag, uimm8>;
 753
 754   // Block AND.
 755   let mayLoad = 1, mayStore = 1 in
 756     defm NC : MemorySS<"nc", 0xD4, z_nc, z_nc_loop>;
 757 }
 758 defm : RMWIByte<and, bdaddr12pair, NI>;
 759 defm : RMWIByte<and, bdaddr20pair, NIY>;
 760
 761 //===----------------------------------------------------------------------===//
 762 // OR
 763 //===----------------------------------------------------------------------===//
 764
 765 let Defs = [CC] in {
 766   // ORs of a register.
 767   let isCommutable = 1, CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 768     defm OR : BinaryRRAndK<"o", 0x16, 0xB9F6, or, GR32, GR32>;
 769     defm OGR : BinaryRREAndK<"og", 0xB981, 0xB9E6, or, GR64, GR64>;
 770   }
 771
 772   // ORs of a 16-bit immediate, leaving other bits unaffected.
 773   // The CC result only reflects the 16-bit field, not the full register.
 774   def OILL : BinaryRI<"oill", 0xA5B, or, GR32, imm32ll16>;
 775   def OILH : BinaryRI<"oilh", 0xA5A, or, GR32, imm32lh16>;
 776   def OILL64 : BinaryAliasRI<or, GR64, imm64ll16>;
 777   def OILH64 : BinaryAliasRI<or, GR64, imm64lh16>;
 778   def OIHL : BinaryRI<"oihl", 0xA59, or, GR64, imm64hl16>;
 779   def OIHH : BinaryRI<"oihh", 0xA58, or, GR64, imm64hh16>;
 780
 781   // ORs of a 32-bit immediate, leaving other bits unaffected.
 782   // The CC result only reflects the 32-bit field, which means we can
 783   // use it as a zero indicator for i32 operations but not otherwise.
 784   let CCValues = 0xC, CompareZeroCCMask = 0x8 in
 785     def OILF : BinaryRIL<"oilf", 0xC0D, or, GR32, uimm32>;
 786   def OILF64 : BinaryAliasRIL<or, GR64, imm64lf32>;
 787   def OIHF : BinaryRIL<"oihf", 0xC0C, or, GR64, imm64hf32>;
 788
 789   // ORs of memory.
 790   let CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 791     defm O  : BinaryRXPair<"o", 0x56, 0xE356, or, GR32, load, 4>;
 792     def  OG : BinaryRXY<"og", 0xE381, or, GR64, load, 8>;
 793   }
 794
 795   // OR to memory
 796   defm OI : BinarySIPair<"oi", 0x96, 0xEB56, null_frag, uimm8>;
 797
 798   // Block OR.
 799   let mayLoad = 1, mayStore = 1 in
 800     defm OC : MemorySS<"oc", 0xD6, z_oc, z_oc_loop>;
 801 }
 802 defm : RMWIByte<or, bdaddr12pair, OI>;
 803 defm : RMWIByte<or, bdaddr20pair, OIY>;
 804
 805 //===----------------------------------------------------------------------===//
 806 // XOR
 807 //===----------------------------------------------------------------------===//
 808
 809 let Defs = [CC] in {
 810   // XORs of a register.
 811   let isCommutable = 1, CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 812     defm XR : BinaryRRAndK<"x", 0x17, 0xB9F7, xor, GR32, GR32>;
 813     defm XGR : BinaryRREAndK<"xg", 0xB982, 0xB9E7, xor, GR64, GR64>;
 814   }
 815
 816   // XORs of a 32-bit immediate, leaving other bits unaffected.
 817   // The CC result only reflects the 32-bit field, which means we can
 818   // use it as a zero indicator for i32 operations but not otherwise.
 819   let CCValues = 0xC, CompareZeroCCMask = 0x8 in
 820     def XILF : BinaryRIL<"xilf", 0xC07, xor, GR32, uimm32>;
 821   def XILF64 : BinaryAliasRIL<xor, GR64, imm64lf32>;
 822   def XIHF : BinaryRIL<"xihf", 0xC06, xor, GR64, imm64hf32>;
 823
 824   // XORs of memory.
 825   let CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 826     defm X  : BinaryRXPair<"x",0x57, 0xE357, xor, GR32, load, 4>;
 827     def  XG : BinaryRXY<"xg", 0xE382, xor, GR64, load, 8>;
 828   }
 829
 830   // XOR to memory
 831   defm XI : BinarySIPair<"xi", 0x97, 0xEB57, null_frag, uimm8>;
 832
 833   // Block XOR.
 834   let mayLoad = 1, mayStore = 1 in
 835     defm XC : MemorySS<"xc", 0xD7, z_xc, z_xc_loop>;
 836 }
 837 defm : RMWIByte<xor, bdaddr12pair, XI>;
 838 defm : RMWIByte<xor, bdaddr20pair, XIY>;
 839
 840 //===----------------------------------------------------------------------===//
 841 // Multiplication
 842 //===----------------------------------------------------------------------===//
 843
 844 // Multiplication of a register.
 845 let isCommutable = 1 in {
 846   def MSR  : BinaryRRE<"ms",  0xB252, mul, GR32, GR32>;
 847   def MSGR : BinaryRRE<"msg", 0xB90C, mul, GR64, GR64>;
 848 }
 849 def MSGFR : BinaryRRE<"msgf", 0xB91C, null_frag, GR64, GR32>;
 850 defm : SXB<mul, GR64, MSGFR>;
 851
 852 // Multiplication of a signed 16-bit immediate.
 853 def MHI  : BinaryRI<"mhi",  0xA7C, mul, GR32, imm32sx16>;
 854 def MGHI : BinaryRI<"mghi", 0xA7D, mul, GR64, imm64sx16>;
 855
 856 // Multiplication of a signed 32-bit immediate.
 857 def MSFI  : BinaryRIL<"msfi",  0xC21, mul, GR32, simm32>;
 858 def MSGFI : BinaryRIL<"msgfi", 0xC20, mul, GR64, imm64sx32>;
 859
 860 // Multiplication of memory.
 861 defm MH   : BinaryRXPair<"mh", 0x4C, 0xE37C, mul, GR32, asextloadi16, 2>;
 862 defm MS   : BinaryRXPair<"ms", 0x71, 0xE351, mul, GR32, load, 4>;
 863 def  MSGF : BinaryRXY<"msgf", 0xE31C, mul, GR64, asextloadi32, 4>;
 864 def  MSG  : BinaryRXY<"msg",  0xE30C, mul, GR64, load, 8>;
 865
 866 // Multiplication of a register, producing two results.
 867 def MLGR : BinaryRRE<"mlg", 0xB986, z_umul_lohi64, GR128, GR64>;
 868
 869 // Multiplication of memory, producing two results.
 870 def MLG : BinaryRXY<"mlg", 0xE386, z_umul_lohi64, GR128, load, 8>;
 871
 872 //===----------------------------------------------------------------------===//
 873 // Division and remainder
 874 //===----------------------------------------------------------------------===//
 875
 876 // Division and remainder, from registers.
 877 def DSGFR : BinaryRRE<"dsgf", 0xB91D, z_sdivrem32, GR128, GR32>;
 878 def DSGR  : BinaryRRE<"dsg",  0xB90D, z_sdivrem64, GR128, GR64>;
 879 def DLR   : BinaryRRE<"dl",   0xB997, z_udivrem32, GR128, GR32>;
 880 def DLGR  : BinaryRRE<"dlg",  0xB987, z_udivrem64, GR128, GR64>;
 881
 882 // Division and remainder, from memory.
 883 def DSGF : BinaryRXY<"dsgf", 0xE31D, z_sdivrem32, GR128, load, 4>;
 884 def DSG  : BinaryRXY<"dsg",  0xE30D, z_sdivrem64, GR128, load, 8>;
 885 def DL   : BinaryRXY<"dl",   0xE397, z_udivrem32, GR128, load, 4>;
 886 def DLG  : BinaryRXY<"dlg",  0xE387, z_udivrem64, GR128, load, 8>;
 887
 888 //===----------------------------------------------------------------------===//
 889 // Shifts
 890 //===----------------------------------------------------------------------===//
 891
 892 // Shift left.
 893 let neverHasSideEffects = 1 in {
 894   defm SLL : ShiftRSAndK<"sll", 0x89, 0xEBDF, shl, GR32>;
 895   def SLLG : ShiftRSY<"sllg", 0xEB0D, shl, GR64>;
 896 }
 897
 898 // Logical shift right.
 899 let neverHasSideEffects = 1 in {
 900   defm SRL : ShiftRSAndK<"srl", 0x88, 0xEBDE, srl, GR32>;
 901   def SRLG : ShiftRSY<"srlg", 0xEB0C, srl, GR64>;
 902 }
 903
 904 // Arithmetic shift right.
 905 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in {
 906   defm SRA : ShiftRSAndK<"sra", 0x8A, 0xEBDC, sra, GR32>;
 907   def SRAG : ShiftRSY<"srag", 0xEB0A, sra, GR64>;
 908 }
 909
 910 // Rotate left.
 911 let neverHasSideEffects = 1 in {
 912   def RLL  : ShiftRSY<"rll",  0xEB1D, rotl, GR32>;
 913   def RLLG : ShiftRSY<"rllg", 0xEB1C, rotl, GR64>;
 914 }
 915
 916 // Rotate second operand left and inserted selected bits into first operand.
 917 // These can act like 32-bit operands provided that the constant start and
 918 // end bits (operands 2 and 3) are in the range [32, 64).
 919 let Defs = [CC] in {
 920   let isCodeGenOnly = 1 in
 921     def RISBG32 : RotateSelectRIEf<"risbg", 0xEC55, GR32, GR32>;
 922   let CCValues = 0xE, CompareZeroCCMask = 0xE in
 923     def RISBG : RotateSelectRIEf<"risbg", 0xEC55, GR64, GR64>;
 924 }
 925
 926 // Forms of RISBG that only affect one word of the destination register.
 927 // They do not set CC.
 928 let isCodeGenOnly = 1 in
 929   def RISBLG32 : RotateSelectRIEf<"risblg", 0xEC51, GR32, GR32>,
 930                  Requires<[FeatureHighWord]>;
 931 def RISBHG : RotateSelectRIEf<"risbhg", 0xEC5D, GRH32, GR64>,
 932              Requires<[FeatureHighWord]>;
 933 def RISBLG : RotateSelectRIEf<"risblg", 0xEC51, GR32, GR64>,
 934              Requires<[FeatureHighWord]>;
 935
 936 // Rotate second operand left and perform a logical operation with selected
 937 // bits of the first operand.  The CC result only describes the selected bits,
 938 // so isn't useful for a full comparison against zero.
 939 let Defs = [CC] in {
 940   def RNSBG : RotateSelectRIEf<"rnsbg", 0xEC54, GR64, GR64>;
 941   def ROSBG : RotateSelectRIEf<"rosbg", 0xEC56, GR64, GR64>;
 942   def RXSBG : RotateSelectRIEf<"rxsbg", 0xEC57, GR64, GR64>;
 943 }
 944
 945 //===----------------------------------------------------------------------===//
 946 // Comparison
 947 //===----------------------------------------------------------------------===//
 948
 949 // Signed comparisons.  We put these before the unsigned comparisons because
 950 // some of the signed forms have COMPARE AND BRANCH equivalents whereas none
 951 // of the unsigned forms do.
 952 let Defs = [CC], CCValues = 0xE in {
 953   // Comparison with a register.
 954   def CR   : CompareRR <"c",   0x19,   z_scmp,    GR32, GR32>;
 955   def CGFR : CompareRRE<"cgf", 0xB930, null_frag, GR64, GR32>;
 956   def CGR  : CompareRRE<"cg",  0xB920, z_scmp,    GR64, GR64>;
 957
 958   // Comparison with a signed 16-bit immediate.
 959   def CHI  : CompareRI<"chi",  0xA7E, z_scmp, GR32, imm32sx16>;
 960   def CGHI : CompareRI<"cghi", 0xA7F, z_scmp, GR64, imm64sx16>;
 961
 962   // Comparison with a signed 32-bit immediate.
 963   def CFI  : CompareRIL<"cfi",  0xC2D, z_scmp, GR32, simm32>;
 964   def CGFI : CompareRIL<"cgfi", 0xC2C, z_scmp, GR64, imm64sx32>;
 965
 966   // Comparison with memory.
 967   defm CH    : CompareRXPair<"ch", 0x49, 0xE379, z_scmp, GR32, asextloadi16, 2>;
 968   defm C     : CompareRXPair<"c",  0x59, 0xE359, z_scmp, GR32, load, 4>;
 969   def  CGH   : CompareRXY<"cgh", 0xE334, z_scmp, GR64, asextloadi16, 2>;
 970   def  CGF   : CompareRXY<"cgf", 0xE330, z_scmp, GR64, asextloadi32, 4>;
 971   def  CG    : CompareRXY<"cg",  0xE320, z_scmp, GR64, load, 8>;
 972   def  CHRL  : CompareRILPC<"chrl",  0xC65, z_scmp, GR32, aligned_asextloadi16>;
 973   def  CRL   : CompareRILPC<"crl",   0xC6D, z_scmp, GR32, aligned_load>;
 974   def  CGHRL : CompareRILPC<"cghrl", 0xC64, z_scmp, GR64, aligned_asextloadi16>;
 975   def  CGFRL : CompareRILPC<"cgfrl", 0xC6C, z_scmp, GR64, aligned_asextloadi32>;
 976   def  CGRL  : CompareRILPC<"cgrl",  0xC68, z_scmp, GR64, aligned_load>;
 977
 978   // Comparison between memory and a signed 16-bit immediate.
 979   def CHHSI : CompareSIL<"chhsi", 0xE554, z_scmp, asextloadi16, imm32sx16>;
 980   def CHSI  : CompareSIL<"chsi",  0xE55C, z_scmp, load, imm32sx16>;
 981   def CGHSI : CompareSIL<"cghsi", 0xE558, z_scmp, load, imm64sx16>;
 982 }
 983 defm : SXB<z_scmp, GR64, CGFR>;
 984
 985 // Unsigned comparisons.
 986 let Defs = [CC], CCValues = 0xE, IsLogical = 1 in {
 987   // Comparison with a register.
 988   def CLR   : CompareRR <"cl",   0x15,   z_ucmp,    GR32, GR32>;
 989   def CLGFR : CompareRRE<"clgf", 0xB931, null_frag, GR64, GR32>;
 990   def CLGR  : CompareRRE<"clg",  0xB921, z_ucmp,    GR64, GR64>;
 991
 992   // Comparison with a signed 32-bit immediate.
 993   def CLFI  : CompareRIL<"clfi",  0xC2F, z_ucmp, GR32, uimm32>;
 994   def CLGFI : CompareRIL<"clgfi", 0xC2E, z_ucmp, GR64, imm64zx32>;
 995
 996   // Comparison with memory.
 997   defm CL     : CompareRXPair<"cl", 0x55, 0xE355, z_ucmp, GR32, load, 4>;
 998   def  CLGF   : CompareRXY<"clgf", 0xE331, z_ucmp, GR64, azextloadi32, 4>;
 999   def  CLG    : CompareRXY<"clg",  0xE321, z_ucmp, GR64, load, 8>;
1000   def  CLHRL  : CompareRILPC<"clhrl",  0xC67, z_ucmp, GR32,
1001                              aligned_azextloadi16>;
1002   def  CLRL   : CompareRILPC<"clrl",   0xC6F, z_ucmp, GR32,
1003                              aligned_load>;
1004   def  CLGHRL : CompareRILPC<"clghrl", 0xC66, z_ucmp, GR64,
1005                              aligned_azextloadi16>;
1006   def  CLGFRL : CompareRILPC<"clgfrl", 0xC6E, z_ucmp, GR64,
1007                              aligned_azextloadi32>;
1008   def  CLGRL  : CompareRILPC<"clgrl",  0xC6A, z_ucmp, GR64,
1009                              aligned_load>;
1010
1011   // Comparison between memory and an unsigned 8-bit immediate.
1012   defm CLI : CompareSIPair<"cli", 0x95, 0xEB55, z_ucmp, azextloadi8, imm32zx8>;
1013
1014   // Comparison between memory and an unsigned 16-bit immediate.
1015   def CLHHSI : CompareSIL<"clhhsi", 0xE555, z_ucmp, azextloadi16, imm32zx16>;
1016   def CLFHSI : CompareSIL<"clfhsi", 0xE55D, z_ucmp, load, imm32zx16>;
1017   def CLGHSI : CompareSIL<"clghsi", 0xE559, z_ucmp, load, imm64zx16>;
1018 }
1019 defm : ZXB<z_ucmp, GR64, CLGFR>;
1020
1021 // Memory-to-memory comparison.
1022 let mayLoad = 1, Defs = [CC] in
1023   defm CLC : MemorySS<"clc", 0xD5, z_clc, z_clc_loop>;
1024
1025 // String comparison.
1026 let mayLoad = 1, Defs = [CC], Uses = [R0L] in
1027   defm CLST : StringRRE<"clst", 0xB25D, z_strcmp>;
1028
1029 // Test under mask.
1030 let Defs = [CC] in {
1031   def TMLL : CompareRI<"tmll", 0xA71, z_tm_reg, GR32, imm32ll16>;
1032   def TMLH : CompareRI<"tmlh", 0xA70, z_tm_reg, GR32, imm32lh16>;
1033
1034   def TMHL : CompareRI<"tmhl", 0xA73, z_tm_reg, GR64, imm64hl16>;
1035   def TMHH : CompareRI<"tmhh", 0xA72, z_tm_reg, GR64, imm64hh16>;
1036
1037   defm TM : CompareSIPair<"tm", 0x91, 0xEB51, z_tm_mem, anyextloadi8, imm32zx8>;
1038 }
1039 def : CompareGR64RI<TMLL, z_tm_reg, imm64ll16>;
1040 def : CompareGR64RI<TMLH, z_tm_reg, imm64lh16>;
1041
1042 //===----------------------------------------------------------------------===//
1043 // Prefetch
1044 //===----------------------------------------------------------------------===//
1045
1046 def PFD : PrefetchRXY<"pfd", 0xE336, z_prefetch>;
1047 def PFDRL : PrefetchRILPC<"pfdrl", 0xC62, z_prefetch>;
1048
1049 //===----------------------------------------------------------------------===//
1050 // Atomic operations
1051 //===----------------------------------------------------------------------===//
1052
1053 def ATOMIC_SWAPW        : AtomicLoadWBinaryReg<z_atomic_swapw>;
1054 def ATOMIC_SWAP_32      : AtomicLoadBinaryReg32<atomic_swap_32>;
1055 def ATOMIC_SWAP_64      : AtomicLoadBinaryReg64<atomic_swap_64>;
1056
1057 def ATOMIC_LOADW_AR     : AtomicLoadWBinaryReg<z_atomic_loadw_add>;
1058 def ATOMIC_LOADW_AFI    : AtomicLoadWBinaryImm<z_atomic_loadw_add, simm32>;
1059 def ATOMIC_LOAD_AR      : AtomicLoadBinaryReg32<atomic_load_add_32>;
1060 def ATOMIC_LOAD_AHI     : AtomicLoadBinaryImm32<atomic_load_add_32, imm32sx16>;
1061 def ATOMIC_LOAD_AFI     : AtomicLoadBinaryImm32<atomic_load_add_32, simm32>;
1062 def ATOMIC_LOAD_AGR     : AtomicLoadBinaryReg64<atomic_load_add_64>;
1063 def ATOMIC_LOAD_AGHI    : AtomicLoadBinaryImm64<atomic_load_add_64, imm64sx16>;
1064 def ATOMIC_LOAD_AGFI    : AtomicLoadBinaryImm64<atomic_load_add_64, imm64sx32>;
1065
1066 def ATOMIC_LOADW_SR     : AtomicLoadWBinaryReg<z_atomic_loadw_sub>;
1067 def ATOMIC_LOAD_SR      : AtomicLoadBinaryReg32<atomic_load_sub_32>;
1068 def ATOMIC_LOAD_SGR     : AtomicLoadBinaryReg64<atomic_load_sub_64>;
1069
1070 def ATOMIC_LOADW_NR     : AtomicLoadWBinaryReg<z_atomic_loadw_and>;
1071 def ATOMIC_LOADW_NILH   : AtomicLoadWBinaryImm<z_atomic_loadw_and, imm32lh16c>;
1072 def ATOMIC_LOAD_NR      : AtomicLoadBinaryReg32<atomic_load_and_32>;
1073 def ATOMIC_LOAD_NILL    : AtomicLoadBinaryImm32<atomic_load_and_32, imm32ll16c>;
1074 def ATOMIC_LOAD_NILH    : AtomicLoadBinaryImm32<atomic_load_and_32, imm32lh16c>;
1075 def ATOMIC_LOAD_NILF    : AtomicLoadBinaryImm32<atomic_load_and_32, uimm32>;
1076 def ATOMIC_LOAD_NGR     : AtomicLoadBinaryReg64<atomic_load_and_64>;
1077 def ATOMIC_LOAD_NILL64  : AtomicLoadBinaryImm64<atomic_load_and_64, imm64ll16c>;
1078 def ATOMIC_LOAD_NILH64  : AtomicLoadBinaryImm64<atomic_load_and_64, imm64lh16c>;
1079 def ATOMIC_LOAD_NIHL    : AtomicLoadBinaryImm64<atomic_load_and_64, imm64hl16c>;
1080 def ATOMIC_LOAD_NIHH    : AtomicLoadBinaryImm64<atomic_load_and_64, imm64hh16c>;
1081 def ATOMIC_LOAD_NILF64  : AtomicLoadBinaryImm64<atomic_load_and_64, imm64lf32c>;
1082 def ATOMIC_LOAD_NIHF    : AtomicLoadBinaryImm64<atomic_load_and_64, imm64hf32c>;
1083
1084 def ATOMIC_LOADW_OR     : AtomicLoadWBinaryReg<z_atomic_loadw_or>;
1085 def ATOMIC_LOADW_OILH   : AtomicLoadWBinaryImm<z_atomic_loadw_or, imm32lh16>;
1086 def ATOMIC_LOAD_OR      : AtomicLoadBinaryReg32<atomic_load_or_32>;
1087 def ATOMIC_LOAD_OILL    : AtomicLoadBinaryImm32<atomic_load_or_32, imm32ll16>;
1088 def ATOMIC_LOAD_OILH    : AtomicLoadBinaryImm32<atomic_load_or_32, imm32lh16>;
1089 def ATOMIC_LOAD_OILF    : AtomicLoadBinaryImm32<atomic_load_or_32, uimm32>;
1090 def ATOMIC_LOAD_OGR     : AtomicLoadBinaryReg64<atomic_load_or_64>;
1091 def ATOMIC_LOAD_OILL64  : AtomicLoadBinaryImm64<atomic_load_or_64, imm64ll16>;
1092 def ATOMIC_LOAD_OILH64  : AtomicLoadBinaryImm64<atomic_load_or_64, imm64lh16>;
1093 def ATOMIC_LOAD_OIHL    : AtomicLoadBinaryImm64<atomic_load_or_64, imm64hl16>;
1094 def ATOMIC_LOAD_OIHH    : AtomicLoadBinaryImm64<atomic_load_or_64, imm64hh16>;
1095 def ATOMIC_LOAD_OILF64  : AtomicLoadBinaryImm64<atomic_load_or_64, imm64lf32>;
1096 def ATOMIC_LOAD_OIHF    : AtomicLoadBinaryImm64<atomic_load_or_64, imm64hf32>;
1097
1098 def ATOMIC_LOADW_XR     : AtomicLoadWBinaryReg<z_atomic_loadw_xor>;
1099 def ATOMIC_LOADW_XILF   : AtomicLoadWBinaryImm<z_atomic_loadw_xor, uimm32>;
1100 def ATOMIC_LOAD_XR      : AtomicLoadBinaryReg32<atomic_load_xor_32>;
1101 def ATOMIC_LOAD_XILF    : AtomicLoadBinaryImm32<atomic_load_xor_32, uimm32>;
1102 def ATOMIC_LOAD_XGR     : AtomicLoadBinaryReg64<atomic_load_xor_64>;
1103 def ATOMIC_LOAD_XILF64  : AtomicLoadBinaryImm64<atomic_load_xor_64, imm64lf32>;
1104 def ATOMIC_LOAD_XIHF    : AtomicLoadBinaryImm64<atomic_load_xor_64, imm64hf32>;
1105
1106 def ATOMIC_LOADW_NRi    : AtomicLoadWBinaryReg<z_atomic_loadw_nand>;
1107 def ATOMIC_LOADW_NILHi  : AtomicLoadWBinaryImm<z_atomic_loadw_nand,
1108                                                imm32lh16c>;
1109 def ATOMIC_LOAD_NRi     : AtomicLoadBinaryReg32<atomic_load_nand_32>;
1110 def ATOMIC_LOAD_NILLi   : AtomicLoadBinaryImm32<atomic_load_nand_32,
1111                                                 imm32ll16c>;
1112 def ATOMIC_LOAD_NILHi   : AtomicLoadBinaryImm32<atomic_load_nand_32,
1113                                                 imm32lh16c>;
1114 def ATOMIC_LOAD_NILFi   : AtomicLoadBinaryImm32<atomic_load_nand_32, uimm32>;
1115 def ATOMIC_LOAD_NGRi    : AtomicLoadBinaryReg64<atomic_load_nand_64>;
1116 def ATOMIC_LOAD_NILL64i : AtomicLoadBinaryImm64<atomic_load_nand_64,
1117                                                 imm64ll16c>;
1118 def ATOMIC_LOAD_NILH64i : AtomicLoadBinaryImm64<atomic_load_nand_64,
1119                                                 imm64lh16c>;
1120 def ATOMIC_LOAD_NIHLi   : AtomicLoadBinaryImm64<atomic_load_nand_64,
1121                                                 imm64hl16c>;
1122 def ATOMIC_LOAD_NIHHi   : AtomicLoadBinaryImm64<atomic_load_nand_64,
1123                                                 imm64hh16c>;
1124 def ATOMIC_LOAD_NILF64i : AtomicLoadBinaryImm64<atomic_load_nand_64,
1125                                                 imm64lf32c>;
1126 def ATOMIC_LOAD_NIHFi   : AtomicLoadBinaryImm64<atomic_load_nand_64,
1127                                                 imm64hf32c>;
1128
1129 def ATOMIC_LOADW_MIN    : AtomicLoadWBinaryReg<z_atomic_loadw_min>;
1130 def ATOMIC_LOAD_MIN_32  : AtomicLoadBinaryReg32<atomic_load_min_32>;
1131 def ATOMIC_LOAD_MIN_64  : AtomicLoadBinaryReg64<atomic_load_min_64>;
1132
1133 def ATOMIC_LOADW_MAX    : AtomicLoadWBinaryReg<z_atomic_loadw_max>;
1134 def ATOMIC_LOAD_MAX_32  : AtomicLoadBinaryReg32<atomic_load_max_32>;
1135 def ATOMIC_LOAD_MAX_64  : AtomicLoadBinaryReg64<atomic_load_max_64>;
1136
1137 def ATOMIC_LOADW_UMIN   : AtomicLoadWBinaryReg<z_atomic_loadw_umin>;
1138 def ATOMIC_LOAD_UMIN_32 : AtomicLoadBinaryReg32<atomic_load_umin_32>;
1139 def ATOMIC_LOAD_UMIN_64 : AtomicLoadBinaryReg64<atomic_load_umin_64>;
1140
1141 def ATOMIC_LOADW_UMAX   : AtomicLoadWBinaryReg<z_atomic_loadw_umax>;
1142 def ATOMIC_LOAD_UMAX_32 : AtomicLoadBinaryReg32<atomic_load_umax_32>;
1143 def ATOMIC_LOAD_UMAX_64 : AtomicLoadBinaryReg64<atomic_load_umax_64>;
1144
1145 def ATOMIC_CMP_SWAPW
1146   : Pseudo<(outs GR32:$dst), (ins bdaddr20only:$addr, GR32:$cmp, GR32:$swap,
1147                                   ADDR32:$bitshift, ADDR32:$negbitshift,
1148                                   uimm32:$bitsize),
1149            [(set GR32:$dst,
1150                  (z_atomic_cmp_swapw bdaddr20only:$addr, GR32:$cmp, GR32:$swap,
1151                                      ADDR32:$bitshift, ADDR32:$negbitshift,
1152                                      uimm32:$bitsize))]> {
1153   let Defs = [CC];
1154   let mayLoad = 1;
1155   let mayStore = 1;
1156   let usesCustomInserter = 1;
1157 }
1158
1159 let Defs = [CC] in {
1160   defm CS  : CmpSwapRSPair<"cs", 0xBA, 0xEB14, atomic_cmp_swap_32, GR32>;
1161   def  CSG : CmpSwapRSY<"csg", 0xEB30, atomic_cmp_swap_64, GR64>;
1162 }
1163
1164 //===----------------------------------------------------------------------===//
1165 // Miscellaneous Instructions.
1166 //===----------------------------------------------------------------------===//
1167
1168 // Extract CC into bits 29 and 28 of a register.
1169 let Uses = [CC] in
1170   def IPM : InherentRRE<"ipm", 0xB222, GR32, (z_ipm)>;
1171
1172 // Read a 32-bit access register into a GR32.  As with all GR32 operations,
1173 // the upper 32 bits of the enclosing GR64 remain unchanged, which is useful
1174 // when a 64-bit address is stored in a pair of access registers.
1175 def EAR : InstRRE<0xB24F, (outs GR32:$R1), (ins access_reg:$R2),
1176                   "ear\t$R1, $R2",
1177                   [(set GR32:$R1, (z_extract_access access_reg:$R2))]>;
1178
1179 // Find leftmost one, AKA count leading zeros.  The instruction actually
1180 // returns a pair of GR64s, the first giving the number of leading zeros
1181 // and the second giving a copy of the source with the leftmost one bit
1182 // cleared.  We only use the first result here.
1183 let Defs = [CC] in {
1184   def FLOGR : UnaryRRE<"flog", 0xB983, null_frag, GR128, GR64>;
1185 }
1186 def : Pat<(ctlz GR64:$src),
1187           (EXTRACT_SUBREG (FLOGR GR64:$src), subreg_h64)>;
1188
1189 // Use subregs to populate the "don't care" bits in a 32-bit to 64-bit anyext.
1190 def : Pat<(i64 (anyext GR32:$src)),
1191           (INSERT_SUBREG (i64 (IMPLICIT_DEF)), GR32:$src, subreg_l32)>;
1192
1193 // Extend GR32s and GR64s to GR128s.
1194 let usesCustomInserter = 1 in {
1195   def AEXT128_64 : Pseudo<(outs GR128:$dst), (ins GR64:$src), []>;
1196   def ZEXT128_32 : Pseudo<(outs GR128:$dst), (ins GR32:$src), []>;
1197   def ZEXT128_64 : Pseudo<(outs GR128:$dst), (ins GR64:$src), []>;
1198 }
1199
1200 // Search a block of memory for a character.
1201 let mayLoad = 1, Defs = [CC], Uses = [R0L] in
1202   defm SRST : StringRRE<"srst", 0xb25e, z_search_string>;
1203
1204 //===----------------------------------------------------------------------===//
1205 // Peepholes.
1206 //===----------------------------------------------------------------------===//
1207
1208 // Use AL* for GR64 additions of unsigned 32-bit values.
1209 defm : ZXB<add, GR64, ALGFR>;
1210 def  : Pat<(add GR64:$src1, imm64zx32:$src2),
1211            (ALGFI GR64:$src1, imm64zx32:$src2)>;
1212 def  : Pat<(add GR64:$src1, (azextloadi32 bdxaddr20only:$addr)),
1213            (ALGF GR64:$src1, bdxaddr20only:$addr)>;
1214
1215 // Use SL* for GR64 subtractions of unsigned 32-bit values.
1216 defm : ZXB<sub, GR64, SLGFR>;
1217 def  : Pat<(add GR64:$src1, imm64zx32n:$src2),
1218            (SLGFI GR64:$src1, imm64zx32n:$src2)>;
1219 def  : Pat<(sub GR64:$src1, (azextloadi32 bdxaddr20only:$addr)),
1220            (SLGF GR64:$src1, bdxaddr20only:$addr)>;
1221
1222 // Optimize sign-extended 1/0 selects to -1/0 selects.  This is important
1223 // for vector legalization.
1224 def : Pat<(sra (shl (i32 (z_select_ccmask 1, 0, uimm8zx4:$valid, uimm8zx4:$cc)),
1225                          (i32 31)),
1226                     (i32 31)),
1227           (Select32 (LHI -1), (LHI 0), uimm8zx4:$valid, uimm8zx4:$cc)>;
1228 def : Pat<(sra (shl (i64 (anyext (i32 (z_select_ccmask 1, 0, uimm8zx4:$valid,
1229                                                        uimm8zx4:$cc)))),
1230                     (i32 63)),
1231                (i32 63)),
1232           (Select64 (LGHI -1), (LGHI 0), uimm8zx4:$valid, uimm8zx4:$cc)>;
1233
1234 // Peepholes for turning scalar operations into block operations.
1235 defm : BlockLoadStore<anyextloadi8, i32, MVCSequence, NCSequence, OCSequence,
1236                       XCSequence, 1>;
1237 defm : BlockLoadStore<anyextloadi16, i32, MVCSequence, NCSequence, OCSequence,
1238                       XCSequence, 2>;
1239 defm : BlockLoadStore<load, i32, MVCSequence, NCSequence, OCSequence,
1240                       XCSequence, 4>;
1241 defm : BlockLoadStore<anyextloadi8, i64, MVCSequence, NCSequence,
1242                       OCSequence, XCSequence, 1>;
1243 defm : BlockLoadStore<anyextloadi16, i64, MVCSequence, NCSequence, OCSequence,
1244                       XCSequence, 2>;
1245 defm : BlockLoadStore<anyextloadi32, i64, MVCSequence, NCSequence, OCSequence,
1246                       XCSequence, 4>;
1247 defm : BlockLoadStore<load, i64, MVCSequence, NCSequence, OCSequence,
1248                       XCSequence, 8>;