lib/Target/R600/SIInstrInfo.td

   1 //===-- SIInstrInfo.td - SI Instruction Infos -------------*- tablegen -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 class vop {
  11   field bits<9> SI3;
  12 }
  13
  14 class vopc <bits<8> si> : vop {
  15   field bits<8> SI = si;
  16
  17   field bits<9> SI3 = {0, si{7-0}};
  18 }
  19
  20 class vop1 <bits<8> si> : vop {
  21   field bits<8> SI  = si;
  22
  23   field bits<9> SI3 = {1, 1, si{6-0}};
  24 }
  25
  26 class vop2 <bits<6> si> : vop {
  27   field bits<6> SI = si;
  28
  29   field bits<9> SI3 = {1, 0, 0, si{5-0}};
  30 }
  31
  32 class vop3 <bits<9> si> : vop {
  33   field bits<9> SI3 = si;
  34 }
  35
  36 // Execpt for the NONE field, this must be kept in sync with the SISubtarget enum
  37 // in AMDGPUMCInstLower.h
  38 def SISubtarget {
  39   int NONE = -1;
  40   int SI = 0;
  41 }
  42
  43 //===----------------------------------------------------------------------===//
  44 // SI DAG Nodes
  45 //===----------------------------------------------------------------------===//
  46
  47 def SIload_constant : SDNode<"AMDGPUISD::LOAD_CONSTANT",
  48   SDTypeProfile<1, 2, [SDTCisVT<0, f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i32>]>,
  49                       [SDNPMayLoad, SDNPMemOperand]
  50 >;
  51
  52 def SItbuffer_store : SDNode<"AMDGPUISD::TBUFFER_STORE_FORMAT",
  53   SDTypeProfile<0, 13,
  54     [SDTCisVT<0, v4i32>,   // rsrc(SGPR)
  55      SDTCisVT<1, iAny>,   // vdata(VGPR)
  56      SDTCisVT<2, i32>,    // num_channels(imm)
  57      SDTCisVT<3, i32>,    // vaddr(VGPR)
  58      SDTCisVT<4, i32>,    // soffset(SGPR)
  59      SDTCisVT<5, i32>,    // inst_offset(imm)
  60      SDTCisVT<6, i32>,    // dfmt(imm)
  61      SDTCisVT<7, i32>,    // nfmt(imm)
  62      SDTCisVT<8, i32>,    // offen(imm)
  63      SDTCisVT<9, i32>,    // idxen(imm)
  64      SDTCisVT<10, i32>,   // glc(imm)
  65      SDTCisVT<11, i32>,   // slc(imm)
  66      SDTCisVT<12, i32>    // tfe(imm)
  67     ]>,
  68   [SDNPMayStore, SDNPMemOperand, SDNPHasChain]
  69 >;
  70
  71 def SIload_input : SDNode<"AMDGPUISD::LOAD_INPUT",
  72   SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i16>,
  73                        SDTCisVT<3, i32>]>
  74 >;
  75
  76 class SDSample<string opcode> : SDNode <opcode,
  77   SDTypeProfile<1, 4, [SDTCisVT<0, v4f32>, SDTCisVT<2, v32i8>,
  78                        SDTCisVT<3, v4i32>, SDTCisVT<4, i32>]>
  79 >;
  80
  81 def SIsample : SDSample<"AMDGPUISD::SAMPLE">;
  82 def SIsampleb : SDSample<"AMDGPUISD::SAMPLEB">;
  83 def SIsampled : SDSample<"AMDGPUISD::SAMPLED">;
  84 def SIsamplel : SDSample<"AMDGPUISD::SAMPLEL">;
  85
  86 def SIconstdata_ptr : SDNode<
  87   "AMDGPUISD::CONST_DATA_PTR", SDTypeProfile <1, 0, [SDTCisVT<0, i64>]>
  88 >;
  89
  90 // Transformation function, extract the lower 32bit of a 64bit immediate
  91 def LO32 : SDNodeXForm<imm, [{
  92   return CurDAG->getTargetConstant(N->getZExtValue() & 0xffffffff, MVT::i32);
  93 }]>;
  94
  95 def LO32f : SDNodeXForm<fpimm, [{
  96   APInt V = N->getValueAPF().bitcastToAPInt().trunc(32);
  97   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
  98 }]>;
  99
 100 // Transformation function, extract the upper 32bit of a 64bit immediate
 101 def HI32 : SDNodeXForm<imm, [{
 102   return CurDAG->getTargetConstant(N->getZExtValue() >> 32, MVT::i32);
 103 }]>;
 104
 105 def HI32f : SDNodeXForm<fpimm, [{
 106   APInt V = N->getValueAPF().bitcastToAPInt().lshr(32).trunc(32);
 107   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
 108 }]>;
 109
 110 def IMM8bitDWORD : PatLeaf <(imm),
 111   [{return (N->getZExtValue() & ~0x3FC) == 0;}]
 112 >;
 113
 114 def as_dword_i32imm : SDNodeXForm<imm, [{
 115   return CurDAG->getTargetConstant(N->getZExtValue() >> 2, MVT::i32);
 116 }]>;
 117
 118 def as_i1imm : SDNodeXForm<imm, [{
 119   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i1);
 120 }]>;
 121
 122 def as_i8imm : SDNodeXForm<imm, [{
 123   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i8);
 124 }]>;
 125
 126 def as_i16imm : SDNodeXForm<imm, [{
 127   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i16);
 128 }]>;
 129
 130 def as_i32imm: SDNodeXForm<imm, [{
 131   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i32);
 132 }]>;
 133
 134 def IMM8bit : PatLeaf <(imm),
 135   [{return isUInt<8>(N->getZExtValue());}]
 136 >;
 137
 138 def IMM12bit : PatLeaf <(imm),
 139   [{return isUInt<12>(N->getZExtValue());}]
 140 >;
 141
 142 def IMM16bit : PatLeaf <(imm),
 143   [{return isUInt<16>(N->getZExtValue());}]
 144 >;
 145
 146 def IMM32bit : PatLeaf <(imm),
 147   [{return isUInt<32>(N->getZExtValue());}]
 148 >;
 149
 150 def mubuf_vaddr_offset : PatFrag<
 151   (ops node:$ptr, node:$offset, node:$imm_offset),
 152   (add (add node:$ptr, node:$offset), node:$imm_offset)
 153 >;
 154
 155 class InlineImm <ValueType vt> : PatLeaf <(vt imm), [{
 156   return isInlineImmediate(N);
 157 }]>;
 158
 159 class SGPRImm <dag frag> : PatLeaf<frag, [{
 160   if (TM.getSubtarget<AMDGPUSubtarget>().getGeneration() <
 161       AMDGPUSubtarget::SOUTHERN_ISLANDS) {
 162     return false;
 163   }
 164   const SIRegisterInfo *SIRI =
 165                        static_cast<const SIRegisterInfo*>(TM.getSubtargetImpl()->getRegisterInfo());
 166   for (SDNode::use_iterator U = N->use_begin(), E = SDNode::use_end();
 167                                                 U != E; ++U) {
 168     if (SIRI->isSGPRClass(getOperandRegClass(*U, U.getOperandNo()))) {
 169       return true;
 170     }
 171   }
 172   return false;
 173 }]>;
 174
 175 //===----------------------------------------------------------------------===//
 176 // Custom Operands
 177 //===----------------------------------------------------------------------===//
 178
 179 def FRAMEri32 : Operand<iPTR> {
 180   let MIOperandInfo = (ops i32:$ptr, i32imm:$index);
 181 }
 182
 183 def sopp_brtarget : Operand<OtherVT> {
 184   let EncoderMethod = "getSOPPBrEncoding";
 185   let OperandType = "OPERAND_PCREL";
 186 }
 187
 188 include "SIInstrFormats.td"
 189
 190 let OperandType = "OPERAND_IMMEDIATE" in {
 191
 192 def offen : Operand<i1> {
 193   let PrintMethod = "printOffen";
 194 }
 195 def idxen : Operand<i1> {
 196   let PrintMethod = "printIdxen";
 197 }
 198 def addr64 : Operand<i1> {
 199   let PrintMethod = "printAddr64";
 200 }
 201 def mbuf_offset : Operand<i16> {
 202   let PrintMethod = "printMBUFOffset";
 203 }
 204 def ds_offset : Operand<i16> {
 205   let PrintMethod = "printDSOffset";
 206 }
 207 def ds_offset0 : Operand<i8> {
 208   let PrintMethod = "printDSOffset0";
 209 }
 210 def ds_offset1 : Operand<i8> {
 211   let PrintMethod = "printDSOffset1";
 212 }
 213 def glc : Operand <i1> {
 214   let PrintMethod = "printGLC";
 215 }
 216 def slc : Operand <i1> {
 217   let PrintMethod = "printSLC";
 218 }
 219 def tfe : Operand <i1> {
 220   let PrintMethod = "printTFE";
 221 }
 222
 223 def omod : Operand <i32> {
 224   let PrintMethod = "printOModSI";
 225 }
 226
 227 def ClampMod : Operand <i1> {
 228   let PrintMethod = "printClampSI";
 229 }
 230
 231 } // End OperandType = "OPERAND_IMMEDIATE"
 232
 233 //===----------------------------------------------------------------------===//
 234 // Complex patterns
 235 //===----------------------------------------------------------------------===//
 236
 237 def DS1Addr1Offset : ComplexPattern<i32, 2, "SelectDS1Addr1Offset">;
 238 def DS64Bit4ByteAligned : ComplexPattern<i32, 3, "SelectDS64Bit4ByteAligned">;
 239
 240 def MUBUFAddr32 : ComplexPattern<i64, 9, "SelectMUBUFAddr32">;
 241 def MUBUFAddr64 : ComplexPattern<i64, 3, "SelectMUBUFAddr64">;
 242 def MUBUFAddr64Atomic : ComplexPattern<i64, 4, "SelectMUBUFAddr64">;
 243 def MUBUFScratch : ComplexPattern<i64, 4, "SelectMUBUFScratch">;
 244 def MUBUFOffset : ComplexPattern<i64, 6, "SelectMUBUFOffset">;
 245 def MUBUFOffsetAtomic : ComplexPattern<i64, 4, "SelectMUBUFOffset">;
 246
 247 def VOP3Mods0 : ComplexPattern<untyped, 4, "SelectVOP3Mods0">;
 248 def VOP3Mods0Clamp : ComplexPattern<untyped, 3, "SelectVOP3Mods0Clamp">;
 249 def VOP3Mods  : ComplexPattern<untyped, 2, "SelectVOP3Mods">;
 250
 251 //===----------------------------------------------------------------------===//
 252 // SI assembler operands
 253 //===----------------------------------------------------------------------===//
 254
 255 def SIOperand {
 256   int ZERO = 0x80;
 257   int VCC = 0x6A;
 258   int FLAT_SCR = 0x68;
 259 }
 260
 261 def SRCMODS {
 262   int NONE = 0;
 263 }
 264
 265 def DSTCLAMP {
 266   int NONE = 0;
 267 }
 268
 269 def DSTOMOD {
 270   int NONE = 0;
 271 }
 272
 273 //===----------------------------------------------------------------------===//
 274 //
 275 // SI Instruction multiclass helpers.
 276 //
 277 // Instructions with _32 take 32-bit operands.
 278 // Instructions with _64 take 64-bit operands.
 279 //
 280 // VOP_* instructions can use either a 32-bit or 64-bit encoding.  The 32-bit
 281 // encoding is the standard encoding, but instruction that make use of
 282 // any of the instruction modifiers must use the 64-bit encoding.
 283 //
 284 // Instructions with _e32 use the 32-bit encoding.
 285 // Instructions with _e64 use the 64-bit encoding.
 286 //
 287 //===----------------------------------------------------------------------===//
 288
 289 class SIMCInstr <string pseudo, int subtarget> {
 290   string PseudoInstr = pseudo;
 291   int Subtarget = subtarget;
 292 }
 293
 294 //===----------------------------------------------------------------------===//
 295 // EXP classes
 296 //===----------------------------------------------------------------------===//
 297
 298 class EXPCommon : InstSI<
 299   (outs),
 300   (ins i32imm:$en, i32imm:$tgt, i32imm:$compr, i32imm:$done, i32imm:$vm,
 301        VReg_32:$src0, VReg_32:$src1, VReg_32:$src2, VReg_32:$src3),
 302   "exp $en, $tgt, $compr, $done, $vm, $src0, $src1, $src2, $src3",
 303   [] > {
 304
 305   let EXP_CNT = 1;
 306   let Uses = [EXEC];
 307 }
 308
 309 multiclass EXP_m {
 310
 311   let isPseudo = 1 in {
 312     def "" : EXPCommon, SIMCInstr <"exp", SISubtarget.NONE> ;
 313   }
 314
 315   def _si : EXPCommon, SIMCInstr <"exp", SISubtarget.SI>, EXPe;
 316 }
 317
 318 //===----------------------------------------------------------------------===//
 319 // Scalar classes
 320 //===----------------------------------------------------------------------===//
 321
 322 class SOP1_32 <bits<8> op, string opName, list<dag> pattern> : SOP1 <
 323   op, (outs SReg_32:$dst), (ins SSrc_32:$src0),
 324   opName#" $dst, $src0", pattern
 325 >;
 326
 327 class SOP1_64 <bits<8> op, string opName, list<dag> pattern> : SOP1 <
 328   op, (outs SReg_64:$dst), (ins SSrc_64:$src0),
 329   opName#" $dst, $src0", pattern
 330 >;
 331
 332 // 64-bit input, 32-bit output.
 333 class SOP1_32_64 <bits<8> op, string opName, list<dag> pattern> : SOP1 <
 334   op, (outs SReg_32:$dst), (ins SSrc_64:$src0),
 335   opName#" $dst, $src0", pattern
 336 >;
 337
 338 class SOP2_32 <bits<7> op, string opName, list<dag> pattern> : SOP2 <
 339   op, (outs SReg_32:$dst), (ins SSrc_32:$src0, SSrc_32:$src1),
 340   opName#" $dst, $src0, $src1", pattern
 341 >;
 342
 343 class SOP2_SELECT_32 <bits<7> op, string opName, list<dag> pattern> : SOP2 <
 344   op, (outs SReg_32:$dst), (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc),
 345   opName#" $dst, $src0, $src1 [$scc]", pattern
 346 >;
 347
 348 class SOP2_64 <bits<7> op, string opName, list<dag> pattern> : SOP2 <
 349   op, (outs SReg_64:$dst), (ins SSrc_64:$src0, SSrc_64:$src1),
 350   opName#" $dst, $src0, $src1", pattern
 351 >;
 352
 353 class SOP2_64_32 <bits<7> op, string opName, list<dag> pattern> : SOP2 <
 354   op, (outs SReg_64:$dst), (ins SSrc_64:$src0, SSrc_32:$src1),
 355   opName#" $dst, $src0, $src1", pattern
 356 >;
 357
 358 class SOP2_SHIFT_64 <bits<7> op, string opName, list<dag> pattern> : SOP2 <
 359   op, (outs SReg_64:$dst), (ins SSrc_64:$src0, SSrc_32:$src1),
 360   opName#" $dst, $src0, $src1", pattern
 361 >;
 362
 363
 364 class SOPC_Helper <bits<7> op, RegisterClass rc, ValueType vt,
 365                     string opName, PatLeaf cond> : SOPC <
 366   op, (outs SCCReg:$dst), (ins rc:$src0, rc:$src1),
 367   opName#" $dst, $src0, $src1", []>;
 368
 369 class SOPC_32<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 370   : SOPC_Helper<op, SSrc_32, i32, opName, cond>;
 371
 372 class SOPC_64<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 373   : SOPC_Helper<op, SSrc_64, i64, opName, cond>;
 374
 375 class SOPK_32 <bits<5> op, string opName, list<dag> pattern> : SOPK <
 376   op, (outs SReg_32:$dst), (ins u16imm:$src0),
 377   opName#" $dst, $src0", pattern
 378 >;
 379
 380 class SOPK_64 <bits<5> op, string opName, list<dag> pattern> : SOPK <
 381   op, (outs SReg_64:$dst), (ins u16imm:$src0),
 382   opName#" $dst, $src0", pattern
 383 >;
 384
 385 //===----------------------------------------------------------------------===//
 386 // SMRD classes
 387 //===----------------------------------------------------------------------===//
 388
 389 class SMRD_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 390   SMRD <outs, ins, "", pattern>,
 391   SIMCInstr<opName, SISubtarget.NONE> {
 392   let isPseudo = 1;
 393 }
 394
 395 class SMRD_Real_si <bits<5> op, string opName, bit imm, dag outs, dag ins,
 396                     string asm> :
 397   SMRD <outs, ins, asm, []>,
 398   SMRDe <op, imm>,
 399   SIMCInstr<opName, SISubtarget.SI>;
 400
 401 multiclass SMRD_m <bits<5> op, string opName, bit imm, dag outs, dag ins,
 402                    string asm, list<dag> pattern> {
 403
 404   def "" : SMRD_Pseudo <opName, outs, ins, pattern>;
 405
 406   def _si : SMRD_Real_si <op, opName, imm, outs, ins, asm>;
 407
 408 }
 409
 410 multiclass SMRD_Helper <bits<5> op, string opName, RegisterClass baseClass,
 411                         RegisterClass dstClass> {
 412   defm _IMM : SMRD_m <
 413     op, opName#"_IMM", 1, (outs dstClass:$dst),
 414     (ins baseClass:$sbase, u32imm:$offset),
 415     opName#" $dst, $sbase, $offset", []
 416   >;
 417
 418   defm _SGPR : SMRD_m <
 419     op, opName#"_SGPR", 0, (outs dstClass:$dst),
 420     (ins baseClass:$sbase, SReg_32:$soff),
 421     opName#" $dst, $sbase, $soff", []
 422   >;
 423 }
 424
 425 //===----------------------------------------------------------------------===//
 426 // Vector ALU classes
 427 //===----------------------------------------------------------------------===//
 428
 429 // This must always be right before the operand being input modified.
 430 def InputMods : OperandWithDefaultOps <i32, (ops (i32 0))> {
 431   let PrintMethod = "printOperandAndMods";
 432 }
 433 def InputModsNoDefault : Operand <i32> {
 434   let PrintMethod = "printOperandAndMods";
 435 }
 436
 437 class getNumSrcArgs<ValueType Src1, ValueType Src2> {
 438   int ret =
 439     !if (!eq(Src1.Value, untyped.Value),      1,   // VOP1
 440          !if (!eq(Src2.Value, untyped.Value), 2,   // VOP2
 441                                               3)); // VOP3
 442 }
 443
 444 // Returns the register class to use for the destination of VOP[123C]
 445 // instructions for the given VT.
 446 class getVALUDstForVT<ValueType VT> {
 447   RegisterClass ret = !if(!eq(VT.Size, 32), VReg_32, VReg_64);
 448 }
 449
 450 // Returns the register class to use for source 0 of VOP[12C]
 451 // instructions for the given VT.
 452 class getVOPSrc0ForVT<ValueType VT> {
 453   RegisterClass ret = !if(!eq(VT.Size, 32), VSrc_32, VSrc_64);
 454 }
 455
 456 // Returns the register class to use for source 1 of VOP[12C] for the
 457 // given VT.
 458 class getVOPSrc1ForVT<ValueType VT> {
 459   RegisterClass ret = !if(!eq(VT.Size, 32), VReg_32, VReg_64);
 460 }
 461
 462 // Returns the register classes for the source arguments of a VOP[12C]
 463 // instruction for the given SrcVTs.
 464 class getInRC32 <list<ValueType> SrcVT> {
 465   list<RegisterClass> ret = [
 466     getVOPSrc0ForVT<SrcVT[0]>.ret,
 467     getVOPSrc1ForVT<SrcVT[1]>.ret
 468   ];
 469 }
 470
 471 // Returns the register class to use for sources of VOP3 instructions for the
 472 // given VT.
 473 class getVOP3SrcForVT<ValueType VT> {
 474   RegisterClass ret = !if(!eq(VT.Size, 32), VCSrc_32, VCSrc_64);
 475 }
 476
 477 // Returns the register classes for the source arguments of a VOP3
 478 // instruction for the given SrcVTs.
 479 class getInRC64 <list<ValueType> SrcVT> {
 480   list<RegisterClass> ret = [
 481     getVOP3SrcForVT<SrcVT[0]>.ret,
 482     getVOP3SrcForVT<SrcVT[1]>.ret,
 483     getVOP3SrcForVT<SrcVT[2]>.ret
 484   ];
 485 }
 486
 487 // Returns 1 if the source arguments have modifiers, 0 if they do not.
 488 class hasModifiers<ValueType SrcVT> {
 489   bit ret = !if(!eq(SrcVT.Value, f32.Value), 1,
 490             !if(!eq(SrcVT.Value, f64.Value), 1, 0));
 491 }
 492
 493 // Returns the input arguments for VOP[12C] instructions for the given SrcVT.
 494 class getIns32 <RegisterClass Src0RC, RegisterClass Src1RC, int NumSrcArgs> {
 495   dag ret = !if(!eq(NumSrcArgs, 1), (ins Src0RC:$src0),               // VOP1
 496             !if(!eq(NumSrcArgs, 2), (ins Src0RC:$src0, Src1RC:$src1), // VOP2
 497                                     (ins)));
 498 }
 499
 500 // Returns the input arguments for VOP3 instructions for the given SrcVT.
 501 class getIns64 <RegisterClass Src0RC, RegisterClass Src1RC,
 502                 RegisterClass Src2RC, int NumSrcArgs,
 503                 bit HasModifiers> {
 504
 505   dag ret =
 506     !if (!eq(NumSrcArgs, 1),
 507       !if (!eq(HasModifiers, 1),
 508         // VOP1 with modifiers
 509         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 510              ClampMod:$clamp, omod:$omod)
 511       /* else */,
 512         // VOP1 without modifiers
 513         (ins Src0RC:$src0)
 514       /* endif */ ),
 515     !if (!eq(NumSrcArgs, 2),
 516       !if (!eq(HasModifiers, 1),
 517         // VOP 2 with modifiers
 518         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 519              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 520              ClampMod:$clamp, omod:$omod)
 521       /* else */,
 522         // VOP2 without modifiers
 523         (ins Src0RC:$src0, Src1RC:$src1)
 524       /* endif */ )
 525     /* NumSrcArgs == 3 */,
 526       !if (!eq(HasModifiers, 1),
 527         // VOP3 with modifiers
 528         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 529              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 530              InputModsNoDefault:$src2_modifiers, Src2RC:$src2,
 531              ClampMod:$clamp, omod:$omod)
 532       /* else */,
 533         // VOP3 without modifiers
 534         (ins Src0RC:$src0, Src1RC:$src1, Src2RC:$src2)
 535       /* endif */ )));
 536 }
 537
 538 // Returns the assembly string for the inputs and outputs of a VOP[12C]
 539 // instruction.  This does not add the _e32 suffix, so it can be reused
 540 // by getAsm64.
 541 class getAsm32 <int NumSrcArgs> {
 542   string src1 = ", $src1";
 543   string src2 = ", $src2";
 544   string ret = " $dst, $src0"#
 545                !if(!eq(NumSrcArgs, 1), "", src1)#
 546                !if(!eq(NumSrcArgs, 3), src2, "");
 547 }
 548
 549 // Returns the assembly string for the inputs and outputs of a VOP3
 550 // instruction.
 551 class getAsm64 <int NumSrcArgs, bit HasModifiers> {
 552   string src0 = "$src0_modifiers,";
 553   string src1 = !if(!eq(NumSrcArgs, 1), "",
 554                    !if(!eq(NumSrcArgs, 2), " $src1_modifiers",
 555                                            " $src1_modifiers,"));
 556   string src2 = !if(!eq(NumSrcArgs, 3), " $src2_modifiers", "");
 557   string ret =
 558   !if(!eq(HasModifiers, 0),
 559       getAsm32<NumSrcArgs>.ret,
 560       " $dst, "#src0#src1#src2#"$clamp"#"$omod");
 561 }
 562
 563
 564 class VOPProfile <list<ValueType> _ArgVT> {
 565
 566   field list<ValueType> ArgVT = _ArgVT;
 567
 568   field ValueType DstVT = ArgVT[0];
 569   field ValueType Src0VT = ArgVT[1];
 570   field ValueType Src1VT = ArgVT[2];
 571   field ValueType Src2VT = ArgVT[3];
 572   field RegisterClass DstRC = getVALUDstForVT<DstVT>.ret;
 573   field RegisterClass Src0RC32 = getVOPSrc0ForVT<Src0VT>.ret;
 574   field RegisterClass Src1RC32 = getVOPSrc1ForVT<Src1VT>.ret;
 575   field RegisterClass Src0RC64 = getVOP3SrcForVT<Src0VT>.ret;
 576   field RegisterClass Src1RC64 = getVOP3SrcForVT<Src1VT>.ret;
 577   field RegisterClass Src2RC64 = getVOP3SrcForVT<Src2VT>.ret;
 578
 579   field int NumSrcArgs = getNumSrcArgs<Src1VT, Src2VT>.ret;
 580   field bit HasModifiers = hasModifiers<Src0VT>.ret;
 581
 582   field dag Outs = (outs DstRC:$dst);
 583
 584   field dag Ins32 = getIns32<Src0RC32, Src1RC32, NumSrcArgs>.ret;
 585   field dag Ins64 = getIns64<Src0RC64, Src1RC64, Src2RC64, NumSrcArgs,
 586                              HasModifiers>.ret;
 587
 588   field string Asm32 = "_e32"#getAsm32<NumSrcArgs>.ret;
 589   field string Asm64 = getAsm64<NumSrcArgs, HasModifiers>.ret;
 590 }
 591
 592 def VOP_F32_F32 : VOPProfile <[f32, f32, untyped, untyped]>;
 593 def VOP_F32_F64 : VOPProfile <[f32, f64, untyped, untyped]>;
 594 def VOP_F32_I32 : VOPProfile <[f32, i32, untyped, untyped]>;
 595 def VOP_F64_F32 : VOPProfile <[f64, f32, untyped, untyped]>;
 596 def VOP_F64_F64 : VOPProfile <[f64, f64, untyped, untyped]>;
 597 def VOP_F64_I32 : VOPProfile <[f64, i32, untyped, untyped]>;
 598 def VOP_I32_F32 : VOPProfile <[i32, f32, untyped, untyped]>;
 599 def VOP_I32_F64 : VOPProfile <[i32, f64, untyped, untyped]>;
 600 def VOP_I32_I32 : VOPProfile <[i32, i32, untyped, untyped]>;
 601
 602 def VOP_F32_F32_F32 : VOPProfile <[f32, f32, f32, untyped]>;
 603 def VOP_F32_F32_I32 : VOPProfile <[f32, f32, i32, untyped]>;
 604 def VOP_F64_F64_F64 : VOPProfile <[f64, f64, f64, untyped]>;
 605 def VOP_F64_F64_I32 : VOPProfile <[f64, f64, i32, untyped]>;
 606 def VOP_I32_F32_F32 : VOPProfile <[i32, f32, f32, untyped]>;
 607 def VOP_I32_I32_I32 : VOPProfile <[i32, i32, i32, untyped]>;
 608 def VOP_I32_I32_I32_VCC : VOPProfile <[i32, i32, i32, untyped]> {
 609   let Src0RC32 = VCSrc_32;
 610 }
 611 def VOP_I64_I64_I32 : VOPProfile <[i64, i64, i32, untyped]>;
 612 def VOP_I64_I64_I64 : VOPProfile <[i64, i64, i64, untyped]>;
 613
 614 def VOP_F32_F32_F32_F32 : VOPProfile <[f32, f32, f32, f32]>;
 615 def VOP_F64_F64_F64_F64 : VOPProfile <[f64, f64, f64, f64]>;
 616 def VOP_I32_I32_I32_I32 : VOPProfile <[i32, i32, i32, i32]>;
 617 def VOP_I64_I32_I32_I64 : VOPProfile <[i64, i32, i32, i64]>;
 618
 619
 620 class VOP <string opName> {
 621   string OpName = opName;
 622 }
 623
 624 class VOP2_REV <string revOp, bit isOrig> {
 625   string RevOp = revOp;
 626   bit IsOrig = isOrig;
 627 }
 628
 629 class AtomicNoRet <string noRetOp, bit isRet> {
 630   string NoRetOp = noRetOp;
 631   bit IsRet = isRet;
 632 }
 633
 634 class VOP1_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 635   VOP1Common <outs, ins, "", pattern>,
 636   SIMCInstr<opName, SISubtarget.NONE> {
 637   let isPseudo = 1;
 638 }
 639
 640 multiclass VOP1_m <vop1 op, dag outs, dag ins, string asm, list<dag> pattern,
 641                    string opName> {
 642   def "" : VOP1_Pseudo <outs, ins, pattern, opName>;
 643
 644   def _si : VOP1<op.SI, outs, ins, asm, []>,
 645             SIMCInstr <opName, SISubtarget.SI>;
 646 }
 647
 648 class VOP3DisableFields <bit HasSrc1, bit HasSrc2, bit HasModifiers> {
 649
 650   bits<2> src0_modifiers = !if(HasModifiers, ?, 0);
 651   bits<2> src1_modifiers = !if(HasModifiers, !if(HasSrc1, ?, 0), 0);
 652   bits<2> src2_modifiers = !if(HasModifiers, !if(HasSrc2, ? ,0) ,0);
 653   bits<2> omod = !if(HasModifiers, ?, 0);
 654   bits<1> clamp = !if(HasModifiers, ?, 0);
 655   bits<9> src1 = !if(HasSrc1, ?, 0);
 656   bits<9> src2 = !if(HasSrc2, ?, 0);
 657 }
 658
 659 class VOP3_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 660   VOP3Common <outs, ins, "", pattern>,
 661   VOP <opName>,
 662   SIMCInstr<opName, SISubtarget.NONE> {
 663   let isPseudo = 1;
 664 }
 665
 666 class VOP3_Real_si <bits<9> op, dag outs, dag ins, string asm, string opName> :
 667   VOP3 <op, outs, ins, asm, []>,
 668   SIMCInstr<opName, SISubtarget.SI>;
 669
 670 multiclass VOP3_m <vop3 op, dag outs, dag ins, string asm, list<dag> pattern,
 671                    string opName, int NumSrcArgs, bit HasMods = 1> {
 672
 673   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 674
 675   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 676             VOP3DisableFields<!if(!eq(NumSrcArgs, 1), 0, 1),
 677                               !if(!eq(NumSrcArgs, 2), 0, 1),
 678                               HasMods>;
 679
 680 }
 681
 682 multiclass VOP3_1_m <vop op, dag outs, dag ins, string asm,
 683                      list<dag> pattern, string opName, bit HasMods = 1> {
 684
 685   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 686
 687   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 688             VOP3DisableFields<0, 0, HasMods>;
 689 }
 690
 691 multiclass VOP3_2_m <vop op, dag outs, dag ins, string asm,
 692                      list<dag> pattern, string opName, string revOp,
 693                      bit HasMods = 1, bit UseFullOp = 0> {
 694
 695   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
 696            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
 697
 698   def _si : VOP3_Real_si <op.SI3,
 699               outs, ins, asm, opName>,
 700             VOP2_REV<revOp#"_e64_si", !eq(revOp, opName)>,
 701             VOP3DisableFields<1, 0, HasMods>;
 702 }
 703
 704 multiclass VOP3b_2_m <vop op, dag outs, dag ins, string asm,
 705                       list<dag> pattern, string opName, string revOp,
 706                       bit HasMods = 1, bit UseFullOp = 0> {
 707   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
 708            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
 709
 710   // The VOP2 variant puts the carry out into VCC, the VOP3 variant
 711   // can write it into any SGPR. We currently don't use the carry out,
 712   // so for now hardcode it to VCC as well.
 713   let sdst = SIOperand.VCC, Defs = [VCC] in {
 714     def _si : VOP3b <op.SI3, outs, ins, asm, pattern>,
 715               VOP3DisableFields<1, 0, HasMods>,
 716               SIMCInstr<opName, SISubtarget.SI>,
 717               VOP2_REV<revOp#"_e64_si", !eq(revOp, opName)>;
 718   } // End sdst = SIOperand.VCC, Defs = [VCC]
 719 }
 720
 721 multiclass VOP3_C_m <vop op, dag outs, dag ins, string asm,
 722                      list<dag> pattern, string opName,
 723                      bit HasMods, bit defExec> {
 724
 725   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 726
 727   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 728               VOP3DisableFields<1, 0, HasMods> {
 729     let Defs = !if(defExec, [EXEC], []);
 730   }
 731 }
 732
 733 multiclass VOP1_Helper <vop1 op, string opName, dag outs,
 734                         dag ins32, string asm32, list<dag> pat32,
 735                         dag ins64, string asm64, list<dag> pat64,
 736                         bit HasMods> {
 737
 738   def _e32 : VOP1 <op.SI, outs, ins32, opName#asm32, pat32>, VOP<opName>;
 739
 740   defm _e64 : VOP3_1_m <op, outs, ins64, opName#"_e64"#asm64, pat64, opName, HasMods>;
 741 }
 742
 743 multiclass VOP1Inst <vop1 op, string opName, VOPProfile P,
 744                      SDPatternOperator node = null_frag> : VOP1_Helper <
 745   op, opName, P.Outs,
 746   P.Ins32, P.Asm32, [],
 747   P.Ins64, P.Asm64,
 748   !if(P.HasModifiers,
 749       [(set P.DstVT:$dst, (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0,
 750                                 i32:$src0_modifiers, i1:$clamp, i32:$omod))))],
 751       [(set P.DstVT:$dst, (node P.Src0VT:$src0))]),
 752   P.HasModifiers
 753 >;
 754
 755 class VOP2_e32 <bits<6> op, string opName, dag outs, dag ins, string asm,
 756                 list<dag> pattern, string revOp> :
 757   VOP2 <op, outs, ins, opName#asm, pattern>,
 758   VOP <opName>,
 759   VOP2_REV<revOp#"_e32", !eq(revOp, opName)>;
 760
 761 multiclass VOP2_Helper <vop2 op, string opName, dag outs,
 762                         dag ins32, string asm32, list<dag> pat32,
 763                         dag ins64, string asm64, list<dag> pat64,
 764                         string revOp, bit HasMods> {
 765   def _e32 : VOP2_e32 <op.SI, opName, outs, ins32, asm32, pat32, revOp>;
 766
 767   defm _e64 : VOP3_2_m <op,
 768     outs, ins64, opName#"_e64"#asm64, pat64, opName, revOp, HasMods
 769   >;
 770 }
 771
 772 multiclass VOP2Inst <vop2 op, string opName, VOPProfile P,
 773                      SDPatternOperator node = null_frag,
 774                      string revOp = opName> : VOP2_Helper <
 775   op, opName, P.Outs,
 776   P.Ins32, P.Asm32, [],
 777   P.Ins64, P.Asm64,
 778   !if(P.HasModifiers,
 779       [(set P.DstVT:$dst,
 780            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 781                                       i1:$clamp, i32:$omod)),
 782                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
 783       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
 784   revOp, P.HasModifiers
 785 >;
 786
 787 multiclass VOP2b_Helper <vop2 op, string opName, dag outs,
 788                          dag ins32, string asm32, list<dag> pat32,
 789                          dag ins64, string asm64, list<dag> pat64,
 790                          string revOp, bit HasMods> {
 791
 792   def _e32 : VOP2_e32 <op.SI, opName, outs, ins32, asm32, pat32, revOp>;
 793
 794   defm _e64 : VOP3b_2_m <op,
 795     outs, ins64, opName#"_e64"#asm64, pat64, opName, revOp, HasMods
 796   >;
 797 }
 798
 799 multiclass VOP2bInst <vop2 op, string opName, VOPProfile P,
 800                       SDPatternOperator node = null_frag,
 801                       string revOp = opName> : VOP2b_Helper <
 802   op, opName, P.Outs,
 803   P.Ins32, P.Asm32, [],
 804   P.Ins64, P.Asm64,
 805   !if(P.HasModifiers,
 806       [(set P.DstVT:$dst,
 807            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 808                                       i1:$clamp, i32:$omod)),
 809                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
 810       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
 811   revOp, P.HasModifiers
 812 >;
 813
 814 multiclass VOPC_Helper <vopc op, string opName,
 815                         dag ins32, string asm32, list<dag> pat32,
 816                         dag out64, dag ins64, string asm64, list<dag> pat64,
 817                         bit HasMods, bit DefExec> {
 818   def _e32 : VOPC <op.SI, ins32, opName#asm32, pat32>, VOP <opName> {
 819     let Defs = !if(DefExec, [EXEC], []);
 820   }
 821
 822   defm _e64 : VOP3_C_m <op, out64, ins64, opName#"_e64"#asm64, pat64, opName,
 823                         HasMods, DefExec>;
 824 }
 825
 826 multiclass VOPCInst <vopc op, string opName,
 827                      VOPProfile P, PatLeaf cond = COND_NULL,
 828                      bit DefExec = 0> : VOPC_Helper <
 829   op, opName,
 830   P.Ins32, P.Asm32, [],
 831   (outs SReg_64:$dst), P.Ins64, P.Asm64,
 832   !if(P.HasModifiers,
 833       [(set i1:$dst,
 834           (setcc (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 835                                       i1:$clamp, i32:$omod)),
 836                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
 837                  cond))],
 838       [(set i1:$dst, (setcc P.Src0VT:$src0, P.Src1VT:$src1, cond))]),
 839   P.HasModifiers, DefExec
 840 >;
 841
 842 multiclass VOPC_F32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
 843   VOPCInst <op, opName, VOP_F32_F32_F32, cond>;
 844
 845 multiclass VOPC_F64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
 846   VOPCInst <op, opName, VOP_F64_F64_F64, cond>;
 847
 848 multiclass VOPC_I32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
 849   VOPCInst <op, opName, VOP_I32_I32_I32, cond>;
 850
 851 multiclass VOPC_I64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
 852   VOPCInst <op, opName, VOP_I64_I64_I64, cond>;
 853
 854
 855 multiclass VOPCX <vopc op, string opName, VOPProfile P,
 856                   PatLeaf cond = COND_NULL>
 857   : VOPCInst <op, opName, P, cond, 1>;
 858
 859 multiclass VOPCX_F32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
 860   VOPCX <op, opName, VOP_F32_F32_F32, cond>;
 861
 862 multiclass VOPCX_F64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
 863   VOPCX <op, opName, VOP_F64_F64_F64, cond>;
 864
 865 multiclass VOPCX_I32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
 866   VOPCX <op, opName, VOP_I32_I32_I32, cond>;
 867
 868 multiclass VOPCX_I64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
 869   VOPCX <op, opName, VOP_I64_I64_I64, cond>;
 870
 871 multiclass VOP3_Helper <vop3 op, string opName, dag outs, dag ins, string asm,
 872                         list<dag> pat, int NumSrcArgs, bit HasMods> : VOP3_m <
 873     op, outs, ins, opName#asm, pat, opName, NumSrcArgs, HasMods
 874 >;
 875
 876 multiclass VOP3Inst <vop3 op, string opName, VOPProfile P,
 877                      SDPatternOperator node = null_frag> : VOP3_Helper <
 878   op, opName, P.Outs, P.Ins64, P.Asm64,
 879   !if(!eq(P.NumSrcArgs, 3),
 880     !if(P.HasModifiers,
 881         [(set P.DstVT:$dst,
 882             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 883                                        i1:$clamp, i32:$omod)),
 884                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
 885                   (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))))],
 886         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1,
 887                                   P.Src2VT:$src2))]),
 888   !if(!eq(P.NumSrcArgs, 2),
 889     !if(P.HasModifiers,
 890         [(set P.DstVT:$dst,
 891             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 892                                        i1:$clamp, i32:$omod)),
 893                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
 894         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))])
 895   /* P.NumSrcArgs == 1 */,
 896     !if(P.HasModifiers,
 897         [(set P.DstVT:$dst,
 898             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 899                                        i1:$clamp, i32:$omod))))],
 900         [(set P.DstVT:$dst, (node P.Src0VT:$src0))]))),
 901   P.NumSrcArgs, P.HasModifiers
 902 >;
 903
 904 multiclass VOP3b_Helper <vop op, RegisterClass vrc, RegisterClass arc,
 905                     string opName, list<dag> pattern> :
 906   VOP3b_2_m <
 907   op, (outs vrc:$vdst, SReg_64:$sdst),
 908       (ins InputModsNoDefault:$src0_modifiers, arc:$src0,
 909            InputModsNoDefault:$src1_modifiers, arc:$src1,
 910            InputModsNoDefault:$src2_modifiers, arc:$src2,
 911            ClampMod:$clamp, omod:$omod),
 912   opName#" $vdst, $sdst, $src0_modifiers, $src1_modifiers, $src2_modifiers"#"$clamp"#"$omod", pattern,
 913   opName, opName, 1, 1
 914 >;
 915
 916 multiclass VOP3b_64 <vop3 op, string opName, list<dag> pattern> :
 917   VOP3b_Helper <op, VReg_64, VSrc_64, opName, pattern>;
 918
 919 multiclass VOP3b_32 <vop3 op, string opName, list<dag> pattern> :
 920   VOP3b_Helper <op, VReg_32, VSrc_32, opName, pattern>;
 921
 922
 923 class Vop3ModPat<Instruction Inst, VOPProfile P, SDPatternOperator node> : Pat<
 924   (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers, i1:$clamp, i32:$omod)),
 925         (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
 926         (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))),
 927   (Inst i32:$src0_modifiers, P.Src0VT:$src0,
 928         i32:$src1_modifiers, P.Src1VT:$src1,
 929         i32:$src2_modifiers, P.Src2VT:$src2,
 930         i1:$clamp,
 931         i32:$omod)>;
 932
 933 //===----------------------------------------------------------------------===//
 934 // Vector I/O classes
 935 //===----------------------------------------------------------------------===//
 936
 937 class DS_1A <bits<8> op, dag outs, dag ins, string asm, list<dag> pat> :
 938     DS <op, outs, ins, asm, pat> {
 939   bits<16> offset;
 940
 941   // Single load interpret the 2 i8imm operands as a single i16 offset.
 942   let offset0 = offset{7-0};
 943   let offset1 = offset{15-8};
 944
 945   let hasSideEffects = 0;
 946 }
 947
 948 class DS_Load_Helper <bits<8> op, string asm, RegisterClass regClass> : DS_1A <
 949   op,
 950   (outs regClass:$vdst),
 951   (ins i1imm:$gds, VReg_32:$addr, ds_offset:$offset),
 952   asm#" $vdst, $addr"#"$offset"#" [M0]",
 953   []> {
 954   let data0 = 0;
 955   let data1 = 0;
 956   let mayLoad = 1;
 957   let mayStore = 0;
 958 }
 959
 960 class DS_Load2_Helper <bits<8> op, string asm, RegisterClass regClass> : DS <
 961   op,
 962   (outs regClass:$vdst),
 963   (ins i1imm:$gds, VReg_32:$addr, ds_offset0:$offset0, ds_offset1:$offset1),
 964   asm#" $vdst, $addr"#"$offset0"#"$offset1 [M0]",
 965   []> {
 966   let data0 = 0;
 967   let data1 = 0;
 968   let mayLoad = 1;
 969   let mayStore = 0;
 970   let hasSideEffects = 0;
 971 }
 972
 973 class DS_Store_Helper <bits<8> op, string asm, RegisterClass regClass> : DS_1A <
 974   op,
 975   (outs),
 976   (ins i1imm:$gds, VReg_32:$addr, regClass:$data0, ds_offset:$offset),
 977   asm#" $addr, $data0"#"$offset"#" [M0]",
 978   []> {
 979   let data1 = 0;
 980   let mayStore = 1;
 981   let mayLoad = 0;
 982   let vdst = 0;
 983 }
 984
 985 class DS_Store2_Helper <bits<8> op, string asm, RegisterClass regClass> : DS <
 986   op,
 987   (outs),
 988   (ins i1imm:$gds, VReg_32:$addr, regClass:$data0, regClass:$data1,
 989        ds_offset0:$offset0, ds_offset1:$offset1),
 990   asm#" $addr, $data0, $data1"#"$offset0"#"$offset1 [M0]",
 991   []> {
 992   let mayStore = 1;
 993   let mayLoad = 0;
 994   let hasSideEffects = 0;
 995   let vdst = 0;
 996 }
 997
 998 // 1 address, 1 data.
 999 class DS_1A1D_RET <bits<8> op, string asm, RegisterClass rc, string noRetOp = ""> : DS_1A <
1000   op,
1001   (outs rc:$vdst),
1002   (ins i1imm:$gds, VReg_32:$addr, rc:$data0, ds_offset:$offset),
1003   asm#" $vdst, $addr, $data0"#"$offset"#" [M0]", []>,
1004   AtomicNoRet<noRetOp, 1> {
1005
1006   let data1 = 0;
1007   let mayStore = 1;
1008   let mayLoad = 1;
1009
1010   let hasPostISelHook = 1; // Adjusted to no return version.
1011 }
1012
1013 // 1 address, 2 data.
1014 class DS_1A2D_RET <bits<8> op, string asm, RegisterClass rc, string noRetOp = ""> : DS_1A <
1015   op,
1016   (outs rc:$vdst),
1017   (ins i1imm:$gds, VReg_32:$addr, rc:$data0, rc:$data1, ds_offset:$offset),
1018   asm#" $vdst, $addr, $data0, $data1"#"$offset"#" [M0]",
1019   []>,
1020   AtomicNoRet<noRetOp, 1> {
1021   let mayStore = 1;
1022   let mayLoad = 1;
1023   let hasPostISelHook = 1; // Adjusted to no return version.
1024 }
1025
1026 // 1 address, 2 data.
1027 class DS_1A2D_NORET <bits<8> op, string asm, RegisterClass rc, string noRetOp = asm> : DS_1A <
1028   op,
1029   (outs),
1030   (ins i1imm:$gds, VReg_32:$addr, rc:$data0, rc:$data1, ds_offset:$offset),
1031   asm#" $addr, $data0, $data1"#"$offset"#" [M0]",
1032   []>,
1033   AtomicNoRet<noRetOp, 0> {
1034   let mayStore = 1;
1035   let mayLoad = 1;
1036 }
1037
1038 // 1 address, 1 data.
1039 class DS_1A1D_NORET <bits<8> op, string asm, RegisterClass rc, string noRetOp = asm> : DS_1A <
1040   op,
1041   (outs),
1042   (ins i1imm:$gds, VReg_32:$addr, rc:$data0, ds_offset:$offset),
1043   asm#" $addr, $data0"#"$offset"#" [M0]",
1044   []>,
1045   AtomicNoRet<noRetOp, 0> {
1046
1047   let data1 = 0;
1048   let mayStore = 1;
1049   let mayLoad = 1;
1050 }
1051
1052 //===----------------------------------------------------------------------===//
1053 // MTBUF classes
1054 //===----------------------------------------------------------------------===//
1055
1056 class MTBUF_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1057   MTBUF <outs, ins, "", pattern>,
1058   SIMCInstr<opName, SISubtarget.NONE> {
1059   let isPseudo = 1;
1060 }
1061
1062 class MTBUF_Real_si <bits<3> op, string opName, dag outs, dag ins,
1063                     string asm> :
1064   MTBUF <outs, ins, asm, []>,
1065   MTBUFe <op>,
1066   SIMCInstr<opName, SISubtarget.SI>;
1067
1068 multiclass MTBUF_m <bits<3> op, string opName, dag outs, dag ins, string asm,
1069                     list<dag> pattern> {
1070
1071   def "" : MTBUF_Pseudo <opName, outs, ins, pattern>;
1072
1073   def _si : MTBUF_Real_si <op, opName, outs, ins, asm>;
1074
1075 }
1076
1077 let mayStore = 1, mayLoad = 0 in {
1078
1079 multiclass MTBUF_Store_Helper <bits<3> op, string opName,
1080                                RegisterClass regClass> : MTBUF_m <
1081   op, opName, (outs),
1082   (ins regClass:$vdata, u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc,
1083    i1imm:$addr64, i8imm:$dfmt, i8imm:$nfmt, VReg_32:$vaddr,
1084    SReg_128:$srsrc, i1imm:$slc, i1imm:$tfe, SSrc_32:$soffset),
1085   opName#" $vdata, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
1086         #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset", []
1087 >;
1088
1089 } // mayStore = 1, mayLoad = 0
1090
1091 let mayLoad = 1, mayStore = 0 in {
1092
1093 multiclass MTBUF_Load_Helper <bits<3> op, string opName,
1094                               RegisterClass regClass> : MTBUF_m <
1095   op, opName, (outs regClass:$dst),
1096   (ins u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc, i1imm:$addr64,
1097        i8imm:$dfmt, i8imm:$nfmt, VReg_32:$vaddr, SReg_128:$srsrc,
1098        i1imm:$slc, i1imm:$tfe, SSrc_32:$soffset),
1099   opName#" $dst, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
1100         #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset", []
1101 >;
1102
1103 } // mayLoad = 1, mayStore = 0
1104
1105 class MUBUFAddr64Table <bit is_addr64, string suffix = ""> {
1106
1107   bit IsAddr64 = is_addr64;
1108   string OpName = NAME # suffix;
1109 }
1110
1111 class MUBUFAtomicAddr64 <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern>
1112     : MUBUF <op, outs, ins, asm, pattern> {
1113
1114   let offen = 0;
1115   let idxen = 0;
1116   let addr64 = 1;
1117   let tfe = 0;
1118   let lds = 0;
1119   let soffset = 128;
1120 }
1121
1122 class MUBUFAtomicOffset <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern>
1123     : MUBUF <op, outs, ins, asm, pattern> {
1124
1125   let offen = 0;
1126   let idxen = 0;
1127   let addr64 = 0;
1128   let tfe = 0;
1129   let lds = 0;
1130   let vaddr = 0;
1131 }
1132
1133 multiclass MUBUF_Atomic <bits<7> op, string name, RegisterClass rc,
1134                          ValueType vt, SDPatternOperator atomic> {
1135
1136   let mayStore = 1, mayLoad = 1, hasPostISelHook = 1 in {
1137
1138     // No return variants
1139     let glc = 0 in {
1140
1141       def _ADDR64 : MUBUFAtomicAddr64 <
1142         op, (outs),
1143         (ins rc:$vdata, SReg_128:$srsrc, VReg_64:$vaddr,
1144              mbuf_offset:$offset, slc:$slc),
1145         name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset"#"$slc", []
1146       >, MUBUFAddr64Table<1>, AtomicNoRet<NAME#"_ADDR64", 0>;
1147
1148       def _OFFSET : MUBUFAtomicOffset <
1149         op, (outs),
1150         (ins rc:$vdata, SReg_128:$srsrc, mbuf_offset:$offset,
1151              SSrc_32:$soffset, slc:$slc),
1152         name#" $vdata, $srsrc, $soffset"#"$offset"#"$slc", []
1153       >, MUBUFAddr64Table<0>, AtomicNoRet<NAME#"_OFFSET", 0>;
1154     } // glc = 0
1155
1156     // Variant that return values
1157     let glc = 1, Constraints = "$vdata = $vdata_in",
1158         DisableEncoding = "$vdata_in"  in {
1159
1160       def _RTN_ADDR64 : MUBUFAtomicAddr64 <
1161         op, (outs rc:$vdata),
1162         (ins rc:$vdata_in, SReg_128:$srsrc, VReg_64:$vaddr,
1163              mbuf_offset:$offset, slc:$slc),
1164         name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset"#" glc"#"$slc",
1165         [(set vt:$vdata,
1166          (atomic (MUBUFAddr64Atomic v4i32:$srsrc, i64:$vaddr, i16:$offset,
1167                                     i1:$slc), vt:$vdata_in))]
1168       >, MUBUFAddr64Table<1, "_RTN">, AtomicNoRet<NAME#"_ADDR64", 1>;
1169
1170       def _RTN_OFFSET : MUBUFAtomicOffset <
1171         op, (outs rc:$vdata),
1172         (ins rc:$vdata_in, SReg_128:$srsrc, mbuf_offset:$offset,
1173              SSrc_32:$soffset, slc:$slc),
1174         name#" $vdata, $srsrc, $soffset"#"$offset"#" glc $slc",
1175         [(set vt:$vdata,
1176          (atomic (MUBUFOffsetAtomic v4i32:$srsrc, i32:$soffset, i16:$offset,
1177                                     i1:$slc), vt:$vdata_in))]
1178       >, MUBUFAddr64Table<0, "_RTN">, AtomicNoRet<NAME#"_OFFSET", 1>;
1179
1180     } // glc = 1
1181
1182   } // mayStore = 1, mayLoad = 1, hasPostISelHook = 1
1183 }
1184
1185 multiclass MUBUF_Load_Helper <bits<7> op, string asm, RegisterClass regClass,
1186                               ValueType load_vt = i32,
1187                               SDPatternOperator ld = null_frag> {
1188
1189   let lds = 0, mayLoad = 1 in {
1190
1191     let addr64 = 0 in {
1192
1193       let offen = 0, idxen = 0, vaddr = 0 in {
1194         def _OFFSET : MUBUF <op, (outs regClass:$vdata),
1195                              (ins SReg_128:$srsrc,
1196                              mbuf_offset:$offset, SSrc_32:$soffset, glc:$glc,
1197                              slc:$slc, tfe:$tfe),
1198                              asm#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1199                              [(set load_vt:$vdata, (ld (MUBUFOffset v4i32:$srsrc,
1200                                                        i32:$soffset, i16:$offset,
1201                                                        i1:$glc, i1:$slc, i1:$tfe)))]>,
1202                      MUBUFAddr64Table<0>;
1203       }
1204
1205       let offen = 1, idxen = 0  in {
1206         def _OFFEN  : MUBUF <op, (outs regClass:$vdata),
1207                              (ins SReg_128:$srsrc, VReg_32:$vaddr,
1208                              SSrc_32:$soffset, mbuf_offset:$offset, glc:$glc, slc:$slc,
1209                              tfe:$tfe),
1210                              asm#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1211       }
1212
1213       let offen = 0, idxen = 1 in {
1214         def _IDXEN  : MUBUF <op, (outs regClass:$vdata),
1215                              (ins SReg_128:$srsrc, VReg_32:$vaddr,
1216                              mbuf_offset:$offset, SSrc_32:$soffset, glc:$glc,
1217                              slc:$slc, tfe:$tfe),
1218                              asm#" $vdata, $vaddr, $srsrc, $soffset idxen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1219       }
1220
1221       let offen = 1, idxen = 1 in {
1222         def _BOTHEN : MUBUF <op, (outs regClass:$vdata),
1223                              (ins SReg_128:$srsrc, VReg_64:$vaddr,
1224                              SSrc_32:$soffset, glc:$glc, slc:$slc, tfe:$tfe),
1225                              asm#" $vdata, $vaddr, $srsrc, $soffset, idxen offen"#"$glc"#"$slc"#"$tfe", []>;
1226       }
1227     }
1228
1229     let offen = 0, idxen = 0, addr64 = 1, glc = 0, slc = 0, tfe = 0, soffset = 128 /* ZERO */ in {
1230       def _ADDR64 : MUBUF <op, (outs regClass:$vdata),
1231                            (ins SReg_128:$srsrc, VReg_64:$vaddr, mbuf_offset:$offset),
1232                            asm#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset",
1233                            [(set load_vt:$vdata, (ld (MUBUFAddr64 v4i32:$srsrc,
1234                                                   i64:$vaddr, i16:$offset)))]>, MUBUFAddr64Table<1>;
1235     }
1236   }
1237 }
1238
1239 multiclass MUBUF_Store_Helper <bits<7> op, string name, RegisterClass vdataClass,
1240                           ValueType store_vt, SDPatternOperator st> {
1241
1242   let addr64 = 0, lds = 0 in {
1243
1244     def "" : MUBUF <
1245       op, (outs),
1246       (ins vdataClass:$vdata, SReg_128:$srsrc, VReg_32:$vaddr, SSrc_32:$soffset,
1247            mbuf_offset:$offset, offen:$offen, idxen:$idxen, glc:$glc, slc:$slc,
1248            tfe:$tfe),
1249       name#" $vdata, $vaddr, $srsrc, $soffset"#"$offen"#"$idxen"#"$offset"#
1250            "$glc"#"$slc"#"$tfe",
1251       []
1252     >;
1253
1254     let offen = 0, idxen = 0, vaddr = 0 in {
1255       def _OFFSET : MUBUF <
1256         op, (outs),
1257         (ins vdataClass:$vdata, SReg_128:$srsrc, mbuf_offset:$offset,
1258               SSrc_32:$soffset, glc:$glc, slc:$slc, tfe:$tfe),
1259         name#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1260         [(st store_vt:$vdata, (MUBUFOffset v4i32:$srsrc, i32:$soffset,
1261                                            i16:$offset, i1:$glc, i1:$slc,
1262                                            i1:$tfe))]
1263       >, MUBUFAddr64Table<0>;
1264     } // offen = 0, idxen = 0, vaddr = 0
1265
1266     let offen = 1, idxen = 0  in {
1267       def _OFFEN  : MUBUF <
1268         op, (outs),
1269         (ins vdataClass:$vdata, SReg_128:$srsrc, VReg_32:$vaddr, SSrc_32:$soffset,
1270              mbuf_offset:$offset, glc:$glc, slc:$slc, tfe:$tfe),
1271         name#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#
1272             "$glc"#"$slc"#"$tfe",
1273         []
1274       >;
1275     } // end offen = 1, idxen = 0
1276
1277   } // End addr64 = 0, lds = 0
1278
1279   def _ADDR64 : MUBUF <
1280     op, (outs),
1281     (ins vdataClass:$vdata, SReg_128:$srsrc, VReg_64:$vaddr, mbuf_offset:$offset),
1282     name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset",
1283     [(st store_vt:$vdata,
1284      (MUBUFAddr64 v4i32:$srsrc, i64:$vaddr, i16:$offset))]>, MUBUFAddr64Table<1>
1285      {
1286
1287       let mayLoad = 0;
1288       let mayStore = 1;
1289
1290       // Encoding
1291       let offen = 0;
1292       let idxen = 0;
1293       let glc = 0;
1294       let addr64 = 1;
1295       let lds = 0;
1296       let slc = 0;
1297       let tfe = 0;
1298       let soffset = 128; // ZERO
1299    }
1300 }
1301
1302 class FLAT_Load_Helper <bits<7> op, string asm, RegisterClass regClass> :
1303       FLAT <op, (outs regClass:$data),
1304                 (ins VReg_64:$addr),
1305             asm#" $data, $addr, [M0, FLAT_SCRATCH]", []> {
1306   let glc = 0;
1307   let slc = 0;
1308   let tfe = 0;
1309   let mayLoad = 1;
1310 }
1311
1312 class FLAT_Store_Helper <bits<7> op, string name, RegisterClass vdataClass> :
1313       FLAT <op, (outs), (ins vdataClass:$data, VReg_64:$addr),
1314           name#" $data, $addr, [M0, FLAT_SCRATCH]",
1315          []> {
1316
1317   let mayLoad = 0;
1318   let mayStore = 1;
1319
1320   // Encoding
1321   let glc = 0;
1322   let slc = 0;
1323   let tfe = 0;
1324 }
1325
1326 class MIMG_Mask <string op, int channels> {
1327   string Op = op;
1328   int Channels = channels;
1329 }
1330
1331 class MIMG_NoSampler_Helper <bits<7> op, string asm,
1332                              RegisterClass dst_rc,
1333                              RegisterClass src_rc> : MIMG <
1334   op,
1335   (outs dst_rc:$vdata),
1336   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1337        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1338        SReg_256:$srsrc),
1339   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1340      #" $tfe, $lwe, $slc, $vaddr, $srsrc",
1341   []> {
1342   let SSAMP = 0;
1343   let mayLoad = 1;
1344   let mayStore = 0;
1345   let hasPostISelHook = 1;
1346 }
1347
1348 multiclass MIMG_NoSampler_Src_Helper <bits<7> op, string asm,
1349                                       RegisterClass dst_rc,
1350                                       int channels> {
1351   def _V1 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_32>,
1352             MIMG_Mask<asm#"_V1", channels>;
1353   def _V2 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_64>,
1354             MIMG_Mask<asm#"_V2", channels>;
1355   def _V4 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_128>,
1356             MIMG_Mask<asm#"_V4", channels>;
1357 }
1358
1359 multiclass MIMG_NoSampler <bits<7> op, string asm> {
1360   defm _V1 : MIMG_NoSampler_Src_Helper <op, asm, VReg_32, 1>;
1361   defm _V2 : MIMG_NoSampler_Src_Helper <op, asm, VReg_64, 2>;
1362   defm _V3 : MIMG_NoSampler_Src_Helper <op, asm, VReg_96, 3>;
1363   defm _V4 : MIMG_NoSampler_Src_Helper <op, asm, VReg_128, 4>;
1364 }
1365
1366 class MIMG_Sampler_Helper <bits<7> op, string asm,
1367                            RegisterClass dst_rc,
1368                            RegisterClass src_rc> : MIMG <
1369   op,
1370   (outs dst_rc:$vdata),
1371   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1372        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1373        SReg_256:$srsrc, SReg_128:$ssamp),
1374   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1375      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
1376   []> {
1377   let mayLoad = 1;
1378   let mayStore = 0;
1379   let hasPostISelHook = 1;
1380 }
1381
1382 multiclass MIMG_Sampler_Src_Helper <bits<7> op, string asm,
1383                                     RegisterClass dst_rc,
1384                                     int channels> {
1385   def _V1 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_32>,
1386             MIMG_Mask<asm#"_V1", channels>;
1387   def _V2 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_64>,
1388             MIMG_Mask<asm#"_V2", channels>;
1389   def _V4 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_128>,
1390             MIMG_Mask<asm#"_V4", channels>;
1391   def _V8 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_256>,
1392             MIMG_Mask<asm#"_V8", channels>;
1393   def _V16 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_512>,
1394             MIMG_Mask<asm#"_V16", channels>;
1395 }
1396
1397 multiclass MIMG_Sampler <bits<7> op, string asm> {
1398   defm _V1 : MIMG_Sampler_Src_Helper<op, asm, VReg_32, 1>;
1399   defm _V2 : MIMG_Sampler_Src_Helper<op, asm, VReg_64, 2>;
1400   defm _V3 : MIMG_Sampler_Src_Helper<op, asm, VReg_96, 3>;
1401   defm _V4 : MIMG_Sampler_Src_Helper<op, asm, VReg_128, 4>;
1402 }
1403
1404 class MIMG_Gather_Helper <bits<7> op, string asm,
1405                           RegisterClass dst_rc,
1406                           RegisterClass src_rc> : MIMG <
1407   op,
1408   (outs dst_rc:$vdata),
1409   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1410        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1411        SReg_256:$srsrc, SReg_128:$ssamp),
1412   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1413      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
1414   []> {
1415   let mayLoad = 1;
1416   let mayStore = 0;
1417
1418   // DMASK was repurposed for GATHER4. 4 components are always
1419   // returned and DMASK works like a swizzle - it selects
1420   // the component to fetch. The only useful DMASK values are
1421   // 1=red, 2=green, 4=blue, 8=alpha. (e.g. 1 returns
1422   // (red,red,red,red) etc.) The ISA document doesn't mention
1423   // this.
1424   // Therefore, disable all code which updates DMASK by setting these two:
1425   let MIMG = 0;
1426   let hasPostISelHook = 0;
1427 }
1428
1429 multiclass MIMG_Gather_Src_Helper <bits<7> op, string asm,
1430                                     RegisterClass dst_rc,
1431                                     int channels> {
1432   def _V1 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_32>,
1433             MIMG_Mask<asm#"_V1", channels>;
1434   def _V2 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_64>,
1435             MIMG_Mask<asm#"_V2", channels>;
1436   def _V4 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_128>,
1437             MIMG_Mask<asm#"_V4", channels>;
1438   def _V8 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_256>,
1439             MIMG_Mask<asm#"_V8", channels>;
1440   def _V16 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_512>,
1441             MIMG_Mask<asm#"_V16", channels>;
1442 }
1443
1444 multiclass MIMG_Gather <bits<7> op, string asm> {
1445   defm _V1 : MIMG_Gather_Src_Helper<op, asm, VReg_32, 1>;
1446   defm _V2 : MIMG_Gather_Src_Helper<op, asm, VReg_64, 2>;
1447   defm _V3 : MIMG_Gather_Src_Helper<op, asm, VReg_96, 3>;
1448   defm _V4 : MIMG_Gather_Src_Helper<op, asm, VReg_128, 4>;
1449 }
1450
1451 //===----------------------------------------------------------------------===//
1452 // Vector instruction mappings
1453 //===----------------------------------------------------------------------===//
1454
1455 // Maps an opcode in e32 form to its e64 equivalent
1456 def getVOPe64 : InstrMapping {
1457   let FilterClass = "VOP";
1458   let RowFields = ["OpName"];
1459   let ColFields = ["Size"];
1460   let KeyCol = ["4"];
1461   let ValueCols = [["8"]];
1462 }
1463
1464 // Maps an opcode in e64 form to its e32 equivalent
1465 def getVOPe32 : InstrMapping {
1466   let FilterClass = "VOP";
1467   let RowFields = ["OpName"];
1468   let ColFields = ["Size"];
1469   let KeyCol = ["8"];
1470   let ValueCols = [["4"]];
1471 }
1472
1473 // Maps an original opcode to its commuted version
1474 def getCommuteRev : InstrMapping {
1475   let FilterClass = "VOP2_REV";
1476   let RowFields = ["RevOp"];
1477   let ColFields = ["IsOrig"];
1478   let KeyCol = ["1"];
1479   let ValueCols = [["0"]];
1480 }
1481
1482 def getMaskedMIMGOp : InstrMapping {
1483   let FilterClass = "MIMG_Mask";
1484   let RowFields = ["Op"];
1485   let ColFields = ["Channels"];
1486   let KeyCol = ["4"];
1487   let ValueCols = [["1"], ["2"], ["3"] ];
1488 }
1489
1490 // Maps an commuted opcode to its original version
1491 def getCommuteOrig : InstrMapping {
1492   let FilterClass = "VOP2_REV";
1493   let RowFields = ["RevOp"];
1494   let ColFields = ["IsOrig"];
1495   let KeyCol = ["0"];
1496   let ValueCols = [["1"]];
1497 }
1498
1499 def isDS : InstrMapping {
1500   let FilterClass = "DS";
1501   let RowFields = ["Inst"];
1502   let ColFields = ["Size"];
1503   let KeyCol = ["8"];
1504   let ValueCols = [["8"]];
1505 }
1506
1507 def getMCOpcode : InstrMapping {
1508   let FilterClass = "SIMCInstr";
1509   let RowFields = ["PseudoInstr"];
1510   let ColFields = ["Subtarget"];
1511   let KeyCol = [!cast<string>(SISubtarget.NONE)];
1512   let ValueCols = [[!cast<string>(SISubtarget.SI)]];
1513 }
1514
1515 def getAddr64Inst : InstrMapping {
1516   let FilterClass = "MUBUFAddr64Table";
1517   let RowFields = ["OpName"];
1518   let ColFields = ["IsAddr64"];
1519   let KeyCol = ["0"];
1520   let ValueCols = [["1"]];
1521 }
1522
1523 // Maps an atomic opcode to its version with a return value.
1524 def getAtomicRetOp : InstrMapping {
1525   let FilterClass = "AtomicNoRet";
1526   let RowFields = ["NoRetOp"];
1527   let ColFields = ["IsRet"];
1528   let KeyCol = ["0"];
1529   let ValueCols = [["1"]];
1530 }
1531
1532 // Maps an atomic opcode to its returnless version.
1533 def getAtomicNoRetOp : InstrMapping {
1534   let FilterClass = "AtomicNoRet";
1535   let RowFields = ["NoRetOp"];
1536   let ColFields = ["IsRet"];
1537   let KeyCol = ["1"];
1538   let ValueCols = [["0"]];
1539 }
1540
1541 include "SIInstructions.td"