lib/Target/R600/AMDGPUInstructions.td

   1 //===-- AMDGPUInstructions.td - Common instruction defs ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file contains instruction defs that are common to all hw codegen
  11 // targets.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 class AMDGPUInst <dag outs, dag ins, string asm, list<dag> pattern> : Instruction {
  16   field bit isRegisterLoad = 0;
  17   field bit isRegisterStore = 0;
  18
  19   let Namespace = "AMDGPU";
  20   let OutOperandList = outs;
  21   let InOperandList = ins;
  22   let AsmString = asm;
  23   let Pattern = pattern;
  24   let Itinerary = NullALU;
  25
  26   let TSFlags{63} = isRegisterLoad;
  27   let TSFlags{62} = isRegisterStore;
  28 }
  29
  30 class AMDGPUShaderInst <dag outs, dag ins, string asm, list<dag> pattern>
  31     : AMDGPUInst<outs, ins, asm, pattern> {
  32
  33   field bits<32> Inst = 0xffffffff;
  34
  35 }
  36
  37 def FP32Denormals : Predicate<"Subtarget.hasFP32Denormals()">;
  38 def FP64Denormals : Predicate<"Subtarget.hasFP64Denormals()">;
  39 def UnsafeFPMath : Predicate<"TM.Options.UnsafeFPMath">;
  40
  41 def InstFlag : OperandWithDefaultOps <i32, (ops (i32 0))>;
  42 def ADDRIndirect : ComplexPattern<iPTR, 2, "SelectADDRIndirect", [], []>;
  43
  44 let OperandType = "OPERAND_IMMEDIATE" in {
  45
  46 def u32imm : Operand<i32> {
  47   let PrintMethod = "printU32ImmOperand";
  48 }
  49
  50 def u16imm : Operand<i16> {
  51   let PrintMethod = "printU16ImmOperand";
  52 }
  53
  54 def u8imm : Operand<i8> {
  55   let PrintMethod = "printU8ImmOperand";
  56 }
  57
  58 } // End OperandType = "OPERAND_IMMEDIATE"
  59
  60 //===--------------------------------------------------------------------===//
  61 // Custom Operands
  62 //===--------------------------------------------------------------------===//
  63 def brtarget   : Operand<OtherVT>;
  64
  65 //===----------------------------------------------------------------------===//
  66 // PatLeafs for floating-point comparisons
  67 //===----------------------------------------------------------------------===//
  68
  69 def COND_OEQ : PatLeaf <
  70   (cond),
  71   [{return N->get() == ISD::SETOEQ || N->get() == ISD::SETEQ;}]
  72 >;
  73
  74 def COND_OGT : PatLeaf <
  75   (cond),
  76   [{return N->get() == ISD::SETOGT || N->get() == ISD::SETGT;}]
  77 >;
  78
  79 def COND_OGE : PatLeaf <
  80   (cond),
  81   [{return N->get() == ISD::SETOGE || N->get() == ISD::SETGE;}]
  82 >;
  83
  84 def COND_OLT : PatLeaf <
  85   (cond),
  86   [{return N->get() == ISD::SETOLT || N->get() == ISD::SETLT;}]
  87 >;
  88
  89 def COND_OLE : PatLeaf <
  90   (cond),
  91   [{return N->get() == ISD::SETOLE || N->get() == ISD::SETLE;}]
  92 >;
  93
  94 def COND_UNE : PatLeaf <
  95   (cond),
  96   [{return N->get() == ISD::SETUNE || N->get() == ISD::SETNE;}]
  97 >;
  98
  99 def COND_O : PatLeaf <(cond), [{return N->get() == ISD::SETO;}]>;
 100 def COND_UO : PatLeaf <(cond), [{return N->get() == ISD::SETUO;}]>;
 101
 102 //===----------------------------------------------------------------------===//
 103 // PatLeafs for unsigned comparisons
 104 //===----------------------------------------------------------------------===//
 105
 106 def COND_UGT : PatLeaf <(cond), [{return N->get() == ISD::SETUGT;}]>;
 107 def COND_UGE : PatLeaf <(cond), [{return N->get() == ISD::SETUGE;}]>;
 108 def COND_ULT : PatLeaf <(cond), [{return N->get() == ISD::SETULT;}]>;
 109 def COND_ULE : PatLeaf <(cond), [{return N->get() == ISD::SETULE;}]>;
 110
 111 //===----------------------------------------------------------------------===//
 112 // PatLeafs for signed comparisons
 113 //===----------------------------------------------------------------------===//
 114
 115 def COND_SGT : PatLeaf <(cond), [{return N->get() == ISD::SETGT;}]>;
 116 def COND_SGE : PatLeaf <(cond), [{return N->get() == ISD::SETGE;}]>;
 117 def COND_SLT : PatLeaf <(cond), [{return N->get() == ISD::SETLT;}]>;
 118 def COND_SLE : PatLeaf <(cond), [{return N->get() == ISD::SETLE;}]>;
 119
 120 //===----------------------------------------------------------------------===//
 121 // PatLeafs for integer equality
 122 //===----------------------------------------------------------------------===//
 123
 124 def COND_EQ : PatLeaf <
 125   (cond),
 126   [{return N->get() == ISD::SETEQ || N->get() == ISD::SETUEQ;}]
 127 >;
 128
 129 def COND_NE : PatLeaf <
 130   (cond),
 131   [{return N->get() == ISD::SETNE || N->get() == ISD::SETUNE;}]
 132 >;
 133
 134 def COND_NULL : PatLeaf <
 135   (cond),
 136   [{(void)N; return false;}]
 137 >;
 138
 139 //===----------------------------------------------------------------------===//
 140 // Load/Store Pattern Fragments
 141 //===----------------------------------------------------------------------===//
 142
 143 class PrivateMemOp <dag ops, dag frag> : PatFrag <ops, frag, [{
 144   return cast<MemSDNode>(N)->getAddressSpace() == AMDGPUAS::PRIVATE_ADDRESS;
 145 }]>;
 146
 147 class PrivateLoad <SDPatternOperator op> : PrivateMemOp <
 148   (ops node:$ptr), (op node:$ptr)
 149 >;
 150
 151 class PrivateStore <SDPatternOperator op> : PrivateMemOp <
 152   (ops node:$value, node:$ptr), (op node:$value, node:$ptr)
 153 >;
 154
 155 def extloadi8_private : PrivateLoad <extloadi8>;
 156 def sextloadi8_private : PrivateLoad <sextloadi8>;
 157 def extloadi16_private : PrivateLoad <extloadi16>;
 158 def sextloadi16_private : PrivateLoad <sextloadi16>;
 159 def load_private : PrivateLoad <load>;
 160
 161 def truncstorei8_private : PrivateStore <truncstorei8>;
 162 def truncstorei16_private : PrivateStore <truncstorei16>;
 163 def store_private : PrivateStore <store>;
 164
 165 def global_store : PatFrag<(ops node:$val, node:$ptr),
 166     (store node:$val, node:$ptr), [{
 167         return isGlobalStore(dyn_cast<StoreSDNode>(N));
 168 }]>;
 169
 170 // Global address space loads
 171 def global_load : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 172     return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 173 }]>;
 174
 175 // Constant address space loads
 176 def constant_load : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 177     return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 178 }]>;
 179
 180 def az_extload : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 181   LoadSDNode *L = cast<LoadSDNode>(N);
 182   return L->getExtensionType() == ISD::ZEXTLOAD ||
 183          L->getExtensionType() == ISD::EXTLOAD;
 184 }]>;
 185
 186 def az_extloadi8 : PatFrag<(ops node:$ptr), (az_extload node:$ptr), [{
 187   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 188 }]>;
 189
 190 def az_extloadi8_global : PatFrag<(ops node:$ptr), (az_extloadi8 node:$ptr), [{
 191     return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 192 }]>;
 193
 194 def sextloadi8_global : PatFrag<(ops node:$ptr), (sextloadi8 node:$ptr), [{
 195     return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 196 }]>;
 197
 198 def az_extloadi8_flat : PatFrag<(ops node:$ptr), (az_extloadi8 node:$ptr), [{
 199     return isFlatLoad(dyn_cast<LoadSDNode>(N));
 200 }]>;
 201
 202 def sextloadi8_flat : PatFrag<(ops node:$ptr), (sextloadi8 node:$ptr), [{
 203     return isFlatLoad(dyn_cast<LoadSDNode>(N));
 204 }]>;
 205
 206 def az_extloadi8_constant : PatFrag<(ops node:$ptr), (az_extloadi8 node:$ptr), [{
 207     return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 208 }]>;
 209
 210 def sextloadi8_constant : PatFrag<(ops node:$ptr), (sextloadi8 node:$ptr), [{
 211     return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 212 }]>;
 213
 214 def az_extloadi8_local : PatFrag<(ops node:$ptr), (az_extloadi8 node:$ptr), [{
 215     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 216 }]>;
 217
 218 def sextloadi8_local : PatFrag<(ops node:$ptr), (sextloadi8 node:$ptr), [{
 219     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 220 }]>;
 221
 222 def az_extloadi16 : PatFrag<(ops node:$ptr), (az_extload node:$ptr), [{
 223   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 224 }]>;
 225
 226 def az_extloadi16_global : PatFrag<(ops node:$ptr), (az_extloadi16 node:$ptr), [{
 227     return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 228 }]>;
 229
 230 def sextloadi16_global : PatFrag<(ops node:$ptr), (sextloadi16 node:$ptr), [{
 231     return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 232 }]>;
 233
 234 def az_extloadi16_flat : PatFrag<(ops node:$ptr), (az_extloadi16 node:$ptr), [{
 235     return isFlatLoad(dyn_cast<LoadSDNode>(N));
 236 }]>;
 237
 238 def sextloadi16_flat : PatFrag<(ops node:$ptr), (sextloadi16 node:$ptr), [{
 239     return isFlatLoad(dyn_cast<LoadSDNode>(N));
 240 }]>;
 241
 242 def az_extloadi16_constant : PatFrag<(ops node:$ptr), (az_extloadi16 node:$ptr), [{
 243     return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 244 }]>;
 245
 246 def sextloadi16_constant : PatFrag<(ops node:$ptr), (sextloadi16 node:$ptr), [{
 247     return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 248 }]>;
 249
 250 def az_extloadi16_local : PatFrag<(ops node:$ptr), (az_extloadi16 node:$ptr), [{
 251     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 252 }]>;
 253
 254 def sextloadi16_local : PatFrag<(ops node:$ptr), (sextloadi16 node:$ptr), [{
 255     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 256 }]>;
 257
 258 def az_extloadi32 : PatFrag<(ops node:$ptr), (az_extload node:$ptr), [{
 259   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 260 }]>;
 261
 262 def az_extloadi32_global : PatFrag<(ops node:$ptr),
 263                                    (az_extloadi32 node:$ptr), [{
 264   return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 265 }]>;
 266
 267 def az_extloadi32_flat : PatFrag<(ops node:$ptr),
 268                                    (az_extloadi32 node:$ptr), [{
 269   return isFlatLoad(dyn_cast<LoadSDNode>(N));
 270 }]>;
 271
 272 def az_extloadi32_constant : PatFrag<(ops node:$ptr),
 273                                      (az_extloadi32 node:$ptr), [{
 274   return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 275 }]>;
 276
 277 def truncstorei8_global : PatFrag<(ops node:$val, node:$ptr),
 278                                   (truncstorei8 node:$val, node:$ptr), [{
 279   return isGlobalStore(dyn_cast<StoreSDNode>(N));
 280 }]>;
 281
 282 def truncstorei16_global : PatFrag<(ops node:$val, node:$ptr),
 283                                   (truncstorei16 node:$val, node:$ptr), [{
 284   return isGlobalStore(dyn_cast<StoreSDNode>(N));
 285 }]>;
 286
 287 def truncstorei8_flat : PatFrag<(ops node:$val, node:$ptr),
 288                                   (truncstorei8 node:$val, node:$ptr), [{
 289   return isFlatStore(dyn_cast<StoreSDNode>(N));
 290 }]>;
 291
 292 def truncstorei16_flat : PatFrag<(ops node:$val, node:$ptr),
 293                                   (truncstorei16 node:$val, node:$ptr), [{
 294   return isFlatStore(dyn_cast<StoreSDNode>(N));
 295 }]>;
 296
 297 def local_store : PatFrag<(ops node:$val, node:$ptr),
 298                              (store node:$val, node:$ptr), [{
 299   return isLocalStore(dyn_cast<StoreSDNode>(N));
 300 }]>;
 301
 302 def truncstorei8_local : PatFrag<(ops node:$val, node:$ptr),
 303                                   (truncstorei8 node:$val, node:$ptr), [{
 304   return isLocalStore(dyn_cast<StoreSDNode>(N));
 305 }]>;
 306
 307 def truncstorei16_local : PatFrag<(ops node:$val, node:$ptr),
 308                                   (truncstorei16 node:$val, node:$ptr), [{
 309   return isLocalStore(dyn_cast<StoreSDNode>(N));
 310 }]>;
 311
 312 def local_load : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 313     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 314 }]>;
 315
 316 class Aligned8Bytes <dag ops, dag frag> : PatFrag <ops, frag, [{
 317     return cast<MemSDNode>(N)->getAlignment() % 8 == 0;
 318 }]>;
 319
 320 def local_load_aligned8bytes : Aligned8Bytes <
 321   (ops node:$ptr), (local_load node:$ptr)
 322 >;
 323
 324 def local_store_aligned8bytes : Aligned8Bytes <
 325   (ops node:$val, node:$ptr), (local_store node:$val, node:$ptr)
 326 >;
 327
 328 class local_binary_atomic_op<SDNode atomic_op> :
 329   PatFrag<(ops node:$ptr, node:$value),
 330     (atomic_op node:$ptr, node:$value), [{
 331   return cast<MemSDNode>(N)->getAddressSpace() == AMDGPUAS::LOCAL_ADDRESS;
 332 }]>;
 333
 334
 335 def atomic_swap_local : local_binary_atomic_op<atomic_swap>;
 336 def atomic_load_add_local : local_binary_atomic_op<atomic_load_add>;
 337 def atomic_load_sub_local : local_binary_atomic_op<atomic_load_sub>;
 338 def atomic_load_and_local : local_binary_atomic_op<atomic_load_and>;
 339 def atomic_load_or_local : local_binary_atomic_op<atomic_load_or>;
 340 def atomic_load_xor_local : local_binary_atomic_op<atomic_load_xor>;
 341 def atomic_load_nand_local : local_binary_atomic_op<atomic_load_nand>;
 342 def atomic_load_min_local : local_binary_atomic_op<atomic_load_min>;
 343 def atomic_load_max_local : local_binary_atomic_op<atomic_load_max>;
 344 def atomic_load_umin_local : local_binary_atomic_op<atomic_load_umin>;
 345 def atomic_load_umax_local : local_binary_atomic_op<atomic_load_umax>;
 346
 347 def mskor_global : PatFrag<(ops node:$val, node:$ptr),
 348                             (AMDGPUstore_mskor node:$val, node:$ptr), [{
 349   return dyn_cast<MemSDNode>(N)->getAddressSpace() == AMDGPUAS::GLOBAL_ADDRESS;
 350 }]>;
 351
 352
 353 def atomic_cmp_swap_32_local :
 354   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 355           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 356   AtomicSDNode *AN = cast<AtomicSDNode>(N);
 357   return AN->getMemoryVT() == MVT::i32 &&
 358          AN->getAddressSpace() == AMDGPUAS::LOCAL_ADDRESS;
 359 }]>;
 360
 361 def atomic_cmp_swap_64_local :
 362   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 363           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 364   AtomicSDNode *AN = cast<AtomicSDNode>(N);
 365   return AN->getMemoryVT() == MVT::i64 &&
 366          AN->getAddressSpace() == AMDGPUAS::LOCAL_ADDRESS;
 367 }]>;
 368
 369 def flat_load : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 370     return isFlatLoad(dyn_cast<LoadSDNode>(N));
 371 }]>;
 372
 373 def flat_store : PatFrag<(ops node:$val, node:$ptr),
 374                          (store node:$val, node:$ptr), [{
 375   return isFlatStore(dyn_cast<StoreSDNode>(N));
 376 }]>;
 377
 378 def mskor_flat : PatFrag<(ops node:$val, node:$ptr),
 379                             (AMDGPUstore_mskor node:$val, node:$ptr), [{
 380   return dyn_cast<MemSDNode>(N)->getAddressSpace() == AMDGPUAS::FLAT_ADDRESS;
 381 }]>;
 382
 383 class global_binary_atomic_op<SDNode atomic_op> : PatFrag<
 384   (ops node:$ptr, node:$value),
 385   (atomic_op node:$ptr, node:$value),
 386   [{return cast<MemSDNode>(N)->getAddressSpace() == AMDGPUAS::GLOBAL_ADDRESS;}]
 387 >;
 388
 389 def atomic_add_global : global_binary_atomic_op<atomic_load_add>;
 390
 391 //===----------------------------------------------------------------------===//
 392 // Misc Pattern Fragments
 393 //===----------------------------------------------------------------------===//
 394
 395 def fmad : PatFrag <
 396   (ops node:$src0, node:$src1, node:$src2),
 397   (fadd (fmul node:$src0, node:$src1), node:$src2)
 398 >;
 399
 400 class Constants {
 401 int TWO_PI = 0x40c90fdb;
 402 int PI = 0x40490fdb;
 403 int TWO_PI_INV = 0x3e22f983;
 404 int FP_UINT_MAX_PLUS_1 = 0x4f800000;    // 1 << 32 in floating point encoding
 405 int FP32_NEG_ONE = 0xbf800000;
 406 int FP32_ONE = 0x3f800000;
 407 }
 408 def CONST : Constants;
 409
 410 def FP_ZERO : PatLeaf <
 411   (fpimm),
 412   [{return N->getValueAPF().isZero();}]
 413 >;
 414
 415 def FP_ONE : PatLeaf <
 416   (fpimm),
 417   [{return N->isExactlyValue(1.0);}]
 418 >;
 419
 420 let isCodeGenOnly = 1, isPseudo = 1 in {
 421
 422 let usesCustomInserter = 1  in {
 423
 424 class CLAMP <RegisterClass rc> : AMDGPUShaderInst <
 425   (outs rc:$dst),
 426   (ins rc:$src0),
 427   "CLAMP $dst, $src0",
 428   [(set f32:$dst, (AMDGPUclamp f32:$src0, (f32 FP_ZERO), (f32 FP_ONE)))]
 429 >;
 430
 431 class FABS <RegisterClass rc> : AMDGPUShaderInst <
 432   (outs rc:$dst),
 433   (ins rc:$src0),
 434   "FABS $dst, $src0",
 435   [(set f32:$dst, (fabs f32:$src0))]
 436 >;
 437
 438 class FNEG <RegisterClass rc> : AMDGPUShaderInst <
 439   (outs rc:$dst),
 440   (ins rc:$src0),
 441   "FNEG $dst, $src0",
 442   [(set f32:$dst, (fneg f32:$src0))]
 443 >;
 444
 445 } // usesCustomInserter = 1
 446
 447 multiclass RegisterLoadStore <RegisterClass dstClass, Operand addrClass,
 448                     ComplexPattern addrPat> {
 449 let UseNamedOperandTable = 1 in {
 450
 451   def RegisterLoad : AMDGPUShaderInst <
 452     (outs dstClass:$dst),
 453     (ins addrClass:$addr, i32imm:$chan),
 454     "RegisterLoad $dst, $addr",
 455     [(set i32:$dst, (AMDGPUregister_load addrPat:$addr, (i32 timm:$chan)))]
 456   > {
 457     let isRegisterLoad = 1;
 458   }
 459
 460   def RegisterStore : AMDGPUShaderInst <
 461     (outs),
 462     (ins dstClass:$val, addrClass:$addr, i32imm:$chan),
 463     "RegisterStore $val, $addr",
 464     [(AMDGPUregister_store i32:$val, addrPat:$addr, (i32 timm:$chan))]
 465   > {
 466     let isRegisterStore = 1;
 467   }
 468 }
 469 }
 470
 471 } // End isCodeGenOnly = 1, isPseudo = 1
 472
 473 /* Generic helper patterns for intrinsics */
 474 /* -------------------------------------- */
 475
 476 class POW_Common <AMDGPUInst log_ieee, AMDGPUInst exp_ieee, AMDGPUInst mul>
 477   : Pat <
 478   (fpow f32:$src0, f32:$src1),
 479   (exp_ieee (mul f32:$src1, (log_ieee f32:$src0)))
 480 >;
 481
 482 /* Other helper patterns */
 483 /* --------------------- */
 484
 485 /* Extract element pattern */
 486 class Extract_Element <ValueType sub_type, ValueType vec_type, int sub_idx,
 487                        SubRegIndex sub_reg>
 488   : Pat<
 489   (sub_type (vector_extract vec_type:$src, sub_idx)),
 490   (EXTRACT_SUBREG $src, sub_reg)
 491 >;
 492
 493 /* Insert element pattern */
 494 class Insert_Element <ValueType elem_type, ValueType vec_type,
 495                       int sub_idx, SubRegIndex sub_reg>
 496   : Pat <
 497   (vector_insert vec_type:$vec, elem_type:$elem, sub_idx),
 498   (INSERT_SUBREG $vec, $elem, sub_reg)
 499 >;
 500
 501 // XXX: Convert to new syntax and use COPY_TO_REG, once the DFAPacketizer
 502 // can handle COPY instructions.
 503 // bitconvert pattern
 504 class BitConvert <ValueType dt, ValueType st, RegisterClass rc> : Pat <
 505   (dt (bitconvert (st rc:$src0))),
 506   (dt rc:$src0)
 507 >;
 508
 509 // XXX: Convert to new syntax and use COPY_TO_REG, once the DFAPacketizer
 510 // can handle COPY instructions.
 511 class DwordAddrPat<ValueType vt, RegisterClass rc> : Pat <
 512   (vt (AMDGPUdwordaddr (vt rc:$addr))),
 513   (vt rc:$addr)
 514 >;
 515
 516 // BFI_INT patterns
 517
 518 multiclass BFIPatterns <Instruction BFI_INT, Instruction LoadImm32> {
 519
 520   // Definition from ISA doc:
 521   // (y & x) | (z & ~x)
 522   def : Pat <
 523     (or (and i32:$y, i32:$x), (and i32:$z, (not i32:$x))),
 524     (BFI_INT $x, $y, $z)
 525   >;
 526
 527   // SHA-256 Ch function
 528   // z ^ (x & (y ^ z))
 529   def : Pat <
 530     (xor i32:$z, (and i32:$x, (xor i32:$y, i32:$z))),
 531     (BFI_INT $x, $y, $z)
 532   >;
 533
 534   def : Pat <
 535     (fcopysign f32:$src0, f32:$src1),
 536     (BFI_INT (LoadImm32 0x7fffffff), $src0, $src1)
 537   >;
 538
 539   def : Pat <
 540     (f64 (fcopysign f64:$src0, f64:$src1)),
 541       (INSERT_SUBREG (INSERT_SUBREG (f64 (IMPLICIT_DEF)),
 542       (i32 (EXTRACT_SUBREG $src0, sub0)), sub0),
 543       (BFI_INT (LoadImm32 0x7fffffff),
 544                (i32 (EXTRACT_SUBREG $src0, sub1)),
 545                (i32 (EXTRACT_SUBREG $src1, sub1))), sub1)
 546   >;
 547 }
 548
 549 // SHA-256 Ma patterns
 550
 551 // ((x & z) | (y & (x | z))) -> BFI_INT (XOR x, y), z, y
 552 class SHA256MaPattern <Instruction BFI_INT, Instruction XOR> : Pat <
 553   (or (and i32:$x, i32:$z), (and i32:$y, (or i32:$x, i32:$z))),
 554   (BFI_INT (XOR i32:$x, i32:$y), i32:$z, i32:$y)
 555 >;
 556
 557 // Bitfield extract patterns
 558
 559 /*
 560
 561 XXX: The BFE pattern is not working correctly because the XForm is not being
 562 applied.
 563
 564 def legalshift32 : ImmLeaf <i32, [{return Imm >=0 && Imm < 32;}]>;
 565 def bfemask : PatLeaf <(imm), [{return isMask_32(N->getZExtValue());}],
 566                             SDNodeXForm<imm, [{ return CurDAG->getTargetConstant(CountTrailingOnes_32(N->getZExtValue()), MVT::i32);}]>>;
 567
 568 class BFEPattern <Instruction BFE> : Pat <
 569   (and (srl i32:$x, legalshift32:$y), bfemask:$z),
 570   (BFE $x, $y, $z)
 571 >;
 572
 573 */
 574
 575 // rotr pattern
 576 class ROTRPattern <Instruction BIT_ALIGN> : Pat <
 577   (rotr i32:$src0, i32:$src1),
 578   (BIT_ALIGN $src0, $src0, $src1)
 579 >;
 580
 581 // 24-bit arithmetic patterns
 582 def umul24 : PatFrag <(ops node:$x, node:$y), (mul node:$x, node:$y)>;
 583
 584 /*
 585 class UMUL24Pattern <Instruction UMUL24> : Pat <
 586   (mul U24:$x, U24:$y),
 587   (UMUL24 $x, $y)
 588 >;
 589 */
 590
 591 class IMad24Pat<Instruction Inst> : Pat <
 592   (add (AMDGPUmul_i24 i32:$src0, i32:$src1), i32:$src2),
 593   (Inst $src0, $src1, $src2)
 594 >;
 595
 596 class UMad24Pat<Instruction Inst> : Pat <
 597   (add (AMDGPUmul_u24 i32:$src0, i32:$src1), i32:$src2),
 598   (Inst $src0, $src1, $src2)
 599 >;
 600
 601 multiclass Expand24IBitOps<Instruction MulInst, Instruction AddInst> {
 602   def _expand_imad24 : Pat <
 603     (AMDGPUmad_i24 i32:$src0, i32:$src1, i32:$src2),
 604     (AddInst (MulInst $src0, $src1), $src2)
 605   >;
 606
 607   def _expand_imul24 : Pat <
 608     (AMDGPUmul_i24 i32:$src0, i32:$src1),
 609     (MulInst $src0, $src1)
 610   >;
 611 }
 612
 613 multiclass Expand24UBitOps<Instruction MulInst, Instruction AddInst> {
 614   def _expand_umad24 : Pat <
 615     (AMDGPUmad_u24 i32:$src0, i32:$src1, i32:$src2),
 616     (AddInst (MulInst $src0, $src1), $src2)
 617   >;
 618
 619   def _expand_umul24 : Pat <
 620     (AMDGPUmul_u24 i32:$src0, i32:$src1),
 621     (MulInst $src0, $src1)
 622   >;
 623 }
 624
 625 class RcpPat<Instruction RcpInst, ValueType vt> : Pat <
 626   (fdiv FP_ONE, vt:$src),
 627   (RcpInst $src)
 628 >;
 629
 630 multiclass RsqPat<Instruction RsqInst, ValueType vt> {
 631   def : Pat <
 632     (fdiv FP_ONE, (fsqrt vt:$src)),
 633     (RsqInst $src)
 634   >;
 635
 636   def : Pat <
 637     (AMDGPUrcp (fsqrt vt:$src)),
 638     (RsqInst $src)
 639   >;
 640 }
 641
 642 include "R600Instructions.td"
 643 include "R700Instructions.td"
 644 include "EvergreenInstructions.td"
 645 include "CaymanInstructions.td"
 646
 647 include "SIInstrInfo.td"
 648