lib/Target/Sparc/SparcInstrInfo.td

   1 //===- SparcInstrInfo.td - Target Description for Sparc Target ------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Sparc instructions in TableGen format.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Instruction format superclass
  16 //===----------------------------------------------------------------------===//
  17
  18 include "SparcInstrFormats.td"
  19
  20 //===----------------------------------------------------------------------===//
  21 // Feature predicates.
  22 //===----------------------------------------------------------------------===//
  23
  24 // HasV9 - This predicate is true when the target processor supports V9
  25 // instructions.  Note that the machine may be running in 32-bit mode.
  26 def HasV9   : Predicate<"Subtarget.isV9()">;
  27
  28 // HasNoV9 - This predicate is true when the target doesn't have V9
  29 // instructions.  Use of this is just a hack for the isel not having proper
  30 // costs for V8 instructions that are more expensive than their V9 ones.
  31 def HasNoV9 : Predicate<"!Subtarget.isV9()">;
  32
  33 // HasVIS - This is true when the target processor has VIS extensions.
  34 def HasVIS : Predicate<"Subtarget.isVIS()">;
  35
  36 // UseDeprecatedInsts - This predicate is true when the target processor is a
  37 // V8, or when it is V9 but the V8 deprecated instructions are efficient enough
  38 // to use when appropriate.  In either of these cases, the instruction selector
  39 // will pick deprecated instructions.
  40 def UseDeprecatedInsts : Predicate<"Subtarget.useDeprecatedV8Instructions()">;
  41
  42 //===----------------------------------------------------------------------===//
  43 // Instruction Pattern Stuff
  44 //===----------------------------------------------------------------------===//
  45
  46 def simm11  : PatLeaf<(imm), [{
  47   // simm11 predicate - True if the imm fits in a 11-bit sign extended field.
  48   return (((int)N->getValue() << (32-11)) >> (32-11)) == (int)N->getValue();
  49 }]>;
  50
  51 def simm13  : PatLeaf<(imm), [{
  52   // simm13 predicate - True if the imm fits in a 13-bit sign extended field.
  53   return (((int)N->getValue() << (32-13)) >> (32-13)) == (int)N->getValue();
  54 }]>;
  55
  56 def LO10 : SDNodeXForm<imm, [{
  57   return CurDAG->getTargetConstant((unsigned)N->getValue() & 1023, MVT::i32);
  58 }]>;
  59
  60 def HI22 : SDNodeXForm<imm, [{
  61   // Transformation function: shift the immediate value down into the low bits.
  62   return CurDAG->getTargetConstant((unsigned)N->getValue() >> 10, MVT::i32);
  63 }]>;
  64
  65 def SETHIimm : PatLeaf<(imm), [{
  66   return (((unsigned)N->getValue() >> 10) << 10) == (unsigned)N->getValue();
  67 }], HI22>;
  68
  69 // Addressing modes.
  70 def ADDRrr : ComplexPattern<i32, 2, "SelectADDRrr", [], []>;
  71 def ADDRri : ComplexPattern<i32, 2, "SelectADDRri", [frameindex], []>;
  72
  73 // Address operands
  74 def MEMrr : Operand<i32> {
  75   let PrintMethod = "printMemOperand";
  76   let MIOperandInfo = (ops IntRegs, IntRegs);
  77 }
  78 def MEMri : Operand<i32> {
  79   let PrintMethod = "printMemOperand";
  80   let MIOperandInfo = (ops IntRegs, i32imm);
  81 }
  82
  83 // Branch targets have OtherVT type.
  84 def brtarget : Operand<OtherVT>;
  85 def calltarget : Operand<i32>;
  86
  87 // Operand for printing out a condition code.
  88 let PrintMethod = "printCCOperand" in
  89   def CCOp : Operand<i32>;
  90
  91 def SDTSPcmpfcc :
  92 SDTypeProfile<0, 2, [SDTCisFP<0>, SDTCisSameAs<0, 1>]>;
  93 def SDTSPbrcc :
  94 SDTypeProfile<0, 2, [SDTCisVT<0, OtherVT>, SDTCisVT<1, i32>]>;
  95 def SDTSPselectcc :
  96 SDTypeProfile<1, 3, [SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisVT<3, i32>]>;
  97 def SDTSPFTOI :
  98 SDTypeProfile<1, 1, [SDTCisVT<0, f32>, SDTCisFP<1>]>;
  99 def SDTSPITOF :
 100 SDTypeProfile<1, 1, [SDTCisFP<0>, SDTCisVT<1, f32>]>;
 101
 102 def SPcmpicc : SDNode<"SPISD::CMPICC", SDTIntBinOp, [SDNPOutFlag]>;
 103 def SPcmpfcc : SDNode<"SPISD::CMPFCC", SDTSPcmpfcc, [SDNPOutFlag]>;
 104 def SPbricc : SDNode<"SPISD::BRICC", SDTSPbrcc, [SDNPHasChain, SDNPInFlag]>;
 105 def SPbrfcc : SDNode<"SPISD::BRFCC", SDTSPbrcc, [SDNPHasChain, SDNPInFlag]>;
 106
 107 def SPhi    : SDNode<"SPISD::Hi", SDTIntUnaryOp>;
 108 def SPlo    : SDNode<"SPISD::Lo", SDTIntUnaryOp>;
 109
 110 def SPftoi  : SDNode<"SPISD::FTOI", SDTSPFTOI>;
 111 def SPitof  : SDNode<"SPISD::ITOF", SDTSPITOF>;
 112
 113 def SPselecticc : SDNode<"SPISD::SELECT_ICC", SDTSPselectcc, [SDNPInFlag]>;
 114 def SPselectfcc : SDNode<"SPISD::SELECT_FCC", SDTSPselectcc, [SDNPInFlag]>;
 115
 116 // These are target-independent nodes, but have target-specific formats.
 117 def SDT_SPCallSeq : SDTypeProfile<0, 1, [ SDTCisVT<0, i32> ]>;
 118 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_SPCallSeq,
 119                            [SDNPHasChain, SDNPOutFlag]>;
 120 def callseq_end   : SDNode<"ISD::CALLSEQ_END",   SDT_SPCallSeq,
 121                            [SDNPHasChain, SDNPOutFlag]>;
 122
 123 def SDT_SPCall    : SDTypeProfile<0, 1, [SDTCisVT<0, i32>]>;
 124 def call          : SDNode<"SPISD::CALL", SDT_SPCall,
 125                            [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
 126
 127 def SDT_SPRetFlag : SDTypeProfile<0, 0, []>;
 128 def retflag       : SDNode<"SPISD::RET_FLAG", SDT_SPRetFlag,
 129                            [SDNPHasChain, SDNPOptInFlag]>;
 130
 131 //===----------------------------------------------------------------------===//
 132 // SPARC Flag Conditions
 133 //===----------------------------------------------------------------------===//
 134
 135 // Note that these values must be kept in sync with the CCOp::CondCode enum
 136 // values.
 137 class ICC_VAL<int N> : PatLeaf<(i32 N)>;
 138 def ICC_NE  : ICC_VAL< 9>;  // Not Equal
 139 def ICC_E   : ICC_VAL< 1>;  // Equal
 140 def ICC_G   : ICC_VAL<10>;  // Greater
 141 def ICC_LE  : ICC_VAL< 2>;  // Less or Equal
 142 def ICC_GE  : ICC_VAL<11>;  // Greater or Equal
 143 def ICC_L   : ICC_VAL< 3>;  // Less
 144 def ICC_GU  : ICC_VAL<12>;  // Greater Unsigned
 145 def ICC_LEU : ICC_VAL< 4>;  // Less or Equal Unsigned
 146 def ICC_CC  : ICC_VAL<13>;  // Carry Clear/Great or Equal Unsigned
 147 def ICC_CS  : ICC_VAL< 5>;  // Carry Set/Less Unsigned
 148 def ICC_POS : ICC_VAL<14>;  // Positive
 149 def ICC_NEG : ICC_VAL< 6>;  // Negative
 150 def ICC_VC  : ICC_VAL<15>;  // Overflow Clear
 151 def ICC_VS  : ICC_VAL< 7>;  // Overflow Set
 152
 153 class FCC_VAL<int N> : PatLeaf<(i32 N)>;
 154 def FCC_U   : FCC_VAL<23>;  // Unordered
 155 def FCC_G   : FCC_VAL<22>;  // Greater
 156 def FCC_UG  : FCC_VAL<21>;  // Unordered or Greater
 157 def FCC_L   : FCC_VAL<20>;  // Less
 158 def FCC_UL  : FCC_VAL<19>;  // Unordered or Less
 159 def FCC_LG  : FCC_VAL<18>;  // Less or Greater
 160 def FCC_NE  : FCC_VAL<17>;  // Not Equal
 161 def FCC_E   : FCC_VAL<25>;  // Equal
 162 def FCC_UE  : FCC_VAL<24>;  // Unordered or Equal
 163 def FCC_GE  : FCC_VAL<25>;  // Greater or Equal
 164 def FCC_UGE : FCC_VAL<26>;  // Unordered or Greater or Equal
 165 def FCC_LE  : FCC_VAL<27>;  // Less or Equal
 166 def FCC_ULE : FCC_VAL<28>;  // Unordered or Less or Equal
 167 def FCC_O   : FCC_VAL<29>;  // Ordered
 168
 169 //===----------------------------------------------------------------------===//
 170 // Instruction Class Templates
 171 //===----------------------------------------------------------------------===//
 172
 173 /// F3_12 multiclass - Define a normal F3_1/F3_2 pattern in one shot.
 174 multiclass F3_12<string OpcStr, bits<6> Op3Val, SDNode OpNode> {
 175   def rr  : F3_1<2, Op3Val,
 176                  (outs IntRegs:$dst), (ins IntRegs:$b, IntRegs:$c),
 177                  !strconcat(OpcStr, " $b, $c, $dst"),
 178                  [(set IntRegs:$dst, (OpNode IntRegs:$b, IntRegs:$c))]>;
 179   def ri  : F3_2<2, Op3Val,
 180                  (outs IntRegs:$dst), (ins IntRegs:$b, i32imm:$c),
 181                  !strconcat(OpcStr, " $b, $c, $dst"),
 182                  [(set IntRegs:$dst, (OpNode IntRegs:$b, simm13:$c))]>;
 183 }
 184
 185 /// F3_12np multiclass - Define a normal F3_1/F3_2 pattern in one shot, with no
 186 /// pattern.
 187 multiclass F3_12np<string OpcStr, bits<6> Op3Val> {
 188   def rr  : F3_1<2, Op3Val,
 189                  (outs IntRegs:$dst), (ins IntRegs:$b, IntRegs:$c),
 190                  !strconcat(OpcStr, " $b, $c, $dst"), []>;
 191   def ri  : F3_2<2, Op3Val,
 192                  (outs IntRegs:$dst), (ins IntRegs:$b, i32imm:$c),
 193                  !strconcat(OpcStr, " $b, $c, $dst"), []>;
 194 }
 195
 196 //===----------------------------------------------------------------------===//
 197 // Instructions
 198 //===----------------------------------------------------------------------===//
 199
 200 // Pseudo instructions.
 201 class Pseudo<dag outs, dag ins, string asmstr, list<dag> pattern>
 202    : InstSP<outs, ins, asmstr, pattern>;
 203
 204 let Defs = [O6], Uses = [O6] in {
 205 def ADJCALLSTACKDOWN : Pseudo<(outs), (ins i32imm:$amt),
 206                                "!ADJCALLSTACKDOWN $amt",
 207                                [(callseq_start imm:$amt)]>;
 208 def ADJCALLSTACKUP : Pseudo<(outs), (ins i32imm:$amt),
 209                             "!ADJCALLSTACKUP $amt",
 210                             [(callseq_end imm:$amt)]>;
 211 }
 212 def IMPLICIT_DEF_Int : Pseudo<(outs IntRegs:$dst), (ins),
 213                               "!IMPLICIT_DEF $dst",
 214                               [(set IntRegs:$dst, (undef))]>;
 215 def IMPLICIT_DEF_FP  : Pseudo<(outs FPRegs:$dst), (ins), "!IMPLICIT_DEF $dst",
 216                               [(set FPRegs:$dst, (undef))]>;
 217 def IMPLICIT_DEF_DFP : Pseudo<(outs DFPRegs:$dst), (ins), "!IMPLICIT_DEF $dst",
 218                               [(set DFPRegs:$dst, (undef))]>;
 219
 220 // FpMOVD/FpNEGD/FpABSD - These are lowered to single-precision ops by the
 221 // fpmover pass.
 222 let Predicates = [HasNoV9] in {  // Only emit these in V8 mode.
 223   def FpMOVD : Pseudo<(outs DFPRegs:$dst), (ins DFPRegs:$src),
 224                       "!FpMOVD $src, $dst", []>;
 225   def FpNEGD : Pseudo<(outs DFPRegs:$dst), (ins DFPRegs:$src),
 226                       "!FpNEGD $src, $dst",
 227                       [(set DFPRegs:$dst, (fneg DFPRegs:$src))]>;
 228   def FpABSD : Pseudo<(outs DFPRegs:$dst), (ins DFPRegs:$src),
 229                       "!FpABSD $src, $dst",
 230                       [(set DFPRegs:$dst, (fabs DFPRegs:$src))]>;
 231 }
 232
 233 // SELECT_CC_* - Used to implement the SELECT_CC DAG operation.  Expanded by the
 234 // scheduler into a branch sequence.  This has to handle all permutations of
 235 // selection between i32/f32/f64 on ICC and FCC.
 236 let usesCustomDAGSchedInserter = 1 in {   // Expanded by the scheduler.
 237   def SELECT_CC_Int_ICC
 238    : Pseudo<(outs IntRegs:$dst), (ins IntRegs:$T, IntRegs:$F, i32imm:$Cond),
 239             "; SELECT_CC_Int_ICC PSEUDO!",
 240             [(set IntRegs:$dst, (SPselecticc IntRegs:$T, IntRegs:$F,
 241                                              imm:$Cond))]>;
 242   def SELECT_CC_Int_FCC
 243    : Pseudo<(outs IntRegs:$dst), (ins IntRegs:$T, IntRegs:$F, i32imm:$Cond),
 244             "; SELECT_CC_Int_FCC PSEUDO!",
 245             [(set IntRegs:$dst, (SPselectfcc IntRegs:$T, IntRegs:$F,
 246                                              imm:$Cond))]>;
 247   def SELECT_CC_FP_ICC
 248    : Pseudo<(outs FPRegs:$dst), (ins FPRegs:$T, FPRegs:$F, i32imm:$Cond),
 249             "; SELECT_CC_FP_ICC PSEUDO!",
 250             [(set FPRegs:$dst, (SPselecticc FPRegs:$T, FPRegs:$F,
 251                                             imm:$Cond))]>;
 252   def SELECT_CC_FP_FCC
 253    : Pseudo<(outs FPRegs:$dst), (ins FPRegs:$T, FPRegs:$F, i32imm:$Cond),
 254             "; SELECT_CC_FP_FCC PSEUDO!",
 255             [(set FPRegs:$dst, (SPselectfcc FPRegs:$T, FPRegs:$F,
 256                                             imm:$Cond))]>;
 257   def SELECT_CC_DFP_ICC
 258    : Pseudo<(outs DFPRegs:$dst), (ins DFPRegs:$T, DFPRegs:$F, i32imm:$Cond),
 259             "; SELECT_CC_DFP_ICC PSEUDO!",
 260             [(set DFPRegs:$dst, (SPselecticc DFPRegs:$T, DFPRegs:$F,
 261                                              imm:$Cond))]>;
 262   def SELECT_CC_DFP_FCC
 263    : Pseudo<(outs DFPRegs:$dst), (ins DFPRegs:$T, DFPRegs:$F, i32imm:$Cond),
 264             "; SELECT_CC_DFP_FCC PSEUDO!",
 265             [(set DFPRegs:$dst, (SPselectfcc DFPRegs:$T, DFPRegs:$F,
 266                                              imm:$Cond))]>;
 267 }
 268
 269
 270 // Section A.3 - Synthetic Instructions, p. 85
 271 // special cases of JMPL:
 272 let isReturn = 1, isTerminator = 1, hasDelaySlot = 1 in {
 273   let rd = O7.Num, rs1 = G0.Num, simm13 = 8 in
 274     def RETL: F3_2<2, 0b111000, (outs), (ins), "retl", [(retflag)]>;
 275 }
 276
 277 // Section B.1 - Load Integer Instructions, p. 90
 278 def LDSBrr : F3_1<3, 0b001001,
 279                   (outs IntRegs:$dst), (ins MEMrr:$addr),
 280                   "ldsb [$addr], $dst",
 281                   [(set IntRegs:$dst, (sextloadi8 ADDRrr:$addr))]>;
 282 def LDSBri : F3_2<3, 0b001001,
 283                   (outs IntRegs:$dst), (ins MEMri:$addr),
 284                   "ldsb [$addr], $dst",
 285                   [(set IntRegs:$dst, (sextloadi8 ADDRri:$addr))]>;
 286 def LDSHrr : F3_1<3, 0b001010,
 287                   (outs IntRegs:$dst), (ins MEMrr:$addr),
 288                   "ldsh [$addr], $dst",
 289                   [(set IntRegs:$dst, (sextloadi16 ADDRrr:$addr))]>;
 290 def LDSHri : F3_2<3, 0b001010,
 291                   (outs IntRegs:$dst), (ins MEMri:$addr),
 292                   "ldsh [$addr], $dst",
 293                   [(set IntRegs:$dst, (sextloadi16 ADDRri:$addr))]>;
 294 def LDUBrr : F3_1<3, 0b000001,
 295                   (outs IntRegs:$dst), (ins MEMrr:$addr),
 296                   "ldub [$addr], $dst",
 297                   [(set IntRegs:$dst, (zextloadi8 ADDRrr:$addr))]>;
 298 def LDUBri : F3_2<3, 0b000001,
 299                   (outs IntRegs:$dst), (ins MEMri:$addr),
 300                   "ldub [$addr], $dst",
 301                   [(set IntRegs:$dst, (zextloadi8 ADDRri:$addr))]>;
 302 def LDUHrr : F3_1<3, 0b000010,
 303                   (outs IntRegs:$dst), (ins MEMrr:$addr),
 304                   "lduh [$addr], $dst",
 305                   [(set IntRegs:$dst, (zextloadi16 ADDRrr:$addr))]>;
 306 def LDUHri : F3_2<3, 0b000010,
 307                   (outs IntRegs:$dst), (ins MEMri:$addr),
 308                   "lduh [$addr], $dst",
 309                   [(set IntRegs:$dst, (zextloadi16 ADDRri:$addr))]>;
 310 def LDrr   : F3_1<3, 0b000000,
 311                   (outs IntRegs:$dst), (ins MEMrr:$addr),
 312                   "ld [$addr], $dst",
 313                   [(set IntRegs:$dst, (load ADDRrr:$addr))]>;
 314 def LDri   : F3_2<3, 0b000000,
 315                   (outs IntRegs:$dst), (ins MEMri:$addr),
 316                   "ld [$addr], $dst",
 317                   [(set IntRegs:$dst, (load ADDRri:$addr))]>;
 318
 319 // Section B.2 - Load Floating-point Instructions, p. 92
 320 def LDFrr  : F3_1<3, 0b100000,
 321                   (outs FPRegs:$dst), (ins MEMrr:$addr),
 322                   "ld [$addr], $dst",
 323                   [(set FPRegs:$dst, (load ADDRrr:$addr))]>;
 324 def LDFri  : F3_2<3, 0b100000,
 325                   (outs FPRegs:$dst), (ins MEMri:$addr),
 326                   "ld [$addr], $dst",
 327                   [(set FPRegs:$dst, (load ADDRri:$addr))]>;
 328 def LDDFrr : F3_1<3, 0b100011,
 329                   (outs DFPRegs:$dst), (ins MEMrr:$addr),
 330                   "ldd [$addr], $dst",
 331                   [(set DFPRegs:$dst, (load ADDRrr:$addr))]>;
 332 def LDDFri : F3_2<3, 0b100011,
 333                   (outs DFPRegs:$dst), (ins MEMri:$addr),
 334                   "ldd [$addr], $dst",
 335                   [(set DFPRegs:$dst, (load ADDRri:$addr))]>;
 336
 337 // Section B.4 - Store Integer Instructions, p. 95
 338 def STBrr : F3_1<3, 0b000101,
 339                  (outs), (ins MEMrr:$addr, IntRegs:$src),
 340                  "stb $src, [$addr]",
 341                  [(truncstorei8 IntRegs:$src, ADDRrr:$addr)]>;
 342 def STBri : F3_2<3, 0b000101,
 343                  (outs), (ins MEMri:$addr, IntRegs:$src),
 344                  "stb $src, [$addr]",
 345                  [(truncstorei8 IntRegs:$src, ADDRri:$addr)]>;
 346 def STHrr : F3_1<3, 0b000110,
 347                  (outs), (ins MEMrr:$addr, IntRegs:$src),
 348                  "sth $src, [$addr]",
 349                  [(truncstorei16 IntRegs:$src, ADDRrr:$addr)]>;
 350 def STHri : F3_2<3, 0b000110,
 351                  (outs), (ins MEMri:$addr, IntRegs:$src),
 352                  "sth $src, [$addr]",
 353                  [(truncstorei16 IntRegs:$src, ADDRri:$addr)]>;
 354 def STrr  : F3_1<3, 0b000100,
 355                  (outs), (ins MEMrr:$addr, IntRegs:$src),
 356                  "st $src, [$addr]",
 357                  [(store IntRegs:$src, ADDRrr:$addr)]>;
 358 def STri  : F3_2<3, 0b000100,
 359                  (outs), (ins MEMri:$addr, IntRegs:$src),
 360                  "st $src, [$addr]",
 361                  [(store IntRegs:$src, ADDRri:$addr)]>;
 362
 363 // Section B.5 - Store Floating-point Instructions, p. 97
 364 def STFrr   : F3_1<3, 0b100100,
 365                    (outs), (ins MEMrr:$addr, FPRegs:$src),
 366                    "st $src, [$addr]",
 367                    [(store FPRegs:$src, ADDRrr:$addr)]>;
 368 def STFri   : F3_2<3, 0b100100,
 369                    (outs), (ins MEMri:$addr, FPRegs:$src),
 370                    "st $src, [$addr]",
 371                    [(store FPRegs:$src, ADDRri:$addr)]>;
 372 def STDFrr  : F3_1<3, 0b100111,
 373                    (outs), (ins MEMrr:$addr, DFPRegs:$src),
 374                    "std  $src, [$addr]",
 375                    [(store DFPRegs:$src, ADDRrr:$addr)]>;
 376 def STDFri  : F3_2<3, 0b100111,
 377                    (outs), (ins MEMri:$addr, DFPRegs:$src),
 378                    "std $src, [$addr]",
 379                    [(store DFPRegs:$src, ADDRri:$addr)]>;
 380
 381 // Section B.9 - SETHI Instruction, p. 104
 382 def SETHIi: F2_1<0b100,
 383                  (outs IntRegs:$dst), (ins i32imm:$src),
 384                  "sethi $src, $dst",
 385                  [(set IntRegs:$dst, SETHIimm:$src)]>;
 386
 387 // Section B.10 - NOP Instruction, p. 105
 388 // (It's a special case of SETHI)
 389 let rd = 0, imm22 = 0 in
 390   def NOP : F2_1<0b100, (outs), (ins), "nop", []>;
 391
 392 // Section B.11 - Logical Instructions, p. 106
 393 defm AND    : F3_12<"and", 0b000001, and>;
 394
 395 def ANDNrr  : F3_1<2, 0b000101,
 396                    (outs IntRegs:$dst), (ins IntRegs:$b, IntRegs:$c),
 397                    "andn $b, $c, $dst",
 398                    [(set IntRegs:$dst, (and IntRegs:$b, (not IntRegs:$c)))]>;
 399 def ANDNri  : F3_2<2, 0b000101,
 400                    (outs IntRegs:$dst), (ins IntRegs:$b, i32imm:$c),
 401                    "andn $b, $c, $dst", []>;
 402
 403 defm OR     : F3_12<"or", 0b000010, or>;
 404
 405 def ORNrr   : F3_1<2, 0b000110,
 406                    (outs IntRegs:$dst), (ins IntRegs:$b, IntRegs:$c),
 407                    "orn $b, $c, $dst",
 408                    [(set IntRegs:$dst, (or IntRegs:$b, (not IntRegs:$c)))]>;
 409 def ORNri   : F3_2<2, 0b000110,
 410                    (outs IntRegs:$dst), (ins IntRegs:$b, i32imm:$c),
 411                    "orn $b, $c, $dst", []>;
 412 defm XOR    : F3_12<"xor", 0b000011, xor>;
 413
 414 def XNORrr  : F3_1<2, 0b000111,
 415                    (outs IntRegs:$dst), (ins IntRegs:$b, IntRegs:$c),
 416                    "xnor $b, $c, $dst",
 417                    [(set IntRegs:$dst, (not (xor IntRegs:$b, IntRegs:$c)))]>;
 418 def XNORri  : F3_2<2, 0b000111,
 419                    (outs IntRegs:$dst), (ins IntRegs:$b, i32imm:$c),
 420                    "xnor $b, $c, $dst", []>;
 421
 422 // Section B.12 - Shift Instructions, p. 107
 423 defm SLL : F3_12<"sll", 0b100101, shl>;
 424 defm SRL : F3_12<"srl", 0b100110, srl>;
 425 defm SRA : F3_12<"sra", 0b100111, sra>;
 426
 427 // Section B.13 - Add Instructions, p. 108
 428 defm ADD   : F3_12<"add", 0b000000, add>;
 429
 430 // "LEA" forms of add (patterns to make tblgen happy)
 431 def LEA_ADDri   : F3_2<2, 0b000000,
 432                    (outs IntRegs:$dst), (ins MEMri:$addr),
 433                    "add ${addr:arith}, $dst",
 434                    [(set IntRegs:$dst, ADDRri:$addr)]>;
 435
 436 defm ADDCC  : F3_12<"addcc", 0b010000, addc>;
 437 defm ADDX  : F3_12<"addx", 0b001000, adde>;
 438
 439 // Section B.15 - Subtract Instructions, p. 110
 440 defm SUB    : F3_12  <"sub"  , 0b000100, sub>;
 441 defm SUBX   : F3_12  <"subx" , 0b001100, sube>;
 442 defm SUBCC  : F3_12  <"subcc", 0b010100, SPcmpicc>;
 443
 444 def SUBXCCrr: F3_1<2, 0b011100,
 445                    (outs IntRegs:$dst), (ins IntRegs:$b, IntRegs:$c),
 446                    "subxcc $b, $c, $dst", []>;
 447
 448 // Section B.18 - Multiply Instructions, p. 113
 449 defm UMUL : F3_12np<"umul", 0b001010>;
 450 defm SMUL : F3_12  <"smul", 0b001011, mul>;
 451
 452
 453 // Section B.19 - Divide Instructions, p. 115
 454 defm UDIV : F3_12np<"udiv", 0b001110>;
 455 defm SDIV : F3_12np<"sdiv", 0b001111>;
 456
 457 // Section B.20 - SAVE and RESTORE, p. 117
 458 defm SAVE    : F3_12np<"save"   , 0b111100>;
 459 defm RESTORE : F3_12np<"restore", 0b111101>;
 460
 461 // Section B.21 - Branch on Integer Condition Codes Instructions, p. 119
 462
 463 // conditional branch class:
 464 class BranchSP<bits<4> cc, dag ins, string asmstr, list<dag> pattern>
 465  : F2_2<cc, 0b010, (outs), ins, asmstr, pattern> {
 466   let isBranch = 1;
 467   let isTerminator = 1;
 468   let hasDelaySlot = 1;
 469 }
 470
 471 let isBarrier = 1 in
 472   def BA   : BranchSP<0b1000, (ins brtarget:$dst),
 473                       "ba $dst",
 474                       [(br bb:$dst)]>;
 475
 476 // FIXME: the encoding for the JIT should look at the condition field.
 477 def BCOND : BranchSP<0, (ins brtarget:$dst, CCOp:$cc),
 478                      "b$cc $dst",
 479                      [(SPbricc bb:$dst, imm:$cc)]>;
 480
 481
 482 // Section B.22 - Branch on Floating-point Condition Codes Instructions, p. 121
 483
 484 // floating-point conditional branch class:
 485 class FPBranchSP<bits<4> cc, dag ins, string asmstr, list<dag> pattern>
 486  : F2_2<cc, 0b110, (outs), ins, asmstr, pattern> {
 487   let isBranch = 1;
 488   let isTerminator = 1;
 489   let hasDelaySlot = 1;
 490 }
 491
 492 // FIXME: the encoding for the JIT should look at the condition field.
 493 def FBCOND  : FPBranchSP<0, (ins brtarget:$dst, CCOp:$cc),
 494                       "fb$cc $dst",
 495                       [(SPbrfcc bb:$dst, imm:$cc)]>;
 496
 497
 498 // Section B.24 - Call and Link Instruction, p. 125
 499 // This is the only Format 1 instruction
 500 let Uses = [O0, O1, O2, O3, O4, O5],
 501     hasDelaySlot = 1, isCall = 1,
 502     Defs = [O0, O1, O2, O3, O4, O5, O7, G1, G2, G3, G4, G5, G6, G7,
 503     D0, D1, D2, D3, D4, D5, D6, D7, D8, D9, D10, D11, D12, D13, D14, D15] in {
 504   def CALL : InstSP<(outs), (ins calltarget:$dst),
 505                     "call $dst", []> {
 506     bits<30> disp;
 507     let op = 1;
 508     let Inst{29-0} = disp;
 509   }
 510
 511   // indirect calls
 512   def JMPLrr : F3_1<2, 0b111000,
 513                     (outs), (ins MEMrr:$ptr),
 514                     "call $ptr",
 515                     [(call  ADDRrr:$ptr)]>;
 516   def JMPLri : F3_2<2, 0b111000,
 517                     (outs), (ins MEMri:$ptr),
 518                     "call $ptr",
 519                     [(call  ADDRri:$ptr)]>;
 520 }
 521
 522 // Section B.28 - Read State Register Instructions
 523 def RDY : F3_1<2, 0b101000,
 524                (outs IntRegs:$dst), (ins),
 525                "rd %y, $dst", []>;
 526
 527 // Section B.29 - Write State Register Instructions
 528 def WRYrr : F3_1<2, 0b110000,
 529                  (outs), (ins IntRegs:$b, IntRegs:$c),
 530                  "wr $b, $c, %y", []>;
 531 def WRYri : F3_2<2, 0b110000,
 532                  (outs), (ins IntRegs:$b, i32imm:$c),
 533                  "wr $b, $c, %y", []>;
 534
 535 // Convert Integer to Floating-point Instructions, p. 141
 536 def FITOS : F3_3<2, 0b110100, 0b011000100,
 537                  (outs FPRegs:$dst), (ins FPRegs:$src),
 538                  "fitos $src, $dst",
 539                  [(set FPRegs:$dst, (SPitof FPRegs:$src))]>;
 540 def FITOD : F3_3<2, 0b110100, 0b011001000,
 541                  (outs DFPRegs:$dst), (ins FPRegs:$src),
 542                  "fitod $src, $dst",
 543                  [(set DFPRegs:$dst, (SPitof FPRegs:$src))]>;
 544
 545 // Convert Floating-point to Integer Instructions, p. 142
 546 def FSTOI : F3_3<2, 0b110100, 0b011010001,
 547                  (outs FPRegs:$dst), (ins FPRegs:$src),
 548                  "fstoi $src, $dst",
 549                  [(set FPRegs:$dst, (SPftoi FPRegs:$src))]>;
 550 def FDTOI : F3_3<2, 0b110100, 0b011010010,
 551                  (outs FPRegs:$dst), (ins DFPRegs:$src),
 552                  "fdtoi $src, $dst",
 553                  [(set FPRegs:$dst, (SPftoi DFPRegs:$src))]>;
 554
 555 // Convert between Floating-point Formats Instructions, p. 143
 556 def FSTOD : F3_3<2, 0b110100, 0b011001001,
 557                  (outs DFPRegs:$dst), (ins FPRegs:$src),
 558                  "fstod $src, $dst",
 559                  [(set DFPRegs:$dst, (fextend FPRegs:$src))]>;
 560 def FDTOS : F3_3<2, 0b110100, 0b011000110,
 561                  (outs FPRegs:$dst), (ins DFPRegs:$src),
 562                  "fdtos $src, $dst",
 563                  [(set FPRegs:$dst, (fround DFPRegs:$src))]>;
 564
 565 // Floating-point Move Instructions, p. 144
 566 def FMOVS : F3_3<2, 0b110100, 0b000000001,
 567                  (outs FPRegs:$dst), (ins FPRegs:$src),
 568                  "fmovs $src, $dst", []>;
 569 def FNEGS : F3_3<2, 0b110100, 0b000000101,
 570                  (outs FPRegs:$dst), (ins FPRegs:$src),
 571                  "fnegs $src, $dst",
 572                  [(set FPRegs:$dst, (fneg FPRegs:$src))]>;
 573 def FABSS : F3_3<2, 0b110100, 0b000001001,
 574                  (outs FPRegs:$dst), (ins FPRegs:$src),
 575                  "fabss $src, $dst",
 576                  [(set FPRegs:$dst, (fabs FPRegs:$src))]>;
 577
 578
 579 // Floating-point Square Root Instructions, p.145
 580 def FSQRTS : F3_3<2, 0b110100, 0b000101001,
 581                   (outs FPRegs:$dst), (ins FPRegs:$src),
 582                   "fsqrts $src, $dst",
 583                   [(set FPRegs:$dst, (fsqrt FPRegs:$src))]>;
 584 def FSQRTD : F3_3<2, 0b110100, 0b000101010,
 585                   (outs DFPRegs:$dst), (ins DFPRegs:$src),
 586                   "fsqrtd $src, $dst",
 587                   [(set DFPRegs:$dst, (fsqrt DFPRegs:$src))]>;
 588
 589
 590
 591 // Floating-point Add and Subtract Instructions, p. 146
 592 def FADDS  : F3_3<2, 0b110100, 0b001000001,
 593                   (outs FPRegs:$dst), (ins FPRegs:$src1, FPRegs:$src2),
 594                   "fadds $src1, $src2, $dst",
 595                   [(set FPRegs:$dst, (fadd FPRegs:$src1, FPRegs:$src2))]>;
 596 def FADDD  : F3_3<2, 0b110100, 0b001000010,
 597                   (outs DFPRegs:$dst), (ins DFPRegs:$src1, DFPRegs:$src2),
 598                   "faddd $src1, $src2, $dst",
 599                   [(set DFPRegs:$dst, (fadd DFPRegs:$src1, DFPRegs:$src2))]>;
 600 def FSUBS  : F3_3<2, 0b110100, 0b001000101,
 601                   (outs FPRegs:$dst), (ins FPRegs:$src1, FPRegs:$src2),
 602                   "fsubs $src1, $src2, $dst",
 603                   [(set FPRegs:$dst, (fsub FPRegs:$src1, FPRegs:$src2))]>;
 604 def FSUBD  : F3_3<2, 0b110100, 0b001000110,
 605                   (outs DFPRegs:$dst), (ins DFPRegs:$src1, DFPRegs:$src2),
 606                   "fsubd $src1, $src2, $dst",
 607                   [(set DFPRegs:$dst, (fsub DFPRegs:$src1, DFPRegs:$src2))]>;
 608
 609 // Floating-point Multiply and Divide Instructions, p. 147
 610 def FMULS  : F3_3<2, 0b110100, 0b001001001,
 611                   (outs FPRegs:$dst), (ins FPRegs:$src1, FPRegs:$src2),
 612                   "fmuls $src1, $src2, $dst",
 613                   [(set FPRegs:$dst, (fmul FPRegs:$src1, FPRegs:$src2))]>;
 614 def FMULD  : F3_3<2, 0b110100, 0b001001010,
 615                   (outs DFPRegs:$dst), (ins DFPRegs:$src1, DFPRegs:$src2),
 616                   "fmuld $src1, $src2, $dst",
 617                   [(set DFPRegs:$dst, (fmul DFPRegs:$src1, DFPRegs:$src2))]>;
 618 def FSMULD : F3_3<2, 0b110100, 0b001101001,
 619                   (outs DFPRegs:$dst), (ins FPRegs:$src1, FPRegs:$src2),
 620                   "fsmuld $src1, $src2, $dst",
 621                   [(set DFPRegs:$dst, (fmul (fextend FPRegs:$src1),
 622                                             (fextend FPRegs:$src2)))]>;
 623 def FDIVS  : F3_3<2, 0b110100, 0b001001101,
 624                  (outs FPRegs:$dst), (ins FPRegs:$src1, FPRegs:$src2),
 625                  "fdivs $src1, $src2, $dst",
 626                  [(set FPRegs:$dst, (fdiv FPRegs:$src1, FPRegs:$src2))]>;
 627 def FDIVD  : F3_3<2, 0b110100, 0b001001110,
 628                  (outs DFPRegs:$dst), (ins DFPRegs:$src1, DFPRegs:$src2),
 629                  "fdivd $src1, $src2, $dst",
 630                  [(set DFPRegs:$dst, (fdiv DFPRegs:$src1, DFPRegs:$src2))]>;
 631
 632 // Floating-point Compare Instructions, p. 148
 633 // Note: the 2nd template arg is different for these guys.
 634 // Note 2: the result of a FCMP is not available until the 2nd cycle
 635 // after the instr is retired, but there is no interlock. This behavior
 636 // is modelled with a forced noop after the instruction.
 637 def FCMPS  : F3_3<2, 0b110101, 0b001010001,
 638                   (outs), (ins FPRegs:$src1, FPRegs:$src2),
 639                   "fcmps $src1, $src2\n\tnop",
 640                   [(SPcmpfcc FPRegs:$src1, FPRegs:$src2)]>;
 641 def FCMPD  : F3_3<2, 0b110101, 0b001010010,
 642                   (outs), (ins DFPRegs:$src1, DFPRegs:$src2),
 643                   "fcmpd $src1, $src2\n\tnop",
 644                   [(SPcmpfcc DFPRegs:$src1, DFPRegs:$src2)]>;
 645
 646
 647 //===----------------------------------------------------------------------===//
 648 // V9 Instructions
 649 //===----------------------------------------------------------------------===//
 650
 651 // V9 Conditional Moves.
 652 let Predicates = [HasV9], isTwoAddress = 1 in {
 653   // Move Integer Register on Condition (MOVcc) p. 194 of the V9 manual.
 654   // FIXME: Add instruction encodings for the JIT some day.
 655   def MOVICCrr
 656     : Pseudo<(outs IntRegs:$dst), (ins IntRegs:$T, IntRegs:$F, CCOp:$cc),
 657              "mov$cc %icc, $F, $dst",
 658              [(set IntRegs:$dst,
 659                          (SPselecticc IntRegs:$F, IntRegs:$T, imm:$cc))]>;
 660   def MOVICCri
 661     : Pseudo<(outs IntRegs:$dst), (ins IntRegs:$T, i32imm:$F, CCOp:$cc),
 662              "mov$cc %icc, $F, $dst",
 663              [(set IntRegs:$dst,
 664                           (SPselecticc simm11:$F, IntRegs:$T, imm:$cc))]>;
 665
 666   def MOVFCCrr
 667     : Pseudo<(outs IntRegs:$dst), (ins IntRegs:$T, IntRegs:$F, CCOp:$cc),
 668              "mov$cc %fcc0, $F, $dst",
 669              [(set IntRegs:$dst,
 670                          (SPselectfcc IntRegs:$F, IntRegs:$T, imm:$cc))]>;
 671   def MOVFCCri
 672     : Pseudo<(outs IntRegs:$dst), (ins IntRegs:$T, i32imm:$F, CCOp:$cc),
 673              "mov$cc %fcc0, $F, $dst",
 674              [(set IntRegs:$dst,
 675                           (SPselectfcc simm11:$F, IntRegs:$T, imm:$cc))]>;
 676
 677   def FMOVS_ICC
 678     : Pseudo<(outs FPRegs:$dst), (ins FPRegs:$T, FPRegs:$F, CCOp:$cc),
 679              "fmovs$cc %icc, $F, $dst",
 680              [(set FPRegs:$dst,
 681                          (SPselecticc FPRegs:$F, FPRegs:$T, imm:$cc))]>;
 682   def FMOVD_ICC
 683     : Pseudo<(outs DFPRegs:$dst), (ins DFPRegs:$T, DFPRegs:$F, CCOp:$cc),
 684              "fmovd$cc %icc, $F, $dst",
 685              [(set DFPRegs:$dst,
 686                          (SPselecticc DFPRegs:$F, DFPRegs:$T, imm:$cc))]>;
 687   def FMOVS_FCC
 688     : Pseudo<(outs FPRegs:$dst), (ins FPRegs:$T, FPRegs:$F, CCOp:$cc),
 689              "fmovs$cc %fcc0, $F, $dst",
 690              [(set FPRegs:$dst,
 691                          (SPselectfcc FPRegs:$F, FPRegs:$T, imm:$cc))]>;
 692   def FMOVD_FCC
 693     : Pseudo<(outs DFPRegs:$dst), (ins DFPRegs:$T, DFPRegs:$F, CCOp:$cc),
 694              "fmovd$cc %fcc0, $F, $dst",
 695              [(set DFPRegs:$dst,
 696                          (SPselectfcc DFPRegs:$F, DFPRegs:$T, imm:$cc))]>;
 697
 698 }
 699
 700 // Floating-Point Move Instructions, p. 164 of the V9 manual.
 701 let Predicates = [HasV9] in {
 702   def FMOVD : F3_3<2, 0b110100, 0b000000010,
 703                    (outs DFPRegs:$dst), (ins DFPRegs:$src),
 704                    "fmovd $src, $dst", []>;
 705   def FNEGD : F3_3<2, 0b110100, 0b000000110,
 706                    (outs DFPRegs:$dst), (ins DFPRegs:$src),
 707                    "fnegd $src, $dst",
 708                    [(set DFPRegs:$dst, (fneg DFPRegs:$src))]>;
 709   def FABSD : F3_3<2, 0b110100, 0b000001010,
 710                    (outs DFPRegs:$dst), (ins DFPRegs:$src),
 711                    "fabsd $src, $dst",
 712                    [(set DFPRegs:$dst, (fabs DFPRegs:$src))]>;
 713 }
 714
 715 // POPCrr - This does a ctpop of a 64-bit register.  As such, we have to clear
 716 // the top 32-bits before using it.  To do this clearing, we use a SLLri X,0.
 717 def POPCrr : F3_1<2, 0b101110,
 718                   (outs IntRegs:$dst), (ins IntRegs:$src),
 719                   "popc $src, $dst", []>, Requires<[HasV9]>;
 720 def : Pat<(ctpop IntRegs:$src),
 721           (POPCrr (SLLri IntRegs:$src, 0))>;
 722
 723 //===----------------------------------------------------------------------===//
 724 // Non-Instruction Patterns
 725 //===----------------------------------------------------------------------===//
 726
 727 // Small immediates.
 728 def : Pat<(i32 simm13:$val),
 729           (ORri G0, imm:$val)>;
 730 // Arbitrary immediates.
 731 def : Pat<(i32 imm:$val),
 732           (ORri (SETHIi (HI22 imm:$val)), (LO10 imm:$val))>;
 733
 734 // subc
 735 def : Pat<(subc IntRegs:$b, IntRegs:$c),
 736           (SUBCCrr IntRegs:$b, IntRegs:$c)>;
 737 def : Pat<(subc IntRegs:$b, simm13:$val),
 738           (SUBCCri IntRegs:$b, imm:$val)>;
 739
 740 // Global addresses, constant pool entries
 741 def : Pat<(SPhi tglobaladdr:$in), (SETHIi tglobaladdr:$in)>;
 742 def : Pat<(SPlo tglobaladdr:$in), (ORri G0, tglobaladdr:$in)>;
 743 def : Pat<(SPhi tconstpool:$in), (SETHIi tconstpool:$in)>;
 744 def : Pat<(SPlo tconstpool:$in), (ORri G0, tconstpool:$in)>;
 745
 746 // Add reg, lo.  This is used when taking the addr of a global/constpool entry.
 747 def : Pat<(add IntRegs:$r, (SPlo tglobaladdr:$in)),
 748           (ADDri IntRegs:$r, tglobaladdr:$in)>;
 749 def : Pat<(add IntRegs:$r, (SPlo tconstpool:$in)),
 750           (ADDri IntRegs:$r, tconstpool:$in)>;
 751
 752 // Calls:
 753 def : Pat<(call tglobaladdr:$dst),
 754           (CALL tglobaladdr:$dst)>;
 755 def : Pat<(call texternalsym:$dst),
 756           (CALL texternalsym:$dst)>;
 757
 758 def : Pat<(ret), (RETL)>;
 759
 760 // Map integer extload's to zextloads.
 761 def : Pat<(i32 (extloadi1 ADDRrr:$src)), (LDUBrr ADDRrr:$src)>;
 762 def : Pat<(i32 (extloadi1 ADDRri:$src)), (LDUBri ADDRri:$src)>;
 763 def : Pat<(i32 (extloadi8 ADDRrr:$src)), (LDUBrr ADDRrr:$src)>;
 764 def : Pat<(i32 (extloadi8 ADDRri:$src)), (LDUBri ADDRri:$src)>;
 765 def : Pat<(i32 (extloadi16 ADDRrr:$src)), (LDUHrr ADDRrr:$src)>;
 766 def : Pat<(i32 (extloadi16 ADDRri:$src)), (LDUHri ADDRri:$src)>;
 767
 768 // zextload bool -> zextload byte
 769 def : Pat<(i32 (zextloadi1 ADDRrr:$src)), (LDUBrr ADDRrr:$src)>;
 770 def : Pat<(i32 (zextloadi1 ADDRri:$src)), (LDUBri ADDRri:$src)>;
 771
 772 // truncstore bool -> truncstore byte.
 773 def : Pat<(truncstorei1 IntRegs:$src, ADDRrr:$addr),
 774           (STBrr ADDRrr:$addr, IntRegs:$src)>;
 775 def : Pat<(truncstorei1 IntRegs:$src, ADDRri:$addr),
 776           (STBri ADDRri:$addr, IntRegs:$src)>;