lib/Target/R600/SIInstrInfo.td

   1 //===-- SIInstrInfo.td - SI Instruction Infos -------------*- tablegen -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 // Execpt for the NONE field, this must be kept in sync with the SISubtarget enum
  11 // in AMDGPUMCInstLower.h
  12 def SISubtarget {
  13   int NONE = -1;
  14   int SI = 0;
  15 }
  16
  17 //===----------------------------------------------------------------------===//
  18 // SI DAG Nodes
  19 //===----------------------------------------------------------------------===//
  20
  21 def SIload_constant : SDNode<"AMDGPUISD::LOAD_CONSTANT",
  22   SDTypeProfile<1, 2, [SDTCisVT<0, f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i32>]>,
  23                       [SDNPMayLoad, SDNPMemOperand]
  24 >;
  25
  26 def SItbuffer_store : SDNode<"AMDGPUISD::TBUFFER_STORE_FORMAT",
  27   SDTypeProfile<0, 13,
  28     [SDTCisVT<0, v4i32>,   // rsrc(SGPR)
  29      SDTCisVT<1, iAny>,   // vdata(VGPR)
  30      SDTCisVT<2, i32>,    // num_channels(imm)
  31      SDTCisVT<3, i32>,    // vaddr(VGPR)
  32      SDTCisVT<4, i32>,    // soffset(SGPR)
  33      SDTCisVT<5, i32>,    // inst_offset(imm)
  34      SDTCisVT<6, i32>,    // dfmt(imm)
  35      SDTCisVT<7, i32>,    // nfmt(imm)
  36      SDTCisVT<8, i32>,    // offen(imm)
  37      SDTCisVT<9, i32>,    // idxen(imm)
  38      SDTCisVT<10, i32>,   // glc(imm)
  39      SDTCisVT<11, i32>,   // slc(imm)
  40      SDTCisVT<12, i32>    // tfe(imm)
  41     ]>,
  42   [SDNPMayStore, SDNPMemOperand, SDNPHasChain]
  43 >;
  44
  45 def SIload_input : SDNode<"AMDGPUISD::LOAD_INPUT",
  46   SDTypeProfile<1, 3, [SDTCisVT<0, v4f32>, SDTCisVT<1, v4i32>, SDTCisVT<2, i16>,
  47                        SDTCisVT<3, i32>]>
  48 >;
  49
  50 class SDSample<string opcode> : SDNode <opcode,
  51   SDTypeProfile<1, 4, [SDTCisVT<0, v4f32>, SDTCisVT<2, v32i8>,
  52                        SDTCisVT<3, v4i32>, SDTCisVT<4, i32>]>
  53 >;
  54
  55 def SIsample : SDSample<"AMDGPUISD::SAMPLE">;
  56 def SIsampleb : SDSample<"AMDGPUISD::SAMPLEB">;
  57 def SIsampled : SDSample<"AMDGPUISD::SAMPLED">;
  58 def SIsamplel : SDSample<"AMDGPUISD::SAMPLEL">;
  59
  60 def SIconstdata_ptr : SDNode<
  61   "AMDGPUISD::CONST_DATA_PTR", SDTypeProfile <1, 0, [SDTCisVT<0, i64>]>
  62 >;
  63
  64 // Transformation function, extract the lower 32bit of a 64bit immediate
  65 def LO32 : SDNodeXForm<imm, [{
  66   return CurDAG->getTargetConstant(N->getZExtValue() & 0xffffffff, MVT::i32);
  67 }]>;
  68
  69 def LO32f : SDNodeXForm<fpimm, [{
  70   APInt V = N->getValueAPF().bitcastToAPInt().trunc(32);
  71   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
  72 }]>;
  73
  74 // Transformation function, extract the upper 32bit of a 64bit immediate
  75 def HI32 : SDNodeXForm<imm, [{
  76   return CurDAG->getTargetConstant(N->getZExtValue() >> 32, MVT::i32);
  77 }]>;
  78
  79 def HI32f : SDNodeXForm<fpimm, [{
  80   APInt V = N->getValueAPF().bitcastToAPInt().lshr(32).trunc(32);
  81   return CurDAG->getTargetConstantFP(APFloat(APFloat::IEEEsingle, V), MVT::f32);
  82 }]>;
  83
  84 def IMM8bitDWORD : PatLeaf <(imm),
  85   [{return (N->getZExtValue() & ~0x3FC) == 0;}]
  86 >;
  87
  88 def as_dword_i32imm : SDNodeXForm<imm, [{
  89   return CurDAG->getTargetConstant(N->getZExtValue() >> 2, MVT::i32);
  90 }]>;
  91
  92 def as_i1imm : SDNodeXForm<imm, [{
  93   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i1);
  94 }]>;
  95
  96 def as_i8imm : SDNodeXForm<imm, [{
  97   return CurDAG->getTargetConstant(N->getZExtValue(), MVT::i8);
  98 }]>;
  99
 100 def as_i16imm : SDNodeXForm<imm, [{
 101   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i16);
 102 }]>;
 103
 104 def as_i32imm: SDNodeXForm<imm, [{
 105   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i32);
 106 }]>;
 107
 108 def IMM8bit : PatLeaf <(imm),
 109   [{return isUInt<8>(N->getZExtValue());}]
 110 >;
 111
 112 def IMM12bit : PatLeaf <(imm),
 113   [{return isUInt<12>(N->getZExtValue());}]
 114 >;
 115
 116 def IMM16bit : PatLeaf <(imm),
 117   [{return isUInt<16>(N->getZExtValue());}]
 118 >;
 119
 120 def IMM32bit : PatLeaf <(imm),
 121   [{return isUInt<32>(N->getZExtValue());}]
 122 >;
 123
 124 def mubuf_vaddr_offset : PatFrag<
 125   (ops node:$ptr, node:$offset, node:$imm_offset),
 126   (add (add node:$ptr, node:$offset), node:$imm_offset)
 127 >;
 128
 129 class InlineImm <ValueType vt> : PatLeaf <(vt imm), [{
 130   return isInlineImmediate(N);
 131 }]>;
 132
 133 class SGPRImm <dag frag> : PatLeaf<frag, [{
 134   if (TM.getSubtarget<AMDGPUSubtarget>().getGeneration() <
 135       AMDGPUSubtarget::SOUTHERN_ISLANDS) {
 136     return false;
 137   }
 138   const SIRegisterInfo *SIRI =
 139                        static_cast<const SIRegisterInfo*>(TM.getSubtargetImpl()->getRegisterInfo());
 140   for (SDNode::use_iterator U = N->use_begin(), E = SDNode::use_end();
 141                                                 U != E; ++U) {
 142     if (SIRI->isSGPRClass(getOperandRegClass(*U, U.getOperandNo()))) {
 143       return true;
 144     }
 145   }
 146   return false;
 147 }]>;
 148
 149 //===----------------------------------------------------------------------===//
 150 // Custom Operands
 151 //===----------------------------------------------------------------------===//
 152
 153 def FRAMEri32 : Operand<iPTR> {
 154   let MIOperandInfo = (ops i32:$ptr, i32imm:$index);
 155 }
 156
 157 def sopp_brtarget : Operand<OtherVT> {
 158   let EncoderMethod = "getSOPPBrEncoding";
 159   let OperandType = "OPERAND_PCREL";
 160 }
 161
 162 include "SIInstrFormats.td"
 163
 164 let OperandType = "OPERAND_IMMEDIATE" in {
 165
 166 def offen : Operand<i1> {
 167   let PrintMethod = "printOffen";
 168 }
 169 def idxen : Operand<i1> {
 170   let PrintMethod = "printIdxen";
 171 }
 172 def addr64 : Operand<i1> {
 173   let PrintMethod = "printAddr64";
 174 }
 175 def mbuf_offset : Operand<i16> {
 176   let PrintMethod = "printMBUFOffset";
 177 }
 178 def glc : Operand <i1> {
 179   let PrintMethod = "printGLC";
 180 }
 181 def slc : Operand <i1> {
 182   let PrintMethod = "printSLC";
 183 }
 184 def tfe : Operand <i1> {
 185   let PrintMethod = "printTFE";
 186 }
 187
 188 def omod : Operand <i32> {
 189   let PrintMethod = "printOModSI";
 190 }
 191
 192 def ClampMod : Operand <i1> {
 193   let PrintMethod = "printClampSI";
 194 }
 195
 196 } // End OperandType = "OPERAND_IMMEDIATE"
 197
 198 //===----------------------------------------------------------------------===//
 199 // Complex patterns
 200 //===----------------------------------------------------------------------===//
 201
 202 def DS1Addr1Offset : ComplexPattern<i32, 2, "SelectDS1Addr1Offset">;
 203 def DS64Bit4ByteAligned : ComplexPattern<i32, 3, "SelectDS64Bit4ByteAligned">;
 204
 205 def MUBUFAddr32 : ComplexPattern<i64, 9, "SelectMUBUFAddr32">;
 206 def MUBUFAddr64 : ComplexPattern<i64, 3, "SelectMUBUFAddr64">;
 207 def MUBUFAddr64Atomic : ComplexPattern<i64, 4, "SelectMUBUFAddr64">;
 208 def MUBUFScratch : ComplexPattern<i64, 4, "SelectMUBUFScratch">;
 209 def MUBUFOffset : ComplexPattern<i64, 6, "SelectMUBUFOffset">;
 210 def MUBUFOffsetAtomic : ComplexPattern<i64, 4, "SelectMUBUFOffset">;
 211
 212 def VOP3Mods0 : ComplexPattern<untyped, 4, "SelectVOP3Mods0">;
 213 def VOP3Mods  : ComplexPattern<untyped, 2, "SelectVOP3Mods">;
 214
 215 //===----------------------------------------------------------------------===//
 216 // SI assembler operands
 217 //===----------------------------------------------------------------------===//
 218
 219 def SIOperand {
 220   int ZERO = 0x80;
 221   int VCC = 0x6A;
 222   int FLAT_SCR = 0x68;
 223 }
 224
 225 def SRCMODS {
 226   int NONE = 0;
 227 }
 228
 229 def DSTCLAMP {
 230   int NONE = 0;
 231 }
 232
 233 def DSTOMOD {
 234   int NONE = 0;
 235 }
 236
 237 //===----------------------------------------------------------------------===//
 238 //
 239 // SI Instruction multiclass helpers.
 240 //
 241 // Instructions with _32 take 32-bit operands.
 242 // Instructions with _64 take 64-bit operands.
 243 //
 244 // VOP_* instructions can use either a 32-bit or 64-bit encoding.  The 32-bit
 245 // encoding is the standard encoding, but instruction that make use of
 246 // any of the instruction modifiers must use the 64-bit encoding.
 247 //
 248 // Instructions with _e32 use the 32-bit encoding.
 249 // Instructions with _e64 use the 64-bit encoding.
 250 //
 251 //===----------------------------------------------------------------------===//
 252
 253 //===----------------------------------------------------------------------===//
 254 // Scalar classes
 255 //===----------------------------------------------------------------------===//
 256
 257 class SOP1_32 <bits<8> op, string opName, list<dag> pattern> : SOP1 <
 258   op, (outs SReg_32:$dst), (ins SSrc_32:$src0),
 259   opName#" $dst, $src0", pattern
 260 >;
 261
 262 class SOP1_64 <bits<8> op, string opName, list<dag> pattern> : SOP1 <
 263   op, (outs SReg_64:$dst), (ins SSrc_64:$src0),
 264   opName#" $dst, $src0", pattern
 265 >;
 266
 267 // 64-bit input, 32-bit output.
 268 class SOP1_32_64 <bits<8> op, string opName, list<dag> pattern> : SOP1 <
 269   op, (outs SReg_32:$dst), (ins SSrc_64:$src0),
 270   opName#" $dst, $src0", pattern
 271 >;
 272
 273 class SOP2_32 <bits<7> op, string opName, list<dag> pattern> : SOP2 <
 274   op, (outs SReg_32:$dst), (ins SSrc_32:$src0, SSrc_32:$src1),
 275   opName#" $dst, $src0, $src1", pattern
 276 >;
 277
 278 class SOP2_64 <bits<7> op, string opName, list<dag> pattern> : SOP2 <
 279   op, (outs SReg_64:$dst), (ins SSrc_64:$src0, SSrc_64:$src1),
 280   opName#" $dst, $src0, $src1", pattern
 281 >;
 282
 283 class SOP2_SHIFT_64 <bits<7> op, string opName, list<dag> pattern> : SOP2 <
 284   op, (outs SReg_64:$dst), (ins SSrc_64:$src0, SSrc_32:$src1),
 285   opName#" $dst, $src0, $src1", pattern
 286 >;
 287
 288
 289 class SOPC_Helper <bits<7> op, RegisterClass rc, ValueType vt,
 290                     string opName, PatLeaf cond> : SOPC <
 291   op, (outs SCCReg:$dst), (ins rc:$src0, rc:$src1),
 292   opName#" $dst, $src0, $src1", []>;
 293
 294 class SOPC_32<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 295   : SOPC_Helper<op, SSrc_32, i32, opName, cond>;
 296
 297 class SOPC_64<bits<7> op, string opName, PatLeaf cond = COND_NULL>
 298   : SOPC_Helper<op, SSrc_64, i64, opName, cond>;
 299
 300 class SOPK_32 <bits<5> op, string opName, list<dag> pattern> : SOPK <
 301   op, (outs SReg_32:$dst), (ins i16imm:$src0),
 302   opName#" $dst, $src0", pattern
 303 >;
 304
 305 class SOPK_64 <bits<5> op, string opName, list<dag> pattern> : SOPK <
 306   op, (outs SReg_64:$dst), (ins i16imm:$src0),
 307   opName#" $dst, $src0", pattern
 308 >;
 309
 310 multiclass SMRD_Helper <bits<5> op, string asm, RegisterClass baseClass,
 311                         RegisterClass dstClass> {
 312   def _IMM : SMRD <
 313     op, 1, (outs dstClass:$dst),
 314     (ins baseClass:$sbase, u32imm:$offset),
 315     asm#" $dst, $sbase, $offset", []
 316   >;
 317
 318   def _SGPR : SMRD <
 319     op, 0, (outs dstClass:$dst),
 320     (ins baseClass:$sbase, SReg_32:$soff),
 321     asm#" $dst, $sbase, $soff", []
 322   >;
 323 }
 324
 325 //===----------------------------------------------------------------------===//
 326 // Vector ALU classes
 327 //===----------------------------------------------------------------------===//
 328
 329 // This must always be right before the operand being input modified.
 330 def InputMods : OperandWithDefaultOps <i32, (ops (i32 0))> {
 331   let PrintMethod = "printOperandAndMods";
 332 }
 333 def InputModsNoDefault : Operand <i32> {
 334   let PrintMethod = "printOperandAndMods";
 335 }
 336
 337 class getNumSrcArgs<ValueType Src1, ValueType Src2> {
 338   int ret =
 339     !if (!eq(Src1.Value, untyped.Value),      1,   // VOP1
 340          !if (!eq(Src2.Value, untyped.Value), 2,   // VOP2
 341                                               3)); // VOP3
 342 }
 343
 344 // Returns the register class to use for the destination of VOP[123C]
 345 // instructions for the given VT.
 346 class getVALUDstForVT<ValueType VT> {
 347   RegisterClass ret = !if(!eq(VT.Size, 32), VReg_32, VReg_64);
 348 }
 349
 350 // Returns the register class to use for source 0 of VOP[12C]
 351 // instructions for the given VT.
 352 class getVOPSrc0ForVT<ValueType VT> {
 353   RegisterClass ret = !if(!eq(VT.Size, 32), VSrc_32, VSrc_64);
 354 }
 355
 356 // Returns the register class to use for source 1 of VOP[12C] for the
 357 // given VT.
 358 class getVOPSrc1ForVT<ValueType VT> {
 359   RegisterClass ret = !if(!eq(VT.Size, 32), VReg_32, VReg_64);
 360 }
 361
 362 // Returns the register classes for the source arguments of a VOP[12C]
 363 // instruction for the given SrcVTs.
 364 class getInRC32 <list<ValueType> SrcVT> {
 365   list<RegisterClass> ret = [
 366     getVOPSrc0ForVT<SrcVT[0]>.ret,
 367     getVOPSrc1ForVT<SrcVT[1]>.ret
 368   ];
 369 }
 370
 371 // Returns the register class to use for sources of VOP3 instructions for the
 372 // given VT.
 373 class getVOP3SrcForVT<ValueType VT> {
 374   RegisterClass ret = !if(!eq(VT.Size, 32), VCSrc_32, VCSrc_64);
 375 }
 376
 377 // Returns the register classes for the source arguments of a VOP3
 378 // instruction for the given SrcVTs.
 379 class getInRC64 <list<ValueType> SrcVT> {
 380   list<RegisterClass> ret = [
 381     getVOP3SrcForVT<SrcVT[0]>.ret,
 382     getVOP3SrcForVT<SrcVT[1]>.ret,
 383     getVOP3SrcForVT<SrcVT[2]>.ret
 384   ];
 385 }
 386
 387 // Returns 1 if the source arguments have modifiers, 0 if they do not.
 388 class hasModifiers<ValueType SrcVT> {
 389   bit ret = !if(!eq(SrcVT.Value, f32.Value), 1,
 390             !if(!eq(SrcVT.Value, f64.Value), 1, 0));
 391 }
 392
 393 // Returns the input arguments for VOP[12C] instructions for the given SrcVT.
 394 class getIns32 <RegisterClass Src0RC, RegisterClass Src1RC, int NumSrcArgs> {
 395   dag ret = !if(!eq(NumSrcArgs, 1), (ins Src0RC:$src0),               // VOP1
 396             !if(!eq(NumSrcArgs, 2), (ins Src0RC:$src0, Src1RC:$src1), // VOP2
 397                                     (ins)));
 398 }
 399
 400 // Returns the input arguments for VOP3 instructions for the given SrcVT.
 401 class getIns64 <RegisterClass Src0RC, RegisterClass Src1RC,
 402                 RegisterClass Src2RC, int NumSrcArgs,
 403                 bit HasModifiers> {
 404
 405   dag ret =
 406     !if (!eq(NumSrcArgs, 1),
 407       !if (!eq(HasModifiers, 1),
 408         // VOP1 with modifiers
 409         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 410              ClampMod:$clamp, omod:$omod)
 411       /* else */,
 412         // VOP1 without modifiers
 413         (ins Src0RC:$src0)
 414       /* endif */ ),
 415     !if (!eq(NumSrcArgs, 2),
 416       !if (!eq(HasModifiers, 1),
 417         // VOP 2 with modifiers
 418         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 419              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 420              ClampMod:$clamp, omod:$omod)
 421       /* else */,
 422         // VOP2 without modifiers
 423         (ins Src0RC:$src0, Src1RC:$src1)
 424       /* endif */ )
 425     /* NumSrcArgs == 3 */,
 426       !if (!eq(HasModifiers, 1),
 427         // VOP3 with modifiers
 428         (ins InputModsNoDefault:$src0_modifiers, Src0RC:$src0,
 429              InputModsNoDefault:$src1_modifiers, Src1RC:$src1,
 430              InputModsNoDefault:$src2_modifiers, Src2RC:$src2,
 431              ClampMod:$clamp, omod:$omod)
 432       /* else */,
 433         // VOP3 without modifiers
 434         (ins Src0RC:$src0, Src1RC:$src1, Src2RC:$src2)
 435       /* endif */ )));
 436 }
 437
 438 // Returns the assembly string for the inputs and outputs of a VOP[12C]
 439 // instruction.  This does not add the _e32 suffix, so it can be reused
 440 // by getAsm64.
 441 class getAsm32 <int NumSrcArgs> {
 442   string src1 = ", $src1";
 443   string src2 = ", $src2";
 444   string ret = " $dst, $src0"#
 445                !if(!eq(NumSrcArgs, 1), "", src1)#
 446                !if(!eq(NumSrcArgs, 3), src2, "");
 447 }
 448
 449 // Returns the assembly string for the inputs and outputs of a VOP3
 450 // instruction.
 451 class getAsm64 <int NumSrcArgs, bit HasModifiers> {
 452   string src0 = "$src0_modifiers,";
 453   string src1 = !if(!eq(NumSrcArgs, 1), "",
 454                    !if(!eq(NumSrcArgs, 2), " $src1_modifiers",
 455                                            " $src1_modifiers,"));
 456   string src2 = !if(!eq(NumSrcArgs, 3), " $src2_modifiers", "");
 457   string ret =
 458   !if(!eq(HasModifiers, 0),
 459       getAsm32<NumSrcArgs>.ret,
 460       " $dst, "#src0#src1#src2#"$clamp"#"$omod");
 461 }
 462
 463
 464 class VOPProfile <list<ValueType> _ArgVT> {
 465
 466   field list<ValueType> ArgVT = _ArgVT;
 467
 468   field ValueType DstVT = ArgVT[0];
 469   field ValueType Src0VT = ArgVT[1];
 470   field ValueType Src1VT = ArgVT[2];
 471   field ValueType Src2VT = ArgVT[3];
 472   field RegisterClass DstRC = getVALUDstForVT<DstVT>.ret;
 473   field RegisterClass Src0RC32 = getVOPSrc0ForVT<Src0VT>.ret;
 474   field RegisterClass Src1RC32 = getVOPSrc1ForVT<Src1VT>.ret;
 475   field RegisterClass Src0RC64 = getVOP3SrcForVT<Src0VT>.ret;
 476   field RegisterClass Src1RC64 = getVOP3SrcForVT<Src1VT>.ret;
 477   field RegisterClass Src2RC64 = getVOP3SrcForVT<Src2VT>.ret;
 478
 479   field int NumSrcArgs = getNumSrcArgs<Src1VT, Src2VT>.ret;
 480   field bit HasModifiers = hasModifiers<Src0VT>.ret;
 481
 482   field dag Outs = (outs DstRC:$dst);
 483
 484   field dag Ins32 = getIns32<Src0RC32, Src1RC32, NumSrcArgs>.ret;
 485   field dag Ins64 = getIns64<Src0RC64, Src1RC64, Src2RC64, NumSrcArgs,
 486                              HasModifiers>.ret;
 487
 488   field string Asm32 = "_e32"#getAsm32<NumSrcArgs>.ret;
 489   field string Asm64 = getAsm64<NumSrcArgs, HasModifiers>.ret;
 490 }
 491
 492 def VOP_F32_F32 : VOPProfile <[f32, f32, untyped, untyped]>;
 493 def VOP_F32_F64 : VOPProfile <[f32, f64, untyped, untyped]>;
 494 def VOP_F32_I32 : VOPProfile <[f32, i32, untyped, untyped]>;
 495 def VOP_F64_F32 : VOPProfile <[f64, f32, untyped, untyped]>;
 496 def VOP_F64_F64 : VOPProfile <[f64, f64, untyped, untyped]>;
 497 def VOP_F64_I32 : VOPProfile <[f64, i32, untyped, untyped]>;
 498 def VOP_I32_F32 : VOPProfile <[i32, f32, untyped, untyped]>;
 499 def VOP_I32_F64 : VOPProfile <[i32, f64, untyped, untyped]>;
 500 def VOP_I32_I32 : VOPProfile <[i32, i32, untyped, untyped]>;
 501
 502 def VOP_F32_F32_F32 : VOPProfile <[f32, f32, f32, untyped]>;
 503 def VOP_F32_F32_I32 : VOPProfile <[f32, f32, i32, untyped]>;
 504 def VOP_F64_F64_F64 : VOPProfile <[f64, f64, f64, untyped]>;
 505 def VOP_F64_F64_I32 : VOPProfile <[f64, f64, i32, untyped]>;
 506 def VOP_I32_F32_F32 : VOPProfile <[i32, f32, f32, untyped]>;
 507 def VOP_I32_I32_I32 : VOPProfile <[i32, i32, i32, untyped]>;
 508 def VOP_I32_I32_I32_VCC : VOPProfile <[i32, i32, i32, untyped]> {
 509   let Src0RC32 = VCSrc_32;
 510 }
 511 def VOP_I64_I64_I32 : VOPProfile <[i64, i64, i32, untyped]>;
 512 def VOP_I64_I64_I64 : VOPProfile <[i64, i64, i64, untyped]>;
 513
 514 def VOP_F32_F32_F32_F32 : VOPProfile <[f32, f32, f32, f32]>;
 515 def VOP_F64_F64_F64_F64 : VOPProfile <[f64, f64, f64, f64]>;
 516 def VOP_I32_I32_I32_I32 : VOPProfile <[i32, i32, i32, i32]>;
 517 def VOP_I64_I32_I32_I64 : VOPProfile <[i64, i32, i32, i64]>;
 518
 519
 520 class VOP <string opName> {
 521   string OpName = opName;
 522 }
 523
 524 class VOP2_REV <string revOp, bit isOrig> {
 525   string RevOp = revOp;
 526   bit IsOrig = isOrig;
 527 }
 528
 529 class AtomicNoRet <string noRetOp, bit isRet> {
 530   string NoRetOp = noRetOp;
 531   bit IsRet = isRet;
 532 }
 533
 534 class SIMCInstr <string pseudo, int subtarget> {
 535   string PseudoInstr = pseudo;
 536   int Subtarget = subtarget;
 537 }
 538
 539 class VOP3DisableFields <bit HasSrc1, bit HasSrc2, bit HasModifiers> {
 540
 541   bits<2> src0_modifiers = !if(HasModifiers, ?, 0);
 542   bits<2> src1_modifiers = !if(HasModifiers, !if(HasSrc1, ?, 0), 0);
 543   bits<2> src2_modifiers = !if(HasModifiers, !if(HasSrc2, ? ,0) ,0);
 544   bits<2> omod = !if(HasModifiers, ?, 0);
 545   bits<1> clamp = !if(HasModifiers, ?, 0);
 546   bits<9> src1 = !if(HasSrc1, ?, 0);
 547   bits<9> src2 = !if(HasSrc2, ?, 0);
 548 }
 549
 550 class VOP3_Pseudo <dag outs, dag ins, list<dag> pattern, string opName> :
 551   VOP3Common <outs, ins, "", pattern>,
 552   VOP <opName>,
 553   SIMCInstr<opName, SISubtarget.NONE> {
 554   let isPseudo = 1;
 555 }
 556
 557 class VOP3_Real_si <bits<9> op, dag outs, dag ins, string asm, string opName> :
 558   VOP3 <op, outs, ins, asm, []>,
 559   SIMCInstr<opName, SISubtarget.SI>;
 560
 561 multiclass VOP3_m <bits<9> op, dag outs, dag ins, string asm, list<dag> pattern,
 562                    string opName, int NumSrcArgs, bit HasMods = 1> {
 563
 564   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 565
 566   def _si : VOP3_Real_si <op, outs, ins, asm, opName>,
 567             VOP3DisableFields<!if(!eq(NumSrcArgs, 1), 0, 1),
 568                               !if(!eq(NumSrcArgs, 2), 0, 1),
 569                               HasMods>;
 570
 571 }
 572
 573 multiclass VOP3_1_m <bits<8> op, dag outs, dag ins, string asm,
 574                      list<dag> pattern, string opName, bit HasMods = 1> {
 575
 576   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 577
 578   def _si : VOP3_Real_si <
 579               {1, 1, op{6}, op{5}, op{4}, op{3}, op{2}, op{1}, op{0}},
 580               outs, ins, asm, opName>,
 581             VOP3DisableFields<0, 0, HasMods>;
 582 }
 583
 584 multiclass VOP3_2_m <bits<9> op, dag outs, dag ins, string asm,
 585                      list<dag> pattern, string opName, string revOp,
 586                      bit HasMods = 1, bit UseFullOp = 0> {
 587
 588   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
 589            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
 590
 591   def _si : VOP3_Real_si <op,
 592               outs, ins, asm, opName>,
 593             VOP2_REV<revOp#"_e64_si", !eq(revOp, opName)>,
 594             VOP3DisableFields<1, 0, HasMods>;
 595 }
 596
 597 multiclass VOP3b_2_m <bits<9> op, dag outs, dag ins, string asm,
 598                       list<dag> pattern, string opName, string revOp,
 599                       bit HasMods = 1, bit UseFullOp = 0> {
 600   def "" : VOP3_Pseudo <outs, ins, pattern, opName>,
 601            VOP2_REV<revOp#"_e64", !eq(revOp, opName)>;
 602
 603   // The VOP2 variant puts the carry out into VCC, the VOP3 variant
 604   // can write it into any SGPR. We currently don't use the carry out,
 605   // so for now hardcode it to VCC as well.
 606   let sdst = SIOperand.VCC, Defs = [VCC] in {
 607     def _si : VOP3b <op, outs, ins, asm, pattern>,
 608               VOP3DisableFields<1, 0, HasMods>,
 609               SIMCInstr<opName, SISubtarget.SI>,
 610               VOP2_REV<revOp#"_e64_si", !eq(revOp, opName)>;
 611   } // End sdst = SIOperand.VCC, Defs = [VCC]
 612 }
 613
 614 multiclass VOP3_C_m <bits<8> op, dag outs, dag ins, string asm,
 615                      list<dag> pattern, string opName,
 616                      bit HasMods, bit defExec> {
 617
 618   def "" : VOP3_Pseudo <outs, ins, pattern, opName>;
 619
 620     def _si : VOP3_Real_si <
 621                 {0, op{7}, op{6}, op{5}, op{4}, op{3}, op{2}, op{1}, op{0}},
 622                 outs, ins, asm, opName>,
 623               VOP3DisableFields<1, 0, HasMods> {
 624   let Defs = !if(defExec, [EXEC], []);
 625   }
 626 }
 627
 628 multiclass VOP1_Helper <bits<8> op, string opName, dag outs,
 629                         dag ins32, string asm32, list<dag> pat32,
 630                         dag ins64, string asm64, list<dag> pat64,
 631                         bit HasMods> {
 632
 633   def _e32 : VOP1 <op, outs, ins32, opName#asm32, pat32>, VOP<opName>;
 634
 635   defm _e64 : VOP3_1_m <op, outs, ins64, opName#"_e64"#asm64, pat64, opName, HasMods>;
 636 }
 637
 638 multiclass VOP1Inst <bits<8> op, string opName, VOPProfile P,
 639                      SDPatternOperator node = null_frag> : VOP1_Helper <
 640   op, opName, P.Outs,
 641   P.Ins32, P.Asm32, [],
 642   P.Ins64, P.Asm64,
 643   !if(P.HasModifiers,
 644       [(set P.DstVT:$dst, (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0,
 645                                 i32:$src0_modifiers, i1:$clamp, i32:$omod))))],
 646       [(set P.DstVT:$dst, (node P.Src0VT:$src0))]),
 647   P.HasModifiers
 648 >;
 649
 650 class VOP2_e32 <bits<6> op, string opName, dag outs, dag ins, string asm,
 651                 list<dag> pattern, string revOp> :
 652   VOP2 <op, outs, ins, opName#asm, pattern>,
 653   VOP <opName>,
 654   VOP2_REV<revOp#"_e32", !eq(revOp, opName)>;
 655
 656 multiclass VOP2_Helper <bits<6> op, string opName, dag outs,
 657                         dag ins32, string asm32, list<dag> pat32,
 658                         dag ins64, string asm64, list<dag> pat64,
 659                         string revOp, bit HasMods> {
 660   def _e32 : VOP2_e32 <op, opName, outs, ins32, asm32, pat32, revOp>;
 661
 662   defm _e64 : VOP3_2_m <
 663     {1, 0, 0, op{5}, op{4}, op{3}, op{2}, op{1}, op{0}},
 664     outs, ins64, opName#"_e64"#asm64, pat64, opName, revOp, HasMods
 665   >;
 666 }
 667
 668 multiclass VOP2Inst <bits<6> op, string opName, VOPProfile P,
 669                      SDPatternOperator node = null_frag,
 670                      string revOp = opName> : VOP2_Helper <
 671   op, opName, P.Outs,
 672   P.Ins32, P.Asm32, [],
 673   P.Ins64, P.Asm64,
 674   !if(P.HasModifiers,
 675       [(set P.DstVT:$dst,
 676            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 677                                       i1:$clamp, i32:$omod)),
 678                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
 679       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
 680   revOp, P.HasModifiers
 681 >;
 682
 683 multiclass VOP2b_Helper <bits<6> op, string opName, dag outs,
 684                          dag ins32, string asm32, list<dag> pat32,
 685                          dag ins64, string asm64, list<dag> pat64,
 686                          string revOp, bit HasMods> {
 687
 688   def _e32 : VOP2_e32 <op, opName, outs, ins32, asm32, pat32, revOp>;
 689
 690   defm _e64 : VOP3b_2_m <
 691     {1, 0, 0, op{5}, op{4}, op{3}, op{2}, op{1}, op{0}},
 692     outs, ins64, opName#"_e64"#asm64, pat64, opName, revOp, HasMods
 693   >;
 694 }
 695
 696 multiclass VOP2bInst <bits<6> op, string opName, VOPProfile P,
 697                       SDPatternOperator node = null_frag,
 698                       string revOp = opName> : VOP2b_Helper <
 699   op, opName, P.Outs,
 700   P.Ins32, P.Asm32, [],
 701   P.Ins64, P.Asm64,
 702   !if(P.HasModifiers,
 703       [(set P.DstVT:$dst,
 704            (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 705                                       i1:$clamp, i32:$omod)),
 706                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
 707       [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))]),
 708   revOp, P.HasModifiers
 709 >;
 710
 711 multiclass VOPC_Helper <bits<8> op, string opName,
 712                         dag ins32, string asm32, list<dag> pat32,
 713                         dag out64, dag ins64, string asm64, list<dag> pat64,
 714                         bit HasMods, bit DefExec> {
 715   def _e32 : VOPC <op, ins32, opName#asm32, pat32>, VOP <opName> {
 716     let Defs = !if(DefExec, [EXEC], []);
 717   }
 718
 719   defm _e64 : VOP3_C_m <op, out64, ins64, opName#"_e64"#asm64, pat64, opName,
 720                         HasMods, DefExec>;
 721 }
 722
 723 multiclass VOPCInst <bits<8> op, string opName,
 724                      VOPProfile P, PatLeaf cond = COND_NULL,
 725                      bit DefExec = 0> : VOPC_Helper <
 726   op, opName,
 727   P.Ins32, P.Asm32, [],
 728   (outs SReg_64:$dst), P.Ins64, P.Asm64,
 729   !if(P.HasModifiers,
 730       [(set i1:$dst,
 731           (setcc (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 732                                       i1:$clamp, i32:$omod)),
 733                  (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
 734                  cond))],
 735       [(set i1:$dst, (setcc P.Src0VT:$src0, P.Src1VT:$src1, cond))]),
 736   P.HasModifiers, DefExec
 737 >;
 738
 739 multiclass VOPC_F32 <bits<8> op, string opName, PatLeaf cond = COND_NULL> :
 740   VOPCInst <op, opName, VOP_F32_F32_F32, cond>;
 741
 742 multiclass VOPC_F64 <bits<8> op, string opName, PatLeaf cond = COND_NULL> :
 743   VOPCInst <op, opName, VOP_F64_F64_F64, cond>;
 744
 745 multiclass VOPC_I32 <bits<8> op, string opName, PatLeaf cond = COND_NULL> :
 746   VOPCInst <op, opName, VOP_I32_I32_I32, cond>;
 747
 748 multiclass VOPC_I64 <bits<8> op, string opName, PatLeaf cond = COND_NULL> :
 749   VOPCInst <op, opName, VOP_I64_I64_I64, cond>;
 750
 751
 752 multiclass VOPCX <bits<8> op, string opName, VOPProfile P,
 753                   PatLeaf cond = COND_NULL>
 754   : VOPCInst <op, opName, P, cond, 1>;
 755
 756 multiclass VOPCX_F32 <bits<8> op, string opName, PatLeaf cond = COND_NULL> :
 757   VOPCX <op, opName, VOP_F32_F32_F32, cond>;
 758
 759 multiclass VOPCX_F64 <bits<8> op, string opName, PatLeaf cond = COND_NULL> :
 760   VOPCX <op, opName, VOP_F64_F64_F64, cond>;
 761
 762 multiclass VOPCX_I32 <bits<8> op, string opName, PatLeaf cond = COND_NULL> :
 763   VOPCX <op, opName, VOP_I32_I32_I32, cond>;
 764
 765 multiclass VOPCX_I64 <bits<8> op, string opName, PatLeaf cond = COND_NULL> :
 766   VOPCX <op, opName, VOP_I64_I64_I64, cond>;
 767
 768 multiclass VOP3_Helper <bits<9> op, string opName, dag outs, dag ins, string asm,
 769                         list<dag> pat, int NumSrcArgs, bit HasMods> : VOP3_m <
 770     op, outs, ins, opName#asm, pat, opName, NumSrcArgs, HasMods
 771 >;
 772
 773 multiclass VOP3Inst <bits<9> op, string opName, VOPProfile P,
 774                      SDPatternOperator node = null_frag> : VOP3_Helper <
 775   op, opName, P.Outs, P.Ins64, P.Asm64,
 776   !if(!eq(P.NumSrcArgs, 3),
 777     !if(P.HasModifiers,
 778         [(set P.DstVT:$dst,
 779             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 780                                        i1:$clamp, i32:$omod)),
 781                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
 782                   (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))))],
 783         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1,
 784                                   P.Src2VT:$src2))]),
 785   !if(!eq(P.NumSrcArgs, 2),
 786     !if(P.HasModifiers,
 787         [(set P.DstVT:$dst,
 788             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 789                                        i1:$clamp, i32:$omod)),
 790                   (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers))))],
 791         [(set P.DstVT:$dst, (node P.Src0VT:$src0, P.Src1VT:$src1))])
 792   /* P.NumSrcArgs == 1 */,
 793     !if(P.HasModifiers,
 794         [(set P.DstVT:$dst,
 795             (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers,
 796                                        i1:$clamp, i32:$omod))))],
 797         [(set P.DstVT:$dst, (node P.Src0VT:$src0))]))),
 798   P.NumSrcArgs, P.HasModifiers
 799 >;
 800
 801 multiclass VOP3b_Helper <bits<9> op, RegisterClass vrc, RegisterClass arc,
 802                     string opName, list<dag> pattern> :
 803   VOP3b_2_m <
 804   op, (outs vrc:$dst0, SReg_64:$dst1),
 805       (ins InputModsNoDefault:$src0_modifiers, arc:$src0,
 806            InputModsNoDefault:$src1_modifiers, arc:$src1,
 807            InputModsNoDefault:$src2_modifiers, arc:$src2,
 808            ClampMod:$clamp, i32imm:$omod),
 809   opName#" $dst0, $dst1, $src0_modifiers, $src1_modifiers, $src2_modifiers"#"$clamp"#"$omod", pattern,
 810   opName, opName, 1, 1
 811 >;
 812
 813 multiclass VOP3b_64 <bits<9> op, string opName, list<dag> pattern> :
 814   VOP3b_Helper <op, VReg_64, VSrc_64, opName, pattern>;
 815
 816 multiclass VOP3b_32 <bits<9> op, string opName, list<dag> pattern> :
 817   VOP3b_Helper <op, VReg_32, VSrc_32, opName, pattern>;
 818
 819
 820 class Vop3ModPat<Instruction Inst, VOPProfile P, SDPatternOperator node> : Pat<
 821   (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0, i32:$src0_modifiers, i1:$clamp, i32:$omod)),
 822         (P.Src1VT (VOP3Mods P.Src1VT:$src1, i32:$src1_modifiers)),
 823         (P.Src2VT (VOP3Mods P.Src2VT:$src2, i32:$src2_modifiers))),
 824   (Inst i32:$src0_modifiers, P.Src0VT:$src0,
 825         i32:$src1_modifiers, P.Src1VT:$src1,
 826         i32:$src2_modifiers, P.Src2VT:$src2,
 827         i1:$clamp,
 828         i32:$omod)>;
 829
 830 //===----------------------------------------------------------------------===//
 831 // Vector I/O classes
 832 //===----------------------------------------------------------------------===//
 833
 834 class DS_1A <bits<8> op, dag outs, dag ins, string asm, list<dag> pat> :
 835     DS <op, outs, ins, asm, pat> {
 836   bits<16> offset;
 837
 838   // Single load interpret the 2 i8imm operands as a single i16 offset.
 839   let offset0 = offset{7-0};
 840   let offset1 = offset{15-8};
 841 }
 842
 843 class DS_Load_Helper <bits<8> op, string asm, RegisterClass regClass> : DS_1A <
 844   op,
 845   (outs regClass:$vdst),
 846   (ins i1imm:$gds, VReg_32:$addr, u16imm:$offset),
 847   asm#" $vdst, $addr, $offset, [M0]",
 848   []> {
 849   let data0 = 0;
 850   let data1 = 0;
 851   let mayLoad = 1;
 852   let mayStore = 0;
 853 }
 854
 855 class DS_Load2_Helper <bits<8> op, string asm, RegisterClass regClass> : DS <
 856   op,
 857   (outs regClass:$vdst),
 858   (ins i1imm:$gds, VReg_32:$addr, u8imm:$offset0, u8imm:$offset1),
 859   asm#" $vdst, $addr, $offset0, $offset1, [M0]",
 860   []> {
 861   let data0 = 0;
 862   let data1 = 0;
 863   let mayLoad = 1;
 864   let mayStore = 0;
 865 }
 866
 867 class DS_Store_Helper <bits<8> op, string asm, RegisterClass regClass> : DS_1A <
 868   op,
 869   (outs),
 870   (ins i1imm:$gds, VReg_32:$addr, regClass:$data0, u16imm:$offset),
 871   asm#" $addr, $data0, $offset [M0]",
 872   []> {
 873   let data1 = 0;
 874   let mayStore = 1;
 875   let mayLoad = 0;
 876   let vdst = 0;
 877 }
 878
 879 class DS_Store2_Helper <bits<8> op, string asm, RegisterClass regClass> : DS <
 880   op,
 881   (outs),
 882   (ins i1imm:$gds, VReg_32:$addr, regClass:$data0, regClass:$data1,
 883        u8imm:$offset0, u8imm:$offset1),
 884   asm#" $addr, $data0, $data1, $offset0, $offset1 [M0]",
 885   []> {
 886   let mayStore = 1;
 887   let mayLoad = 0;
 888   let vdst = 0;
 889 }
 890
 891 // 1 address, 1 data.
 892 class DS_1A1D_RET <bits<8> op, string asm, RegisterClass rc, string noRetOp = ""> : DS_1A <
 893   op,
 894   (outs rc:$vdst),
 895   (ins i1imm:$gds, VReg_32:$addr, rc:$data0, u16imm:$offset),
 896   asm#" $vdst, $addr, $data0, $offset, [M0]", []>,
 897   AtomicNoRet<noRetOp, 1> {
 898
 899   let data1 = 0;
 900   let mayStore = 1;
 901   let mayLoad = 1;
 902
 903   let hasPostISelHook = 1; // Adjusted to no return version.
 904 }
 905
 906 // 1 address, 2 data.
 907 class DS_1A2D_RET <bits<8> op, string asm, RegisterClass rc, string noRetOp = ""> : DS_1A <
 908   op,
 909   (outs rc:$vdst),
 910   (ins i1imm:$gds, VReg_32:$addr, rc:$data0, rc:$data1, u16imm:$offset),
 911   asm#" $vdst, $addr, $data0, $data1, $offset, [M0]",
 912   []>,
 913   AtomicNoRet<noRetOp, 1> {
 914   let mayStore = 1;
 915   let mayLoad = 1;
 916
 917   let hasPostISelHook = 1; // Adjusted to no return version.
 918 }
 919
 920 // 1 address, 2 data.
 921 class DS_1A2D_NORET <bits<8> op, string asm, RegisterClass rc, string noRetOp = asm> : DS_1A <
 922   op,
 923   (outs),
 924   (ins i1imm:$gds, VReg_32:$addr, rc:$data0, rc:$data1, u16imm:$offset),
 925   asm#" $addr, $data0, $data1, $offset, [M0]",
 926   []>,
 927   AtomicNoRet<noRetOp, 0> {
 928   let mayStore = 1;
 929   let mayLoad = 1;
 930 }
 931
 932 // 1 address, 1 data.
 933 class DS_1A1D_NORET <bits<8> op, string asm, RegisterClass rc, string noRetOp = asm> : DS_1A <
 934   op,
 935   (outs),
 936   (ins i1imm:$gds, VReg_32:$addr, rc:$data0, u16imm:$offset),
 937   asm#" $addr, $data0, $offset, [M0]",
 938   []>,
 939   AtomicNoRet<noRetOp, 0> {
 940
 941   let data1 = 0;
 942   let mayStore = 1;
 943   let mayLoad = 1;
 944 }
 945
 946 class MUBUFAddr64Table <bit is_addr64, string suffix = ""> {
 947
 948   bit IsAddr64 = is_addr64;
 949   string OpName = NAME # suffix;
 950 }
 951
 952 class MTBUF_Store_Helper <bits<3> op, string asm, RegisterClass regClass> : MTBUF <
 953   op,
 954   (outs),
 955   (ins regClass:$vdata, u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc,
 956    i1imm:$addr64, i8imm:$dfmt, i8imm:$nfmt, VReg_32:$vaddr,
 957    SReg_128:$srsrc, i1imm:$slc, i1imm:$tfe, SSrc_32:$soffset),
 958   asm#" $vdata, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
 959      #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset",
 960   []> {
 961   let mayStore = 1;
 962   let mayLoad = 0;
 963 }
 964
 965 class MUBUFAtomicAddr64 <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern>
 966     : MUBUF <op, outs, ins, asm, pattern> {
 967
 968   let offen = 0;
 969   let idxen = 0;
 970   let addr64 = 1;
 971   let tfe = 0;
 972   let lds = 0;
 973   let soffset = 128;
 974 }
 975
 976 class MUBUFAtomicOffset <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern>
 977     : MUBUF <op, outs, ins, asm, pattern> {
 978
 979   let offen = 0;
 980   let idxen = 0;
 981   let addr64 = 0;
 982   let tfe = 0;
 983   let lds = 0;
 984   let vaddr = 0;
 985 }
 986
 987 multiclass MUBUF_Atomic <bits<7> op, string name, RegisterClass rc,
 988                          ValueType vt, SDPatternOperator atomic> {
 989
 990   let mayStore = 1, mayLoad = 1, hasPostISelHook = 1 in {
 991
 992     // No return variants
 993     let glc = 0 in {
 994
 995       def _ADDR64 : MUBUFAtomicAddr64 <
 996         op, (outs),
 997         (ins rc:$vdata, SReg_128:$srsrc, VReg_64:$vaddr,
 998              mbuf_offset:$offset, slc:$slc),
 999         name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset"#"$slc", []
1000       >, MUBUFAddr64Table<1>, AtomicNoRet<NAME#"_ADDR64", 0>;
1001
1002       def _OFFSET : MUBUFAtomicOffset <
1003         op, (outs),
1004         (ins rc:$vdata, SReg_128:$srsrc, mbuf_offset:$offset,
1005              SSrc_32:$soffset, slc:$slc),
1006         name#" $vdata, $srsrc, $soffset"#"$offset"#"$slc", []
1007       >, MUBUFAddr64Table<0>, AtomicNoRet<NAME#"_OFFSET", 0>;
1008     } // glc = 0
1009
1010     // Variant that return values
1011     let glc = 1, Constraints = "$vdata = $vdata_in",
1012         DisableEncoding = "$vdata_in"  in {
1013
1014       def _RTN_ADDR64 : MUBUFAtomicAddr64 <
1015         op, (outs rc:$vdata),
1016         (ins rc:$vdata_in, SReg_128:$srsrc, VReg_64:$vaddr,
1017              mbuf_offset:$offset, slc:$slc),
1018         name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset"#" glc"#"$slc",
1019         [(set vt:$vdata,
1020          (atomic (MUBUFAddr64Atomic v4i32:$srsrc, i64:$vaddr, i16:$offset,
1021                                     i1:$slc), vt:$vdata_in))]
1022       >, MUBUFAddr64Table<1, "_RTN">, AtomicNoRet<NAME#"_ADDR64", 1>;
1023
1024       def _RTN_OFFSET : MUBUFAtomicOffset <
1025         op, (outs rc:$vdata),
1026         (ins rc:$vdata_in, SReg_128:$srsrc, mbuf_offset:$offset,
1027              SSrc_32:$soffset, slc:$slc),
1028         name#" $vdata, $srsrc, $soffset"#"$offset"#" glc $slc",
1029         [(set vt:$vdata,
1030          (atomic (MUBUFOffsetAtomic v4i32:$srsrc, i32:$soffset, i16:$offset,
1031                                     i1:$slc), vt:$vdata_in))]
1032       >, MUBUFAddr64Table<0, "_RTN">, AtomicNoRet<NAME#"_OFFSET", 1>;
1033
1034     } // glc = 1
1035
1036   } // mayStore = 1, mayLoad = 1, hasPostISelHook = 1
1037 }
1038
1039 multiclass MUBUF_Load_Helper <bits<7> op, string asm, RegisterClass regClass,
1040                               ValueType load_vt = i32,
1041                               SDPatternOperator ld = null_frag> {
1042
1043   let lds = 0, mayLoad = 1 in {
1044
1045     let addr64 = 0 in {
1046
1047       let offen = 0, idxen = 0, vaddr = 0 in {
1048         def _OFFSET : MUBUF <op, (outs regClass:$vdata),
1049                              (ins SReg_128:$srsrc,
1050                              mbuf_offset:$offset, SSrc_32:$soffset, glc:$glc,
1051                              slc:$slc, tfe:$tfe),
1052                              asm#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1053                              [(set load_vt:$vdata, (ld (MUBUFOffset v4i32:$srsrc,
1054                                                        i32:$soffset, i16:$offset,
1055                                                        i1:$glc, i1:$slc, i1:$tfe)))]>,
1056                      MUBUFAddr64Table<0>;
1057       }
1058
1059       let offen = 1, idxen = 0  in {
1060         def _OFFEN  : MUBUF <op, (outs regClass:$vdata),
1061                              (ins SReg_128:$srsrc, VReg_32:$vaddr,
1062                              SSrc_32:$soffset, mbuf_offset:$offset, glc:$glc, slc:$slc,
1063                              tfe:$tfe),
1064                              asm#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1065       }
1066
1067       let offen = 0, idxen = 1 in {
1068         def _IDXEN  : MUBUF <op, (outs regClass:$vdata),
1069                              (ins SReg_128:$srsrc, VReg_32:$vaddr,
1070                              mbuf_offset:$offset, SSrc_32:$soffset, glc:$glc,
1071                              slc:$slc, tfe:$tfe),
1072                              asm#" $vdata, $vaddr, $srsrc, $soffset idxen"#"$offset"#"$glc"#"$slc"#"$tfe", []>;
1073       }
1074
1075       let offen = 1, idxen = 1 in {
1076         def _BOTHEN : MUBUF <op, (outs regClass:$vdata),
1077                              (ins SReg_128:$srsrc, VReg_64:$vaddr,
1078                              SSrc_32:$soffset, glc:$glc, slc:$slc, tfe:$tfe),
1079                              asm#" $vdata, $vaddr, $srsrc, $soffset, idxen offen"#"$glc"#"$slc"#"$tfe", []>;
1080       }
1081     }
1082
1083     let offen = 0, idxen = 0, addr64 = 1, glc = 0, slc = 0, tfe = 0, soffset = 128 /* ZERO */ in {
1084       def _ADDR64 : MUBUF <op, (outs regClass:$vdata),
1085                            (ins SReg_128:$srsrc, VReg_64:$vaddr, mbuf_offset:$offset),
1086                            asm#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset",
1087                            [(set load_vt:$vdata, (ld (MUBUFAddr64 v4i32:$srsrc,
1088                                                   i64:$vaddr, i16:$offset)))]>, MUBUFAddr64Table<1>;
1089     }
1090   }
1091 }
1092
1093 multiclass MUBUF_Store_Helper <bits<7> op, string name, RegisterClass vdataClass,
1094                           ValueType store_vt, SDPatternOperator st> {
1095
1096   let addr64 = 0, lds = 0 in {
1097
1098     def "" : MUBUF <
1099       op, (outs),
1100       (ins vdataClass:$vdata, SReg_128:$srsrc, VReg_32:$vaddr, SSrc_32:$soffset,
1101            mbuf_offset:$offset, offen:$offen, idxen:$idxen, glc:$glc, slc:$slc,
1102            tfe:$tfe),
1103       name#" $vdata, $vaddr, $srsrc, $soffset"#"$offen"#"$idxen"#"$offset"#
1104            "$glc"#"$slc"#"$tfe",
1105       []
1106     >;
1107
1108     let offen = 0, idxen = 0, vaddr = 0 in {
1109       def _OFFSET : MUBUF <
1110         op, (outs),
1111         (ins vdataClass:$vdata, SReg_128:$srsrc, mbuf_offset:$offset,
1112               SSrc_32:$soffset, glc:$glc, slc:$slc, tfe:$tfe),
1113         name#" $vdata, $srsrc, $soffset"#"$offset"#"$glc"#"$slc"#"$tfe",
1114         [(st store_vt:$vdata, (MUBUFOffset v4i32:$srsrc, i32:$soffset,
1115                                            i16:$offset, i1:$glc, i1:$slc,
1116                                            i1:$tfe))]
1117       >, MUBUFAddr64Table<0>;
1118     } // offen = 0, idxen = 0, vaddr = 0
1119
1120     let offen = 1, idxen = 0  in {
1121       def _OFFEN  : MUBUF <
1122         op, (outs),
1123         (ins vdataClass:$vdata, SReg_128:$srsrc, VReg_32:$vaddr, SSrc_32:$soffset,
1124              mbuf_offset:$offset, glc:$glc, slc:$slc, tfe:$tfe),
1125         name#" $vdata, $vaddr, $srsrc, $soffset offen"#"$offset"#
1126             "$glc"#"$slc"#"$tfe",
1127         []
1128       >;
1129     } // end offen = 1, idxen = 0
1130
1131   } // End addr64 = 0, lds = 0
1132
1133   def _ADDR64 : MUBUF <
1134     op, (outs),
1135     (ins vdataClass:$vdata, SReg_128:$srsrc, VReg_64:$vaddr, mbuf_offset:$offset),
1136     name#" $vdata, $vaddr, $srsrc, 0 addr64"#"$offset",
1137     [(st store_vt:$vdata,
1138      (MUBUFAddr64 v4i32:$srsrc, i64:$vaddr, i16:$offset))]>, MUBUFAddr64Table<1>
1139      {
1140
1141       let mayLoad = 0;
1142       let mayStore = 1;
1143
1144       // Encoding
1145       let offen = 0;
1146       let idxen = 0;
1147       let glc = 0;
1148       let addr64 = 1;
1149       let lds = 0;
1150       let slc = 0;
1151       let tfe = 0;
1152       let soffset = 128; // ZERO
1153    }
1154 }
1155
1156 class FLAT_Load_Helper <bits<7> op, string asm, RegisterClass regClass> :
1157       FLAT <op, (outs regClass:$data),
1158                 (ins VReg_64:$addr),
1159             asm#" $data, $addr, [M0, FLAT_SCRATCH]", []> {
1160   let glc = 0;
1161   let slc = 0;
1162   let tfe = 0;
1163   let mayLoad = 1;
1164 }
1165
1166 class FLAT_Store_Helper <bits<7> op, string name, RegisterClass vdataClass> :
1167       FLAT <op, (outs), (ins vdataClass:$data, VReg_64:$addr),
1168           name#" $data, $addr, [M0, FLAT_SCRATCH]",
1169          []> {
1170
1171   let mayLoad = 0;
1172   let mayStore = 1;
1173
1174   // Encoding
1175   let glc = 0;
1176   let slc = 0;
1177   let tfe = 0;
1178 }
1179
1180 class MTBUF_Load_Helper <bits<3> op, string asm, RegisterClass regClass> : MTBUF <
1181   op,
1182   (outs regClass:$dst),
1183   (ins u16imm:$offset, i1imm:$offen, i1imm:$idxen, i1imm:$glc, i1imm:$addr64,
1184        i8imm:$dfmt, i8imm:$nfmt, VReg_32:$vaddr, SReg_128:$srsrc,
1185        i1imm:$slc, i1imm:$tfe, SSrc_32:$soffset),
1186   asm#" $dst, $offset, $offen, $idxen, $glc, $addr64, $dfmt,"
1187      #" $nfmt, $vaddr, $srsrc, $slc, $tfe, $soffset",
1188   []> {
1189   let mayLoad = 1;
1190   let mayStore = 0;
1191 }
1192
1193 class MIMG_Mask <string op, int channels> {
1194   string Op = op;
1195   int Channels = channels;
1196 }
1197
1198 class MIMG_NoSampler_Helper <bits<7> op, string asm,
1199                              RegisterClass dst_rc,
1200                              RegisterClass src_rc> : MIMG <
1201   op,
1202   (outs dst_rc:$vdata),
1203   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1204        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1205        SReg_256:$srsrc),
1206   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1207      #" $tfe, $lwe, $slc, $vaddr, $srsrc",
1208   []> {
1209   let SSAMP = 0;
1210   let mayLoad = 1;
1211   let mayStore = 0;
1212   let hasPostISelHook = 1;
1213 }
1214
1215 multiclass MIMG_NoSampler_Src_Helper <bits<7> op, string asm,
1216                                       RegisterClass dst_rc,
1217                                       int channels> {
1218   def _V1 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_32>,
1219             MIMG_Mask<asm#"_V1", channels>;
1220   def _V2 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_64>,
1221             MIMG_Mask<asm#"_V2", channels>;
1222   def _V4 : MIMG_NoSampler_Helper <op, asm, dst_rc, VReg_128>,
1223             MIMG_Mask<asm#"_V4", channels>;
1224 }
1225
1226 multiclass MIMG_NoSampler <bits<7> op, string asm> {
1227   defm _V1 : MIMG_NoSampler_Src_Helper <op, asm, VReg_32, 1>;
1228   defm _V2 : MIMG_NoSampler_Src_Helper <op, asm, VReg_64, 2>;
1229   defm _V3 : MIMG_NoSampler_Src_Helper <op, asm, VReg_96, 3>;
1230   defm _V4 : MIMG_NoSampler_Src_Helper <op, asm, VReg_128, 4>;
1231 }
1232
1233 class MIMG_Sampler_Helper <bits<7> op, string asm,
1234                            RegisterClass dst_rc,
1235                            RegisterClass src_rc> : MIMG <
1236   op,
1237   (outs dst_rc:$vdata),
1238   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1239        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1240        SReg_256:$srsrc, SReg_128:$ssamp),
1241   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1242      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
1243   []> {
1244   let mayLoad = 1;
1245   let mayStore = 0;
1246   let hasPostISelHook = 1;
1247 }
1248
1249 multiclass MIMG_Sampler_Src_Helper <bits<7> op, string asm,
1250                                     RegisterClass dst_rc,
1251                                     int channels> {
1252   def _V1 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_32>,
1253             MIMG_Mask<asm#"_V1", channels>;
1254   def _V2 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_64>,
1255             MIMG_Mask<asm#"_V2", channels>;
1256   def _V4 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_128>,
1257             MIMG_Mask<asm#"_V4", channels>;
1258   def _V8 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_256>,
1259             MIMG_Mask<asm#"_V8", channels>;
1260   def _V16 : MIMG_Sampler_Helper <op, asm, dst_rc, VReg_512>,
1261             MIMG_Mask<asm#"_V16", channels>;
1262 }
1263
1264 multiclass MIMG_Sampler <bits<7> op, string asm> {
1265   defm _V1 : MIMG_Sampler_Src_Helper<op, asm, VReg_32, 1>;
1266   defm _V2 : MIMG_Sampler_Src_Helper<op, asm, VReg_64, 2>;
1267   defm _V3 : MIMG_Sampler_Src_Helper<op, asm, VReg_96, 3>;
1268   defm _V4 : MIMG_Sampler_Src_Helper<op, asm, VReg_128, 4>;
1269 }
1270
1271 class MIMG_Gather_Helper <bits<7> op, string asm,
1272                           RegisterClass dst_rc,
1273                           RegisterClass src_rc> : MIMG <
1274   op,
1275   (outs dst_rc:$vdata),
1276   (ins i32imm:$dmask, i1imm:$unorm, i1imm:$glc, i1imm:$da, i1imm:$r128,
1277        i1imm:$tfe, i1imm:$lwe, i1imm:$slc, src_rc:$vaddr,
1278        SReg_256:$srsrc, SReg_128:$ssamp),
1279   asm#" $vdata, $dmask, $unorm, $glc, $da, $r128,"
1280      #" $tfe, $lwe, $slc, $vaddr, $srsrc, $ssamp",
1281   []> {
1282   let mayLoad = 1;
1283   let mayStore = 0;
1284
1285   // DMASK was repurposed for GATHER4. 4 components are always
1286   // returned and DMASK works like a swizzle - it selects
1287   // the component to fetch. The only useful DMASK values are
1288   // 1=red, 2=green, 4=blue, 8=alpha. (e.g. 1 returns
1289   // (red,red,red,red) etc.) The ISA document doesn't mention
1290   // this.
1291   // Therefore, disable all code which updates DMASK by setting these two:
1292   let MIMG = 0;
1293   let hasPostISelHook = 0;
1294 }
1295
1296 multiclass MIMG_Gather_Src_Helper <bits<7> op, string asm,
1297                                     RegisterClass dst_rc,
1298                                     int channels> {
1299   def _V1 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_32>,
1300             MIMG_Mask<asm#"_V1", channels>;
1301   def _V2 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_64>,
1302             MIMG_Mask<asm#"_V2", channels>;
1303   def _V4 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_128>,
1304             MIMG_Mask<asm#"_V4", channels>;
1305   def _V8 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_256>,
1306             MIMG_Mask<asm#"_V8", channels>;
1307   def _V16 : MIMG_Gather_Helper <op, asm, dst_rc, VReg_512>,
1308             MIMG_Mask<asm#"_V16", channels>;
1309 }
1310
1311 multiclass MIMG_Gather <bits<7> op, string asm> {
1312   defm _V1 : MIMG_Gather_Src_Helper<op, asm, VReg_32, 1>;
1313   defm _V2 : MIMG_Gather_Src_Helper<op, asm, VReg_64, 2>;
1314   defm _V3 : MIMG_Gather_Src_Helper<op, asm, VReg_96, 3>;
1315   defm _V4 : MIMG_Gather_Src_Helper<op, asm, VReg_128, 4>;
1316 }
1317
1318 //===----------------------------------------------------------------------===//
1319 // Vector instruction mappings
1320 //===----------------------------------------------------------------------===//
1321
1322 // Maps an opcode in e32 form to its e64 equivalent
1323 def getVOPe64 : InstrMapping {
1324   let FilterClass = "VOP";
1325   let RowFields = ["OpName"];
1326   let ColFields = ["Size"];
1327   let KeyCol = ["4"];
1328   let ValueCols = [["8"]];
1329 }
1330
1331 // Maps an opcode in e64 form to its e32 equivalent
1332 def getVOPe32 : InstrMapping {
1333   let FilterClass = "VOP";
1334   let RowFields = ["OpName"];
1335   let ColFields = ["Size"];
1336   let KeyCol = ["8"];
1337   let ValueCols = [["4"]];
1338 }
1339
1340 // Maps an original opcode to its commuted version
1341 def getCommuteRev : InstrMapping {
1342   let FilterClass = "VOP2_REV";
1343   let RowFields = ["RevOp"];
1344   let ColFields = ["IsOrig"];
1345   let KeyCol = ["1"];
1346   let ValueCols = [["0"]];
1347 }
1348
1349 def getMaskedMIMGOp : InstrMapping {
1350   let FilterClass = "MIMG_Mask";
1351   let RowFields = ["Op"];
1352   let ColFields = ["Channels"];
1353   let KeyCol = ["4"];
1354   let ValueCols = [["1"], ["2"], ["3"] ];
1355 }
1356
1357 // Maps an commuted opcode to its original version
1358 def getCommuteOrig : InstrMapping {
1359   let FilterClass = "VOP2_REV";
1360   let RowFields = ["RevOp"];
1361   let ColFields = ["IsOrig"];
1362   let KeyCol = ["0"];
1363   let ValueCols = [["1"]];
1364 }
1365
1366 def isDS : InstrMapping {
1367   let FilterClass = "DS";
1368   let RowFields = ["Inst"];
1369   let ColFields = ["Size"];
1370   let KeyCol = ["8"];
1371   let ValueCols = [["8"]];
1372 }
1373
1374 def getMCOpcode : InstrMapping {
1375   let FilterClass = "SIMCInstr";
1376   let RowFields = ["PseudoInstr"];
1377   let ColFields = ["Subtarget"];
1378   let KeyCol = [!cast<string>(SISubtarget.NONE)];
1379   let ValueCols = [[!cast<string>(SISubtarget.SI)]];
1380 }
1381
1382 def getAddr64Inst : InstrMapping {
1383   let FilterClass = "MUBUFAddr64Table";
1384   let RowFields = ["OpName"];
1385   let ColFields = ["IsAddr64"];
1386   let KeyCol = ["0"];
1387   let ValueCols = [["1"]];
1388 }
1389
1390 // Maps an atomic opcode to its version with a return value.
1391 def getAtomicRetOp : InstrMapping {
1392   let FilterClass = "AtomicNoRet";
1393   let RowFields = ["NoRetOp"];
1394   let ColFields = ["IsRet"];
1395   let KeyCol = ["0"];
1396   let ValueCols = [["1"]];
1397 }
1398
1399 // Maps an atomic opcode to its returnless version.
1400 def getAtomicNoRetOp : InstrMapping {
1401   let FilterClass = "AtomicNoRet";
1402   let RowFields = ["NoRetOp"];
1403   let ColFields = ["IsRet"];
1404   let KeyCol = ["1"];
1405   let ValueCols = [["0"]];
1406 }
1407
1408 include "SIInstructions.td"