lib/Target/R600/SIInstrInfo.td

   1 //===-- SIInstrInfo.td - SI Instruction Infos -------------*- tablegen -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 class vop {
  11   field bits<9> SI3;
  12   field bits<10> VI3;
  13 }
  14
  15 class vopc <bits<8> si, bits<8> vi = !add(0x40, si)> : vop {
  16   field bits<8> SI = si;
  17   field bits<8> VI = vi;
  18
  19   field bits<9>  SI3 = {0, si{7-0}};
  20   field bits<10> VI3 = {0, 0, vi{7-0}};
  21 }
  22
  23 class vop1 <bits<8> si, bits<8> vi = si> : vop {
  24   field bits<8> SI = si;
  25   field bits<8> VI = vi;
  26
  27   field bits<9>  SI3 = {1, 1, si{6-0}};
  28   field bits<10> VI3 = !add(0x140, vi);
  29 }
  30
  31 class vop2 <bits<6> si, bits<6> vi = si> : vop {
  32   field bits<6> SI = si;
  33   field bits<6> VI = vi;
  34
  35   field bits<9>  SI3 = {1, 0, 0, si{5-0}};
  36   field bits<10> VI3 = {0, 1, 0, 0, vi{5-0}};
  37 }
  38
  39 // Specify a VOP2 opcode for SI and VOP3 opcode for VI
  40 // that doesn't have VOP2 encoding on VI
  41 class vop23 <bits<6> si, bits<10> vi> : vop2 <si> {
  42   let VI3 = vi;
  43 }
  44
  45 class vop3 <bits<9> si, bits<10> vi = {0, si}> : vop {
  46   let SI3 = si;
  47   let VI3 = vi;
  48 }
  49
  50 class sop1 <bits<8> si, bits<8> vi = si> {
  51   field bits<8> SI = si;
  52   field bits<8> VI = vi;
  53 }
  54
  55 class sop2 <bits<7> si, bits<7> vi = si> {
  56   field bits<7> SI = si;
  57   field bits<7> VI = vi;
  58 }
  59
  60 class sopk <bits<5> si, bits<5> vi = si> {
  61   field bits<5> SI = si;
  62   field bits<5> VI = vi;
  63 }
  64
  65 // Execpt for the NONE field, this must be kept in sync with the SISubtarget enum
  66 // in AMDGPUInstrInfo.cpp
  67 def SISubtarget {
  68   int NONE = -1;
  69   int SI = 0;
  70   int VI = 1;
  71 }
  72
  73 //===----------------------------------------------------------------------===//
  74 // SI DAG Nodes
  75 //===----------------------------------------------------------------------===//
  76
  77 def SIload_constant : SDNode<"AMDGPUISD::LOAD_CONSTANT",
  78   SDTypeProfile<1, 2, [SDTCisVT<0, f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i32>]>,
  79                       [SDNPMayLoad, SDNPMemOperand]
  80 >;
  81
  82 def SItbuffer_store : SDNode<"AMDGPUISD::TBUFFER_STORE_FORMAT",
  83   SDTypeProfile<0, 13,
  84     [SDTCisVT<0, v4i32>,   // rsrc(SGPR)
  85      SDTCisVT<1, iAny>,   // vdata(VGPR)
  86      SDTCisVT<2, i32>,    // num_channels(imm)
  87      SDTCisVT<3, i32>,    // vaddr(VGPR)
  88      SDTCisVT<4, i32>,    // soffset(SGPR)
  89      SDTCisVT<5, i32>,    // inst_offset(imm)
  90      SDTCisVT<6, i32>,    // dfmt(imm)
  91      SDTCisVT<7, i32>,    // nfmt(imm)
  92      SDTCisVT<8, i32>,    // offen(imm)
  93      SDTCisVT<9, i32>,    // idxen(imm)
  94      SDTCisVT<10, i32>,   // glc(imm)
  95      SDTCisVT<11, i32>,   // slc(imm)
  96      SDTCisVT<12, i32>    // tfe(imm)
  97     ]>,
  98   [SDNPMayStore, SDNPMemOperand, SDNPHasChain]
  99 >;
 100
 101 def SIload_input : SDNode<"AMDGPUISD::LOAD_INPUT",
 102   SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i16>,
 103                        SDTCisVT<3, i32>]>
 104 >;
 105
 106 class SDSample<string opcode> : SDNode <opcode,
 107   SDTypeProfile<1, 4, [SDTCisVT<0, v4f32>, SDTCisVT<2, v32i8>,
 108                        SDTCisVT<3, v4i32>, SDTCisVT<4, i32>]>
 109 >;
 110
 111 def SIsample : SDSample<"AMDGPUISD::SAMPLE">;
 112 def SIsampleb : SDSample<"AMDGPUISD::SAMPLEB">;
 113 def SIsampled : SDSample<"AMDGPUISD::SAMPLED">;
 114 def SIsamplel : SDSample<"AMDGPUISD::SAMPLEL">;
 115
 116 def SIconstdata_ptr : SDNode<
 117   "AMDGPUISD::CONST_DATA_PTR", SDTypeProfile <1, 0, [SDTCisVT<0, i64>]>
 118 >;
 119
 120 // Transformation function, extract the lower 32bit of a 64bit immediate
 121 def LO32 : SDNodeXForm<imm, [{
 122   return CurDAG->getTargetConstant(N->getZExtValue() & 0xffffffff, MVT::i32);
 123 }]>;
 124
 125 def LO32f : SDNodeXForm<fpimm, [{
 126   APInt V = N->getValueAPF().bitcastToAPInt().trunc(32);
 127   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
 128 }]>;
 129
 130 // Transformation function, extract the upper 32bit of a 64bit immediate
 131 def HI32 : SDNodeXForm<imm, [{
 132   return CurDAG->getTargetConstant(N->getZExtValue() >> 32, MVT::i32);
 133 }]>;
 134
 135 def HI32f : SDNodeXForm<fpimm, [{
 136   APInt V = N->getValueAPF().bitcastToAPInt().lshr(32).trunc(32);
 137   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
 138 }]>;
 139
 140 def IMM8bitDWORD : PatLeaf <(imm),
 141   [{return (N->getZExtValue() & ~0x3FC) == 0;}]
 142 >;
 143
 144 def as_dword_i32imm : SDNodeXForm<imm, [{
 145   return CurDAG->getTargetConstant(N->getZExtValue() >> 2, MVT::i32);
 146 }]>;
 147
 148 def as_i1imm : SDNodeXForm<imm, [{
 149   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i1);
 150 }]>;
 151
 152 def as_i8imm : SDNodeXForm<imm, [{
 153   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i8);
 154 }]>;
 155
 156 def as_i16imm : SDNodeXForm<imm, [{
 157   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i16);
 158 }]>;
 159
 160 def as_i32imm: SDNodeXForm<imm, [{
 161   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i32);
 162 }]>;
 163
 164 def as_i64imm: SDNodeXForm<imm, [{
 165   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i64);
 166 }]>;
 167
 168 // Copied from the AArch64 backend:
 169 def bitcast_fpimm_to_i32 : SDNodeXForm<fpimm, [{
 170 return CurDAG->getTargetConstant(
 171   N->getValueAPF().bitcastToAPInt().getZExtValue(), MVT::i32);
 172 }]>;
 173
 174 // Copied from the AArch64 backend:
 175 def bitcast_fpimm_to_i64 : SDNodeXForm<fpimm, [{
 176 return CurDAG->getTargetConstant(
 177   N->getValueAPF().bitcastToAPInt().getZExtValue(), MVT::i64);
 178 }]>;
 179
 180 def IMM8bit : PatLeaf <(imm),
 181   [{return isUInt<8>(N->getZExtValue());}]
 182 >;
 183
 184 def IMM12bit : PatLeaf <(imm),
 185   [{return isUInt<12>(N->getZExtValue());}]
 186 >;
 187
 188 def IMM16bit : PatLeaf <(imm),
 189   [{return isUInt<16>(N->getZExtValue());}]
 190 >;
 191
 192 def IMM20bit : PatLeaf <(imm),
 193   [{return isUInt<20>(N->getZExtValue());}]
 194 >;
 195
 196 def IMM32bit : PatLeaf <(imm),
 197   [{return isUInt<32>(N->getZExtValue());}]
 198 >;
 199
 200 def mubuf_vaddr_offset : PatFrag<
 201   (ops node:$ptr, node:$offset, node:$imm_offset),
 202   (add (add node:$ptr, node:$offset), node:$imm_offset)
 203 >;
 204
 205 class InlineImm <ValueType vt> : PatLeaf <(vt imm), [{
 206   return isInlineImmediate(N);
 207 }]>;
 208
 209 class InlineFPImm <ValueType vt> : PatLeaf <(vt fpimm), [{
 210   return isInlineImmediate(N);
 211 }]>;
 212
 213 class SGPRImm <dag frag> : PatLeaf<frag, [{
 214   if (Subtarget->getGeneration() < AMDGPUSubtarget::SOUTHERN_ISLANDS) {
 215     return false;
 216   }
 217   const SIRegisterInfo *SIRI =
 218       static_cast<const SIRegisterInfo *>(Subtarget->getRegisterInfo());
 219   for (SDNode::use_iterator U = N->use_begin(), E = SDNode::use_end();
 220                                                 U != E; ++U) {
 221     if (SIRI->isSGPRClass(getOperandRegClass(*U, U.getOperandNo()))) {
 222       return true;
 223     }
 224   }
 225   return false;
 226 }]>;
 227
 228 //===----------------------------------------------------------------------===//
 229 // Custom Operands
 230 //===----------------------------------------------------------------------===//
 231
 232 def FRAMEri32 : Operand<iPTR> {
 233   let MIOperandInfo = (ops i32:$ptr, i32imm:$index);
 234 }
 235
 236 def sopp_brtarget : Operand<OtherVT> {
 237   let EncoderMethod = "getSOPPBrEncoding";
 238   let OperandType = "OPERAND_PCREL";
 239 }
 240
 241 include "SIInstrFormats.td"
 242 include "VIInstrFormats.td"
 243
 244 let OperandType = "OPERAND_IMMEDIATE" in {
 245
 246 def offen : Operand<i1> {
 247   let PrintMethod = "printOffen";
 248 }
 249 def idxen : Operand<i1> {
 250   let PrintMethod = "printIdxen";
 251 }
 252 def addr64 : Operand<i1> {
 253   let PrintMethod = "printAddr64";
 254 }
 255 def mbuf_offset : Operand<i16> {
 256   let PrintMethod = "printMBUFOffset";
 257 }
 258 def ds_offset : Operand<i16> {
 259   let PrintMethod = "printDSOffset";
 260 }
 261 def ds_offset0 : Operand<i8> {
 262   let PrintMethod = "printDSOffset0";
 263 }
 264 def ds_offset1 : Operand<i8> {
 265   let PrintMethod = "printDSOffset1";
 266 }
 267 def glc : Operand <i1> {
 268   let PrintMethod = "printGLC";
 269 }
 270 def slc : Operand <i1> {
 271   let PrintMethod = "printSLC";
 272 }
 273 def tfe : Operand <i1> {
 274   let PrintMethod = "printTFE";
 275 }
 276
 277 def omod : Operand <i32> {
 278   let PrintMethod = "printOModSI";
 279 }
 280
 281 def ClampMod : Operand <i1> {
 282   let PrintMethod = "printClampSI";
 283 }
 284
 285 } // End OperandType = "OPERAND_IMMEDIATE"
 286
 287 //===----------------------------------------------------------------------===//
 288 // Complex patterns
 289 //===----------------------------------------------------------------------===//
 290
 291 def DS1Addr1Offset : ComplexPattern<i32, 2, "SelectDS1Addr1Offset">;
 292 def DS64Bit4ByteAligned : ComplexPattern<i32, 3, "SelectDS64Bit4ByteAligned">;
 293
 294 def MUBUFAddr32 : ComplexPattern<i64, 9, "SelectMUBUFAddr32">;
 295 def MUBUFAddr64 : ComplexPattern<i64, 3, "SelectMUBUFAddr64">;
 296 def MUBUFAddr64Atomic : ComplexPattern<i64, 4, "SelectMUBUFAddr64">;
 297 def MUBUFScratch : ComplexPattern<i64, 4, "SelectMUBUFScratch">;
 298 def MUBUFOffset : ComplexPattern<i64, 6, "SelectMUBUFOffset">;
 299 def MUBUFOffsetAtomic : ComplexPattern<i64, 4, "SelectMUBUFOffset">;
 300
 301 def VOP3Mods0 : ComplexPattern<untyped, 4, "SelectVOP3Mods0">;
 302 def VOP3Mods0Clamp : ComplexPattern<untyped, 3, "SelectVOP3Mods0Clamp">;
 303 def VOP3Mods0Clamp0OMod : ComplexPattern<untyped, 4, "SelectVOP3Mods0Clamp0OMod">;
 304 def VOP3Mods  : ComplexPattern<untyped, 2, "SelectVOP3Mods">;
 305
 306 //===----------------------------------------------------------------------===//
 307 // SI assembler operands
 308 //===----------------------------------------------------------------------===//
 309
 310 def SIOperand {
 311   int ZERO = 0x80;
 312   int VCC = 0x6A;
 313   int FLAT_SCR = 0x68;
 314 }
 315
 316 def SRCMODS {
 317   int NONE = 0;
 318 }
 319
 320 def DSTCLAMP {
 321   int NONE = 0;
 322 }
 323
 324 def DSTOMOD {
 325   int NONE = 0;
 326 }
 327
 328 //===----------------------------------------------------------------------===//
 329 //
 330 // SI Instruction multiclass helpers.
 331 //
 332 // Instructions with _32 take 32-bit operands.
 333 // Instructions with _64 take 64-bit operands.
 334 //
 335 // VOP_* instructions can use either a 32-bit or 64-bit encoding.  The 32-bit
 336 // encoding is the standard encoding, but instruction that make use of
 337 // any of the instruction modifiers must use the 64-bit encoding.
 338 //
 339 // Instructions with _e32 use the 32-bit encoding.
 340 // Instructions with _e64 use the 64-bit encoding.
 341 //
 342 //===----------------------------------------------------------------------===//
 343
 344 class SIMCInstr <string pseudo, int subtarget> {
 345   string PseudoInstr = pseudo;
 346   int Subtarget = subtarget;
 347 }
 348
 349 //===----------------------------------------------------------------------===//
 350 // EXP classes
 351 //===----------------------------------------------------------------------===//
 352
 353 class EXPCommon : InstSI<
 354   (outs),
 355   (ins i32imm:$en, i32imm:$tgt, i32imm:$compr, i32imm:$done, i32imm:$vm,
 356        VGPR_32:$src0, VGPR_32:$src1, VGPR_32:$src2, VGPR_32:$src3),
 357   "exp $en, $tgt, $compr, $done, $vm, $src0, $src1, $src2, $src3",
 358   [] > {
 359
 360   let EXP_CNT = 1;
 361   let Uses = [EXEC];
 362 }
 363
 364 multiclass EXP_m {
 365
 366   let isPseudo = 1 in {
 367     def "" : EXPCommon, SIMCInstr <"exp", SISubtarget.NONE> ;
 368   }
 369
 370   def _si : EXPCommon, SIMCInstr <"exp", SISubtarget.SI>, EXPe;
 371
 372   def _vi : EXPCommon, SIMCInstr <"exp", SISubtarget.VI>, EXPe_vi;
 373 }
 374
 375 //===----------------------------------------------------------------------===//
 376 // Scalar classes
 377 //===----------------------------------------------------------------------===//
 378
 379 class SOP1_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 380   SOP1 <outs, ins, "", pattern>,
 381   SIMCInstr<opName, SISubtarget.NONE> {
 382   let isPseudo = 1;
 383 }
 384
 385 class SOP1_Real_si <sop1 op, string opName, dag outs, dag ins, string asm> :
 386   SOP1 <outs, ins, asm, []>,
 387   SOP1e <op.SI>,
 388   SIMCInstr<opName, SISubtarget.SI>;
 389
 390 class SOP1_Real_vi <sop1 op, string opName, dag outs, dag ins, string asm> :
 391   SOP1 <outs, ins, asm, []>,
 392   SOP1e <op.VI>,
 393   SIMCInstr<opName, SISubtarget.VI>;
 394
 395 multiclass SOP1_32 <sop1 op, string opName, list<dag> pattern> {
 396   def "" : SOP1_Pseudo <opName, (outs SReg_32:$dst), (ins SSrc_32:$src0),
 397     pattern>;
 398
 399   def _si : SOP1_Real_si <op, opName, (outs SReg_32:$dst), (ins SSrc_32:$src0),
 400     opName#" $dst, $src0">;
 401
 402   def _vi : SOP1_Real_vi <op, opName, (outs SReg_32:$dst), (ins SSrc_32:$src0),
 403     opName#" $dst, $src0">;
 404 }
 405
 406 multiclass SOP1_64 <sop1 op, string opName, list<dag> pattern> {
 407   def "" : SOP1_Pseudo <opName, (outs SReg_64:$dst), (ins SSrc_64:$src0),
 408     pattern>;
 409
 410   def _si : SOP1_Real_si <op, opName, (outs SReg_64:$dst), (ins SSrc_64:$src0),
 411     opName#" $dst, $src0">;
 412
 413   def _vi : SOP1_Real_vi <op, opName, (outs SReg_64:$dst), (ins SSrc_64:$src0),
 414     opName#" $dst, $src0">;
 415 }
 416
 417 // no input, 64-bit output.
 418 multiclass SOP1_64_0 <sop1 op, string opName, list<dag> pattern> {
 419   def "" : SOP1_Pseudo <opName, (outs SReg_64:$dst), (ins), pattern>;
 420
 421   def _si : SOP1_Real_si <op, opName, (outs SReg_64:$dst), (ins),
 422     opName#" $dst"> {
 423     let SSRC0 = 0;
 424   }
 425
 426   def _vi : SOP1_Real_vi <op, opName, (outs SReg_64:$dst), (ins),
 427     opName#" $dst"> {
 428     let SSRC0 = 0;
 429   }
 430 }
 431
 432 // 64-bit input, 32-bit output.
 433 multiclass SOP1_32_64 <sop1 op, string opName, list<dag> pattern> {
 434   def "" : SOP1_Pseudo <opName, (outs SReg_32:$dst), (ins SSrc_64:$src0),
 435     pattern>;
 436
 437   def _si : SOP1_Real_si <op, opName, (outs SReg_32:$dst), (ins SSrc_64:$src0),
 438     opName#" $dst, $src0">;
 439
 440   def _vi : SOP1_Real_vi <op, opName, (outs SReg_32:$dst), (ins SSrc_64:$src0),
 441     opName#" $dst, $src0">;
 442 }
 443
 444 class SOP2_Pseudo<string opName, dag outs, dag ins, list<dag> pattern> :
 445   SOP2<outs, ins, "", pattern>,
 446   SIMCInstr<opName, SISubtarget.NONE> {
 447   let isPseudo = 1;
 448   let Size = 4;
 449 }
 450
 451 class SOP2_Real_si<sop2 op, string opName, dag outs, dag ins, string asm> :
 452   SOP2<outs, ins, asm, []>,
 453   SOP2e<op.SI>,
 454   SIMCInstr<opName, SISubtarget.SI>;
 455
 456 class SOP2_Real_vi<sop2 op, string opName, dag outs, dag ins, string asm> :
 457   SOP2<outs, ins, asm, []>,
 458   SOP2e<op.VI>,
 459   SIMCInstr<opName, SISubtarget.VI>;
 460
 461 multiclass SOP2_SELECT_32 <sop2 op, string opName, list<dag> pattern> {
 462   def "" : SOP2_Pseudo <opName, (outs SReg_32:$dst),
 463     (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc), pattern>;
 464
 465   def _si : SOP2_Real_si <op, opName, (outs SReg_32:$dst),
 466     (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc),
 467     opName#" $dst, $src0, $src1 [$scc]">;
 468
 469   def _vi : SOP2_Real_vi <op, opName, (outs SReg_32:$dst),
 470     (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc),
 471     opName#" $dst, $src0, $src1 [$scc]">;
 472 }
 473
 474 multiclass SOP2_32 <sop2 op, string opName, list<dag> pattern> {
 475   def "" : SOP2_Pseudo <opName, (outs SReg_32:$dst),
 476     (ins SSrc_32:$src0, SSrc_32:$src1), pattern>;
 477
 478   def _si : SOP2_Real_si <op, opName, (outs SReg_32:$dst),
 479     (ins SSrc_32:$src0, SSrc_32:$src1), opName#" $dst, $src0, $src1">;
 480
 481   def _vi : SOP2_Real_vi <op, opName, (outs SReg_32:$dst),
 482     (ins SSrc_32:$src0, SSrc_32:$src1), opName#" $dst, $src0, $src1">;
 483 }
 484
 485 multiclass SOP2_64 <sop2 op, string opName, list<dag> pattern> {
 486   def "" : SOP2_Pseudo <opName, (outs SReg_64:$dst),
 487     (ins SSrc_64:$src0, SSrc_64:$src1), pattern>;
 488
 489   def _si : SOP2_Real_si <op, opName, (outs SReg_64:$dst),
 490     (ins SSrc_64:$src0, SSrc_64:$src1), opName#" $dst, $src0, $src1">;
 491
 492   def _vi : SOP2_Real_vi <op, opName, (outs SReg_64:$dst),
 493     (ins SSrc_64:$src0, SSrc_64:$src1), opName#" $dst, $src0, $src1">;
 494 }
 495
 496 multiclass SOP2_64_32 <sop2 op, string opName, list<dag> pattern> {
 497   def "" : SOP2_Pseudo <opName, (outs SReg_64:$dst),
 498     (ins SSrc_64:$src0, SSrc_32:$src1), pattern>;
 499
 500   def _si : SOP2_Real_si <op, opName, (outs SReg_64:$dst),
 501     (ins SSrc_64:$src0, SSrc_32:$src1), opName#" $dst, $src0, $src1">;
 502
 503   def _vi : SOP2_Real_vi <op, opName, (outs SReg_64:$dst),
 504     (ins SSrc_64:$src0, SSrc_32:$src1), opName#" $dst, $src0, $src1">;
 505 }
 506
 507
 508 class SOPC_Helper <bits<7> op, RegisterOperand rc, ValueType vt,
 509                     string opName, PatLeaf cond> : SOPC <
 510   op, (outs SCCReg:$dst), (ins rc:$src0, rc:$src1),
 511   opName#" $dst, $src0, $src1", []>;
 512
 513 class SOPC_32<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 514   : SOPC_Helper<op, SSrc_32, i32, opName, cond>;
 515
 516 class SOPC_64<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 517   : SOPC_Helper<op, SSrc_64, i64, opName, cond>;
 518
 519 class SOPK_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 520   SOPK <outs, ins, "", pattern>,
 521   SIMCInstr<opName, SISubtarget.NONE> {
 522   let isPseudo = 1;
 523 }
 524
 525 class SOPK_Real_si <sopk op, string opName, dag outs, dag ins, string asm> :
 526   SOPK <outs, ins, asm, []>,
 527   SOPKe <op.SI>,
 528   SIMCInstr<opName, SISubtarget.SI>;
 529
 530 class SOPK_Real_vi <sopk op, string opName, dag outs, dag ins, string asm> :
 531   SOPK <outs, ins, asm, []>,
 532   SOPKe <op.VI>,
 533   SIMCInstr<opName, SISubtarget.VI>;
 534
 535 multiclass SOPK_32 <sopk op, string opName, list<dag> pattern> {
 536   def "" : SOPK_Pseudo <opName, (outs SReg_32:$dst), (ins u16imm:$src0),
 537     pattern>;
 538
 539   def _si : SOPK_Real_si <op, opName, (outs SReg_32:$dst), (ins u16imm:$src0),
 540     opName#" $dst, $src0">;
 541
 542   def _vi : SOPK_Real_vi <op, opName, (outs SReg_32:$dst), (ins u16imm:$src0),
 543     opName#" $dst, $src0">;
 544 }
 545
 546 multiclass SOPK_SCC <sopk op, string opName, list<dag> pattern> {
 547   def "" : SOPK_Pseudo <opName, (outs SCCReg:$dst),
 548     (ins SReg_32:$src0, u16imm:$src1), pattern>;
 549
 550   def _si : SOPK_Real_si <op, opName, (outs SCCReg:$dst),
 551     (ins SReg_32:$src0, u16imm:$src1), opName#" $dst, $src0">;
 552
 553   def _vi : SOPK_Real_vi <op, opName, (outs SCCReg:$dst),
 554     (ins SReg_32:$src0, u16imm:$src1), opName#" $dst, $src0">;
 555 }
 556
 557 //===----------------------------------------------------------------------===//
 558 // SMRD classes
 559 //===----------------------------------------------------------------------===//
 560
 561 class SMRD_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 562   SMRD <outs, ins, "", pattern>,
 563   SIMCInstr<opName, SISubtarget.NONE> {
 564   let isPseudo = 1;
 565 }
 566
 567 class SMRD_Real_si <bits<5> op, string opName, bit imm, dag outs, dag ins,
 568                     string asm> :
 569   SMRD <outs, ins, asm, []>,
 570   SMRDe <op, imm>,
 571   SIMCInstr<opName, SISubtarget.SI>;
 572
 573 class SMRD_Real_vi <bits<8> op, string opName, bit imm, dag outs, dag ins,
 574                     string asm> :
 575   SMRD <outs, ins, asm, []>,
 576   SMEMe_vi <op, imm>,
 577   SIMCInstr<opName, SISubtarget.VI>;
 578
 579 multiclass SMRD_m <bits<5> op, string opName, bit imm, dag outs, dag ins,
 580                    string asm, list<dag> pattern> {
 581
 582   def "" : SMRD_Pseudo <opName, outs, ins, pattern>;
 583
 584   def _si : SMRD_Real_si <op, opName, imm, outs, ins, asm>;
 585
 586   def _vi : SMRD_Real_vi <{0, 0, 0, op}, opName, imm, outs, ins, asm>;
 587 }
 588
 589 multiclass SMRD_Helper <bits<5> op, string opName, RegisterClass baseClass,
 590                         RegisterClass dstClass> {
 591   defm _IMM : SMRD_m <
 592     op, opName#"_IMM", 1, (outs dstClass:$dst),
 593     (ins baseClass:$sbase, u32imm:$offset),
 594     opName#" $dst, $sbase, $offset", []
 595   >;
 596
 597   defm _SGPR : SMRD_m <
 598     op, opName#"_SGPR", 0, (outs dstClass:$dst),
 599     (ins baseClass:$sbase, SReg_32:$soff),
 600     opName#" $dst, $sbase, $soff", []
 601   >;
 602 }
 603
 604 //===----------------------------------------------------------------------===//
 605 // Vector ALU classes
 606 //===----------------------------------------------------------------------===//
 607
 608 // This must always be right before the operand being input modified.
 609 def InputMods : OperandWithDefaultOps <i32, (ops (i32 0))> {
 610   let PrintMethod = "printOperandAndMods";
 611 }
 612 def InputModsNoDefault : Operand <i32> {
 613   let PrintMethod = "printOperandAndMods";
 614 }
 615
 616 class getNumSrcArgs<ValueType Src1, ValueType Src2> {
 617   int ret =
 618     !if (!eq(Src1.Value, untyped.Value),      1,   // VOP1
 619          !if (!eq(Src2.Value, untyped.Value), 2,   // VOP2
 620                                               3)); // VOP3
 621 }
 622
 623 // Returns the register class to use for the destination of VOP[123C]
 624 // instructions for the given VT.
 625 class getVALUDstForVT<ValueType VT> {
 626   RegisterClass ret = !if(!eq(VT.Size, 32), VGPR_32,
 627                           !if(!eq(VT.Size, 64), VReg_64,
 628                             SReg_64)); // else VT == i1
 629 }
 630
 631 // Returns the register class to use for source 0 of VOP[12C]
 632 // instructions for the given VT.
 633 class getVOPSrc0ForVT<ValueType VT> {
 634   RegisterOperand ret = !if(!eq(VT.Size, 32), VSrc_32, VSrc_64);
 635 }
 636
 637 // Returns the register class to use for source 1 of VOP[12C] for the
 638 // given VT.
 639 class getVOPSrc1ForVT<ValueType VT> {
 640   RegisterClass ret = !if(!eq(VT.Size, 32), VGPR_32, VReg_64);
 641 }
 642
 643 // Returns the register classes for the source arguments of a VOP[12C]
 644 // instruction for the given SrcVTs.
 645 class getInRC32 <list<ValueType> SrcVT> {
 646   list<DAGOperand> ret = [
 647     getVOPSrc0ForVT<SrcVT[0]>.ret,
 648     getVOPSrc1ForVT<SrcVT[1]>.ret
 649   ];
 650 }
 651
 652 // Returns the register class to use for sources of VOP3 instructions for the
 653 // given VT.
 654 class getVOP3SrcForVT<ValueType VT> {
 655   RegisterOperand ret = !if(!eq(VT.Size, 32), VCSrc_32, VCSrc_64);
 656 }
 657
 658 // Returns the register classes for the source arguments of a VOP3
 659 // instruction for the given SrcVTs.
 660 class getInRC64 <list<ValueType> SrcVT> {
 661   list<DAGOperand> ret = [
 662     getVOP3SrcForVT<SrcVT[0]>.ret,
 663     getVOP3SrcForVT<SrcVT[1]>.ret,
 664     getVOP3SrcForVT<SrcVT[2]>.ret
 665   ];
 666 }
 667
 668 // Returns 1 if the source arguments have modifiers, 0 if they do not.
 669 class hasModifiers<ValueType SrcVT> {
 670   bit ret = !if(!eq(SrcVT.Value, f32.Value), 1,
 671             !if(!eq(SrcVT.Value, f64.Value), 1, 0));
 672 }
 673
 674 // Returns the input arguments for VOP[12C] instructions for the given SrcVT.
 675 class getIns32 <RegisterOperand Src0RC, RegisterClass Src1RC, int NumSrcArgs> {
 676   dag ret = !if(!eq(NumSrcArgs, 1), (ins Src0RC:$src0),               // VOP1
 677             !if(!eq(NumSrcArgs, 2), (ins Src0RC:$src0, Src1RC:$src1), // VOP2
 678                                     (ins)));
 679 }
 680
 681 // Returns the input arguments for VOP3 instructions for the given SrcVT.
 682 class getIns64 <RegisterOperand Src0RC, RegisterOperand Src1RC,
 683                 RegisterOperand Src2RC, int NumSrcArgs,
 684                 bit HasModifiers> {
 685
 686   dag ret =
 687     !if (!eq(NumSrcArgs, 1),
 688       !if (!eq(HasModifiers, 1),
 689         // VOP1 with modifiers
 690         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 691              ClampMod:$clamp, omod:$omod)
 692       /* else */,
 693         // VOP1 without modifiers
 694         (ins Src0RC:$src0)
 695       /* endif */ ),
 696     !if (!eq(NumSrcArgs, 2),
 697       !if (!eq(HasModifiers, 1),
 698         // VOP 2 with modifiers
 699         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 700              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 701              ClampMod:$clamp, omod:$omod)
 702       /* else */,
 703         // VOP2 without modifiers
 704         (ins Src0RC:$src0, Src1RC:$src1)
 705       /* endif */ )
 706     /* NumSrcArgs == 3 */,
 707       !if (!eq(HasModifiers, 1),
 708         // VOP3 with modifiers
 709         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 710              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 711              InputModsNoDefault:$src2_modifiers, Src2RC:$src2,
 712              ClampMod:$clamp, omod:$omod)
 713       /* else */,
 714         // VOP3 without modifiers
 715         (ins Src0RC:$src0, Src1RC:$src1, Src2RC:$src2)
 716       /* endif */ )));
 717 }
 718
 719 // Returns the assembly string for the inputs and outputs of a VOP[12C]
 720 // instruction.  This does not add the _e32 suffix, so it can be reused
 721 // by getAsm64.
 722 class getAsm32 <int NumSrcArgs> {
 723   string src1 = ", $src1";
 724   string src2 = ", $src2";
 725   string ret = " $dst, $src0"#
 726                !if(!eq(NumSrcArgs, 1), "", src1)#
 727                !if(!eq(NumSrcArgs, 3), src2, "");
 728 }
 729
 730 // Returns the assembly string for the inputs and outputs of a VOP3
 731 // instruction.
 732 class getAsm64 <int NumSrcArgs, bit HasModifiers> {
 733   string src0 = !if(!eq(NumSrcArgs, 1), "$src0_modifiers", "$src0_modifiers,");
 734   string src1 = !if(!eq(NumSrcArgs, 1), "",
 735                    !if(!eq(NumSrcArgs, 2), " $src1_modifiers",
 736                                            " $src1_modifiers,"));
 737   string src2 = !if(!eq(NumSrcArgs, 3), " $src2_modifiers", "");
 738   string ret =
 739   !if(!eq(HasModifiers, 0),
 740       getAsm32<NumSrcArgs>.ret,
 741       " $dst, "#src0#src1#src2#"$clamp"#"$omod");
 742 }
 743
 744
 745 class VOPProfile <list<ValueType> _ArgVT> {
 746
 747   field list<ValueType> ArgVT = _ArgVT;
 748
 749   field ValueType DstVT = ArgVT[0];
 750   field ValueType Src0VT = ArgVT[1];
 751   field ValueType Src1VT = ArgVT[2];
 752   field ValueType Src2VT = ArgVT[3];
 753   field RegisterClass DstRC = getVALUDstForVT<DstVT>.ret;
 754   field RegisterOperand Src0RC32 = getVOPSrc0ForVT<Src0VT>.ret;
 755   field RegisterClass Src1RC32 = getVOPSrc1ForVT<Src1VT>.ret;
 756   field RegisterOperand Src0RC64 = getVOP3SrcForVT<Src0VT>.ret;
 757   field RegisterOperand Src1RC64 = getVOP3SrcForVT<Src1VT>.ret;
 758   field RegisterOperand Src2RC64 = getVOP3SrcForVT<Src2VT>.ret;
 759
 760   field int NumSrcArgs = getNumSrcArgs<Src1VT, Src2VT>.ret;
 761   field bit HasModifiers = hasModifiers<Src0VT>.ret;
 762
 763   field dag Outs = (outs DstRC:$dst);
 764
 765   field dag Ins32 = getIns32<Src0RC32, Src1RC32, NumSrcArgs>.ret;
 766   field dag Ins64 = getIns64<Src0RC64, Src1RC64, Src2RC64, NumSrcArgs,
 767                              HasModifiers>.ret;
 768
 769   field string Asm32 = "_e32"#getAsm32<NumSrcArgs>.ret;
 770   field string Asm64 = getAsm64<NumSrcArgs, HasModifiers>.ret;
 771 }
 772
 773 def VOP_F32_F32 : VOPProfile <[f32, f32, untyped, untyped]>;
 774 def VOP_F32_F64 : VOPProfile <[f32, f64, untyped, untyped]>;
 775 def VOP_F32_I32 : VOPProfile <[f32, i32, untyped, untyped]>;
 776 def VOP_F64_F32 : VOPProfile <[f64, f32, untyped, untyped]>;
 777 def VOP_F64_F64 : VOPProfile <[f64, f64, untyped, untyped]>;
 778 def VOP_F64_I32 : VOPProfile <[f64, i32, untyped, untyped]>;
 779 def VOP_I32_F32 : VOPProfile <[i32, f32, untyped, untyped]>;
 780 def VOP_I32_F64 : VOPProfile <[i32, f64, untyped, untyped]>;
 781 def VOP_I32_I32 : VOPProfile <[i32, i32, untyped, untyped]>;
 782
 783 def VOP_F32_F32_F32 : VOPProfile <[f32, f32, f32, untyped]>;
 784 def VOP_F32_F32_I32 : VOPProfile <[f32, f32, i32, untyped]>;
 785 def VOP_F64_F64_F64 : VOPProfile <[f64, f64, f64, untyped]>;
 786 def VOP_F64_F64_I32 : VOPProfile <[f64, f64, i32, untyped]>;
 787 def VOP_I32_F32_F32 : VOPProfile <[i32, f32, f32, untyped]>;
 788 def VOP_I32_F32_I32 : VOPProfile <[i32, f32, i32, untyped]>;
 789 def VOP_I32_I32_I32 : VOPProfile <[i32, i32, i32, untyped]>;
 790 def VOP_I32_I32_I32_VCC : VOPProfile <[i32, i32, i32, untyped]> {
 791   let Src0RC32 = VCSrc_32;
 792 }
 793
 794 def VOP_I1_F32_I32 : VOPProfile <[i1, f32, i32, untyped]> {
 795   let Ins64 = (ins InputModsNoDefault:$src0_modifiers, Src0RC64:$src0, Src1RC64:$src1);
 796   let Asm64 = " $dst, $src0_modifiers, $src1";
 797 }
 798
 799 def VOP_I1_F64_I32 : VOPProfile <[i1, f64, i32, untyped]> {
 800   let Ins64 = (ins InputModsNoDefault:$src0_modifiers, Src0RC64:$src0, Src1RC64:$src1);
 801   let Asm64 = " $dst, $src0_modifiers, $src1";
 802 }
 803
 804 def VOP_I64_I64_I32 : VOPProfile <[i64, i64, i32, untyped]>;
 805 def VOP_I64_I64_I64 : VOPProfile <[i64, i64, i64, untyped]>;
 806
 807 def VOP_F32_F32_F32_F32 : VOPProfile <[f32, f32, f32, f32]>;
 808 def VOP_F64_F64_F64_F64 : VOPProfile <[f64, f64, f64, f64]>;
 809 def VOP_I32_I32_I32_I32 : VOPProfile <[i32, i32, i32, i32]>;
 810 def VOP_I64_I32_I32_I64 : VOPProfile <[i64, i32, i32, i64]>;
 811
 812
 813 class VOP <string opName> {
 814   string OpName = opName;
 815 }
 816
 817 class VOP2_REV <string revOp, bit isOrig> {
 818   string RevOp = revOp;
 819   bit IsOrig = isOrig;
 820 }
 821
 822 class AtomicNoRet <string noRetOp, bit isRet> {
 823   string NoRetOp = noRetOp;
 824   bit IsRet = isRet;
 825 }
 826
 827 class VOP1_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 828   VOP1Common <outs, ins, "", pattern>,
 829   VOP <opName>,
 830   SIMCInstr <opName#"_e32", SISubtarget.NONE> {
 831   let isPseudo = 1;
 832 }
 833
 834 multiclass VOP1_m <vop1 op, dag outs, dag ins, string asm, list<dag> pattern,
 835                    string opName> {
 836   def "" : VOP1_Pseudo <outs, ins, pattern, opName>;
 837
 838   def _si : VOP1<op.SI, outs, ins, asm, []>,
 839             SIMCInstr <opName#"_e32", SISubtarget.SI>;
 840   def _vi : VOP1<op.VI, outs, ins, asm, []>,
 841             SIMCInstr <opName#"_e32", SISubtarget.VI>;
 842 }
 843
 844 class VOP2_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 845   VOP2Common <outs, ins, "", pattern>,
 846   VOP <opName>,
 847   SIMCInstr<opName#"_e32", SISubtarget.NONE> {
 848   let isPseudo = 1;
 849 }
 850
 851 multiclass VOP2SI_m <vop2 op, dag outs, dag ins, string asm, list<dag> pattern,
 852                      string opName, string revOpSI> {
 853   def "" : VOP2_Pseudo <outs, ins, pattern, opName>,
 854            VOP2_REV<revOpSI#"_e32", !eq(revOpSI, opName)>;
 855
 856   def _si : VOP2 <op.SI, outs, ins, opName#asm, []>,
 857             VOP2_REV<revOpSI#"_e32_si", !eq(revOpSI, opName)>,
 858             SIMCInstr <opName#"_e32", SISubtarget.SI>;
 859 }
 860
 861 multiclass VOP2_m <vop2 op, dag outs, dag ins, string asm, list<dag> pattern,
 862                    string opName, string revOpSI, string revOpVI> {
 863   def "" : VOP2_Pseudo <outs, ins, pattern, opName>,
 864            VOP2_REV<revOpSI#"_e32", !eq(revOpSI, opName)>;
 865
 866   def _si : VOP2 <op.SI, outs, ins, opName#asm, []>,
 867             VOP2_REV<revOpSI#"_e32_si", !eq(revOpSI, opName)>,
 868             SIMCInstr <opName#"_e32", SISubtarget.SI>;
 869   def _vi : VOP2 <op.VI, outs, ins, opName#asm, []>,
 870             VOP2_REV<revOpVI#"_e32_vi", !eq(revOpVI, opName)>,
 871             SIMCInstr <opName#"_e32", SISubtarget.VI>;
 872 }
 873
 874 class VOP3DisableFields <bit HasSrc1, bit HasSrc2, bit HasModifiers> {
 875
 876   bits<2> src0_modifiers = !if(HasModifiers, ?, 0);
 877   bits<2> src1_modifiers = !if(HasModifiers, !if(HasSrc1, ?, 0), 0);
 878   bits<2> src2_modifiers = !if(HasModifiers, !if(HasSrc2, ? ,0) ,0);
 879   bits<2> omod = !if(HasModifiers, ?, 0);
 880   bits<1> clamp = !if(HasModifiers, ?, 0);
 881   bits<9> src1 = !if(HasSrc1, ?, 0);
 882   bits<9> src2 = !if(HasSrc2, ?, 0);
 883 }
 884
 885 class VOP3_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 886   VOP3Common <outs, ins, "", pattern>,
 887   VOP <opName>,
 888   SIMCInstr<opName#"_e64", SISubtarget.NONE> {
 889   let isPseudo = 1;
 890 }
 891
 892 class VOP3_Real_si <bits<9> op, dag outs, dag ins, string asm, string opName> :
 893   VOP3Common <outs, ins, asm, []>,
 894   VOP3e <op>,
 895   SIMCInstr<opName#"_e64", SISubtarget.SI>;
 896
 897 class VOP3_Real_vi <bits<10> op, dag outs, dag ins, string asm, string opName> :
 898   VOP3Common <outs, ins, asm, []>,
 899   VOP3e_vi <op>,
 900   SIMCInstr <opName#"_e64", SISubtarget.VI>;
 901
 902 multiclass VOP3_m <vop op, dag outs, dag ins, string asm, list<dag> pattern,
 903                    string opName, int NumSrcArgs, bit HasMods = 1> {
 904
 905   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 906
 907   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 908             VOP3DisableFields<!if(!eq(NumSrcArgs, 1), 0, 1),
 909                               !if(!eq(NumSrcArgs, 2), 0, 1),
 910                               HasMods>;
 911   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
 912             VOP3DisableFields<!if(!eq(NumSrcArgs, 1), 0, 1),
 913                               !if(!eq(NumSrcArgs, 2), 0, 1),
 914                               HasMods>;
 915 }
 916
 917 // VOP3_m without source modifiers
 918 multiclass VOP3_m_nosrcmod <vop op, dag outs, dag ins, string asm, list<dag> pattern,
 919                    string opName, int NumSrcArgs, bit HasMods = 1> {
 920
 921   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 922
 923   let src0_modifiers = 0,
 924       src1_modifiers = 0,
 925       src2_modifiers = 0 in {
 926     def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>;
 927     def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>;
 928   }
 929 }
 930
 931 multiclass VOP3_1_m <vop op, dag outs, dag ins, string asm,
 932                      list<dag> pattern, string opName, bit HasMods = 1> {
 933
 934   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 935
 936   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 937             VOP3DisableFields<0, 0, HasMods>;
 938
 939   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
 940             VOP3DisableFields<0, 0, HasMods>;
 941 }
 942
 943 multiclass VOP3_2_m <vop op, dag outs, dag ins, string asm,
 944                      list<dag> pattern, string opName, string revOpSI, string revOpVI,
 945                      bit HasMods = 1, bit UseFullOp = 0> {
 946
 947   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
 948            VOP2_REV<revOpSI#"_e64", !eq(revOpSI, opName)>;
 949
 950   def _si : VOP3_Real_si <op.SI3,
 951               outs, ins, asm, opName>,
 952             VOP2_REV<revOpSI#"_e64_si", !eq(revOpSI, opName)>,
 953             VOP3DisableFields<1, 0, HasMods>;
 954
 955   def _vi : VOP3_Real_vi <op.VI3,
 956               outs, ins, asm, opName>,
 957             VOP2_REV<revOpVI#"_e64_vi", !eq(revOpVI, opName)>,
 958             VOP3DisableFields<1, 0, HasMods>;
 959 }
 960
 961 multiclass VOP3b_2_m <vop op, dag outs, dag ins, string asm,
 962                       list<dag> pattern, string opName, string revOp,
 963                       bit HasMods = 1, bit UseFullOp = 0> {
 964   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
 965            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
 966
 967   // The VOP2 variant puts the carry out into VCC, the VOP3 variant
 968   // can write it into any SGPR. We currently don't use the carry out,
 969   // so for now hardcode it to VCC as well.
 970   let sdst = SIOperand.VCC, Defs = [VCC] in {
 971     def _si : VOP3b <op.SI3, outs, ins, asm, []>,
 972               VOP3DisableFields<1, 0, HasMods>,
 973               SIMCInstr<opName#"_e64", SISubtarget.SI>,
 974               VOP2_REV<revOp#"_e64_si", !eq(revOp, opName)>;
 975
 976     // TODO: Do we need this VI variant here?
 977     /*def _vi : VOP3b_vi <op.VI3, outs, ins, asm, []>,
 978               VOP3DisableFields<1, 0, HasMods>,
 979               SIMCInstr<opName#"_e64", SISubtarget.VI>,
 980               VOP2_REV<revOp#"_e64_vi", !eq(revOp, opName)>;*/
 981   } // End sdst = SIOperand.VCC, Defs = [VCC]
 982 }
 983
 984 multiclass VOP3_C_m <vop op, dag outs, dag ins, string asm,
 985                      list<dag> pattern, string opName,
 986                      bit HasMods, bit defExec> {
 987
 988   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 989
 990   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 991             VOP3DisableFields<1, 0, HasMods> {
 992     let Defs = !if(defExec, [EXEC], []);
 993   }
 994
 995   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
 996             VOP3DisableFields<1, 0, HasMods> {
 997     let Defs = !if(defExec, [EXEC], []);
 998   }
 999 }
1000
1001 // An instruction that is VOP2 on SI and VOP3 on VI, no modifiers.
1002 multiclass VOP2SI_3VI_m <vop3 op, string opName, dag outs, dag ins,
1003                          string asm, list<dag> pattern = []> {
1004   let isPseudo = 1 in {
1005     def "" : VOPAnyCommon <outs, ins, "", pattern>,
1006              SIMCInstr<opName, SISubtarget.NONE>;
1007   }
1008
1009   def _si : VOP2 <op.SI3{5-0}, outs, ins, asm, []>,
1010             SIMCInstr <opName, SISubtarget.SI>;
1011
1012   def _vi : VOP3Common <outs, ins, asm, []>,
1013             VOP3e_vi <op.VI3>,
1014             VOP3DisableFields <1, 0, 0>,
1015             SIMCInstr <opName, SISubtarget.VI>;
1016 }
1017
1018 multiclass VOP1_Helper <vop1 op, string opName, dag outs,
1019                         dag ins32, string asm32, list<dag> pat32,
1020                         dag ins64, string asm64, list<dag> pat64,
1021                         bit HasMods> {
1022
1023   defm _e32 : VOP1_m <op, outs, ins32, opName#asm32, pat32, opName>;
1024
1025   defm _e64 : VOP3_1_m <op, outs, ins64, opName#"_e64"#asm64, pat64, opName, HasMods>;
1026 }
1027
1028 multiclass VOP1Inst <vop1 op, string opName, VOPProfile P,
1029                      SDPatternOperator node = null_frag> : VOP1_Helper <
1030   op, opName, P.Outs,
1031   P.Ins32, P.Asm32, [],
1032   P.Ins64, P.Asm64,
1033   !if(P.HasModifiers,
1034       [(set P.DstVT:$dst, (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0,
1035                                 i32:$src0_modifiers, i1:$clamp, i32:$omod))))],
1036       [(set P.DstVT:$dst, (node P.Src0VT:$src0))]),
1037   P.HasModifiers
1038 >;
1039
1040 multiclass VOP1InstSI <vop1 op, string opName, VOPProfile P,
1041                        SDPatternOperator node = null_frag> {
1042
1043   def _e32 : VOP1 <op.SI, P.Outs, P.Ins32, opName#P.Asm32, []>,
1044              VOP <opName>;
1045
1046   def _e64 : VOP3Common <P.Outs, P.Ins64, opName#P.Asm64,
1047     !if(P.HasModifiers,
1048       [(set P.DstVT:$dst, (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0,
1049                                 i32:$src0_modifiers, i1:$clamp, i32:$omod))))],
1050       [(set P.DstVT:$dst, (node P.Src0VT:$src0))])>,
1051             VOP <opName>,
1052             VOP3e <op.SI3>,
1053             VOP3DisableFields<0, 0, P.HasModifiers>;
1054 }
1055
1056 multiclass VOP2_Helper <vop2 op, string opName, dag outs,
1057                         dag ins32, string asm32, list<dag> pat32,
1058                         dag ins64, string asm64, list<dag> pat64,
1059                         string revOpSI, string revOpVI, bit HasMods> {
1060   defm _e32 : VOP2_m <op, outs, ins32, asm32, pat32, opName, revOpSI, revOpVI>;
1061
1062   defm _e64 : VOP3_2_m <op,
1063     outs, ins64, opName#"_e64"#asm64, pat64, opName, revOpSI, revOpVI, HasMods
1064   >;
1065 }
1066
1067 multiclass VOP2Inst <vop2 op, string opName, VOPProfile P,
1068                      SDPatternOperator node = null_frag,
1069                      string revOpSI = opName, string revOpVI = revOpSI> : VOP2_Helper <
1070   op, opName, P.Outs,
1071   P.Ins32, P.Asm32, [],
1072   P.Ins64, P.Asm64,
1073   !if(P.HasModifiers,
1074       [(set P.DstVT:$dst,
1075            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1076                                       i1:$clamp, i32:$omod)),
1077                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1078       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1079   revOpSI, revOpVI, P.HasModifiers
1080 >;
1081
1082 multiclass VOP2b_Helper <vop2 op, string opName, dag outs,
1083                          dag ins32, string asm32, list<dag> pat32,
1084                          dag ins64, string asm64, list<dag> pat64,
1085                          string revOp, bit HasMods> {
1086
1087   defm _e32 : VOP2_m <op, outs, ins32, asm32, pat32, opName, revOp, revOp>;
1088
1089   defm _e64 : VOP3b_2_m <op,
1090     outs, ins64, opName#"_e64"#asm64, pat64, opName, revOp, HasMods
1091   >;
1092 }
1093
1094 multiclass VOP2bInst <vop2 op, string opName, VOPProfile P,
1095                       SDPatternOperator node = null_frag,
1096                       string revOp = opName> : VOP2b_Helper <
1097   op, opName, P.Outs,
1098   P.Ins32, P.Asm32, [],
1099   P.Ins64, P.Asm64,
1100   !if(P.HasModifiers,
1101       [(set P.DstVT:$dst,
1102            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1103                                       i1:$clamp, i32:$omod)),
1104                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1105       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1106   revOp, P.HasModifiers
1107 >;
1108
1109 // A VOP2 instruction that is VOP3-only on VI.
1110 multiclass VOP2_VI3_Helper <vop23 op, string opName, dag outs,
1111                             dag ins32, string asm32, list<dag> pat32,
1112                             dag ins64, string asm64, list<dag> pat64,
1113                             string revOpSI, string revOpVI, bit HasMods> {
1114   defm _e32 : VOP2SI_m <op, outs, ins32, asm32, pat32, opName, revOpSI>;
1115
1116   defm _e64 : VOP3_2_m <op, outs, ins64, opName#"_e64"#asm64, pat64, opName,
1117                         revOpSI, revOpVI, HasMods>;
1118 }
1119
1120 multiclass VOP2_VI3_Inst <vop23 op, string opName, VOPProfile P,
1121                           SDPatternOperator node = null_frag,
1122                           string revOpSI = opName, string revOpVI = revOpSI>
1123                           : VOP2_VI3_Helper <
1124   op, opName, P.Outs,
1125   P.Ins32, P.Asm32, [],
1126   P.Ins64, P.Asm64,
1127   !if(P.HasModifiers,
1128       [(set P.DstVT:$dst,
1129            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1130                                       i1:$clamp, i32:$omod)),
1131                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1132       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1133   revOpSI, revOpVI, P.HasModifiers
1134 >;
1135
1136 class VOPC_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
1137   VOPCCommon <ins, "", pattern>,
1138   VOP <opName>,
1139   SIMCInstr<opName#"_e32", SISubtarget.NONE> {
1140   let isPseudo = 1;
1141 }
1142
1143 multiclass VOPC_m <vopc op, dag outs, dag ins, string asm, list<dag> pattern,
1144                    string opName, bit DefExec> {
1145   def "" : VOPC_Pseudo <outs, ins, pattern, opName>;
1146
1147   def _si : VOPC<op.SI, ins, asm, []>,
1148             SIMCInstr <opName#"_e32", SISubtarget.SI> {
1149     let Defs = !if(DefExec, [EXEC], []);
1150   }
1151
1152   def _vi : VOPC<op.VI, ins, asm, []>,
1153             SIMCInstr <opName#"_e32", SISubtarget.VI> {
1154     let Defs = !if(DefExec, [EXEC], []);
1155   }
1156 }
1157
1158 multiclass VOPC_Helper <vopc op, string opName,
1159                         dag ins32, string asm32, list<dag> pat32,
1160                         dag out64, dag ins64, string asm64, list<dag> pat64,
1161                         bit HasMods, bit DefExec> {
1162   defm _e32 : VOPC_m <op, (outs), ins32, opName#asm32, pat32, opName, DefExec>;
1163
1164   defm _e64 : VOP3_C_m <op, out64, ins64, opName#"_e64"#asm64, pat64,
1165                         opName, HasMods, DefExec>;
1166 }
1167
1168 multiclass VOPCInst <vopc op, string opName,
1169                      VOPProfile P, PatLeaf cond = COND_NULL,
1170                      bit DefExec = 0> : VOPC_Helper <
1171   op, opName,
1172   P.Ins32, P.Asm32, [],
1173   (outs SReg_64:$dst), P.Ins64, P.Asm64,
1174   !if(P.HasModifiers,
1175       [(set i1:$dst,
1176           (setcc (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1177                                       i1:$clamp, i32:$omod)),
1178                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1179                  cond))],
1180       [(set i1:$dst, (setcc P.Src0VT:$src0, P.Src1VT:$src1, cond))]),
1181   P.HasModifiers, DefExec
1182 >;
1183
1184 multiclass VOPCClassInst <vopc op, string opName, VOPProfile P,
1185                      bit DefExec = 0> : VOPC_Helper <
1186   op, opName,
1187   P.Ins32, P.Asm32, [],
1188   (outs SReg_64:$dst), P.Ins64, P.Asm64,
1189   !if(P.HasModifiers,
1190       [(set i1:$dst,
1191           (AMDGPUfp_class (P.Src0VT (VOP3Mods0Clamp0OMod P.Src0VT:$src0, i32:$src0_modifiers)), P.Src1VT:$src1))],
1192       [(set i1:$dst, (AMDGPUfp_class P.Src0VT:$src0, P.Src1VT:$src1))]),
1193   P.HasModifiers, DefExec
1194 >;
1195
1196
1197 multiclass VOPC_F32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1198   VOPCInst <op, opName, VOP_F32_F32_F32, cond>;
1199
1200 multiclass VOPC_F64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1201   VOPCInst <op, opName, VOP_F64_F64_F64, cond>;
1202
1203 multiclass VOPC_I32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1204   VOPCInst <op, opName, VOP_I32_I32_I32, cond>;
1205
1206 multiclass VOPC_I64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1207   VOPCInst <op, opName, VOP_I64_I64_I64, cond>;
1208
1209
1210 multiclass VOPCX <vopc op, string opName, VOPProfile P,
1211                   PatLeaf cond = COND_NULL>
1212   : VOPCInst <op, opName, P, cond, 1>;
1213
1214 multiclass VOPCX_F32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1215   VOPCX <op, opName, VOP_F32_F32_F32, cond>;
1216
1217 multiclass VOPCX_F64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1218   VOPCX <op, opName, VOP_F64_F64_F64, cond>;
1219
1220 multiclass VOPCX_I32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1221   VOPCX <op, opName, VOP_I32_I32_I32, cond>;
1222
1223 multiclass VOPCX_I64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1224   VOPCX <op, opName, VOP_I64_I64_I64, cond>;
1225
1226 multiclass VOP3_Helper <vop3 op, string opName, dag outs, dag ins, string asm,
1227                         list<dag> pat, int NumSrcArgs, bit HasMods> : VOP3_m <
1228     op, outs, ins, opName#asm, pat, opName, NumSrcArgs, HasMods
1229 >;
1230
1231 multiclass VOPC_CLASS_F32 <vopc op, string opName> :
1232   VOPCClassInst <op, opName, VOP_I1_F32_I32, 0>;
1233
1234 multiclass VOPCX_CLASS_F32 <vopc op, string opName> :
1235   VOPCClassInst <op, opName, VOP_I1_F32_I32, 1>;
1236
1237 multiclass VOPC_CLASS_F64 <vopc op, string opName> :
1238   VOPCClassInst <op, opName, VOP_I1_F64_I32, 0>;
1239
1240 multiclass VOPCX_CLASS_F64 <vopc op, string opName> :
1241   VOPCClassInst <op, opName, VOP_I1_F64_I32, 1>;
1242
1243 multiclass VOP3Inst <vop3 op, string opName, VOPProfile P,
1244                      SDPatternOperator node = null_frag> : VOP3_Helper <
1245   op, opName, P.Outs, P.Ins64, P.Asm64,
1246   !if(!eq(P.NumSrcArgs, 3),
1247     !if(P.HasModifiers,
1248         [(set P.DstVT:$dst,
1249             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1250                                        i1:$clamp, i32:$omod)),
1251                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1252                   (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))))],
1253         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1,
1254                                   P.Src2VT:$src2))]),
1255   !if(!eq(P.NumSrcArgs, 2),
1256     !if(P.HasModifiers,
1257         [(set P.DstVT:$dst,
1258             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1259                                        i1:$clamp, i32:$omod)),
1260                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1261         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))])
1262   /* P.NumSrcArgs == 1 */,
1263     !if(P.HasModifiers,
1264         [(set P.DstVT:$dst,
1265             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1266                                        i1:$clamp, i32:$omod))))],
1267         [(set P.DstVT:$dst, (node P.Src0VT:$src0))]))),
1268   P.NumSrcArgs, P.HasModifiers
1269 >;
1270
1271 multiclass VOP3b_Helper <vop op, RegisterClass vrc, RegisterOperand arc,
1272                     string opName, list<dag> pattern> :
1273   VOP3b_2_m <
1274   op, (outs vrc:$vdst, SReg_64:$sdst),
1275       (ins InputModsNoDefault:$src0_modifiers, arc:$src0,
1276            InputModsNoDefault:$src1_modifiers, arc:$src1,
1277            InputModsNoDefault:$src2_modifiers, arc:$src2,
1278            ClampMod:$clamp, omod:$omod),
1279   opName#" $vdst, $sdst, $src0_modifiers, $src1_modifiers, $src2_modifiers"#"$clamp"#"$omod", pattern,
1280   opName, opName, 1, 1
1281 >;
1282
1283 multiclass VOP3b_64 <vop3 op, string opName, list<dag> pattern> :
1284   VOP3b_Helper <op, VReg_64, VSrc_64, opName, pattern>;
1285
1286 multiclass VOP3b_32 <vop3 op, string opName, list<dag> pattern> :
1287   VOP3b_Helper <op, VGPR_32, VSrc_32, opName, pattern>;
1288
1289
1290 class Vop3ModPat<Instruction Inst, VOPProfile P, SDPatternOperator node> : Pat<
1291   (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers, i1:$clamp, i32:$omod)),
1292         (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1293         (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))),
1294   (Inst i32:$src0_modifiers, P.Src0VT:$src0,
1295         i32:$src1_modifiers, P.Src1VT:$src1,
1296         i32:$src2_modifiers, P.Src2VT:$src2,
1297         i1:$clamp,
1298         i32:$omod)>;
1299
1300 //===----------------------------------------------------------------------===//
1301 // Interpolation opcodes
1302 //===----------------------------------------------------------------------===//
1303
1304 class VINTRP_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1305   VINTRPCommon <outs, ins, "", pattern>,
1306   SIMCInstr<opName, SISubtarget.NONE> {
1307   let isPseudo = 1;
1308 }
1309
1310 class VINTRP_Real_si <bits <2> op, string opName, dag outs, dag ins,
1311                       string asm> :
1312   VINTRPCommon <outs, ins, asm, []>,
1313   VINTRPe <op>,
1314   SIMCInstr<opName, SISubtarget.SI>;
1315
1316 class VINTRP_Real_vi <bits <2> op, string opName, dag outs, dag ins,
1317                       string asm> :
1318   VINTRPCommon <outs, ins, asm, []>,
1319   VINTRPe_vi <op>,
1320   SIMCInstr<opName, SISubtarget.VI>;
1321
1322 multiclass VINTRP_m <bits <2> op, string opName, dag outs, dag ins, string asm,
1323                      string disableEncoding = "", string constraints = "",
1324                      list<dag> pattern = []> {
1325   let DisableEncoding = disableEncoding,
1326       Constraints = constraints in {
1327     def "" : VINTRP_Pseudo <opName, outs, ins, pattern>;
1328
1329     def _si : VINTRP_Real_si <op, opName, outs, ins, asm>;
1330
1331     def _vi : VINTRP_Real_vi <op, opName, outs, ins, asm>;
1332   }
1333 }
1334
1335 //===----------------------------------------------------------------------===//
1336 // Vector I/O classes
1337 //===----------------------------------------------------------------------===//
1338
1339 class DS_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1340   DS <outs, ins, "", pattern>,
1341   SIMCInstr <opName, SISubtarget.NONE> {
1342   let isPseudo = 1;
1343 }
1344
1345 class DS_Real_si <bits<8> op, string opName, dag outs, dag ins, string asm> :
1346   DS <outs, ins, asm, []>,
1347   DSe <op>,
1348   SIMCInstr <opName, SISubtarget.SI>;
1349
1350 class DS_Real_vi <bits<8> op, string opName, dag outs, dag ins, string asm> :
1351   DS <outs, ins, asm, []>,
1352   DSe_vi <op>,
1353   SIMCInstr <opName, SISubtarget.VI>;
1354
1355 class DS_1A_Real_si <bits<8> op, string opName, dag outs, dag ins, string asm> :
1356   DS <outs, ins, asm, []>,
1357   DSe <op>,
1358   SIMCInstr <opName, SISubtarget.SI> {
1359
1360   // Single load interpret the 2 i8imm operands as a single i16 offset.
1361   bits<16> offset;
1362   let offset0 = offset{7-0};
1363   let offset1 = offset{15-8};
1364 }
1365
1366 class DS_1A_Real_vi <bits<8> op, string opName, dag outs, dag ins, string asm> :
1367   DS <outs, ins, asm, []>,
1368   DSe_vi <op>,
1369   SIMCInstr <opName, SISubtarget.VI> {
1370
1371   // Single load interpret the 2 i8imm operands as a single i16 offset.
1372   bits<16> offset;
1373   let offset0 = offset{7-0};
1374   let offset1 = offset{15-8};
1375 }
1376
1377 multiclass DS_1A_Load_m <bits<8> op, string opName, dag outs, dag ins, string asm,
1378                          list<dag> pat> {
1379   let hasSideEffects = 0, mayLoad = 1, mayStore = 0 in {
1380     def "" : DS_Pseudo <opName, outs, ins, pat>;
1381
1382     let data0 = 0, data1 = 0 in {
1383       def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1384       def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1385     }
1386   }
1387 }
1388
1389 multiclass DS_Load_Helper <bits<8> op, string asm, RegisterClass regClass>
1390     : DS_1A_Load_m <
1391   op,
1392   asm,
1393   (outs regClass:$vdst),
1394   (ins i1imm:$gds, VGPR_32:$addr, ds_offset:$offset, M0Reg:$m0),
1395   asm#" $vdst, $addr"#"$offset"#" [M0]",
1396   []>;
1397
1398 multiclass DS_Load2_m <bits<8> op, string opName, dag outs, dag ins, string asm,
1399                        list<dag> pat> {
1400   let hasSideEffects = 0, mayLoad = 1, mayStore = 0 in {
1401     def "" : DS_Pseudo <opName, outs, ins, pat>;
1402
1403     let data0 = 0, data1 = 0 in {
1404       def _si : DS_Real_si <op, opName, outs, ins, asm>;
1405       def _vi : DS_Real_vi <op, opName, outs, ins, asm>;
1406     }
1407   }
1408 }
1409
1410 multiclass DS_Load2_Helper <bits<8> op, string asm, RegisterClass regClass>
1411     : DS_Load2_m <
1412   op,
1413   asm,
1414   (outs regClass:$vdst),
1415   (ins i1imm:$gds, VGPR_32:$addr, ds_offset0:$offset0, ds_offset1:$offset1,
1416         M0Reg:$m0),
1417   asm#" $vdst, $addr"#"$offset0"#"$offset1 [M0]",
1418   []>;
1419
1420 multiclass DS_1A_Store_m <bits<8> op, string opName, dag outs, dag ins,
1421                           string asm, list<dag> pat> {
1422   let hasSideEffects = 0, mayLoad = 0, mayStore = 1 in {
1423     def "" : DS_Pseudo <opName, outs, ins, pat>;
1424
1425     let data1 = 0, vdst = 0 in {
1426       def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1427       def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1428     }
1429   }
1430 }
1431
1432 multiclass DS_Store_Helper <bits<8> op, string asm, RegisterClass regClass>
1433     : DS_1A_Store_m <
1434   op,
1435   asm,
1436   (outs),
1437   (ins i1imm:$gds, VGPR_32:$addr, regClass:$data0, ds_offset:$offset, M0Reg:$m0),
1438   asm#" $addr, $data0"#"$offset"#" [M0]",
1439   []>;
1440
1441 multiclass DS_Store_m <bits<8> op, string opName, dag outs, dag ins,
1442                        string asm, list<dag> pat> {
1443   let hasSideEffects = 0, mayLoad = 0, mayStore = 1 in {
1444     def "" : DS_Pseudo <opName, outs, ins, pat>;
1445
1446     let vdst = 0 in {
1447       def _si : DS_Real_si <op, opName, outs, ins, asm>;
1448       def _vi : DS_Real_vi <op, opName, outs, ins, asm>;
1449     }
1450   }
1451 }
1452
1453 multiclass DS_Store2_Helper <bits<8> op, string asm, RegisterClass regClass>
1454     : DS_Store_m <
1455   op,
1456   asm,
1457   (outs),
1458   (ins i1imm:$gds, VGPR_32:$addr, regClass:$data0, regClass:$data1,
1459        ds_offset0:$offset0, ds_offset1:$offset1, M0Reg:$m0),
1460   asm#" $addr, $data0, $data1"#"$offset0"#"$offset1 [M0]",
1461   []>;
1462
1463 // 1 address, 1 data.
1464 multiclass DS_1A1D_RET_m <bits<8> op, string opName, dag outs, dag ins,
1465                           string asm, list<dag> pat, string noRetOp> {
1466   let mayLoad = 1, mayStore = 1,
1467       hasPostISelHook = 1 // Adjusted to no return version.
1468       in {
1469     def "" : DS_Pseudo <opName, outs, ins, pat>,
1470              AtomicNoRet<noRetOp, 1>;
1471
1472     let data1 = 0 in {
1473       def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1474       def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1475     }
1476   }
1477 }
1478
1479 multiclass DS_1A1D_RET <bits<8> op, string asm, RegisterClass rc,
1480                         string noRetOp = ""> : DS_1A1D_RET_m <
1481   op, asm,
1482   (outs rc:$vdst),
1483   (ins i1imm:$gds, VGPR_32:$addr, rc:$data0, ds_offset:$offset, M0Reg:$m0),
1484   asm#" $vdst, $addr, $data0"#"$offset"#" [M0]", [], noRetOp>;
1485
1486 // 1 address, 2 data.
1487 multiclass DS_1A2D_RET_m <bits<8> op, string opName, dag outs, dag ins,
1488                           string asm, list<dag> pat, string noRetOp> {
1489   let mayLoad = 1, mayStore = 1,
1490       hasPostISelHook = 1 // Adjusted to no return version.
1491       in {
1492     def "" : DS_Pseudo <opName, outs, ins, pat>,
1493              AtomicNoRet<noRetOp, 1>;
1494
1495     def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1496     def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1497   }
1498 }
1499
1500 multiclass DS_1A2D_RET <bits<8> op, string asm, RegisterClass rc,
1501                    string noRetOp = ""> : DS_1A2D_RET_m <
1502   op, asm,
1503   (outs rc:$vdst),
1504   (ins i1imm:$gds, VGPR_32:$addr, rc:$data0, rc:$data1, ds_offset:$offset, M0Reg:$m0),
1505   asm#" $vdst, $addr, $data0, $data1"#"$offset"#" [M0]",
1506   [], noRetOp>;
1507
1508 // 1 address, 2 data.
1509 multiclass DS_1A2D_NORET_m <bits<8> op, string opName, dag outs, dag ins,
1510                             string asm, list<dag> pat, string noRetOp> {
1511   let mayLoad = 1, mayStore = 1 in {
1512     def "" : DS_Pseudo <opName, outs, ins, pat>,
1513              AtomicNoRet<noRetOp, 0>;
1514
1515     def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1516     def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1517   }
1518 }
1519
1520 multiclass DS_1A2D_NORET <bits<8> op, string asm, RegisterClass rc,
1521                      string noRetOp = asm> : DS_1A2D_NORET_m <
1522   op, asm,
1523   (outs),
1524   (ins i1imm:$gds, VGPR_32:$addr, rc:$data0, rc:$data1, ds_offset:$offset, M0Reg:$m0),
1525   asm#" $addr, $data0, $data1"#"$offset"#" [M0]",
1526   [], noRetOp>;
1527
1528 // 1 address, 1 data.
1529 multiclass DS_1A1D_NORET_m <bits<8> op, string opName, dag outs, dag ins,
1530                             string asm, list<dag> pat, string noRetOp> {
1531   let mayLoad = 1, mayStore = 1 in {
1532     def "" : DS_Pseudo <opName, outs, ins, pat>,
1533              AtomicNoRet<noRetOp, 0>;
1534
1535     let data1 = 0 in {
1536       def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1537       def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1538     }
1539   }
1540 }
1541
1542 multiclass DS_1A1D_NORET <bits<8> op, string asm, RegisterClass rc,
1543                           string noRetOp = asm> : DS_1A1D_NORET_m <
1544   op, asm,
1545   (outs),
1546   (ins i1imm:$gds, VGPR_32:$addr, rc:$data0, ds_offset:$offset, M0Reg:$m0),
1547   asm#" $addr, $data0"#"$offset"#" [M0]",
1548   [], noRetOp>;
1549
1550 //===----------------------------------------------------------------------===//
1551 // MTBUF classes
1552 //===----------------------------------------------------------------------===//
1553
1554 class MTBUF_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1555   MTBUF <outs, ins, "", pattern>,
1556   SIMCInstr<opName, SISubtarget.NONE> {
1557   let isPseudo = 1;
1558 }
1559
1560 class MTBUF_Real_si <bits<3> op, string opName, dag outs, dag ins,
1561                     string asm> :
1562   MTBUF <outs, ins, asm, []>,
1563   MTBUFe <op>,
1564   SIMCInstr<opName, SISubtarget.SI>;
1565
1566 class MTBUF_Real_vi <bits<4> op, string opName, dag outs, dag ins, string asm> :
1567   MTBUF <outs, ins, asm, []>,
1568   MTBUFe_vi <op>,
1569   SIMCInstr <opName, SISubtarget.VI>;
1570
1571 multiclass MTBUF_m <bits<3> op, string opName, dag outs, dag ins, string asm,
1572                     list<dag> pattern> {
1573
1574   def "" : MTBUF_Pseudo <opName, outs, ins, pattern>;
1575
1576   def _si : MTBUF_Real_si <op, opName, outs, ins, asm>;
1577
1578   def _vi : MTBUF_Real_vi <{0, op{2}, op{1}, op{0}}, opName, outs, ins, asm>;
1579
1580 }
1581
1582 let mayStore = 1, mayLoad = 0 in {
1583
1584 multiclass MTBUF_Store_Helper <bits<3> op, string opName,
1585                                RegisterClass regClass> : MTBUF_m <
1586   op, opName, (outs),
1587   (ins regClass:$vdata, u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc,
1588    i1imm:$addr64, i8imm:$dfmt, i8imm:$nfmt, VGPR_32:$vaddr,
1589    SReg_128:$srsrc, i1imm:$slc, i1imm:$tfe, SCSrc_32:$soffset),
1590   opName#" $vdata, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
1591         #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset", []
1592 >;
1593
1594 } // mayStore = 1, mayLoad = 0
1595
1596 let mayLoad = 1, mayStore = 0 in {
1597
1598 multiclass MTBUF_Load_Helper <bits<3> op, string opName,
1599                               RegisterClass regClass> : MTBUF_m <
1600   op, opName, (outs regClass:$dst),
1601   (ins u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc, i1imm:$addr64,
1602        i8imm:$dfmt, i8imm:$nfmt, VGPR_32:$vaddr, SReg_128:$srsrc,
1603        i1imm:$slc, i1imm:$tfe, SCSrc_32:$soffset),
1604   opName#" $dst, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
1605         #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset", []
1606 >;
1607
1608 } // mayLoad = 1, mayStore = 0
1609
1610 //===----------------------------------------------------------------------===//
1611 // MUBUF classes
1612 //===----------------------------------------------------------------------===//
1613
1614 class mubuf <bits<7> si, bits<7> vi = si> {
1615   field bits<7> SI = si;
1616   field bits<7> VI = vi;
1617 }
1618
1619 class MUBUFAddr64Table <bit is_addr64, string suffix = ""> {
1620   bit IsAddr64 = is_addr64;
1621   string OpName = NAME # suffix;
1622 }
1623
1624 class MUBUF_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1625   MUBUF <outs, ins, "", pattern>,
1626   SIMCInstr<opName, SISubtarget.NONE> {
1627   let isPseudo = 1;
1628
1629   // dummy fields, so that we can use let statements around multiclasses
1630   bits<1> offen;
1631   bits<1> idxen;
1632   bits<8> vaddr;
1633   bits<1> glc;
1634   bits<1> slc;
1635   bits<1> tfe;
1636   bits<8> soffset;
1637 }
1638
1639 class MUBUF_Real_si <mubuf op, string opName, dag outs, dag ins,
1640                      string asm> :
1641   MUBUF <outs, ins, asm, []>,
1642   MUBUFe <op.SI>,
1643   SIMCInstr<opName, SISubtarget.SI> {
1644   let lds = 0;
1645 }
1646
1647 class MUBUF_Real_vi <mubuf op, string opName, dag outs, dag ins,
1648                      string asm> :
1649   MUBUF <outs, ins, asm, []>,
1650   MUBUFe_vi <op.VI>,
1651   SIMCInstr<opName, SISubtarget.VI> {
1652   let lds = 0;
1653 }
1654
1655 multiclass MUBUF_m <mubuf op, string opName, dag outs, dag ins, string asm,
1656                     list<dag> pattern> {
1657
1658   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1659            MUBUFAddr64Table <0>;
1660
1661   let addr64 = 0 in {
1662     def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1663   }
1664
1665   def _vi : MUBUF_Real_vi <op, opName, outs, ins, asm>;
1666 }
1667
1668 multiclass MUBUFAddr64_m <mubuf op, string opName, dag outs,
1669                           dag ins, string asm, list<dag> pattern> {
1670
1671   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1672            MUBUFAddr64Table <1>;
1673
1674   let addr64 = 1 in {
1675     def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1676   }
1677
1678   // There is no VI version. If the pseudo is selected, it should be lowered
1679   // for VI appropriately.
1680 }
1681
1682 class MUBUF_si <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern> :
1683   MUBUF <outs, ins, asm, pattern>, MUBUFe <op> {
1684   let lds = 0;
1685 }
1686
1687 multiclass MUBUFAtomicOffset_m <mubuf op, string opName, dag outs, dag ins,
1688                                 string asm, list<dag> pattern, bit is_return> {
1689
1690   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1691            MUBUFAddr64Table <0, !if(is_return, "_RTN", "")>,
1692            AtomicNoRet<NAME#"_OFFSET", is_return>;
1693
1694   let offen = 0, idxen = 0, tfe = 0, vaddr = 0 in {
1695     let addr64 = 0 in {
1696       def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1697     }
1698
1699     def _vi : MUBUF_Real_vi <op, opName, outs, ins, asm>;
1700   }
1701 }
1702
1703 multiclass MUBUFAtomicAddr64_m <mubuf op, string opName, dag outs, dag ins,
1704                                 string asm, list<dag> pattern, bit is_return> {
1705
1706   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1707            MUBUFAddr64Table <1, !if(is_return, "_RTN", "")>,
1708            AtomicNoRet<NAME#"_ADDR64", is_return>;
1709
1710   let offen = 0, idxen = 0, addr64 = 1, tfe = 0, soffset = 128 in {
1711     def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1712   }
1713
1714   // There is no VI version. If the pseudo is selected, it should be lowered
1715   // for VI appropriately.
1716 }
1717
1718 multiclass MUBUF_Atomic <mubuf op, string name, RegisterClass rc,
1719                          ValueType vt, SDPatternOperator atomic> {
1720
1721   let mayStore = 1, mayLoad = 1, hasPostISelHook = 1 in {
1722
1723     // No return variants
1724     let glc = 0 in {
1725
1726       defm _ADDR64 : MUBUFAtomicAddr64_m <
1727         op, name#"_addr64", (outs),
1728         (ins rc:$vdata, SReg_128:$srsrc, VReg_64:$vaddr,
1729              mbuf_offset:$offset, slc:$slc),
1730         name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset"#"$slc", [], 0
1731       >;
1732
1733       defm _OFFSET : MUBUFAtomicOffset_m <
1734         op, name#"_offset", (outs),
1735         (ins rc:$vdata, SReg_128:$srsrc, mbuf_offset:$offset,
1736              SCSrc_32:$soffset, slc:$slc),
1737         name#" $vdata, $srsrc, $soffset"#"$offset"#"$slc", [], 0
1738       >;
1739     } // glc = 0
1740
1741     // Variant that return values
1742     let glc = 1, Constraints = "$vdata = $vdata_in",
1743         DisableEncoding = "$vdata_in"  in {
1744
1745       defm _RTN_ADDR64 : MUBUFAtomicAddr64_m <
1746         op, name#"_rtn_addr64", (outs rc:$vdata),
1747         (ins rc:$vdata_in, SReg_128:$srsrc, VReg_64:$vaddr,
1748              mbuf_offset:$offset, slc:$slc),
1749         name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset"#" glc"#"$slc",
1750         [(set vt:$vdata,
1751          (atomic (MUBUFAddr64Atomic v4i32:$srsrc, i64:$vaddr, i16:$offset,
1752                                     i1:$slc), vt:$vdata_in))], 1
1753       >;
1754
1755       defm _RTN_OFFSET : MUBUFAtomicOffset_m <
1756         op, name#"_rtn_offset", (outs rc:$vdata),
1757         (ins rc:$vdata_in, SReg_128:$srsrc, mbuf_offset:$offset,
1758              SCSrc_32:$soffset, slc:$slc),
1759         name#" $vdata, $srsrc, $soffset"#"$offset"#" glc $slc",
1760         [(set vt:$vdata,
1761          (atomic (MUBUFOffsetAtomic v4i32:$srsrc, i32:$soffset, i16:$offset,
1762                                     i1:$slc), vt:$vdata_in))], 1
1763       >;
1764
1765     } // glc = 1
1766
1767   } // mayStore = 1, mayLoad = 1, hasPostISelHook = 1
1768 }
1769
1770 multiclass MUBUF_Load_Helper <mubuf op, string name, RegisterClass regClass,
1771                               ValueType load_vt = i32,
1772                               SDPatternOperator ld = null_frag> {
1773
1774   let mayLoad = 1, mayStore = 0 in {
1775     let offen = 0, idxen = 0, vaddr = 0 in {
1776       defm _OFFSET : MUBUF_m <op, name#"_offset", (outs regClass:$vdata),
1777                            (ins SReg_128:$srsrc,
1778                            mbuf_offset:$offset, SCSrc_32:$soffset, glc:$glc,
1779                            slc:$slc, tfe:$tfe),
1780                            name#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1781                            [(set load_vt:$vdata, (ld (MUBUFOffset v4i32:$srsrc,
1782                                                      i32:$soffset, i16:$offset,
1783                                                      i1:$glc, i1:$slc, i1:$tfe)))]>;
1784     }
1785
1786     let offen = 1, idxen = 0  in {
1787       defm _OFFEN  : MUBUF_m <op, name#"_offen", (outs regClass:$vdata),
1788                            (ins SReg_128:$srsrc, VGPR_32:$vaddr,
1789                            SCSrc_32:$soffset, mbuf_offset:$offset, glc:$glc, slc:$slc,
1790                            tfe:$tfe),
1791                            name#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1792     }
1793
1794     let offen = 0, idxen = 1 in {
1795       defm _IDXEN  : MUBUF_m <op, name#"_idxen", (outs regClass:$vdata),
1796                            (ins SReg_128:$srsrc, VGPR_32:$vaddr,
1797                            mbuf_offset:$offset, SCSrc_32:$soffset, glc:$glc,
1798                            slc:$slc, tfe:$tfe),
1799                            name#" $vdata, $vaddr, $srsrc, $soffset idxen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1800     }
1801
1802     let offen = 1, idxen = 1 in {
1803       defm _BOTHEN : MUBUF_m <op, name#"_bothen", (outs regClass:$vdata),
1804                            (ins SReg_128:$srsrc, VReg_64:$vaddr,
1805                            SCSrc_32:$soffset, glc:$glc, slc:$slc, tfe:$tfe),
1806                            name#" $vdata, $vaddr, $srsrc, $soffset, idxen offen"#"$glc"#"$slc"#"$tfe", []>;
1807     }
1808
1809     let offen = 0, idxen = 0, glc = 0, slc = 0, tfe = 0, soffset = 128 /* ZERO */ in {
1810       defm _ADDR64 : MUBUFAddr64_m <op, name#"_addr64", (outs regClass:$vdata),
1811                            (ins SReg_128:$srsrc, VReg_64:$vaddr, mbuf_offset:$offset),
1812                            name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset",
1813                            [(set load_vt:$vdata, (ld (MUBUFAddr64 v4i32:$srsrc,
1814                                                   i64:$vaddr, i16:$offset)))]>;
1815     }
1816   }
1817 }
1818
1819 multiclass MUBUF_Store_Helper <mubuf op, string name, RegisterClass vdataClass,
1820                           ValueType store_vt, SDPatternOperator st> {
1821   let mayLoad = 0, mayStore = 1 in {
1822     defm : MUBUF_m <op, name, (outs),
1823                     (ins vdataClass:$vdata, SReg_128:$srsrc, VGPR_32:$vaddr, SCSrc_32:$soffset,
1824                     mbuf_offset:$offset, offen:$offen, idxen:$idxen, glc:$glc, slc:$slc,
1825                     tfe:$tfe),
1826                     name#" $vdata, $vaddr, $srsrc, $soffset"#"$offen"#"$idxen"#"$offset"#
1827                     "$glc"#"$slc"#"$tfe", []>;
1828
1829     let offen = 0, idxen = 0, vaddr = 0 in {
1830       defm _OFFSET : MUBUF_m <op, name#"_offset",(outs),
1831                               (ins vdataClass:$vdata, SReg_128:$srsrc, mbuf_offset:$offset,
1832                               SCSrc_32:$soffset, glc:$glc, slc:$slc, tfe:$tfe),
1833                               name#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1834                               [(st store_vt:$vdata, (MUBUFOffset v4i32:$srsrc, i32:$soffset,
1835                                    i16:$offset, i1:$glc, i1:$slc, i1:$tfe))]>;
1836     } // offen = 0, idxen = 0, vaddr = 0
1837
1838     let offen = 1, idxen = 0  in {
1839       defm _OFFEN : MUBUF_m <op, name#"_offen", (outs),
1840                              (ins vdataClass:$vdata, SReg_128:$srsrc, VGPR_32:$vaddr, SCSrc_32:$soffset,
1841                              mbuf_offset:$offset, glc:$glc, slc:$slc, tfe:$tfe),
1842                              name#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#
1843                              "$glc"#"$slc"#"$tfe", []>;
1844     } // end offen = 1, idxen = 0
1845
1846     let offen = 0, idxen = 0, glc = 0, slc = 0, tfe = 0,
1847         soffset = 128 /* ZERO */ in {
1848       defm _ADDR64 : MUBUFAddr64_m <op, name#"_addr64", (outs),
1849                                     (ins vdataClass:$vdata, SReg_128:$srsrc, VReg_64:$vaddr, mbuf_offset:$offset),
1850                                     name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset",
1851                                     [(st store_vt:$vdata,
1852                                       (MUBUFAddr64 v4i32:$srsrc, i64:$vaddr, i16:$offset))]>;
1853     }
1854   } // End mayLoad = 0, mayStore = 1
1855 }
1856
1857 class FLAT_Load_Helper <bits<7> op, string asm, RegisterClass regClass> :
1858       FLAT <op, (outs regClass:$data),
1859                 (ins VReg_64:$addr),
1860             asm#" $data, $addr, [M0, FLAT_SCRATCH]", []> {
1861   let glc = 0;
1862   let slc = 0;
1863   let tfe = 0;
1864   let mayLoad = 1;
1865 }
1866
1867 class FLAT_Store_Helper <bits<7> op, string name, RegisterClass vdataClass> :
1868       FLAT <op, (outs), (ins vdataClass:$data, VReg_64:$addr),
1869           name#" $data, $addr, [M0, FLAT_SCRATCH]",
1870          []> {
1871
1872   let mayLoad = 0;
1873   let mayStore = 1;
1874
1875   // Encoding
1876   let glc = 0;
1877   let slc = 0;
1878   let tfe = 0;
1879 }
1880
1881 class MIMG_Mask <string op, int channels> {
1882   string Op = op;
1883   int Channels = channels;
1884 }
1885
1886 class MIMG_NoSampler_Helper <bits<7> op, string asm,
1887                              RegisterClass dst_rc,
1888                              RegisterClass src_rc> : MIMG <
1889   op,
1890   (outs dst_rc:$vdata),
1891   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1892        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1893        SReg_256:$srsrc),
1894   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1895      #" $tfe, $lwe, $slc, $vaddr, $srsrc",
1896   []> {
1897   let SSAMP = 0;
1898   let mayLoad = 1;
1899   let mayStore = 0;
1900   let hasPostISelHook = 1;
1901 }
1902
1903 multiclass MIMG_NoSampler_Src_Helper <bits<7> op, string asm,
1904                                       RegisterClass dst_rc,
1905                                       int channels> {
1906   def _V1 : MIMG_NoSampler_Helper <op, asm, dst_rc, VGPR_32>,
1907             MIMG_Mask<asm#"_V1", channels>;
1908   def _V2 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_64>,
1909             MIMG_Mask<asm#"_V2", channels>;
1910   def _V4 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_128>,
1911             MIMG_Mask<asm#"_V4", channels>;
1912 }
1913
1914 multiclass MIMG_NoSampler <bits<7> op, string asm> {
1915   defm _V1 : MIMG_NoSampler_Src_Helper <op, asm, VGPR_32, 1>;
1916   defm _V2 : MIMG_NoSampler_Src_Helper <op, asm, VReg_64, 2>;
1917   defm _V3 : MIMG_NoSampler_Src_Helper <op, asm, VReg_96, 3>;
1918   defm _V4 : MIMG_NoSampler_Src_Helper <op, asm, VReg_128, 4>;
1919 }
1920
1921 class MIMG_Sampler_Helper <bits<7> op, string asm,
1922                            RegisterClass dst_rc,
1923                            RegisterClass src_rc> : MIMG <
1924   op,
1925   (outs dst_rc:$vdata),
1926   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1927        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1928        SReg_256:$srsrc, SReg_128:$ssamp),
1929   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1930      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
1931   []> {
1932   let mayLoad = 1;
1933   let mayStore = 0;
1934   let hasPostISelHook = 1;
1935 }
1936
1937 multiclass MIMG_Sampler_Src_Helper <bits<7> op, string asm,
1938                                     RegisterClass dst_rc,
1939                                     int channels> {
1940   def _V1 : MIMG_Sampler_Helper <op, asm, dst_rc, VGPR_32>,
1941             MIMG_Mask<asm#"_V1", channels>;
1942   def _V2 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_64>,
1943             MIMG_Mask<asm#"_V2", channels>;
1944   def _V4 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_128>,
1945             MIMG_Mask<asm#"_V4", channels>;
1946   def _V8 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_256>,
1947             MIMG_Mask<asm#"_V8", channels>;
1948   def _V16 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_512>,
1949             MIMG_Mask<asm#"_V16", channels>;
1950 }
1951
1952 multiclass MIMG_Sampler <bits<7> op, string asm> {
1953   defm _V1 : MIMG_Sampler_Src_Helper<op, asm, VGPR_32, 1>;
1954   defm _V2 : MIMG_Sampler_Src_Helper<op, asm, VReg_64, 2>;
1955   defm _V3 : MIMG_Sampler_Src_Helper<op, asm, VReg_96, 3>;
1956   defm _V4 : MIMG_Sampler_Src_Helper<op, asm, VReg_128, 4>;
1957 }
1958
1959 class MIMG_Gather_Helper <bits<7> op, string asm,
1960                           RegisterClass dst_rc,
1961                           RegisterClass src_rc> : MIMG <
1962   op,
1963   (outs dst_rc:$vdata),
1964   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1965        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1966        SReg_256:$srsrc, SReg_128:$ssamp),
1967   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1968      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
1969   []> {
1970   let mayLoad = 1;
1971   let mayStore = 0;
1972
1973   // DMASK was repurposed for GATHER4. 4 components are always
1974   // returned and DMASK works like a swizzle - it selects
1975   // the component to fetch. The only useful DMASK values are
1976   // 1=red, 2=green, 4=blue, 8=alpha. (e.g. 1 returns
1977   // (red,red,red,red) etc.) The ISA document doesn't mention
1978   // this.
1979   // Therefore, disable all code which updates DMASK by setting these two:
1980   let MIMG = 0;
1981   let hasPostISelHook = 0;
1982 }
1983
1984 multiclass MIMG_Gather_Src_Helper <bits<7> op, string asm,
1985                                     RegisterClass dst_rc,
1986                                     int channels> {
1987   def _V1 : MIMG_Gather_Helper <op, asm, dst_rc, VGPR_32>,
1988             MIMG_Mask<asm#"_V1", channels>;
1989   def _V2 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_64>,
1990             MIMG_Mask<asm#"_V2", channels>;
1991   def _V4 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_128>,
1992             MIMG_Mask<asm#"_V4", channels>;
1993   def _V8 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_256>,
1994             MIMG_Mask<asm#"_V8", channels>;
1995   def _V16 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_512>,
1996             MIMG_Mask<asm#"_V16", channels>;
1997 }
1998
1999 multiclass MIMG_Gather <bits<7> op, string asm> {
2000   defm _V1 : MIMG_Gather_Src_Helper<op, asm, VGPR_32, 1>;
2001   defm _V2 : MIMG_Gather_Src_Helper<op, asm, VReg_64, 2>;
2002   defm _V3 : MIMG_Gather_Src_Helper<op, asm, VReg_96, 3>;
2003   defm _V4 : MIMG_Gather_Src_Helper<op, asm, VReg_128, 4>;
2004 }
2005
2006 //===----------------------------------------------------------------------===//
2007 // Vector instruction mappings
2008 //===----------------------------------------------------------------------===//
2009
2010 // Maps an opcode in e32 form to its e64 equivalent
2011 def getVOPe64 : InstrMapping {
2012   let FilterClass = "VOP";
2013   let RowFields = ["OpName"];
2014   let ColFields = ["Size"];
2015   let KeyCol = ["4"];
2016   let ValueCols = [["8"]];
2017 }
2018
2019 // Maps an opcode in e64 form to its e32 equivalent
2020 def getVOPe32 : InstrMapping {
2021   let FilterClass = "VOP";
2022   let RowFields = ["OpName"];
2023   let ColFields = ["Size"];
2024   let KeyCol = ["8"];
2025   let ValueCols = [["4"]];
2026 }
2027
2028 // Maps an original opcode to its commuted version
2029 def getCommuteRev : InstrMapping {
2030   let FilterClass = "VOP2_REV";
2031   let RowFields = ["RevOp"];
2032   let ColFields = ["IsOrig"];
2033   let KeyCol = ["1"];
2034   let ValueCols = [["0"]];
2035 }
2036
2037 def getMaskedMIMGOp : InstrMapping {
2038   let FilterClass = "MIMG_Mask";
2039   let RowFields = ["Op"];
2040   let ColFields = ["Channels"];
2041   let KeyCol = ["4"];
2042   let ValueCols = [["1"], ["2"], ["3"] ];
2043 }
2044
2045 // Maps an commuted opcode to its original version
2046 def getCommuteOrig : InstrMapping {
2047   let FilterClass = "VOP2_REV";
2048   let RowFields = ["RevOp"];
2049   let ColFields = ["IsOrig"];
2050   let KeyCol = ["0"];
2051   let ValueCols = [["1"]];
2052 }
2053
2054 def getMCOpcodeGen : InstrMapping {
2055   let FilterClass = "SIMCInstr";
2056   let RowFields = ["PseudoInstr"];
2057   let ColFields = ["Subtarget"];
2058   let KeyCol = [!cast<string>(SISubtarget.NONE)];
2059   let ValueCols = [[!cast<string>(SISubtarget.SI)],[!cast<string>(SISubtarget.VI)]];
2060 }
2061
2062 def getAddr64Inst : InstrMapping {
2063   let FilterClass = "MUBUFAddr64Table";
2064   let RowFields = ["OpName"];
2065   let ColFields = ["IsAddr64"];
2066   let KeyCol = ["0"];
2067   let ValueCols = [["1"]];
2068 }
2069
2070 // Maps an atomic opcode to its version with a return value.
2071 def getAtomicRetOp : InstrMapping {
2072   let FilterClass = "AtomicNoRet";
2073   let RowFields = ["NoRetOp"];
2074   let ColFields = ["IsRet"];
2075   let KeyCol = ["0"];
2076   let ValueCols = [["1"]];
2077 }
2078
2079 // Maps an atomic opcode to its returnless version.
2080 def getAtomicNoRetOp : InstrMapping {
2081   let FilterClass = "AtomicNoRet";
2082   let RowFields = ["NoRetOp"];
2083   let ColFields = ["IsRet"];
2084   let KeyCol = ["1"];
2085   let ValueCols = [["0"]];
2086 }
2087
2088 include "SIInstructions.td"
2089 include "CIInstructions.td"
2090 include "VIInstructions.td"