lib/Target/R600/SIInstrInfo.td

   1 //===-- SIInstrInfo.td - SI Instruction Infos -------------*- tablegen -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 class vop {
  11   field bits<9> SI3;
  12   field bits<10> VI3;
  13 }
  14
  15 class vopc <bits<8> si, bits<8> vi = !add(0x40, si)> : vop {
  16   field bits<8> SI = si;
  17   field bits<8> VI = vi;
  18
  19   field bits<9>  SI3 = {0, si{7-0}};
  20   field bits<10> VI3 = {0, 0, vi{7-0}};
  21 }
  22
  23 class vop1 <bits<8> si, bits<8> vi = si> : vop {
  24   field bits<8> SI = si;
  25   field bits<8> VI = vi;
  26
  27   field bits<9>  SI3 = {1, 1, si{6-0}};
  28   field bits<10> VI3 = !add(0x140, vi);
  29 }
  30
  31 class vop2 <bits<6> si, bits<6> vi = si> : vop {
  32   field bits<6> SI = si;
  33   field bits<6> VI = vi;
  34
  35   field bits<9>  SI3 = {1, 0, 0, si{5-0}};
  36   field bits<10> VI3 = {0, 1, 0, 0, vi{5-0}};
  37 }
  38
  39 // Specify a VOP2 opcode for SI and VOP3 opcode for VI
  40 // that doesn't have VOP2 encoding on VI
  41 class vop23 <bits<6> si, bits<10> vi> : vop2 <si> {
  42   let VI3 = vi;
  43 }
  44
  45 class vop3 <bits<9> si, bits<10> vi = {0, si}> : vop {
  46   let SI3 = si;
  47   let VI3 = vi;
  48 }
  49
  50 class sop1 <bits<8> si, bits<8> vi = si> {
  51   field bits<8> SI = si;
  52   field bits<8> VI = vi;
  53 }
  54
  55 class sop2 <bits<7> si, bits<7> vi = si> {
  56   field bits<7> SI = si;
  57   field bits<7> VI = vi;
  58 }
  59
  60 class sopk <bits<5> si, bits<5> vi = si> {
  61   field bits<5> SI = si;
  62   field bits<5> VI = vi;
  63 }
  64
  65 // Execpt for the NONE field, this must be kept in sync with the SISubtarget enum
  66 // in AMDGPUInstrInfo.cpp
  67 def SISubtarget {
  68   int NONE = -1;
  69   int SI = 0;
  70   int VI = 1;
  71 }
  72
  73 //===----------------------------------------------------------------------===//
  74 // SI DAG Nodes
  75 //===----------------------------------------------------------------------===//
  76
  77 def SIload_constant : SDNode<"AMDGPUISD::LOAD_CONSTANT",
  78   SDTypeProfile<1, 2, [SDTCisVT<0, f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i32>]>,
  79                       [SDNPMayLoad, SDNPMemOperand]
  80 >;
  81
  82 def SItbuffer_store : SDNode<"AMDGPUISD::TBUFFER_STORE_FORMAT",
  83   SDTypeProfile<0, 13,
  84     [SDTCisVT<0, v4i32>,   // rsrc(SGPR)
  85      SDTCisVT<1, iAny>,   // vdata(VGPR)
  86      SDTCisVT<2, i32>,    // num_channels(imm)
  87      SDTCisVT<3, i32>,    // vaddr(VGPR)
  88      SDTCisVT<4, i32>,    // soffset(SGPR)
  89      SDTCisVT<5, i32>,    // inst_offset(imm)
  90      SDTCisVT<6, i32>,    // dfmt(imm)
  91      SDTCisVT<7, i32>,    // nfmt(imm)
  92      SDTCisVT<8, i32>,    // offen(imm)
  93      SDTCisVT<9, i32>,    // idxen(imm)
  94      SDTCisVT<10, i32>,   // glc(imm)
  95      SDTCisVT<11, i32>,   // slc(imm)
  96      SDTCisVT<12, i32>    // tfe(imm)
  97     ]>,
  98   [SDNPMayStore, SDNPMemOperand, SDNPHasChain]
  99 >;
 100
 101 def SIload_input : SDNode<"AMDGPUISD::LOAD_INPUT",
 102   SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i16>,
 103                        SDTCisVT<3, i32>]>
 104 >;
 105
 106 class SDSample<string opcode> : SDNode <opcode,
 107   SDTypeProfile<1, 4, [SDTCisVT<0, v4f32>, SDTCisVT<2, v32i8>,
 108                        SDTCisVT<3, v4i32>, SDTCisVT<4, i32>]>
 109 >;
 110
 111 def SIsample : SDSample<"AMDGPUISD::SAMPLE">;
 112 def SIsampleb : SDSample<"AMDGPUISD::SAMPLEB">;
 113 def SIsampled : SDSample<"AMDGPUISD::SAMPLED">;
 114 def SIsamplel : SDSample<"AMDGPUISD::SAMPLEL">;
 115
 116 def SIconstdata_ptr : SDNode<
 117   "AMDGPUISD::CONST_DATA_PTR", SDTypeProfile <1, 0, [SDTCisVT<0, i64>]>
 118 >;
 119
 120 // Transformation function, extract the lower 32bit of a 64bit immediate
 121 def LO32 : SDNodeXForm<imm, [{
 122   return CurDAG->getTargetConstant(N->getZExtValue() & 0xffffffff, MVT::i32);
 123 }]>;
 124
 125 def LO32f : SDNodeXForm<fpimm, [{
 126   APInt V = N->getValueAPF().bitcastToAPInt().trunc(32);
 127   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
 128 }]>;
 129
 130 // Transformation function, extract the upper 32bit of a 64bit immediate
 131 def HI32 : SDNodeXForm<imm, [{
 132   return CurDAG->getTargetConstant(N->getZExtValue() >> 32, MVT::i32);
 133 }]>;
 134
 135 def HI32f : SDNodeXForm<fpimm, [{
 136   APInt V = N->getValueAPF().bitcastToAPInt().lshr(32).trunc(32);
 137   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
 138 }]>;
 139
 140 def IMM8bitDWORD : PatLeaf <(imm),
 141   [{return (N->getZExtValue() & ~0x3FC) == 0;}]
 142 >;
 143
 144 def as_dword_i32imm : SDNodeXForm<imm, [{
 145   return CurDAG->getTargetConstant(N->getZExtValue() >> 2, MVT::i32);
 146 }]>;
 147
 148 def as_i1imm : SDNodeXForm<imm, [{
 149   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i1);
 150 }]>;
 151
 152 def as_i8imm : SDNodeXForm<imm, [{
 153   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i8);
 154 }]>;
 155
 156 def as_i16imm : SDNodeXForm<imm, [{
 157   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i16);
 158 }]>;
 159
 160 def as_i32imm: SDNodeXForm<imm, [{
 161   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i32);
 162 }]>;
 163
 164 def as_i64imm: SDNodeXForm<imm, [{
 165   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i64);
 166 }]>;
 167
 168 // Copied from the AArch64 backend:
 169 def bitcast_fpimm_to_i32 : SDNodeXForm<fpimm, [{
 170 return CurDAG->getTargetConstant(
 171   N->getValueAPF().bitcastToAPInt().getZExtValue(), MVT::i32);
 172 }]>;
 173
 174 // Copied from the AArch64 backend:
 175 def bitcast_fpimm_to_i64 : SDNodeXForm<fpimm, [{
 176 return CurDAG->getTargetConstant(
 177   N->getValueAPF().bitcastToAPInt().getZExtValue(), MVT::i64);
 178 }]>;
 179
 180 def IMM8bit : PatLeaf <(imm),
 181   [{return isUInt<8>(N->getZExtValue());}]
 182 >;
 183
 184 def IMM12bit : PatLeaf <(imm),
 185   [{return isUInt<12>(N->getZExtValue());}]
 186 >;
 187
 188 def IMM16bit : PatLeaf <(imm),
 189   [{return isUInt<16>(N->getZExtValue());}]
 190 >;
 191
 192 def IMM20bit : PatLeaf <(imm),
 193   [{return isUInt<20>(N->getZExtValue());}]
 194 >;
 195
 196 def IMM32bit : PatLeaf <(imm),
 197   [{return isUInt<32>(N->getZExtValue());}]
 198 >;
 199
 200 def mubuf_vaddr_offset : PatFrag<
 201   (ops node:$ptr, node:$offset, node:$imm_offset),
 202   (add (add node:$ptr, node:$offset), node:$imm_offset)
 203 >;
 204
 205 class InlineImm <ValueType vt> : PatLeaf <(vt imm), [{
 206   return isInlineImmediate(N);
 207 }]>;
 208
 209 class InlineFPImm <ValueType vt> : PatLeaf <(vt fpimm), [{
 210   return isInlineImmediate(N);
 211 }]>;
 212
 213 class SGPRImm <dag frag> : PatLeaf<frag, [{
 214   if (Subtarget->getGeneration() < AMDGPUSubtarget::SOUTHERN_ISLANDS) {
 215     return false;
 216   }
 217   const SIRegisterInfo *SIRI =
 218       static_cast<const SIRegisterInfo *>(Subtarget->getRegisterInfo());
 219   for (SDNode::use_iterator U = N->use_begin(), E = SDNode::use_end();
 220                                                 U != E; ++U) {
 221     if (SIRI->isSGPRClass(getOperandRegClass(*U, U.getOperandNo()))) {
 222       return true;
 223     }
 224   }
 225   return false;
 226 }]>;
 227
 228 //===----------------------------------------------------------------------===//
 229 // Custom Operands
 230 //===----------------------------------------------------------------------===//
 231
 232 def FRAMEri32 : Operand<iPTR> {
 233   let MIOperandInfo = (ops i32:$ptr, i32imm:$index);
 234 }
 235
 236 def sopp_brtarget : Operand<OtherVT> {
 237   let EncoderMethod = "getSOPPBrEncoding";
 238   let OperandType = "OPERAND_PCREL";
 239 }
 240
 241 include "SIInstrFormats.td"
 242 include "VIInstrFormats.td"
 243
 244 let OperandType = "OPERAND_IMMEDIATE" in {
 245
 246 def offen : Operand<i1> {
 247   let PrintMethod = "printOffen";
 248 }
 249 def idxen : Operand<i1> {
 250   let PrintMethod = "printIdxen";
 251 }
 252 def addr64 : Operand<i1> {
 253   let PrintMethod = "printAddr64";
 254 }
 255 def mbuf_offset : Operand<i16> {
 256   let PrintMethod = "printMBUFOffset";
 257 }
 258 def ds_offset : Operand<i16> {
 259   let PrintMethod = "printDSOffset";
 260 }
 261 def ds_offset0 : Operand<i8> {
 262   let PrintMethod = "printDSOffset0";
 263 }
 264 def ds_offset1 : Operand<i8> {
 265   let PrintMethod = "printDSOffset1";
 266 }
 267 def glc : Operand <i1> {
 268   let PrintMethod = "printGLC";
 269 }
 270 def slc : Operand <i1> {
 271   let PrintMethod = "printSLC";
 272 }
 273 def tfe : Operand <i1> {
 274   let PrintMethod = "printTFE";
 275 }
 276
 277 def omod : Operand <i32> {
 278   let PrintMethod = "printOModSI";
 279 }
 280
 281 def ClampMod : Operand <i1> {
 282   let PrintMethod = "printClampSI";
 283 }
 284
 285 } // End OperandType = "OPERAND_IMMEDIATE"
 286
 287 //===----------------------------------------------------------------------===//
 288 // Complex patterns
 289 //===----------------------------------------------------------------------===//
 290
 291 def DS1Addr1Offset : ComplexPattern<i32, 2, "SelectDS1Addr1Offset">;
 292 def DS64Bit4ByteAligned : ComplexPattern<i32, 3, "SelectDS64Bit4ByteAligned">;
 293
 294 def MUBUFAddr32 : ComplexPattern<i64, 9, "SelectMUBUFAddr32">;
 295 def MUBUFAddr64 : ComplexPattern<i64, 4, "SelectMUBUFAddr64">;
 296 def MUBUFAddr64Atomic : ComplexPattern<i64, 5, "SelectMUBUFAddr64">;
 297 def MUBUFScratch : ComplexPattern<i64, 4, "SelectMUBUFScratch">;
 298 def MUBUFOffset : ComplexPattern<i64, 6, "SelectMUBUFOffset">;
 299 def MUBUFOffsetAtomic : ComplexPattern<i64, 4, "SelectMUBUFOffset">;
 300
 301 def VOP3Mods0 : ComplexPattern<untyped, 4, "SelectVOP3Mods0">;
 302 def VOP3Mods0Clamp : ComplexPattern<untyped, 3, "SelectVOP3Mods0Clamp">;
 303 def VOP3Mods0Clamp0OMod : ComplexPattern<untyped, 4, "SelectVOP3Mods0Clamp0OMod">;
 304 def VOP3Mods  : ComplexPattern<untyped, 2, "SelectVOP3Mods">;
 305
 306 //===----------------------------------------------------------------------===//
 307 // SI assembler operands
 308 //===----------------------------------------------------------------------===//
 309
 310 def SIOperand {
 311   int ZERO = 0x80;
 312   int VCC = 0x6A;
 313   int FLAT_SCR = 0x68;
 314 }
 315
 316 def SRCMODS {
 317   int NONE = 0;
 318 }
 319
 320 def DSTCLAMP {
 321   int NONE = 0;
 322 }
 323
 324 def DSTOMOD {
 325   int NONE = 0;
 326 }
 327
 328 //===----------------------------------------------------------------------===//
 329 //
 330 // SI Instruction multiclass helpers.
 331 //
 332 // Instructions with _32 take 32-bit operands.
 333 // Instructions with _64 take 64-bit operands.
 334 //
 335 // VOP_* instructions can use either a 32-bit or 64-bit encoding.  The 32-bit
 336 // encoding is the standard encoding, but instruction that make use of
 337 // any of the instruction modifiers must use the 64-bit encoding.
 338 //
 339 // Instructions with _e32 use the 32-bit encoding.
 340 // Instructions with _e64 use the 64-bit encoding.
 341 //
 342 //===----------------------------------------------------------------------===//
 343
 344 class SIMCInstr <string pseudo, int subtarget> {
 345   string PseudoInstr = pseudo;
 346   int Subtarget = subtarget;
 347 }
 348
 349 //===----------------------------------------------------------------------===//
 350 // EXP classes
 351 //===----------------------------------------------------------------------===//
 352
 353 class EXPCommon : InstSI<
 354   (outs),
 355   (ins i32imm:$en, i32imm:$tgt, i32imm:$compr, i32imm:$done, i32imm:$vm,
 356        VGPR_32:$src0, VGPR_32:$src1, VGPR_32:$src2, VGPR_32:$src3),
 357   "exp $en, $tgt, $compr, $done, $vm, $src0, $src1, $src2, $src3",
 358   [] > {
 359
 360   let EXP_CNT = 1;
 361   let Uses = [EXEC];
 362 }
 363
 364 multiclass EXP_m {
 365
 366   let isPseudo = 1 in {
 367     def "" : EXPCommon, SIMCInstr <"exp", SISubtarget.NONE> ;
 368   }
 369
 370   def _si : EXPCommon, SIMCInstr <"exp", SISubtarget.SI>, EXPe;
 371
 372   def _vi : EXPCommon, SIMCInstr <"exp", SISubtarget.VI>, EXPe_vi;
 373 }
 374
 375 //===----------------------------------------------------------------------===//
 376 // Scalar classes
 377 //===----------------------------------------------------------------------===//
 378
 379 class SOP1_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 380   SOP1 <outs, ins, "", pattern>,
 381   SIMCInstr<opName, SISubtarget.NONE> {
 382   let isPseudo = 1;
 383 }
 384
 385 class SOP1_Real_si <sop1 op, string opName, dag outs, dag ins, string asm> :
 386   SOP1 <outs, ins, asm, []>,
 387   SOP1e <op.SI>,
 388   SIMCInstr<opName, SISubtarget.SI>;
 389
 390 class SOP1_Real_vi <sop1 op, string opName, dag outs, dag ins, string asm> :
 391   SOP1 <outs, ins, asm, []>,
 392   SOP1e <op.VI>,
 393   SIMCInstr<opName, SISubtarget.VI>;
 394
 395 multiclass SOP1_m <sop1 op, string opName, dag outs, dag ins, string asm,
 396                    list<dag> pattern> {
 397
 398   def "" : SOP1_Pseudo <opName, outs, ins, pattern>;
 399
 400   def _si : SOP1_Real_si <op, opName, outs, ins, asm>;
 401
 402   def _vi : SOP1_Real_vi <op, opName, outs, ins, asm>;
 403
 404 }
 405
 406 multiclass SOP1_32 <sop1 op, string opName, list<dag> pattern> : SOP1_m <
 407     op, opName, (outs SReg_32:$dst), (ins SSrc_32:$src0),
 408     opName#" $dst, $src0", pattern
 409 >;
 410
 411 multiclass SOP1_64 <sop1 op, string opName, list<dag> pattern> : SOP1_m <
 412     op, opName, (outs SReg_64:$dst), (ins SSrc_64:$src0),
 413     opName#" $dst, $src0", pattern
 414 >;
 415
 416 // no input, 64-bit output.
 417 multiclass SOP1_64_0 <sop1 op, string opName, list<dag> pattern> {
 418   def "" : SOP1_Pseudo <opName, (outs SReg_64:$dst), (ins), pattern>;
 419
 420   def _si : SOP1_Real_si <op, opName, (outs SReg_64:$dst), (ins),
 421     opName#" $dst"> {
 422     let SSRC0 = 0;
 423   }
 424
 425   def _vi : SOP1_Real_vi <op, opName, (outs SReg_64:$dst), (ins),
 426     opName#" $dst"> {
 427     let SSRC0 = 0;
 428   }
 429 }
 430
 431 // 64-bit input, 32-bit output.
 432 multiclass SOP1_32_64 <sop1 op, string opName, list<dag> pattern> : SOP1_m <
 433     op, opName, (outs SReg_32:$dst), (ins SSrc_64:$src0),
 434     opName#" $dst, $src0", pattern
 435 >;
 436
 437 class SOP2_Pseudo<string opName, dag outs, dag ins, list<dag> pattern> :
 438   SOP2<outs, ins, "", pattern>,
 439   SIMCInstr<opName, SISubtarget.NONE> {
 440   let isPseudo = 1;
 441   let Size = 4;
 442 }
 443
 444 class SOP2_Real_si<sop2 op, string opName, dag outs, dag ins, string asm> :
 445   SOP2<outs, ins, asm, []>,
 446   SOP2e<op.SI>,
 447   SIMCInstr<opName, SISubtarget.SI>;
 448
 449 class SOP2_Real_vi<sop2 op, string opName, dag outs, dag ins, string asm> :
 450   SOP2<outs, ins, asm, []>,
 451   SOP2e<op.VI>,
 452   SIMCInstr<opName, SISubtarget.VI>;
 453
 454 multiclass SOP2_SELECT_32 <sop2 op, string opName, list<dag> pattern> {
 455   def "" : SOP2_Pseudo <opName, (outs SReg_32:$dst),
 456     (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc), pattern>;
 457
 458   def _si : SOP2_Real_si <op, opName, (outs SReg_32:$dst),
 459     (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc),
 460     opName#" $dst, $src0, $src1 [$scc]">;
 461
 462   def _vi : SOP2_Real_vi <op, opName, (outs SReg_32:$dst),
 463     (ins SSrc_32:$src0, SSrc_32:$src1, SCCReg:$scc),
 464     opName#" $dst, $src0, $src1 [$scc]">;
 465 }
 466
 467 multiclass SOP2_32 <sop2 op, string opName, list<dag> pattern> {
 468   def "" : SOP2_Pseudo <opName, (outs SReg_32:$dst),
 469     (ins SSrc_32:$src0, SSrc_32:$src1), pattern>;
 470
 471   def _si : SOP2_Real_si <op, opName, (outs SReg_32:$dst),
 472     (ins SSrc_32:$src0, SSrc_32:$src1), opName#" $dst, $src0, $src1">;
 473
 474   def _vi : SOP2_Real_vi <op, opName, (outs SReg_32:$dst),
 475     (ins SSrc_32:$src0, SSrc_32:$src1), opName#" $dst, $src0, $src1">;
 476 }
 477
 478 multiclass SOP2_64 <sop2 op, string opName, list<dag> pattern> {
 479   def "" : SOP2_Pseudo <opName, (outs SReg_64:$dst),
 480     (ins SSrc_64:$src0, SSrc_64:$src1), pattern>;
 481
 482   def _si : SOP2_Real_si <op, opName, (outs SReg_64:$dst),
 483     (ins SSrc_64:$src0, SSrc_64:$src1), opName#" $dst, $src0, $src1">;
 484
 485   def _vi : SOP2_Real_vi <op, opName, (outs SReg_64:$dst),
 486     (ins SSrc_64:$src0, SSrc_64:$src1), opName#" $dst, $src0, $src1">;
 487 }
 488
 489 multiclass SOP2_64_32 <sop2 op, string opName, list<dag> pattern> {
 490   def "" : SOP2_Pseudo <opName, (outs SReg_64:$dst),
 491     (ins SSrc_64:$src0, SSrc_32:$src1), pattern>;
 492
 493   def _si : SOP2_Real_si <op, opName, (outs SReg_64:$dst),
 494     (ins SSrc_64:$src0, SSrc_32:$src1), opName#" $dst, $src0, $src1">;
 495
 496   def _vi : SOP2_Real_vi <op, opName, (outs SReg_64:$dst),
 497     (ins SSrc_64:$src0, SSrc_32:$src1), opName#" $dst, $src0, $src1">;
 498 }
 499
 500
 501 class SOPC_Helper <bits<7> op, RegisterOperand rc, ValueType vt,
 502                     string opName, PatLeaf cond> : SOPC <
 503   op, (outs SCCReg:$dst), (ins rc:$src0, rc:$src1),
 504   opName#" $dst, $src0, $src1", []>;
 505
 506 class SOPC_32<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 507   : SOPC_Helper<op, SSrc_32, i32, opName, cond>;
 508
 509 class SOPC_64<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 510   : SOPC_Helper<op, SSrc_64, i64, opName, cond>;
 511
 512 class SOPK_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 513   SOPK <outs, ins, "", pattern>,
 514   SIMCInstr<opName, SISubtarget.NONE> {
 515   let isPseudo = 1;
 516 }
 517
 518 class SOPK_Real_si <sopk op, string opName, dag outs, dag ins, string asm> :
 519   SOPK <outs, ins, asm, []>,
 520   SOPKe <op.SI>,
 521   SIMCInstr<opName, SISubtarget.SI>;
 522
 523 class SOPK_Real_vi <sopk op, string opName, dag outs, dag ins, string asm> :
 524   SOPK <outs, ins, asm, []>,
 525   SOPKe <op.VI>,
 526   SIMCInstr<opName, SISubtarget.VI>;
 527
 528 multiclass SOPK_32 <sopk op, string opName, list<dag> pattern> {
 529   def "" : SOPK_Pseudo <opName, (outs SReg_32:$dst), (ins u16imm:$src0),
 530     pattern>;
 531
 532   def _si : SOPK_Real_si <op, opName, (outs SReg_32:$dst), (ins u16imm:$src0),
 533     opName#" $dst, $src0">;
 534
 535   def _vi : SOPK_Real_vi <op, opName, (outs SReg_32:$dst), (ins u16imm:$src0),
 536     opName#" $dst, $src0">;
 537 }
 538
 539 multiclass SOPK_SCC <sopk op, string opName, list<dag> pattern> {
 540   def "" : SOPK_Pseudo <opName, (outs SCCReg:$dst),
 541     (ins SReg_32:$src0, u16imm:$src1), pattern>;
 542
 543   def _si : SOPK_Real_si <op, opName, (outs SCCReg:$dst),
 544     (ins SReg_32:$src0, u16imm:$src1), opName#" $dst, $src0">;
 545
 546   def _vi : SOPK_Real_vi <op, opName, (outs SCCReg:$dst),
 547     (ins SReg_32:$src0, u16imm:$src1), opName#" $dst, $src0">;
 548 }
 549
 550 //===----------------------------------------------------------------------===//
 551 // SMRD classes
 552 //===----------------------------------------------------------------------===//
 553
 554 class SMRD_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
 555   SMRD <outs, ins, "", pattern>,
 556   SIMCInstr<opName, SISubtarget.NONE> {
 557   let isPseudo = 1;
 558 }
 559
 560 class SMRD_Real_si <bits<5> op, string opName, bit imm, dag outs, dag ins,
 561                     string asm> :
 562   SMRD <outs, ins, asm, []>,
 563   SMRDe <op, imm>,
 564   SIMCInstr<opName, SISubtarget.SI>;
 565
 566 class SMRD_Real_vi <bits<8> op, string opName, bit imm, dag outs, dag ins,
 567                     string asm> :
 568   SMRD <outs, ins, asm, []>,
 569   SMEMe_vi <op, imm>,
 570   SIMCInstr<opName, SISubtarget.VI>;
 571
 572 multiclass SMRD_m <bits<5> op, string opName, bit imm, dag outs, dag ins,
 573                    string asm, list<dag> pattern> {
 574
 575   def "" : SMRD_Pseudo <opName, outs, ins, pattern>;
 576
 577   def _si : SMRD_Real_si <op, opName, imm, outs, ins, asm>;
 578
 579   // glc is only applicable to scalar stores, which are not yet
 580   // implemented.
 581   let glc = 0 in {
 582     def _vi : SMRD_Real_vi <{0, 0, 0, op}, opName, imm, outs, ins, asm>;
 583   }
 584 }
 585
 586 multiclass SMRD_Helper <bits<5> op, string opName, RegisterClass baseClass,
 587                         RegisterClass dstClass> {
 588   defm _IMM : SMRD_m <
 589     op, opName#"_IMM", 1, (outs dstClass:$dst),
 590     (ins baseClass:$sbase, u32imm:$offset),
 591     opName#" $dst, $sbase, $offset", []
 592   >;
 593
 594   defm _SGPR : SMRD_m <
 595     op, opName#"_SGPR", 0, (outs dstClass:$dst),
 596     (ins baseClass:$sbase, SReg_32:$soff),
 597     opName#" $dst, $sbase, $soff", []
 598   >;
 599 }
 600
 601 //===----------------------------------------------------------------------===//
 602 // Vector ALU classes
 603 //===----------------------------------------------------------------------===//
 604
 605 // This must always be right before the operand being input modified.
 606 def InputMods : OperandWithDefaultOps <i32, (ops (i32 0))> {
 607   let PrintMethod = "printOperandAndMods";
 608 }
 609 def InputModsNoDefault : Operand <i32> {
 610   let PrintMethod = "printOperandAndMods";
 611 }
 612
 613 class getNumSrcArgs<ValueType Src1, ValueType Src2> {
 614   int ret =
 615     !if (!eq(Src1.Value, untyped.Value),      1,   // VOP1
 616          !if (!eq(Src2.Value, untyped.Value), 2,   // VOP2
 617                                               3)); // VOP3
 618 }
 619
 620 // Returns the register class to use for the destination of VOP[123C]
 621 // instructions for the given VT.
 622 class getVALUDstForVT<ValueType VT> {
 623   RegisterClass ret = !if(!eq(VT.Size, 32), VGPR_32,
 624                           !if(!eq(VT.Size, 64), VReg_64,
 625                             SReg_64)); // else VT == i1
 626 }
 627
 628 // Returns the register class to use for source 0 of VOP[12C]
 629 // instructions for the given VT.
 630 class getVOPSrc0ForVT<ValueType VT> {
 631   RegisterOperand ret = !if(!eq(VT.Size, 32), VSrc_32, VSrc_64);
 632 }
 633
 634 // Returns the register class to use for source 1 of VOP[12C] for the
 635 // given VT.
 636 class getVOPSrc1ForVT<ValueType VT> {
 637   RegisterClass ret = !if(!eq(VT.Size, 32), VGPR_32, VReg_64);
 638 }
 639
 640 // Returns the register class to use for sources of VOP3 instructions for the
 641 // given VT.
 642 class getVOP3SrcForVT<ValueType VT> {
 643   RegisterOperand ret = !if(!eq(VT.Size, 32), VCSrc_32, VCSrc_64);
 644 }
 645
 646 // Returns 1 if the source arguments have modifiers, 0 if they do not.
 647 class hasModifiers<ValueType SrcVT> {
 648   bit ret = !if(!eq(SrcVT.Value, f32.Value), 1,
 649             !if(!eq(SrcVT.Value, f64.Value), 1, 0));
 650 }
 651
 652 // Returns the input arguments for VOP[12C] instructions for the given SrcVT.
 653 class getIns32 <RegisterOperand Src0RC, RegisterClass Src1RC, int NumSrcArgs> {
 654   dag ret = !if(!eq(NumSrcArgs, 1), (ins Src0RC:$src0),               // VOP1
 655             !if(!eq(NumSrcArgs, 2), (ins Src0RC:$src0, Src1RC:$src1), // VOP2
 656                                     (ins)));
 657 }
 658
 659 // Returns the input arguments for VOP3 instructions for the given SrcVT.
 660 class getIns64 <RegisterOperand Src0RC, RegisterOperand Src1RC,
 661                 RegisterOperand Src2RC, int NumSrcArgs,
 662                 bit HasModifiers> {
 663
 664   dag ret =
 665     !if (!eq(NumSrcArgs, 1),
 666       !if (!eq(HasModifiers, 1),
 667         // VOP1 with modifiers
 668         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 669              ClampMod:$clamp, omod:$omod)
 670       /* else */,
 671         // VOP1 without modifiers
 672         (ins Src0RC:$src0)
 673       /* endif */ ),
 674     !if (!eq(NumSrcArgs, 2),
 675       !if (!eq(HasModifiers, 1),
 676         // VOP 2 with modifiers
 677         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 678              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 679              ClampMod:$clamp, omod:$omod)
 680       /* else */,
 681         // VOP2 without modifiers
 682         (ins Src0RC:$src0, Src1RC:$src1)
 683       /* endif */ )
 684     /* NumSrcArgs == 3 */,
 685       !if (!eq(HasModifiers, 1),
 686         // VOP3 with modifiers
 687         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 688              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 689              InputModsNoDefault:$src2_modifiers, Src2RC:$src2,
 690              ClampMod:$clamp, omod:$omod)
 691       /* else */,
 692         // VOP3 without modifiers
 693         (ins Src0RC:$src0, Src1RC:$src1, Src2RC:$src2)
 694       /* endif */ )));
 695 }
 696
 697 // Returns the assembly string for the inputs and outputs of a VOP[12C]
 698 // instruction.  This does not add the _e32 suffix, so it can be reused
 699 // by getAsm64.
 700 class getAsm32 <int NumSrcArgs> {
 701   string src1 = ", $src1";
 702   string src2 = ", $src2";
 703   string ret = " $dst, $src0"#
 704                !if(!eq(NumSrcArgs, 1), "", src1)#
 705                !if(!eq(NumSrcArgs, 3), src2, "");
 706 }
 707
 708 // Returns the assembly string for the inputs and outputs of a VOP3
 709 // instruction.
 710 class getAsm64 <int NumSrcArgs, bit HasModifiers> {
 711   string src0 = !if(!eq(NumSrcArgs, 1), "$src0_modifiers", "$src0_modifiers,");
 712   string src1 = !if(!eq(NumSrcArgs, 1), "",
 713                    !if(!eq(NumSrcArgs, 2), " $src1_modifiers",
 714                                            " $src1_modifiers,"));
 715   string src2 = !if(!eq(NumSrcArgs, 3), " $src2_modifiers", "");
 716   string ret =
 717   !if(!eq(HasModifiers, 0),
 718       getAsm32<NumSrcArgs>.ret,
 719       " $dst, "#src0#src1#src2#"$clamp"#"$omod");
 720 }
 721
 722
 723 class VOPProfile <list<ValueType> _ArgVT> {
 724
 725   field list<ValueType> ArgVT = _ArgVT;
 726
 727   field ValueType DstVT = ArgVT[0];
 728   field ValueType Src0VT = ArgVT[1];
 729   field ValueType Src1VT = ArgVT[2];
 730   field ValueType Src2VT = ArgVT[3];
 731   field RegisterClass DstRC = getVALUDstForVT<DstVT>.ret;
 732   field RegisterOperand Src0RC32 = getVOPSrc0ForVT<Src0VT>.ret;
 733   field RegisterClass Src1RC32 = getVOPSrc1ForVT<Src1VT>.ret;
 734   field RegisterOperand Src0RC64 = getVOP3SrcForVT<Src0VT>.ret;
 735   field RegisterOperand Src1RC64 = getVOP3SrcForVT<Src1VT>.ret;
 736   field RegisterOperand Src2RC64 = getVOP3SrcForVT<Src2VT>.ret;
 737
 738   field int NumSrcArgs = getNumSrcArgs<Src1VT, Src2VT>.ret;
 739   field bit HasModifiers = hasModifiers<Src0VT>.ret;
 740
 741   field dag Outs = (outs DstRC:$dst);
 742
 743   field dag Ins32 = getIns32<Src0RC32, Src1RC32, NumSrcArgs>.ret;
 744   field dag Ins64 = getIns64<Src0RC64, Src1RC64, Src2RC64, NumSrcArgs,
 745                              HasModifiers>.ret;
 746
 747   field string Asm32 = "_e32"#getAsm32<NumSrcArgs>.ret;
 748   field string Asm64 = getAsm64<NumSrcArgs, HasModifiers>.ret;
 749 }
 750
 751 def VOP_F32_F32 : VOPProfile <[f32, f32, untyped, untyped]>;
 752 def VOP_F32_F64 : VOPProfile <[f32, f64, untyped, untyped]>;
 753 def VOP_F32_I32 : VOPProfile <[f32, i32, untyped, untyped]>;
 754 def VOP_F64_F32 : VOPProfile <[f64, f32, untyped, untyped]>;
 755 def VOP_F64_F64 : VOPProfile <[f64, f64, untyped, untyped]>;
 756 def VOP_F64_I32 : VOPProfile <[f64, i32, untyped, untyped]>;
 757 def VOP_I32_F32 : VOPProfile <[i32, f32, untyped, untyped]>;
 758 def VOP_I32_F64 : VOPProfile <[i32, f64, untyped, untyped]>;
 759 def VOP_I32_I32 : VOPProfile <[i32, i32, untyped, untyped]>;
 760
 761 def VOP_F32_F32_F32 : VOPProfile <[f32, f32, f32, untyped]>;
 762 def VOP_F32_F32_I32 : VOPProfile <[f32, f32, i32, untyped]>;
 763 def VOP_F64_F64_F64 : VOPProfile <[f64, f64, f64, untyped]>;
 764 def VOP_F64_F64_I32 : VOPProfile <[f64, f64, i32, untyped]>;
 765 def VOP_I32_F32_F32 : VOPProfile <[i32, f32, f32, untyped]>;
 766 def VOP_I32_F32_I32 : VOPProfile <[i32, f32, i32, untyped]>;
 767 def VOP_I32_I32_I32 : VOPProfile <[i32, i32, i32, untyped]>;
 768 def VOP_I32_I32_I32_VCC : VOPProfile <[i32, i32, i32, untyped]> {
 769   let Src0RC32 = VCSrc_32;
 770 }
 771
 772 def VOP_I1_F32_I32 : VOPProfile <[i1, f32, i32, untyped]> {
 773   let Ins64 = (ins InputModsNoDefault:$src0_modifiers, Src0RC64:$src0, Src1RC64:$src1);
 774   let Asm64 = " $dst, $src0_modifiers, $src1";
 775 }
 776
 777 def VOP_I1_F64_I32 : VOPProfile <[i1, f64, i32, untyped]> {
 778   let Ins64 = (ins InputModsNoDefault:$src0_modifiers, Src0RC64:$src0, Src1RC64:$src1);
 779   let Asm64 = " $dst, $src0_modifiers, $src1";
 780 }
 781
 782 def VOP_I64_I64_I32 : VOPProfile <[i64, i64, i32, untyped]>;
 783 def VOP_I64_I32_I64 : VOPProfile <[i64, i32, i64, untyped]>;
 784 def VOP_I64_I64_I64 : VOPProfile <[i64, i64, i64, untyped]>;
 785
 786 def VOP_F32_F32_F32_F32 : VOPProfile <[f32, f32, f32, f32]>;
 787 def VOP_F64_F64_F64_F64 : VOPProfile <[f64, f64, f64, f64]>;
 788 def VOP_I32_I32_I32_I32 : VOPProfile <[i32, i32, i32, i32]>;
 789 def VOP_I64_I32_I32_I64 : VOPProfile <[i64, i32, i32, i64]>;
 790
 791
 792 class VOP <string opName> {
 793   string OpName = opName;
 794 }
 795
 796 class VOP2_REV <string revOp, bit isOrig> {
 797   string RevOp = revOp;
 798   bit IsOrig = isOrig;
 799 }
 800
 801 class AtomicNoRet <string noRetOp, bit isRet> {
 802   string NoRetOp = noRetOp;
 803   bit IsRet = isRet;
 804 }
 805
 806 class VOP1_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 807   VOP1Common <outs, ins, "", pattern>,
 808   VOP <opName>,
 809   SIMCInstr <opName#"_e32", SISubtarget.NONE> {
 810   let isPseudo = 1;
 811 }
 812
 813 multiclass VOP1_m <vop1 op, dag outs, dag ins, string asm, list<dag> pattern,
 814                    string opName> {
 815   def "" : VOP1_Pseudo <outs, ins, pattern, opName>;
 816
 817   def _si : VOP1<op.SI, outs, ins, asm, []>,
 818             SIMCInstr <opName#"_e32", SISubtarget.SI>;
 819   def _vi : VOP1<op.VI, outs, ins, asm, []>,
 820             SIMCInstr <opName#"_e32", SISubtarget.VI>;
 821 }
 822
 823 multiclass VOP1SI_m <vop1 op, dag outs, dag ins, string asm, list<dag> pattern,
 824                    string opName> {
 825   def "" : VOP1_Pseudo <outs, ins, pattern, opName>;
 826
 827   def _si : VOP1<op.SI, outs, ins, asm, []>,
 828             SIMCInstr <opName#"_e32", SISubtarget.SI>;
 829   // No VI instruction. This class is for SI only.
 830 }
 831
 832 class VOP2_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 833   VOP2Common <outs, ins, "", pattern>,
 834   VOP <opName>,
 835   SIMCInstr<opName#"_e32", SISubtarget.NONE> {
 836   let isPseudo = 1;
 837 }
 838
 839 multiclass VOP2SI_m <vop2 op, dag outs, dag ins, string asm, list<dag> pattern,
 840                      string opName, string revOp> {
 841   def "" : VOP2_Pseudo <outs, ins, pattern, opName>,
 842            VOP2_REV<revOp#"_e32", !eq(revOp, opName)>;
 843
 844   def _si : VOP2 <op.SI, outs, ins, opName#asm, []>,
 845             SIMCInstr <opName#"_e32", SISubtarget.SI>;
 846 }
 847
 848 multiclass VOP2_m <vop2 op, dag outs, dag ins, string asm, list<dag> pattern,
 849                    string opName, string revOp> {
 850   def "" : VOP2_Pseudo <outs, ins, pattern, opName>,
 851            VOP2_REV<revOp#"_e32", !eq(revOp, opName)>;
 852
 853   def _si : VOP2 <op.SI, outs, ins, opName#asm, []>,
 854             SIMCInstr <opName#"_e32", SISubtarget.SI>;
 855   def _vi : VOP2 <op.VI, outs, ins, opName#asm, []>,
 856             SIMCInstr <opName#"_e32", SISubtarget.VI>;
 857 }
 858
 859 class VOP3DisableFields <bit HasSrc1, bit HasSrc2, bit HasModifiers> {
 860
 861   bits<2> src0_modifiers = !if(HasModifiers, ?, 0);
 862   bits<2> src1_modifiers = !if(HasModifiers, !if(HasSrc1, ?, 0), 0);
 863   bits<2> src2_modifiers = !if(HasModifiers, !if(HasSrc2, ? ,0) ,0);
 864   bits<2> omod = !if(HasModifiers, ?, 0);
 865   bits<1> clamp = !if(HasModifiers, ?, 0);
 866   bits<9> src1 = !if(HasSrc1, ?, 0);
 867   bits<9> src2 = !if(HasSrc2, ?, 0);
 868 }
 869
 870 class VOP3_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 871   VOP3Common <outs, ins, "", pattern>,
 872   VOP <opName>,
 873   SIMCInstr<opName#"_e64", SISubtarget.NONE> {
 874   let isPseudo = 1;
 875 }
 876
 877 class VOP3_Real_si <bits<9> op, dag outs, dag ins, string asm, string opName> :
 878   VOP3Common <outs, ins, asm, []>,
 879   VOP3e <op>,
 880   SIMCInstr<opName#"_e64", SISubtarget.SI>;
 881
 882 class VOP3_Real_vi <bits<10> op, dag outs, dag ins, string asm, string opName> :
 883   VOP3Common <outs, ins, asm, []>,
 884   VOP3e_vi <op>,
 885   SIMCInstr <opName#"_e64", SISubtarget.VI>;
 886
 887 class VOP3b_Real_si <bits<9> op, dag outs, dag ins, string asm, string opName> :
 888   VOP3Common <outs, ins, asm, []>,
 889   VOP3be <op>,
 890   SIMCInstr<opName#"_e64", SISubtarget.SI>;
 891
 892 class VOP3b_Real_vi <bits<10> op, dag outs, dag ins, string asm, string opName> :
 893   VOP3Common <outs, ins, asm, []>,
 894   VOP3be_vi <op>,
 895   SIMCInstr <opName#"_e64", SISubtarget.VI>;
 896
 897 multiclass VOP3_m <vop op, dag outs, dag ins, string asm, list<dag> pattern,
 898                    string opName, int NumSrcArgs, bit HasMods = 1> {
 899
 900   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 901
 902   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 903             VOP3DisableFields<!if(!eq(NumSrcArgs, 1), 0, 1),
 904                               !if(!eq(NumSrcArgs, 2), 0, 1),
 905                               HasMods>;
 906   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
 907             VOP3DisableFields<!if(!eq(NumSrcArgs, 1), 0, 1),
 908                               !if(!eq(NumSrcArgs, 2), 0, 1),
 909                               HasMods>;
 910 }
 911
 912 // VOP3_m without source modifiers
 913 multiclass VOP3_m_nomods <vop op, dag outs, dag ins, string asm, list<dag> pattern,
 914                    string opName, int NumSrcArgs, bit HasMods = 1> {
 915
 916   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 917
 918   let src0_modifiers = 0,
 919       src1_modifiers = 0,
 920       src2_modifiers = 0,
 921       clamp = 0,
 922       omod = 0 in {
 923     def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>;
 924     def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>;
 925   }
 926 }
 927
 928 multiclass VOP3_1_m <vop op, dag outs, dag ins, string asm,
 929                      list<dag> pattern, string opName, bit HasMods = 1> {
 930
 931   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 932
 933   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 934             VOP3DisableFields<0, 0, HasMods>;
 935
 936   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
 937             VOP3DisableFields<0, 0, HasMods>;
 938 }
 939
 940 multiclass VOP3SI_1_m <vop op, dag outs, dag ins, string asm,
 941                      list<dag> pattern, string opName, bit HasMods = 1> {
 942
 943   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 944
 945   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 946             VOP3DisableFields<0, 0, HasMods>;
 947   // No VI instruction. This class is for SI only.
 948 }
 949
 950 multiclass VOP3_2_m <vop op, dag outs, dag ins, string asm,
 951                      list<dag> pattern, string opName, string revOp,
 952                      bit HasMods = 1, bit UseFullOp = 0> {
 953
 954   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
 955            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
 956
 957   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 958             VOP3DisableFields<1, 0, HasMods>;
 959
 960   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
 961             VOP3DisableFields<1, 0, HasMods>;
 962 }
 963
 964 multiclass VOP3SI_2_m <vop op, dag outs, dag ins, string asm,
 965                      list<dag> pattern, string opName, string revOp,
 966                      bit HasMods = 1, bit UseFullOp = 0> {
 967
 968   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
 969            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
 970
 971   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
 972             VOP3DisableFields<1, 0, HasMods>;
 973
 974   // No VI instruction. This class is for SI only.
 975 }
 976
 977 // XXX - Is v_div_scale_{f32|f64} only available in vop3b without
 978 // option of implicit vcc use?
 979 multiclass VOP3b_2_m <vop op, dag outs, dag ins, string asm,
 980                       list<dag> pattern, string opName, string revOp,
 981                       bit HasMods = 1, bit UseFullOp = 0> {
 982   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
 983            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
 984
 985   // The VOP2 variant puts the carry out into VCC, the VOP3 variant
 986   // can write it into any SGPR. We currently don't use the carry out,
 987   // so for now hardcode it to VCC as well.
 988   let sdst = SIOperand.VCC, Defs = [VCC] in {
 989     def _si : VOP3b_Real_si <op.SI3, outs, ins, asm, opName>,
 990               VOP3DisableFields<1, 0, HasMods>;
 991
 992     def _vi : VOP3b_Real_vi <op.VI3, outs, ins, asm, opName>,
 993               VOP3DisableFields<1, 0, HasMods>;
 994   } // End sdst = SIOperand.VCC, Defs = [VCC]
 995 }
 996
 997 multiclass VOP3b_3_m <vop op, dag outs, dag ins, string asm,
 998                       list<dag> pattern, string opName, string revOp,
 999                       bit HasMods = 1, bit UseFullOp = 0> {
1000   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
1001
1002
1003   def _si : VOP3b_Real_si <op.SI3, outs, ins, asm, opName>,
1004             VOP3DisableFields<1, 1, HasMods>;
1005
1006   def _vi : VOP3b_Real_vi <op.VI3, outs, ins, asm, opName>,
1007             VOP3DisableFields<1, 1, HasMods>;
1008 }
1009
1010 multiclass VOP3_C_m <vop op, dag outs, dag ins, string asm,
1011                      list<dag> pattern, string opName,
1012                      bit HasMods, bit defExec> {
1013
1014   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
1015
1016   def _si : VOP3_Real_si <op.SI3, outs, ins, asm, opName>,
1017             VOP3DisableFields<1, 0, HasMods> {
1018     let Defs = !if(defExec, [EXEC], []);
1019   }
1020
1021   def _vi : VOP3_Real_vi <op.VI3, outs, ins, asm, opName>,
1022             VOP3DisableFields<1, 0, HasMods> {
1023     let Defs = !if(defExec, [EXEC], []);
1024   }
1025 }
1026
1027 // An instruction that is VOP2 on SI and VOP3 on VI, no modifiers.
1028 multiclass VOP2SI_3VI_m <vop3 op, string opName, dag outs, dag ins,
1029                          string asm, list<dag> pattern = []> {
1030   let isPseudo = 1 in {
1031     def "" : VOPAnyCommon <outs, ins, "", pattern>,
1032              SIMCInstr<opName, SISubtarget.NONE>;
1033   }
1034
1035   def _si : VOP2 <op.SI3{5-0}, outs, ins, asm, []>,
1036             SIMCInstr <opName, SISubtarget.SI>;
1037
1038   def _vi : VOP3Common <outs, ins, asm, []>,
1039             VOP3e_vi <op.VI3>,
1040             VOP3DisableFields <1, 0, 0>,
1041             SIMCInstr <opName, SISubtarget.VI>;
1042 }
1043
1044 multiclass VOP1_Helper <vop1 op, string opName, dag outs,
1045                         dag ins32, string asm32, list<dag> pat32,
1046                         dag ins64, string asm64, list<dag> pat64,
1047                         bit HasMods> {
1048
1049   defm _e32 : VOP1_m <op, outs, ins32, opName#asm32, pat32, opName>;
1050
1051   defm _e64 : VOP3_1_m <op, outs, ins64, opName#"_e64"#asm64, pat64, opName, HasMods>;
1052 }
1053
1054 multiclass VOP1Inst <vop1 op, string opName, VOPProfile P,
1055                      SDPatternOperator node = null_frag> : VOP1_Helper <
1056   op, opName, P.Outs,
1057   P.Ins32, P.Asm32, [],
1058   P.Ins64, P.Asm64,
1059   !if(P.HasModifiers,
1060       [(set P.DstVT:$dst, (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0,
1061                                 i32:$src0_modifiers, i1:$clamp, i32:$omod))))],
1062       [(set P.DstVT:$dst, (node P.Src0VT:$src0))]),
1063   P.HasModifiers
1064 >;
1065
1066 multiclass VOP1InstSI <vop1 op, string opName, VOPProfile P,
1067                        SDPatternOperator node = null_frag> {
1068
1069   defm _e32 : VOP1SI_m <op, P.Outs, P.Ins32, opName#P.Asm32, [], opName>;
1070
1071   defm _e64 : VOP3SI_1_m <op, P.Outs, P.Ins64, opName#P.Asm64,
1072     !if(P.HasModifiers,
1073       [(set P.DstVT:$dst, (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0,
1074                                 i32:$src0_modifiers, i1:$clamp, i32:$omod))))],
1075       [(set P.DstVT:$dst, (node P.Src0VT:$src0))]),
1076     opName, P.HasModifiers>;
1077 }
1078
1079 multiclass VOP2_Helper <vop2 op, string opName, dag outs,
1080                         dag ins32, string asm32, list<dag> pat32,
1081                         dag ins64, string asm64, list<dag> pat64,
1082                         string revOp, bit HasMods> {
1083   defm _e32 : VOP2_m <op, outs, ins32, asm32, pat32, opName, revOp>;
1084
1085   defm _e64 : VOP3_2_m <op,
1086     outs, ins64, opName#"_e64"#asm64, pat64, opName, revOp, HasMods
1087   >;
1088 }
1089
1090 multiclass VOP2Inst <vop2 op, string opName, VOPProfile P,
1091                      SDPatternOperator node = null_frag,
1092                      string revOp = opName> : VOP2_Helper <
1093   op, opName, P.Outs,
1094   P.Ins32, P.Asm32, [],
1095   P.Ins64, P.Asm64,
1096   !if(P.HasModifiers,
1097       [(set P.DstVT:$dst,
1098            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1099                                       i1:$clamp, i32:$omod)),
1100                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1101       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1102   revOp, P.HasModifiers
1103 >;
1104
1105 multiclass VOP2InstSI <vop2 op, string opName, VOPProfile P,
1106                        SDPatternOperator node = null_frag,
1107                        string revOp = opName> {
1108   defm _e32 : VOP2SI_m <op, P.Outs, P.Ins32, P.Asm32, [], opName, revOp>;
1109
1110   defm _e64 : VOP3SI_2_m <op, P.Outs, P.Ins64, opName#"_e64"#P.Asm64,
1111     !if(P.HasModifiers,
1112         [(set P.DstVT:$dst,
1113              (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1114                                         i1:$clamp, i32:$omod)),
1115                    (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1116         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1117     opName, revOp, P.HasModifiers>;
1118 }
1119
1120 multiclass VOP2b_Helper <vop2 op, string opName, dag outs,
1121                          dag ins32, string asm32, list<dag> pat32,
1122                          dag ins64, string asm64, list<dag> pat64,
1123                          string revOp, bit HasMods> {
1124
1125   defm _e32 : VOP2_m <op, outs, ins32, asm32, pat32, opName, revOp>;
1126
1127   defm _e64 : VOP3b_2_m <op,
1128     outs, ins64, opName#"_e64"#asm64, pat64, opName, revOp, HasMods
1129   >;
1130 }
1131
1132 multiclass VOP2bInst <vop2 op, string opName, VOPProfile P,
1133                       SDPatternOperator node = null_frag,
1134                       string revOp = opName> : VOP2b_Helper <
1135   op, opName, P.Outs,
1136   P.Ins32, P.Asm32, [],
1137   P.Ins64, P.Asm64,
1138   !if(P.HasModifiers,
1139       [(set P.DstVT:$dst,
1140            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1141                                       i1:$clamp, i32:$omod)),
1142                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1143       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1144   revOp, P.HasModifiers
1145 >;
1146
1147 // A VOP2 instruction that is VOP3-only on VI.
1148 multiclass VOP2_VI3_Helper <vop23 op, string opName, dag outs,
1149                             dag ins32, string asm32, list<dag> pat32,
1150                             dag ins64, string asm64, list<dag> pat64,
1151                             string revOp, bit HasMods> {
1152   defm _e32 : VOP2SI_m <op, outs, ins32, asm32, pat32, opName, revOp>;
1153
1154   defm _e64 : VOP3_2_m <op, outs, ins64, opName#"_e64"#asm64, pat64, opName,
1155                         revOp, HasMods>;
1156 }
1157
1158 multiclass VOP2_VI3_Inst <vop23 op, string opName, VOPProfile P,
1159                           SDPatternOperator node = null_frag,
1160                           string revOp = opName>
1161                           : VOP2_VI3_Helper <
1162   op, opName, P.Outs,
1163   P.Ins32, P.Asm32, [],
1164   P.Ins64, P.Asm64,
1165   !if(P.HasModifiers,
1166       [(set P.DstVT:$dst,
1167            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1168                                       i1:$clamp, i32:$omod)),
1169                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1170       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
1171   revOp, P.HasModifiers
1172 >;
1173
1174 class VOPC_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
1175   VOPCCommon <ins, "", pattern>,
1176   VOP <opName>,
1177   SIMCInstr<opName#"_e32", SISubtarget.NONE> {
1178   let isPseudo = 1;
1179 }
1180
1181 multiclass VOPC_m <vopc op, dag outs, dag ins, string asm, list<dag> pattern,
1182                    string opName, bit DefExec> {
1183   def "" : VOPC_Pseudo <outs, ins, pattern, opName>;
1184
1185   def _si : VOPC<op.SI, ins, asm, []>,
1186             SIMCInstr <opName#"_e32", SISubtarget.SI> {
1187     let Defs = !if(DefExec, [EXEC], []);
1188   }
1189
1190   def _vi : VOPC<op.VI, ins, asm, []>,
1191             SIMCInstr <opName#"_e32", SISubtarget.VI> {
1192     let Defs = !if(DefExec, [EXEC], []);
1193   }
1194 }
1195
1196 multiclass VOPC_Helper <vopc op, string opName,
1197                         dag ins32, string asm32, list<dag> pat32,
1198                         dag out64, dag ins64, string asm64, list<dag> pat64,
1199                         bit HasMods, bit DefExec> {
1200   defm _e32 : VOPC_m <op, (outs), ins32, opName#asm32, pat32, opName, DefExec>;
1201
1202   defm _e64 : VOP3_C_m <op, out64, ins64, opName#"_e64"#asm64, pat64,
1203                         opName, HasMods, DefExec>;
1204 }
1205
1206 multiclass VOPCInst <vopc op, string opName,
1207                      VOPProfile P, PatLeaf cond = COND_NULL,
1208                      bit DefExec = 0> : VOPC_Helper <
1209   op, opName,
1210   P.Ins32, P.Asm32, [],
1211   (outs SReg_64:$dst), P.Ins64, P.Asm64,
1212   !if(P.HasModifiers,
1213       [(set i1:$dst,
1214           (setcc (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1215                                       i1:$clamp, i32:$omod)),
1216                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1217                  cond))],
1218       [(set i1:$dst, (setcc P.Src0VT:$src0, P.Src1VT:$src1, cond))]),
1219   P.HasModifiers, DefExec
1220 >;
1221
1222 multiclass VOPCClassInst <vopc op, string opName, VOPProfile P,
1223                      bit DefExec = 0> : VOPC_Helper <
1224   op, opName,
1225   P.Ins32, P.Asm32, [],
1226   (outs SReg_64:$dst), P.Ins64, P.Asm64,
1227   !if(P.HasModifiers,
1228       [(set i1:$dst,
1229           (AMDGPUfp_class (P.Src0VT (VOP3Mods0Clamp0OMod P.Src0VT:$src0, i32:$src0_modifiers)), P.Src1VT:$src1))],
1230       [(set i1:$dst, (AMDGPUfp_class P.Src0VT:$src0, P.Src1VT:$src1))]),
1231   P.HasModifiers, DefExec
1232 >;
1233
1234
1235 multiclass VOPC_F32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1236   VOPCInst <op, opName, VOP_F32_F32_F32, cond>;
1237
1238 multiclass VOPC_F64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1239   VOPCInst <op, opName, VOP_F64_F64_F64, cond>;
1240
1241 multiclass VOPC_I32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1242   VOPCInst <op, opName, VOP_I32_I32_I32, cond>;
1243
1244 multiclass VOPC_I64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1245   VOPCInst <op, opName, VOP_I64_I64_I64, cond>;
1246
1247
1248 multiclass VOPCX <vopc op, string opName, VOPProfile P,
1249                   PatLeaf cond = COND_NULL>
1250   : VOPCInst <op, opName, P, cond, 1>;
1251
1252 multiclass VOPCX_F32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1253   VOPCX <op, opName, VOP_F32_F32_F32, cond>;
1254
1255 multiclass VOPCX_F64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1256   VOPCX <op, opName, VOP_F64_F64_F64, cond>;
1257
1258 multiclass VOPCX_I32 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1259   VOPCX <op, opName, VOP_I32_I32_I32, cond>;
1260
1261 multiclass VOPCX_I64 <vopc op, string opName, PatLeaf cond = COND_NULL> :
1262   VOPCX <op, opName, VOP_I64_I64_I64, cond>;
1263
1264 multiclass VOP3_Helper <vop3 op, string opName, dag outs, dag ins, string asm,
1265                         list<dag> pat, int NumSrcArgs, bit HasMods> : VOP3_m <
1266     op, outs, ins, opName#asm, pat, opName, NumSrcArgs, HasMods
1267 >;
1268
1269 multiclass VOPC_CLASS_F32 <vopc op, string opName> :
1270   VOPCClassInst <op, opName, VOP_I1_F32_I32, 0>;
1271
1272 multiclass VOPCX_CLASS_F32 <vopc op, string opName> :
1273   VOPCClassInst <op, opName, VOP_I1_F32_I32, 1>;
1274
1275 multiclass VOPC_CLASS_F64 <vopc op, string opName> :
1276   VOPCClassInst <op, opName, VOP_I1_F64_I32, 0>;
1277
1278 multiclass VOPCX_CLASS_F64 <vopc op, string opName> :
1279   VOPCClassInst <op, opName, VOP_I1_F64_I32, 1>;
1280
1281 multiclass VOP3Inst <vop3 op, string opName, VOPProfile P,
1282                      SDPatternOperator node = null_frag> : VOP3_Helper <
1283   op, opName, P.Outs, P.Ins64, P.Asm64,
1284   !if(!eq(P.NumSrcArgs, 3),
1285     !if(P.HasModifiers,
1286         [(set P.DstVT:$dst,
1287             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1288                                        i1:$clamp, i32:$omod)),
1289                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1290                   (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))))],
1291         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1,
1292                                   P.Src2VT:$src2))]),
1293   !if(!eq(P.NumSrcArgs, 2),
1294     !if(P.HasModifiers,
1295         [(set P.DstVT:$dst,
1296             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1297                                        i1:$clamp, i32:$omod)),
1298                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
1299         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))])
1300   /* P.NumSrcArgs == 1 */,
1301     !if(P.HasModifiers,
1302         [(set P.DstVT:$dst,
1303             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1304                                        i1:$clamp, i32:$omod))))],
1305         [(set P.DstVT:$dst, (node P.Src0VT:$src0))]))),
1306   P.NumSrcArgs, P.HasModifiers
1307 >;
1308
1309 // Special case for v_div_fmas_{f32|f64}, since it seems to be the
1310 // only VOP instruction that implicitly reads VCC.
1311 multiclass VOP3_VCC_Inst <vop3 op, string opName,
1312                           VOPProfile P,
1313                           SDPatternOperator node = null_frag> : VOP3_Helper <
1314   op, opName,
1315   P.Outs,
1316   (ins InputModsNoDefault:$src0_modifiers, P.Src0RC64:$src0,
1317        InputModsNoDefault:$src1_modifiers, P.Src1RC64:$src1,
1318        InputModsNoDefault:$src2_modifiers, P.Src2RC64:$src2,
1319        ClampMod:$clamp,
1320        omod:$omod),
1321   " $dst, $src0_modifiers, $src1_modifiers, $src2_modifiers"#"$clamp"#"$omod",
1322   [(set P.DstVT:$dst,
1323             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
1324                                        i1:$clamp, i32:$omod)),
1325                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1326                   (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers)),
1327                   (i1 VCC)))],
1328   3, 1
1329 >;
1330
1331 multiclass VOP3b_Helper <vop op, RegisterClass vrc, RegisterOperand arc,
1332                     string opName, list<dag> pattern> :
1333   VOP3b_3_m <
1334   op, (outs vrc:$vdst, SReg_64:$sdst),
1335       (ins InputModsNoDefault:$src0_modifiers, arc:$src0,
1336            InputModsNoDefault:$src1_modifiers, arc:$src1,
1337            InputModsNoDefault:$src2_modifiers, arc:$src2,
1338            ClampMod:$clamp, omod:$omod),
1339   opName#" $vdst, $sdst, $src0_modifiers, $src1_modifiers, $src2_modifiers"#"$clamp"#"$omod", pattern,
1340   opName, opName, 1, 1
1341 >;
1342
1343 multiclass VOP3b_64 <vop3 op, string opName, list<dag> pattern> :
1344   VOP3b_Helper <op, VReg_64, VSrc_64, opName, pattern>;
1345
1346 multiclass VOP3b_32 <vop3 op, string opName, list<dag> pattern> :
1347   VOP3b_Helper <op, VGPR_32, VSrc_32, opName, pattern>;
1348
1349
1350 class Vop3ModPat<Instruction Inst, VOPProfile P, SDPatternOperator node> : Pat<
1351   (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers, i1:$clamp, i32:$omod)),
1352         (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
1353         (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))),
1354   (Inst i32:$src0_modifiers, P.Src0VT:$src0,
1355         i32:$src1_modifiers, P.Src1VT:$src1,
1356         i32:$src2_modifiers, P.Src2VT:$src2,
1357         i1:$clamp,
1358         i32:$omod)>;
1359
1360 //===----------------------------------------------------------------------===//
1361 // Interpolation opcodes
1362 //===----------------------------------------------------------------------===//
1363
1364 class VINTRP_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1365   VINTRPCommon <outs, ins, "", pattern>,
1366   SIMCInstr<opName, SISubtarget.NONE> {
1367   let isPseudo = 1;
1368 }
1369
1370 class VINTRP_Real_si <bits <2> op, string opName, dag outs, dag ins,
1371                       string asm> :
1372   VINTRPCommon <outs, ins, asm, []>,
1373   VINTRPe <op>,
1374   SIMCInstr<opName, SISubtarget.SI>;
1375
1376 class VINTRP_Real_vi <bits <2> op, string opName, dag outs, dag ins,
1377                       string asm> :
1378   VINTRPCommon <outs, ins, asm, []>,
1379   VINTRPe_vi <op>,
1380   SIMCInstr<opName, SISubtarget.VI>;
1381
1382 multiclass VINTRP_m <bits <2> op, string opName, dag outs, dag ins, string asm,
1383                      string disableEncoding = "", string constraints = "",
1384                      list<dag> pattern = []> {
1385   let DisableEncoding = disableEncoding,
1386       Constraints = constraints in {
1387     def "" : VINTRP_Pseudo <opName, outs, ins, pattern>;
1388
1389     def _si : VINTRP_Real_si <op, opName, outs, ins, asm>;
1390
1391     def _vi : VINTRP_Real_vi <op, opName, outs, ins, asm>;
1392   }
1393 }
1394
1395 //===----------------------------------------------------------------------===//
1396 // Vector I/O classes
1397 //===----------------------------------------------------------------------===//
1398
1399 class DS_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1400   DS <outs, ins, "", pattern>,
1401   SIMCInstr <opName, SISubtarget.NONE> {
1402   let isPseudo = 1;
1403 }
1404
1405 class DS_Real_si <bits<8> op, string opName, dag outs, dag ins, string asm> :
1406   DS <outs, ins, asm, []>,
1407   DSe <op>,
1408   SIMCInstr <opName, SISubtarget.SI>;
1409
1410 class DS_Real_vi <bits<8> op, string opName, dag outs, dag ins, string asm> :
1411   DS <outs, ins, asm, []>,
1412   DSe_vi <op>,
1413   SIMCInstr <opName, SISubtarget.VI>;
1414
1415 class DS_1A_Real_si <bits<8> op, string opName, dag outs, dag ins, string asm> :
1416   DS <outs, ins, asm, []>,
1417   DSe <op>,
1418   SIMCInstr <opName, SISubtarget.SI> {
1419
1420   // Single load interpret the 2 i8imm operands as a single i16 offset.
1421   bits<16> offset;
1422   let offset0 = offset{7-0};
1423   let offset1 = offset{15-8};
1424 }
1425
1426 class DS_1A_Real_vi <bits<8> op, string opName, dag outs, dag ins, string asm> :
1427   DS <outs, ins, asm, []>,
1428   DSe_vi <op>,
1429   SIMCInstr <opName, SISubtarget.VI> {
1430
1431   // Single load interpret the 2 i8imm operands as a single i16 offset.
1432   bits<16> offset;
1433   let offset0 = offset{7-0};
1434   let offset1 = offset{15-8};
1435 }
1436
1437 multiclass DS_1A_Load_m <bits<8> op, string opName, dag outs, dag ins, string asm,
1438                          list<dag> pat> {
1439   let hasSideEffects = 0, mayLoad = 1, mayStore = 0 in {
1440     def "" : DS_Pseudo <opName, outs, ins, pat>;
1441
1442     let data0 = 0, data1 = 0 in {
1443       def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1444       def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1445     }
1446   }
1447 }
1448
1449 multiclass DS_Load_Helper <bits<8> op, string asm, RegisterClass regClass>
1450     : DS_1A_Load_m <
1451   op,
1452   asm,
1453   (outs regClass:$vdst),
1454   (ins i1imm:$gds, VGPR_32:$addr, ds_offset:$offset, M0Reg:$m0),
1455   asm#" $vdst, $addr"#"$offset"#" [M0]",
1456   []>;
1457
1458 multiclass DS_Load2_m <bits<8> op, string opName, dag outs, dag ins, string asm,
1459                        list<dag> pat> {
1460   let hasSideEffects = 0, mayLoad = 1, mayStore = 0 in {
1461     def "" : DS_Pseudo <opName, outs, ins, pat>;
1462
1463     let data0 = 0, data1 = 0 in {
1464       def _si : DS_Real_si <op, opName, outs, ins, asm>;
1465       def _vi : DS_Real_vi <op, opName, outs, ins, asm>;
1466     }
1467   }
1468 }
1469
1470 multiclass DS_Load2_Helper <bits<8> op, string asm, RegisterClass regClass>
1471     : DS_Load2_m <
1472   op,
1473   asm,
1474   (outs regClass:$vdst),
1475   (ins i1imm:$gds, VGPR_32:$addr, ds_offset0:$offset0, ds_offset1:$offset1,
1476         M0Reg:$m0),
1477   asm#" $vdst, $addr"#"$offset0"#"$offset1 [M0]",
1478   []>;
1479
1480 multiclass DS_1A_Store_m <bits<8> op, string opName, dag outs, dag ins,
1481                           string asm, list<dag> pat> {
1482   let hasSideEffects = 0, mayLoad = 0, mayStore = 1 in {
1483     def "" : DS_Pseudo <opName, outs, ins, pat>;
1484
1485     let data1 = 0, vdst = 0 in {
1486       def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1487       def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1488     }
1489   }
1490 }
1491
1492 multiclass DS_Store_Helper <bits<8> op, string asm, RegisterClass regClass>
1493     : DS_1A_Store_m <
1494   op,
1495   asm,
1496   (outs),
1497   (ins i1imm:$gds, VGPR_32:$addr, regClass:$data0, ds_offset:$offset, M0Reg:$m0),
1498   asm#" $addr, $data0"#"$offset"#" [M0]",
1499   []>;
1500
1501 multiclass DS_Store_m <bits<8> op, string opName, dag outs, dag ins,
1502                        string asm, list<dag> pat> {
1503   let hasSideEffects = 0, mayLoad = 0, mayStore = 1 in {
1504     def "" : DS_Pseudo <opName, outs, ins, pat>;
1505
1506     let vdst = 0 in {
1507       def _si : DS_Real_si <op, opName, outs, ins, asm>;
1508       def _vi : DS_Real_vi <op, opName, outs, ins, asm>;
1509     }
1510   }
1511 }
1512
1513 multiclass DS_Store2_Helper <bits<8> op, string asm, RegisterClass regClass>
1514     : DS_Store_m <
1515   op,
1516   asm,
1517   (outs),
1518   (ins i1imm:$gds, VGPR_32:$addr, regClass:$data0, regClass:$data1,
1519        ds_offset0:$offset0, ds_offset1:$offset1, M0Reg:$m0),
1520   asm#" $addr, $data0, $data1"#"$offset0"#"$offset1 [M0]",
1521   []>;
1522
1523 // 1 address, 1 data.
1524 multiclass DS_1A1D_RET_m <bits<8> op, string opName, dag outs, dag ins,
1525                           string asm, list<dag> pat, string noRetOp> {
1526   let mayLoad = 1, mayStore = 1,
1527       hasPostISelHook = 1 // Adjusted to no return version.
1528       in {
1529     def "" : DS_Pseudo <opName, outs, ins, pat>,
1530              AtomicNoRet<noRetOp, 1>;
1531
1532     let data1 = 0 in {
1533       def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1534       def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1535     }
1536   }
1537 }
1538
1539 multiclass DS_1A1D_RET <bits<8> op, string asm, RegisterClass rc,
1540                         string noRetOp = ""> : DS_1A1D_RET_m <
1541   op, asm,
1542   (outs rc:$vdst),
1543   (ins i1imm:$gds, VGPR_32:$addr, rc:$data0, ds_offset:$offset, M0Reg:$m0),
1544   asm#" $vdst, $addr, $data0"#"$offset"#" [M0]", [], noRetOp>;
1545
1546 // 1 address, 2 data.
1547 multiclass DS_1A2D_RET_m <bits<8> op, string opName, dag outs, dag ins,
1548                           string asm, list<dag> pat, string noRetOp> {
1549   let mayLoad = 1, mayStore = 1,
1550       hasPostISelHook = 1 // Adjusted to no return version.
1551       in {
1552     def "" : DS_Pseudo <opName, outs, ins, pat>,
1553              AtomicNoRet<noRetOp, 1>;
1554
1555     def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1556     def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1557   }
1558 }
1559
1560 multiclass DS_1A2D_RET <bits<8> op, string asm, RegisterClass rc,
1561                    string noRetOp = ""> : DS_1A2D_RET_m <
1562   op, asm,
1563   (outs rc:$vdst),
1564   (ins i1imm:$gds, VGPR_32:$addr, rc:$data0, rc:$data1, ds_offset:$offset, M0Reg:$m0),
1565   asm#" $vdst, $addr, $data0, $data1"#"$offset"#" [M0]",
1566   [], noRetOp>;
1567
1568 // 1 address, 2 data.
1569 multiclass DS_1A2D_NORET_m <bits<8> op, string opName, dag outs, dag ins,
1570                             string asm, list<dag> pat, string noRetOp> {
1571   let mayLoad = 1, mayStore = 1 in {
1572     def "" : DS_Pseudo <opName, outs, ins, pat>,
1573              AtomicNoRet<noRetOp, 0>;
1574
1575     let vdst = 0 in {
1576       def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1577       def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1578     }
1579   }
1580 }
1581
1582 multiclass DS_1A2D_NORET <bits<8> op, string asm, RegisterClass rc,
1583                      string noRetOp = asm> : DS_1A2D_NORET_m <
1584   op, asm,
1585   (outs),
1586   (ins i1imm:$gds, VGPR_32:$addr, rc:$data0, rc:$data1, ds_offset:$offset, M0Reg:$m0),
1587   asm#" $addr, $data0, $data1"#"$offset"#" [M0]",
1588   [], noRetOp>;
1589
1590 // 1 address, 1 data.
1591 multiclass DS_1A1D_NORET_m <bits<8> op, string opName, dag outs, dag ins,
1592                             string asm, list<dag> pat, string noRetOp> {
1593   let mayLoad = 1, mayStore = 1 in {
1594     def "" : DS_Pseudo <opName, outs, ins, pat>,
1595              AtomicNoRet<noRetOp, 0>;
1596
1597     let data1 = 0, vdst = 0 in {
1598       def _si : DS_1A_Real_si <op, opName, outs, ins, asm>;
1599       def _vi : DS_1A_Real_vi <op, opName, outs, ins, asm>;
1600     }
1601   }
1602 }
1603
1604 multiclass DS_1A1D_NORET <bits<8> op, string asm, RegisterClass rc,
1605                           string noRetOp = asm> : DS_1A1D_NORET_m <
1606   op, asm,
1607   (outs),
1608   (ins i1imm:$gds, VGPR_32:$addr, rc:$data0, ds_offset:$offset, M0Reg:$m0),
1609   asm#" $addr, $data0"#"$offset"#" [M0]",
1610   [], noRetOp>;
1611
1612 //===----------------------------------------------------------------------===//
1613 // MTBUF classes
1614 //===----------------------------------------------------------------------===//
1615
1616 class MTBUF_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1617   MTBUF <outs, ins, "", pattern>,
1618   SIMCInstr<opName, SISubtarget.NONE> {
1619   let isPseudo = 1;
1620 }
1621
1622 class MTBUF_Real_si <bits<3> op, string opName, dag outs, dag ins,
1623                     string asm> :
1624   MTBUF <outs, ins, asm, []>,
1625   MTBUFe <op>,
1626   SIMCInstr<opName, SISubtarget.SI>;
1627
1628 class MTBUF_Real_vi <bits<4> op, string opName, dag outs, dag ins, string asm> :
1629   MTBUF <outs, ins, asm, []>,
1630   MTBUFe_vi <op>,
1631   SIMCInstr <opName, SISubtarget.VI>;
1632
1633 multiclass MTBUF_m <bits<3> op, string opName, dag outs, dag ins, string asm,
1634                     list<dag> pattern> {
1635
1636   def "" : MTBUF_Pseudo <opName, outs, ins, pattern>;
1637
1638   def _si : MTBUF_Real_si <op, opName, outs, ins, asm>;
1639
1640   def _vi : MTBUF_Real_vi <{0, op{2}, op{1}, op{0}}, opName, outs, ins, asm>;
1641
1642 }
1643
1644 let mayStore = 1, mayLoad = 0 in {
1645
1646 multiclass MTBUF_Store_Helper <bits<3> op, string opName,
1647                                RegisterClass regClass> : MTBUF_m <
1648   op, opName, (outs),
1649   (ins regClass:$vdata, u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc,
1650    i1imm:$addr64, i8imm:$dfmt, i8imm:$nfmt, VGPR_32:$vaddr,
1651    SReg_128:$srsrc, i1imm:$slc, i1imm:$tfe, SCSrc_32:$soffset),
1652   opName#" $vdata, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
1653         #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset", []
1654 >;
1655
1656 } // mayStore = 1, mayLoad = 0
1657
1658 let mayLoad = 1, mayStore = 0 in {
1659
1660 multiclass MTBUF_Load_Helper <bits<3> op, string opName,
1661                               RegisterClass regClass> : MTBUF_m <
1662   op, opName, (outs regClass:$dst),
1663   (ins u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc, i1imm:$addr64,
1664        i8imm:$dfmt, i8imm:$nfmt, VGPR_32:$vaddr, SReg_128:$srsrc,
1665        i1imm:$slc, i1imm:$tfe, SCSrc_32:$soffset),
1666   opName#" $dst, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
1667         #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset", []
1668 >;
1669
1670 } // mayLoad = 1, mayStore = 0
1671
1672 //===----------------------------------------------------------------------===//
1673 // MUBUF classes
1674 //===----------------------------------------------------------------------===//
1675
1676 class mubuf <bits<7> si, bits<7> vi = si> {
1677   field bits<7> SI = si;
1678   field bits<7> VI = vi;
1679 }
1680
1681 class MUBUFAddr64Table <bit is_addr64, string suffix = ""> {
1682   bit IsAddr64 = is_addr64;
1683   string OpName = NAME # suffix;
1684 }
1685
1686 class MUBUF_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
1687   MUBUF <outs, ins, "", pattern>,
1688   SIMCInstr<opName, SISubtarget.NONE> {
1689   let isPseudo = 1;
1690
1691   // dummy fields, so that we can use let statements around multiclasses
1692   bits<1> offen;
1693   bits<1> idxen;
1694   bits<8> vaddr;
1695   bits<1> glc;
1696   bits<1> slc;
1697   bits<1> tfe;
1698   bits<8> soffset;
1699 }
1700
1701 class MUBUF_Real_si <mubuf op, string opName, dag outs, dag ins,
1702                      string asm> :
1703   MUBUF <outs, ins, asm, []>,
1704   MUBUFe <op.SI>,
1705   SIMCInstr<opName, SISubtarget.SI> {
1706   let lds = 0;
1707 }
1708
1709 class MUBUF_Real_vi <mubuf op, string opName, dag outs, dag ins,
1710                      string asm> :
1711   MUBUF <outs, ins, asm, []>,
1712   MUBUFe_vi <op.VI>,
1713   SIMCInstr<opName, SISubtarget.VI> {
1714   let lds = 0;
1715 }
1716
1717 multiclass MUBUF_m <mubuf op, string opName, dag outs, dag ins, string asm,
1718                     list<dag> pattern> {
1719
1720   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1721            MUBUFAddr64Table <0>;
1722
1723   let addr64 = 0 in {
1724     def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1725   }
1726
1727   def _vi : MUBUF_Real_vi <op, opName, outs, ins, asm>;
1728 }
1729
1730 multiclass MUBUFAddr64_m <mubuf op, string opName, dag outs,
1731                           dag ins, string asm, list<dag> pattern> {
1732
1733   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1734            MUBUFAddr64Table <1>;
1735
1736   let addr64 = 1 in {
1737     def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1738   }
1739
1740   // There is no VI version. If the pseudo is selected, it should be lowered
1741   // for VI appropriately.
1742 }
1743
1744 class MUBUF_si <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern> :
1745   MUBUF <outs, ins, asm, pattern>, MUBUFe <op> {
1746   let lds = 0;
1747 }
1748
1749 multiclass MUBUFAtomicOffset_m <mubuf op, string opName, dag outs, dag ins,
1750                                 string asm, list<dag> pattern, bit is_return> {
1751
1752   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1753            MUBUFAddr64Table <0, !if(is_return, "_RTN", "")>,
1754            AtomicNoRet<NAME#"_OFFSET", is_return>;
1755
1756   let offen = 0, idxen = 0, tfe = 0, vaddr = 0 in {
1757     let addr64 = 0 in {
1758       def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1759     }
1760
1761     def _vi : MUBUF_Real_vi <op, opName, outs, ins, asm>;
1762   }
1763 }
1764
1765 multiclass MUBUFAtomicAddr64_m <mubuf op, string opName, dag outs, dag ins,
1766                                 string asm, list<dag> pattern, bit is_return> {
1767
1768   def "" : MUBUF_Pseudo <opName, outs, ins, pattern>,
1769            MUBUFAddr64Table <1, !if(is_return, "_RTN", "")>,
1770            AtomicNoRet<NAME#"_ADDR64", is_return>;
1771
1772   let offen = 0, idxen = 0, addr64 = 1, tfe = 0 in {
1773     def _si : MUBUF_Real_si <op, opName, outs, ins, asm>;
1774   }
1775
1776   // There is no VI version. If the pseudo is selected, it should be lowered
1777   // for VI appropriately.
1778 }
1779
1780 multiclass MUBUF_Atomic <mubuf op, string name, RegisterClass rc,
1781                          ValueType vt, SDPatternOperator atomic> {
1782
1783   let mayStore = 1, mayLoad = 1, hasPostISelHook = 1 in {
1784
1785     // No return variants
1786     let glc = 0 in {
1787
1788       defm _ADDR64 : MUBUFAtomicAddr64_m <
1789         op, name#"_addr64", (outs),
1790         (ins rc:$vdata, SReg_128:$srsrc, VReg_64:$vaddr,
1791              mbuf_offset:$offset, SCSrc_32:$soffset, slc:$slc),
1792         name#" $vdata, $vaddr, $srsrc, $soffset addr64"#"$offset"#"$slc", [], 0
1793       >;
1794
1795       defm _OFFSET : MUBUFAtomicOffset_m <
1796         op, name#"_offset", (outs),
1797         (ins rc:$vdata, SReg_128:$srsrc, mbuf_offset:$offset,
1798              SCSrc_32:$soffset, slc:$slc),
1799         name#" $vdata, $srsrc, $soffset"#"$offset"#"$slc", [], 0
1800       >;
1801     } // glc = 0
1802
1803     // Variant that return values
1804     let glc = 1, Constraints = "$vdata = $vdata_in",
1805         DisableEncoding = "$vdata_in"  in {
1806
1807       defm _RTN_ADDR64 : MUBUFAtomicAddr64_m <
1808         op, name#"_rtn_addr64", (outs rc:$vdata),
1809         (ins rc:$vdata_in, SReg_128:$srsrc, VReg_64:$vaddr,
1810              mbuf_offset:$offset, SSrc_32:$soffset, slc:$slc),
1811         name#" $vdata, $vaddr, $srsrc, $soffset addr64"#"$offset"#" glc"#"$slc",
1812         [(set vt:$vdata,
1813          (atomic (MUBUFAddr64Atomic v4i32:$srsrc, i64:$vaddr, i32:$soffset,
1814                                     i16:$offset, i1:$slc), vt:$vdata_in))], 1
1815       >;
1816
1817       defm _RTN_OFFSET : MUBUFAtomicOffset_m <
1818         op, name#"_rtn_offset", (outs rc:$vdata),
1819         (ins rc:$vdata_in, SReg_128:$srsrc, mbuf_offset:$offset,
1820              SCSrc_32:$soffset, slc:$slc),
1821         name#" $vdata, $srsrc, $soffset"#"$offset"#" glc $slc",
1822         [(set vt:$vdata,
1823          (atomic (MUBUFOffsetAtomic v4i32:$srsrc, i32:$soffset, i16:$offset,
1824                                     i1:$slc), vt:$vdata_in))], 1
1825       >;
1826
1827     } // glc = 1
1828
1829   } // mayStore = 1, mayLoad = 1, hasPostISelHook = 1
1830 }
1831
1832 multiclass MUBUF_Load_Helper <mubuf op, string name, RegisterClass regClass,
1833                               ValueType load_vt = i32,
1834                               SDPatternOperator ld = null_frag> {
1835
1836   let mayLoad = 1, mayStore = 0 in {
1837     let offen = 0, idxen = 0, vaddr = 0 in {
1838       defm _OFFSET : MUBUF_m <op, name#"_offset", (outs regClass:$vdata),
1839                            (ins SReg_128:$srsrc,
1840                            mbuf_offset:$offset, SCSrc_32:$soffset, glc:$glc,
1841                            slc:$slc, tfe:$tfe),
1842                            name#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1843                            [(set load_vt:$vdata, (ld (MUBUFOffset v4i32:$srsrc,
1844                                                      i32:$soffset, i16:$offset,
1845                                                      i1:$glc, i1:$slc, i1:$tfe)))]>;
1846     }
1847
1848     let offen = 1, idxen = 0  in {
1849       defm _OFFEN  : MUBUF_m <op, name#"_offen", (outs regClass:$vdata),
1850                            (ins SReg_128:$srsrc, VGPR_32:$vaddr,
1851                            SCSrc_32:$soffset, mbuf_offset:$offset, glc:$glc, slc:$slc,
1852                            tfe:$tfe),
1853                            name#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1854     }
1855
1856     let offen = 0, idxen = 1 in {
1857       defm _IDXEN  : MUBUF_m <op, name#"_idxen", (outs regClass:$vdata),
1858                            (ins SReg_128:$srsrc, VGPR_32:$vaddr,
1859                            mbuf_offset:$offset, SCSrc_32:$soffset, glc:$glc,
1860                            slc:$slc, tfe:$tfe),
1861                            name#" $vdata, $vaddr, $srsrc, $soffset idxen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1862     }
1863
1864     let offen = 1, idxen = 1 in {
1865       defm _BOTHEN : MUBUF_m <op, name#"_bothen", (outs regClass:$vdata),
1866                            (ins SReg_128:$srsrc, VReg_64:$vaddr,
1867                            SCSrc_32:$soffset, mbuf_offset:$offset, glc:$glc, slc:$slc, tfe:$tfe),
1868                            name#" $vdata, $vaddr, $srsrc, $soffset idxen offen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1869     }
1870
1871     let offen = 0, idxen = 0, glc = 0, slc = 0, tfe = 0 in {
1872       defm _ADDR64 : MUBUFAddr64_m <op, name#"_addr64", (outs regClass:$vdata),
1873                            (ins SReg_128:$srsrc, VReg_64:$vaddr,
1874                                 SCSrc_32:$soffset, mbuf_offset:$offset),
1875                            name#" $vdata, $vaddr, $srsrc, $soffset addr64"#"$offset",
1876                            [(set load_vt:$vdata, (ld (MUBUFAddr64 v4i32:$srsrc,
1877                                                   i64:$vaddr, i32:$soffset,
1878                                                   i16:$offset)))]>;
1879     }
1880   }
1881 }
1882
1883 multiclass MUBUF_Store_Helper <mubuf op, string name, RegisterClass vdataClass,
1884                           ValueType store_vt, SDPatternOperator st> {
1885   let mayLoad = 0, mayStore = 1 in {
1886     defm : MUBUF_m <op, name, (outs),
1887                     (ins vdataClass:$vdata, SReg_128:$srsrc, VGPR_32:$vaddr, SCSrc_32:$soffset,
1888                     mbuf_offset:$offset, offen:$offen, idxen:$idxen, glc:$glc, slc:$slc,
1889                     tfe:$tfe),
1890                     name#" $vdata, $vaddr, $srsrc, $soffset"#"$offen"#"$idxen"#"$offset"#
1891                     "$glc"#"$slc"#"$tfe", []>;
1892
1893     let offen = 0, idxen = 0, vaddr = 0 in {
1894       defm _OFFSET : MUBUF_m <op, name#"_offset",(outs),
1895                               (ins vdataClass:$vdata, SReg_128:$srsrc, mbuf_offset:$offset,
1896                               SCSrc_32:$soffset, glc:$glc, slc:$slc, tfe:$tfe),
1897                               name#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1898                               [(st store_vt:$vdata, (MUBUFOffset v4i32:$srsrc, i32:$soffset,
1899                                    i16:$offset, i1:$glc, i1:$slc, i1:$tfe))]>;
1900     } // offen = 0, idxen = 0, vaddr = 0
1901
1902     let offen = 1, idxen = 0  in {
1903       defm _OFFEN : MUBUF_m <op, name#"_offen", (outs),
1904                              (ins vdataClass:$vdata, SReg_128:$srsrc, VGPR_32:$vaddr, SCSrc_32:$soffset,
1905                              mbuf_offset:$offset, glc:$glc, slc:$slc, tfe:$tfe),
1906                              name#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#
1907                              "$glc"#"$slc"#"$tfe", []>;
1908     } // end offen = 1, idxen = 0
1909
1910     let offen = 0, idxen = 0, glc = 0, slc = 0, tfe = 0 in {
1911       defm _ADDR64 : MUBUFAddr64_m <op, name#"_addr64", (outs),
1912                                     (ins vdataClass:$vdata, SReg_128:$srsrc,
1913                                          VReg_64:$vaddr, SCSrc_32:$soffset,
1914                                          mbuf_offset:$offset),
1915                                     name#" $vdata, $vaddr, $srsrc, $soffset addr64"#"$offset",
1916                                     [(st store_vt:$vdata,
1917                                       (MUBUFAddr64 v4i32:$srsrc, i64:$vaddr,
1918                                                    i32:$soffset, i16:$offset))]>;
1919     }
1920   } // End mayLoad = 0, mayStore = 1
1921 }
1922
1923 class FLAT_Load_Helper <bits<7> op, string asm, RegisterClass regClass> :
1924       FLAT <op, (outs regClass:$vdst),
1925                 (ins VReg_64:$addr),
1926             asm#" $vdst, $addr, [M0, FLAT_SCRATCH]", []> {
1927   let glc = 0;
1928   let slc = 0;
1929   let tfe = 0;
1930   let data = 0;
1931   let mayLoad = 1;
1932 }
1933
1934 class FLAT_Store_Helper <bits<7> op, string name, RegisterClass vdataClass> :
1935       FLAT <op, (outs), (ins vdataClass:$data, VReg_64:$addr),
1936           name#" $data, $addr, [M0, FLAT_SCRATCH]",
1937          []> {
1938
1939   let mayLoad = 0;
1940   let mayStore = 1;
1941
1942   // Encoding
1943   let glc = 0;
1944   let slc = 0;
1945   let tfe = 0;
1946   let vdst = 0;
1947 }
1948
1949 class MIMG_Mask <string op, int channels> {
1950   string Op = op;
1951   int Channels = channels;
1952 }
1953
1954 class MIMG_NoSampler_Helper <bits<7> op, string asm,
1955                              RegisterClass dst_rc,
1956                              RegisterClass src_rc> : MIMG <
1957   op,
1958   (outs dst_rc:$vdata),
1959   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1960        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1961        SReg_256:$srsrc),
1962   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1963      #" $tfe, $lwe, $slc, $vaddr, $srsrc",
1964   []> {
1965   let SSAMP = 0;
1966   let mayLoad = 1;
1967   let mayStore = 0;
1968   let hasPostISelHook = 1;
1969 }
1970
1971 multiclass MIMG_NoSampler_Src_Helper <bits<7> op, string asm,
1972                                       RegisterClass dst_rc,
1973                                       int channels> {
1974   def _V1 : MIMG_NoSampler_Helper <op, asm, dst_rc, VGPR_32>,
1975             MIMG_Mask<asm#"_V1", channels>;
1976   def _V2 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_64>,
1977             MIMG_Mask<asm#"_V2", channels>;
1978   def _V4 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_128>,
1979             MIMG_Mask<asm#"_V4", channels>;
1980 }
1981
1982 multiclass MIMG_NoSampler <bits<7> op, string asm> {
1983   defm _V1 : MIMG_NoSampler_Src_Helper <op, asm, VGPR_32, 1>;
1984   defm _V2 : MIMG_NoSampler_Src_Helper <op, asm, VReg_64, 2>;
1985   defm _V3 : MIMG_NoSampler_Src_Helper <op, asm, VReg_96, 3>;
1986   defm _V4 : MIMG_NoSampler_Src_Helper <op, asm, VReg_128, 4>;
1987 }
1988
1989 class MIMG_Sampler_Helper <bits<7> op, string asm,
1990                            RegisterClass dst_rc,
1991                            RegisterClass src_rc, int wqm> : MIMG <
1992   op,
1993   (outs dst_rc:$vdata),
1994   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1995        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1996        SReg_256:$srsrc, SReg_128:$ssamp),
1997   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1998      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
1999   []> {
2000   let mayLoad = 1;
2001   let mayStore = 0;
2002   let hasPostISelHook = 1;
2003   let WQM = wqm;
2004 }
2005
2006 multiclass MIMG_Sampler_Src_Helper <bits<7> op, string asm,
2007                                     RegisterClass dst_rc,
2008                                     int channels, int wqm> {
2009   def _V1 : MIMG_Sampler_Helper <op, asm, dst_rc, VGPR_32, wqm>,
2010             MIMG_Mask<asm#"_V1", channels>;
2011   def _V2 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_64, wqm>,
2012             MIMG_Mask<asm#"_V2", channels>;
2013   def _V4 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_128, wqm>,
2014             MIMG_Mask<asm#"_V4", channels>;
2015   def _V8 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_256, wqm>,
2016             MIMG_Mask<asm#"_V8", channels>;
2017   def _V16 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_512, wqm>,
2018             MIMG_Mask<asm#"_V16", channels>;
2019 }
2020
2021 multiclass MIMG_Sampler <bits<7> op, string asm> {
2022   defm _V1 : MIMG_Sampler_Src_Helper<op, asm, VGPR_32, 1, 0>;
2023   defm _V2 : MIMG_Sampler_Src_Helper<op, asm, VReg_64, 2, 0>;
2024   defm _V3 : MIMG_Sampler_Src_Helper<op, asm, VReg_96, 3, 0>;
2025   defm _V4 : MIMG_Sampler_Src_Helper<op, asm, VReg_128, 4, 0>;
2026 }
2027
2028 multiclass MIMG_Sampler_WQM <bits<7> op, string asm> {
2029   defm _V1 : MIMG_Sampler_Src_Helper<op, asm, VGPR_32, 1, 1>;
2030   defm _V2 : MIMG_Sampler_Src_Helper<op, asm, VReg_64, 2, 1>;
2031   defm _V3 : MIMG_Sampler_Src_Helper<op, asm, VReg_96, 3, 1>;
2032   defm _V4 : MIMG_Sampler_Src_Helper<op, asm, VReg_128, 4, 1>;
2033 }
2034
2035 class MIMG_Gather_Helper <bits<7> op, string asm,
2036                           RegisterClass dst_rc,
2037                           RegisterClass src_rc, int wqm> : MIMG <
2038   op,
2039   (outs dst_rc:$vdata),
2040   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
2041        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
2042        SReg_256:$srsrc, SReg_128:$ssamp),
2043   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
2044      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
2045   []> {
2046   let mayLoad = 1;
2047   let mayStore = 0;
2048
2049   // DMASK was repurposed for GATHER4. 4 components are always
2050   // returned and DMASK works like a swizzle - it selects
2051   // the component to fetch. The only useful DMASK values are
2052   // 1=red, 2=green, 4=blue, 8=alpha. (e.g. 1 returns
2053   // (red,red,red,red) etc.) The ISA document doesn't mention
2054   // this.
2055   // Therefore, disable all code which updates DMASK by setting these two:
2056   let MIMG = 0;
2057   let hasPostISelHook = 0;
2058   let WQM = wqm;
2059 }
2060
2061 multiclass MIMG_Gather_Src_Helper <bits<7> op, string asm,
2062                                     RegisterClass dst_rc,
2063                                     int channels, int wqm> {
2064   def _V1 : MIMG_Gather_Helper <op, asm, dst_rc, VGPR_32, wqm>,
2065             MIMG_Mask<asm#"_V1", channels>;
2066   def _V2 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_64, wqm>,
2067             MIMG_Mask<asm#"_V2", channels>;
2068   def _V4 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_128, wqm>,
2069             MIMG_Mask<asm#"_V4", channels>;
2070   def _V8 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_256, wqm>,
2071             MIMG_Mask<asm#"_V8", channels>;
2072   def _V16 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_512, wqm>,
2073             MIMG_Mask<asm#"_V16", channels>;
2074 }
2075
2076 multiclass MIMG_Gather <bits<7> op, string asm> {
2077   defm _V1 : MIMG_Gather_Src_Helper<op, asm, VGPR_32, 1, 0>;
2078   defm _V2 : MIMG_Gather_Src_Helper<op, asm, VReg_64, 2, 0>;
2079   defm _V3 : MIMG_Gather_Src_Helper<op, asm, VReg_96, 3, 0>;
2080   defm _V4 : MIMG_Gather_Src_Helper<op, asm, VReg_128, 4, 0>;
2081 }
2082
2083 multiclass MIMG_Gather_WQM <bits<7> op, string asm> {
2084   defm _V1 : MIMG_Gather_Src_Helper<op, asm, VGPR_32, 1, 1>;
2085   defm _V2 : MIMG_Gather_Src_Helper<op, asm, VReg_64, 2, 1>;
2086   defm _V3 : MIMG_Gather_Src_Helper<op, asm, VReg_96, 3, 1>;
2087   defm _V4 : MIMG_Gather_Src_Helper<op, asm, VReg_128, 4, 1>;
2088 }
2089
2090 //===----------------------------------------------------------------------===//
2091 // Vector instruction mappings
2092 //===----------------------------------------------------------------------===//
2093
2094 // Maps an opcode in e32 form to its e64 equivalent
2095 def getVOPe64 : InstrMapping {
2096   let FilterClass = "VOP";
2097   let RowFields = ["OpName"];
2098   let ColFields = ["Size"];
2099   let KeyCol = ["4"];
2100   let ValueCols = [["8"]];
2101 }
2102
2103 // Maps an opcode in e64 form to its e32 equivalent
2104 def getVOPe32 : InstrMapping {
2105   let FilterClass = "VOP";
2106   let RowFields = ["OpName"];
2107   let ColFields = ["Size"];
2108   let KeyCol = ["8"];
2109   let ValueCols = [["4"]];
2110 }
2111
2112 // Maps an original opcode to its commuted version
2113 def getCommuteRev : InstrMapping {
2114   let FilterClass = "VOP2_REV";
2115   let RowFields = ["RevOp"];
2116   let ColFields = ["IsOrig"];
2117   let KeyCol = ["1"];
2118   let ValueCols = [["0"]];
2119 }
2120
2121 def getMaskedMIMGOp : InstrMapping {
2122   let FilterClass = "MIMG_Mask";
2123   let RowFields = ["Op"];
2124   let ColFields = ["Channels"];
2125   let KeyCol = ["4"];
2126   let ValueCols = [["1"], ["2"], ["3"] ];
2127 }
2128
2129 // Maps an commuted opcode to its original version
2130 def getCommuteOrig : InstrMapping {
2131   let FilterClass = "VOP2_REV";
2132   let RowFields = ["RevOp"];
2133   let ColFields = ["IsOrig"];
2134   let KeyCol = ["0"];
2135   let ValueCols = [["1"]];
2136 }
2137
2138 def getMCOpcodeGen : InstrMapping {
2139   let FilterClass = "SIMCInstr";
2140   let RowFields = ["PseudoInstr"];
2141   let ColFields = ["Subtarget"];
2142   let KeyCol = [!cast<string>(SISubtarget.NONE)];
2143   let ValueCols = [[!cast<string>(SISubtarget.SI)],[!cast<string>(SISubtarget.VI)]];
2144 }
2145
2146 def getAddr64Inst : InstrMapping {
2147   let FilterClass = "MUBUFAddr64Table";
2148   let RowFields = ["OpName"];
2149   let ColFields = ["IsAddr64"];
2150   let KeyCol = ["0"];
2151   let ValueCols = [["1"]];
2152 }
2153
2154 // Maps an atomic opcode to its version with a return value.
2155 def getAtomicRetOp : InstrMapping {
2156   let FilterClass = "AtomicNoRet";
2157   let RowFields = ["NoRetOp"];
2158   let ColFields = ["IsRet"];
2159   let KeyCol = ["0"];
2160   let ValueCols = [["1"]];
2161 }
2162
2163 // Maps an atomic opcode to its returnless version.
2164 def getAtomicNoRetOp : InstrMapping {
2165   let FilterClass = "AtomicNoRet";
2166   let RowFields = ["NoRetOp"];
2167   let ColFields = ["IsRet"];
2168   let KeyCol = ["1"];
2169   let ValueCols = [["0"]];
2170 }
2171
2172 include "SIInstructions.td"
2173 include "CIInstructions.td"
2174 include "VIInstructions.td"