lib/Target/R600/SIInstrInfo.td

   1 //===-- SIInstrInfo.td - SI Instruction Infos -------------*- tablegen -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 class vop {
  11   field bits<9> SI3;
  12   field bits<10> VI3;
  13 }
  14
  15 class vopc <bits<8> si, bits<8> vi = !add(0x40, si)> : vop {
  16   field bits<8> SI = si;
  17   field bits<8> VI = vi;
  18
  19   field bits<9>  SI3 = {0, si{7-0}};
  20   field bits<10> VI3 = {0, 0, vi{7-0}};
  21 }
  22
  23 class vop1 <bits<8> si, bits<8> vi = si> : vop {
  24   field bits<8> SI = si;
  25   field bits<8> VI = vi;
  26
  27   field bits<9>  SI3 = {1, 1, si{6-0}};
  28   field bits<10> VI3 = !add(0x140, vi);
  29 }
  30
  31 class vop2 <bits<6> si, bits<6> vi = si> : vop {
  32   field bits<6> SI = si;
  33   field bits<6> VI = vi;
  34
  35   field bits<9>  SI3 = {1, 0, 0, si{5-0}};
  36   field bits<10> VI3 = {0, 1, 0, 0, vi{5-0}};
  37 }
  38
  39 // Specify a VOP2 opcode for SI and VOP3 opcode for VI
  40 // that doesn't have VOP2 encoding on VI
  41 class vop23 <bits<6> si, bits<10> vi> : vop2 <si> {
  42   let VI3 = vi;
  43 }
  44
  45 class vop3 <bits<9> si, bits<10> vi = {0, si}> : vop {
  46   let SI3 = si;
  47   let VI3 = vi;
  48 }
  49
  50 class sop1 <bits<8> si, bits<8> vi = si> {
  51   field bits<8> SI = si;
  52   field bits<8> VI = vi;
  53 }
  54
  55 class sop2 <bits<7> si, bits<7> vi = si> {
  56   field bits<7> SI = si;
  57   field bits<7> VI = vi;
  58 }
  59
  60 class sopk <bits<5> si, bits<5> vi = si> {
  61   field bits<5> SI = si;
  62   field bits<5> VI = vi;
  63 }
  64
  65 // Execpt for the NONE field, this must be kept in sync with the SISubtarget enum
  66 // in AMDGPUInstrInfo.cpp
  67 def SISubtarget {
  68   int NONE = -1;
  69   int SI = 0;
  70   int VI = 1;
  71 }
  72
  73 //===----------------------------------------------------------------------===//
  74 // SI DAG Nodes
  75 //===----------------------------------------------------------------------===//
  76
  77 def SIload_constant : SDNode<"AMDGPUISD::LOAD_CONSTANT",
  78   SDTypeProfile<1, 2, [SDTCisVT<0, f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i32>]>,
  79                       [SDNPMayLoad, SDNPMemOperand]
  80 >;
  81
  82 def SItbuffer_store : SDNode<"AMDGPUISD::TBUFFER_STORE_FORMAT",
  83   SDTypeProfile<0, 13,
  84     [SDTCisVT<0, v4i32>,   // rsrc(SGPR)
  85      SDTCisVT<1, iAny>,   // vdata(VGPR)
  86      SDTCisVT<2, i32>,    // num_channels(imm)
  87      SDTCisVT<3, i32>,    // vaddr(VGPR)
  88      SDTCisVT<4, i32>,    // soffset(SGPR)
  89      SDTCisVT<5, i32>,    // inst_offset(imm)
  90      SDTCisVT<6, i32>,    // dfmt(imm)
  91      SDTCisVT<7, i32>,    // nfmt(imm)
  92      SDTCisVT<8, i32>,    // offen(imm)
  93      SDTCisVT<9, i32>,    // idxen(imm)
  94      SDTCisVT<10, i32>,   // glc(imm)
  95      SDTCisVT<11, i32>,   // slc(imm)
  96      SDTCisVT<12, i32>    // tfe(imm)
  97     ]>,
  98   [SDNPMayStore, SDNPMemOperand, SDNPHasChain]
  99 >;
 100
 101 def SIload_input : SDNode<"AMDGPUISD::LOAD_INPUT",
 102   SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i16>,
 103                        SDTCisVT<3, i32>]>
 104 >;
 105
 106 class SDSample<string opcode> : SDNode <opcode,
 107   SDTypeProfile<1, 4, [SDTCisVT<0, v4f32>, SDTCisVT<2, v32i8>,
 108                        SDTCisVT<3, v4i32>, SDTCisVT<4, i32>]>
 109 >;
 110
 111 def SIsample : SDSample<"AMDGPUISD::SAMPLE">;
 112 def SIsampleb : SDSample<"AMDGPUISD::SAMPLEB">;
 113 def SIsampled : SDSample<"AMDGPUISD::SAMPLED">;
 114 def SIsamplel : SDSample<"AMDGPUISD::SAMPLEL">;
 115
 116 def SIconstdata_ptr : SDNode<
 117   "AMDGPUISD::CONST_DATA_PTR", SDTypeProfile <1, 0, [SDTCisVT<0, i64>]>
 118 >;
 119
 120 // Transformation function, extract the lower 32bit of a 64bit immediate
 121 def LO32 : SDNodeXForm<imm, [{
 122   return CurDAG->getTargetConstant(N->getZExtValue() & 0xffffffff, MVT::i32);
 123 }]>;
 124
 125 def LO32f : SDNodeXForm<fpimm, [{
 126   APInt V = N->getValueAPF().bitcastToAPInt().trunc(32);
 127   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
 128 }]>;
 129
 130 // Transformation function, extract the upper 32bit of a 64bit immediate
 131 def HI32 : SDNodeXForm<imm, [{
 132   return CurDAG->getTargetConstant(N->getZExtValue() >> 32, MVT::i32);
 133 }]>;
 134
 135 def HI32f : SDNodeXForm<fpimm, [{
 136   APInt V = N->getValueAPF().bitcastToAPInt().lshr(32).trunc(32);
 137   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
 138 }]>;
 139
 140 def IMM8bitDWORD : PatLeaf <(imm),
 141   [{return (N->getZExtValue() & ~0x3FC) == 0;}]
 142 >;
 143
 144 def as_dword_i32imm : SDNodeXForm<imm, [{
 145   return CurDAG->getTargetConstant(N->getZExtValue() >> 2, MVT::i32);
 146 }]>;
 147
 148 def as_i1imm : SDNodeXForm<imm, [{
 149   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i1);
 150 }]>;
 151
 152 def as_i8imm : SDNodeXForm<imm, [{
 153   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i8);
 154 }]>;
 155
 156 def as_i16imm : SDNodeXForm<imm, [{
 157   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i16);
 158 }]>;
 159
 160 def as_i32imm: SDNodeXForm<imm, [{
 161   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i32);
 162 }]>;
 163
 164 def as_i64imm: SDNodeXForm<imm, [{
 165   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i64);
 166 }]>;
 167
 168 // Copied from the AArch64 backend:
 169 def bitcast_fpimm_to_i32 : SDNodeXForm<fpimm, [{
 170 return CurDAG->getTargetConstant(
 171   N->getValueAPF().bitcastToAPInt().getZExtValue(), MVT::i32);
 172 }]>;
 173
 174 // Copied from the AArch64 backend:
 175 def bitcast_fpimm_to_i64 : SDNodeXForm<fpimm, [{
 176 return CurDAG->getTargetConstant(
 177   N->getValueAPF().bitcastToAPInt().getZExtValue(), MVT::i64);
 178 }]>;
 179
 180 def IMM8bit : PatLeaf <(imm),
 181   [{return isUInt<8>(N->getZExtValue());}]
 182 >;
 183
 184 def IMM12bit : PatLeaf <(imm),
 185   [{return isUInt<12>(N->getZExtValue());}]
 186 >;
 187
 188 def IMM16bit : PatLeaf <(imm),
 189   [{return isUInt<16>(N->getZExtValue());}]
 190 >;
 191
 192 def IMM20bit : PatLeaf <(imm),
 193   [{return isUInt<20>(N->getZExtValue());}]
 194 >;
 195
 196 def IMM32bit : PatLeaf <(imm),
 197   [{return isUInt<32>(N->getZExtValue());}]
 198 >;
 199
 200 def mubuf_vaddr_offset : PatFrag<
 201   (ops node:$ptr, node:$offset, node:$imm_offset),
 202   (add (add node:$ptr, node:$offset), node:$imm_offset)
 203 >;
 204
 205 class InlineImm <ValueType vt> : PatLeaf <(vt imm), [{
 206   return isInlineImmediate(N);
 207 }]>;
 208
 209 class InlineFPImm <ValueType vt> : PatLeaf <(vt fpimm), [{
 210   return isInlineImmediate(N);
 211 }]>;
 212
 213 class SGPRImm <dag frag> : PatLeaf<frag, [{
 214   if (Subtarget->getGeneration() < AMDGPUSubtarget::SOUTHERN_ISLANDS) {
 215     return false;
 216   }
 217   const SIRegisterInfo *SIRI =
 218       static_cast<const SIRegisterInfo *>(Subtarget->getRegisterInfo());
 219   for (SDNode::use_iterator U = N->use_begin(), E = SDNode::use_end();
 220                                                 U != E; ++U) {
 221     if (SIRI->isSGPRClass(getOperandRegClass(*U, U.getOperandNo()))) {
 222       return true;
 223     }
 224   }
 225   return false;
 226 }]>;
 227
 228 //===----------------------------------------------------------------------===//
 229 // Custom Operands
 230 //===----------------------------------------------------------------------===//
 231
 232 def FRAMEri32 : Operand<iPTR> {
 233   let MIOperandInfo = (ops i32:$ptr, i32imm:$index);
 234 }
 235
 236 def sopp_brtarget : Operand<OtherVT> {
 237   let EncoderMethod = "getSOPPBrEncoding";
 238   let OperandType = "OPERAND_PCREL";
 239 }
 240
 241 include "SIInstrFormats.td"
 242 include "VIInstrFormats.td"
 243
 244 let OperandType = "OPERAND_IMMEDIATE" in {
 245
 246 def offen : Operand<i1> {
 247   let PrintMethod = "printOffen";
 248 }
 249 def idxen : Operand<i1> {
 250   let PrintMethod = "printIdxen";
 251 }
 252 def addr64 : Operand<i1> {
 253   let PrintMethod = "printAddr64";
 254 }
 255 def mbuf_offset : Operand<i16> {
 256   let PrintMethod = "printMBUFOffset";
 257 }
 258 def ds_offset : Operand<i16> {
 259   let PrintMethod = "printDSOffset";
 260 }
 261 def ds_offset0 : Operand<i8> {
 262   let PrintMethod = "printDSOffset0";
 263 }
 264 def ds_offset1 : Operand<i8> {
 265   let PrintMethod = "printDSOffset1";
 266 }
 267 def gds : Operand <i1> {
 268   let PrintMethod = "printGDS";
 269 }
 270 def glc : Operand <i1> {
 271   let PrintMethod = "printGLC";
 272 }
 273 def slc : Operand <i1> {
 274   let PrintMethod = "printSLC";
 275 }
 276 def tfe : Operand <i1> {
 277   let PrintMethod = "printTFE";
 278 }
 279
 280 def omod : Operand <i32> {
 281   let PrintMethod = "printOModSI";
 282 }
 283
 284 def ClampMod : Operand <i1> {
 285   let PrintMethod = "printClampSI";
 286 }
 287
 288 } // End OperandType = "OPERAND_IMMEDIATE"
 289
 290 def VOPDstS64 : VOPDstOperand <SReg_64>;
 291
 292 //===----------------------------------------------------------------------===//
 293 // Complex patterns
 294 //===----------------------------------------------------------------------===//
 295
 296 def DS1Addr1Offset : ComplexPattern<i32, 2, "SelectDS1Addr1Offset">;
 297 def DS64Bit4ByteAligned : ComplexPattern<i32, 3, "SelectDS64Bit4ByteAligned">;
 298
 299 def MUBUFAddr32 : ComplexPattern<i64, 9, "SelectMUBUFAddr32">;
 300 def MUBUFAddr64 : ComplexPattern<i64, 7, "SelectMUBUFAddr64">;
 301 def MUBUFAddr64Atomic : ComplexPattern<i64, 5, "SelectMUBUFAddr64">;
 302 def MUBUFScratch : ComplexPattern<i64, 4, "SelectMUBUFScratch">;
 303 def MUBUFOffset : ComplexPattern<i64, 6, "SelectMUBUFOffset">;
 304 def MUBUFOffsetAtomic : ComplexPattern<i64, 4, "SelectMUBUFOffset">;
 305
 306 def VOP3Mods0 : ComplexPattern<untyped, 4, "SelectVOP3Mods0">;
 307 def VOP3Mods0Clamp : ComplexPattern<untyped, 3, "SelectVOP3Mods0Clamp">;
 308 def VOP3Mods0Clamp0OMod : ComplexPattern<untyped, 4, "SelectVOP3Mods0Clamp0OMod">;
 309 def VOP3Mods  : ComplexPattern<untyped, 2, "SelectVOP3Mods">;
 310
 311 //===----------------------------------------------------------------------===//
 312 // SI assembler operands
 313 //===----------------------------------------------------------------------===//
 314
 315 def SIOperand {
 316   int ZERO = 0x80;
 317   int VCC = 0x6A;
 318   int FLAT_SCR = 0x68;
 319 }
 320
 321 def SRCMODS {
 322   int NONE = 0;
 323 }
 324
 325 def DSTCLAMP {
 326   int NONE = 0;
 327 }
 328
 329 def DSTOMOD {
 330   int NONE = 0;
 331 }
 332
 333 //===----------------------------------------------------------------------===//
 334 //
 335 // SI Instruction multiclass helpers.
 336 //
 337 // Instructions with _32 take 32-bit operands.
 338 // Instructions with _64 take 64-bit operands.
 339 //
 340 // VOP_* instructions can use either a 32-bit or 64-bit encoding.  The 32-bit
 341 // encoding is the standard encoding, but instruction that make use of
 342 // any of the instruction modifiers must use the 64-bit encoding.
 343 //
 344 // Instructions with _e32 use the 32-bit encoding.
 345 // Instructions with _e64 use the 64-bit encoding.
 346 //
 347 //===----------------------------------------------------------------------===//
 348
 349 class SIMCInstr <string pseudo, int subtarget> {
 350   string PseudoInstr = pseudo;
 351   int Subtarget = subtarget;
 352 }
 353
 354 //===----------------------------------------------------------------------===//
 355 // EXP classes
 356 //===----------------------------------------------------------------------===//
 357
 358 class EXPCommon : InstSI<
 359   (outs),
 360   (ins i32imm:$en, i32imm:$tgt, i32imm:$compr, i32imm:$done, i32imm:$vm,
 361        VGPR_32:$src0, VGPR_32:$src1, VGPR_32:$src2, VGPR_32:$src3),
 362   "exp $en, $tgt, $compr, $done, $vm, $src0, $src1, $src2, $src3",
 363   [] > {
 364
 365   let EXP_CNT = 1;
 366   let Uses = [EXEC];
 367 }
 368
 369 multiclass EXP_m {
 370
 371   let isPseudo = 1, isCodeGenOnly = 1 in {
 372     def "" : EXPCommon, SIMCInstr <"exp", SISubtarget.NONE> ;
 373   }
 374
 375   def _si : EXPCommon, SIMCInstr <"exp", SISubtarget.SI>, EXPe;
 376
 377   def _vi : EXPCommon, SIMCInstr <"exp", SISubtarget.VI>, EXPe_vi;
 378 }
 379
 380 //===----------------------------------------------------------------------===//
 381 // Scalar classes
 382 //===----------------------------------------------------------------------===//
 383
 384 class SOP1_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 385   SOP1 <outs, ins, "", pattern>,
 386   SIMCInstr<opName, SISubtarget.NONE> {
 387   let isPseudo = 1;
 388   let isCodeGenOnly = 1;
 389 }
 390
 391 class SOP1_Real_si <sop1 op, string opName, dag outs, dag ins, string asm> :
 392   SOP1 <outs, ins, asm, []>,
 393   SOP1e <op.SI>,
 394   SIMCInstr<opName, SISubtarget.SI>;
 395
 396 class SOP1_Real_vi <sop1 op, string opName, dag outs, dag ins, string asm> :
 397   SOP1 <outs, ins, asm, []>,
 398   SOP1e <op.VI>,
 399   SIMCInstr<opName, SISubtarget.VI>;
 400
 401 multiclass SOP1_m <sop1 op, string opName, dag outs, dag ins, string asm,
 402                    list<dag> pattern> {
 403
 404   def "" : SOP1_Pseudo <opName, outs, ins, pattern>;
 405
 406   def _si : SOP1_Real_si <op, opName, outs, ins, asm>;
 407
 408   def _vi : SOP1_Real_vi <op, opName, outs, ins, asm>;
 409
 410 }
 411
 412 multiclass SOP1_32 <sop1 op, string opName, list<dag> pattern> : SOP1_m <
 413     op, opName, (outs SReg_32:$dst), (ins SSrc_32:$src0),
 414     opName#" $dst, $src0", pattern
 415 >;
 416
 417 multiclass SOP1_64 <sop1 op, string opName, list<dag> pattern> : SOP1_m <
 418     op, opName, (outs SReg_64:$dst), (ins SSrc_64:$src0),
 419     opName#" $dst, $src0", pattern
 420 >;
 421
 422 // no input, 64-bit output.
 423 multiclass SOP1_64_0 <sop1 op, string opName, list<dag> pattern> {
 424   def "" : SOP1_Pseudo <opName, (outs SReg_64:$dst), (ins), pattern>;
 425
 426   def _si : SOP1_Real_si <op, opName, (outs SReg_64:$dst), (ins),
 427     opName#" $dst"> {
 428     let ssrc0 = 0;
 429   }
 430
 431   def _vi : SOP1_Real_vi <op, opName, (outs SReg_64:$dst), (ins),
 432     opName#" $dst"> {
 433     let ssrc0 = 0;
 434   }
 435 }
 436
 437 // 64-bit input, no output
 438 multiclass SOP1_1 <sop1 op, string opName, list<dag> pattern> {
 439   def "" : SOP1_Pseudo <opName, (outs), (ins SReg_64:$src0), pattern>;
 440
 441   def _si : SOP1_Real_si <op, opName, (outs), (ins SReg_64:$src0),
 442     opName#" $src0"> {
 443     let sdst = 0;
 444   }
 445
 446   def _vi : SOP1_Real_vi <op, opName, (outs), (ins SReg_64:$src0),
 447     opName#" $src0"> {
 448     let sdst = 0;
 449   }
 450 }
 451
 452 // 64-bit input, 32-bit output.
 453 multiclass SOP1_32_64 <sop1 op, string opName, list<dag> pattern> : SOP1_m <
 454     op, opName, (outs SReg_32:$dst), (ins SSrc_64:$src0),
 455     opName#" $dst, $src0", pattern
 456 >;
 457
 458 class SOP2_Pseudo<string opName, dag outs, dag ins, list<dag> pattern> :
 459   SOP2<outs, ins, "", pattern>,
 460   SIMCInstr<opName, SISubtarget.NONE> {
 461   let isPseudo = 1;
 462   let isCodeGenOnly = 1;
 463   let Size = 4;
 464
 465   // Pseudo instructions have no encodings, but adding this field here allows
 466   // us to do:
 467   // let sdst = xxx in {
 468   // for multiclasses that include both real and pseudo instructions.
 469   field bits<7> sdst = 0;
 470 }
 471
 472 class SOP2_Real_si<sop2 op, string opName, dag outs, dag ins, string asm> :
 473   SOP2<outs, ins, asm, []>,
 474   SOP2e<op.SI>,
 475   SIMCInstr<opName, SISubtarget.SI>;
 476
 477 class SOP2_Real_vi<sop2 op, string opName, dag outs, dag ins, string asm> :
 478   SOP2<outs, ins, asm, []>,
 479   SOP2e<op.VI>,
 480   SIMCInstr<opName, SISubtarget.VI>;
 481
 482 multiclass SOP2_SELECT_32 <sop2 op, string opName, list<dag> pattern> {
 483   def "" : SOP2_Pseudo <opName, (outs SReg_32:$dst),
 484     (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc), pattern>;
 485
 486   def _si : SOP2_Real_si <op, opName, (outs SReg_32:$dst),
 487     (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc),
 488     opName#" $dst, $src0, $src1 [$scc]">;
 489
 490   def _vi : SOP2_Real_vi <op, opName, (outs SReg_32:$dst),
 491     (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc),
 492     opName#" $dst, $src0, $src1 [$scc]">;
 493 }
 494
 495 multiclass SOP2_m <sop2 op, string opName, dag outs, dag ins, string asm,
 496                    list<dag> pattern> {
 497
 498   def "" : SOP2_Pseudo <opName, outs, ins, pattern>;
 499
 500   def _si : SOP2_Real_si <op, opName, outs, ins, asm>;
 501
 502   def _vi : SOP2_Real_vi <op, opName, outs, ins, asm>;
 503
 504 }
 505
 506 multiclass SOP2_32 <sop2 op, string opName, list<dag> pattern> : SOP2_m <
 507     op, opName, (outs SReg_32:$dst), (ins SSrc_32:$src0, SSrc_32:$src1),
 508     opName#" $dst, $src0, $src1", pattern
 509 >;
 510
 511 multiclass SOP2_64 <sop2 op, string opName, list<dag> pattern> : SOP2_m <
 512     op, opName, (outs SReg_64:$dst), (ins SSrc_64:$src0, SSrc_64:$src1),
 513     opName#" $dst, $src0, $src1", pattern
 514 >;
 515
 516 multiclass SOP2_64_32 <sop2 op, string opName, list<dag> pattern> : SOP2_m <
 517     op, opName, (outs SReg_64:$dst), (ins SSrc_64:$src0, SSrc_32:$src1),
 518     opName#" $dst, $src0, $src1", pattern
 519 >;
 520
 521 class SOPC_Helper <bits<7> op, RegisterOperand rc, ValueType vt,
 522                     string opName, PatLeaf cond> : SOPC <
 523   op, (outs SCCReg:$dst), (ins rc:$src0, rc:$src1),
 524   opName#" $src0, $src1", []>;
 525
 526 class SOPC_32<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 527   : SOPC_Helper<op, SSrc_32, i32, opName, cond>;
 528
 529 class SOPC_64<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 530   : SOPC_Helper<op, SSrc_64, i64, opName, cond>;
 531
 532 class SOPK_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 533   SOPK <outs, ins, "", pattern>,
 534   SIMCInstr<opName, SISubtarget.NONE> {
 535   let isPseudo = 1;
 536   let isCodeGenOnly = 1;
 537 }
 538
 539 class SOPK_Real_si <sopk op, string opName, dag outs, dag ins, string asm> :
 540   SOPK <outs, ins, asm, []>,
 541   SOPKe <op.SI>,
 542   SIMCInstr<opName, SISubtarget.SI>;
 543
 544 class SOPK_Real_vi <sopk op, string opName, dag outs, dag ins, string asm> :
 545   SOPK <outs, ins, asm, []>,
 546   SOPKe <op.VI>,
 547   SIMCInstr<opName, SISubtarget.VI>;
 548
 549 multiclass SOPK_32 <sopk op, string opName, list<dag> pattern> {
 550   def "" : SOPK_Pseudo <opName, (outs SReg_32:$dst), (ins u16imm:$src0),
 551     pattern>;
 552
 553   def _si : SOPK_Real_si <op, opName, (outs SReg_32:$dst), (ins u16imm:$src0),
 554     opName#" $dst, $src0">;
 555
 556   def _vi : SOPK_Real_vi <op, opName, (outs SReg_32:$dst), (ins u16imm:$src0),
 557     opName#" $dst, $src0">;
 558 }
 559
 560 multiclass SOPK_SCC <sopk op, string opName, list<dag> pattern> {
 561   def "" : SOPK_Pseudo <opName, (outs SCCReg:$dst),
 562     (ins SReg_32:$src0, u16imm:$src1), pattern>;
 563
 564   def _si : SOPK_Real_si <op, opName, (outs SCCReg:$dst),
 565     (ins SReg_32:$src0, u16imm:$src1), opName#" $dst, $src0">;
 566
 567   def _vi : SOPK_Real_vi <op, opName, (outs SCCReg:$dst),
 568     (ins SReg_32:$src0, u16imm:$src1), opName#" $dst, $src0">;
 569 }
 570
 571 //===----------------------------------------------------------------------===//
 572 // SMRD classes
 573 //===----------------------------------------------------------------------===//
 574
 575 class SMRD_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 576   SMRD <outs, ins, "", pattern>,
 577   SIMCInstr<opName, SISubtarget.NONE> {
 578   let isPseudo = 1;
 579   let isCodeGenOnly = 1;
 580 }
 581
 582 class SMRD_Real_si <bits<5> op, string opName, bit imm, dag outs, dag ins,
 583                     string asm> :
 584   SMRD <outs, ins, asm, []>,
 585   SMRDe <op, imm>,
 586   SIMCInstr<opName, SISubtarget.SI>;
 587
 588 class SMRD_Real_vi <bits<8> op, string opName, bit imm, dag outs, dag ins,
 589                     string asm> :
 590   SMRD <outs, ins, asm, []>,
 591   SMEMe_vi <op, imm>,
 592   SIMCInstr<opName, SISubtarget.VI>;
 593
 594 multiclass SMRD_m <bits<5> op, string opName, bit imm, dag outs, dag ins,
 595                    string asm, list<dag> pattern> {
 596
 597   def "" : SMRD_Pseudo <opName, outs, ins, pattern>;
 598
 599   def _si : SMRD_Real_si <op, opName, imm, outs, ins, asm>;
 600
 601   // glc is only applicable to scalar stores, which are not yet
 602   // implemented.
 603   let glc = 0 in {
 604     def _vi : SMRD_Real_vi <{0, 0, 0, op}, opName, imm, outs, ins, asm>;
 605   }
 606 }
 607
 608 multiclass SMRD_Helper <bits<5> op, string opName, RegisterClass baseClass,
 609                         RegisterClass dstClass> {
 610   defm _IMM : SMRD_m <
 611     op, opName#"_IMM", 1, (outs dstClass:$dst),
 612     (ins baseClass:$sbase, u32imm:$offset),
 613     opName#" $dst, $sbase, $offset", []
 614   >;
 615
 616   defm _SGPR : SMRD_m <
 617     op, opName#"_SGPR", 0, (outs dstClass:$dst),
 618     (ins baseClass:$sbase, SReg_32:$soff),
 619     opName#" $dst, $sbase, $soff", []
 620   >;
 621 }
 622
 623 //===----------------------------------------------------------------------===//
 624 // Vector ALU classes
 625 //===----------------------------------------------------------------------===//
 626
 627 // This must always be right before the operand being input modified.
 628 def InputMods : OperandWithDefaultOps <i32, (ops (i32 0))> {
 629   let PrintMethod = "printOperandAndMods";
 630 }
 631 def InputModsNoDefault : Operand <i32> {
 632   let PrintMethod = "printOperandAndMods";
 633 }
 634
 635 class getNumSrcArgs<ValueType Src1, ValueType Src2> {
 636   int ret =
 637     !if (!eq(Src1.Value, untyped.Value),      1,   // VOP1
 638          !if (!eq(Src2.Value, untyped.Value), 2,   // VOP2
 639                                               3)); // VOP3
 640 }
 641
 642 // Returns the register class to use for the destination of VOP[123C]
 643 // instructions for the given VT.
 644 class getVALUDstForVT<ValueType VT> {
 645   RegisterOperand ret = !if(!eq(VT.Size, 32), VOPDstOperand<VGPR_32>,
 646                           !if(!eq(VT.Size, 64), VOPDstOperand<VReg_64>,
 647                             VOPDstOperand<SReg_64>)); // else VT == i1
 648 }
 649
 650 // Returns the register class to use for source 0 of VOP[12C]
 651 // instructions for the given VT.
 652 class getVOPSrc0ForVT<ValueType VT> {
 653   RegisterOperand ret = !if(!eq(VT.Size, 32), VSrc_32, VSrc_64);
 654 }
 655
 656 // Returns the register class to use for source 1 of VOP[12C] for the
 657 // given VT.
 658 class getVOPSrc1ForVT<ValueType VT> {
 659   RegisterClass ret = !if(!eq(VT.Size, 32), VGPR_32, VReg_64);
 660 }
 661
 662 // Returns the register class to use for sources of VOP3 instructions for the
 663 // given VT.
 664 class getVOP3SrcForVT<ValueType VT> {
 665   RegisterOperand ret = !if(!eq(VT.Size, 32), VCSrc_32, VCSrc_64);
 666 }
 667
 668 // Returns 1 if the source arguments have modifiers, 0 if they do not.
 669 class hasModifiers<ValueType SrcVT> {
 670   bit ret = !if(!eq(SrcVT.Value, f32.Value), 1,
 671             !if(!eq(SrcVT.Value, f64.Value), 1, 0));
 672 }
 673
 674 // Returns the input arguments for VOP[12C] instructions for the given SrcVT.
 675 class getIns32 <RegisterOperand Src0RC, RegisterClass Src1RC, int NumSrcArgs> {
 676   dag ret = !if(!eq(NumSrcArgs, 1), (ins Src0RC:$src0),               // VOP1
 677             !if(!eq(NumSrcArgs, 2), (ins Src0RC:$src0, Src1RC:$src1), // VOP2
 678                                     (ins)));
 679 }
 680
 681 // Returns the input arguments for VOP3 instructions for the given SrcVT.
 682 class getIns64 <RegisterOperand Src0RC, RegisterOperand Src1RC,
 683                 RegisterOperand Src2RC, int NumSrcArgs,
 684                 bit HasModifiers> {
 685
 686   dag ret =
 687     !if (!eq(NumSrcArgs, 1),
 688       !if (!eq(HasModifiers, 1),
 689         // VOP1 with modifiers
 690         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 691              ClampMod:$clamp, omod:$omod)
 692       /* else */,
 693         // VOP1 without modifiers
 694         (ins Src0RC:$src0)
 695       /* endif */ ),
 696     !if (!eq(NumSrcArgs, 2),
 697       !if (!eq(HasModifiers, 1),
 698         // VOP 2 with modifiers
 699         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 700              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 701              ClampMod:$clamp, omod:$omod)
 702       /* else */,
 703         // VOP2 without modifiers
 704         (ins Src0RC:$src0, Src1RC:$src1)
 705       /* endif */ )
 706     /* NumSrcArgs == 3 */,
 707       !if (!eq(HasModifiers, 1),
 708         // VOP3 with modifiers
 709         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 710              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 711              InputModsNoDefault:$src2_modifiers, Src2RC:$src2,
 712              ClampMod:$clamp, omod:$omod)
 713       /* else */,
 714         // VOP3 without modifiers
 715         (ins Src0RC:$src0, Src1RC:$src1, Src2RC:$src2)
 716       /* endif */ )));
 717 }
 718
 719 // Returns the assembly string for the inputs and outputs of a VOP[12C]
 720 // instruction.  This does not add the _e32 suffix, so it can be reused
 721 // by getAsm64.
 722 class getAsm32 <int NumSrcArgs> {
 723   string src1 = ", $src1";
 724   string src2 = ", $src2";
 725   string ret = "$dst, $src0"#
 726                !if(!eq(NumSrcArgs, 1), "", src1)#
 727                !if(!eq(NumSrcArgs, 3), src2, "");
 728 }
 729
 730 // Returns the assembly string for the inputs and outputs of a VOP3
 731 // instruction.
 732 class getAsm64 <int NumSrcArgs, bit HasModifiers> {
 733   string src0 = !if(!eq(NumSrcArgs, 1), "$src0_modifiers", "$src0_modifiers,");
 734   string src1 = !if(!eq(NumSrcArgs, 1), "",
 735                    !if(!eq(NumSrcArgs, 2), " $src1_modifiers",
 736                                            " $src1_modifiers,"));
 737   string src2 = !if(!eq(NumSrcArgs, 3), " $src2_modifiers", "");
 738   string ret =
 739   !if(!eq(HasModifiers, 0),
 740       getAsm32<NumSrcArgs>.ret,
 741       "$dst, "#src0#src1#src2#"$clamp"#"$omod");
 742 }
 743
 744
 745 class VOPProfile <list<ValueType> _ArgVT> {
 746
 747   field list<ValueType> ArgVT = _ArgVT;
 748
 749   field ValueType DstVT = ArgVT[0];
 750   field ValueType Src0VT = ArgVT[1];
 751   field ValueType Src1VT = ArgVT[2];
 752   field ValueType Src2VT = ArgVT[3];
 753   field RegisterOperand DstRC = getVALUDstForVT<DstVT>.ret;
 754   field RegisterOperand Src0RC32 = getVOPSrc0ForVT<Src0VT>.ret;
 755   field RegisterClass Src1RC32 = getVOPSrc1ForVT<Src1VT>.ret;
 756   field RegisterOperand Src0RC64 = getVOP3SrcForVT<Src0VT>.ret;
 757   field RegisterOperand Src1RC64 = getVOP3SrcForVT<Src1VT>.ret;
 758   field RegisterOperand Src2RC64 = getVOP3SrcForVT<Src2VT>.ret;
 759
 760   field int NumSrcArgs = getNumSrcArgs<Src1VT, Src2VT>.ret;
 761   field bit HasModifiers = hasModifiers<Src0VT>.ret;
 762
 763   field dag Outs = (outs DstRC:$dst);
 764
 765   field dag Ins32 = getIns32<Src0RC32, Src1RC32, NumSrcArgs>.ret;
 766   field dag Ins64 = getIns64<Src0RC64, Src1RC64, Src2RC64, NumSrcArgs,
 767                              HasModifiers>.ret;
 768
 769   field string Asm32 = getAsm32<NumSrcArgs>.ret;
 770   field string Asm64 = getAsm64<NumSrcArgs, HasModifiers>.ret;
 771 }
 772
 773 def VOP_F32_F32 : VOPProfile <[f32, f32, untyped, untyped]>;
 774 def VOP_F32_F64 : VOPProfile <[f32, f64, untyped, untyped]>;
 775 def VOP_F32_I32 : VOPProfile <[f32, i32, untyped, untyped]>;
 776 def VOP_F64_F32 : VOPProfile <[f64, f32, untyped, untyped]>;
 777 def VOP_F64_F64 : VOPProfile <[f64, f64, untyped, untyped]>;
 778 def VOP_F64_I32 : VOPProfile <[f64, i32, untyped, untyped]>;
 779 def VOP_I32_F32 : VOPProfile <[i32, f32, untyped, untyped]>;
 780 def VOP_I32_F64 : VOPProfile <[i32, f64, untyped, untyped]>;
 781 def VOP_I32_I32 : VOPProfile <[i32, i32, untyped, untyped]>;
 782
 783 def VOP_F32_F32_F32 : VOPProfile <[f32, f32, f32, untyped]>;
 784 def VOP_F32_F32_I32 : VOPProfile <[f32, f32, i32, untyped]>;
 785 def VOP_F64_F64_F64 : VOPProfile <[f64, f64, f64, untyped]>;
 786 def VOP_F64_F64_I32 : VOPProfile <[f64, f64, i32, untyped]>;
 787 def VOP_I32_F32_F32 : VOPProfile <[i32, f32, f32, untyped]>;
 788 def VOP_I32_F32_I32 : VOPProfile <[i32, f32, i32, untyped]>;
 789 def VOP_I32_I32_I32 : VOPProfile <[i32, i32, i32, untyped]>;
 790 def VOP_I32_I32_I32_VCC : VOPProfile <[i32, i32, i32, untyped]> {
 791   let Src0RC32 = VCSrc_32;
 792 }
 793
 794 def VOP_I1_F32_I32 : VOPProfile <[i1, f32, i32, untyped]> {
 795   let Ins64 = (ins InputModsNoDefault:$src0_modifiers, Src0RC64:$src0, Src1RC64:$src1);
 796   let Asm64 = "$dst, $src0_modifiers, $src1";
 797 }
 798
 799 def VOP_I1_F64_I32 : VOPProfile <[i1, f64, i32, untyped]> {
 800   let Ins64 = (ins InputModsNoDefault:$src0_modifiers, Src0RC64:$src0, Src1RC64:$src1);
 801   let Asm64 = "$dst, $src0_modifiers, $src1";
 802 }
 803
 804 def VOP_I64_I64_I32 : VOPProfile <[i64, i64, i32, untyped]>;
 805 def VOP_I64_I32_I64 : VOPProfile <[i64, i32, i64, untyped]>;
 806 def VOP_I64_I64_I64 : VOPProfile <[i64, i64, i64, untyped]>;
 807 def VOP_CNDMASK : VOPProfile <[i32, i32, i32, untyped]> {
 808   let Ins32 = (ins Src0RC32:$src0, Src1RC32:$src1, VCCReg:$src2);
 809   let Ins64 = (ins Src0RC64:$src0, Src1RC64:$src1, SSrc_64:$src2);
 810   let Asm64 = "$dst, $src0, $src1, $src2";
 811 }
 812
 813 def VOP_F32_F32_F32_F32 : VOPProfile <[f32, f32, f32, f32]>;
 814 def VOP_MADK : VOPProfile <[f32, f32, f32, f32]> {
 815   field dag Ins = (ins VCSrc_32:$src0, VGPR_32:$vsrc1, u32imm:$src2);
 816   field string Asm = "$dst, $src0, $vsrc1, $src2";
 817 }
 818 def VOP_F64_F64_F64_F64 : VOPProfile <[f64, f64, f64, f64]>;
 819 def VOP_I32_I32_I32_I32 : VOPProfile <[i32, i32, i32, i32]>;
 820 def VOP_I64_I32_I32_I64 : VOPProfile <[i64, i32, i32, i64]>;
 821
 822
 823 class VOP <string opName> {
 824   string OpName = opName;
 825 }
 826
 827 class VOP2_REV <string revOp, bit isOrig> {
 828   string RevOp = revOp;
 829   bit IsOrig = isOrig;
 830 }
 831
 832 class VOPC_REV <string revOp, bit isOrig> {
 833   string RevOp = revOp;
 834   bit IsOrig = isOrig;
 835 }
 836
 837 class AtomicNoRet <string noRetOp, bit isRet> {
 838   string NoRetOp = noRetOp;
 839   bit IsRet = isRet;
 840 }
 841
 842 class VOP1_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 843   VOP1Common <outs, ins, "", pattern>,
 844   VOP <opName>,
 845   SIMCInstr <opName#"_e32", SISubtarget.NONE> {
 846   let isPseudo = 1;
 847   let isCodeGenOnly = 1;
 848
 849   field bits<8> vdst;
 850   field bits<9> src0;
 851 }
 852
 853 class VOP1_Real_si <string opName, vop1 op, dag outs, dag ins, string asm> :
 854   VOP1<op.SI, outs, ins, asm, []>,
 855   SIMCInstr <opName#"_e32", SISubtarget.SI>;
 856
 857 class VOP1_Real_vi <string opName, vop1 op, dag outs, dag ins, string asm> :
 858   VOP1<op.VI, outs, ins, asm, []>,
 859   SIMCInstr <opName#"_e32", SISubtarget.VI>;
 860
 861 multiclass VOP1_m <vop1 op, dag outs, dag ins, string asm, list<dag> pattern,
 862                    string opName> {
 863   def "" : VOP1_Pseudo <outs, ins, pattern, opName>;
 864
 865   def _si : VOP1_Real_si <opName, op, outs, ins, asm>;
 866
 867   def _vi : VOP1_Real_vi <opName, op, outs, ins, asm>;
 868 }
 869
 870 multiclass VOP1SI_m <vop1 op, dag outs, dag ins, string asm, list<dag> pattern,
 871                    string opName> {
 872   def "" : VOP1_Pseudo <outs, ins, pattern, opName>;
 873
 874   def _si : VOP1_Real_si <opName, op, outs, ins, asm>;
 875 }
 876
 877 class VOP2_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 878   VOP2Common <outs, ins, "", pattern>,
 879   VOP <opName>,
 880   SIMCInstr<opName#"_e32", SISubtarget.NONE> {
 881   let isPseudo = 1;
 882   let isCodeGenOnly = 1;
 883 }
 884
 885 class VOP2_Real_si <string opName, vop2 op, dag outs, dag ins, string asm> :
 886   VOP2 <op.SI, outs, ins, opName#asm, []>,
 887   SIMCInstr <opName#"_e32", SISubtarget.SI>;
 888
 889 class VOP2_Real_vi <string opName, vop2 op, dag outs, dag ins, string asm> :
 890   VOP2 <op.SI, outs, ins, opName#asm, []>,
 891   SIMCInstr <opName#"_e32", SISubtarget.VI>;
 892
 893 multiclass VOP2SI_m <vop2 op, dag outs, dag ins, string asm, list<dag> pattern,
 894                      string opName, string revOp> {
 895   def "" : VOP2_Pseudo <outs, ins, pattern, opName>,
 896            VOP2_REV<revOp#"_e32", !eq(revOp, opName)>;
 897
 898   def _si : VOP2_Real_si <opName, op, outs, ins, asm>;
 899 }
 900
 901 multiclass VOP2_m <vop2 op, dag outs, dag ins, string asm, list<dag> pattern,
 902                    string opName, string revOp> {
 903   def "" : VOP2_Pseudo <outs, ins, pattern, opName>,
 904            VOP2_REV<revOp#"_e32", !eq(revOp, opName)>;
 905
 906   def _si : VOP2_Real_si <opName, op, outs, ins, asm>;
 907
 908   def _vi : VOP2_Real_vi <opName, op, outs, ins, asm>;
 909
 910 }
 911
 912 class VOP3DisableFields <bit HasSrc1, bit HasSrc2, bit HasModifiers> {
 913
 914   bits<2> src0_modifiers = !if(HasModifiers, ?, 0);
 915   bits<2> src1_modifiers = !if(HasModifiers, !if(HasSrc1, ?, 0), 0);
 916   bits<2> src2_modifiers = !if(HasModifiers, !if(HasSrc2, ?, 0), 0);
 917   bits<2> omod = !if(HasModifiers, ?, 0);
 918   bits<1> clamp = !if(HasModifiers, ?, 0);
 919   bits<9> src1 = !if(HasSrc1, ?, 0);
 920   bits<9> src2 = !if(HasSrc2, ?, 0);
 921 }
 922
 923 class VOP3DisableModFields <bit HasSrc0Mods,
 924                             bit HasSrc1Mods = 0,
 925                             bit HasSrc2Mods = 0,
 926                             bit HasOutputMods = 0> {
 927   bits<2> src0_modifiers = !if(HasSrc0Mods, ?, 0);
 928   bits<2> src1_modifiers = !if(HasSrc1Mods, ?, 0);
 929   bits<2> src2_modifiers = !if(HasSrc2Mods, ?, 0);
 930   bits<2> omod = !if(HasOutputMods, ?, 0);
 931   bits<1> clamp = !if(HasOutputMods, ?, 0);
 932 }
 933
 934 class VOP3_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 935   VOP3Common <outs, ins, "", pattern>,
 936   VOP <opName>,
 937   SIMCInstr<opName#"_e64", SISubtarget.NONE> {
 938   let isPseudo = 1;
 939   let isCodeGenOnly = 1;
 940 }
 941
 942 class VOP3_Real_si <bits<9> op, dag outs, dag ins, string asm, string opName> :
 943   VOP3Common <outs, ins, asm, []>,
 944   VOP3e <op>,
 945   SIMCInstr<opName#"_e64", SISubtarget.SI>;
 946
 947 class VOP3_Real_vi <bits<10> op, dag outs, dag ins, string asm, string opName> :
 948   VOP3Common <outs, ins, asm, []>,
 949   VOP3e_vi <op>,
 950   SIMCInstr <opName#"_e64", SISubtarget.VI>;
 951
 952 class VOP3b_Real_si <bits<9> op, dag outs, dag ins, string asm, string opName> :
 953   VOP3Common <outs, ins, asm, []>,
 954   VOP3be <op>,
 955   SIMCInstr<opName#"_e64", SISubtarget.SI>;
 956
 957 class VOP3b_Real_vi <bits<10> op, dag outs, dag ins, string asm, string opName> :
 958   VOP3Common <outs, ins, asm, []>,
 959   VOP3be_vi <op>,
 960   SIMCInstr <opName#"_e64", SISubtarget.VI>;
 961
 962 multiclass VOP3_m <vop op, dag outs, dag ins, string asm, list<dag> pattern,
 963                    string opName, int NumSrcArgs, bit HasMods = 1> {
 964
 965   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 966
 967   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 968             VOP3DisableFields<!if(!eq(NumSrcArgs, 1), 0, 1),
 969                               !if(!eq(NumSrcArgs, 2), 0, 1),
 970                               HasMods>;
 971   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
 972             VOP3DisableFields<!if(!eq(NumSrcArgs, 1), 0, 1),
 973                               !if(!eq(NumSrcArgs, 2), 0, 1),
 974                               HasMods>;
 975 }
 976
 977 // VOP3_m without source modifiers
 978 multiclass VOP3_m_nomods <vop op, dag outs, dag ins, string asm, list<dag> pattern,
 979                    string opName, int NumSrcArgs, bit HasMods = 1> {
 980
 981   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 982
 983   let src0_modifiers = 0,
 984       src1_modifiers = 0,
 985       src2_modifiers = 0,
 986       clamp = 0,
 987       omod = 0 in {
 988     def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>;
 989     def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>;
 990   }
 991 }
 992
 993 multiclass VOP3_1_m <vop op, dag outs, dag ins, string asm,
 994                      list<dag> pattern, string opName, bit HasMods = 1> {
 995
 996   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 997
 998   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 999             VOP3DisableFields<0, 0, HasMods>;
1000
1001   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
1002             VOP3DisableFields<0, 0, HasMods>;
1003 }
1004
1005 multiclass VOP3SI_1_m <vop op, dag outs, dag ins, string asm,
1006                      list<dag> pattern, string opName, bit HasMods = 1> {
1007
1008   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
1009
1010   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
1011             VOP3DisableFields<0, 0, HasMods>;
1012   // No VI instruction. This class is for SI only.
1013 }
1014
1015 multiclass VOP3_2_m <vop op, dag outs, dag ins, string asm,
1016                      list<dag> pattern, string opName, string revOp,
1017                      bit HasMods = 1, bit UseFullOp = 0> {
1018
1019   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
1020            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
1021
1022   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
1023             VOP3DisableFields<1, 0, HasMods>;
1024
1025   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
1026             VOP3DisableFields<1, 0, HasMods>;
1027 }
1028
1029 multiclass VOP3SI_2_m <vop op, dag outs, dag ins, string asm,
1030                      list<dag> pattern, string opName, string revOp,
1031                      bit HasMods = 1, bit UseFullOp = 0> {
1032
1033   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
1034            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
1035
1036   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
1037             VOP3DisableFields<1, 0, HasMods>;
1038
1039   // No VI instruction. This class is for SI only.
1040 }
1041
1042 // XXX - Is v_div_scale_{f32|f64} only available in vop3b without
1043 // option of implicit vcc use?
1044 multiclass VOP3b_2_m <vop op, dag outs, dag ins, string asm,
1045                       list<dag> pattern, string opName, string revOp,
1046                       bit HasMods = 1, bit UseFullOp = 0> {
1047   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
1048            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
1049
1050   // The VOP2 variant puts the carry out into VCC, the VOP3 variant
1051   // can write it into any SGPR. We currently don't use the carry out,
1052   // so for now hardcode it to VCC as well.
1053   let sdst = SIOperand.VCC, Defs = [VCC] in {
1054     def _si : VOP3b_Real_si <op.SI3, outs, ins, asm, opName>,
1055               VOP3DisableFields<1, 0, HasMods>;
1056
1057     def _vi : VOP3b_Real_vi <op.VI3, outs, ins, asm, opName>,
1058               VOP3DisableFields<1, 0, HasMods>;
1059   } // End sdst = SIOperand.VCC, Defs = [VCC]
1060 }
1061
1062 multiclass VOP3b_3_m <vop op, dag outs, dag ins, string asm,
1063                       list<dag> pattern, string opName, string revOp,
1064                       bit HasMods = 1, bit UseFullOp = 0> {
1065   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
1066
1067
1068   def _si : VOP3b_Real_si <op.SI3, outs, ins, asm, opName>,
1069             VOP3DisableFields<1, 1, HasMods>;
1070
1071   def _vi : VOP3b_Real_vi <op.VI3, outs, ins, asm, opName>,
1072             VOP3DisableFields<1, 1, HasMods>;
1073 }
1074
1075 multiclass VOP3_C_m <vop op, dag outs, dag ins, string asm,
1076                      list<dag> pattern, string opName,
1077                      bit HasMods, bit defExec, string revOp> {
1078
1079   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
1080            VOPC_REV<revOp#"_e64", !eq(revOp, opName)>;
1081
1082   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
1083             VOP3DisableFields<1, 0, HasMods> {
1084     let Defs = !if(defExec, [EXEC], []);
1085   }
1086
1087   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
1088             VOP3DisableFields<1, 0, HasMods> {
1089     let Defs = !if(defExec, [EXEC], []);
1090   }
1091 }
1092
1093 // An instruction that is VOP2 on SI and VOP3 on VI, no modifiers.
1094 multiclass VOP2SI_3VI_m <vop3 op, string opName, dag outs, dag ins,
1095                          string asm, list<dag> pattern = []> {
1096   let isPseudo = 1, isCodeGenOnly = 1 in {
1097     def "" : VOPAnyCommon <outs, ins, "", pattern>,
1098              SIMCInstr<opName, SISubtarget.NONE>;
1099   }
1100
1101   def _si : VOP2 <op.SI3{5-0}, outs, ins, asm, []>,
1102             SIMCInstr <opName, SISubtarget.SI>;
1103
1104   def _vi : VOP3Common <outs, ins, asm, []>,
1105             VOP3e_vi <op.VI3>,
1106             VOP3DisableFields <1, 0, 0>,
1107             SIMCInstr <opName, SISubtarget.VI>;
1108 }
1109
1110 multiclass VOP1_Helper <vop1 op, string opName, dag outs,
1111                         dag ins32, string asm32, list<dag> pat32,
1112                         dag ins64, string asm64, list<dag> pat64,
1113                         bit HasMods> {
1114
1115   defm _e32 : VOP1_m <op, outs, ins32, opName#asm32, pat32, opName>;
1116
1117   defm _e64 : VOP3_1_m <op, outs, ins64, opName#asm64, pat64, opName, HasMods>;
1118 }
1119
1120 multiclass VOP1Inst <vop1 op, string opName, VOPProfile P,
1121                      SDPatternOperator node = null_frag> : VOP1_Helper <
1122   op, opName, P.Outs,
1123   P.Ins32, P.Asm32, [],
1124   P.Ins64, P.Asm64,
1125   !if(P.HasModifiers,
1126       [(set P.DstVT:$dst, (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0,
1127                                 i32:$src0_modifiers, i1:$clamp, i32:$omod))))],
1128       [(set P.DstVT:$dst, (node P.Src0VT:$src0))]),
1129   P.HasModifiers
1130 >;
1131
1132 multiclass VOP1InstSI <vop1 op, string opName, VOPProfile P,
1133                        SDPatternOperator node = null_frag> {
1134
1135   defm _e32 : VOP1SI_m <op, P.Outs, P.Ins32, opName#P.Asm32, [], opName>;
1136
1137   defm _e64 : VOP3SI_1_m <op, P.Outs, P.Ins64, opName#P.Asm64,
1138     !if(P.HasModifiers,
1139       [(set P.DstVT:$dst, (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0,
1140                                 i32:$src0_modifiers, i1:$clamp, i32:$omod))))],
1141       [(set P.DstVT:$dst, (node P.Src0VT:$src0))]),
1142     opName, P.HasModifiers>;
1143 }
1144
1145 multiclass VOP2_Helper <vop2 op, string opName, dag outs,
1146                         dag ins32, string asm32, list<dag> pat32,
1147                         dag ins64, string asm64, list<dag> pat64,
1148                         string revOp, bit HasMods> {
1149   defm _e32 : VOP2_m <op, outs, ins32, asm32, pat32, opName, revOp>;
1150
1151   defm _e64 : VOP3_2_m <op,
1152     outs, ins64, opName#asm64, pat64, opName, revOp, HasMods
1153   >;
1154 }
1155
1156 multiclass VOP2Inst <vop2 op, string opName, VOPProfile P,
1157                      SDPatternOperator node = null_frag,
1158                      string revOp = opName> : VOP2_Helper <
1159   op, opName, P.Outs,
1160   P.Ins32, P.Asm32, [],
1161   P.Ins64, P.Asm64,
1162   !if(P.HasModifiers,
1163       [(set P.DstVT:$dst,
1164            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1165                                       i1:$clamp, i32:$omod)),
1166                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1167       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1168   revOp, P.HasModifiers
1169 >;
1170
1171 multiclass VOP2InstSI <vop2 op, string opName, VOPProfile P,
1172                        SDPatternOperator node = null_frag,
1173                        string revOp = opName> {
1174   defm _e32 : VOP2SI_m <op, P.Outs, P.Ins32, P.Asm32, [], opName, revOp>;
1175
1176   defm _e64 : VOP3SI_2_m <op, P.Outs, P.Ins64, opName#P.Asm64,
1177     !if(P.HasModifiers,
1178         [(set P.DstVT:$dst,
1179              (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1180                                         i1:$clamp, i32:$omod)),
1181                    (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1182         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1183     opName, revOp, P.HasModifiers>;
1184 }
1185
1186 multiclass VOP2b_Helper <vop2 op, string opName, dag outs,
1187                          dag ins32, string asm32, list<dag> pat32,
1188                          dag ins64, string asm64, list<dag> pat64,
1189                          string revOp, bit HasMods> {
1190
1191   defm _e32 : VOP2_m <op, outs, ins32, asm32, pat32, opName, revOp>;
1192
1193   defm _e64 : VOP3b_2_m <op,
1194     outs, ins64, opName#asm64, pat64, opName, revOp, HasMods
1195   >;
1196 }
1197
1198 multiclass VOP2bInst <vop2 op, string opName, VOPProfile P,
1199                       SDPatternOperator node = null_frag,
1200                       string revOp = opName> : VOP2b_Helper <
1201   op, opName, P.Outs,
1202   P.Ins32, P.Asm32, [],
1203   P.Ins64, P.Asm64,
1204   !if(P.HasModifiers,
1205       [(set P.DstVT:$dst,
1206            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1207                                       i1:$clamp, i32:$omod)),
1208                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1209       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1210   revOp, P.HasModifiers
1211 >;
1212
1213 // A VOP2 instruction that is VOP3-only on VI.
1214 multiclass VOP2_VI3_Helper <vop23 op, string opName, dag outs,
1215                             dag ins32, string asm32, list<dag> pat32,
1216                             dag ins64, string asm64, list<dag> pat64,
1217                             string revOp, bit HasMods> {
1218   defm _e32 : VOP2SI_m <op, outs, ins32, asm32, pat32, opName, revOp>;
1219
1220   defm _e64 : VOP3_2_m <op, outs, ins64, opName#asm64, pat64, opName,
1221                         revOp, HasMods>;
1222 }
1223
1224 multiclass VOP2_VI3_Inst <vop23 op, string opName, VOPProfile P,
1225                           SDPatternOperator node = null_frag,
1226                           string revOp = opName>
1227                           : VOP2_VI3_Helper <
1228   op, opName, P.Outs,
1229   P.Ins32, P.Asm32, [],
1230   P.Ins64, P.Asm64,
1231   !if(P.HasModifiers,
1232       [(set P.DstVT:$dst,
1233            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1234                                       i1:$clamp, i32:$omod)),
1235                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1236       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1237   revOp, P.HasModifiers
1238 >;
1239
1240 multiclass VOP2MADK <vop2 op, string opName, list<dag> pattern = []> {
1241
1242   def "" : VOP2_Pseudo <VOP_MADK.Outs, VOP_MADK.Ins, pattern, opName>;
1243
1244 let isCodeGenOnly = 0 in {
1245   def _si : VOP2Common <VOP_MADK.Outs, VOP_MADK.Ins,
1246                         !strconcat(opName, VOP_MADK.Asm), []>,
1247             SIMCInstr <opName#"_e32", SISubtarget.SI>,
1248             VOP2_MADKe <op.SI>;
1249
1250   def _vi : VOP2Common <VOP_MADK.Outs, VOP_MADK.Ins,
1251                         !strconcat(opName, VOP_MADK.Asm), []>,
1252             SIMCInstr <opName#"_e32", SISubtarget.VI>,
1253             VOP2_MADKe <op.VI>;
1254 } // End isCodeGenOnly = 0
1255 }
1256
1257 class VOPC_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
1258   VOPCCommon <ins, "", pattern>,
1259   VOP <opName>,
1260   SIMCInstr<opName#"_e32", SISubtarget.NONE> {
1261   let isPseudo = 1;
1262   let isCodeGenOnly = 1;
1263 }
1264
1265 multiclass VOPC_m <vopc op, dag outs, dag ins, string asm, list<dag> pattern,
1266                    string opName, bit DefExec, string revOpName = ""> {
1267   def "" : VOPC_Pseudo <outs, ins, pattern, opName>;
1268
1269   def _si : VOPC<op.SI, ins, asm, []>,
1270             SIMCInstr <opName#"_e32", SISubtarget.SI> {
1271     let Defs = !if(DefExec, [EXEC], []);
1272   }
1273
1274   def _vi : VOPC<op.VI, ins, asm, []>,
1275             SIMCInstr <opName#"_e32", SISubtarget.VI> {
1276     let Defs = !if(DefExec, [EXEC], []);
1277   }
1278 }
1279
1280 multiclass VOPC_Helper <vopc op, string opName,
1281                         dag ins32, string asm32, list<dag> pat32,
1282                         dag out64, dag ins64, string asm64, list<dag> pat64,
1283                         bit HasMods, bit DefExec, string revOp> {
1284   defm _e32 : VOPC_m <op, (outs), ins32, opName#asm32, pat32, opName, DefExec>;
1285
1286   defm _e64 : VOP3_C_m <op, out64, ins64, opName#asm64, pat64,
1287                         opName, HasMods, DefExec, revOp>;
1288 }
1289
1290 // Special case for class instructions which only have modifiers on
1291 // the 1st source operand.
1292 multiclass VOPC_Class_Helper <vopc op, string opName,
1293                              dag ins32, string asm32, list<dag> pat32,
1294                              dag out64, dag ins64, string asm64, list<dag> pat64,
1295                              bit HasMods, bit DefExec, string revOp> {
1296   defm _e32 : VOPC_m <op, (outs), ins32, opName#asm32, pat32, opName, DefExec>;
1297
1298   defm _e64 : VOP3_C_m <op, out64, ins64, opName#asm64, pat64,
1299                         opName, HasMods, DefExec, revOp>,
1300                         VOP3DisableModFields<1, 0, 0>;
1301 }
1302
1303 multiclass VOPCInst <vopc op, string opName,
1304                      VOPProfile P, PatLeaf cond = COND_NULL,
1305                      string revOp = opName,
1306                      bit DefExec = 0> : VOPC_Helper <
1307   op, opName,
1308   P.Ins32, P.Asm32, [],
1309   (outs VOPDstS64:$dst), P.Ins64, P.Asm64,
1310   !if(P.HasModifiers,
1311       [(set i1:$dst,
1312           (setcc (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1313                                       i1:$clamp, i32:$omod)),
1314                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1315                  cond))],
1316       [(set i1:$dst, (setcc P.Src0VT:$src0, P.Src1VT:$src1, cond))]),
1317   P.HasModifiers, DefExec, revOp
1318 >;
1319
1320 multiclass VOPCClassInst <vopc op, string opName, VOPProfile P,
1321                      bit DefExec = 0> : VOPC_Class_Helper <
1322   op, opName,
1323   P.Ins32, P.Asm32, [],
1324   (outs VOPDstS64:$dst), P.Ins64, P.Asm64,
1325   !if(P.HasModifiers,
1326       [(set i1:$dst,
1327           (AMDGPUfp_class (P.Src0VT (VOP3Mods0Clamp0OMod P.Src0VT:$src0, i32:$src0_modifiers)), P.Src1VT:$src1))],
1328       [(set i1:$dst, (AMDGPUfp_class P.Src0VT:$src0, P.Src1VT:$src1))]),
1329   P.HasModifiers, DefExec, opName
1330 >;
1331
1332
1333 multiclass VOPC_F32 <vopc op, string opName, PatLeaf cond = COND_NULL, string revOp = opName> :
1334   VOPCInst <op, opName, VOP_F32_F32_F32, cond, revOp>;
1335
1336 multiclass VOPC_F64 <vopc op, string opName, PatLeaf cond = COND_NULL, string revOp = opName> :
1337   VOPCInst <op, opName, VOP_F64_F64_F64, cond, revOp>;
1338
1339 multiclass VOPC_I32 <vopc op, string opName, PatLeaf cond = COND_NULL, string revOp = opName> :
1340   VOPCInst <op, opName, VOP_I32_I32_I32, cond, revOp>;
1341
1342 multiclass VOPC_I64 <vopc op, string opName, PatLeaf cond = COND_NULL, string revOp = opName> :
1343   VOPCInst <op, opName, VOP_I64_I64_I64, cond, revOp>;
1344
1345
1346 multiclass VOPCX <vopc op, string opName, VOPProfile P,
1347                   PatLeaf cond = COND_NULL,
1348                   string revOp = "">
1349   : VOPCInst <op, opName, P, cond, revOp, 1>;
1350
1351 multiclass VOPCX_F32 <vopc op, string opName, string revOp = opName> :
1352   VOPCX <op, opName, VOP_F32_F32_F32, COND_NULL, revOp>;
1353
1354 multiclass VOPCX_F64 <vopc op, string opName, string revOp = opName> :
1355   VOPCX <op, opName, VOP_F64_F64_F64, COND_NULL, revOp>;
1356
1357 multiclass VOPCX_I32 <vopc op, string opName, string revOp = opName> :
1358   VOPCX <op, opName, VOP_I32_I32_I32, COND_NULL, revOp>;
1359
1360 multiclass VOPCX_I64 <vopc op, string opName, string revOp = opName> :
1361   VOPCX <op, opName, VOP_I64_I64_I64, COND_NULL, revOp>;
1362
1363 multiclass VOP3_Helper <vop3 op, string opName, dag outs, dag ins, string asm,
1364                         list<dag> pat, int NumSrcArgs, bit HasMods> : VOP3_m <
1365     op, outs, ins, opName#" "#asm, pat, opName, NumSrcArgs, HasMods
1366 >;
1367
1368 multiclass VOPC_CLASS_F32 <vopc op, string opName> :
1369   VOPCClassInst <op, opName, VOP_I1_F32_I32, 0>;
1370
1371 multiclass VOPCX_CLASS_F32 <vopc op, string opName> :
1372   VOPCClassInst <op, opName, VOP_I1_F32_I32, 1>;
1373
1374 multiclass VOPC_CLASS_F64 <vopc op, string opName> :
1375   VOPCClassInst <op, opName, VOP_I1_F64_I32, 0>;
1376
1377 multiclass VOPCX_CLASS_F64 <vopc op, string opName> :
1378   VOPCClassInst <op, opName, VOP_I1_F64_I32, 1>;
1379
1380 multiclass VOP3Inst <vop3 op, string opName, VOPProfile P,
1381                      SDPatternOperator node = null_frag> : VOP3_Helper <
1382   op, opName, (outs P.DstRC.RegClass:$dst), P.Ins64, P.Asm64,
1383   !if(!eq(P.NumSrcArgs, 3),
1384     !if(P.HasModifiers,
1385         [(set P.DstVT:$dst,
1386             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1387                                        i1:$clamp, i32:$omod)),
1388                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1389                   (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))))],
1390         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1,
1391                                   P.Src2VT:$src2))]),
1392   !if(!eq(P.NumSrcArgs, 2),
1393     !if(P.HasModifiers,
1394         [(set P.DstVT:$dst,
1395             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1396                                        i1:$clamp, i32:$omod)),
1397                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1398         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))])
1399   /* P.NumSrcArgs == 1 */,
1400     !if(P.HasModifiers,
1401         [(set P.DstVT:$dst,
1402             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1403                                        i1:$clamp, i32:$omod))))],
1404         [(set P.DstVT:$dst, (node P.Src0VT:$src0))]))),
1405   P.NumSrcArgs, P.HasModifiers
1406 >;
1407
1408 // Special case for v_div_fmas_{f32|f64}, since it seems to be the
1409 // only VOP instruction that implicitly reads VCC.
1410 multiclass VOP3_VCC_Inst <vop3 op, string opName,
1411                           VOPProfile P,
1412                           SDPatternOperator node = null_frag> : VOP3_Helper <
1413   op, opName,
1414   (outs P.DstRC.RegClass:$dst),
1415   (ins InputModsNoDefault:$src0_modifiers, P.Src0RC64:$src0,
1416        InputModsNoDefault:$src1_modifiers, P.Src1RC64:$src1,
1417        InputModsNoDefault:$src2_modifiers, P.Src2RC64:$src2,
1418        ClampMod:$clamp,
1419        omod:$omod),
1420   " $dst, $src0_modifiers, $src1_modifiers, $src2_modifiers"#"$clamp"#"$omod",
1421   [(set P.DstVT:$dst,
1422             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1423                                        i1:$clamp, i32:$omod)),
1424                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1425                   (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers)),
1426                   (i1 VCC)))],
1427   3, 1
1428 >;
1429
1430 multiclass VOP3b_Helper <vop op, RegisterClass vrc, RegisterOperand arc,
1431                     string opName, list<dag> pattern> :
1432   VOP3b_3_m <
1433   op, (outs vrc:$vdst, SReg_64:$sdst),
1434       (ins InputModsNoDefault:$src0_modifiers, arc:$src0,
1435            InputModsNoDefault:$src1_modifiers, arc:$src1,
1436            InputModsNoDefault:$src2_modifiers, arc:$src2,
1437            ClampMod:$clamp, omod:$omod),
1438   opName#" $vdst, $sdst, $src0_modifiers, $src1_modifiers, $src2_modifiers"#"$clamp"#"$omod", pattern,
1439   opName, opName, 1, 1
1440 >;
1441
1442 multiclass VOP3b_64 <vop3 op, string opName, list<dag> pattern> :
1443   VOP3b_Helper <op, VReg_64, VSrc_64, opName, pattern>;
1444
1445 multiclass VOP3b_32 <vop3 op, string opName, list<dag> pattern> :
1446   VOP3b_Helper <op, VGPR_32, VSrc_32, opName, pattern>;
1447
1448
1449 class Vop3ModPat<Instruction Inst, VOPProfile P, SDPatternOperator node> : Pat<
1450   (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers, i1:$clamp, i32:$omod)),
1451         (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1452         (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))),
1453   (Inst i32:$src0_modifiers, P.Src0VT:$src0,
1454         i32:$src1_modifiers, P.Src1VT:$src1,
1455         i32:$src2_modifiers, P.Src2VT:$src2,
1456         i1:$clamp,
1457         i32:$omod)>;
1458
1459 //===----------------------------------------------------------------------===//
1460 // Interpolation opcodes
1461 //===----------------------------------------------------------------------===//
1462
1463 class VINTRP_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1464   VINTRPCommon <outs, ins, "", pattern>,
1465   SIMCInstr<opName, SISubtarget.NONE> {
1466   let isPseudo = 1;
1467   let isCodeGenOnly = 1;
1468 }
1469
1470 class VINTRP_Real_si <bits <2> op, string opName, dag outs, dag ins,
1471                       string asm> :
1472   VINTRPCommon <outs, ins, asm, []>,
1473   VINTRPe <op>,
1474   SIMCInstr<opName, SISubtarget.SI>;
1475
1476 class VINTRP_Real_vi <bits <2> op, string opName, dag outs, dag ins,
1477                       string asm> :
1478   VINTRPCommon <outs, ins, asm, []>,
1479   VINTRPe_vi <op>,
1480   SIMCInstr<opName, SISubtarget.VI>;
1481
1482 multiclass VINTRP_m <bits <2> op, string opName, dag outs, dag ins, string asm,
1483                      string disableEncoding = "", string constraints = "",
1484                      list<dag> pattern = []> {
1485   let DisableEncoding = disableEncoding,
1486       Constraints = constraints in {
1487     def "" : VINTRP_Pseudo <opName, outs, ins, pattern>;
1488
1489     def _si : VINTRP_Real_si <op, opName, outs, ins, asm>;
1490
1491     def _vi : VINTRP_Real_vi <op, opName, outs, ins, asm>;
1492   }
1493 }
1494
1495 //===----------------------------------------------------------------------===//
1496 // Vector I/O classes
1497 //===----------------------------------------------------------------------===//
1498
1499 class DS_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1500   DS <outs, ins, "", pattern>,
1501   SIMCInstr <opName, SISubtarget.NONE> {
1502   let isPseudo = 1;
1503   let isCodeGenOnly = 1;
1504 }
1505
1506 class DS_Real_si <bits<8> op, string opName, dag outs, dag ins, string asm> :
1507   DS <outs, ins, asm, []>,
1508   DSe <op>,
1509   SIMCInstr <opName, SISubtarget.SI>;
1510
1511 class DS_Real_vi <bits<8> op, string opName, dag outs, dag ins, string asm> :
1512   DS <outs, ins, asm, []>,
1513   DSe_vi <op>,
1514   SIMCInstr <opName, SISubtarget.VI>;
1515
1516 class DS_Off16_Real_si <bits<8> op, string opName, dag outs, dag ins, string asm> :
1517   DS_Real_si <op,opName, outs, ins, asm> {
1518
1519   // Single load interpret the 2 i8imm operands as a single i16 offset.
1520   bits<16> offset;
1521   let offset0 = offset{7-0};
1522   let offset1 = offset{15-8};
1523 }
1524
1525 class DS_Off16_Real_vi <bits<8> op, string opName, dag outs, dag ins, string asm> :
1526   DS_Real_vi <op, opName, outs, ins, asm> {
1527
1528   // Single load interpret the 2 i8imm operands as a single i16 offset.
1529   bits<16> offset;
1530   let offset0 = offset{7-0};
1531   let offset1 = offset{15-8};
1532 }
1533
1534 multiclass DS_1A_RET <bits<8> op, string opName, RegisterClass rc,
1535   dag outs = (outs rc:$vdst),
1536   dag ins = (ins VGPR_32:$addr, ds_offset:$offset, gds:$gds, M0Reg:$m0),
1537   string asm = opName#" $vdst, $addr"#"$offset$gds"> {
1538
1539   def "" : DS_Pseudo <opName, outs, ins, []>;
1540
1541   let data0 = 0, data1 = 0 in {
1542     def _si : DS_Off16_Real_si <op, opName, outs, ins, asm>;
1543     def _vi : DS_Off16_Real_vi <op, opName, outs, ins, asm>;
1544   }
1545 }
1546
1547 multiclass DS_1A_Off8_RET <bits<8> op, string opName, RegisterClass rc,
1548   dag outs = (outs rc:$vdst),
1549   dag ins = (ins VGPR_32:$addr, ds_offset0:$offset0, ds_offset1:$offset1,
1550                  gds:$gds, M0Reg:$m0),
1551   string asm = opName#" $vdst, $addr"#"$offset0"#"$offset1$gds"> {
1552
1553   def "" : DS_Pseudo <opName, outs, ins, []>;
1554
1555   let data0 = 0, data1 = 0 in {
1556     def _si : DS_Real_si <op, opName, outs, ins, asm>;
1557     def _vi : DS_Real_vi <op, opName, outs, ins, asm>;
1558   }
1559 }
1560
1561 multiclass DS_1A1D_NORET <bits<8> op, string opName, RegisterClass rc,
1562   dag outs = (outs),
1563   dag ins = (ins VGPR_32:$addr, rc:$data0, ds_offset:$offset, gds:$gds,
1564                  M0Reg:$m0),
1565   string asm = opName#" $addr, $data0"#"$offset$gds"> {
1566
1567   def "" : DS_Pseudo <opName, outs, ins, []>,
1568            AtomicNoRet<opName, 0>;
1569
1570   let data1 = 0, vdst = 0 in {
1571     def _si : DS_Off16_Real_si <op, opName, outs, ins, asm>;
1572     def _vi : DS_Off16_Real_vi <op, opName, outs, ins, asm>;
1573   }
1574 }
1575
1576 multiclass DS_1A1D_Off8_NORET <bits<8> op, string opName, RegisterClass rc,
1577   dag outs = (outs),
1578   dag ins = (ins VGPR_32:$addr, rc:$data0, rc:$data1,
1579               ds_offset0:$offset0, ds_offset1:$offset1, gds:$gds, M0Reg:$m0),
1580   string asm = opName#" $addr, $data0, $data1"#"$offset0"#"$offset1"#"$gds"> {
1581
1582   def "" : DS_Pseudo <opName, outs, ins, []>;
1583
1584   let vdst = 0 in {
1585     def _si : DS_Real_si <op, opName, outs, ins, asm>;
1586     def _vi : DS_Real_vi <op, opName, outs, ins, asm>;
1587   }
1588 }
1589
1590 multiclass DS_1A1D_RET <bits<8> op, string opName, RegisterClass rc,
1591                         string noRetOp = "",
1592   dag outs = (outs rc:$vdst),
1593   dag ins = (ins VGPR_32:$addr, rc:$data0, ds_offset:$offset, gds:$gds,
1594                  M0Reg:$m0),
1595   string asm = opName#" $vdst, $addr, $data0"#"$offset$gds"> {
1596
1597   def "" : DS_Pseudo <opName, outs, ins, []>,
1598            AtomicNoRet<noRetOp, 1>;
1599
1600   let data1 = 0 in {
1601     def _si : DS_Off16_Real_si <op, opName, outs, ins, asm>;
1602     def _vi : DS_Off16_Real_vi <op, opName, outs, ins, asm>;
1603   }
1604 }
1605
1606 multiclass DS_1A2D_RET_m <bits<8> op, string opName, RegisterClass rc,
1607                           string noRetOp = "", dag ins,
1608   dag outs = (outs rc:$vdst),
1609   string asm = opName#" $vdst, $addr, $data0, $data1"#"$offset"#"$gds"> {
1610
1611   def "" : DS_Pseudo <opName, outs, ins, []>,
1612            AtomicNoRet<noRetOp, 1>;
1613
1614   def _si : DS_Off16_Real_si <op, opName, outs, ins, asm>;
1615   def _vi : DS_Off16_Real_vi <op, opName, outs, ins, asm>;
1616 }
1617
1618 multiclass DS_1A2D_RET <bits<8> op, string asm, RegisterClass rc,
1619                         string noRetOp = "", RegisterClass src = rc> :
1620   DS_1A2D_RET_m <op, asm, rc, noRetOp,
1621                  (ins VGPR_32:$addr, src:$data0, src:$data1,
1622                       ds_offset:$offset, gds:$gds, M0Reg:$m0)
1623 >;
1624
1625 multiclass DS_1A2D_NORET <bits<8> op, string opName, RegisterClass rc,
1626                           string noRetOp = opName,
1627   dag outs = (outs),
1628   dag ins = (ins VGPR_32:$addr, rc:$data0, rc:$data1,
1629                  ds_offset:$offset, gds:$gds, M0Reg:$m0),
1630   string asm = opName#" $addr, $data0, $data1"#"$offset"#"$gds"> {
1631
1632   def "" : DS_Pseudo <opName, outs, ins, []>,
1633            AtomicNoRet<noRetOp, 0>;
1634
1635   let vdst = 0 in {
1636     def _si : DS_Off16_Real_si <op, opName, outs, ins, asm>;
1637     def _vi : DS_Off16_Real_vi <op, opName, outs, ins, asm>;
1638   }
1639 }
1640
1641 multiclass DS_0A_RET <bits<8> op, string opName,
1642   dag outs = (outs VGPR_32:$vdst),
1643   dag ins = (ins ds_offset:$offset, gds:$gds, M0Reg:$m0),
1644   string asm = opName#" $vdst"#"$offset"#"$gds"> {
1645
1646   let mayLoad = 1, mayStore = 1 in {
1647     def "" : DS_Pseudo <opName, outs, ins, []>;
1648
1649     let addr = 0, data0 = 0, data1 = 0 in {
1650       def _si : DS_Off16_Real_si <op, opName, outs, ins, asm>;
1651       def _vi : DS_Off16_Real_vi <op, opName, outs, ins, asm>;
1652     } // end addr = 0, data0 = 0, data1 = 0
1653   } // end mayLoad = 1, mayStore = 1
1654 }
1655
1656 multiclass DS_1A_RET_GDS <bits<8> op, string opName,
1657   dag outs = (outs VGPR_32:$vdst),
1658   dag ins = (ins VGPR_32:$addr, ds_offset:$offset, M0Reg:$m0),
1659   string asm = opName#" $vdst, $addr"#"$offset gds"> {
1660
1661   def "" : DS_Pseudo <opName, outs, ins, []>;
1662
1663   let data0 = 0, data1 = 0, gds = 1 in {
1664     def _si : DS_Off16_Real_si <op, opName, outs, ins, asm>;
1665     def _vi : DS_Off16_Real_vi <op, opName, outs, ins, asm>;
1666   } // end data0 = 0, data1 = 0, gds = 1
1667 }
1668
1669 multiclass DS_1A_GDS <bits<8> op, string opName,
1670   dag outs = (outs),
1671   dag ins = (ins VGPR_32:$addr, M0Reg:$m0),
1672   string asm = opName#" $addr gds"> {
1673
1674   def "" : DS_Pseudo <opName, outs, ins, []>;
1675
1676   let vdst = 0, data0 = 0, data1 = 0, offset0 = 0, offset1 = 0, gds = 1 in {
1677     def _si : DS_Real_si <op, opName, outs, ins, asm>;
1678     def _vi : DS_Real_vi <op, opName, outs, ins, asm>;
1679   } // end vdst = 0, data = 0, data1 = 0, gds = 1
1680 }
1681
1682 multiclass DS_1A <bits<8> op, string opName,
1683   dag outs = (outs),
1684   dag ins = (ins VGPR_32:$addr, ds_offset:$offset, M0Reg:$m0, gds:$gds),
1685   string asm = opName#" $addr"#"$offset"#"$gds"> {
1686
1687   let mayLoad = 1, mayStore = 1 in {
1688     def "" : DS_Pseudo <opName, outs, ins, []>;
1689
1690     let vdst = 0, data0 = 0, data1 = 0 in {
1691       def _si : DS_Off16_Real_si <op, opName, outs, ins, asm>;
1692       def _vi : DS_Off16_Real_vi <op, opName, outs, ins, asm>;
1693     } // let vdst = 0, data0 = 0, data1 = 0
1694   } // end mayLoad = 1, mayStore = 1
1695 }
1696
1697 //===----------------------------------------------------------------------===//
1698 // MTBUF classes
1699 //===----------------------------------------------------------------------===//
1700
1701 class MTBUF_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1702   MTBUF <outs, ins, "", pattern>,
1703   SIMCInstr<opName, SISubtarget.NONE> {
1704   let isPseudo = 1;
1705   let isCodeGenOnly = 1;
1706 }
1707
1708 class MTBUF_Real_si <bits<3> op, string opName, dag outs, dag ins,
1709                     string asm> :
1710   MTBUF <outs, ins, asm, []>,
1711   MTBUFe <op>,
1712   SIMCInstr<opName, SISubtarget.SI>;
1713
1714 class MTBUF_Real_vi <bits<4> op, string opName, dag outs, dag ins, string asm> :
1715   MTBUF <outs, ins, asm, []>,
1716   MTBUFe_vi <op>,
1717   SIMCInstr <opName, SISubtarget.VI>;
1718
1719 multiclass MTBUF_m <bits<3> op, string opName, dag outs, dag ins, string asm,
1720                     list<dag> pattern> {
1721
1722   def "" : MTBUF_Pseudo <opName, outs, ins, pattern>;
1723
1724   def _si : MTBUF_Real_si <op, opName, outs, ins, asm>;
1725
1726   def _vi : MTBUF_Real_vi <{0, op{2}, op{1}, op{0}}, opName, outs, ins, asm>;
1727
1728 }
1729
1730 let mayStore = 1, mayLoad = 0 in {
1731
1732 multiclass MTBUF_Store_Helper <bits<3> op, string opName,
1733                                RegisterClass regClass> : MTBUF_m <
1734   op, opName, (outs),
1735   (ins regClass:$vdata, u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc,
1736    i1imm:$addr64, i8imm:$dfmt, i8imm:$nfmt, VGPR_32:$vaddr,
1737    SReg_128:$srsrc, i1imm:$slc, i1imm:$tfe, SCSrc_32:$soffset),
1738   opName#" $vdata, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
1739         #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset", []
1740 >;
1741
1742 } // mayStore = 1, mayLoad = 0
1743
1744 let mayLoad = 1, mayStore = 0 in {
1745
1746 multiclass MTBUF_Load_Helper <bits<3> op, string opName,
1747                               RegisterClass regClass> : MTBUF_m <
1748   op, opName, (outs regClass:$dst),
1749   (ins u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc, i1imm:$addr64,
1750        i8imm:$dfmt, i8imm:$nfmt, VGPR_32:$vaddr, SReg_128:$srsrc,
1751        i1imm:$slc, i1imm:$tfe, SCSrc_32:$soffset),
1752   opName#" $dst, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
1753         #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset", []
1754 >;
1755
1756 } // mayLoad = 1, mayStore = 0
1757
1758 //===----------------------------------------------------------------------===//
1759 // MUBUF classes
1760 //===----------------------------------------------------------------------===//
1761
1762 class mubuf <bits<7> si, bits<7> vi = si> {
1763   field bits<7> SI = si;
1764   field bits<7> VI = vi;
1765 }
1766
1767 class MUBUFAddr64Table <bit is_addr64, string suffix = ""> {
1768   bit IsAddr64 = is_addr64;
1769   string OpName = NAME # suffix;
1770 }
1771
1772 class MUBUF_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1773   MUBUF <outs, ins, "", pattern>,
1774   SIMCInstr<opName, SISubtarget.NONE> {
1775   let isPseudo = 1;
1776   let isCodeGenOnly = 1;
1777
1778   // dummy fields, so that we can use let statements around multiclasses
1779   bits<1> offen;
1780   bits<1> idxen;
1781   bits<8> vaddr;
1782   bits<1> glc;
1783   bits<1> slc;
1784   bits<1> tfe;
1785   bits<8> soffset;
1786 }
1787
1788 class MUBUF_Real_si <mubuf op, string opName, dag outs, dag ins,
1789                      string asm> :
1790   MUBUF <outs, ins, asm, []>,
1791   MUBUFe <op.SI>,
1792   SIMCInstr<opName, SISubtarget.SI> {
1793   let lds = 0;
1794 }
1795
1796 class MUBUF_Real_vi <mubuf op, string opName, dag outs, dag ins,
1797                      string asm> :
1798   MUBUF <outs, ins, asm, []>,
1799   MUBUFe_vi <op.VI>,
1800   SIMCInstr<opName, SISubtarget.VI> {
1801   let lds = 0;
1802 }
1803
1804 multiclass MUBUF_m <mubuf op, string opName, dag outs, dag ins, string asm,
1805                     list<dag> pattern> {
1806
1807   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1808            MUBUFAddr64Table <0>;
1809
1810   let addr64 = 0 in {
1811     def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1812   }
1813
1814   def _vi : MUBUF_Real_vi <op, opName, outs, ins, asm>;
1815 }
1816
1817 multiclass MUBUFAddr64_m <mubuf op, string opName, dag outs,
1818                           dag ins, string asm, list<dag> pattern> {
1819
1820   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1821            MUBUFAddr64Table <1>;
1822
1823   let addr64 = 1 in {
1824     def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1825   }
1826
1827   // There is no VI version. If the pseudo is selected, it should be lowered
1828   // for VI appropriately.
1829 }
1830
1831 class MUBUF_si <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern> :
1832   MUBUF <outs, ins, asm, pattern>, MUBUFe <op> {
1833   let lds = 0;
1834 }
1835
1836 multiclass MUBUFAtomicOffset_m <mubuf op, string opName, dag outs, dag ins,
1837                                 string asm, list<dag> pattern, bit is_return> {
1838
1839   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1840            MUBUFAddr64Table <0, !if(is_return, "_RTN", "")>,
1841            AtomicNoRet<NAME#"_OFFSET", is_return>;
1842
1843   let offen = 0, idxen = 0, tfe = 0, vaddr = 0 in {
1844     let addr64 = 0 in {
1845       def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1846     }
1847
1848     def _vi : MUBUF_Real_vi <op, opName, outs, ins, asm>;
1849   }
1850 }
1851
1852 multiclass MUBUFAtomicAddr64_m <mubuf op, string opName, dag outs, dag ins,
1853                                 string asm, list<dag> pattern, bit is_return> {
1854
1855   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1856            MUBUFAddr64Table <1, !if(is_return, "_RTN", "")>,
1857            AtomicNoRet<NAME#"_ADDR64", is_return>;
1858
1859   let offen = 0, idxen = 0, addr64 = 1, tfe = 0 in {
1860     def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1861   }
1862
1863   // There is no VI version. If the pseudo is selected, it should be lowered
1864   // for VI appropriately.
1865 }
1866
1867 multiclass MUBUF_Atomic <mubuf op, string name, RegisterClass rc,
1868                          ValueType vt, SDPatternOperator atomic> {
1869
1870   let mayStore = 1, mayLoad = 1, hasPostISelHook = 1 in {
1871
1872     // No return variants
1873     let glc = 0 in {
1874
1875       defm _ADDR64 : MUBUFAtomicAddr64_m <
1876         op, name#"_addr64", (outs),
1877         (ins rc:$vdata, SReg_128:$srsrc, VReg_64:$vaddr,
1878              SCSrc_32:$soffset, mbuf_offset:$offset, slc:$slc),
1879         name#" $vdata, $vaddr, $srsrc, $soffset addr64"#"$offset"#"$slc", [], 0
1880       >;
1881
1882       defm _OFFSET : MUBUFAtomicOffset_m <
1883         op, name#"_offset", (outs),
1884         (ins rc:$vdata, SReg_128:$srsrc, SCSrc_32:$soffset, mbuf_offset:$offset,
1885              slc:$slc),
1886         name#" $vdata, $srsrc, $soffset"#"$offset"#"$slc", [], 0
1887       >;
1888     } // glc = 0
1889
1890     // Variant that return values
1891     let glc = 1, Constraints = "$vdata = $vdata_in",
1892         DisableEncoding = "$vdata_in"  in {
1893
1894       defm _RTN_ADDR64 : MUBUFAtomicAddr64_m <
1895         op, name#"_rtn_addr64", (outs rc:$vdata),
1896         (ins rc:$vdata_in, SReg_128:$srsrc, VReg_64:$vaddr,
1897              SCSrc_32:$soffset, mbuf_offset:$offset, slc:$slc),
1898         name#" $vdata, $vaddr, $srsrc, $soffset addr64"#"$offset"#" glc"#"$slc",
1899         [(set vt:$vdata,
1900          (atomic (MUBUFAddr64Atomic v4i32:$srsrc, i64:$vaddr, i32:$soffset,
1901                                     i16:$offset, i1:$slc), vt:$vdata_in))], 1
1902       >;
1903
1904       defm _RTN_OFFSET : MUBUFAtomicOffset_m <
1905         op, name#"_rtn_offset", (outs rc:$vdata),
1906         (ins rc:$vdata_in, SReg_128:$srsrc, SCSrc_32:$soffset,
1907              mbuf_offset:$offset, slc:$slc),
1908         name#" $vdata, $srsrc, $soffset"#"$offset"#" glc $slc",
1909         [(set vt:$vdata,
1910          (atomic (MUBUFOffsetAtomic v4i32:$srsrc, i32:$soffset, i16:$offset,
1911                                     i1:$slc), vt:$vdata_in))], 1
1912       >;
1913
1914     } // glc = 1
1915
1916   } // mayStore = 1, mayLoad = 1, hasPostISelHook = 1
1917 }
1918
1919 multiclass MUBUF_Load_Helper <mubuf op, string name, RegisterClass regClass,
1920                               ValueType load_vt = i32,
1921                               SDPatternOperator ld = null_frag> {
1922
1923   let mayLoad = 1, mayStore = 0 in {
1924     let offen = 0, idxen = 0, vaddr = 0 in {
1925       defm _OFFSET : MUBUF_m <op, name#"_offset", (outs regClass:$vdata),
1926                            (ins SReg_128:$srsrc, SCSrc_32:$soffset,
1927                            mbuf_offset:$offset, glc:$glc, slc:$slc, tfe:$tfe),
1928                            name#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1929                            [(set load_vt:$vdata, (ld (MUBUFOffset v4i32:$srsrc,
1930                                                      i32:$soffset, i16:$offset,
1931                                                      i1:$glc, i1:$slc, i1:$tfe)))]>;
1932     }
1933
1934     let offen = 1, idxen = 0  in {
1935       defm _OFFEN  : MUBUF_m <op, name#"_offen", (outs regClass:$vdata),
1936                            (ins VGPR_32:$vaddr, SReg_128:$srsrc,
1937                            SCSrc_32:$soffset, mbuf_offset:$offset, glc:$glc, slc:$slc,
1938                            tfe:$tfe),
1939                            name#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1940     }
1941
1942     let offen = 0, idxen = 1 in {
1943       defm _IDXEN  : MUBUF_m <op, name#"_idxen", (outs regClass:$vdata),
1944                            (ins VGPR_32:$vaddr, SReg_128:$srsrc,
1945                            SCSrc_32:$soffset, mbuf_offset:$offset, glc:$glc,
1946                            slc:$slc, tfe:$tfe),
1947                            name#" $vdata, $vaddr, $srsrc, $soffset idxen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1948     }
1949
1950     let offen = 1, idxen = 1 in {
1951       defm _BOTHEN : MUBUF_m <op, name#"_bothen", (outs regClass:$vdata),
1952                            (ins VReg_64:$vaddr, SReg_128:$srsrc, SCSrc_32:$soffset,
1953                            mbuf_offset:$offset, glc:$glc, slc:$slc, tfe:$tfe),
1954                            name#" $vdata, $vaddr, $srsrc, $soffset idxen offen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1955     }
1956
1957     let offen = 0, idxen = 0 in {
1958       defm _ADDR64 : MUBUFAddr64_m <op, name#"_addr64", (outs regClass:$vdata),
1959                            (ins VReg_64:$vaddr, SReg_128:$srsrc,
1960                                 SCSrc_32:$soffset, mbuf_offset:$offset,
1961                                 glc:$glc, slc:$slc, tfe:$tfe),
1962                            name#" $vdata, $vaddr, $srsrc, $soffset addr64"#"$offset"#
1963                                 "$glc"#"$slc"#"$tfe",
1964                            [(set load_vt:$vdata, (ld (MUBUFAddr64 v4i32:$srsrc,
1965                                                   i64:$vaddr, i32:$soffset,
1966                                                   i16:$offset, i1:$glc, i1:$slc,
1967                                                   i1:$tfe)))]>;
1968     }
1969   }
1970 }
1971
1972 multiclass MUBUF_Store_Helper <mubuf op, string name, RegisterClass vdataClass,
1973                           ValueType store_vt = i32, SDPatternOperator st = null_frag> {
1974   let mayLoad = 0, mayStore = 1 in {
1975     defm : MUBUF_m <op, name, (outs),
1976                     (ins vdataClass:$vdata, VGPR_32:$vaddr, SReg_128:$srsrc, SCSrc_32:$soffset,
1977                     mbuf_offset:$offset, offen:$offen, idxen:$idxen, glc:$glc, slc:$slc,
1978                     tfe:$tfe),
1979                     name#" $vdata, $vaddr, $srsrc, $soffset"#"$offen"#"$idxen"#"$offset"#
1980                          "$glc"#"$slc"#"$tfe", []>;
1981
1982     let offen = 0, idxen = 0, vaddr = 0 in {
1983       defm _OFFSET : MUBUF_m <op, name#"_offset",(outs),
1984                               (ins vdataClass:$vdata, SReg_128:$srsrc, SCSrc_32:$soffset,
1985                               mbuf_offset:$offset, glc:$glc, slc:$slc, tfe:$tfe),
1986                               name#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1987                               [(st store_vt:$vdata, (MUBUFOffset v4i32:$srsrc, i32:$soffset,
1988                                    i16:$offset, i1:$glc, i1:$slc, i1:$tfe))]>;
1989     } // offen = 0, idxen = 0, vaddr = 0
1990
1991     let offen = 1, idxen = 0  in {
1992       defm _OFFEN : MUBUF_m <op, name#"_offen", (outs),
1993                              (ins vdataClass:$vdata, VGPR_32:$vaddr, SReg_128:$srsrc,
1994                               SCSrc_32:$soffset, mbuf_offset:$offset, glc:$glc,
1995                               slc:$slc, tfe:$tfe),
1996                              name#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#
1997                              "$glc"#"$slc"#"$tfe", []>;
1998     } // end offen = 1, idxen = 0
1999
2000     let offen = 0, idxen = 1 in {
2001       defm _IDXEN  : MUBUF_m <op, name#"_idxen", (outs),
2002                            (ins vdataClass:$vdata, VGPR_32:$vaddr, SReg_128:$srsrc,
2003                            SCSrc_32:$soffset, mbuf_offset:$offset, glc:$glc,
2004                            slc:$slc, tfe:$tfe),
2005                            name#" $vdata, $vaddr, $srsrc, $soffset idxen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
2006     }
2007
2008     let offen = 1, idxen = 1 in {
2009       defm _BOTHEN : MUBUF_m <op, name#"_bothen", (outs),
2010                            (ins vdataClass:$vdata, VReg_64:$vaddr, SReg_128:$srsrc, SCSrc_32:$soffset,
2011                            mbuf_offset:$offset, glc:$glc, slc:$slc, tfe:$tfe),
2012                            name#" $vdata, $vaddr, $srsrc, $soffset idxen offen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
2013     }
2014
2015     let offen = 0, idxen = 0 in {
2016       defm _ADDR64 : MUBUFAddr64_m <op, name#"_addr64", (outs),
2017                                     (ins vdataClass:$vdata, VReg_64:$vaddr, SReg_128:$srsrc,
2018                                          SCSrc_32:$soffset,
2019                                          mbuf_offset:$offset, glc:$glc, slc:$slc,
2020                                          tfe:$tfe),
2021                                     name#" $vdata, $vaddr, $srsrc, $soffset addr64"#
2022                                          "$offset"#"$glc"#"$slc"#"$tfe",
2023                                     [(st store_vt:$vdata,
2024                                       (MUBUFAddr64 v4i32:$srsrc, i64:$vaddr,
2025                                                    i32:$soffset, i16:$offset,
2026                                                    i1:$glc, i1:$slc, i1:$tfe))]>;
2027     }
2028   } // End mayLoad = 0, mayStore = 1
2029 }
2030
2031 class FLAT_Load_Helper <bits<7> op, string asm, RegisterClass regClass> :
2032       FLAT <op, (outs regClass:$vdst),
2033                 (ins VReg_64:$addr),
2034             asm#" $vdst, $addr, [M0, FLAT_SCRATCH]", []> {
2035   let glc = 0;
2036   let slc = 0;
2037   let tfe = 0;
2038   let data = 0;
2039   let mayLoad = 1;
2040 }
2041
2042 class FLAT_Store_Helper <bits<7> op, string name, RegisterClass vdataClass> :
2043       FLAT <op, (outs), (ins vdataClass:$data, VReg_64:$addr),
2044           name#" $data, $addr, [M0, FLAT_SCRATCH]",
2045          []> {
2046
2047   let mayLoad = 0;
2048   let mayStore = 1;
2049
2050   // Encoding
2051   let glc = 0;
2052   let slc = 0;
2053   let tfe = 0;
2054   let vdst = 0;
2055 }
2056
2057 class MIMG_Mask <string op, int channels> {
2058   string Op = op;
2059   int Channels = channels;
2060 }
2061
2062 class MIMG_NoSampler_Helper <bits<7> op, string asm,
2063                              RegisterClass dst_rc,
2064                              RegisterClass src_rc> : MIMG <
2065   op,
2066   (outs dst_rc:$vdata),
2067   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
2068        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
2069        SReg_256:$srsrc),
2070   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
2071      #" $tfe, $lwe, $slc, $vaddr, $srsrc",
2072   []> {
2073   let ssamp = 0;
2074   let mayLoad = 1;
2075   let mayStore = 0;
2076   let hasPostISelHook = 1;
2077 }
2078
2079 multiclass MIMG_NoSampler_Src_Helper <bits<7> op, string asm,
2080                                       RegisterClass dst_rc,
2081                                       int channels> {
2082   def _V1 : MIMG_NoSampler_Helper <op, asm, dst_rc, VGPR_32>,
2083             MIMG_Mask<asm#"_V1", channels>;
2084   def _V2 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_64>,
2085             MIMG_Mask<asm#"_V2", channels>;
2086   def _V4 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_128>,
2087             MIMG_Mask<asm#"_V4", channels>;
2088 }
2089
2090 multiclass MIMG_NoSampler <bits<7> op, string asm> {
2091   defm _V1 : MIMG_NoSampler_Src_Helper <op, asm, VGPR_32, 1>;
2092   defm _V2 : MIMG_NoSampler_Src_Helper <op, asm, VReg_64, 2>;
2093   defm _V3 : MIMG_NoSampler_Src_Helper <op, asm, VReg_96, 3>;
2094   defm _V4 : MIMG_NoSampler_Src_Helper <op, asm, VReg_128, 4>;
2095 }
2096
2097 class MIMG_Sampler_Helper <bits<7> op, string asm,
2098                            RegisterClass dst_rc,
2099                            RegisterClass src_rc, int wqm> : MIMG <
2100   op,
2101   (outs dst_rc:$vdata),
2102   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
2103        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
2104        SReg_256:$srsrc, SReg_128:$ssamp),
2105   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
2106      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
2107   []> {
2108   let mayLoad = 1;
2109   let mayStore = 0;
2110   let hasPostISelHook = 1;
2111   let WQM = wqm;
2112 }
2113
2114 multiclass MIMG_Sampler_Src_Helper <bits<7> op, string asm,
2115                                     RegisterClass dst_rc,
2116                                     int channels, int wqm> {
2117   def _V1 : MIMG_Sampler_Helper <op, asm, dst_rc, VGPR_32, wqm>,
2118             MIMG_Mask<asm#"_V1", channels>;
2119   def _V2 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_64, wqm>,
2120             MIMG_Mask<asm#"_V2", channels>;
2121   def _V4 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_128, wqm>,
2122             MIMG_Mask<asm#"_V4", channels>;
2123   def _V8 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_256, wqm>,
2124             MIMG_Mask<asm#"_V8", channels>;
2125   def _V16 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_512, wqm>,
2126             MIMG_Mask<asm#"_V16", channels>;
2127 }
2128
2129 multiclass MIMG_Sampler <bits<7> op, string asm> {
2130   defm _V1 : MIMG_Sampler_Src_Helper<op, asm, VGPR_32, 1, 0>;
2131   defm _V2 : MIMG_Sampler_Src_Helper<op, asm, VReg_64, 2, 0>;
2132   defm _V3 : MIMG_Sampler_Src_Helper<op, asm, VReg_96, 3, 0>;
2133   defm _V4 : MIMG_Sampler_Src_Helper<op, asm, VReg_128, 4, 0>;
2134 }
2135
2136 multiclass MIMG_Sampler_WQM <bits<7> op, string asm> {
2137   defm _V1 : MIMG_Sampler_Src_Helper<op, asm, VGPR_32, 1, 1>;
2138   defm _V2 : MIMG_Sampler_Src_Helper<op, asm, VReg_64, 2, 1>;
2139   defm _V3 : MIMG_Sampler_Src_Helper<op, asm, VReg_96, 3, 1>;
2140   defm _V4 : MIMG_Sampler_Src_Helper<op, asm, VReg_128, 4, 1>;
2141 }
2142
2143 class MIMG_Gather_Helper <bits<7> op, string asm,
2144                           RegisterClass dst_rc,
2145                           RegisterClass src_rc, int wqm> : MIMG <
2146   op,
2147   (outs dst_rc:$vdata),
2148   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
2149        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
2150        SReg_256:$srsrc, SReg_128:$ssamp),
2151   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
2152      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
2153   []> {
2154   let mayLoad = 1;
2155   let mayStore = 0;
2156
2157   // DMASK was repurposed for GATHER4. 4 components are always
2158   // returned and DMASK works like a swizzle - it selects
2159   // the component to fetch. The only useful DMASK values are
2160   // 1=red, 2=green, 4=blue, 8=alpha. (e.g. 1 returns
2161   // (red,red,red,red) etc.) The ISA document doesn't mention
2162   // this.
2163   // Therefore, disable all code which updates DMASK by setting these two:
2164   let MIMG = 0;
2165   let hasPostISelHook = 0;
2166   let WQM = wqm;
2167 }
2168
2169 multiclass MIMG_Gather_Src_Helper <bits<7> op, string asm,
2170                                     RegisterClass dst_rc,
2171                                     int channels, int wqm> {
2172   def _V1 : MIMG_Gather_Helper <op, asm, dst_rc, VGPR_32, wqm>,
2173             MIMG_Mask<asm#"_V1", channels>;
2174   def _V2 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_64, wqm>,
2175             MIMG_Mask<asm#"_V2", channels>;
2176   def _V4 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_128, wqm>,
2177             MIMG_Mask<asm#"_V4", channels>;
2178   def _V8 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_256, wqm>,
2179             MIMG_Mask<asm#"_V8", channels>;
2180   def _V16 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_512, wqm>,
2181             MIMG_Mask<asm#"_V16", channels>;
2182 }
2183
2184 multiclass MIMG_Gather <bits<7> op, string asm> {
2185   defm _V1 : MIMG_Gather_Src_Helper<op, asm, VGPR_32, 1, 0>;
2186   defm _V2 : MIMG_Gather_Src_Helper<op, asm, VReg_64, 2, 0>;
2187   defm _V3 : MIMG_Gather_Src_Helper<op, asm, VReg_96, 3, 0>;
2188   defm _V4 : MIMG_Gather_Src_Helper<op, asm, VReg_128, 4, 0>;
2189 }
2190
2191 multiclass MIMG_Gather_WQM <bits<7> op, string asm> {
2192   defm _V1 : MIMG_Gather_Src_Helper<op, asm, VGPR_32, 1, 1>;
2193   defm _V2 : MIMG_Gather_Src_Helper<op, asm, VReg_64, 2, 1>;
2194   defm _V3 : MIMG_Gather_Src_Helper<op, asm, VReg_96, 3, 1>;
2195   defm _V4 : MIMG_Gather_Src_Helper<op, asm, VReg_128, 4, 1>;
2196 }
2197
2198 //===----------------------------------------------------------------------===//
2199 // Vector instruction mappings
2200 //===----------------------------------------------------------------------===//
2201
2202 // Maps an opcode in e32 form to its e64 equivalent
2203 def getVOPe64 : InstrMapping {
2204   let FilterClass = "VOP";
2205   let RowFields = ["OpName"];
2206   let ColFields = ["Size"];
2207   let KeyCol = ["4"];
2208   let ValueCols = [["8"]];
2209 }
2210
2211 // Maps an opcode in e64 form to its e32 equivalent
2212 def getVOPe32 : InstrMapping {
2213   let FilterClass = "VOP";
2214   let RowFields = ["OpName"];
2215   let ColFields = ["Size"];
2216   let KeyCol = ["8"];
2217   let ValueCols = [["4"]];
2218 }
2219
2220 def getMaskedMIMGOp : InstrMapping {
2221   let FilterClass = "MIMG_Mask";
2222   let RowFields = ["Op"];
2223   let ColFields = ["Channels"];
2224   let KeyCol = ["4"];
2225   let ValueCols = [["1"], ["2"], ["3"] ];
2226 }
2227
2228 // Maps an commuted opcode to its original version
2229 def getCommuteOrig : InstrMapping {
2230   let FilterClass = "VOP2_REV";
2231   let RowFields = ["RevOp"];
2232   let ColFields = ["IsOrig"];
2233   let KeyCol = ["0"];
2234   let ValueCols = [["1"]];
2235 }
2236
2237 // Maps an original opcode to its commuted version
2238 def getCommuteRev : InstrMapping {
2239   let FilterClass = "VOP2_REV";
2240   let RowFields = ["RevOp"];
2241   let ColFields = ["IsOrig"];
2242   let KeyCol = ["1"];
2243   let ValueCols = [["0"]];
2244 }
2245
2246 def getCommuteCmpOrig : InstrMapping {
2247   let FilterClass = "VOPC_REV";
2248   let RowFields = ["RevOp"];
2249   let ColFields = ["IsOrig"];
2250   let KeyCol = ["0"];
2251   let ValueCols = [["1"]];
2252 }
2253
2254 // Maps an original opcode to its commuted version
2255 def getCommuteCmpRev : InstrMapping {
2256   let FilterClass = "VOPC_REV";
2257   let RowFields = ["RevOp"];
2258   let ColFields = ["IsOrig"];
2259   let KeyCol = ["1"];
2260   let ValueCols = [["0"]];
2261 }
2262
2263
2264 def getMCOpcodeGen : InstrMapping {
2265   let FilterClass = "SIMCInstr";
2266   let RowFields = ["PseudoInstr"];
2267   let ColFields = ["Subtarget"];
2268   let KeyCol = [!cast<string>(SISubtarget.NONE)];
2269   let ValueCols = [[!cast<string>(SISubtarget.SI)],[!cast<string>(SISubtarget.VI)]];
2270 }
2271
2272 def getAddr64Inst : InstrMapping {
2273   let FilterClass = "MUBUFAddr64Table";
2274   let RowFields = ["OpName"];
2275   let ColFields = ["IsAddr64"];
2276   let KeyCol = ["0"];
2277   let ValueCols = [["1"]];
2278 }
2279
2280 // Maps an atomic opcode to its version with a return value.
2281 def getAtomicRetOp : InstrMapping {
2282   let FilterClass = "AtomicNoRet";
2283   let RowFields = ["NoRetOp"];
2284   let ColFields = ["IsRet"];
2285   let KeyCol = ["0"];
2286   let ValueCols = [["1"]];
2287 }
2288
2289 // Maps an atomic opcode to its returnless version.
2290 def getAtomicNoRetOp : InstrMapping {
2291   let FilterClass = "AtomicNoRet";
2292   let RowFields = ["NoRetOp"];
2293   let ColFields = ["IsRet"];
2294   let KeyCol = ["1"];
2295   let ValueCols = [["0"]];
2296 }
2297
2298 include "SIInstructions.td"
2299 include "CIInstructions.td"
2300 include "VIInstructions.td"