lib/Target/PowerPC/PPCInstrInfo.td

   1 //===-- PPCInstrInfo.td - The PowerPC Instruction Set ------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the subset of the 32-bit PowerPC instruction set, as used
  11 // by the PowerPC instruction selector.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 include "PPCInstrFormats.td"
  16
  17 //===----------------------------------------------------------------------===//
  18 // PowerPC specific type constraints.
  19 //
  20 def SDT_PPCstfiwx : SDTypeProfile<0, 2, [ // stfiwx
  21   SDTCisVT<0, f64>, SDTCisPtrTy<1>
  22 ]>;
  23 def SDT_PPClfiwx : SDTypeProfile<1, 1, [ // lfiw[az]x
  24   SDTCisVT<0, f64>, SDTCisPtrTy<1>
  25 ]>;
  26
  27 def SDT_PPCCallSeqStart : SDCallSeqStart<[ SDTCisVT<0, i32> ]>;
  28 def SDT_PPCCallSeqEnd   : SDCallSeqEnd<[ SDTCisVT<0, i32>,
  29                                          SDTCisVT<1, i32> ]>;
  30 def SDT_PPCvperm   : SDTypeProfile<1, 3, [
  31   SDTCisVT<3, v16i8>, SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>
  32 ]>;
  33
  34 def SDT_PPCvcmp : SDTypeProfile<1, 3, [
  35   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisVT<3, i32>
  36 ]>;
  37
  38 def SDT_PPCcondbr : SDTypeProfile<0, 3, [
  39   SDTCisVT<0, i32>, SDTCisVT<2, OtherVT>
  40 ]>;
  41
  42 def SDT_PPClbrx : SDTypeProfile<1, 2, [
  43   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>
  44 ]>;
  45 def SDT_PPCstbrx : SDTypeProfile<0, 3, [
  46   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>
  47 ]>;
  48
  49 def SDT_PPClarx : SDTypeProfile<1, 1, [
  50   SDTCisInt<0>, SDTCisPtrTy<1>
  51 ]>;
  52 def SDT_PPCstcx : SDTypeProfile<0, 2, [
  53   SDTCisInt<0>, SDTCisPtrTy<1>
  54 ]>;
  55
  56 def SDT_PPCTC_ret : SDTypeProfile<0, 2, [
  57   SDTCisPtrTy<0>, SDTCisVT<1, i32>
  58 ]>;
  59
  60 def tocentry32 : Operand<iPTR> {
  61   let MIOperandInfo = (ops i32imm:$imm);
  62 }
  63
  64 //===----------------------------------------------------------------------===//
  65 // PowerPC specific DAG Nodes.
  66 //
  67
  68 def PPCfre    : SDNode<"PPCISD::FRE",     SDTFPUnaryOp, []>;
  69 def PPCfrsqrte: SDNode<"PPCISD::FRSQRTE", SDTFPUnaryOp, []>;
  70
  71 def PPCfcfid  : SDNode<"PPCISD::FCFID",   SDTFPUnaryOp, []>;
  72 def PPCfcfidu : SDNode<"PPCISD::FCFIDU",  SDTFPUnaryOp, []>;
  73 def PPCfcfids : SDNode<"PPCISD::FCFIDS",  SDTFPRoundOp, []>;
  74 def PPCfcfidus: SDNode<"PPCISD::FCFIDUS", SDTFPRoundOp, []>;
  75 def PPCfctidz : SDNode<"PPCISD::FCTIDZ", SDTFPUnaryOp, []>;
  76 def PPCfctiwz : SDNode<"PPCISD::FCTIWZ", SDTFPUnaryOp, []>;
  77 def PPCfctiduz: SDNode<"PPCISD::FCTIDUZ",SDTFPUnaryOp, []>;
  78 def PPCfctiwuz: SDNode<"PPCISD::FCTIWUZ",SDTFPUnaryOp, []>;
  79 def PPCstfiwx : SDNode<"PPCISD::STFIWX", SDT_PPCstfiwx,
  80                        [SDNPHasChain, SDNPMayStore]>;
  81 def PPClfiwax : SDNode<"PPCISD::LFIWAX", SDT_PPClfiwx,
  82                        [SDNPHasChain, SDNPMayLoad]>;
  83 def PPClfiwzx : SDNode<"PPCISD::LFIWZX", SDT_PPClfiwx,
  84                        [SDNPHasChain, SDNPMayLoad]>;
  85
  86 // Extract FPSCR (not modeled at the DAG level).
  87 def PPCmffs   : SDNode<"PPCISD::MFFS",
  88                        SDTypeProfile<1, 0, [SDTCisVT<0, f64>]>, []>;
  89
  90 // Perform FADD in round-to-zero mode.
  91 def PPCfaddrtz: SDNode<"PPCISD::FADDRTZ", SDTFPBinOp, []>;
  92
  93
  94 def PPCfsel   : SDNode<"PPCISD::FSEL",
  95    // Type constraint for fsel.
  96    SDTypeProfile<1, 3, [SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>,
  97                         SDTCisFP<0>, SDTCisVT<1, f64>]>, []>;
  98
  99 def PPChi       : SDNode<"PPCISD::Hi", SDTIntBinOp, []>;
 100 def PPClo       : SDNode<"PPCISD::Lo", SDTIntBinOp, []>;
 101 def PPCtoc_entry: SDNode<"PPCISD::TOC_ENTRY", SDTIntBinOp, [SDNPMayLoad]>;
 102 def PPCvmaddfp  : SDNode<"PPCISD::VMADDFP", SDTFPTernaryOp, []>;
 103 def PPCvnmsubfp : SDNode<"PPCISD::VNMSUBFP", SDTFPTernaryOp, []>;
 104
 105 def PPCppc32GOT : SDNode<"PPCISD::PPC32_GOT", SDTIntLeaf, []>;
 106
 107 def PPCaddisGotTprelHA : SDNode<"PPCISD::ADDIS_GOT_TPREL_HA", SDTIntBinOp>;
 108 def PPCldGotTprelL : SDNode<"PPCISD::LD_GOT_TPREL_L", SDTIntBinOp,
 109                             [SDNPMayLoad]>;
 110 def PPCaddTls     : SDNode<"PPCISD::ADD_TLS", SDTIntBinOp, []>;
 111 def PPCaddisTlsgdHA : SDNode<"PPCISD::ADDIS_TLSGD_HA", SDTIntBinOp>;
 112 def PPCaddiTlsgdL   : SDNode<"PPCISD::ADDI_TLSGD_L", SDTIntBinOp>;
 113 def PPCgetTlsAddr   : SDNode<"PPCISD::GET_TLS_ADDR", SDTIntBinOp>;
 114 def PPCaddisTlsldHA : SDNode<"PPCISD::ADDIS_TLSLD_HA", SDTIntBinOp>;
 115 def PPCaddiTlsldL   : SDNode<"PPCISD::ADDI_TLSLD_L", SDTIntBinOp>;
 116 def PPCgetTlsldAddr : SDNode<"PPCISD::GET_TLSLD_ADDR", SDTIntBinOp>;
 117 def PPCaddisDtprelHA : SDNode<"PPCISD::ADDIS_DTPREL_HA", SDTIntBinOp,
 118                               [SDNPHasChain]>;
 119 def PPCaddiDtprelL   : SDNode<"PPCISD::ADDI_DTPREL_L", SDTIntBinOp>;
 120
 121 def PPCvperm    : SDNode<"PPCISD::VPERM", SDT_PPCvperm, []>;
 122
 123 // These nodes represent the 32-bit PPC shifts that operate on 6-bit shift
 124 // amounts.  These nodes are generated by the multi-precision shift code.
 125 def PPCsrl        : SDNode<"PPCISD::SRL"       , SDTIntShiftOp>;
 126 def PPCsra        : SDNode<"PPCISD::SRA"       , SDTIntShiftOp>;
 127 def PPCshl        : SDNode<"PPCISD::SHL"       , SDTIntShiftOp>;
 128
 129 // These are target-independent nodes, but have target-specific formats.
 130 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_PPCCallSeqStart,
 131                            [SDNPHasChain, SDNPOutGlue]>;
 132 def callseq_end   : SDNode<"ISD::CALLSEQ_END",   SDT_PPCCallSeqEnd,
 133                            [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 134
 135 def SDT_PPCCall   : SDTypeProfile<0, -1, [SDTCisInt<0>]>;
 136 def PPCcall  : SDNode<"PPCISD::CALL", SDT_PPCCall,
 137                       [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 138                        SDNPVariadic]>;
 139 def PPCcall_nop  : SDNode<"PPCISD::CALL_NOP", SDT_PPCCall,
 140                           [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 141                            SDNPVariadic]>;
 142 def PPCload   : SDNode<"PPCISD::LOAD", SDTypeProfile<1, 1, []>,
 143                        [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 144 def PPCload_toc : SDNode<"PPCISD::LOAD_TOC", SDTypeProfile<0, 1, []>,
 145                           [SDNPHasChain, SDNPSideEffect,
 146                            SDNPInGlue, SDNPOutGlue]>;
 147 def PPCmtctr      : SDNode<"PPCISD::MTCTR", SDT_PPCCall,
 148                            [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 149 def PPCbctrl : SDNode<"PPCISD::BCTRL", SDTNone,
 150                       [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 151                        SDNPVariadic]>;
 152
 153 def retflag       : SDNode<"PPCISD::RET_FLAG", SDTNone,
 154                            [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
 155
 156 def PPCtc_return : SDNode<"PPCISD::TC_RETURN", SDT_PPCTC_ret,
 157                         [SDNPHasChain,  SDNPOptInGlue, SDNPVariadic]>;
 158
 159 def PPCeh_sjlj_setjmp  : SDNode<"PPCISD::EH_SJLJ_SETJMP",
 160                                 SDTypeProfile<1, 1, [SDTCisInt<0>,
 161                                                      SDTCisPtrTy<1>]>,
 162                                 [SDNPHasChain, SDNPSideEffect]>;
 163 def PPCeh_sjlj_longjmp : SDNode<"PPCISD::EH_SJLJ_LONGJMP",
 164                                 SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>,
 165                                 [SDNPHasChain, SDNPSideEffect]>;
 166
 167 def SDT_PPCsc     : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 168 def PPCsc         : SDNode<"PPCISD::SC", SDT_PPCsc,
 169                            [SDNPHasChain, SDNPSideEffect]>;
 170
 171 def PPCvcmp       : SDNode<"PPCISD::VCMP" , SDT_PPCvcmp, []>;
 172 def PPCvcmp_o     : SDNode<"PPCISD::VCMPo", SDT_PPCvcmp, [SDNPOutGlue]>;
 173
 174 def PPCcondbranch : SDNode<"PPCISD::COND_BRANCH", SDT_PPCcondbr,
 175                            [SDNPHasChain, SDNPOptInGlue]>;
 176
 177 def PPClbrx       : SDNode<"PPCISD::LBRX", SDT_PPClbrx,
 178                            [SDNPHasChain, SDNPMayLoad]>;
 179 def PPCstbrx      : SDNode<"PPCISD::STBRX", SDT_PPCstbrx,
 180                            [SDNPHasChain, SDNPMayStore]>;
 181
 182 // Instructions to set/unset CR bit 6 for SVR4 vararg calls
 183 def PPCcr6set   : SDNode<"PPCISD::CR6SET", SDTNone,
 184                          [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 185 def PPCcr6unset : SDNode<"PPCISD::CR6UNSET", SDTNone,
 186                          [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 187
 188 // Instructions to support atomic operations
 189 def PPClarx      : SDNode<"PPCISD::LARX", SDT_PPClarx,
 190                           [SDNPHasChain, SDNPMayLoad]>;
 191 def PPCstcx      : SDNode<"PPCISD::STCX", SDT_PPCstcx,
 192                           [SDNPHasChain, SDNPMayStore]>;
 193
 194 // Instructions to support medium and large code model
 195 def PPCaddisTocHA : SDNode<"PPCISD::ADDIS_TOC_HA", SDTIntBinOp, []>;
 196 def PPCldTocL     : SDNode<"PPCISD::LD_TOC_L", SDTIntBinOp, [SDNPMayLoad]>;
 197 def PPCaddiTocL   : SDNode<"PPCISD::ADDI_TOC_L", SDTIntBinOp, []>;
 198
 199
 200 // Instructions to support dynamic alloca.
 201 def SDTDynOp  : SDTypeProfile<1, 2, []>;
 202 def PPCdynalloc   : SDNode<"PPCISD::DYNALLOC", SDTDynOp, [SDNPHasChain]>;
 203
 204 //===----------------------------------------------------------------------===//
 205 // PowerPC specific transformation functions and pattern fragments.
 206 //
 207
 208 def SHL32 : SDNodeXForm<imm, [{
 209   // Transformation function: 31 - imm
 210   return getI32Imm(31 - N->getZExtValue());
 211 }]>;
 212
 213 def SRL32 : SDNodeXForm<imm, [{
 214   // Transformation function: 32 - imm
 215   return N->getZExtValue() ? getI32Imm(32 - N->getZExtValue()) : getI32Imm(0);
 216 }]>;
 217
 218 def LO16 : SDNodeXForm<imm, [{
 219   // Transformation function: get the low 16 bits.
 220   return getI32Imm((unsigned short)N->getZExtValue());
 221 }]>;
 222
 223 def HI16 : SDNodeXForm<imm, [{
 224   // Transformation function: shift the immediate value down into the low bits.
 225   return getI32Imm((unsigned)N->getZExtValue() >> 16);
 226 }]>;
 227
 228 def HA16 : SDNodeXForm<imm, [{
 229   // Transformation function: shift the immediate value down into the low bits.
 230   signed int Val = N->getZExtValue();
 231   return getI32Imm((Val - (signed short)Val) >> 16);
 232 }]>;
 233 def MB : SDNodeXForm<imm, [{
 234   // Transformation function: get the start bit of a mask
 235   unsigned mb = 0, me;
 236   (void)isRunOfOnes((unsigned)N->getZExtValue(), mb, me);
 237   return getI32Imm(mb);
 238 }]>;
 239
 240 def ME : SDNodeXForm<imm, [{
 241   // Transformation function: get the end bit of a mask
 242   unsigned mb, me = 0;
 243   (void)isRunOfOnes((unsigned)N->getZExtValue(), mb, me);
 244   return getI32Imm(me);
 245 }]>;
 246 def maskimm32 : PatLeaf<(imm), [{
 247   // maskImm predicate - True if immediate is a run of ones.
 248   unsigned mb, me;
 249   if (N->getValueType(0) == MVT::i32)
 250     return isRunOfOnes((unsigned)N->getZExtValue(), mb, me);
 251   else
 252     return false;
 253 }]>;
 254
 255 def imm32SExt16  : Operand<i32>, ImmLeaf<i32, [{
 256   // imm32SExt16 predicate - True if the i32 immediate fits in a 16-bit
 257   // sign extended field.  Used by instructions like 'addi'.
 258   return (int32_t)Imm == (short)Imm;
 259 }]>;
 260 def imm64SExt16  : Operand<i64>, ImmLeaf<i64, [{
 261   // imm64SExt16 predicate - True if the i64 immediate fits in a 16-bit
 262   // sign extended field.  Used by instructions like 'addi'.
 263   return (int64_t)Imm == (short)Imm;
 264 }]>;
 265 def immZExt16  : PatLeaf<(imm), [{
 266   // immZExt16 predicate - True if the immediate fits in a 16-bit zero extended
 267   // field.  Used by instructions like 'ori'.
 268   return (uint64_t)N->getZExtValue() == (unsigned short)N->getZExtValue();
 269 }], LO16>;
 270
 271 // imm16Shifted* - These match immediates where the low 16-bits are zero.  There
 272 // are two forms: imm16ShiftedSExt and imm16ShiftedZExt.  These two forms are
 273 // identical in 32-bit mode, but in 64-bit mode, they return true if the
 274 // immediate fits into a sign/zero extended 32-bit immediate (with the low bits
 275 // clear).
 276 def imm16ShiftedZExt : PatLeaf<(imm), [{
 277   // imm16ShiftedZExt predicate - True if only bits in the top 16-bits of the
 278   // immediate are set.  Used by instructions like 'xoris'.
 279   return (N->getZExtValue() & ~uint64_t(0xFFFF0000)) == 0;
 280 }], HI16>;
 281
 282 def imm16ShiftedSExt : PatLeaf<(imm), [{
 283   // imm16ShiftedSExt predicate - True if only bits in the top 16-bits of the
 284   // immediate are set.  Used by instructions like 'addis'.  Identical to
 285   // imm16ShiftedZExt in 32-bit mode.
 286   if (N->getZExtValue() & 0xFFFF) return false;
 287   if (N->getValueType(0) == MVT::i32)
 288     return true;
 289   // For 64-bit, make sure it is sext right.
 290   return N->getZExtValue() == (uint64_t)(int)N->getZExtValue();
 291 }], HI16>;
 292
 293 def imm64ZExt32  : Operand<i64>, ImmLeaf<i64, [{
 294   // imm64ZExt32 predicate - True if the i64 immediate fits in a 32-bit
 295   // zero extended field.
 296   return isUInt<32>(Imm);
 297 }]>;
 298
 299 // Some r+i load/store instructions (such as LD, STD, LDU, etc.) that require
 300 // restricted memrix (4-aligned) constants are alignment sensitive. If these
 301 // offsets are hidden behind TOC entries than the values of the lower-order
 302 // bits cannot be checked directly. As a result, we need to also incorporate
 303 // an alignment check into the relevant patterns.
 304
 305 def aligned4load : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 306   return cast<LoadSDNode>(N)->getAlignment() >= 4;
 307 }]>;
 308 def aligned4store : PatFrag<(ops node:$val, node:$ptr),
 309                             (store node:$val, node:$ptr), [{
 310   return cast<StoreSDNode>(N)->getAlignment() >= 4;
 311 }]>;
 312 def aligned4sextloadi32 : PatFrag<(ops node:$ptr), (sextloadi32 node:$ptr), [{
 313   return cast<LoadSDNode>(N)->getAlignment() >= 4;
 314 }]>;
 315 def aligned4pre_store : PatFrag<
 316                           (ops node:$val, node:$base, node:$offset),
 317                           (pre_store node:$val, node:$base, node:$offset), [{
 318   return cast<StoreSDNode>(N)->getAlignment() >= 4;
 319 }]>;
 320
 321 def unaligned4load : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 322   return cast<LoadSDNode>(N)->getAlignment() < 4;
 323 }]>;
 324 def unaligned4store : PatFrag<(ops node:$val, node:$ptr),
 325                               (store node:$val, node:$ptr), [{
 326   return cast<StoreSDNode>(N)->getAlignment() < 4;
 327 }]>;
 328 def unaligned4sextloadi32 : PatFrag<(ops node:$ptr), (sextloadi32 node:$ptr), [{
 329   return cast<LoadSDNode>(N)->getAlignment() < 4;
 330 }]>;
 331
 332 //===----------------------------------------------------------------------===//
 333 // PowerPC Flag Definitions.
 334
 335 class isPPC64 { bit PPC64 = 1; }
 336 class isDOT   { bit RC = 1; }
 337
 338 class RegConstraint<string C> {
 339   string Constraints = C;
 340 }
 341 class NoEncode<string E> {
 342   string DisableEncoding = E;
 343 }
 344
 345
 346 //===----------------------------------------------------------------------===//
 347 // PowerPC Operand Definitions.
 348
 349 // In the default PowerPC assembler syntax, registers are specified simply
 350 // by number, so they cannot be distinguished from immediate values (without
 351 // looking at the opcode).  This means that the default operand matching logic
 352 // for the asm parser does not work, and we need to specify custom matchers.
 353 // Since those can only be specified with RegisterOperand classes and not
 354 // directly on the RegisterClass, all instructions patterns used by the asm
 355 // parser need to use a RegisterOperand (instead of a RegisterClass) for
 356 // all their register operands.
 357 // For this purpose, we define one RegisterOperand for each RegisterClass,
 358 // using the same name as the class, just in lower case.
 359
 360 def PPCRegGPRCAsmOperand : AsmOperandClass {
 361   let Name = "RegGPRC"; let PredicateMethod = "isRegNumber";
 362 }
 363 def gprc : RegisterOperand<GPRC> {
 364   let ParserMatchClass = PPCRegGPRCAsmOperand;
 365 }
 366 def PPCRegG8RCAsmOperand : AsmOperandClass {
 367   let Name = "RegG8RC"; let PredicateMethod = "isRegNumber";
 368 }
 369 def g8rc : RegisterOperand<G8RC> {
 370   let ParserMatchClass = PPCRegG8RCAsmOperand;
 371 }
 372 def PPCRegGPRCNoR0AsmOperand : AsmOperandClass {
 373   let Name = "RegGPRCNoR0"; let PredicateMethod = "isRegNumber";
 374 }
 375 def gprc_nor0 : RegisterOperand<GPRC_NOR0> {
 376   let ParserMatchClass = PPCRegGPRCNoR0AsmOperand;
 377 }
 378 def PPCRegG8RCNoX0AsmOperand : AsmOperandClass {
 379   let Name = "RegG8RCNoX0"; let PredicateMethod = "isRegNumber";
 380 }
 381 def g8rc_nox0 : RegisterOperand<G8RC_NOX0> {
 382   let ParserMatchClass = PPCRegG8RCNoX0AsmOperand;
 383 }
 384 def PPCRegF8RCAsmOperand : AsmOperandClass {
 385   let Name = "RegF8RC"; let PredicateMethod = "isRegNumber";
 386 }
 387 def f8rc : RegisterOperand<F8RC> {
 388   let ParserMatchClass = PPCRegF8RCAsmOperand;
 389 }
 390 def PPCRegF4RCAsmOperand : AsmOperandClass {
 391   let Name = "RegF4RC"; let PredicateMethod = "isRegNumber";
 392 }
 393 def f4rc : RegisterOperand<F4RC> {
 394   let ParserMatchClass = PPCRegF4RCAsmOperand;
 395 }
 396 def PPCRegVRRCAsmOperand : AsmOperandClass {
 397   let Name = "RegVRRC"; let PredicateMethod = "isRegNumber";
 398 }
 399 def vrrc : RegisterOperand<VRRC> {
 400   let ParserMatchClass = PPCRegVRRCAsmOperand;
 401 }
 402 def PPCRegCRBITRCAsmOperand : AsmOperandClass {
 403   let Name = "RegCRBITRC"; let PredicateMethod = "isCRBitNumber";
 404 }
 405 def crbitrc : RegisterOperand<CRBITRC> {
 406   let ParserMatchClass = PPCRegCRBITRCAsmOperand;
 407 }
 408 def PPCRegCRRCAsmOperand : AsmOperandClass {
 409   let Name = "RegCRRC"; let PredicateMethod = "isCCRegNumber";
 410 }
 411 def crrc : RegisterOperand<CRRC> {
 412   let ParserMatchClass = PPCRegCRRCAsmOperand;
 413 }
 414
 415 def PPCU2ImmAsmOperand : AsmOperandClass {
 416   let Name = "U2Imm"; let PredicateMethod = "isU2Imm";
 417   let RenderMethod = "addImmOperands";
 418 }
 419 def u2imm   : Operand<i32> {
 420   let PrintMethod = "printU2ImmOperand";
 421   let ParserMatchClass = PPCU2ImmAsmOperand;
 422 }
 423
 424 def PPCU4ImmAsmOperand : AsmOperandClass {
 425   let Name = "U4Imm"; let PredicateMethod = "isU4Imm";
 426   let RenderMethod = "addImmOperands";
 427 }
 428 def u4imm   : Operand<i32> {
 429   let PrintMethod = "printU4ImmOperand";
 430   let ParserMatchClass = PPCU4ImmAsmOperand;
 431 }
 432 def PPCS5ImmAsmOperand : AsmOperandClass {
 433   let Name = "S5Imm"; let PredicateMethod = "isS5Imm";
 434   let RenderMethod = "addImmOperands";
 435 }
 436 def s5imm   : Operand<i32> {
 437   let PrintMethod = "printS5ImmOperand";
 438   let ParserMatchClass = PPCS5ImmAsmOperand;
 439   let DecoderMethod = "decodeSImmOperand<5>";
 440 }
 441 def PPCU5ImmAsmOperand : AsmOperandClass {
 442   let Name = "U5Imm"; let PredicateMethod = "isU5Imm";
 443   let RenderMethod = "addImmOperands";
 444 }
 445 def u5imm   : Operand<i32> {
 446   let PrintMethod = "printU5ImmOperand";
 447   let ParserMatchClass = PPCU5ImmAsmOperand;
 448   let DecoderMethod = "decodeUImmOperand<5>";
 449 }
 450 def PPCU6ImmAsmOperand : AsmOperandClass {
 451   let Name = "U6Imm"; let PredicateMethod = "isU6Imm";
 452   let RenderMethod = "addImmOperands";
 453 }
 454 def u6imm   : Operand<i32> {
 455   let PrintMethod = "printU6ImmOperand";
 456   let ParserMatchClass = PPCU6ImmAsmOperand;
 457   let DecoderMethod = "decodeUImmOperand<6>";
 458 }
 459 def PPCS16ImmAsmOperand : AsmOperandClass {
 460   let Name = "S16Imm"; let PredicateMethod = "isS16Imm";
 461   let RenderMethod = "addImmOperands";
 462 }
 463 def s16imm  : Operand<i32> {
 464   let PrintMethod = "printS16ImmOperand";
 465   let EncoderMethod = "getImm16Encoding";
 466   let ParserMatchClass = PPCS16ImmAsmOperand;
 467   let DecoderMethod = "decodeSImmOperand<16>";
 468 }
 469 def PPCU16ImmAsmOperand : AsmOperandClass {
 470   let Name = "U16Imm"; let PredicateMethod = "isU16Imm";
 471   let RenderMethod = "addImmOperands";
 472 }
 473 def u16imm  : Operand<i32> {
 474   let PrintMethod = "printU16ImmOperand";
 475   let EncoderMethod = "getImm16Encoding";
 476   let ParserMatchClass = PPCU16ImmAsmOperand;
 477   let DecoderMethod = "decodeUImmOperand<16>";
 478 }
 479 def PPCS17ImmAsmOperand : AsmOperandClass {
 480   let Name = "S17Imm"; let PredicateMethod = "isS17Imm";
 481   let RenderMethod = "addImmOperands";
 482 }
 483 def s17imm  : Operand<i32> {
 484   // This operand type is used for addis/lis to allow the assembler parser
 485   // to accept immediates in the range -65536..65535 for compatibility with
 486   // the GNU assembler.  The operand is treated as 16-bit otherwise.
 487   let PrintMethod = "printS16ImmOperand";
 488   let EncoderMethod = "getImm16Encoding";
 489   let ParserMatchClass = PPCS17ImmAsmOperand;
 490   let DecoderMethod = "decodeSImmOperand<16>";
 491 }
 492 def PPCDirectBrAsmOperand : AsmOperandClass {
 493   let Name = "DirectBr"; let PredicateMethod = "isDirectBr";
 494   let RenderMethod = "addBranchTargetOperands";
 495 }
 496 def directbrtarget : Operand<OtherVT> {
 497   let PrintMethod = "printBranchOperand";
 498   let EncoderMethod = "getDirectBrEncoding";
 499   let ParserMatchClass = PPCDirectBrAsmOperand;
 500 }
 501 def absdirectbrtarget : Operand<OtherVT> {
 502   let PrintMethod = "printAbsBranchOperand";
 503   let EncoderMethod = "getAbsDirectBrEncoding";
 504   let ParserMatchClass = PPCDirectBrAsmOperand;
 505 }
 506 def PPCCondBrAsmOperand : AsmOperandClass {
 507   let Name = "CondBr"; let PredicateMethod = "isCondBr";
 508   let RenderMethod = "addBranchTargetOperands";
 509 }
 510 def condbrtarget : Operand<OtherVT> {
 511   let PrintMethod = "printBranchOperand";
 512   let EncoderMethod = "getCondBrEncoding";
 513   let ParserMatchClass = PPCCondBrAsmOperand;
 514 }
 515 def abscondbrtarget : Operand<OtherVT> {
 516   let PrintMethod = "printAbsBranchOperand";
 517   let EncoderMethod = "getAbsCondBrEncoding";
 518   let ParserMatchClass = PPCCondBrAsmOperand;
 519 }
 520 def calltarget : Operand<iPTR> {
 521   let PrintMethod = "printBranchOperand";
 522   let EncoderMethod = "getDirectBrEncoding";
 523   let ParserMatchClass = PPCDirectBrAsmOperand;
 524 }
 525 def abscalltarget : Operand<iPTR> {
 526   let PrintMethod = "printAbsBranchOperand";
 527   let EncoderMethod = "getAbsDirectBrEncoding";
 528   let ParserMatchClass = PPCDirectBrAsmOperand;
 529 }
 530 def PPCCRBitMaskOperand : AsmOperandClass {
 531  let Name = "CRBitMask"; let PredicateMethod = "isCRBitMask";
 532 }
 533 def crbitm: Operand<i8> {
 534   let PrintMethod = "printcrbitm";
 535   let EncoderMethod = "get_crbitm_encoding";
 536   let DecoderMethod = "decodeCRBitMOperand";
 537   let ParserMatchClass = PPCCRBitMaskOperand;
 538 }
 539 // Address operands
 540 // A version of ptr_rc which excludes R0 (or X0 in 64-bit mode).
 541 def PPCRegGxRCNoR0Operand : AsmOperandClass {
 542   let Name = "RegGxRCNoR0"; let PredicateMethod = "isRegNumber";
 543 }
 544 def ptr_rc_nor0 : Operand<iPTR>, PointerLikeRegClass<1> {
 545   let ParserMatchClass = PPCRegGxRCNoR0Operand;
 546 }
 547 // A version of ptr_rc usable with the asm parser.
 548 def PPCRegGxRCOperand : AsmOperandClass {
 549   let Name = "RegGxRC"; let PredicateMethod = "isRegNumber";
 550 }
 551 def ptr_rc_idx : Operand<iPTR>, PointerLikeRegClass<0> {
 552   let ParserMatchClass = PPCRegGxRCOperand;
 553 }
 554
 555 def PPCDispRIOperand : AsmOperandClass {
 556  let Name = "DispRI"; let PredicateMethod = "isS16Imm";
 557  let RenderMethod = "addImmOperands";
 558 }
 559 def dispRI : Operand<iPTR> {
 560   let ParserMatchClass = PPCDispRIOperand;
 561 }
 562 def PPCDispRIXOperand : AsmOperandClass {
 563  let Name = "DispRIX"; let PredicateMethod = "isS16ImmX4";
 564  let RenderMethod = "addImmOperands";
 565 }
 566 def dispRIX : Operand<iPTR> {
 567   let ParserMatchClass = PPCDispRIXOperand;
 568 }
 569 def PPCDispSPE8Operand : AsmOperandClass {
 570  let Name = "DispSPE8"; let PredicateMethod = "isU8ImmX8";
 571  let RenderMethod = "addImmOperands";
 572 }
 573 def dispSPE8 : Operand<iPTR> {
 574   let ParserMatchClass = PPCDispSPE8Operand;
 575 }
 576 def PPCDispSPE4Operand : AsmOperandClass {
 577  let Name = "DispSPE4"; let PredicateMethod = "isU7ImmX4";
 578  let RenderMethod = "addImmOperands";
 579 }
 580 def dispSPE4 : Operand<iPTR> {
 581   let ParserMatchClass = PPCDispSPE4Operand;
 582 }
 583 def PPCDispSPE2Operand : AsmOperandClass {
 584  let Name = "DispSPE2"; let PredicateMethod = "isU6ImmX2";
 585  let RenderMethod = "addImmOperands";
 586 }
 587 def dispSPE2 : Operand<iPTR> {
 588   let ParserMatchClass = PPCDispSPE2Operand;
 589 }
 590
 591 def memri : Operand<iPTR> {
 592   let PrintMethod = "printMemRegImm";
 593   let MIOperandInfo = (ops dispRI:$imm, ptr_rc_nor0:$reg);
 594   let EncoderMethod = "getMemRIEncoding";
 595   let DecoderMethod = "decodeMemRIOperands";
 596 }
 597 def memrr : Operand<iPTR> {
 598   let PrintMethod = "printMemRegReg";
 599   let MIOperandInfo = (ops ptr_rc_nor0:$ptrreg, ptr_rc_idx:$offreg);
 600 }
 601 def memrix : Operand<iPTR> {   // memri where the imm is 4-aligned.
 602   let PrintMethod = "printMemRegImm";
 603   let MIOperandInfo = (ops dispRIX:$imm, ptr_rc_nor0:$reg);
 604   let EncoderMethod = "getMemRIXEncoding";
 605   let DecoderMethod = "decodeMemRIXOperands";
 606 }
 607 def spe8dis : Operand<iPTR> {   // SPE displacement where the imm is 8-aligned.
 608   let PrintMethod = "printMemRegImm";
 609   let MIOperandInfo = (ops dispSPE8:$imm, ptr_rc_nor0:$reg);
 610   let EncoderMethod = "getSPE8DisEncoding";
 611 }
 612 def spe4dis : Operand<iPTR> {   // SPE displacement where the imm is 4-aligned.
 613   let PrintMethod = "printMemRegImm";
 614   let MIOperandInfo = (ops dispSPE4:$imm, ptr_rc_nor0:$reg);
 615   let EncoderMethod = "getSPE4DisEncoding";
 616 }
 617 def spe2dis : Operand<iPTR> {   // SPE displacement where the imm is 2-aligned.
 618   let PrintMethod = "printMemRegImm";
 619   let MIOperandInfo = (ops dispSPE2:$imm, ptr_rc_nor0:$reg);
 620   let EncoderMethod = "getSPE2DisEncoding";
 621 }
 622
 623 // A single-register address. This is used with the SjLj
 624 // pseudo-instructions.
 625 def memr : Operand<iPTR> {
 626   let MIOperandInfo = (ops ptr_rc:$ptrreg);
 627 }
 628 def PPCTLSRegOperand : AsmOperandClass {
 629   let Name = "TLSReg"; let PredicateMethod = "isTLSReg";
 630   let RenderMethod = "addTLSRegOperands";
 631 }
 632 def tlsreg32 : Operand<i32> {
 633   let EncoderMethod = "getTLSRegEncoding";
 634   let ParserMatchClass = PPCTLSRegOperand;
 635 }
 636 def tlsgd32 : Operand<i32> {}
 637 def tlscall32 : Operand<i32> {
 638   let PrintMethod = "printTLSCall";
 639   let MIOperandInfo = (ops calltarget:$func, tlsgd32:$sym);
 640   let EncoderMethod = "getTLSCallEncoding";
 641 }
 642
 643 // PowerPC Predicate operand.
 644 def pred : Operand<OtherVT> {
 645   let PrintMethod = "printPredicateOperand";
 646   let MIOperandInfo = (ops i32imm:$bibo, crrc:$reg);
 647 }
 648
 649 // Define PowerPC specific addressing mode.
 650 def iaddr  : ComplexPattern<iPTR, 2, "SelectAddrImm",    [], []>;
 651 def xaddr  : ComplexPattern<iPTR, 2, "SelectAddrIdx",    [], []>;
 652 def xoaddr : ComplexPattern<iPTR, 2, "SelectAddrIdxOnly",[], []>;
 653 def ixaddr : ComplexPattern<iPTR, 2, "SelectAddrImmX4",  [], []>; // "std"
 654
 655 // The address in a single register. This is used with the SjLj
 656 // pseudo-instructions.
 657 def addr   : ComplexPattern<iPTR, 1, "SelectAddr",[], []>;
 658
 659 /// This is just the offset part of iaddr, used for preinc.
 660 def iaddroff : ComplexPattern<iPTR, 1, "SelectAddrImmOffs", [], []>;
 661
 662 //===----------------------------------------------------------------------===//
 663 // PowerPC Instruction Predicate Definitions.
 664 def In32BitMode  : Predicate<"!PPCSubTarget->isPPC64()">;
 665 def In64BitMode  : Predicate<"PPCSubTarget->isPPC64()">;
 666 def IsBookE  : Predicate<"PPCSubTarget->isBookE()">;
 667 def IsNotBookE  : Predicate<"!PPCSubTarget->isBookE()">;
 668 def IsPPC4xx  : Predicate<"PPCSubTarget->isPPC4xx()">;
 669 def IsPPC6xx  : Predicate<"PPCSubTarget->isPPC6xx()">;
 670 def IsE500  : Predicate<"PPCSubTarget->isE500()">;
 671 def HasSPE  : Predicate<"PPCSubTarget->HasSPE()">;
 672
 673 //===----------------------------------------------------------------------===//
 674 // PowerPC Multiclass Definitions.
 675
 676 multiclass XForm_6r<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 677                     string asmbase, string asmstr, InstrItinClass itin,
 678                     list<dag> pattern> {
 679   let BaseName = asmbase in {
 680     def NAME : XForm_6<opcode, xo, OOL, IOL,
 681                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 682                        pattern>, RecFormRel;
 683     let Defs = [CR0] in
 684     def o    : XForm_6<opcode, xo, OOL, IOL,
 685                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 686                        []>, isDOT, RecFormRel;
 687   }
 688 }
 689
 690 multiclass XForm_6rc<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 691                      string asmbase, string asmstr, InstrItinClass itin,
 692                      list<dag> pattern> {
 693   let BaseName = asmbase in {
 694     let Defs = [CARRY] in
 695     def NAME : XForm_6<opcode, xo, OOL, IOL,
 696                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 697                        pattern>, RecFormRel;
 698     let Defs = [CARRY, CR0] in
 699     def o    : XForm_6<opcode, xo, OOL, IOL,
 700                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 701                        []>, isDOT, RecFormRel;
 702   }
 703 }
 704
 705 multiclass XForm_10rc<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 706                       string asmbase, string asmstr, InstrItinClass itin,
 707                       list<dag> pattern> {
 708   let BaseName = asmbase in {
 709     let Defs = [CARRY] in
 710     def NAME : XForm_10<opcode, xo, OOL, IOL,
 711                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 712                        pattern>, RecFormRel;
 713     let Defs = [CARRY, CR0] in
 714     def o    : XForm_10<opcode, xo, OOL, IOL,
 715                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 716                        []>, isDOT, RecFormRel;
 717   }
 718 }
 719
 720 multiclass XForm_11r<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 721                     string asmbase, string asmstr, InstrItinClass itin,
 722                     list<dag> pattern> {
 723   let BaseName = asmbase in {
 724     def NAME : XForm_11<opcode, xo, OOL, IOL,
 725                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 726                        pattern>, RecFormRel;
 727     let Defs = [CR0] in
 728     def o    : XForm_11<opcode, xo, OOL, IOL,
 729                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 730                        []>, isDOT, RecFormRel;
 731   }
 732 }
 733
 734 multiclass XOForm_1r<bits<6> opcode, bits<9> xo, bit oe, dag OOL, dag IOL,
 735                     string asmbase, string asmstr, InstrItinClass itin,
 736                     list<dag> pattern> {
 737   let BaseName = asmbase in {
 738     def NAME : XOForm_1<opcode, xo, oe, OOL, IOL,
 739                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 740                        pattern>, RecFormRel;
 741     let Defs = [CR0] in
 742     def o    : XOForm_1<opcode, xo, oe, OOL, IOL,
 743                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 744                        []>, isDOT, RecFormRel;
 745   }
 746 }
 747
 748 multiclass XOForm_1rc<bits<6> opcode, bits<9> xo, bit oe, dag OOL, dag IOL,
 749                       string asmbase, string asmstr, InstrItinClass itin,
 750                       list<dag> pattern> {
 751   let BaseName = asmbase in {
 752     let Defs = [CARRY] in
 753     def NAME : XOForm_1<opcode, xo, oe, OOL, IOL,
 754                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 755                        pattern>, RecFormRel;
 756     let Defs = [CARRY, CR0] in
 757     def o    : XOForm_1<opcode, xo, oe, OOL, IOL,
 758                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 759                        []>, isDOT, RecFormRel;
 760   }
 761 }
 762
 763 multiclass XOForm_3r<bits<6> opcode, bits<9> xo, bit oe, dag OOL, dag IOL,
 764                     string asmbase, string asmstr, InstrItinClass itin,
 765                     list<dag> pattern> {
 766   let BaseName = asmbase in {
 767     def NAME : XOForm_3<opcode, xo, oe, OOL, IOL,
 768                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 769                        pattern>, RecFormRel;
 770     let Defs = [CR0] in
 771     def o    : XOForm_3<opcode, xo, oe, OOL, IOL,
 772                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 773                        []>, isDOT, RecFormRel;
 774   }
 775 }
 776
 777 multiclass XOForm_3rc<bits<6> opcode, bits<9> xo, bit oe, dag OOL, dag IOL,
 778                       string asmbase, string asmstr, InstrItinClass itin,
 779                       list<dag> pattern> {
 780   let BaseName = asmbase in {
 781     let Defs = [CARRY] in
 782     def NAME : XOForm_3<opcode, xo, oe, OOL, IOL,
 783                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 784                        pattern>, RecFormRel;
 785     let Defs = [CARRY, CR0] in
 786     def o    : XOForm_3<opcode, xo, oe, OOL, IOL,
 787                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 788                        []>, isDOT, RecFormRel;
 789   }
 790 }
 791
 792 multiclass MForm_2r<bits<6> opcode, dag OOL, dag IOL,
 793                     string asmbase, string asmstr, InstrItinClass itin,
 794                     list<dag> pattern> {
 795   let BaseName = asmbase in {
 796     def NAME : MForm_2<opcode, OOL, IOL,
 797                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 798                        pattern>, RecFormRel;
 799     let Defs = [CR0] in
 800     def o    : MForm_2<opcode, OOL, IOL,
 801                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 802                        []>, isDOT, RecFormRel;
 803   }
 804 }
 805
 806 multiclass MDForm_1r<bits<6> opcode, bits<3> xo, dag OOL, dag IOL,
 807                     string asmbase, string asmstr, InstrItinClass itin,
 808                     list<dag> pattern> {
 809   let BaseName = asmbase in {
 810     def NAME : MDForm_1<opcode, xo, OOL, IOL,
 811                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 812                        pattern>, RecFormRel;
 813     let Defs = [CR0] in
 814     def o    : MDForm_1<opcode, xo, OOL, IOL,
 815                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 816                        []>, isDOT, RecFormRel;
 817   }
 818 }
 819
 820 multiclass MDSForm_1r<bits<6> opcode, bits<4> xo, dag OOL, dag IOL,
 821                      string asmbase, string asmstr, InstrItinClass itin,
 822                      list<dag> pattern> {
 823   let BaseName = asmbase in {
 824     def NAME : MDSForm_1<opcode, xo, OOL, IOL,
 825                         !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 826                         pattern>, RecFormRel;
 827     let Defs = [CR0] in
 828     def o    : MDSForm_1<opcode, xo, OOL, IOL,
 829                         !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 830                         []>, isDOT, RecFormRel;
 831   }
 832 }
 833
 834 multiclass XSForm_1rc<bits<6> opcode, bits<9> xo, dag OOL, dag IOL,
 835                       string asmbase, string asmstr, InstrItinClass itin,
 836                       list<dag> pattern> {
 837   let BaseName = asmbase in {
 838     let Defs = [CARRY] in
 839     def NAME : XSForm_1<opcode, xo, OOL, IOL,
 840                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 841                        pattern>, RecFormRel;
 842     let Defs = [CARRY, CR0] in
 843     def o    : XSForm_1<opcode, xo, OOL, IOL,
 844                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 845                        []>, isDOT, RecFormRel;
 846   }
 847 }
 848
 849 multiclass XForm_26r<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 850                     string asmbase, string asmstr, InstrItinClass itin,
 851                     list<dag> pattern> {
 852   let BaseName = asmbase in {
 853     def NAME : XForm_26<opcode, xo, OOL, IOL,
 854                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 855                        pattern>, RecFormRel;
 856     let Defs = [CR1] in
 857     def o    : XForm_26<opcode, xo, OOL, IOL,
 858                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 859                        []>, isDOT, RecFormRel;
 860   }
 861 }
 862
 863 multiclass XForm_28r<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 864                     string asmbase, string asmstr, InstrItinClass itin,
 865                     list<dag> pattern> {
 866   let BaseName = asmbase in {
 867     def NAME : XForm_28<opcode, xo, OOL, IOL,
 868                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 869                        pattern>, RecFormRel;
 870     let Defs = [CR1] in
 871     def o    : XForm_28<opcode, xo, OOL, IOL,
 872                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 873                        []>, isDOT, RecFormRel;
 874   }
 875 }
 876
 877 multiclass AForm_1r<bits<6> opcode, bits<5> xo, dag OOL, dag IOL,
 878                     string asmbase, string asmstr, InstrItinClass itin,
 879                     list<dag> pattern> {
 880   let BaseName = asmbase in {
 881     def NAME : AForm_1<opcode, xo, OOL, IOL,
 882                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 883                        pattern>, RecFormRel;
 884     let Defs = [CR1] in
 885     def o    : AForm_1<opcode, xo, OOL, IOL,
 886                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 887                        []>, isDOT, RecFormRel;
 888   }
 889 }
 890
 891 multiclass AForm_2r<bits<6> opcode, bits<5> xo, dag OOL, dag IOL,
 892                     string asmbase, string asmstr, InstrItinClass itin,
 893                     list<dag> pattern> {
 894   let BaseName = asmbase in {
 895     def NAME : AForm_2<opcode, xo, OOL, IOL,
 896                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 897                        pattern>, RecFormRel;
 898     let Defs = [CR1] in
 899     def o    : AForm_2<opcode, xo, OOL, IOL,
 900                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 901                        []>, isDOT, RecFormRel;
 902   }
 903 }
 904
 905 multiclass AForm_3r<bits<6> opcode, bits<5> xo, dag OOL, dag IOL,
 906                     string asmbase, string asmstr, InstrItinClass itin,
 907                     list<dag> pattern> {
 908   let BaseName = asmbase in {
 909     def NAME : AForm_3<opcode, xo, OOL, IOL,
 910                        !strconcat(asmbase, !strconcat(" ", asmstr)), itin,
 911                        pattern>, RecFormRel;
 912     let Defs = [CR1] in
 913     def o    : AForm_3<opcode, xo, OOL, IOL,
 914                        !strconcat(asmbase, !strconcat(". ", asmstr)), itin,
 915                        []>, isDOT, RecFormRel;
 916   }
 917 }
 918
 919 //===----------------------------------------------------------------------===//
 920 // PowerPC Instruction Definitions.
 921
 922 // Pseudo-instructions:
 923
 924 let hasCtrlDep = 1 in {
 925 let Defs = [R1], Uses = [R1] in {
 926 def ADJCALLSTACKDOWN : Pseudo<(outs), (ins u16imm:$amt), "#ADJCALLSTACKDOWN $amt",
 927                               [(callseq_start timm:$amt)]>;
 928 def ADJCALLSTACKUP   : Pseudo<(outs), (ins u16imm:$amt1, u16imm:$amt2), "#ADJCALLSTACKUP $amt1 $amt2",
 929                               [(callseq_end timm:$amt1, timm:$amt2)]>;
 930 }
 931
 932 def UPDATE_VRSAVE    : Pseudo<(outs gprc:$rD), (ins gprc:$rS),
 933                               "UPDATE_VRSAVE $rD, $rS", []>;
 934 }
 935
 936 let Defs = [R1], Uses = [R1] in
 937 def DYNALLOC : Pseudo<(outs gprc:$result), (ins gprc:$negsize, memri:$fpsi), "#DYNALLOC",
 938                        [(set i32:$result,
 939                              (PPCdynalloc i32:$negsize, iaddr:$fpsi))]>;
 940
 941 // SELECT_CC_* - Used to implement the SELECT_CC DAG operation.  Expanded after
 942 // instruction selection into a branch sequence.
 943 let usesCustomInserter = 1,    // Expanded after instruction selection.
 944     PPC970_Single = 1 in {
 945   // Note that SELECT_CC_I4 and SELECT_CC_I8 use the no-r0 register classes
 946   // because either operand might become the first operand in an isel, and
 947   // that operand cannot be r0.
 948   def SELECT_CC_I4 : Pseudo<(outs gprc:$dst), (ins crrc:$cond,
 949                               gprc_nor0:$T, gprc_nor0:$F,
 950                               i32imm:$BROPC), "#SELECT_CC_I4",
 951                               []>;
 952   def SELECT_CC_I8 : Pseudo<(outs g8rc:$dst), (ins crrc:$cond,
 953                               g8rc_nox0:$T, g8rc_nox0:$F,
 954                               i32imm:$BROPC), "#SELECT_CC_I8",
 955                               []>;
 956   def SELECT_CC_F4  : Pseudo<(outs f4rc:$dst), (ins crrc:$cond, f4rc:$T, f4rc:$F,
 957                               i32imm:$BROPC), "#SELECT_CC_F4",
 958                               []>;
 959   def SELECT_CC_F8  : Pseudo<(outs f8rc:$dst), (ins crrc:$cond, f8rc:$T, f8rc:$F,
 960                               i32imm:$BROPC), "#SELECT_CC_F8",
 961                               []>;
 962   def SELECT_CC_VRRC: Pseudo<(outs vrrc:$dst), (ins crrc:$cond, vrrc:$T, vrrc:$F,
 963                               i32imm:$BROPC), "#SELECT_CC_VRRC",
 964                               []>;
 965
 966   // SELECT_* pseudo instructions, like SELECT_CC_* but taking condition
 967   // register bit directly.
 968   def SELECT_I4 : Pseudo<(outs gprc:$dst), (ins crbitrc:$cond,
 969                           gprc_nor0:$T, gprc_nor0:$F), "#SELECT_I4",
 970                           [(set i32:$dst, (select i1:$cond, i32:$T, i32:$F))]>;
 971   def SELECT_I8 : Pseudo<(outs g8rc:$dst), (ins crbitrc:$cond,
 972                           g8rc_nox0:$T, g8rc_nox0:$F), "#SELECT_I8",
 973                           [(set i64:$dst, (select i1:$cond, i64:$T, i64:$F))]>;
 974   def SELECT_F4  : Pseudo<(outs f4rc:$dst), (ins crbitrc:$cond,
 975                           f4rc:$T, f4rc:$F), "#SELECT_F4",
 976                           [(set f32:$dst, (select i1:$cond, f32:$T, f32:$F))]>;
 977   def SELECT_F8  : Pseudo<(outs f8rc:$dst), (ins crbitrc:$cond,
 978                           f8rc:$T, f8rc:$F), "#SELECT_F8",
 979                           [(set f64:$dst, (select i1:$cond, f64:$T, f64:$F))]>;
 980   def SELECT_VRRC: Pseudo<(outs vrrc:$dst), (ins crbitrc:$cond,
 981                           vrrc:$T, vrrc:$F), "#SELECT_VRRC",
 982                           [(set v4i32:$dst,
 983                                 (select i1:$cond, v4i32:$T, v4i32:$F))]>;
 984 }
 985
 986 // SPILL_CR - Indicate that we're dumping the CR register, so we'll need to
 987 // scavenge a register for it.
 988 let mayStore = 1 in {
 989 def SPILL_CR : Pseudo<(outs), (ins crrc:$cond, memri:$F),
 990                      "#SPILL_CR", []>;
 991 def SPILL_CRBIT : Pseudo<(outs), (ins crbitrc:$cond, memri:$F),
 992                          "#SPILL_CRBIT", []>;
 993 }
 994
 995 // RESTORE_CR - Indicate that we're restoring the CR register (previously
 996 // spilled), so we'll need to scavenge a register for it.
 997 let mayLoad = 1 in {
 998 def RESTORE_CR : Pseudo<(outs crrc:$cond), (ins memri:$F),
 999                      "#RESTORE_CR", []>;
1000 def RESTORE_CRBIT : Pseudo<(outs crbitrc:$cond), (ins memri:$F),
1001                            "#RESTORE_CRBIT", []>;
1002 }
1003
1004 let isTerminator = 1, isBarrier = 1, PPC970_Unit = 7 in {
1005   let isReturn = 1, Uses = [LR, RM] in
1006     def BLR : XLForm_2_ext<19, 16, 20, 0, 0, (outs), (ins), "blr", IIC_BrB,
1007                            [(retflag)]>;
1008   let isBranch = 1, isIndirectBranch = 1, Uses = [CTR] in {
1009     def BCTR : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", IIC_BrB,
1010                             []>;
1011
1012     let isCodeGenOnly = 1 in {
1013       def BCCCTR : XLForm_2_br<19, 528, 0, (outs), (ins pred:$cond),
1014                                "b${cond:cc}ctr${cond:pm} ${cond:reg}", IIC_BrB,
1015                                []>;
1016
1017       def BCCTR :  XLForm_2_br2<19, 528, 12, 0, (outs), (ins crbitrc:$bi),
1018                                 "bcctr 12, $bi, 0", IIC_BrB, []>;
1019       def BCCTRn : XLForm_2_br2<19, 528, 4, 0, (outs), (ins crbitrc:$bi),
1020                                 "bcctr 4, $bi, 0", IIC_BrB, []>;
1021     }
1022   }
1023 }
1024
1025 let Defs = [LR] in
1026   def MovePCtoLR : Pseudo<(outs), (ins), "#MovePCtoLR", []>,
1027                    PPC970_Unit_BRU;
1028
1029 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7 in {
1030   let isBarrier = 1 in {
1031   def B   : IForm<18, 0, 0, (outs), (ins directbrtarget:$dst),
1032                   "b $dst", IIC_BrB,
1033                   [(br bb:$dst)]>;
1034   def BA  : IForm<18, 1, 0, (outs), (ins absdirectbrtarget:$dst),
1035                   "ba $dst", IIC_BrB, []>;
1036   }
1037
1038   // BCC represents an arbitrary conditional branch on a predicate.
1039   // FIXME: should be able to write a pattern for PPCcondbranch, but can't use
1040   // a two-value operand where a dag node expects two operands. :(
1041   let isCodeGenOnly = 1 in {
1042     def BCC : BForm<16, 0, 0, (outs), (ins pred:$cond, condbrtarget:$dst),
1043                     "b${cond:cc}${cond:pm} ${cond:reg}, $dst"
1044                     /*[(PPCcondbranch crrc:$crS, imm:$opc, bb:$dst)]*/>;
1045     def BCCA : BForm<16, 1, 0, (outs), (ins pred:$cond, abscondbrtarget:$dst),
1046                      "b${cond:cc}a${cond:pm} ${cond:reg}, $dst">;
1047
1048     let isReturn = 1, Uses = [LR, RM] in
1049     def BCCLR : XLForm_2_br<19, 16, 0, (outs), (ins pred:$cond),
1050                            "b${cond:cc}lr${cond:pm} ${cond:reg}", IIC_BrB, []>;
1051   }
1052
1053   let isCodeGenOnly = 1 in {
1054     let Pattern = [(brcond i1:$bi, bb:$dst)] in
1055     def BC  : BForm_4<16, 12, 0, 0, (outs), (ins crbitrc:$bi, condbrtarget:$dst),
1056              "bc 12, $bi, $dst">;
1057
1058     let Pattern = [(brcond (not i1:$bi), bb:$dst)] in
1059     def BCn : BForm_4<16, 4, 0, 0, (outs), (ins crbitrc:$bi, condbrtarget:$dst),
1060              "bc 4, $bi, $dst">;
1061
1062     let isReturn = 1, Uses = [LR, RM] in
1063     def BCLR  : XLForm_2_br2<19, 16, 12, 0, (outs), (ins crbitrc:$bi),
1064                              "bclr 12, $bi, 0", IIC_BrB, []>;
1065     def BCLRn : XLForm_2_br2<19, 16, 4, 0, (outs), (ins crbitrc:$bi),
1066                              "bclr 4, $bi, 0", IIC_BrB, []>;
1067   }
1068
1069   let isReturn = 1, Defs = [CTR], Uses = [CTR, LR, RM] in {
1070    def BDZLR  : XLForm_2_ext<19, 16, 18, 0, 0, (outs), (ins),
1071                              "bdzlr", IIC_BrB, []>;
1072    def BDNZLR : XLForm_2_ext<19, 16, 16, 0, 0, (outs), (ins),
1073                              "bdnzlr", IIC_BrB, []>;
1074    def BDZLRp : XLForm_2_ext<19, 16, 27, 0, 0, (outs), (ins),
1075                              "bdzlr+", IIC_BrB, []>;
1076    def BDNZLRp: XLForm_2_ext<19, 16, 25, 0, 0, (outs), (ins),
1077                              "bdnzlr+", IIC_BrB, []>;
1078    def BDZLRm : XLForm_2_ext<19, 16, 26, 0, 0, (outs), (ins),
1079                              "bdzlr-", IIC_BrB, []>;
1080    def BDNZLRm: XLForm_2_ext<19, 16, 24, 0, 0, (outs), (ins),
1081                              "bdnzlr-", IIC_BrB, []>;
1082   }
1083
1084   let Defs = [CTR], Uses = [CTR] in {
1085     def BDZ  : BForm_1<16, 18, 0, 0, (outs), (ins condbrtarget:$dst),
1086                        "bdz $dst">;
1087     def BDNZ : BForm_1<16, 16, 0, 0, (outs), (ins condbrtarget:$dst),
1088                        "bdnz $dst">;
1089     def BDZA  : BForm_1<16, 18, 1, 0, (outs), (ins abscondbrtarget:$dst),
1090                         "bdza $dst">;
1091     def BDNZA : BForm_1<16, 16, 1, 0, (outs), (ins abscondbrtarget:$dst),
1092                         "bdnza $dst">;
1093     def BDZp : BForm_1<16, 27, 0, 0, (outs), (ins condbrtarget:$dst),
1094                        "bdz+ $dst">;
1095     def BDNZp: BForm_1<16, 25, 0, 0, (outs), (ins condbrtarget:$dst),
1096                        "bdnz+ $dst">;
1097     def BDZAp : BForm_1<16, 27, 1, 0, (outs), (ins abscondbrtarget:$dst),
1098                         "bdza+ $dst">;
1099     def BDNZAp: BForm_1<16, 25, 1, 0, (outs), (ins abscondbrtarget:$dst),
1100                         "bdnza+ $dst">;
1101     def BDZm : BForm_1<16, 26, 0, 0, (outs), (ins condbrtarget:$dst),
1102                        "bdz- $dst">;
1103     def BDNZm: BForm_1<16, 24, 0, 0, (outs), (ins condbrtarget:$dst),
1104                        "bdnz- $dst">;
1105     def BDZAm : BForm_1<16, 26, 1, 0, (outs), (ins abscondbrtarget:$dst),
1106                         "bdza- $dst">;
1107     def BDNZAm: BForm_1<16, 24, 1, 0, (outs), (ins abscondbrtarget:$dst),
1108                         "bdnza- $dst">;
1109   }
1110 }
1111
1112 // The unconditional BCL used by the SjLj setjmp code.
1113 let isCall = 1, hasCtrlDep = 1, isCodeGenOnly = 1, PPC970_Unit = 7 in {
1114   let Defs = [LR], Uses = [RM] in {
1115     def BCLalways  : BForm_2<16, 20, 31, 0, 1, (outs), (ins condbrtarget:$dst),
1116                             "bcl 20, 31, $dst">;
1117   }
1118 }
1119
1120 let isCall = 1, PPC970_Unit = 7, Defs = [LR] in {
1121   // Convenient aliases for call instructions
1122   let Uses = [RM] in {
1123     def BL  : IForm<18, 0, 1, (outs), (ins calltarget:$func),
1124                     "bl $func", IIC_BrB, []>;  // See Pat patterns below.
1125     def BLA : IForm<18, 1, 1, (outs), (ins abscalltarget:$func),
1126                     "bla $func", IIC_BrB, [(PPCcall (i32 imm:$func))]>;
1127
1128     let isCodeGenOnly = 1 in {
1129       def BL_TLS  : IForm<18, 0, 1, (outs), (ins tlscall32:$func),
1130                           "bl $func", IIC_BrB, []>;
1131       def BCCL : BForm<16, 0, 1, (outs), (ins pred:$cond, condbrtarget:$dst),
1132                        "b${cond:cc}l${cond:pm} ${cond:reg}, $dst">;
1133       def BCCLA : BForm<16, 1, 1, (outs), (ins pred:$cond, abscondbrtarget:$dst),
1134                         "b${cond:cc}la${cond:pm} ${cond:reg}, $dst">;
1135
1136       def BCL  : BForm_4<16, 12, 0, 1, (outs),
1137                          (ins crbitrc:$bi, condbrtarget:$dst),
1138                          "bcl 12, $bi, $dst">;
1139       def BCLn : BForm_4<16, 4, 0, 1, (outs),
1140                          (ins crbitrc:$bi, condbrtarget:$dst),
1141                          "bcl 4, $bi, $dst">;
1142     }
1143   }
1144   let Uses = [CTR, RM] in {
1145     def BCTRL : XLForm_2_ext<19, 528, 20, 0, 1, (outs), (ins),
1146                              "bctrl", IIC_BrB, [(PPCbctrl)]>,
1147                 Requires<[In32BitMode]>;
1148
1149     let isCodeGenOnly = 1 in {
1150       def BCCCTRL : XLForm_2_br<19, 528, 1, (outs), (ins pred:$cond),
1151                                 "b${cond:cc}ctrl${cond:pm} ${cond:reg}", IIC_BrB,
1152                                 []>;
1153
1154       def BCCTRL  : XLForm_2_br2<19, 528, 12, 1, (outs), (ins crbitrc:$bi),
1155                                  "bcctrl 12, $bi, 0", IIC_BrB, []>;
1156       def BCCTRLn : XLForm_2_br2<19, 528, 4, 1, (outs), (ins crbitrc:$bi),
1157                                  "bcctrl 4, $bi, 0", IIC_BrB, []>;
1158     }
1159   }
1160   let Uses = [LR, RM] in {
1161     def BLRL : XLForm_2_ext<19, 16, 20, 0, 1, (outs), (ins),
1162                             "blrl", IIC_BrB, []>;
1163
1164     let isCodeGenOnly = 1 in {
1165       def BCCLRL : XLForm_2_br<19, 16, 1, (outs), (ins pred:$cond),
1166                               "b${cond:cc}lrl${cond:pm} ${cond:reg}", IIC_BrB,
1167                               []>;
1168
1169       def BCLRL  : XLForm_2_br2<19, 16, 12, 1, (outs), (ins crbitrc:$bi),
1170                                 "bclrl 12, $bi, 0", IIC_BrB, []>;
1171       def BCLRLn : XLForm_2_br2<19, 16, 4, 1, (outs), (ins crbitrc:$bi),
1172                                 "bclrl 4, $bi, 0", IIC_BrB, []>;
1173     }
1174   }
1175   let Defs = [CTR], Uses = [CTR, RM] in {
1176     def BDZL  : BForm_1<16, 18, 0, 1, (outs), (ins condbrtarget:$dst),
1177                         "bdzl $dst">;
1178     def BDNZL : BForm_1<16, 16, 0, 1, (outs), (ins condbrtarget:$dst),
1179                         "bdnzl $dst">;
1180     def BDZLA  : BForm_1<16, 18, 1, 1, (outs), (ins abscondbrtarget:$dst),
1181                          "bdzla $dst">;
1182     def BDNZLA : BForm_1<16, 16, 1, 1, (outs), (ins abscondbrtarget:$dst),
1183                          "bdnzla $dst">;
1184     def BDZLp : BForm_1<16, 27, 0, 1, (outs), (ins condbrtarget:$dst),
1185                         "bdzl+ $dst">;
1186     def BDNZLp: BForm_1<16, 25, 0, 1, (outs), (ins condbrtarget:$dst),
1187                         "bdnzl+ $dst">;
1188     def BDZLAp : BForm_1<16, 27, 1, 1, (outs), (ins abscondbrtarget:$dst),
1189                          "bdzla+ $dst">;
1190     def BDNZLAp: BForm_1<16, 25, 1, 1, (outs), (ins abscondbrtarget:$dst),
1191                          "bdnzla+ $dst">;
1192     def BDZLm : BForm_1<16, 26, 0, 1, (outs), (ins condbrtarget:$dst),
1193                         "bdzl- $dst">;
1194     def BDNZLm: BForm_1<16, 24, 0, 1, (outs), (ins condbrtarget:$dst),
1195                         "bdnzl- $dst">;
1196     def BDZLAm : BForm_1<16, 26, 1, 1, (outs), (ins abscondbrtarget:$dst),
1197                          "bdzla- $dst">;
1198     def BDNZLAm: BForm_1<16, 24, 1, 1, (outs), (ins abscondbrtarget:$dst),
1199                          "bdnzla- $dst">;
1200   }
1201   let Defs = [CTR], Uses = [CTR, LR, RM] in {
1202     def BDZLRL  : XLForm_2_ext<19, 16, 18, 0, 1, (outs), (ins),
1203                                "bdzlrl", IIC_BrB, []>;
1204     def BDNZLRL : XLForm_2_ext<19, 16, 16, 0, 1, (outs), (ins),
1205                                "bdnzlrl", IIC_BrB, []>;
1206     def BDZLRLp : XLForm_2_ext<19, 16, 27, 0, 1, (outs), (ins),
1207                                "bdzlrl+", IIC_BrB, []>;
1208     def BDNZLRLp: XLForm_2_ext<19, 16, 25, 0, 1, (outs), (ins),
1209                                "bdnzlrl+", IIC_BrB, []>;
1210     def BDZLRLm : XLForm_2_ext<19, 16, 26, 0, 1, (outs), (ins),
1211                                "bdzlrl-", IIC_BrB, []>;
1212     def BDNZLRLm: XLForm_2_ext<19, 16, 24, 0, 1, (outs), (ins),
1213                                "bdnzlrl-", IIC_BrB, []>;
1214   }
1215 }
1216
1217 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
1218 def TCRETURNdi :Pseudo< (outs),
1219                         (ins calltarget:$dst, i32imm:$offset),
1220                  "#TC_RETURNd $dst $offset",
1221                  []>;
1222
1223
1224 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
1225 def TCRETURNai :Pseudo<(outs), (ins abscalltarget:$func, i32imm:$offset),
1226                  "#TC_RETURNa $func $offset",
1227                  [(PPCtc_return (i32 imm:$func), imm:$offset)]>;
1228
1229 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
1230 def TCRETURNri : Pseudo<(outs), (ins CTRRC:$dst, i32imm:$offset),
1231                  "#TC_RETURNr $dst $offset",
1232                  []>;
1233
1234
1235 let isCodeGenOnly = 1 in {
1236
1237 let isTerminator = 1, isBarrier = 1, PPC970_Unit = 7, isBranch = 1,
1238     isIndirectBranch = 1, isCall = 1, isReturn = 1, Uses = [CTR, RM]  in
1239 def TAILBCTR : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", IIC_BrB,
1240                             []>, Requires<[In32BitMode]>;
1241
1242 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
1243     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
1244 def TAILB   : IForm<18, 0, 0, (outs), (ins calltarget:$dst),
1245                   "b $dst", IIC_BrB,
1246                   []>;
1247
1248 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
1249     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
1250 def TAILBA   : IForm<18, 0, 0, (outs), (ins abscalltarget:$dst),
1251                   "ba $dst", IIC_BrB,
1252                   []>;
1253
1254 }
1255
1256 let hasSideEffects = 1, isBarrier = 1, usesCustomInserter = 1 in {
1257   let Defs = [CTR] in
1258   def EH_SjLj_SetJmp32  : Pseudo<(outs gprc:$dst), (ins memr:$buf),
1259                             "#EH_SJLJ_SETJMP32",
1260                             [(set i32:$dst, (PPCeh_sjlj_setjmp addr:$buf))]>,
1261                           Requires<[In32BitMode]>;
1262   let isTerminator = 1 in
1263   def EH_SjLj_LongJmp32 : Pseudo<(outs), (ins memr:$buf),
1264                             "#EH_SJLJ_LONGJMP32",
1265                             [(PPCeh_sjlj_longjmp addr:$buf)]>,
1266                           Requires<[In32BitMode]>;
1267 }
1268
1269 let isBranch = 1, isTerminator = 1 in {
1270   def EH_SjLj_Setup : Pseudo<(outs), (ins directbrtarget:$dst),
1271                         "#EH_SjLj_Setup\t$dst", []>;
1272 }
1273
1274 // System call.
1275 let PPC970_Unit = 7 in {
1276   def SC     : SCForm<17, 1, (outs), (ins i32imm:$lev),
1277                       "sc $lev", IIC_BrB, [(PPCsc (i32 imm:$lev))]>;
1278 }
1279
1280 // DCB* instructions.
1281 def DCBA   : DCB_Form<758, 0, (outs), (ins memrr:$dst), "dcba $dst",
1282                       IIC_LdStDCBF, [(int_ppc_dcba xoaddr:$dst)]>,
1283                       PPC970_DGroup_Single;
1284 def DCBF   : DCB_Form<86, 0, (outs), (ins memrr:$dst), "dcbf $dst",
1285                       IIC_LdStDCBF, [(int_ppc_dcbf xoaddr:$dst)]>,
1286                       PPC970_DGroup_Single;
1287 def DCBI   : DCB_Form<470, 0, (outs), (ins memrr:$dst), "dcbi $dst",
1288                       IIC_LdStDCBF, [(int_ppc_dcbi xoaddr:$dst)]>,
1289                       PPC970_DGroup_Single;
1290 def DCBST  : DCB_Form<54, 0, (outs), (ins memrr:$dst), "dcbst $dst",
1291                       IIC_LdStDCBF, [(int_ppc_dcbst xoaddr:$dst)]>,
1292                       PPC970_DGroup_Single;
1293 def DCBT   : DCB_Form<278, 0, (outs), (ins memrr:$dst), "dcbt $dst",
1294                       IIC_LdStDCBF, [(int_ppc_dcbt xoaddr:$dst)]>,
1295                       PPC970_DGroup_Single;
1296 def DCBTST : DCB_Form<246, 0, (outs), (ins memrr:$dst), "dcbtst $dst",
1297                       IIC_LdStDCBF, [(int_ppc_dcbtst xoaddr:$dst)]>,
1298                       PPC970_DGroup_Single;
1299 def DCBZ   : DCB_Form<1014, 0, (outs), (ins memrr:$dst), "dcbz $dst",
1300                       IIC_LdStDCBF, [(int_ppc_dcbz xoaddr:$dst)]>,
1301                       PPC970_DGroup_Single;
1302 def DCBZL  : DCB_Form<1014, 1, (outs), (ins memrr:$dst), "dcbzl $dst",
1303                       IIC_LdStDCBF, [(int_ppc_dcbzl xoaddr:$dst)]>,
1304                       PPC970_DGroup_Single;
1305
1306 def : Pat<(prefetch xoaddr:$dst, (i32 0), imm, (i32 1)),
1307           (DCBT xoaddr:$dst)>;
1308
1309 // Atomic operations
1310 let usesCustomInserter = 1 in {
1311   let Defs = [CR0] in {
1312     def ATOMIC_LOAD_ADD_I8 : Pseudo<
1313       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_ADD_I8",
1314       [(set i32:$dst, (atomic_load_add_8 xoaddr:$ptr, i32:$incr))]>;
1315     def ATOMIC_LOAD_SUB_I8 : Pseudo<
1316       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_SUB_I8",
1317       [(set i32:$dst, (atomic_load_sub_8 xoaddr:$ptr, i32:$incr))]>;
1318     def ATOMIC_LOAD_AND_I8 : Pseudo<
1319       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_AND_I8",
1320       [(set i32:$dst, (atomic_load_and_8 xoaddr:$ptr, i32:$incr))]>;
1321     def ATOMIC_LOAD_OR_I8 : Pseudo<
1322       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_OR_I8",
1323       [(set i32:$dst, (atomic_load_or_8 xoaddr:$ptr, i32:$incr))]>;
1324     def ATOMIC_LOAD_XOR_I8 : Pseudo<
1325       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "ATOMIC_LOAD_XOR_I8",
1326       [(set i32:$dst, (atomic_load_xor_8 xoaddr:$ptr, i32:$incr))]>;
1327     def ATOMIC_LOAD_NAND_I8 : Pseudo<
1328       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_NAND_I8",
1329       [(set i32:$dst, (atomic_load_nand_8 xoaddr:$ptr, i32:$incr))]>;
1330     def ATOMIC_LOAD_ADD_I16 : Pseudo<
1331       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_ADD_I16",
1332       [(set i32:$dst, (atomic_load_add_16 xoaddr:$ptr, i32:$incr))]>;
1333     def ATOMIC_LOAD_SUB_I16 : Pseudo<
1334       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_SUB_I16",
1335       [(set i32:$dst, (atomic_load_sub_16 xoaddr:$ptr, i32:$incr))]>;
1336     def ATOMIC_LOAD_AND_I16 : Pseudo<
1337       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_AND_I16",
1338       [(set i32:$dst, (atomic_load_and_16 xoaddr:$ptr, i32:$incr))]>;
1339     def ATOMIC_LOAD_OR_I16 : Pseudo<
1340       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_OR_I16",
1341       [(set i32:$dst, (atomic_load_or_16 xoaddr:$ptr, i32:$incr))]>;
1342     def ATOMIC_LOAD_XOR_I16 : Pseudo<
1343       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_XOR_I16",
1344       [(set i32:$dst, (atomic_load_xor_16 xoaddr:$ptr, i32:$incr))]>;
1345     def ATOMIC_LOAD_NAND_I16 : Pseudo<
1346       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_NAND_I16",
1347       [(set i32:$dst, (atomic_load_nand_16 xoaddr:$ptr, i32:$incr))]>;
1348     def ATOMIC_LOAD_ADD_I32 : Pseudo<
1349       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_ADD_I32",
1350       [(set i32:$dst, (atomic_load_add_32 xoaddr:$ptr, i32:$incr))]>;
1351     def ATOMIC_LOAD_SUB_I32 : Pseudo<
1352       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_SUB_I32",
1353       [(set i32:$dst, (atomic_load_sub_32 xoaddr:$ptr, i32:$incr))]>;
1354     def ATOMIC_LOAD_AND_I32 : Pseudo<
1355       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_AND_I32",
1356       [(set i32:$dst, (atomic_load_and_32 xoaddr:$ptr, i32:$incr))]>;
1357     def ATOMIC_LOAD_OR_I32 : Pseudo<
1358       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_OR_I32",
1359       [(set i32:$dst, (atomic_load_or_32 xoaddr:$ptr, i32:$incr))]>;
1360     def ATOMIC_LOAD_XOR_I32 : Pseudo<
1361       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_XOR_I32",
1362       [(set i32:$dst, (atomic_load_xor_32 xoaddr:$ptr, i32:$incr))]>;
1363     def ATOMIC_LOAD_NAND_I32 : Pseudo<
1364       (outs gprc:$dst), (ins memrr:$ptr, gprc:$incr), "#ATOMIC_LOAD_NAND_I32",
1365       [(set i32:$dst, (atomic_load_nand_32 xoaddr:$ptr, i32:$incr))]>;
1366
1367     def ATOMIC_CMP_SWAP_I8 : Pseudo<
1368       (outs gprc:$dst), (ins memrr:$ptr, gprc:$old, gprc:$new), "#ATOMIC_CMP_SWAP_I8",
1369       [(set i32:$dst, (atomic_cmp_swap_8 xoaddr:$ptr, i32:$old, i32:$new))]>;
1370     def ATOMIC_CMP_SWAP_I16 : Pseudo<
1371       (outs gprc:$dst), (ins memrr:$ptr, gprc:$old, gprc:$new), "#ATOMIC_CMP_SWAP_I16 $dst $ptr $old $new",
1372       [(set i32:$dst, (atomic_cmp_swap_16 xoaddr:$ptr, i32:$old, i32:$new))]>;
1373     def ATOMIC_CMP_SWAP_I32 : Pseudo<
1374       (outs gprc:$dst), (ins memrr:$ptr, gprc:$old, gprc:$new), "#ATOMIC_CMP_SWAP_I32 $dst $ptr $old $new",
1375       [(set i32:$dst, (atomic_cmp_swap_32 xoaddr:$ptr, i32:$old, i32:$new))]>;
1376
1377     def ATOMIC_SWAP_I8 : Pseudo<
1378       (outs gprc:$dst), (ins memrr:$ptr, gprc:$new), "#ATOMIC_SWAP_i8",
1379       [(set i32:$dst, (atomic_swap_8 xoaddr:$ptr, i32:$new))]>;
1380     def ATOMIC_SWAP_I16 : Pseudo<
1381       (outs gprc:$dst), (ins memrr:$ptr, gprc:$new), "#ATOMIC_SWAP_I16",
1382       [(set i32:$dst, (atomic_swap_16 xoaddr:$ptr, i32:$new))]>;
1383     def ATOMIC_SWAP_I32 : Pseudo<
1384       (outs gprc:$dst), (ins memrr:$ptr, gprc:$new), "#ATOMIC_SWAP_I32",
1385       [(set i32:$dst, (atomic_swap_32 xoaddr:$ptr, i32:$new))]>;
1386   }
1387 }
1388
1389 // Instructions to support atomic operations
1390 def LWARX : XForm_1<31,  20, (outs gprc:$rD), (ins memrr:$src),
1391                    "lwarx $rD, $src", IIC_LdStLWARX,
1392                    [(set i32:$rD, (PPClarx xoaddr:$src))]>;
1393
1394 let Defs = [CR0] in
1395 def STWCX : XForm_1<31, 150, (outs), (ins gprc:$rS, memrr:$dst),
1396                    "stwcx. $rS, $dst", IIC_LdStSTWCX,
1397                    [(PPCstcx i32:$rS, xoaddr:$dst)]>,
1398                    isDOT;
1399
1400 let isTerminator = 1, isBarrier = 1, hasCtrlDep = 1 in
1401 def TRAP  : XForm_24<31, 4, (outs), (ins), "trap", IIC_LdStLoad, [(trap)]>;
1402
1403 def TWI : DForm_base<3, (outs), (ins u5imm:$to, gprc:$rA, s16imm:$imm),
1404                      "twi $to, $rA, $imm", IIC_IntTrapW, []>;
1405 def TW : XForm_1<31, 4, (outs), (ins u5imm:$to, gprc:$rA, gprc:$rB),
1406                  "tw $to, $rA, $rB", IIC_IntTrapW, []>;
1407 def TDI : DForm_base<2, (outs), (ins u5imm:$to, g8rc:$rA, s16imm:$imm),
1408                      "tdi $to, $rA, $imm", IIC_IntTrapD, []>;
1409 def TD : XForm_1<31, 68, (outs), (ins u5imm:$to, g8rc:$rA, g8rc:$rB),
1410                  "td $to, $rA, $rB", IIC_IntTrapD, []>;
1411
1412 //===----------------------------------------------------------------------===//
1413 // PPC32 Load Instructions.
1414 //
1415
1416 // Unindexed (r+i) Loads.
1417 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
1418 def LBZ : DForm_1<34, (outs gprc:$rD), (ins memri:$src),
1419                   "lbz $rD, $src", IIC_LdStLoad,
1420                   [(set i32:$rD, (zextloadi8 iaddr:$src))]>;
1421 def LHA : DForm_1<42, (outs gprc:$rD), (ins memri:$src),
1422                   "lha $rD, $src", IIC_LdStLHA,
1423                   [(set i32:$rD, (sextloadi16 iaddr:$src))]>,
1424                   PPC970_DGroup_Cracked;
1425 def LHZ : DForm_1<40, (outs gprc:$rD), (ins memri:$src),
1426                   "lhz $rD, $src", IIC_LdStLoad,
1427                   [(set i32:$rD, (zextloadi16 iaddr:$src))]>;
1428 def LWZ : DForm_1<32, (outs gprc:$rD), (ins memri:$src),
1429                   "lwz $rD, $src", IIC_LdStLoad,
1430                   [(set i32:$rD, (load iaddr:$src))]>;
1431
1432 def LFS : DForm_1<48, (outs f4rc:$rD), (ins memri:$src),
1433                   "lfs $rD, $src", IIC_LdStLFD,
1434                   [(set f32:$rD, (load iaddr:$src))]>;
1435 def LFD : DForm_1<50, (outs f8rc:$rD), (ins memri:$src),
1436                   "lfd $rD, $src", IIC_LdStLFD,
1437                   [(set f64:$rD, (load iaddr:$src))]>;
1438
1439
1440 // Unindexed (r+i) Loads with Update (preinc).
1441 let mayLoad = 1, neverHasSideEffects = 1 in {
1442 def LBZU : DForm_1<35, (outs gprc:$rD, ptr_rc_nor0:$ea_result), (ins memri:$addr),
1443                    "lbzu $rD, $addr", IIC_LdStLoadUpd,
1444                    []>, RegConstraint<"$addr.reg = $ea_result">,
1445                    NoEncode<"$ea_result">;
1446
1447 def LHAU : DForm_1<43, (outs gprc:$rD, ptr_rc_nor0:$ea_result), (ins memri:$addr),
1448                    "lhau $rD, $addr", IIC_LdStLHAU,
1449                    []>, RegConstraint<"$addr.reg = $ea_result">,
1450                    NoEncode<"$ea_result">;
1451
1452 def LHZU : DForm_1<41, (outs gprc:$rD, ptr_rc_nor0:$ea_result), (ins memri:$addr),
1453                    "lhzu $rD, $addr", IIC_LdStLoadUpd,
1454                    []>, RegConstraint<"$addr.reg = $ea_result">,
1455                    NoEncode<"$ea_result">;
1456
1457 def LWZU : DForm_1<33, (outs gprc:$rD, ptr_rc_nor0:$ea_result), (ins memri:$addr),
1458                    "lwzu $rD, $addr", IIC_LdStLoadUpd,
1459                    []>, RegConstraint<"$addr.reg = $ea_result">,
1460                    NoEncode<"$ea_result">;
1461
1462 def LFSU : DForm_1<49, (outs f4rc:$rD, ptr_rc_nor0:$ea_result), (ins memri:$addr),
1463                   "lfsu $rD, $addr", IIC_LdStLFDU,
1464                   []>, RegConstraint<"$addr.reg = $ea_result">,
1465                    NoEncode<"$ea_result">;
1466
1467 def LFDU : DForm_1<51, (outs f8rc:$rD, ptr_rc_nor0:$ea_result), (ins memri:$addr),
1468                   "lfdu $rD, $addr", IIC_LdStLFDU,
1469                   []>, RegConstraint<"$addr.reg = $ea_result">,
1470                    NoEncode<"$ea_result">;
1471
1472
1473 // Indexed (r+r) Loads with Update (preinc).
1474 def LBZUX : XForm_1<31, 119, (outs gprc:$rD, ptr_rc_nor0:$ea_result),
1475                    (ins memrr:$addr),
1476                    "lbzux $rD, $addr", IIC_LdStLoadUpdX,
1477                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
1478                    NoEncode<"$ea_result">;
1479
1480 def LHAUX : XForm_1<31, 375, (outs gprc:$rD, ptr_rc_nor0:$ea_result),
1481                    (ins memrr:$addr),
1482                    "lhaux $rD, $addr", IIC_LdStLHAUX,
1483                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
1484                    NoEncode<"$ea_result">;
1485
1486 def LHZUX : XForm_1<31, 311, (outs gprc:$rD, ptr_rc_nor0:$ea_result),
1487                    (ins memrr:$addr),
1488                    "lhzux $rD, $addr", IIC_LdStLoadUpdX,
1489                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
1490                    NoEncode<"$ea_result">;
1491
1492 def LWZUX : XForm_1<31, 55, (outs gprc:$rD, ptr_rc_nor0:$ea_result),
1493                    (ins memrr:$addr),
1494                    "lwzux $rD, $addr", IIC_LdStLoadUpdX,
1495                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
1496                    NoEncode<"$ea_result">;
1497
1498 def LFSUX : XForm_1<31, 567, (outs f4rc:$rD, ptr_rc_nor0:$ea_result),
1499                    (ins memrr:$addr),
1500                    "lfsux $rD, $addr", IIC_LdStLFDUX,
1501                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
1502                    NoEncode<"$ea_result">;
1503
1504 def LFDUX : XForm_1<31, 631, (outs f8rc:$rD, ptr_rc_nor0:$ea_result),
1505                    (ins memrr:$addr),
1506                    "lfdux $rD, $addr", IIC_LdStLFDUX,
1507                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
1508                    NoEncode<"$ea_result">;
1509 }
1510 }
1511
1512 // Indexed (r+r) Loads.
1513 //
1514 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
1515 def LBZX : XForm_1<31,  87, (outs gprc:$rD), (ins memrr:$src),
1516                    "lbzx $rD, $src", IIC_LdStLoad,
1517                    [(set i32:$rD, (zextloadi8 xaddr:$src))]>;
1518 def LHAX : XForm_1<31, 343, (outs gprc:$rD), (ins memrr:$src),
1519                    "lhax $rD, $src", IIC_LdStLHA,
1520                    [(set i32:$rD, (sextloadi16 xaddr:$src))]>,
1521                    PPC970_DGroup_Cracked;
1522 def LHZX : XForm_1<31, 279, (outs gprc:$rD), (ins memrr:$src),
1523                    "lhzx $rD, $src", IIC_LdStLoad,
1524                    [(set i32:$rD, (zextloadi16 xaddr:$src))]>;
1525 def LWZX : XForm_1<31,  23, (outs gprc:$rD), (ins memrr:$src),
1526                    "lwzx $rD, $src", IIC_LdStLoad,
1527                    [(set i32:$rD, (load xaddr:$src))]>;
1528
1529
1530 def LHBRX : XForm_1<31, 790, (outs gprc:$rD), (ins memrr:$src),
1531                    "lhbrx $rD, $src", IIC_LdStLoad,
1532                    [(set i32:$rD, (PPClbrx xoaddr:$src, i16))]>;
1533 def LWBRX : XForm_1<31,  534, (outs gprc:$rD), (ins memrr:$src),
1534                    "lwbrx $rD, $src", IIC_LdStLoad,
1535                    [(set i32:$rD, (PPClbrx xoaddr:$src, i32))]>;
1536
1537 def LFSX   : XForm_25<31, 535, (outs f4rc:$frD), (ins memrr:$src),
1538                       "lfsx $frD, $src", IIC_LdStLFD,
1539                       [(set f32:$frD, (load xaddr:$src))]>;
1540 def LFDX   : XForm_25<31, 599, (outs f8rc:$frD), (ins memrr:$src),
1541                       "lfdx $frD, $src", IIC_LdStLFD,
1542                       [(set f64:$frD, (load xaddr:$src))]>;
1543
1544 def LFIWAX : XForm_25<31, 855, (outs f8rc:$frD), (ins memrr:$src),
1545                       "lfiwax $frD, $src", IIC_LdStLFD,
1546                       [(set f64:$frD, (PPClfiwax xoaddr:$src))]>;
1547 def LFIWZX : XForm_25<31, 887, (outs f8rc:$frD), (ins memrr:$src),
1548                       "lfiwzx $frD, $src", IIC_LdStLFD,
1549                       [(set f64:$frD, (PPClfiwzx xoaddr:$src))]>;
1550 }
1551
1552 // Load Multiple
1553 def LMW : DForm_1<46, (outs gprc:$rD), (ins memri:$src),
1554                   "lmw $rD, $src", IIC_LdStLMW, []>;
1555
1556 //===----------------------------------------------------------------------===//
1557 // PPC32 Store Instructions.
1558 //
1559
1560 // Unindexed (r+i) Stores.
1561 let PPC970_Unit = 2 in {
1562 def STB  : DForm_1<38, (outs), (ins gprc:$rS, memri:$src),
1563                    "stb $rS, $src", IIC_LdStStore,
1564                    [(truncstorei8 i32:$rS, iaddr:$src)]>;
1565 def STH  : DForm_1<44, (outs), (ins gprc:$rS, memri:$src),
1566                    "sth $rS, $src", IIC_LdStStore,
1567                    [(truncstorei16 i32:$rS, iaddr:$src)]>;
1568 def STW  : DForm_1<36, (outs), (ins gprc:$rS, memri:$src),
1569                    "stw $rS, $src", IIC_LdStStore,
1570                    [(store i32:$rS, iaddr:$src)]>;
1571 def STFS : DForm_1<52, (outs), (ins f4rc:$rS, memri:$dst),
1572                    "stfs $rS, $dst", IIC_LdStSTFD,
1573                    [(store f32:$rS, iaddr:$dst)]>;
1574 def STFD : DForm_1<54, (outs), (ins f8rc:$rS, memri:$dst),
1575                    "stfd $rS, $dst", IIC_LdStSTFD,
1576                    [(store f64:$rS, iaddr:$dst)]>;
1577 }
1578
1579 // Unindexed (r+i) Stores with Update (preinc).
1580 let PPC970_Unit = 2, mayStore = 1 in {
1581 def STBU  : DForm_1<39, (outs ptr_rc_nor0:$ea_res), (ins gprc:$rS, memri:$dst),
1582                     "stbu $rS, $dst", IIC_LdStStoreUpd, []>,
1583                     RegConstraint<"$dst.reg = $ea_res">, NoEncode<"$ea_res">;
1584 def STHU  : DForm_1<45, (outs ptr_rc_nor0:$ea_res), (ins gprc:$rS, memri:$dst),
1585                     "sthu $rS, $dst", IIC_LdStStoreUpd, []>,
1586                     RegConstraint<"$dst.reg = $ea_res">, NoEncode<"$ea_res">;
1587 def STWU  : DForm_1<37, (outs ptr_rc_nor0:$ea_res), (ins gprc:$rS, memri:$dst),
1588                     "stwu $rS, $dst", IIC_LdStStoreUpd, []>,
1589                     RegConstraint<"$dst.reg = $ea_res">, NoEncode<"$ea_res">;
1590 def STFSU : DForm_1<53, (outs ptr_rc_nor0:$ea_res), (ins f4rc:$rS, memri:$dst),
1591                     "stfsu $rS, $dst", IIC_LdStSTFDU, []>,
1592                     RegConstraint<"$dst.reg = $ea_res">, NoEncode<"$ea_res">;
1593 def STFDU : DForm_1<55, (outs ptr_rc_nor0:$ea_res), (ins f8rc:$rS, memri:$dst),
1594                     "stfdu $rS, $dst", IIC_LdStSTFDU, []>,
1595                     RegConstraint<"$dst.reg = $ea_res">, NoEncode<"$ea_res">;
1596 }
1597
1598 // Patterns to match the pre-inc stores.  We can't put the patterns on
1599 // the instruction definitions directly as ISel wants the address base
1600 // and offset to be separate operands, not a single complex operand.
1601 def : Pat<(pre_truncsti8 i32:$rS, iPTR:$ptrreg, iaddroff:$ptroff),
1602           (STBU $rS, iaddroff:$ptroff, $ptrreg)>;
1603 def : Pat<(pre_truncsti16 i32:$rS, iPTR:$ptrreg, iaddroff:$ptroff),
1604           (STHU $rS, iaddroff:$ptroff, $ptrreg)>;
1605 def : Pat<(pre_store i32:$rS, iPTR:$ptrreg, iaddroff:$ptroff),
1606           (STWU $rS, iaddroff:$ptroff, $ptrreg)>;
1607 def : Pat<(pre_store f32:$rS, iPTR:$ptrreg, iaddroff:$ptroff),
1608           (STFSU $rS, iaddroff:$ptroff, $ptrreg)>;
1609 def : Pat<(pre_store f64:$rS, iPTR:$ptrreg, iaddroff:$ptroff),
1610           (STFDU $rS, iaddroff:$ptroff, $ptrreg)>;
1611
1612 // Indexed (r+r) Stores.
1613 let PPC970_Unit = 2 in {
1614 def STBX  : XForm_8<31, 215, (outs), (ins gprc:$rS, memrr:$dst),
1615                    "stbx $rS, $dst", IIC_LdStStore,
1616                    [(truncstorei8 i32:$rS, xaddr:$dst)]>,
1617                    PPC970_DGroup_Cracked;
1618 def STHX  : XForm_8<31, 407, (outs), (ins gprc:$rS, memrr:$dst),
1619                    "sthx $rS, $dst", IIC_LdStStore,
1620                    [(truncstorei16 i32:$rS, xaddr:$dst)]>,
1621                    PPC970_DGroup_Cracked;
1622 def STWX  : XForm_8<31, 151, (outs), (ins gprc:$rS, memrr:$dst),
1623                    "stwx $rS, $dst", IIC_LdStStore,
1624                    [(store i32:$rS, xaddr:$dst)]>,
1625                    PPC970_DGroup_Cracked;
1626
1627 def STHBRX: XForm_8<31, 918, (outs), (ins gprc:$rS, memrr:$dst),
1628                    "sthbrx $rS, $dst", IIC_LdStStore,
1629                    [(PPCstbrx i32:$rS, xoaddr:$dst, i16)]>,
1630                    PPC970_DGroup_Cracked;
1631 def STWBRX: XForm_8<31, 662, (outs), (ins gprc:$rS, memrr:$dst),
1632                    "stwbrx $rS, $dst", IIC_LdStStore,
1633                    [(PPCstbrx i32:$rS, xoaddr:$dst, i32)]>,
1634                    PPC970_DGroup_Cracked;
1635
1636 def STFIWX: XForm_28<31, 983, (outs), (ins f8rc:$frS, memrr:$dst),
1637                      "stfiwx $frS, $dst", IIC_LdStSTFD,
1638                      [(PPCstfiwx f64:$frS, xoaddr:$dst)]>;
1639
1640 def STFSX : XForm_28<31, 663, (outs), (ins f4rc:$frS, memrr:$dst),
1641                      "stfsx $frS, $dst", IIC_LdStSTFD,
1642                      [(store f32:$frS, xaddr:$dst)]>;
1643 def STFDX : XForm_28<31, 727, (outs), (ins f8rc:$frS, memrr:$dst),
1644                      "stfdx $frS, $dst", IIC_LdStSTFD,
1645                      [(store f64:$frS, xaddr:$dst)]>;
1646 }
1647
1648 // Indexed (r+r) Stores with Update (preinc).
1649 let PPC970_Unit = 2, mayStore = 1 in {
1650 def STBUX : XForm_8<31, 247, (outs ptr_rc_nor0:$ea_res), (ins gprc:$rS, memrr:$dst),
1651                     "stbux $rS, $dst", IIC_LdStStoreUpd, []>,
1652                     RegConstraint<"$dst.ptrreg = $ea_res">, NoEncode<"$ea_res">,
1653                     PPC970_DGroup_Cracked;
1654 def STHUX : XForm_8<31, 439, (outs ptr_rc_nor0:$ea_res), (ins gprc:$rS, memrr:$dst),
1655                     "sthux $rS, $dst", IIC_LdStStoreUpd, []>,
1656                     RegConstraint<"$dst.ptrreg = $ea_res">, NoEncode<"$ea_res">,
1657                     PPC970_DGroup_Cracked;
1658 def STWUX : XForm_8<31, 183, (outs ptr_rc_nor0:$ea_res), (ins gprc:$rS, memrr:$dst),
1659                     "stwux $rS, $dst", IIC_LdStStoreUpd, []>,
1660                     RegConstraint<"$dst.ptrreg = $ea_res">, NoEncode<"$ea_res">,
1661                     PPC970_DGroup_Cracked;
1662 def STFSUX: XForm_8<31, 695, (outs ptr_rc_nor0:$ea_res), (ins f4rc:$rS, memrr:$dst),
1663                     "stfsux $rS, $dst", IIC_LdStSTFDU, []>,
1664                     RegConstraint<"$dst.ptrreg = $ea_res">, NoEncode<"$ea_res">,
1665                     PPC970_DGroup_Cracked;
1666 def STFDUX: XForm_8<31, 759, (outs ptr_rc_nor0:$ea_res), (ins f8rc:$rS, memrr:$dst),
1667                     "stfdux $rS, $dst", IIC_LdStSTFDU, []>,
1668                     RegConstraint<"$dst.ptrreg = $ea_res">, NoEncode<"$ea_res">,
1669                     PPC970_DGroup_Cracked;
1670 }
1671
1672 // Patterns to match the pre-inc stores.  We can't put the patterns on
1673 // the instruction definitions directly as ISel wants the address base
1674 // and offset to be separate operands, not a single complex operand.
1675 def : Pat<(pre_truncsti8 i32:$rS, iPTR:$ptrreg, iPTR:$ptroff),
1676           (STBUX $rS, $ptrreg, $ptroff)>;
1677 def : Pat<(pre_truncsti16 i32:$rS, iPTR:$ptrreg, iPTR:$ptroff),
1678           (STHUX $rS, $ptrreg, $ptroff)>;
1679 def : Pat<(pre_store i32:$rS, iPTR:$ptrreg, iPTR:$ptroff),
1680           (STWUX $rS, $ptrreg, $ptroff)>;
1681 def : Pat<(pre_store f32:$rS, iPTR:$ptrreg, iPTR:$ptroff),
1682           (STFSUX $rS, $ptrreg, $ptroff)>;
1683 def : Pat<(pre_store f64:$rS, iPTR:$ptrreg, iPTR:$ptroff),
1684           (STFDUX $rS, $ptrreg, $ptroff)>;
1685
1686 // Store Multiple
1687 def STMW : DForm_1<47, (outs), (ins gprc:$rS, memri:$dst),
1688                    "stmw $rS, $dst", IIC_LdStLMW, []>;
1689
1690 def SYNC : XForm_24_sync<31, 598, (outs), (ins i32imm:$L),
1691                         "sync $L", IIC_LdStSync, []>, Requires<[IsNotBookE]>;
1692
1693 let isCodeGenOnly = 1 in {
1694   def MSYNC : XForm_24_sync<31, 598, (outs), (ins),
1695                            "msync", IIC_LdStSync, []>, Requires<[IsBookE]> {
1696     let L = 0;
1697   }
1698 }
1699
1700 def : Pat<(int_ppc_sync), (SYNC 0)>, Requires<[IsNotBookE]>;
1701 def : Pat<(int_ppc_sync), (MSYNC)>, Requires<[IsBookE]>;
1702
1703 //===----------------------------------------------------------------------===//
1704 // PPC32 Arithmetic Instructions.
1705 //
1706
1707 let PPC970_Unit = 1 in {  // FXU Operations.
1708 def ADDI   : DForm_2<14, (outs gprc:$rD), (ins gprc_nor0:$rA, s16imm:$imm),
1709                      "addi $rD, $rA, $imm", IIC_IntSimple,
1710                      [(set i32:$rD, (add i32:$rA, imm32SExt16:$imm))]>;
1711 let BaseName = "addic" in {
1712 let Defs = [CARRY] in
1713 def ADDIC  : DForm_2<12, (outs gprc:$rD), (ins gprc:$rA, s16imm:$imm),
1714                      "addic $rD, $rA, $imm", IIC_IntGeneral,
1715                      [(set i32:$rD, (addc i32:$rA, imm32SExt16:$imm))]>,
1716                      RecFormRel, PPC970_DGroup_Cracked;
1717 let Defs = [CARRY, CR0] in
1718 def ADDICo : DForm_2<13, (outs gprc:$rD), (ins gprc:$rA, s16imm:$imm),
1719                      "addic. $rD, $rA, $imm", IIC_IntGeneral,
1720                      []>, isDOT, RecFormRel;
1721 }
1722 def ADDIS  : DForm_2<15, (outs gprc:$rD), (ins gprc_nor0:$rA, s17imm:$imm),
1723                      "addis $rD, $rA, $imm", IIC_IntSimple,
1724                      [(set i32:$rD, (add i32:$rA, imm16ShiftedSExt:$imm))]>;
1725 let isCodeGenOnly = 1 in
1726 def LA     : DForm_2<14, (outs gprc:$rD), (ins gprc_nor0:$rA, s16imm:$sym),
1727                      "la $rD, $sym($rA)", IIC_IntGeneral,
1728                      [(set i32:$rD, (add i32:$rA,
1729                                           (PPClo tglobaladdr:$sym, 0)))]>;
1730 def MULLI  : DForm_2< 7, (outs gprc:$rD), (ins gprc:$rA, s16imm:$imm),
1731                      "mulli $rD, $rA, $imm", IIC_IntMulLI,
1732                      [(set i32:$rD, (mul i32:$rA, imm32SExt16:$imm))]>;
1733 let Defs = [CARRY] in
1734 def SUBFIC : DForm_2< 8, (outs gprc:$rD), (ins gprc:$rA, s16imm:$imm),
1735                      "subfic $rD, $rA, $imm", IIC_IntGeneral,
1736                      [(set i32:$rD, (subc imm32SExt16:$imm, i32:$rA))]>;
1737
1738 let isReMaterializable = 1, isAsCheapAsAMove = 1, isMoveImm = 1 in {
1739   def LI  : DForm_2_r0<14, (outs gprc:$rD), (ins s16imm:$imm),
1740                        "li $rD, $imm", IIC_IntSimple,
1741                        [(set i32:$rD, imm32SExt16:$imm)]>;
1742   def LIS : DForm_2_r0<15, (outs gprc:$rD), (ins s17imm:$imm),
1743                        "lis $rD, $imm", IIC_IntSimple,
1744                        [(set i32:$rD, imm16ShiftedSExt:$imm)]>;
1745 }
1746 }
1747
1748 let PPC970_Unit = 1 in {  // FXU Operations.
1749 let Defs = [CR0] in {
1750 def ANDIo : DForm_4<28, (outs gprc:$dst), (ins gprc:$src1, u16imm:$src2),
1751                     "andi. $dst, $src1, $src2", IIC_IntGeneral,
1752                     [(set i32:$dst, (and i32:$src1, immZExt16:$src2))]>,
1753                     isDOT;
1754 def ANDISo : DForm_4<29, (outs gprc:$dst), (ins gprc:$src1, u16imm:$src2),
1755                     "andis. $dst, $src1, $src2", IIC_IntGeneral,
1756                     [(set i32:$dst, (and i32:$src1, imm16ShiftedZExt:$src2))]>,
1757                     isDOT;
1758 }
1759 def ORI   : DForm_4<24, (outs gprc:$dst), (ins gprc:$src1, u16imm:$src2),
1760                     "ori $dst, $src1, $src2", IIC_IntSimple,
1761                     [(set i32:$dst, (or i32:$src1, immZExt16:$src2))]>;
1762 def ORIS  : DForm_4<25, (outs gprc:$dst), (ins gprc:$src1, u16imm:$src2),
1763                     "oris $dst, $src1, $src2", IIC_IntSimple,
1764                     [(set i32:$dst, (or i32:$src1, imm16ShiftedZExt:$src2))]>;
1765 def XORI  : DForm_4<26, (outs gprc:$dst), (ins gprc:$src1, u16imm:$src2),
1766                     "xori $dst, $src1, $src2", IIC_IntSimple,
1767                     [(set i32:$dst, (xor i32:$src1, immZExt16:$src2))]>;
1768 def XORIS : DForm_4<27, (outs gprc:$dst), (ins gprc:$src1, u16imm:$src2),
1769                     "xoris $dst, $src1, $src2", IIC_IntSimple,
1770                     [(set i32:$dst, (xor i32:$src1, imm16ShiftedZExt:$src2))]>;
1771
1772 def NOP   : DForm_4_zero<24, (outs), (ins), "nop", IIC_IntSimple,
1773                          []>;
1774 let isCodeGenOnly = 1 in {
1775 // The POWER6 and POWER7 have special group-terminating nops.
1776 def NOP_GT_PWR6 : DForm_4_fixedreg_zero<24, 1, (outs), (ins),
1777                                         "ori 1, 1, 0", IIC_IntSimple, []>;
1778 def NOP_GT_PWR7 : DForm_4_fixedreg_zero<24, 2, (outs), (ins),
1779                                         "ori 2, 2, 0", IIC_IntSimple, []>;
1780 }
1781
1782 let isCompare = 1, neverHasSideEffects = 1 in {
1783   def CMPWI : DForm_5_ext<11, (outs crrc:$crD), (ins gprc:$rA, s16imm:$imm),
1784                           "cmpwi $crD, $rA, $imm", IIC_IntCompare>;
1785   def CMPLWI : DForm_6_ext<10, (outs crrc:$dst), (ins gprc:$src1, u16imm:$src2),
1786                            "cmplwi $dst, $src1, $src2", IIC_IntCompare>;
1787 }
1788 }
1789
1790 let PPC970_Unit = 1, neverHasSideEffects = 1 in {  // FXU Operations.
1791 let isCommutable = 1 in {
1792 defm NAND : XForm_6r<31, 476, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1793                      "nand", "$rA, $rS, $rB", IIC_IntSimple,
1794                      [(set i32:$rA, (not (and i32:$rS, i32:$rB)))]>;
1795 defm AND  : XForm_6r<31,  28, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1796                      "and", "$rA, $rS, $rB", IIC_IntSimple,
1797                      [(set i32:$rA, (and i32:$rS, i32:$rB))]>;
1798 } // isCommutable
1799 defm ANDC : XForm_6r<31,  60, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1800                      "andc", "$rA, $rS, $rB", IIC_IntSimple,
1801                      [(set i32:$rA, (and i32:$rS, (not i32:$rB)))]>;
1802 let isCommutable = 1 in {
1803 defm OR   : XForm_6r<31, 444, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1804                      "or", "$rA, $rS, $rB", IIC_IntSimple,
1805                      [(set i32:$rA, (or i32:$rS, i32:$rB))]>;
1806 defm NOR  : XForm_6r<31, 124, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1807                      "nor", "$rA, $rS, $rB", IIC_IntSimple,
1808                      [(set i32:$rA, (not (or i32:$rS, i32:$rB)))]>;
1809 } // isCommutable
1810 defm ORC  : XForm_6r<31, 412, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1811                      "orc", "$rA, $rS, $rB", IIC_IntSimple,
1812                      [(set i32:$rA, (or i32:$rS, (not i32:$rB)))]>;
1813 let isCommutable = 1 in {
1814 defm EQV  : XForm_6r<31, 284, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1815                      "eqv", "$rA, $rS, $rB", IIC_IntSimple,
1816                      [(set i32:$rA, (not (xor i32:$rS, i32:$rB)))]>;
1817 defm XOR  : XForm_6r<31, 316, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1818                      "xor", "$rA, $rS, $rB", IIC_IntSimple,
1819                      [(set i32:$rA, (xor i32:$rS, i32:$rB))]>;
1820 } // isCommutable
1821 defm SLW  : XForm_6r<31,  24, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1822                      "slw", "$rA, $rS, $rB", IIC_IntGeneral,
1823                      [(set i32:$rA, (PPCshl i32:$rS, i32:$rB))]>;
1824 defm SRW  : XForm_6r<31, 536, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1825                      "srw", "$rA, $rS, $rB", IIC_IntGeneral,
1826                      [(set i32:$rA, (PPCsrl i32:$rS, i32:$rB))]>;
1827 defm SRAW : XForm_6rc<31, 792, (outs gprc:$rA), (ins gprc:$rS, gprc:$rB),
1828                       "sraw", "$rA, $rS, $rB", IIC_IntShift,
1829                       [(set i32:$rA, (PPCsra i32:$rS, i32:$rB))]>;
1830 }
1831
1832 let PPC970_Unit = 1 in {  // FXU Operations.
1833 let neverHasSideEffects = 1 in {
1834 defm SRAWI : XForm_10rc<31, 824, (outs gprc:$rA), (ins gprc:$rS, u5imm:$SH),
1835                         "srawi", "$rA, $rS, $SH", IIC_IntShift,
1836                         [(set i32:$rA, (sra i32:$rS, (i32 imm:$SH)))]>;
1837 defm CNTLZW : XForm_11r<31,  26, (outs gprc:$rA), (ins gprc:$rS),
1838                         "cntlzw", "$rA, $rS", IIC_IntGeneral,
1839                         [(set i32:$rA, (ctlz i32:$rS))]>;
1840 defm EXTSB  : XForm_11r<31, 954, (outs gprc:$rA), (ins gprc:$rS),
1841                         "extsb", "$rA, $rS", IIC_IntSimple,
1842                         [(set i32:$rA, (sext_inreg i32:$rS, i8))]>;
1843 defm EXTSH  : XForm_11r<31, 922, (outs gprc:$rA), (ins gprc:$rS),
1844                         "extsh", "$rA, $rS", IIC_IntSimple,
1845                         [(set i32:$rA, (sext_inreg i32:$rS, i16))]>;
1846 }
1847 let isCompare = 1, neverHasSideEffects = 1 in {
1848   def CMPW   : XForm_16_ext<31, 0, (outs crrc:$crD), (ins gprc:$rA, gprc:$rB),
1849                             "cmpw $crD, $rA, $rB", IIC_IntCompare>;
1850   def CMPLW  : XForm_16_ext<31, 32, (outs crrc:$crD), (ins gprc:$rA, gprc:$rB),
1851                             "cmplw $crD, $rA, $rB", IIC_IntCompare>;
1852 }
1853 }
1854 let PPC970_Unit = 3 in {  // FPU Operations.
1855 //def FCMPO  : XForm_17<63, 32, (outs CRRC:$crD), (ins FPRC:$fA, FPRC:$fB),
1856 //                      "fcmpo $crD, $fA, $fB", IIC_FPCompare>;
1857 let isCompare = 1, neverHasSideEffects = 1 in {
1858   def FCMPUS : XForm_17<63, 0, (outs crrc:$crD), (ins f4rc:$fA, f4rc:$fB),
1859                         "fcmpu $crD, $fA, $fB", IIC_FPCompare>;
1860   let Interpretation64Bit = 1, isCodeGenOnly = 1 in
1861   def FCMPUD : XForm_17<63, 0, (outs crrc:$crD), (ins f8rc:$fA, f8rc:$fB),
1862                         "fcmpu $crD, $fA, $fB", IIC_FPCompare>;
1863 }
1864
1865 let Uses = [RM] in {
1866   let neverHasSideEffects = 1 in {
1867   defm FCTIW  : XForm_26r<63, 14, (outs f8rc:$frD), (ins f8rc:$frB),
1868                           "fctiw", "$frD, $frB", IIC_FPGeneral,
1869                           []>;
1870   defm FCTIWZ : XForm_26r<63, 15, (outs f8rc:$frD), (ins f8rc:$frB),
1871                           "fctiwz", "$frD, $frB", IIC_FPGeneral,
1872                           [(set f64:$frD, (PPCfctiwz f64:$frB))]>;
1873
1874   defm FRSP   : XForm_26r<63, 12, (outs f4rc:$frD), (ins f8rc:$frB),
1875                           "frsp", "$frD, $frB", IIC_FPGeneral,
1876                           [(set f32:$frD, (fround f64:$frB))]>;
1877
1878   let Interpretation64Bit = 1, isCodeGenOnly = 1 in
1879   defm FRIND  : XForm_26r<63, 392, (outs f8rc:$frD), (ins f8rc:$frB),
1880                           "frin", "$frD, $frB", IIC_FPGeneral,
1881                           [(set f64:$frD, (frnd f64:$frB))]>;
1882   defm FRINS  : XForm_26r<63, 392, (outs f4rc:$frD), (ins f4rc:$frB),
1883                           "frin", "$frD, $frB", IIC_FPGeneral,
1884                           [(set f32:$frD, (frnd f32:$frB))]>;
1885   }
1886
1887   let neverHasSideEffects = 1 in {
1888   let Interpretation64Bit = 1, isCodeGenOnly = 1 in
1889   defm FRIPD  : XForm_26r<63, 456, (outs f8rc:$frD), (ins f8rc:$frB),
1890                           "frip", "$frD, $frB", IIC_FPGeneral,
1891                           [(set f64:$frD, (fceil f64:$frB))]>;
1892   defm FRIPS  : XForm_26r<63, 456, (outs f4rc:$frD), (ins f4rc:$frB),
1893                           "frip", "$frD, $frB", IIC_FPGeneral,
1894                           [(set f32:$frD, (fceil f32:$frB))]>;
1895   let Interpretation64Bit = 1, isCodeGenOnly = 1 in
1896   defm FRIZD  : XForm_26r<63, 424, (outs f8rc:$frD), (ins f8rc:$frB),
1897                           "friz", "$frD, $frB", IIC_FPGeneral,
1898                           [(set f64:$frD, (ftrunc f64:$frB))]>;
1899   defm FRIZS  : XForm_26r<63, 424, (outs f4rc:$frD), (ins f4rc:$frB),
1900                           "friz", "$frD, $frB", IIC_FPGeneral,
1901                           [(set f32:$frD, (ftrunc f32:$frB))]>;
1902   let Interpretation64Bit = 1, isCodeGenOnly = 1 in
1903   defm FRIMD  : XForm_26r<63, 488, (outs f8rc:$frD), (ins f8rc:$frB),
1904                           "frim", "$frD, $frB", IIC_FPGeneral,
1905                           [(set f64:$frD, (ffloor f64:$frB))]>;
1906   defm FRIMS  : XForm_26r<63, 488, (outs f4rc:$frD), (ins f4rc:$frB),
1907                           "frim", "$frD, $frB", IIC_FPGeneral,
1908                           [(set f32:$frD, (ffloor f32:$frB))]>;
1909
1910   defm FSQRT  : XForm_26r<63, 22, (outs f8rc:$frD), (ins f8rc:$frB),
1911                           "fsqrt", "$frD, $frB", IIC_FPSqrtD,
1912                           [(set f64:$frD, (fsqrt f64:$frB))]>;
1913   defm FSQRTS : XForm_26r<59, 22, (outs f4rc:$frD), (ins f4rc:$frB),
1914                           "fsqrts", "$frD, $frB", IIC_FPSqrtS,
1915                           [(set f32:$frD, (fsqrt f32:$frB))]>;
1916   }
1917   }
1918 }
1919
1920 /// Note that FMR is defined as pseudo-ops on the PPC970 because they are
1921 /// often coalesced away and we don't want the dispatch group builder to think
1922 /// that they will fill slots (which could cause the load of a LSU reject to
1923 /// sneak into a d-group with a store).
1924 let neverHasSideEffects = 1 in
1925 defm FMR   : XForm_26r<63, 72, (outs f4rc:$frD), (ins f4rc:$frB),
1926                        "fmr", "$frD, $frB", IIC_FPGeneral,
1927                        []>,  // (set f32:$frD, f32:$frB)
1928                        PPC970_Unit_Pseudo;
1929
1930 let PPC970_Unit = 3, neverHasSideEffects = 1 in {  // FPU Operations.
1931 // These are artificially split into two different forms, for 4/8 byte FP.
1932 defm FABSS  : XForm_26r<63, 264, (outs f4rc:$frD), (ins f4rc:$frB),
1933                         "fabs", "$frD, $frB", IIC_FPGeneral,
1934                         [(set f32:$frD, (fabs f32:$frB))]>;
1935 let Interpretation64Bit = 1, isCodeGenOnly = 1 in
1936 defm FABSD  : XForm_26r<63, 264, (outs f8rc:$frD), (ins f8rc:$frB),
1937                         "fabs", "$frD, $frB", IIC_FPGeneral,
1938                         [(set f64:$frD, (fabs f64:$frB))]>;
1939 defm FNABSS : XForm_26r<63, 136, (outs f4rc:$frD), (ins f4rc:$frB),
1940                         "fnabs", "$frD, $frB", IIC_FPGeneral,
1941                         [(set f32:$frD, (fneg (fabs f32:$frB)))]>;
1942 let Interpretation64Bit = 1, isCodeGenOnly = 1 in
1943 defm FNABSD : XForm_26r<63, 136, (outs f8rc:$frD), (ins f8rc:$frB),
1944                         "fnabs", "$frD, $frB", IIC_FPGeneral,
1945                         [(set f64:$frD, (fneg (fabs f64:$frB)))]>;
1946 defm FNEGS  : XForm_26r<63, 40, (outs f4rc:$frD), (ins f4rc:$frB),
1947                         "fneg", "$frD, $frB", IIC_FPGeneral,
1948                         [(set f32:$frD, (fneg f32:$frB))]>;
1949 let Interpretation64Bit = 1, isCodeGenOnly = 1 in
1950 defm FNEGD  : XForm_26r<63, 40, (outs f8rc:$frD), (ins f8rc:$frB),
1951                         "fneg", "$frD, $frB", IIC_FPGeneral,
1952                         [(set f64:$frD, (fneg f64:$frB))]>;
1953
1954 defm FCPSGNS : XForm_28r<63, 8, (outs f4rc:$frD), (ins f4rc:$frA, f4rc:$frB),
1955                         "fcpsgn", "$frD, $frA, $frB", IIC_FPGeneral,
1956                         [(set f32:$frD, (fcopysign f32:$frB, f32:$frA))]>;
1957 let Interpretation64Bit = 1, isCodeGenOnly = 1 in
1958 defm FCPSGND : XForm_28r<63, 8, (outs f8rc:$frD), (ins f8rc:$frA, f8rc:$frB),
1959                         "fcpsgn", "$frD, $frA, $frB", IIC_FPGeneral,
1960                         [(set f64:$frD, (fcopysign f64:$frB, f64:$frA))]>;
1961
1962 // Reciprocal estimates.
1963 defm FRE      : XForm_26r<63, 24, (outs f8rc:$frD), (ins f8rc:$frB),
1964                           "fre", "$frD, $frB", IIC_FPGeneral,
1965                           [(set f64:$frD, (PPCfre f64:$frB))]>;
1966 defm FRES     : XForm_26r<59, 24, (outs f4rc:$frD), (ins f4rc:$frB),
1967                           "fres", "$frD, $frB", IIC_FPGeneral,
1968                           [(set f32:$frD, (PPCfre f32:$frB))]>;
1969 defm FRSQRTE  : XForm_26r<63, 26, (outs f8rc:$frD), (ins f8rc:$frB),
1970                           "frsqrte", "$frD, $frB", IIC_FPGeneral,
1971                           [(set f64:$frD, (PPCfrsqrte f64:$frB))]>;
1972 defm FRSQRTES : XForm_26r<59, 26, (outs f4rc:$frD), (ins f4rc:$frB),
1973                           "frsqrtes", "$frD, $frB", IIC_FPGeneral,
1974                           [(set f32:$frD, (PPCfrsqrte f32:$frB))]>;
1975 }
1976
1977 // XL-Form instructions.  condition register logical ops.
1978 //
1979 let neverHasSideEffects = 1 in
1980 def MCRF   : XLForm_3<19, 0, (outs crrc:$BF), (ins crrc:$BFA),
1981                       "mcrf $BF, $BFA", IIC_BrMCR>,
1982              PPC970_DGroup_First, PPC970_Unit_CRU;
1983
1984 let isCommutable = 1 in {
1985 def CRAND  : XLForm_1<19, 257, (outs crbitrc:$CRD),
1986                                (ins crbitrc:$CRA, crbitrc:$CRB),
1987                       "crand $CRD, $CRA, $CRB", IIC_BrCR,
1988                       [(set i1:$CRD, (and i1:$CRA, i1:$CRB))]>;
1989
1990 def CRNAND : XLForm_1<19, 225, (outs crbitrc:$CRD),
1991                                (ins crbitrc:$CRA, crbitrc:$CRB),
1992                       "crnand $CRD, $CRA, $CRB", IIC_BrCR,
1993                       [(set i1:$CRD, (not (and i1:$CRA, i1:$CRB)))]>;
1994
1995 def CROR   : XLForm_1<19, 449, (outs crbitrc:$CRD),
1996                                (ins crbitrc:$CRA, crbitrc:$CRB),
1997                       "cror $CRD, $CRA, $CRB", IIC_BrCR,
1998                       [(set i1:$CRD, (or i1:$CRA, i1:$CRB))]>;
1999
2000 def CRXOR  : XLForm_1<19, 193, (outs crbitrc:$CRD),
2001                                (ins crbitrc:$CRA, crbitrc:$CRB),
2002                       "crxor $CRD, $CRA, $CRB", IIC_BrCR,
2003                       [(set i1:$CRD, (xor i1:$CRA, i1:$CRB))]>;
2004
2005 def CRNOR  : XLForm_1<19, 33, (outs crbitrc:$CRD),
2006                               (ins crbitrc:$CRA, crbitrc:$CRB),
2007                       "crnor $CRD, $CRA, $CRB", IIC_BrCR,
2008                       [(set i1:$CRD, (not (or i1:$CRA, i1:$CRB)))]>;
2009
2010 def CREQV  : XLForm_1<19, 289, (outs crbitrc:$CRD),
2011                                (ins crbitrc:$CRA, crbitrc:$CRB),
2012                       "creqv $CRD, $CRA, $CRB", IIC_BrCR,
2013                       [(set i1:$CRD, (not (xor i1:$CRA, i1:$CRB)))]>;
2014 } // isCommutable
2015
2016 def CRANDC : XLForm_1<19, 129, (outs crbitrc:$CRD),
2017                                (ins crbitrc:$CRA, crbitrc:$CRB),
2018                       "crandc $CRD, $CRA, $CRB", IIC_BrCR,
2019                       [(set i1:$CRD, (and i1:$CRA, (not i1:$CRB)))]>;
2020
2021 def CRORC  : XLForm_1<19, 417, (outs crbitrc:$CRD),
2022                                (ins crbitrc:$CRA, crbitrc:$CRB),
2023                       "crorc $CRD, $CRA, $CRB", IIC_BrCR,
2024                       [(set i1:$CRD, (or i1:$CRA, (not i1:$CRB)))]>;
2025
2026 let isCodeGenOnly = 1 in {
2027 def CRSET  : XLForm_1_ext<19, 289, (outs crbitrc:$dst), (ins),
2028               "creqv $dst, $dst, $dst", IIC_BrCR,
2029               [(set i1:$dst, 1)]>;
2030
2031 def CRUNSET: XLForm_1_ext<19, 193, (outs crbitrc:$dst), (ins),
2032               "crxor $dst, $dst, $dst", IIC_BrCR,
2033               [(set i1:$dst, 0)]>;
2034
2035 let Defs = [CR1EQ], CRD = 6 in {
2036 def CR6SET  : XLForm_1_ext<19, 289, (outs), (ins),
2037               "creqv 6, 6, 6", IIC_BrCR,
2038               [(PPCcr6set)]>;
2039
2040 def CR6UNSET: XLForm_1_ext<19, 193, (outs), (ins),
2041               "crxor 6, 6, 6", IIC_BrCR,
2042               [(PPCcr6unset)]>;
2043 }
2044 }
2045
2046 // XFX-Form instructions.  Instructions that deal with SPRs.
2047 //
2048
2049 def MFSPR : XFXForm_1<31, 339, (outs gprc:$RT), (ins i32imm:$SPR),
2050                       "mfspr $RT, $SPR", IIC_SprMFSPR>;
2051 def MTSPR : XFXForm_1<31, 467, (outs), (ins i32imm:$SPR, gprc:$RT),
2052                       "mtspr $SPR, $RT", IIC_SprMTSPR>;
2053
2054 def MFTB : XFXForm_1<31, 371, (outs gprc:$RT), (ins i32imm:$SPR),
2055                      "mftb $RT, $SPR", IIC_SprMFTB>, Deprecated<DeprecatedMFTB>;
2056
2057 let Uses = [CTR] in {
2058 def MFCTR : XFXForm_1_ext<31, 339, 9, (outs gprc:$rT), (ins),
2059                           "mfctr $rT", IIC_SprMFSPR>,
2060             PPC970_DGroup_First, PPC970_Unit_FXU;
2061 }
2062 let Defs = [CTR], Pattern = [(PPCmtctr i32:$rS)] in {
2063 def MTCTR : XFXForm_7_ext<31, 467, 9, (outs), (ins gprc:$rS),
2064                           "mtctr $rS", IIC_SprMTSPR>,
2065             PPC970_DGroup_First, PPC970_Unit_FXU;
2066 }
2067 let hasSideEffects = 1, isCodeGenOnly = 1, Defs = [CTR] in {
2068 let Pattern = [(int_ppc_mtctr i32:$rS)] in
2069 def MTCTRloop : XFXForm_7_ext<31, 467, 9, (outs), (ins gprc:$rS),
2070                               "mtctr $rS", IIC_SprMTSPR>,
2071                 PPC970_DGroup_First, PPC970_Unit_FXU;
2072 }
2073
2074 let Defs = [LR] in {
2075 def MTLR  : XFXForm_7_ext<31, 467, 8, (outs), (ins gprc:$rS),
2076                           "mtlr $rS", IIC_SprMTSPR>,
2077             PPC970_DGroup_First, PPC970_Unit_FXU;
2078 }
2079 let Uses = [LR] in {
2080 def MFLR  : XFXForm_1_ext<31, 339, 8, (outs gprc:$rT), (ins),
2081                           "mflr $rT", IIC_SprMFSPR>,
2082             PPC970_DGroup_First, PPC970_Unit_FXU;
2083 }
2084
2085 let isCodeGenOnly = 1 in {
2086   // Move to/from VRSAVE: despite being a SPR, the VRSAVE register is renamed
2087   // like a GPR on the PPC970.  As such, copies in and out have the same
2088   // performance characteristics as an OR instruction.
2089   def MTVRSAVE : XFXForm_7_ext<31, 467, 256, (outs), (ins gprc:$rS),
2090                                "mtspr 256, $rS", IIC_IntGeneral>,
2091                  PPC970_DGroup_Single, PPC970_Unit_FXU;
2092   def MFVRSAVE : XFXForm_1_ext<31, 339, 256, (outs gprc:$rT), (ins),
2093                                "mfspr $rT, 256", IIC_IntGeneral>,
2094                  PPC970_DGroup_First, PPC970_Unit_FXU;
2095
2096   def MTVRSAVEv : XFXForm_7_ext<31, 467, 256,
2097                                 (outs VRSAVERC:$reg), (ins gprc:$rS),
2098                                 "mtspr 256, $rS", IIC_IntGeneral>,
2099                   PPC970_DGroup_Single, PPC970_Unit_FXU;
2100   def MFVRSAVEv : XFXForm_1_ext<31, 339, 256, (outs gprc:$rT),
2101                                 (ins VRSAVERC:$reg),
2102                                 "mfspr $rT, 256", IIC_IntGeneral>,
2103                   PPC970_DGroup_First, PPC970_Unit_FXU;
2104 }
2105
2106 // SPILL_VRSAVE - Indicate that we're dumping the VRSAVE register,
2107 // so we'll need to scavenge a register for it.
2108 let mayStore = 1 in
2109 def SPILL_VRSAVE : Pseudo<(outs), (ins VRSAVERC:$vrsave, memri:$F),
2110                      "#SPILL_VRSAVE", []>;
2111
2112 // RESTORE_VRSAVE - Indicate that we're restoring the VRSAVE register (previously
2113 // spilled), so we'll need to scavenge a register for it.
2114 let mayLoad = 1 in
2115 def RESTORE_VRSAVE : Pseudo<(outs VRSAVERC:$vrsave), (ins memri:$F),
2116                      "#RESTORE_VRSAVE", []>;
2117
2118 let neverHasSideEffects = 1 in {
2119 def MTOCRF: XFXForm_5a<31, 144, (outs crbitm:$FXM), (ins gprc:$ST),
2120                        "mtocrf $FXM, $ST", IIC_BrMCRX>,
2121             PPC970_DGroup_First, PPC970_Unit_CRU;
2122
2123 def MTCRF : XFXForm_5<31, 144, (outs), (ins i32imm:$FXM, gprc:$rS),
2124                       "mtcrf $FXM, $rS", IIC_BrMCRX>,
2125             PPC970_MicroCode, PPC970_Unit_CRU;
2126
2127 let hasExtraSrcRegAllocReq = 1 in // to enable post-ra anti-dep breaking.
2128 def MFOCRF: XFXForm_5a<31, 19, (outs gprc:$rT), (ins crbitm:$FXM),
2129                        "mfocrf $rT, $FXM", IIC_SprMFCRF>,
2130             PPC970_DGroup_First, PPC970_Unit_CRU;
2131
2132 def MFCR : XFXForm_3<31, 19, (outs gprc:$rT), (ins),
2133                      "mfcr $rT", IIC_SprMFCR>,
2134                      PPC970_MicroCode, PPC970_Unit_CRU;
2135 } // neverHasSideEffects = 1
2136
2137 // Pseudo instruction to perform FADD in round-to-zero mode.
2138 let usesCustomInserter = 1, Uses = [RM] in {
2139   def FADDrtz: Pseudo<(outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRB), "",
2140                       [(set f64:$FRT, (PPCfaddrtz f64:$FRA, f64:$FRB))]>;
2141 }
2142
2143 // The above pseudo gets expanded to make use of the following instructions
2144 // to manipulate FPSCR.  Note that FPSCR is not modeled at the DAG level.
2145 let Uses = [RM], Defs = [RM] in {
2146   def MTFSB0 : XForm_43<63, 70, (outs), (ins u5imm:$FM),
2147                         "mtfsb0 $FM", IIC_IntMTFSB0, []>,
2148                PPC970_DGroup_Single, PPC970_Unit_FPU;
2149   def MTFSB1 : XForm_43<63, 38, (outs), (ins u5imm:$FM),
2150                         "mtfsb1 $FM", IIC_IntMTFSB0, []>,
2151                PPC970_DGroup_Single, PPC970_Unit_FPU;
2152   def MTFSF  : XFLForm<63, 711, (outs), (ins i32imm:$FM, f8rc:$rT),
2153                        "mtfsf $FM, $rT", IIC_IntMTFSB0, []>,
2154                PPC970_DGroup_Single, PPC970_Unit_FPU;
2155 }
2156 let Uses = [RM] in {
2157   def MFFS   : XForm_42<63, 583, (outs f8rc:$rT), (ins),
2158                          "mffs $rT", IIC_IntMFFS,
2159                          [(set f64:$rT, (PPCmffs))]>,
2160                PPC970_DGroup_Single, PPC970_Unit_FPU;
2161 }
2162
2163
2164 let PPC970_Unit = 1, neverHasSideEffects = 1 in {  // FXU Operations.
2165 // XO-Form instructions.  Arithmetic instructions that can set overflow bit
2166 let isCommutable = 1 in
2167 defm ADD4  : XOForm_1r<31, 266, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2168                        "add", "$rT, $rA, $rB", IIC_IntSimple,
2169                        [(set i32:$rT, (add i32:$rA, i32:$rB))]>;
2170 let isCodeGenOnly = 1 in
2171 def ADD4TLS  : XOForm_1<31, 266, 0, (outs gprc:$rT), (ins gprc:$rA, tlsreg32:$rB),
2172                        "add $rT, $rA, $rB", IIC_IntSimple,
2173                        [(set i32:$rT, (add i32:$rA, tglobaltlsaddr:$rB))]>;
2174 let isCommutable = 1 in
2175 defm ADDC  : XOForm_1rc<31, 10, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2176                         "addc", "$rT, $rA, $rB", IIC_IntGeneral,
2177                         [(set i32:$rT, (addc i32:$rA, i32:$rB))]>,
2178                         PPC970_DGroup_Cracked;
2179
2180 defm DIVW  : XOForm_1r<31, 491, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2181                        "divw", "$rT, $rA, $rB", IIC_IntDivW,
2182                        [(set i32:$rT, (sdiv i32:$rA, i32:$rB))]>,
2183                        PPC970_DGroup_First, PPC970_DGroup_Cracked;
2184 defm DIVWU : XOForm_1r<31, 459, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2185                        "divwu", "$rT, $rA, $rB", IIC_IntDivW,
2186                        [(set i32:$rT, (udiv i32:$rA, i32:$rB))]>,
2187                        PPC970_DGroup_First, PPC970_DGroup_Cracked;
2188 let isCommutable = 1 in {
2189 defm MULHW : XOForm_1r<31, 75, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2190                        "mulhw", "$rT, $rA, $rB", IIC_IntMulHW,
2191                        [(set i32:$rT, (mulhs i32:$rA, i32:$rB))]>;
2192 defm MULHWU : XOForm_1r<31, 11, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2193                        "mulhwu", "$rT, $rA, $rB", IIC_IntMulHWU,
2194                        [(set i32:$rT, (mulhu i32:$rA, i32:$rB))]>;
2195 defm MULLW : XOForm_1r<31, 235, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2196                        "mullw", "$rT, $rA, $rB", IIC_IntMulHW,
2197                        [(set i32:$rT, (mul i32:$rA, i32:$rB))]>;
2198 } // isCommutable
2199 defm SUBF  : XOForm_1r<31, 40, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2200                        "subf", "$rT, $rA, $rB", IIC_IntGeneral,
2201                        [(set i32:$rT, (sub i32:$rB, i32:$rA))]>;
2202 defm SUBFC : XOForm_1rc<31, 8, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2203                         "subfc", "$rT, $rA, $rB", IIC_IntGeneral,
2204                         [(set i32:$rT, (subc i32:$rB, i32:$rA))]>,
2205                         PPC970_DGroup_Cracked;
2206 defm NEG    : XOForm_3r<31, 104, 0, (outs gprc:$rT), (ins gprc:$rA),
2207                         "neg", "$rT, $rA", IIC_IntSimple,
2208                         [(set i32:$rT, (ineg i32:$rA))]>;
2209 let Uses = [CARRY] in {
2210 let isCommutable = 1 in
2211 defm ADDE  : XOForm_1rc<31, 138, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2212                         "adde", "$rT, $rA, $rB", IIC_IntGeneral,
2213                         [(set i32:$rT, (adde i32:$rA, i32:$rB))]>;
2214 defm ADDME  : XOForm_3rc<31, 234, 0, (outs gprc:$rT), (ins gprc:$rA),
2215                          "addme", "$rT, $rA", IIC_IntGeneral,
2216                          [(set i32:$rT, (adde i32:$rA, -1))]>;
2217 defm ADDZE  : XOForm_3rc<31, 202, 0, (outs gprc:$rT), (ins gprc:$rA),
2218                          "addze", "$rT, $rA", IIC_IntGeneral,
2219                          [(set i32:$rT, (adde i32:$rA, 0))]>;
2220 defm SUBFE : XOForm_1rc<31, 136, 0, (outs gprc:$rT), (ins gprc:$rA, gprc:$rB),
2221                         "subfe", "$rT, $rA, $rB", IIC_IntGeneral,
2222                         [(set i32:$rT, (sube i32:$rB, i32:$rA))]>;
2223 defm SUBFME : XOForm_3rc<31, 232, 0, (outs gprc:$rT), (ins gprc:$rA),
2224                          "subfme", "$rT, $rA", IIC_IntGeneral,
2225                          [(set i32:$rT, (sube -1, i32:$rA))]>;
2226 defm SUBFZE : XOForm_3rc<31, 200, 0, (outs gprc:$rT), (ins gprc:$rA),
2227                          "subfze", "$rT, $rA", IIC_IntGeneral,
2228                          [(set i32:$rT, (sube 0, i32:$rA))]>;
2229 }
2230 }
2231
2232 // A-Form instructions.  Most of the instructions executed in the FPU are of
2233 // this type.
2234 //
2235 let PPC970_Unit = 3, neverHasSideEffects = 1 in {  // FPU Operations.
2236 let Uses = [RM] in {
2237 let isCommutable = 1 in {
2238   defm FMADD : AForm_1r<63, 29,
2239                       (outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRC, f8rc:$FRB),
2240                       "fmadd", "$FRT, $FRA, $FRC, $FRB", IIC_FPFused,
2241                       [(set f64:$FRT, (fma f64:$FRA, f64:$FRC, f64:$FRB))]>;
2242   defm FMADDS : AForm_1r<59, 29,
2243                       (outs f4rc:$FRT), (ins f4rc:$FRA, f4rc:$FRC, f4rc:$FRB),
2244                       "fmadds", "$FRT, $FRA, $FRC, $FRB", IIC_FPGeneral,
2245                       [(set f32:$FRT, (fma f32:$FRA, f32:$FRC, f32:$FRB))]>;
2246   defm FMSUB : AForm_1r<63, 28,
2247                       (outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRC, f8rc:$FRB),
2248                       "fmsub", "$FRT, $FRA, $FRC, $FRB", IIC_FPFused,
2249                       [(set f64:$FRT,
2250                             (fma f64:$FRA, f64:$FRC, (fneg f64:$FRB)))]>;
2251   defm FMSUBS : AForm_1r<59, 28,
2252                       (outs f4rc:$FRT), (ins f4rc:$FRA, f4rc:$FRC, f4rc:$FRB),
2253                       "fmsubs", "$FRT, $FRA, $FRC, $FRB", IIC_FPGeneral,
2254                       [(set f32:$FRT,
2255                             (fma f32:$FRA, f32:$FRC, (fneg f32:$FRB)))]>;
2256   defm FNMADD : AForm_1r<63, 31,
2257                       (outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRC, f8rc:$FRB),
2258                       "fnmadd", "$FRT, $FRA, $FRC, $FRB", IIC_FPFused,
2259                       [(set f64:$FRT,
2260                             (fneg (fma f64:$FRA, f64:$FRC, f64:$FRB)))]>;
2261   defm FNMADDS : AForm_1r<59, 31,
2262                       (outs f4rc:$FRT), (ins f4rc:$FRA, f4rc:$FRC, f4rc:$FRB),
2263                       "fnmadds", "$FRT, $FRA, $FRC, $FRB", IIC_FPGeneral,
2264                       [(set f32:$FRT,
2265                             (fneg (fma f32:$FRA, f32:$FRC, f32:$FRB)))]>;
2266   defm FNMSUB : AForm_1r<63, 30,
2267                       (outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRC, f8rc:$FRB),
2268                       "fnmsub", "$FRT, $FRA, $FRC, $FRB", IIC_FPFused,
2269                       [(set f64:$FRT, (fneg (fma f64:$FRA, f64:$FRC,
2270                                                  (fneg f64:$FRB))))]>;
2271   defm FNMSUBS : AForm_1r<59, 30,
2272                       (outs f4rc:$FRT), (ins f4rc:$FRA, f4rc:$FRC, f4rc:$FRB),
2273                       "fnmsubs", "$FRT, $FRA, $FRC, $FRB", IIC_FPGeneral,
2274                       [(set f32:$FRT, (fneg (fma f32:$FRA, f32:$FRC,
2275                                                  (fneg f32:$FRB))))]>;
2276 } // isCommutable
2277 }
2278 // FSEL is artificially split into 4 and 8-byte forms for the result.  To avoid
2279 // having 4 of these, force the comparison to always be an 8-byte double (code
2280 // should use an FMRSD if the input comparison value really wants to be a float)
2281 // and 4/8 byte forms for the result and operand type..
2282 let Interpretation64Bit = 1, isCodeGenOnly = 1 in
2283 defm FSELD : AForm_1r<63, 23,
2284                       (outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRC, f8rc:$FRB),
2285                       "fsel", "$FRT, $FRA, $FRC, $FRB", IIC_FPGeneral,
2286                       [(set f64:$FRT, (PPCfsel f64:$FRA, f64:$FRC, f64:$FRB))]>;
2287 defm FSELS : AForm_1r<63, 23,
2288                       (outs f4rc:$FRT), (ins f8rc:$FRA, f4rc:$FRC, f4rc:$FRB),
2289                       "fsel", "$FRT, $FRA, $FRC, $FRB", IIC_FPGeneral,
2290                       [(set f32:$FRT, (PPCfsel f64:$FRA, f32:$FRC, f32:$FRB))]>;
2291 let Uses = [RM] in {
2292   let isCommutable = 1 in {
2293   defm FADD  : AForm_2r<63, 21,
2294                         (outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRB),
2295                         "fadd", "$FRT, $FRA, $FRB", IIC_FPAddSub,
2296                         [(set f64:$FRT, (fadd f64:$FRA, f64:$FRB))]>;
2297   defm FADDS : AForm_2r<59, 21,
2298                         (outs f4rc:$FRT), (ins f4rc:$FRA, f4rc:$FRB),
2299                         "fadds", "$FRT, $FRA, $FRB", IIC_FPGeneral,
2300                         [(set f32:$FRT, (fadd f32:$FRA, f32:$FRB))]>;
2301   } // isCommutable
2302   defm FDIV  : AForm_2r<63, 18,
2303                         (outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRB),
2304                         "fdiv", "$FRT, $FRA, $FRB", IIC_FPDivD,
2305                         [(set f64:$FRT, (fdiv f64:$FRA, f64:$FRB))]>;
2306   defm FDIVS : AForm_2r<59, 18,
2307                         (outs f4rc:$FRT), (ins f4rc:$FRA, f4rc:$FRB),
2308                         "fdivs", "$FRT, $FRA, $FRB", IIC_FPDivS,
2309                         [(set f32:$FRT, (fdiv f32:$FRA, f32:$FRB))]>;
2310   let isCommutable = 1 in {
2311   defm FMUL  : AForm_3r<63, 25,
2312                         (outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRC),
2313                         "fmul", "$FRT, $FRA, $FRC", IIC_FPFused,
2314                         [(set f64:$FRT, (fmul f64:$FRA, f64:$FRC))]>;
2315   defm FMULS : AForm_3r<59, 25,
2316                         (outs f4rc:$FRT), (ins f4rc:$FRA, f4rc:$FRC),
2317                         "fmuls", "$FRT, $FRA, $FRC", IIC_FPGeneral,
2318                         [(set f32:$FRT, (fmul f32:$FRA, f32:$FRC))]>;
2319   } // isCommutable
2320   defm FSUB  : AForm_2r<63, 20,
2321                         (outs f8rc:$FRT), (ins f8rc:$FRA, f8rc:$FRB),
2322                         "fsub", "$FRT, $FRA, $FRB", IIC_FPAddSub,
2323                         [(set f64:$FRT, (fsub f64:$FRA, f64:$FRB))]>;
2324   defm FSUBS : AForm_2r<59, 20,
2325                         (outs f4rc:$FRT), (ins f4rc:$FRA, f4rc:$FRB),
2326                         "fsubs", "$FRT, $FRA, $FRB", IIC_FPGeneral,
2327                         [(set f32:$FRT, (fsub f32:$FRA, f32:$FRB))]>;
2328   }
2329 }
2330
2331 let neverHasSideEffects = 1 in {
2332 let PPC970_Unit = 1 in {  // FXU Operations.
2333   let isSelect = 1 in
2334   def ISEL  : AForm_4<31, 15,
2335                      (outs gprc:$rT), (ins gprc_nor0:$rA, gprc:$rB, crbitrc:$cond),
2336                      "isel $rT, $rA, $rB, $cond", IIC_IntGeneral,
2337                      []>;
2338 }
2339
2340 let PPC970_Unit = 1 in {  // FXU Operations.
2341 // M-Form instructions.  rotate and mask instructions.
2342 //
2343 let isCommutable = 1 in {
2344 // RLWIMI can be commuted if the rotate amount is zero.
2345 defm RLWIMI : MForm_2r<20, (outs gprc:$rA),
2346                        (ins gprc:$rSi, gprc:$rS, u5imm:$SH, u5imm:$MB,
2347                        u5imm:$ME), "rlwimi", "$rA, $rS, $SH, $MB, $ME",
2348                        IIC_IntRotate, []>, PPC970_DGroup_Cracked,
2349                        RegConstraint<"$rSi = $rA">, NoEncode<"$rSi">;
2350 }
2351 let BaseName = "rlwinm" in {
2352 def RLWINM : MForm_2<21,
2353                      (outs gprc:$rA), (ins gprc:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
2354                      "rlwinm $rA, $rS, $SH, $MB, $ME", IIC_IntGeneral,
2355                      []>, RecFormRel;
2356 let Defs = [CR0] in
2357 def RLWINMo : MForm_2<21,
2358                       (outs gprc:$rA), (ins gprc:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
2359                       "rlwinm. $rA, $rS, $SH, $MB, $ME", IIC_IntGeneral,
2360                       []>, isDOT, RecFormRel, PPC970_DGroup_Cracked;
2361 }
2362 defm RLWNM  : MForm_2r<23, (outs gprc:$rA),
2363                        (ins gprc:$rS, gprc:$rB, u5imm:$MB, u5imm:$ME),
2364                        "rlwnm", "$rA, $rS, $rB, $MB, $ME", IIC_IntGeneral,
2365                        []>;
2366 }
2367 } // neverHasSideEffects = 1
2368
2369 //===----------------------------------------------------------------------===//
2370 // PowerPC Instruction Patterns
2371 //
2372
2373 // Arbitrary immediate support.  Implement in terms of LIS/ORI.
2374 def : Pat<(i32 imm:$imm),
2375           (ORI (LIS (HI16 imm:$imm)), (LO16 imm:$imm))>;
2376
2377 // Implement the 'not' operation with the NOR instruction.
2378 def i32not : OutPatFrag<(ops node:$in),
2379                         (NOR $in, $in)>;
2380 def        : Pat<(not i32:$in),
2381                  (i32not $in)>;
2382
2383 // ADD an arbitrary immediate.
2384 def : Pat<(add i32:$in, imm:$imm),
2385           (ADDIS (ADDI $in, (LO16 imm:$imm)), (HA16 imm:$imm))>;
2386 // OR an arbitrary immediate.
2387 def : Pat<(or i32:$in, imm:$imm),
2388           (ORIS (ORI $in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
2389 // XOR an arbitrary immediate.
2390 def : Pat<(xor i32:$in, imm:$imm),
2391           (XORIS (XORI $in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
2392 // SUBFIC
2393 def : Pat<(sub imm32SExt16:$imm, i32:$in),
2394           (SUBFIC $in, imm:$imm)>;
2395
2396 // SHL/SRL
2397 def : Pat<(shl i32:$in, (i32 imm:$imm)),
2398           (RLWINM $in, imm:$imm, 0, (SHL32 imm:$imm))>;
2399 def : Pat<(srl i32:$in, (i32 imm:$imm)),
2400           (RLWINM $in, (SRL32 imm:$imm), imm:$imm, 31)>;
2401
2402 // ROTL
2403 def : Pat<(rotl i32:$in, i32:$sh),
2404           (RLWNM $in, $sh, 0, 31)>;
2405 def : Pat<(rotl i32:$in, (i32 imm:$imm)),
2406           (RLWINM $in, imm:$imm, 0, 31)>;
2407
2408 // RLWNM
2409 def : Pat<(and (rotl i32:$in, i32:$sh), maskimm32:$imm),
2410           (RLWNM $in, $sh, (MB maskimm32:$imm), (ME maskimm32:$imm))>;
2411
2412 // Calls
2413 def : Pat<(PPCcall (i32 tglobaladdr:$dst)),
2414           (BL tglobaladdr:$dst)>;
2415 def : Pat<(PPCcall (i32 texternalsym:$dst)),
2416           (BL texternalsym:$dst)>;
2417
2418
2419 def : Pat<(PPCtc_return (i32 tglobaladdr:$dst),  imm:$imm),
2420           (TCRETURNdi tglobaladdr:$dst, imm:$imm)>;
2421
2422 def : Pat<(PPCtc_return (i32 texternalsym:$dst), imm:$imm),
2423           (TCRETURNdi texternalsym:$dst, imm:$imm)>;
2424
2425 def : Pat<(PPCtc_return CTRRC:$dst, imm:$imm),
2426           (TCRETURNri CTRRC:$dst, imm:$imm)>;
2427
2428
2429
2430 // Hi and Lo for Darwin Global Addresses.
2431 def : Pat<(PPChi tglobaladdr:$in, 0), (LIS tglobaladdr:$in)>;
2432 def : Pat<(PPClo tglobaladdr:$in, 0), (LI tglobaladdr:$in)>;
2433 def : Pat<(PPChi tconstpool:$in, 0), (LIS tconstpool:$in)>;
2434 def : Pat<(PPClo tconstpool:$in, 0), (LI tconstpool:$in)>;
2435 def : Pat<(PPChi tjumptable:$in, 0), (LIS tjumptable:$in)>;
2436 def : Pat<(PPClo tjumptable:$in, 0), (LI tjumptable:$in)>;
2437 def : Pat<(PPChi tblockaddress:$in, 0), (LIS tblockaddress:$in)>;
2438 def : Pat<(PPClo tblockaddress:$in, 0), (LI tblockaddress:$in)>;
2439 def : Pat<(PPChi tglobaltlsaddr:$g, i32:$in),
2440           (ADDIS $in, tglobaltlsaddr:$g)>;
2441 def : Pat<(PPClo tglobaltlsaddr:$g, i32:$in),
2442           (ADDI $in, tglobaltlsaddr:$g)>;
2443 def : Pat<(add i32:$in, (PPChi tglobaladdr:$g, 0)),
2444           (ADDIS $in, tglobaladdr:$g)>;
2445 def : Pat<(add i32:$in, (PPChi tconstpool:$g, 0)),
2446           (ADDIS $in, tconstpool:$g)>;
2447 def : Pat<(add i32:$in, (PPChi tjumptable:$g, 0)),
2448           (ADDIS $in, tjumptable:$g)>;
2449 def : Pat<(add i32:$in, (PPChi tblockaddress:$g, 0)),
2450           (ADDIS $in, tblockaddress:$g)>;
2451
2452 // Support for thread-local storage.
2453 def PPC32GOT: Pseudo<(outs gprc:$rD), (ins), "#PPC32GOT",
2454                 [(set i32:$rD, (PPCppc32GOT))]>;
2455
2456 // Get the _GLOBAL_OFFSET_TABLE_ in PIC mode.
2457 // This uses two output registers, the first as the real output, the second as a
2458 // temporary register, used internally in code generation.
2459 def PPC32PICGOT: Pseudo<(outs gprc:$rD, gprc:$rT), (ins), "#PPC32PICGOT",
2460                 []>, NoEncode<"$rT">;
2461
2462 def LDgotTprelL32: Pseudo<(outs gprc:$rD), (ins s16imm:$disp, gprc_nor0:$reg),
2463                            "#LDgotTprelL32",
2464                            [(set i32:$rD,
2465                              (PPCldGotTprelL tglobaltlsaddr:$disp, i32:$reg))]>;
2466 def : Pat<(PPCaddTls i32:$in, tglobaltlsaddr:$g),
2467           (ADD4TLS $in, tglobaltlsaddr:$g)>;
2468
2469 def ADDItlsgdL32 : Pseudo<(outs gprc:$rD), (ins gprc_nor0:$reg, s16imm:$disp),
2470                          "#ADDItlsgdL32",
2471                          [(set i32:$rD,
2472                            (PPCaddiTlsgdL i32:$reg, tglobaltlsaddr:$disp))]>;
2473 def GETtlsADDR32 : Pseudo<(outs gprc:$rD), (ins gprc:$reg, tlsgd32:$sym),
2474                           "#GETtlsADDR32",
2475                           [(set i32:$rD,
2476                             (PPCgetTlsAddr i32:$reg, tglobaltlsaddr:$sym))]>;
2477 def ADDItlsldL32 : Pseudo<(outs gprc:$rD), (ins gprc_nor0:$reg, s16imm:$disp),
2478                           "#ADDItlsldL32",
2479                           [(set i32:$rD,
2480                             (PPCaddiTlsldL i32:$reg, tglobaltlsaddr:$disp))]>;
2481 def GETtlsldADDR32 : Pseudo<(outs gprc:$rD), (ins gprc:$reg, tlsgd32:$sym),
2482                             "#GETtlsldADDR32",
2483                             [(set i32:$rD,
2484                               (PPCgetTlsldAddr i32:$reg, tglobaltlsaddr:$sym))]>;
2485 def ADDIdtprelL32 : Pseudo<(outs gprc:$rD), (ins gprc_nor0:$reg, s16imm:$disp),
2486                            "#ADDIdtprelL32",
2487                            [(set i32:$rD,
2488                              (PPCaddiDtprelL i32:$reg, tglobaltlsaddr:$disp))]>;
2489 def ADDISdtprelHA32 : Pseudo<(outs gprc:$rD), (ins gprc_nor0:$reg, s16imm:$disp),
2490                             "#ADDISdtprelHA32",
2491                             [(set i32:$rD,
2492                               (PPCaddisDtprelHA i32:$reg,
2493                                                 tglobaltlsaddr:$disp))]>;
2494
2495 // Support for Position-independent code
2496 def LWZtoc: Pseudo<(outs gprc:$rD), (ins tocentry32:$disp, gprc:$reg),
2497                   "#LWZtoc",
2498                   [(set i32:$rD,
2499                      (PPCtoc_entry tglobaladdr:$disp, i32:$reg))]>;
2500 // Get Global (GOT) Base Register offset, from the word immediately preceding
2501 // the function label.
2502 def GetGBRO:    Pseudo<(outs gprc:$rT), (ins gprc:$rI), "#GetGBRO", []>;
2503 // Update the Global(GOT) Base Register with the above offset.
2504 def UpdateGBR:  Pseudo<(outs gprc:$rT), (ins gprc:$rI), "#UpdateGBR", []>;
2505
2506
2507 // Standard shifts.  These are represented separately from the real shifts above
2508 // so that we can distinguish between shifts that allow 5-bit and 6-bit shift
2509 // amounts.
2510 def : Pat<(sra i32:$rS, i32:$rB),
2511           (SRAW $rS, $rB)>;
2512 def : Pat<(srl i32:$rS, i32:$rB),
2513           (SRW $rS, $rB)>;
2514 def : Pat<(shl i32:$rS, i32:$rB),
2515           (SLW $rS, $rB)>;
2516
2517 def : Pat<(zextloadi1 iaddr:$src),
2518           (LBZ iaddr:$src)>;
2519 def : Pat<(zextloadi1 xaddr:$src),
2520           (LBZX xaddr:$src)>;
2521 def : Pat<(extloadi1 iaddr:$src),
2522           (LBZ iaddr:$src)>;
2523 def : Pat<(extloadi1 xaddr:$src),
2524           (LBZX xaddr:$src)>;
2525 def : Pat<(extloadi8 iaddr:$src),
2526           (LBZ iaddr:$src)>;
2527 def : Pat<(extloadi8 xaddr:$src),
2528           (LBZX xaddr:$src)>;
2529 def : Pat<(extloadi16 iaddr:$src),
2530           (LHZ iaddr:$src)>;
2531 def : Pat<(extloadi16 xaddr:$src),
2532           (LHZX xaddr:$src)>;
2533 def : Pat<(f64 (extloadf32 iaddr:$src)),
2534           (COPY_TO_REGCLASS (LFS iaddr:$src), F8RC)>;
2535 def : Pat<(f64 (extloadf32 xaddr:$src)),
2536           (COPY_TO_REGCLASS (LFSX xaddr:$src), F8RC)>;
2537
2538 def : Pat<(f64 (fextend f32:$src)),
2539           (COPY_TO_REGCLASS $src, F8RC)>;
2540
2541 def : Pat<(atomic_fence (imm), (imm)), (SYNC 0)>, Requires<[IsNotBookE]>;
2542 def : Pat<(atomic_fence (imm), (imm)), (MSYNC)>, Requires<[IsBookE]>;
2543
2544 // Additional FNMSUB patterns: -a*c + b == -(a*c - b)
2545 def : Pat<(fma (fneg f64:$A), f64:$C, f64:$B),
2546           (FNMSUB $A, $C, $B)>;
2547 def : Pat<(fma f64:$A, (fneg f64:$C), f64:$B),
2548           (FNMSUB $A, $C, $B)>;
2549 def : Pat<(fma (fneg f32:$A), f32:$C, f32:$B),
2550           (FNMSUBS $A, $C, $B)>;
2551 def : Pat<(fma f32:$A, (fneg f32:$C), f32:$B),
2552           (FNMSUBS $A, $C, $B)>;
2553
2554 // FCOPYSIGN's operand types need not agree.
2555 def : Pat<(fcopysign f64:$frB, f32:$frA),
2556           (FCPSGND (COPY_TO_REGCLASS $frA, F8RC), $frB)>;
2557 def : Pat<(fcopysign f32:$frB, f64:$frA),
2558           (FCPSGNS (COPY_TO_REGCLASS $frA, F4RC), $frB)>;
2559
2560 include "PPCInstrAltivec.td"
2561 include "PPCInstrSPE.td"
2562 include "PPCInstr64Bit.td"
2563 include "PPCInstrVSX.td"
2564
2565 def crnot : OutPatFrag<(ops node:$in),
2566                        (CRNOR $in, $in)>;
2567 def       : Pat<(not i1:$in),
2568                 (crnot $in)>;
2569
2570 // Patterns for arithmetic i1 operations.
2571 def : Pat<(add i1:$a, i1:$b),
2572           (CRXOR $a, $b)>;
2573 def : Pat<(sub i1:$a, i1:$b),
2574           (CRXOR $a, $b)>;
2575 def : Pat<(mul i1:$a, i1:$b),
2576           (CRAND $a, $b)>;
2577
2578 // We're sometimes asked to materialize i1 -1, which is just 1 in this case
2579 // (-1 is used to mean all bits set).
2580 def : Pat<(i1 -1), (CRSET)>;
2581
2582 // i1 extensions, implemented in terms of isel.
2583 def : Pat<(i32 (zext i1:$in)),
2584           (SELECT_I4 $in, (LI 1), (LI 0))>;
2585 def : Pat<(i32 (sext i1:$in)),
2586           (SELECT_I4 $in, (LI -1), (LI 0))>;
2587
2588 def : Pat<(i64 (zext i1:$in)),
2589           (SELECT_I8 $in, (LI8 1), (LI8 0))>;
2590 def : Pat<(i64 (sext i1:$in)),
2591           (SELECT_I8 $in, (LI8 -1), (LI8 0))>;
2592
2593 // FIXME: We should choose either a zext or a sext based on other constants
2594 // already around.
2595 def : Pat<(i32 (anyext i1:$in)),
2596           (SELECT_I4 $in, (LI 1), (LI 0))>;
2597 def : Pat<(i64 (anyext i1:$in)),
2598           (SELECT_I8 $in, (LI8 1), (LI8 0))>;
2599
2600 // match setcc on i1 variables.
2601 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETLT)),
2602           (CRANDC $s2, $s1)>;
2603 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETULT)),
2604           (CRANDC $s2, $s1)>;
2605 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETLE)),
2606           (CRORC $s2, $s1)>;
2607 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETULE)),
2608           (CRORC $s2, $s1)>;
2609 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETEQ)),
2610           (CREQV $s1, $s2)>;
2611 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETGE)),
2612           (CRORC $s1, $s2)>;
2613 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETUGE)),
2614           (CRORC $s1, $s2)>;
2615 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETGT)),
2616           (CRANDC $s1, $s2)>;
2617 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETUGT)),
2618           (CRANDC $s1, $s2)>;
2619 def : Pat<(i1 (setcc i1:$s1, i1:$s2, SETNE)),
2620           (CRXOR $s1, $s2)>;
2621
2622 // match setcc on non-i1 (non-vector) variables. Note that SETUEQ, SETOGE,
2623 // SETOLE, SETONE, SETULT and SETUGT should be expanded by legalize for
2624 // floating-point types.
2625
2626 multiclass CRNotPat<dag pattern, dag result> {
2627   def : Pat<pattern, (crnot result)>;
2628   def : Pat<(not pattern), result>;
2629
2630   // We can also fold the crnot into an extension:
2631   def : Pat<(i32 (zext pattern)),
2632             (SELECT_I4 result, (LI 0), (LI 1))>;
2633   def : Pat<(i32 (sext pattern)),
2634             (SELECT_I4 result, (LI 0), (LI -1))>;
2635
2636   // We can also fold the crnot into an extension:
2637   def : Pat<(i64 (zext pattern)),
2638             (SELECT_I8 result, (LI8 0), (LI8 1))>;
2639   def : Pat<(i64 (sext pattern)),
2640             (SELECT_I8 result, (LI8 0), (LI8 -1))>;
2641
2642   // FIXME: We should choose either a zext or a sext based on other constants
2643   // already around.
2644   def : Pat<(i32 (anyext pattern)),
2645             (SELECT_I4 result, (LI 0), (LI 1))>;
2646
2647   def : Pat<(i64 (anyext pattern)),
2648             (SELECT_I8 result, (LI8 0), (LI8 1))>;
2649 }
2650
2651 // FIXME: Because of what seems like a bug in TableGen's type-inference code,
2652 // we need to write imm:$imm in the output patterns below, not just $imm, or
2653 // else the resulting matcher will not correctly add the immediate operand
2654 // (making it a register operand instead).
2655
2656 // extended SETCC.
2657 multiclass ExtSetCCPat<CondCode cc, PatFrag pfrag,
2658                        OutPatFrag rfrag, OutPatFrag rfrag8> {
2659   def : Pat<(i32 (zext (i1 (pfrag i32:$s1, cc)))),
2660             (rfrag $s1)>;
2661   def : Pat<(i64 (zext (i1 (pfrag i64:$s1, cc)))),
2662             (rfrag8 $s1)>;
2663   def : Pat<(i64 (zext (i1 (pfrag i32:$s1, cc)))),
2664             (INSERT_SUBREG (i64 (IMPLICIT_DEF)), (rfrag $s1), sub_32)>;
2665   def : Pat<(i32 (zext (i1 (pfrag i64:$s1, cc)))),
2666             (EXTRACT_SUBREG (rfrag8 $s1), sub_32)>;
2667
2668   def : Pat<(i32 (anyext (i1 (pfrag i32:$s1, cc)))),
2669             (rfrag $s1)>;
2670   def : Pat<(i64 (anyext (i1 (pfrag i64:$s1, cc)))),
2671             (rfrag8 $s1)>;
2672   def : Pat<(i64 (anyext (i1 (pfrag i32:$s1, cc)))),
2673             (INSERT_SUBREG (i64 (IMPLICIT_DEF)), (rfrag $s1), sub_32)>;
2674   def : Pat<(i32 (anyext (i1 (pfrag i64:$s1, cc)))),
2675             (EXTRACT_SUBREG (rfrag8 $s1), sub_32)>;
2676 }
2677
2678 // Note that we do all inversions below with i(32|64)not, instead of using
2679 // (xori x, 1) because on the A2 nor has single-cycle latency while xori
2680 // has 2-cycle latency.
2681
2682 defm : ExtSetCCPat<SETEQ,
2683                    PatFrag<(ops node:$in, node:$cc),
2684                            (setcc $in, 0, $cc)>,
2685                    OutPatFrag<(ops node:$in),
2686                               (RLWINM (CNTLZW $in), 27, 31, 31)>,
2687                    OutPatFrag<(ops node:$in),
2688                               (RLDICL (CNTLZD $in), 58, 63)> >;
2689
2690 defm : ExtSetCCPat<SETNE,
2691                    PatFrag<(ops node:$in, node:$cc),
2692                            (setcc $in, 0, $cc)>,
2693                    OutPatFrag<(ops node:$in),
2694                               (RLWINM (i32not (CNTLZW $in)), 27, 31, 31)>,
2695                    OutPatFrag<(ops node:$in),
2696                               (RLDICL (i64not (CNTLZD $in)), 58, 63)> >;
2697
2698 defm : ExtSetCCPat<SETLT,
2699                    PatFrag<(ops node:$in, node:$cc),
2700                            (setcc $in, 0, $cc)>,
2701                    OutPatFrag<(ops node:$in),
2702                               (RLWINM $in, 1, 31, 31)>,
2703                    OutPatFrag<(ops node:$in),
2704                               (RLDICL $in, 1, 63)> >;
2705
2706 defm : ExtSetCCPat<SETGE,
2707                    PatFrag<(ops node:$in, node:$cc),
2708                            (setcc $in, 0, $cc)>,
2709                    OutPatFrag<(ops node:$in),
2710                               (RLWINM (i32not $in), 1, 31, 31)>,
2711                    OutPatFrag<(ops node:$in),
2712                               (RLDICL (i64not $in), 1, 63)> >;
2713
2714 defm : ExtSetCCPat<SETGT,
2715                    PatFrag<(ops node:$in, node:$cc),
2716                            (setcc $in, 0, $cc)>,
2717                    OutPatFrag<(ops node:$in),
2718                               (RLWINM (ANDC (NEG $in), $in), 1, 31, 31)>,
2719                    OutPatFrag<(ops node:$in),
2720                               (RLDICL (ANDC8 (NEG8 $in), $in), 1, 63)> >;
2721
2722 defm : ExtSetCCPat<SETLE,
2723                    PatFrag<(ops node:$in, node:$cc),
2724                            (setcc $in, 0, $cc)>,
2725                    OutPatFrag<(ops node:$in),
2726                               (RLWINM (ORC $in, (NEG $in)), 1, 31, 31)>,
2727                    OutPatFrag<(ops node:$in),
2728                               (RLDICL (ORC8 $in, (NEG8 $in)), 1, 63)> >;
2729
2730 defm : ExtSetCCPat<SETLT,
2731                    PatFrag<(ops node:$in, node:$cc),
2732                            (setcc $in, -1, $cc)>,
2733                    OutPatFrag<(ops node:$in),
2734                               (RLWINM (AND $in, (ADDI $in, 1)), 1, 31, 31)>,
2735                    OutPatFrag<(ops node:$in),
2736                               (RLDICL (AND8 $in, (ADDI8 $in, 1)), 1, 63)> >;
2737
2738 defm : ExtSetCCPat<SETGE,
2739                    PatFrag<(ops node:$in, node:$cc),
2740                            (setcc $in, -1, $cc)>,
2741                    OutPatFrag<(ops node:$in),
2742                               (RLWINM (NAND $in, (ADDI $in, 1)), 1, 31, 31)>,
2743                    OutPatFrag<(ops node:$in),
2744                               (RLDICL (NAND8 $in, (ADDI8 $in, 1)), 1, 63)> >;
2745
2746 defm : ExtSetCCPat<SETGT,
2747                    PatFrag<(ops node:$in, node:$cc),
2748                            (setcc $in, -1, $cc)>,
2749                    OutPatFrag<(ops node:$in),
2750                               (RLWINM (i32not $in), 1, 31, 31)>,
2751                    OutPatFrag<(ops node:$in),
2752                               (RLDICL (i64not $in), 1, 63)> >;
2753
2754 defm : ExtSetCCPat<SETLE,
2755                    PatFrag<(ops node:$in, node:$cc),
2756                            (setcc $in, -1, $cc)>,
2757                    OutPatFrag<(ops node:$in),
2758                               (RLWINM $in, 1, 31, 31)>,
2759                    OutPatFrag<(ops node:$in),
2760                               (RLDICL $in, 1, 63)> >;
2761
2762 // SETCC for i32.
2763 def : Pat<(i1 (setcc i32:$s1, immZExt16:$imm, SETULT)),
2764           (EXTRACT_SUBREG (CMPLWI $s1, imm:$imm), sub_lt)>;
2765 def : Pat<(i1 (setcc i32:$s1, imm32SExt16:$imm, SETLT)),
2766           (EXTRACT_SUBREG (CMPWI $s1, imm:$imm), sub_lt)>;
2767 def : Pat<(i1 (setcc i32:$s1, immZExt16:$imm, SETUGT)),
2768           (EXTRACT_SUBREG (CMPLWI $s1, imm:$imm), sub_gt)>;
2769 def : Pat<(i1 (setcc i32:$s1, imm32SExt16:$imm, SETGT)),
2770           (EXTRACT_SUBREG (CMPWI $s1, imm:$imm), sub_gt)>;
2771 def : Pat<(i1 (setcc i32:$s1, imm32SExt16:$imm, SETEQ)),
2772           (EXTRACT_SUBREG (CMPWI $s1, imm:$imm), sub_eq)>;
2773 def : Pat<(i1 (setcc i32:$s1, immZExt16:$imm, SETEQ)),
2774           (EXTRACT_SUBREG (CMPLWI $s1, imm:$imm), sub_eq)>;
2775
2776 // For non-equality comparisons, the default code would materialize the
2777 // constant, then compare against it, like this:
2778 //   lis r2, 4660
2779 //   ori r2, r2, 22136
2780 //   cmpw cr0, r3, r2
2781 //   beq cr0,L6
2782 // Since we are just comparing for equality, we can emit this instead:
2783 //   xoris r0,r3,0x1234
2784 //   cmplwi cr0,r0,0x5678
2785 //   beq cr0,L6
2786
2787 def : Pat<(i1 (setcc i32:$s1, imm:$imm, SETEQ)),
2788           (EXTRACT_SUBREG (CMPLWI (XORIS $s1, (HI16 imm:$imm)),
2789                                   (LO16 imm:$imm)), sub_eq)>;
2790
2791 defm : CRNotPat<(i1 (setcc i32:$s1, immZExt16:$imm, SETUGE)),
2792                 (EXTRACT_SUBREG (CMPLWI $s1, imm:$imm), sub_lt)>;
2793 defm : CRNotPat<(i1 (setcc i32:$s1, imm32SExt16:$imm, SETGE)),
2794                 (EXTRACT_SUBREG (CMPWI $s1, imm:$imm), sub_lt)>;
2795 defm : CRNotPat<(i1 (setcc i32:$s1, immZExt16:$imm, SETULE)),
2796                 (EXTRACT_SUBREG (CMPLWI $s1, imm:$imm), sub_gt)>;
2797 defm : CRNotPat<(i1 (setcc i32:$s1, imm32SExt16:$imm, SETLE)),
2798                 (EXTRACT_SUBREG (CMPWI $s1, imm:$imm), sub_gt)>;
2799 defm : CRNotPat<(i1 (setcc i32:$s1, imm32SExt16:$imm, SETNE)),
2800                 (EXTRACT_SUBREG (CMPWI $s1, imm:$imm), sub_eq)>;
2801 defm : CRNotPat<(i1 (setcc i32:$s1, immZExt16:$imm, SETNE)),
2802                 (EXTRACT_SUBREG (CMPLWI $s1, imm:$imm), sub_eq)>;
2803
2804 defm : CRNotPat<(i1 (setcc i32:$s1, imm:$imm, SETNE)),
2805                 (EXTRACT_SUBREG (CMPLWI (XORIS $s1, (HI16 imm:$imm)),
2806                                         (LO16 imm:$imm)), sub_eq)>;
2807
2808 def : Pat<(i1 (setcc i32:$s1, i32:$s2, SETULT)),
2809           (EXTRACT_SUBREG (CMPLW $s1, $s2), sub_lt)>;
2810 def : Pat<(i1 (setcc i32:$s1, i32:$s2, SETLT)),
2811           (EXTRACT_SUBREG (CMPW $s1, $s2), sub_lt)>;
2812 def : Pat<(i1 (setcc i32:$s1, i32:$s2, SETUGT)),
2813           (EXTRACT_SUBREG (CMPLW $s1, $s2), sub_gt)>;
2814 def : Pat<(i1 (setcc i32:$s1, i32:$s2, SETGT)),
2815           (EXTRACT_SUBREG (CMPW $s1, $s2), sub_gt)>;
2816 def : Pat<(i1 (setcc i32:$s1, i32:$s2, SETEQ)),
2817           (EXTRACT_SUBREG (CMPW $s1, $s2), sub_eq)>;
2818
2819 defm : CRNotPat<(i1 (setcc i32:$s1, i32:$s2, SETUGE)),
2820                 (EXTRACT_SUBREG (CMPLW $s1, $s2), sub_lt)>;
2821 defm : CRNotPat<(i1 (setcc i32:$s1, i32:$s2, SETGE)),
2822                 (EXTRACT_SUBREG (CMPW $s1, $s2), sub_lt)>;
2823 defm : CRNotPat<(i1 (setcc i32:$s1, i32:$s2, SETULE)),
2824                 (EXTRACT_SUBREG (CMPLW $s1, $s2), sub_gt)>;
2825 defm : CRNotPat<(i1 (setcc i32:$s1, i32:$s2, SETLE)),
2826                 (EXTRACT_SUBREG (CMPW $s1, $s2), sub_gt)>;
2827 defm : CRNotPat<(i1 (setcc i32:$s1, i32:$s2, SETNE)),
2828                 (EXTRACT_SUBREG (CMPW $s1, $s2), sub_eq)>;
2829
2830 // SETCC for i64.
2831 def : Pat<(i1 (setcc i64:$s1, immZExt16:$imm, SETULT)),
2832           (EXTRACT_SUBREG (CMPLDI $s1, imm:$imm), sub_lt)>;
2833 def : Pat<(i1 (setcc i64:$s1, imm64SExt16:$imm, SETLT)),
2834           (EXTRACT_SUBREG (CMPDI $s1, imm:$imm), sub_lt)>;
2835 def : Pat<(i1 (setcc i64:$s1, immZExt16:$imm, SETUGT)),
2836           (EXTRACT_SUBREG (CMPLDI $s1, imm:$imm), sub_gt)>;
2837 def : Pat<(i1 (setcc i64:$s1, imm64SExt16:$imm, SETGT)),
2838           (EXTRACT_SUBREG (CMPDI $s1, imm:$imm), sub_gt)>;
2839 def : Pat<(i1 (setcc i64:$s1, imm64SExt16:$imm, SETEQ)),
2840           (EXTRACT_SUBREG (CMPDI $s1, imm:$imm), sub_eq)>;
2841 def : Pat<(i1 (setcc i64:$s1, immZExt16:$imm, SETEQ)),
2842           (EXTRACT_SUBREG (CMPLDI $s1, imm:$imm), sub_eq)>;
2843
2844 // For non-equality comparisons, the default code would materialize the
2845 // constant, then compare against it, like this:
2846 //   lis r2, 4660
2847 //   ori r2, r2, 22136
2848 //   cmpd cr0, r3, r2
2849 //   beq cr0,L6
2850 // Since we are just comparing for equality, we can emit this instead:
2851 //   xoris r0,r3,0x1234
2852 //   cmpldi cr0,r0,0x5678
2853 //   beq cr0,L6
2854
2855 def : Pat<(i1 (setcc i64:$s1, imm64ZExt32:$imm, SETEQ)),
2856           (EXTRACT_SUBREG (CMPLDI (XORIS8 $s1, (HI16 imm:$imm)),
2857                                   (LO16 imm:$imm)), sub_eq)>;
2858
2859 defm : CRNotPat<(i1 (setcc i64:$s1, immZExt16:$imm, SETUGE)),
2860                 (EXTRACT_SUBREG (CMPLDI $s1, imm:$imm), sub_lt)>;
2861 defm : CRNotPat<(i1 (setcc i64:$s1, imm64SExt16:$imm, SETGE)),
2862                 (EXTRACT_SUBREG (CMPDI $s1, imm:$imm), sub_lt)>;
2863 defm : CRNotPat<(i1 (setcc i64:$s1, immZExt16:$imm, SETULE)),
2864                 (EXTRACT_SUBREG (CMPLDI $s1, imm:$imm), sub_gt)>;
2865 defm : CRNotPat<(i1 (setcc i64:$s1, imm64SExt16:$imm, SETLE)),
2866                 (EXTRACT_SUBREG (CMPDI $s1, imm:$imm), sub_gt)>;
2867 defm : CRNotPat<(i1 (setcc i64:$s1, imm64SExt16:$imm, SETNE)),
2868                 (EXTRACT_SUBREG (CMPDI $s1, imm:$imm), sub_eq)>;
2869 defm : CRNotPat<(i1 (setcc i64:$s1, immZExt16:$imm, SETNE)),
2870                 (EXTRACT_SUBREG (CMPLDI $s1, imm:$imm), sub_eq)>;
2871
2872 defm : CRNotPat<(i1 (setcc i64:$s1, imm64ZExt32:$imm, SETNE)),
2873                 (EXTRACT_SUBREG (CMPLDI (XORIS8 $s1, (HI16 imm:$imm)),
2874                                         (LO16 imm:$imm)), sub_eq)>;
2875
2876 def : Pat<(i1 (setcc i64:$s1, i64:$s2, SETULT)),
2877           (EXTRACT_SUBREG (CMPLD $s1, $s2), sub_lt)>;
2878 def : Pat<(i1 (setcc i64:$s1, i64:$s2, SETLT)),
2879           (EXTRACT_SUBREG (CMPD $s1, $s2), sub_lt)>;
2880 def : Pat<(i1 (setcc i64:$s1, i64:$s2, SETUGT)),
2881           (EXTRACT_SUBREG (CMPLD $s1, $s2), sub_gt)>;
2882 def : Pat<(i1 (setcc i64:$s1, i64:$s2, SETGT)),
2883           (EXTRACT_SUBREG (CMPD $s1, $s2), sub_gt)>;
2884 def : Pat<(i1 (setcc i64:$s1, i64:$s2, SETEQ)),
2885           (EXTRACT_SUBREG (CMPD $s1, $s2), sub_eq)>;
2886
2887 defm : CRNotPat<(i1 (setcc i64:$s1, i64:$s2, SETUGE)),
2888                 (EXTRACT_SUBREG (CMPLD $s1, $s2), sub_lt)>;
2889 defm : CRNotPat<(i1 (setcc i64:$s1, i64:$s2, SETGE)),
2890                 (EXTRACT_SUBREG (CMPD $s1, $s2), sub_lt)>;
2891 defm : CRNotPat<(i1 (setcc i64:$s1, i64:$s2, SETULE)),
2892                 (EXTRACT_SUBREG (CMPLD $s1, $s2), sub_gt)>;
2893 defm : CRNotPat<(i1 (setcc i64:$s1, i64:$s2, SETLE)),
2894                 (EXTRACT_SUBREG (CMPD $s1, $s2), sub_gt)>;
2895 defm : CRNotPat<(i1 (setcc i64:$s1, i64:$s2, SETNE)),
2896                 (EXTRACT_SUBREG (CMPD $s1, $s2), sub_eq)>;
2897
2898 // SETCC for f32.
2899 def : Pat<(i1 (setcc f32:$s1, f32:$s2, SETOLT)),
2900           (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_lt)>;
2901 def : Pat<(i1 (setcc f32:$s1, f32:$s2, SETLT)),
2902           (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_lt)>;
2903 def : Pat<(i1 (setcc f32:$s1, f32:$s2, SETOGT)),
2904           (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_gt)>;
2905 def : Pat<(i1 (setcc f32:$s1, f32:$s2, SETGT)),
2906           (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_gt)>;
2907 def : Pat<(i1 (setcc f32:$s1, f32:$s2, SETOEQ)),
2908           (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_eq)>;
2909 def : Pat<(i1 (setcc f32:$s1, f32:$s2, SETEQ)),
2910           (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_eq)>;
2911 def : Pat<(i1 (setcc f32:$s1, f32:$s2, SETUO)),
2912           (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_un)>;
2913
2914 defm : CRNotPat<(i1 (setcc f32:$s1, f32:$s2, SETUGE)),
2915                 (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_lt)>;
2916 defm : CRNotPat<(i1 (setcc f32:$s1, f32:$s2, SETGE)),
2917                 (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_lt)>;
2918 defm : CRNotPat<(i1 (setcc f32:$s1, f32:$s2, SETULE)),
2919                 (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_gt)>;
2920 defm : CRNotPat<(i1 (setcc f32:$s1, f32:$s2, SETLE)),
2921                 (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_gt)>;
2922 defm : CRNotPat<(i1 (setcc f32:$s1, f32:$s2, SETUNE)),
2923                 (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_eq)>;
2924 defm : CRNotPat<(i1 (setcc f32:$s1, f32:$s2, SETNE)),
2925                 (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_eq)>;
2926 defm : CRNotPat<(i1 (setcc f32:$s1, f32:$s2, SETO)),
2927                 (EXTRACT_SUBREG (FCMPUS $s1, $s2), sub_un)>;
2928
2929 // SETCC for f64.
2930 def : Pat<(i1 (setcc f64:$s1, f64:$s2, SETOLT)),
2931           (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_lt)>;
2932 def : Pat<(i1 (setcc f64:$s1, f64:$s2, SETLT)),
2933           (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_lt)>;
2934 def : Pat<(i1 (setcc f64:$s1, f64:$s2, SETOGT)),
2935           (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_gt)>;
2936 def : Pat<(i1 (setcc f64:$s1, f64:$s2, SETGT)),
2937           (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_gt)>;
2938 def : Pat<(i1 (setcc f64:$s1, f64:$s2, SETOEQ)),
2939           (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_eq)>;
2940 def : Pat<(i1 (setcc f64:$s1, f64:$s2, SETEQ)),
2941           (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_eq)>;
2942 def : Pat<(i1 (setcc f64:$s1, f64:$s2, SETUO)),
2943           (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_un)>;
2944
2945 defm : CRNotPat<(i1 (setcc f64:$s1, f64:$s2, SETUGE)),
2946                 (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_lt)>;
2947 defm : CRNotPat<(i1 (setcc f64:$s1, f64:$s2, SETGE)),
2948                 (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_lt)>;
2949 defm : CRNotPat<(i1 (setcc f64:$s1, f64:$s2, SETULE)),
2950                 (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_gt)>;
2951 defm : CRNotPat<(i1 (setcc f64:$s1, f64:$s2, SETLE)),
2952                 (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_gt)>;
2953 defm : CRNotPat<(i1 (setcc f64:$s1, f64:$s2, SETUNE)),
2954                 (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_eq)>;
2955 defm : CRNotPat<(i1 (setcc f64:$s1, f64:$s2, SETNE)),
2956                 (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_eq)>;
2957 defm : CRNotPat<(i1 (setcc f64:$s1, f64:$s2, SETO)),
2958                 (EXTRACT_SUBREG (FCMPUD $s1, $s2), sub_un)>;
2959
2960 // match select on i1 variables:
2961 def : Pat<(i1 (select i1:$cond, i1:$tval, i1:$fval)),
2962           (CROR (CRAND        $cond , $tval),
2963                 (CRAND (crnot $cond), $fval))>;
2964
2965 // match selectcc on i1 variables:
2966 //   select (lhs == rhs), tval, fval is:
2967 //   ((lhs == rhs) & tval) | (!(lhs == rhs) & fval)
2968 def : Pat <(i1 (selectcc i1:$lhs, i1:$rhs, i1:$tval, i1:$fval, SETLT)),
2969            (CROR (CRAND (CRANDC $rhs, $lhs), $tval),
2970                  (CRAND (CRORC  $lhs, $rhs), $fval))>;
2971 def : Pat <(i1 (selectcc i1:$lhs, i1:$rhs, i1:$tval, i1:$fval, SETLE)),
2972            (CROR (CRAND (CRORC  $rhs, $lhs), $tval),
2973                  (CRAND (CRANDC $lhs, $rhs), $fval))>;
2974 def : Pat <(i1 (selectcc i1:$lhs, i1:$rhs, i1:$tval, i1:$fval, SETEQ)),
2975            (CROR (CRAND (CREQV $lhs, $rhs), $tval),
2976                  (CRAND (CRXOR $lhs, $rhs), $fval))>;
2977 def : Pat <(i1 (selectcc i1:$lhs, i1:$rhs, i1:$tval, i1:$fval, SETGE)),
2978            (CROR (CRAND (CRORC  $lhs, $rhs), $tval),
2979                  (CRAND (CRANDC $rhs, $lhs), $fval))>;
2980 def : Pat <(i1 (selectcc i1:$lhs, i1:$rhs, i1:$tval, i1:$fval, SETGT)),
2981            (CROR (CRAND (CRANDC $lhs, $rhs), $tval),
2982                  (CRAND (CRORC  $rhs, $lhs), $fval))>;
2983 def : Pat <(i1 (selectcc i1:$lhs, i1:$rhs, i1:$tval, i1:$fval, SETNE)),
2984            (CROR (CRAND (CREQV $lhs, $rhs), $fval),
2985                  (CRAND (CRXOR $lhs, $rhs), $tval))>;
2986
2987 // match selectcc on i1 variables with non-i1 output.
2988 def : Pat<(i32 (selectcc i1:$lhs, i1:$rhs, i32:$tval, i32:$fval, SETLT)),
2989           (SELECT_I4 (CRANDC $rhs, $lhs), $tval, $fval)>;
2990 def : Pat<(i32 (selectcc i1:$lhs, i1:$rhs, i32:$tval, i32:$fval, SETLE)),
2991           (SELECT_I4 (CRORC  $rhs, $lhs), $tval, $fval)>;
2992 def : Pat<(i32 (selectcc i1:$lhs, i1:$rhs, i32:$tval, i32:$fval, SETEQ)),
2993           (SELECT_I4 (CREQV $lhs, $rhs), $tval, $fval)>;
2994 def : Pat<(i32 (selectcc i1:$lhs, i1:$rhs, i32:$tval, i32:$fval, SETGE)),
2995           (SELECT_I4 (CRORC  $lhs, $rhs), $tval, $fval)>;
2996 def : Pat<(i32 (selectcc i1:$lhs, i1:$rhs, i32:$tval, i32:$fval, SETGT)),
2997           (SELECT_I4 (CRANDC $lhs, $rhs), $tval, $fval)>;
2998 def : Pat<(i32 (selectcc i1:$lhs, i1:$rhs, i32:$tval, i32:$fval, SETNE)),
2999           (SELECT_I4 (CRXOR $lhs, $rhs), $tval, $fval)>;
3000
3001 def : Pat<(i64 (selectcc i1:$lhs, i1:$rhs, i64:$tval, i64:$fval, SETLT)),
3002           (SELECT_I8 (CRANDC $rhs, $lhs), $tval, $fval)>;
3003 def : Pat<(i64 (selectcc i1:$lhs, i1:$rhs, i64:$tval, i64:$fval, SETLE)),
3004           (SELECT_I8 (CRORC  $rhs, $lhs), $tval, $fval)>;
3005 def : Pat<(i64 (selectcc i1:$lhs, i1:$rhs, i64:$tval, i64:$fval, SETEQ)),
3006           (SELECT_I8 (CREQV $lhs, $rhs), $tval, $fval)>;
3007 def : Pat<(i64 (selectcc i1:$lhs, i1:$rhs, i64:$tval, i64:$fval, SETGE)),
3008           (SELECT_I8 (CRORC  $lhs, $rhs), $tval, $fval)>;
3009 def : Pat<(i64 (selectcc i1:$lhs, i1:$rhs, i64:$tval, i64:$fval, SETGT)),
3010           (SELECT_I8 (CRANDC $lhs, $rhs), $tval, $fval)>;
3011 def : Pat<(i64 (selectcc i1:$lhs, i1:$rhs, i64:$tval, i64:$fval, SETNE)),
3012           (SELECT_I8 (CRXOR $lhs, $rhs), $tval, $fval)>;
3013
3014 def : Pat<(f32 (selectcc i1:$lhs, i1:$rhs, f32:$tval, f32:$fval, SETLT)),
3015           (SELECT_F4 (CRANDC $rhs, $lhs), $tval, $fval)>;
3016 def : Pat<(f32 (selectcc i1:$lhs, i1:$rhs, f32:$tval, f32:$fval, SETLE)),
3017           (SELECT_F4 (CRORC  $rhs, $lhs), $tval, $fval)>;
3018 def : Pat<(f32 (selectcc i1:$lhs, i1:$rhs, f32:$tval, f32:$fval, SETEQ)),
3019           (SELECT_F4 (CREQV $lhs, $rhs), $tval, $fval)>;
3020 def : Pat<(f32 (selectcc i1:$lhs, i1:$rhs, f32:$tval, f32:$fval, SETGE)),
3021           (SELECT_F4 (CRORC  $lhs, $rhs), $tval, $fval)>;
3022 def : Pat<(f32 (selectcc i1:$lhs, i1:$rhs, f32:$tval, f32:$fval, SETGT)),
3023           (SELECT_F4 (CRANDC $lhs, $rhs), $tval, $fval)>;
3024 def : Pat<(f32 (selectcc i1:$lhs, i1:$rhs, f32:$tval, f32:$fval, SETNE)),
3025           (SELECT_F4 (CRXOR $lhs, $rhs), $tval, $fval)>;
3026
3027 def : Pat<(f64 (selectcc i1:$lhs, i1:$rhs, f64:$tval, f64:$fval, SETLT)),
3028           (SELECT_F8 (CRANDC $rhs, $lhs), $tval, $fval)>;
3029 def : Pat<(f64 (selectcc i1:$lhs, i1:$rhs, f64:$tval, f64:$fval, SETLE)),
3030           (SELECT_F8 (CRORC  $rhs, $lhs), $tval, $fval)>;
3031 def : Pat<(f64 (selectcc i1:$lhs, i1:$rhs, f64:$tval, f64:$fval, SETEQ)),
3032           (SELECT_F8 (CREQV $lhs, $rhs), $tval, $fval)>;
3033 def : Pat<(f64 (selectcc i1:$lhs, i1:$rhs, f64:$tval, f64:$fval, SETGE)),
3034           (SELECT_F8 (CRORC  $lhs, $rhs), $tval, $fval)>;
3035 def : Pat<(f64 (selectcc i1:$lhs, i1:$rhs, f64:$tval, f64:$fval, SETGT)),
3036           (SELECT_F8 (CRANDC $lhs, $rhs), $tval, $fval)>;
3037 def : Pat<(f64 (selectcc i1:$lhs, i1:$rhs, f64:$tval, f64:$fval, SETNE)),
3038           (SELECT_F8 (CRXOR $lhs, $rhs), $tval, $fval)>;
3039
3040 def : Pat<(v4i32 (selectcc i1:$lhs, i1:$rhs, v4i32:$tval, v4i32:$fval, SETLT)),
3041           (SELECT_VRRC (CRANDC $rhs, $lhs), $tval, $fval)>;
3042 def : Pat<(v4i32 (selectcc i1:$lhs, i1:$rhs, v4i32:$tval, v4i32:$fval, SETLE)),
3043           (SELECT_VRRC (CRORC  $rhs, $lhs), $tval, $fval)>;
3044 def : Pat<(v4i32 (selectcc i1:$lhs, i1:$rhs, v4i32:$tval, v4i32:$fval, SETEQ)),
3045           (SELECT_VRRC (CREQV $lhs, $rhs), $tval, $fval)>;
3046 def : Pat<(v4i32 (selectcc i1:$lhs, i1:$rhs, v4i32:$tval, v4i32:$fval, SETGE)),
3047           (SELECT_VRRC (CRORC  $lhs, $rhs), $tval, $fval)>;
3048 def : Pat<(v4i32 (selectcc i1:$lhs, i1:$rhs, v4i32:$tval, v4i32:$fval, SETGT)),
3049           (SELECT_VRRC (CRANDC $lhs, $rhs), $tval, $fval)>;
3050 def : Pat<(v4i32 (selectcc i1:$lhs, i1:$rhs, v4i32:$tval, v4i32:$fval, SETNE)),
3051           (SELECT_VRRC (CRXOR $lhs, $rhs), $tval, $fval)>;
3052
3053 let usesCustomInserter = 1 in {
3054 def ANDIo_1_EQ_BIT : Pseudo<(outs crbitrc:$dst), (ins gprc:$in),
3055                              "#ANDIo_1_EQ_BIT",
3056                              [(set i1:$dst, (trunc (not i32:$in)))]>;
3057 def ANDIo_1_GT_BIT : Pseudo<(outs crbitrc:$dst), (ins gprc:$in),
3058                              "#ANDIo_1_GT_BIT",
3059                              [(set i1:$dst, (trunc i32:$in))]>;
3060
3061 def ANDIo_1_EQ_BIT8 : Pseudo<(outs crbitrc:$dst), (ins g8rc:$in),
3062                               "#ANDIo_1_EQ_BIT8",
3063                               [(set i1:$dst, (trunc (not i64:$in)))]>;
3064 def ANDIo_1_GT_BIT8 : Pseudo<(outs crbitrc:$dst), (ins g8rc:$in),
3065                               "#ANDIo_1_GT_BIT8",
3066                               [(set i1:$dst, (trunc i64:$in))]>;
3067 }
3068
3069 def : Pat<(i1 (not (trunc i32:$in))),
3070            (ANDIo_1_EQ_BIT $in)>;
3071 def : Pat<(i1 (not (trunc i64:$in))),
3072            (ANDIo_1_EQ_BIT8 $in)>;
3073
3074 //===----------------------------------------------------------------------===//
3075 // PowerPC Instructions used for assembler/disassembler only
3076 //
3077
3078 // FIXME: For B=0 or B > 8, the registers following RT are used.
3079 // WARNING: Do not add patterns for this instruction without fixing this.
3080 def LSWI  : XForm_base_r3xo<31, 597, (outs gprc:$RT), (ins gprc:$A, u5imm:$B),
3081                             "lswi $RT, $A, $B", IIC_LdStLoad, []>;
3082
3083 // FIXME: For B=0 or B > 8, the registers following RT are used.
3084 // WARNING: Do not add patterns for this instruction without fixing this.
3085 def STSWI : XForm_base_r3xo<31, 725, (outs), (ins gprc:$RT, gprc:$A, u5imm:$B),
3086                             "stswi $RT, $A, $B", IIC_LdStLoad, []>;
3087
3088 def ISYNC : XLForm_2_ext<19, 150, 0, 0, 0, (outs), (ins),
3089                          "isync", IIC_SprISYNC, []>;
3090
3091 def ICBI : XForm_1a<31, 982, (outs), (ins memrr:$src),
3092                     "icbi $src", IIC_LdStICBI, []>;
3093
3094 def EIEIO : XForm_24_eieio<31, 854, (outs), (ins),
3095                            "eieio", IIC_LdStLoad, []>;
3096
3097 def WAIT : XForm_24_sync<31, 62, (outs), (ins i32imm:$L),
3098                          "wait $L", IIC_LdStLoad, []>;
3099
3100 def MBAR : XForm_mbar<31, 854, (outs), (ins u5imm:$MO),
3101                          "mbar $MO", IIC_LdStLoad>, Requires<[IsBookE]>;
3102
3103 def MTSR: XForm_sr<31, 210, (outs), (ins gprc:$RS, u4imm:$SR),
3104             "mtsr $SR, $RS", IIC_SprMTSR>;
3105
3106 def MFSR: XForm_sr<31, 595, (outs gprc:$RS), (ins u4imm:$SR),
3107             "mfsr $RS, $SR", IIC_SprMFSR>;
3108
3109 def MTSRIN: XForm_srin<31, 242, (outs), (ins gprc:$RS, gprc:$RB),
3110             "mtsrin $RS, $RB", IIC_SprMTSR>;
3111
3112 def MFSRIN: XForm_srin<31, 659, (outs gprc:$RS), (ins gprc:$RB),
3113             "mfsrin $RS, $RB", IIC_SprMFSR>;
3114
3115 def MTMSR: XForm_mtmsr<31, 146, (outs), (ins gprc:$RS, i32imm:$L),
3116                     "mtmsr $RS, $L", IIC_SprMTMSR>;
3117
3118 def WRTEE: XForm_mtmsr<31, 131, (outs), (ins gprc:$RS),
3119                     "wrtee $RS", IIC_SprMTMSR>, Requires<[IsBookE]> {
3120   let L = 0;
3121 }
3122
3123 def WRTEEI: I<31, (outs), (ins i1imm:$E), "wrteei $E", IIC_SprMTMSR>,
3124               Requires<[IsBookE]> {
3125   bits<1> E;
3126
3127   let Inst{16} = E;
3128   let Inst{21-30} = 163;
3129 }
3130
3131 def DCI: I<31, (outs), (ins u4imm:$CT), "dci $CT", IIC_LdStLoad>,
3132               Requires<[IsPPC4xx]> {
3133   bits<4> CT;
3134
3135   let Inst{7-10} = CT;
3136   let Inst{21-30} = 454;
3137 }
3138
3139 def ICI: I<31, (outs), (ins u4imm:$CT), "ici $CT", IIC_LdStLoad>,
3140               Requires<[IsPPC4xx]> {
3141   bits<4> CT;
3142
3143   let Inst{7-10} = CT;
3144   let Inst{21-30} = 966;
3145 }
3146
3147 def MFMSR : XForm_rs<31, 83, (outs gprc:$RT), (ins),
3148                   "mfmsr $RT", IIC_SprMFMSR, []>;
3149
3150 def MTMSRD : XForm_mtmsr<31, 178, (outs), (ins gprc:$RS, i32imm:$L),
3151                     "mtmsrd $RS, $L", IIC_SprMTMSRD>;
3152
3153 def SLBIE : XForm_16b<31, 434, (outs), (ins gprc:$RB),
3154                         "slbie $RB", IIC_SprSLBIE, []>;
3155
3156 def SLBMTE : XForm_26<31, 402, (outs), (ins gprc:$RS, gprc:$RB),
3157                     "slbmte $RS, $RB", IIC_SprSLBMTE, []>;
3158
3159 def SLBMFEE : XForm_26<31, 915, (outs gprc:$RT), (ins gprc:$RB),
3160                        "slbmfee $RT, $RB", IIC_SprSLBMFEE, []>;
3161
3162 def SLBIA : XForm_0<31, 498, (outs), (ins), "slbia", IIC_SprSLBIA, []>;
3163
3164 def TLBIA : XForm_0<31, 370, (outs), (ins),
3165                         "tlbia", IIC_SprTLBIA, []>;
3166
3167 def TLBSYNC : XForm_0<31, 566, (outs), (ins),
3168                         "tlbsync", IIC_SprTLBSYNC, []>;
3169
3170 def TLBIEL : XForm_16b<31, 274, (outs), (ins gprc:$RB),
3171                           "tlbiel $RB", IIC_SprTLBIEL, []>;
3172
3173 def TLBLD : XForm_16b<31, 978, (outs), (ins gprc:$RB),
3174                           "tlbld $RB", IIC_LdStLoad, []>, Requires<[IsPPC6xx]>;
3175 def TLBLI : XForm_16b<31, 1010, (outs), (ins gprc:$RB),
3176                           "tlbli $RB", IIC_LdStLoad, []>, Requires<[IsPPC6xx]>;
3177
3178 def TLBIE : XForm_26<31, 306, (outs), (ins gprc:$RS, gprc:$RB),
3179                           "tlbie $RB,$RS", IIC_SprTLBIE, []>;
3180
3181 def TLBSX : XForm_tlb<914, (outs), (ins gprc:$A, gprc:$B), "tlbsx $A, $B",
3182                 IIC_LdStLoad>, Requires<[IsBookE]>;
3183
3184 def TLBIVAX : XForm_tlb<786, (outs), (ins gprc:$A, gprc:$B), "tlbivax $A, $B",
3185                 IIC_LdStLoad>, Requires<[IsBookE]>;
3186
3187 def TLBRE : XForm_24_eieio<31, 946, (outs), (ins),
3188                            "tlbre", IIC_LdStLoad, []>, Requires<[IsBookE]>;
3189
3190 def TLBWE : XForm_24_eieio<31, 978, (outs), (ins),
3191                            "tlbwe", IIC_LdStLoad, []>, Requires<[IsBookE]>;
3192
3193 def TLBRE2 : XForm_tlbws<31, 946, (outs gprc:$RS), (ins gprc:$A, i1imm:$WS),
3194                "tlbre $RS, $A, $WS", IIC_LdStLoad, []>, Requires<[IsPPC4xx]>;
3195
3196 def TLBWE2 : XForm_tlbws<31, 978, (outs), (ins gprc:$RS, gprc:$A, i1imm:$WS),
3197                "tlbwe $RS, $A, $WS", IIC_LdStLoad, []>, Requires<[IsPPC4xx]>;
3198
3199 def TLBSX2 : XForm_base_r3xo<31, 914, (outs), (ins gprc:$RST, gprc:$A, gprc:$B),
3200                              "tlbsx $RST, $A, $B", IIC_LdStLoad, []>,
3201                              Requires<[IsPPC4xx]>;
3202 def TLBSX2D : XForm_base_r3xo<31, 914, (outs),
3203                               (ins gprc:$RST, gprc:$A, gprc:$B),
3204                               "tlbsx. $RST, $A, $B", IIC_LdStLoad, []>,
3205                               Requires<[IsPPC4xx]>, isDOT;
3206
3207 def RFID : XForm_0<19, 18, (outs), (ins), "rfid", IIC_IntRFID, []>;
3208
3209 def RFI : XForm_0<19, 50, (outs), (ins), "rfi", IIC_SprRFI, []>,
3210                   Requires<[IsBookE]>;
3211 def RFCI : XForm_0<19, 51, (outs), (ins), "rfci", IIC_BrB, []>,
3212                    Requires<[IsBookE]>;
3213
3214 def RFDI : XForm_0<19, 39, (outs), (ins), "rfdi", IIC_BrB, []>,
3215                    Requires<[IsE500]>;
3216 def RFMCI : XForm_0<19, 38, (outs), (ins), "rfmci", IIC_BrB, []>,
3217                     Requires<[IsE500]>;
3218
3219 def MFDCR : XFXForm_1<31, 323, (outs gprc:$RT), (ins i32imm:$SPR),
3220                       "mfdcr $RT, $SPR", IIC_SprMFSPR>, Requires<[IsPPC4xx]>;
3221 def MTDCR : XFXForm_1<31, 451, (outs), (ins gprc:$RT, i32imm:$SPR),
3222                       "mtdcr $SPR, $RT", IIC_SprMTSPR>, Requires<[IsPPC4xx]>;
3223
3224 //===----------------------------------------------------------------------===//
3225 // PowerPC Assembler Instruction Aliases
3226 //
3227
3228 // Pseudo-instructions for alternate assembly syntax (never used by codegen).
3229 // These are aliases that require C++ handling to convert to the target
3230 // instruction, while InstAliases can be handled directly by tblgen.
3231 class PPCAsmPseudo<string asm, dag iops>
3232   : Instruction {
3233   let Namespace = "PPC";
3234   bit PPC64 = 0;  // Default value, override with isPPC64
3235
3236   let OutOperandList = (outs);
3237   let InOperandList = iops;
3238   let Pattern = [];
3239   let AsmString = asm;
3240   let isAsmParserOnly = 1;
3241   let isPseudo = 1;
3242 }
3243
3244 def : InstAlias<"sc", (SC 0)>;
3245
3246 def : InstAlias<"sync", (SYNC 0)>, Requires<[IsNotBookE]>;
3247 def : InstAlias<"msync", (SYNC 0)>, Requires<[IsNotBookE]>;
3248 def : InstAlias<"lwsync", (SYNC 1)>, Requires<[IsNotBookE]>;
3249 def : InstAlias<"ptesync", (SYNC 2)>, Requires<[IsNotBookE]>;
3250
3251 def : InstAlias<"wait", (WAIT 0)>;
3252 def : InstAlias<"waitrsv", (WAIT 1)>;
3253 def : InstAlias<"waitimpl", (WAIT 2)>;
3254
3255 def : InstAlias<"mbar", (MBAR 0)>, Requires<[IsBookE]>;
3256
3257 def : InstAlias<"crset $bx", (CREQV crbitrc:$bx, crbitrc:$bx, crbitrc:$bx)>;
3258 def : InstAlias<"crclr $bx", (CRXOR crbitrc:$bx, crbitrc:$bx, crbitrc:$bx)>;
3259 def : InstAlias<"crmove $bx, $by", (CROR crbitrc:$bx, crbitrc:$by, crbitrc:$by)>;
3260 def : InstAlias<"crnot $bx, $by", (CRNOR crbitrc:$bx, crbitrc:$by, crbitrc:$by)>;
3261
3262 def : InstAlias<"mtxer $Rx", (MTSPR 1, gprc:$Rx)>;
3263 def : InstAlias<"mfxer $Rx", (MFSPR gprc:$Rx, 1)>;
3264
3265 def : InstAlias<"mfrtcu $Rx", (MFSPR gprc:$Rx, 4)>;
3266 def : InstAlias<"mfrtcl $Rx", (MFSPR gprc:$Rx, 5)>;
3267
3268 def : InstAlias<"mtdscr $Rx", (MTSPR 17, gprc:$Rx)>;
3269 def : InstAlias<"mfdscr $Rx", (MFSPR gprc:$Rx, 17)>;
3270
3271 def : InstAlias<"mtdsisr $Rx", (MTSPR 18, gprc:$Rx)>;
3272 def : InstAlias<"mfdsisr $Rx", (MFSPR gprc:$Rx, 18)>;
3273
3274 def : InstAlias<"mtdar $Rx", (MTSPR 19, gprc:$Rx)>;
3275 def : InstAlias<"mfdar $Rx", (MFSPR gprc:$Rx, 19)>;
3276
3277 def : InstAlias<"mtdec $Rx", (MTSPR 22, gprc:$Rx)>;
3278 def : InstAlias<"mfdec $Rx", (MFSPR gprc:$Rx, 22)>;
3279
3280 def : InstAlias<"mtsdr1 $Rx", (MTSPR 25, gprc:$Rx)>;
3281 def : InstAlias<"mfsdr1 $Rx", (MFSPR gprc:$Rx, 25)>;
3282
3283 def : InstAlias<"mtsrr0 $Rx", (MTSPR 26, gprc:$Rx)>;
3284 def : InstAlias<"mfsrr0 $Rx", (MFSPR gprc:$Rx, 26)>;
3285
3286 def : InstAlias<"mtsrr1 $Rx", (MTSPR 27, gprc:$Rx)>;
3287 def : InstAlias<"mfsrr1 $Rx", (MFSPR gprc:$Rx, 27)>;
3288
3289 def : InstAlias<"mtsrr2 $Rx", (MTSPR 990, gprc:$Rx)>, Requires<[IsPPC4xx]>;
3290 def : InstAlias<"mfsrr2 $Rx", (MFSPR gprc:$Rx, 990)>, Requires<[IsPPC4xx]>;
3291
3292 def : InstAlias<"mtsrr3 $Rx", (MTSPR 991, gprc:$Rx)>, Requires<[IsPPC4xx]>;
3293 def : InstAlias<"mfsrr3 $Rx", (MFSPR gprc:$Rx, 991)>, Requires<[IsPPC4xx]>;
3294
3295 def : InstAlias<"mtcfar $Rx", (MTSPR 28, gprc:$Rx)>;
3296 def : InstAlias<"mfcfar $Rx", (MFSPR gprc:$Rx, 28)>;
3297
3298 def : InstAlias<"mtamr $Rx", (MTSPR 29, gprc:$Rx)>;
3299 def : InstAlias<"mfamr $Rx", (MFSPR gprc:$Rx, 29)>;
3300
3301 def : InstAlias<"mtpid $Rx", (MTSPR 48, gprc:$Rx)>, Requires<[IsBookE]>;
3302 def : InstAlias<"mfpid $Rx", (MFSPR gprc:$Rx, 48)>, Requires<[IsBookE]>;
3303
3304 def : InstAlias<"mftb $Rx", (MFTB gprc:$Rx, 268)>;
3305 def : InstAlias<"mftbl $Rx", (MFTB gprc:$Rx, 268)>;
3306 def : InstAlias<"mftbu $Rx", (MFTB gprc:$Rx, 269)>;
3307
3308 def : InstAlias<"mttbl $Rx", (MTSPR 284, gprc:$Rx)>;
3309 def : InstAlias<"mttbu $Rx", (MTSPR 285, gprc:$Rx)>;
3310
3311 def : InstAlias<"mftblo $Rx", (MFSPR gprc:$Rx, 989)>, Requires<[IsPPC4xx]>;
3312 def : InstAlias<"mttblo $Rx", (MTSPR 989, gprc:$Rx)>, Requires<[IsPPC4xx]>;
3313 def : InstAlias<"mftbhi $Rx", (MFSPR gprc:$Rx, 988)>, Requires<[IsPPC4xx]>;
3314 def : InstAlias<"mttbhi $Rx", (MTSPR 988, gprc:$Rx)>, Requires<[IsPPC4xx]>;
3315
3316 def : InstAlias<"xnop", (XORI R0, R0, 0)>;
3317
3318 def : InstAlias<"mr $rA, $rB", (OR8 g8rc:$rA, g8rc:$rB, g8rc:$rB)>;
3319 def : InstAlias<"mr. $rA, $rB", (OR8o g8rc:$rA, g8rc:$rB, g8rc:$rB)>;
3320
3321 def : InstAlias<"not $rA, $rB", (NOR8 g8rc:$rA, g8rc:$rB, g8rc:$rB)>;
3322 def : InstAlias<"not. $rA, $rB", (NOR8o g8rc:$rA, g8rc:$rB, g8rc:$rB)>;
3323
3324 def : InstAlias<"mtcr $rA", (MTCRF8 255, g8rc:$rA)>;
3325
3326 foreach BATR = 0-3 in {
3327     def : InstAlias<"mtdbatu "#BATR#", $Rx",
3328                     (MTSPR !add(BATR, !add(BATR, 536)), gprc:$Rx)>,
3329                     Requires<[IsPPC6xx]>;
3330     def : InstAlias<"mfdbatu $Rx, "#BATR,
3331                     (MFSPR gprc:$Rx, !add(BATR, !add(BATR, 536)))>,
3332                     Requires<[IsPPC6xx]>;
3333     def : InstAlias<"mtdbatl "#BATR#", $Rx",
3334                     (MTSPR !add(BATR, !add(BATR, 537)), gprc:$Rx)>,
3335                     Requires<[IsPPC6xx]>;
3336     def : InstAlias<"mfdbatl $Rx, "#BATR,
3337                     (MFSPR gprc:$Rx, !add(BATR, !add(BATR, 537)))>,
3338                     Requires<[IsPPC6xx]>;
3339     def : InstAlias<"mtibatu "#BATR#", $Rx",
3340                     (MTSPR !add(BATR, !add(BATR, 528)), gprc:$Rx)>,
3341                     Requires<[IsPPC6xx]>;
3342     def : InstAlias<"mfibatu $Rx, "#BATR,
3343                     (MFSPR gprc:$Rx, !add(BATR, !add(BATR, 528)))>,
3344                     Requires<[IsPPC6xx]>;
3345     def : InstAlias<"mtibatl "#BATR#", $Rx",
3346                     (MTSPR !add(BATR, !add(BATR, 529)), gprc:$Rx)>,
3347                     Requires<[IsPPC6xx]>;
3348     def : InstAlias<"mfibatl $Rx, "#BATR,
3349                     (MFSPR gprc:$Rx, !add(BATR, !add(BATR, 529)))>,
3350                     Requires<[IsPPC6xx]>;
3351 }
3352
3353 foreach BR = 0-7 in {
3354     def : InstAlias<"mfbr"#BR#" $Rx",
3355                     (MFDCR gprc:$Rx, !add(BR, 0x80))>,
3356                     Requires<[IsPPC4xx]>;
3357     def : InstAlias<"mtbr"#BR#" $Rx",
3358                     (MTDCR gprc:$Rx, !add(BR, 0x80))>,
3359                     Requires<[IsPPC4xx]>;
3360 }
3361
3362 def : InstAlias<"mtdccr $Rx", (MTSPR 1018, gprc:$Rx)>, Requires<[IsPPC4xx]>;
3363 def : InstAlias<"mfdccr $Rx", (MFSPR gprc:$Rx, 1018)>, Requires<[IsPPC4xx]>;
3364
3365 def : InstAlias<"mticcr $Rx", (MTSPR 1019, gprc:$Rx)>, Requires<[IsPPC4xx]>;
3366 def : InstAlias<"mficcr $Rx", (MFSPR gprc:$Rx, 1019)>, Requires<[IsPPC4xx]>;
3367
3368 def : InstAlias<"mtdear $Rx", (MTSPR 981, gprc:$Rx)>, Requires<[IsPPC4xx]>;
3369 def : InstAlias<"mfdear $Rx", (MFSPR gprc:$Rx, 981)>, Requires<[IsPPC4xx]>;
3370
3371 def : InstAlias<"mtesr $Rx", (MTSPR 980, gprc:$Rx)>, Requires<[IsPPC4xx]>;
3372 def : InstAlias<"mfesr $Rx", (MFSPR gprc:$Rx, 980)>, Requires<[IsPPC4xx]>;
3373
3374 def : InstAlias<"mfspefscr $Rx", (MFSPR gprc:$Rx, 512)>;
3375 def : InstAlias<"mtspefscr $Rx", (MTSPR 512, gprc:$Rx)>;
3376
3377 def : InstAlias<"mttcr $Rx", (MTSPR 986, gprc:$Rx)>, Requires<[IsPPC4xx]>;
3378 def : InstAlias<"mftcr $Rx", (MFSPR gprc:$Rx, 986)>, Requires<[IsPPC4xx]>;
3379
3380 def LAx : PPCAsmPseudo<"la $rA, $addr", (ins gprc:$rA, memri:$addr)>;
3381
3382 def SUBI : PPCAsmPseudo<"subi $rA, $rB, $imm",
3383                         (ins gprc:$rA, gprc:$rB, s16imm:$imm)>;
3384 def SUBIS : PPCAsmPseudo<"subis $rA, $rB, $imm",
3385                          (ins gprc:$rA, gprc:$rB, s16imm:$imm)>;
3386 def SUBIC : PPCAsmPseudo<"subic $rA, $rB, $imm",
3387                          (ins gprc:$rA, gprc:$rB, s16imm:$imm)>;
3388 def SUBICo : PPCAsmPseudo<"subic. $rA, $rB, $imm",
3389                           (ins gprc:$rA, gprc:$rB, s16imm:$imm)>;
3390
3391 def : InstAlias<"sub $rA, $rB, $rC", (SUBF8 g8rc:$rA, g8rc:$rC, g8rc:$rB)>;
3392 def : InstAlias<"sub. $rA, $rB, $rC", (SUBF8o g8rc:$rA, g8rc:$rC, g8rc:$rB)>;
3393 def : InstAlias<"subc $rA, $rB, $rC", (SUBFC8 g8rc:$rA, g8rc:$rC, g8rc:$rB)>;
3394 def : InstAlias<"subc. $rA, $rB, $rC", (SUBFC8o g8rc:$rA, g8rc:$rC, g8rc:$rB)>;
3395
3396 def : InstAlias<"mtmsrd $RS", (MTMSRD gprc:$RS, 0)>;
3397 def : InstAlias<"mtmsr $RS", (MTMSR gprc:$RS, 0)>;
3398
3399 def : InstAlias<"mfasr $RT", (MFSPR gprc:$RT, 280)>;
3400 def : InstAlias<"mtasr $RT", (MTSPR 280, gprc:$RT)>;
3401
3402 foreach SPRG = 0-3 in {
3403   def : InstAlias<"mfsprg $RT, "#SPRG, (MFSPR gprc:$RT, !add(SPRG, 272))>;
3404   def : InstAlias<"mfsprg"#SPRG#" $RT", (MFSPR gprc:$RT, !add(SPRG, 272))>;
3405   def : InstAlias<"mtsprg "#SPRG#", $RT", (MTSPR !add(SPRG, 272), gprc:$RT)>;
3406   def : InstAlias<"mtsprg"#SPRG#" $RT", (MTSPR !add(SPRG, 272), gprc:$RT)>;
3407 }
3408 foreach SPRG = 4-7 in {
3409   def : InstAlias<"mfsprg $RT, "#SPRG, (MFSPR gprc:$RT, !add(SPRG, 256))>,
3410                   Requires<[IsBookE]>;
3411   def : InstAlias<"mfsprg"#SPRG#" $RT", (MFSPR gprc:$RT, !add(SPRG, 256))>,
3412                   Requires<[IsBookE]>;
3413   def : InstAlias<"mtsprg "#SPRG#", $RT", (MTSPR !add(SPRG, 256), gprc:$RT)>,
3414                   Requires<[IsBookE]>;
3415   def : InstAlias<"mtsprg"#SPRG#" $RT", (MTSPR !add(SPRG, 256), gprc:$RT)>,
3416                   Requires<[IsBookE]>;
3417 }
3418
3419 def : InstAlias<"mtasr $RS", (MTSPR 280, gprc:$RS)>;
3420
3421 def : InstAlias<"mfdec $RT", (MFSPR gprc:$RT, 22)>;
3422 def : InstAlias<"mtdec $RT", (MTSPR 22, gprc:$RT)>;
3423
3424 def : InstAlias<"mfpvr $RT", (MFSPR gprc:$RT, 287)>;
3425
3426 def : InstAlias<"mfsdr1 $RT", (MFSPR gprc:$RT, 25)>;
3427 def : InstAlias<"mtsdr1 $RT", (MTSPR 25, gprc:$RT)>;
3428
3429 def : InstAlias<"mfsrr0 $RT", (MFSPR gprc:$RT, 26)>;
3430 def : InstAlias<"mfsrr1 $RT", (MFSPR gprc:$RT, 27)>;
3431 def : InstAlias<"mtsrr0 $RT", (MTSPR 26, gprc:$RT)>;
3432 def : InstAlias<"mtsrr1 $RT", (MTSPR 27, gprc:$RT)>;
3433
3434 def : InstAlias<"tlbie $RB", (TLBIE R0, gprc:$RB)>;
3435
3436 def : InstAlias<"tlbrehi $RS, $A", (TLBRE2 gprc:$RS, gprc:$A, 0)>,
3437                 Requires<[IsPPC4xx]>;
3438 def : InstAlias<"tlbrelo $RS, $A", (TLBRE2 gprc:$RS, gprc:$A, 1)>,
3439                 Requires<[IsPPC4xx]>;
3440 def : InstAlias<"tlbwehi $RS, $A", (TLBWE2 gprc:$RS, gprc:$A, 0)>,
3441                 Requires<[IsPPC4xx]>;
3442 def : InstAlias<"tlbwelo $RS, $A", (TLBWE2 gprc:$RS, gprc:$A, 1)>,
3443                 Requires<[IsPPC4xx]>;
3444
3445 def EXTLWI : PPCAsmPseudo<"extlwi $rA, $rS, $n, $b",
3446                           (ins gprc:$rA, gprc:$rS, u5imm:$n, u5imm:$b)>;
3447 def EXTLWIo : PPCAsmPseudo<"extlwi. $rA, $rS, $n, $b",
3448                            (ins gprc:$rA, gprc:$rS, u5imm:$n, u5imm:$b)>;
3449 def EXTRWI : PPCAsmPseudo<"extrwi $rA, $rS, $n, $b",
3450                           (ins gprc:$rA, gprc:$rS, u5imm:$n, u5imm:$b)>;
3451 def EXTRWIo : PPCAsmPseudo<"extrwi. $rA, $rS, $n, $b",
3452                            (ins gprc:$rA, gprc:$rS, u5imm:$n, u5imm:$b)>;
3453 def INSLWI : PPCAsmPseudo<"inslwi $rA, $rS, $n, $b",
3454                           (ins gprc:$rA, gprc:$rS, u5imm:$n, u5imm:$b)>;
3455 def INSLWIo : PPCAsmPseudo<"inslwi. $rA, $rS, $n, $b",
3456                            (ins gprc:$rA, gprc:$rS, u5imm:$n, u5imm:$b)>;
3457 def INSRWI : PPCAsmPseudo<"insrwi $rA, $rS, $n, $b",
3458                           (ins gprc:$rA, gprc:$rS, u5imm:$n, u5imm:$b)>;
3459 def INSRWIo : PPCAsmPseudo<"insrwi. $rA, $rS, $n, $b",
3460                            (ins gprc:$rA, gprc:$rS, u5imm:$n, u5imm:$b)>;
3461 def ROTRWI : PPCAsmPseudo<"rotrwi $rA, $rS, $n",
3462                           (ins gprc:$rA, gprc:$rS, u5imm:$n)>;
3463 def ROTRWIo : PPCAsmPseudo<"rotrwi. $rA, $rS, $n",
3464                            (ins gprc:$rA, gprc:$rS, u5imm:$n)>;
3465 def SLWI : PPCAsmPseudo<"slwi $rA, $rS, $n",
3466                         (ins gprc:$rA, gprc:$rS, u5imm:$n)>;
3467 def SLWIo : PPCAsmPseudo<"slwi. $rA, $rS, $n",
3468                          (ins gprc:$rA, gprc:$rS, u5imm:$n)>;
3469 def SRWI : PPCAsmPseudo<"srwi $rA, $rS, $n",
3470                         (ins gprc:$rA, gprc:$rS, u5imm:$n)>;
3471 def SRWIo : PPCAsmPseudo<"srwi. $rA, $rS, $n",
3472                          (ins gprc:$rA, gprc:$rS, u5imm:$n)>;
3473 def CLRRWI : PPCAsmPseudo<"clrrwi $rA, $rS, $n",
3474                           (ins gprc:$rA, gprc:$rS, u5imm:$n)>;
3475 def CLRRWIo : PPCAsmPseudo<"clrrwi. $rA, $rS, $n",
3476                            (ins gprc:$rA, gprc:$rS, u5imm:$n)>;
3477 def CLRLSLWI : PPCAsmPseudo<"clrlslwi $rA, $rS, $b, $n",
3478                             (ins gprc:$rA, gprc:$rS, u5imm:$b, u5imm:$n)>;
3479 def CLRLSLWIo : PPCAsmPseudo<"clrlslwi. $rA, $rS, $b, $n",
3480                              (ins gprc:$rA, gprc:$rS, u5imm:$b, u5imm:$n)>;
3481
3482 def : InstAlias<"rotlwi $rA, $rS, $n", (RLWINM gprc:$rA, gprc:$rS, u5imm:$n, 0, 31)>;
3483 def : InstAlias<"rotlwi. $rA, $rS, $n", (RLWINMo gprc:$rA, gprc:$rS, u5imm:$n, 0, 31)>;
3484 def : InstAlias<"rotlw $rA, $rS, $rB", (RLWNM gprc:$rA, gprc:$rS, gprc:$rB, 0, 31)>;
3485 def : InstAlias<"rotlw. $rA, $rS, $rB", (RLWNMo gprc:$rA, gprc:$rS, gprc:$rB, 0, 31)>;
3486 def : InstAlias<"clrlwi $rA, $rS, $n", (RLWINM gprc:$rA, gprc:$rS, 0, u5imm:$n, 31)>;
3487 def : InstAlias<"clrlwi. $rA, $rS, $n", (RLWINMo gprc:$rA, gprc:$rS, 0, u5imm:$n, 31)>;
3488
3489 def EXTLDI : PPCAsmPseudo<"extldi $rA, $rS, $n, $b",
3490                           (ins g8rc:$rA, g8rc:$rS, u6imm:$n, u6imm:$b)>;
3491 def EXTLDIo : PPCAsmPseudo<"extldi. $rA, $rS, $n, $b",
3492                            (ins g8rc:$rA, g8rc:$rS, u6imm:$n, u6imm:$b)>;
3493 def EXTRDI : PPCAsmPseudo<"extrdi $rA, $rS, $n, $b",
3494                           (ins g8rc:$rA, g8rc:$rS, u6imm:$n, u6imm:$b)>;
3495 def EXTRDIo : PPCAsmPseudo<"extrdi. $rA, $rS, $n, $b",
3496                            (ins g8rc:$rA, g8rc:$rS, u6imm:$n, u6imm:$b)>;
3497 def INSRDI : PPCAsmPseudo<"insrdi $rA, $rS, $n, $b",
3498                           (ins g8rc:$rA, g8rc:$rS, u6imm:$n, u6imm:$b)>;
3499 def INSRDIo : PPCAsmPseudo<"insrdi. $rA, $rS, $n, $b",
3500                            (ins g8rc:$rA, g8rc:$rS, u6imm:$n, u6imm:$b)>;
3501 def ROTRDI : PPCAsmPseudo<"rotrdi $rA, $rS, $n",
3502                           (ins g8rc:$rA, g8rc:$rS, u6imm:$n)>;
3503 def ROTRDIo : PPCAsmPseudo<"rotrdi. $rA, $rS, $n",
3504                            (ins g8rc:$rA, g8rc:$rS, u6imm:$n)>;
3505 def SLDI : PPCAsmPseudo<"sldi $rA, $rS, $n",
3506                         (ins g8rc:$rA, g8rc:$rS, u6imm:$n)>;
3507 def SLDIo : PPCAsmPseudo<"sldi. $rA, $rS, $n",
3508                          (ins g8rc:$rA, g8rc:$rS, u6imm:$n)>;
3509 def SRDI : PPCAsmPseudo<"srdi $rA, $rS, $n",
3510                         (ins g8rc:$rA, g8rc:$rS, u6imm:$n)>;
3511 def SRDIo : PPCAsmPseudo<"srdi. $rA, $rS, $n",
3512                          (ins g8rc:$rA, g8rc:$rS, u6imm:$n)>;
3513 def CLRRDI : PPCAsmPseudo<"clrrdi $rA, $rS, $n",
3514                           (ins g8rc:$rA, g8rc:$rS, u6imm:$n)>;
3515 def CLRRDIo : PPCAsmPseudo<"clrrdi. $rA, $rS, $n",
3516                            (ins g8rc:$rA, g8rc:$rS, u6imm:$n)>;
3517 def CLRLSLDI : PPCAsmPseudo<"clrlsldi $rA, $rS, $b, $n",
3518                             (ins g8rc:$rA, g8rc:$rS, u6imm:$b, u6imm:$n)>;
3519 def CLRLSLDIo : PPCAsmPseudo<"clrlsldi. $rA, $rS, $b, $n",
3520                              (ins g8rc:$rA, g8rc:$rS, u6imm:$b, u6imm:$n)>;
3521
3522 def : InstAlias<"rotldi $rA, $rS, $n", (RLDICL g8rc:$rA, g8rc:$rS, u6imm:$n, 0)>;
3523 def : InstAlias<"rotldi. $rA, $rS, $n", (RLDICLo g8rc:$rA, g8rc:$rS, u6imm:$n, 0)>;
3524 def : InstAlias<"rotld $rA, $rS, $rB", (RLDCL g8rc:$rA, g8rc:$rS, gprc:$rB, 0)>;
3525 def : InstAlias<"rotld. $rA, $rS, $rB", (RLDCLo g8rc:$rA, g8rc:$rS, gprc:$rB, 0)>;
3526 def : InstAlias<"clrldi $rA, $rS, $n", (RLDICL g8rc:$rA, g8rc:$rS, 0, u6imm:$n)>;
3527 def : InstAlias<"clrldi. $rA, $rS, $n", (RLDICLo g8rc:$rA, g8rc:$rS, 0, u6imm:$n)>;
3528
3529 // These generic branch instruction forms are used for the assembler parser only.
3530 // Defs and Uses are conservative, since we don't know the BO value.
3531 let PPC970_Unit = 7 in {
3532   let Defs = [CTR], Uses = [CTR, RM] in {
3533     def gBC : BForm_3<16, 0, 0, (outs),
3534                       (ins u5imm:$bo, crbitrc:$bi, condbrtarget:$dst),
3535                       "bc $bo, $bi, $dst">;
3536     def gBCA : BForm_3<16, 1, 0, (outs),
3537                        (ins u5imm:$bo, crbitrc:$bi, abscondbrtarget:$dst),
3538                        "bca $bo, $bi, $dst">;
3539   }
3540   let Defs = [LR, CTR], Uses = [CTR, RM] in {
3541     def gBCL : BForm_3<16, 0, 1, (outs),
3542                        (ins u5imm:$bo, crbitrc:$bi, condbrtarget:$dst),
3543                        "bcl $bo, $bi, $dst">;
3544     def gBCLA : BForm_3<16, 1, 1, (outs),
3545                         (ins u5imm:$bo, crbitrc:$bi, abscondbrtarget:$dst),
3546                         "bcla $bo, $bi, $dst">;
3547   }
3548   let Defs = [CTR], Uses = [CTR, LR, RM] in
3549     def gBCLR : XLForm_2<19, 16, 0, (outs),
3550                          (ins u5imm:$bo, crbitrc:$bi, i32imm:$bh),
3551                          "bclr $bo, $bi, $bh", IIC_BrB, []>;
3552   let Defs = [LR, CTR], Uses = [CTR, LR, RM] in
3553     def gBCLRL : XLForm_2<19, 16, 1, (outs),
3554                           (ins u5imm:$bo, crbitrc:$bi, i32imm:$bh),
3555                           "bclrl $bo, $bi, $bh", IIC_BrB, []>;
3556   let Defs = [CTR], Uses = [CTR, LR, RM] in
3557     def gBCCTR : XLForm_2<19, 528, 0, (outs),
3558                           (ins u5imm:$bo, crbitrc:$bi, i32imm:$bh),
3559                           "bcctr $bo, $bi, $bh", IIC_BrB, []>;
3560   let Defs = [LR, CTR], Uses = [CTR, LR, RM] in
3561     def gBCCTRL : XLForm_2<19, 528, 1, (outs),
3562                            (ins u5imm:$bo, crbitrc:$bi, i32imm:$bh),
3563                            "bcctrl $bo, $bi, $bh", IIC_BrB, []>;
3564 }
3565 def : InstAlias<"bclr $bo, $bi", (gBCLR u5imm:$bo, crbitrc:$bi, 0)>;
3566 def : InstAlias<"bclrl $bo, $bi", (gBCLRL u5imm:$bo, crbitrc:$bi, 0)>;
3567 def : InstAlias<"bcctr $bo, $bi", (gBCCTR u5imm:$bo, crbitrc:$bi, 0)>;
3568 def : InstAlias<"bcctrl $bo, $bi", (gBCCTRL u5imm:$bo, crbitrc:$bi, 0)>;
3569
3570 multiclass BranchSimpleMnemonic1<string name, string pm, int bo> {
3571   def : InstAlias<"b"#name#pm#" $bi, $dst", (gBC bo, crbitrc:$bi, condbrtarget:$dst)>;
3572   def : InstAlias<"b"#name#"a"#pm#" $bi, $dst", (gBCA bo, crbitrc:$bi, abscondbrtarget:$dst)>;
3573   def : InstAlias<"b"#name#"lr"#pm#" $bi", (gBCLR bo, crbitrc:$bi, 0)>;
3574   def : InstAlias<"b"#name#"l"#pm#" $bi, $dst", (gBCL bo, crbitrc:$bi, condbrtarget:$dst)>;
3575   def : InstAlias<"b"#name#"la"#pm#" $bi, $dst", (gBCLA bo, crbitrc:$bi, abscondbrtarget:$dst)>;
3576   def : InstAlias<"b"#name#"lrl"#pm#" $bi", (gBCLRL bo, crbitrc:$bi, 0)>;
3577 }
3578 multiclass BranchSimpleMnemonic2<string name, string pm, int bo>
3579   : BranchSimpleMnemonic1<name, pm, bo> {
3580   def : InstAlias<"b"#name#"ctr"#pm#" $bi", (gBCCTR bo, crbitrc:$bi, 0)>;
3581   def : InstAlias<"b"#name#"ctrl"#pm#" $bi", (gBCCTRL bo, crbitrc:$bi, 0)>;
3582 }
3583 defm : BranchSimpleMnemonic2<"t", "", 12>;
3584 defm : BranchSimpleMnemonic2<"f", "", 4>;
3585 defm : BranchSimpleMnemonic2<"t", "-", 14>;
3586 defm : BranchSimpleMnemonic2<"f", "-", 6>;
3587 defm : BranchSimpleMnemonic2<"t", "+", 15>;
3588 defm : BranchSimpleMnemonic2<"f", "+", 7>;
3589 defm : BranchSimpleMnemonic1<"dnzt", "", 8>;
3590 defm : BranchSimpleMnemonic1<"dnzf", "", 0>;
3591 defm : BranchSimpleMnemonic1<"dzt", "", 10>;
3592 defm : BranchSimpleMnemonic1<"dzf", "", 2>;
3593
3594 multiclass BranchExtendedMnemonicPM<string name, string pm, int bibo> {
3595   def : InstAlias<"b"#name#pm#" $cc, $dst",
3596                   (BCC bibo, crrc:$cc, condbrtarget:$dst)>;
3597   def : InstAlias<"b"#name#pm#" $dst",
3598                   (BCC bibo, CR0, condbrtarget:$dst)>;
3599
3600   def : InstAlias<"b"#name#"a"#pm#" $cc, $dst",
3601                   (BCCA bibo, crrc:$cc, abscondbrtarget:$dst)>;
3602   def : InstAlias<"b"#name#"a"#pm#" $dst",
3603                   (BCCA bibo, CR0, abscondbrtarget:$dst)>;
3604
3605   def : InstAlias<"b"#name#"lr"#pm#" $cc",
3606                   (BCCLR bibo, crrc:$cc)>;
3607   def : InstAlias<"b"#name#"lr"#pm,
3608                   (BCCLR bibo, CR0)>;
3609
3610   def : InstAlias<"b"#name#"ctr"#pm#" $cc",
3611                   (BCCCTR bibo, crrc:$cc)>;
3612   def : InstAlias<"b"#name#"ctr"#pm,
3613                   (BCCCTR bibo, CR0)>;
3614
3615   def : InstAlias<"b"#name#"l"#pm#" $cc, $dst",
3616                   (BCCL bibo, crrc:$cc, condbrtarget:$dst)>;
3617   def : InstAlias<"b"#name#"l"#pm#" $dst",
3618                   (BCCL bibo, CR0, condbrtarget:$dst)>;
3619
3620   def : InstAlias<"b"#name#"la"#pm#" $cc, $dst",
3621                   (BCCLA bibo, crrc:$cc, abscondbrtarget:$dst)>;
3622   def : InstAlias<"b"#name#"la"#pm#" $dst",
3623                   (BCCLA bibo, CR0, abscondbrtarget:$dst)>;
3624
3625   def : InstAlias<"b"#name#"lrl"#pm#" $cc",
3626                   (BCCLRL bibo, crrc:$cc)>;
3627   def : InstAlias<"b"#name#"lrl"#pm,
3628                   (BCCLRL bibo, CR0)>;
3629
3630   def : InstAlias<"b"#name#"ctrl"#pm#" $cc",
3631                   (BCCCTRL bibo, crrc:$cc)>;
3632   def : InstAlias<"b"#name#"ctrl"#pm,
3633                   (BCCCTRL bibo, CR0)>;
3634 }
3635 multiclass BranchExtendedMnemonic<string name, int bibo> {
3636   defm : BranchExtendedMnemonicPM<name, "", bibo>;
3637   defm : BranchExtendedMnemonicPM<name, "-", !add(bibo, 2)>;
3638   defm : BranchExtendedMnemonicPM<name, "+", !add(bibo, 3)>;
3639 }
3640 defm : BranchExtendedMnemonic<"lt", 12>;
3641 defm : BranchExtendedMnemonic<"gt", 44>;
3642 defm : BranchExtendedMnemonic<"eq", 76>;
3643 defm : BranchExtendedMnemonic<"un", 108>;
3644 defm : BranchExtendedMnemonic<"so", 108>;
3645 defm : BranchExtendedMnemonic<"ge", 4>;
3646 defm : BranchExtendedMnemonic<"nl", 4>;
3647 defm : BranchExtendedMnemonic<"le", 36>;
3648 defm : BranchExtendedMnemonic<"ng", 36>;
3649 defm : BranchExtendedMnemonic<"ne", 68>;
3650 defm : BranchExtendedMnemonic<"nu", 100>;
3651 defm : BranchExtendedMnemonic<"ns", 100>;
3652
3653 def : InstAlias<"cmpwi $rA, $imm", (CMPWI CR0, gprc:$rA, s16imm:$imm)>;
3654 def : InstAlias<"cmpw $rA, $rB", (CMPW CR0, gprc:$rA, gprc:$rB)>;
3655 def : InstAlias<"cmplwi $rA, $imm", (CMPLWI CR0, gprc:$rA, u16imm:$imm)>;
3656 def : InstAlias<"cmplw $rA, $rB", (CMPLW CR0, gprc:$rA, gprc:$rB)>;
3657 def : InstAlias<"cmpdi $rA, $imm", (CMPDI CR0, g8rc:$rA, s16imm64:$imm)>;
3658 def : InstAlias<"cmpd $rA, $rB", (CMPD CR0, g8rc:$rA, g8rc:$rB)>;
3659 def : InstAlias<"cmpldi $rA, $imm", (CMPLDI CR0, g8rc:$rA, u16imm64:$imm)>;
3660 def : InstAlias<"cmpld $rA, $rB", (CMPLD CR0, g8rc:$rA, g8rc:$rB)>;
3661
3662 def : InstAlias<"cmpi $bf, 0, $rA, $imm", (CMPWI crrc:$bf, gprc:$rA, s16imm:$imm)>;
3663 def : InstAlias<"cmp $bf, 0, $rA, $rB", (CMPW crrc:$bf, gprc:$rA, gprc:$rB)>;
3664 def : InstAlias<"cmpli $bf, 0, $rA, $imm", (CMPLWI crrc:$bf, gprc:$rA, u16imm:$imm)>;
3665 def : InstAlias<"cmpl $bf, 0, $rA, $rB", (CMPLW crrc:$bf, gprc:$rA, gprc:$rB)>;
3666 def : InstAlias<"cmpi $bf, 1, $rA, $imm", (CMPDI crrc:$bf, g8rc:$rA, s16imm64:$imm)>;
3667 def : InstAlias<"cmp $bf, 1, $rA, $rB", (CMPD crrc:$bf, g8rc:$rA, g8rc:$rB)>;
3668 def : InstAlias<"cmpli $bf, 1, $rA, $imm", (CMPLDI crrc:$bf, g8rc:$rA, u16imm64:$imm)>;
3669 def : InstAlias<"cmpl $bf, 1, $rA, $rB", (CMPLD crrc:$bf, g8rc:$rA, g8rc:$rB)>;
3670
3671 multiclass TrapExtendedMnemonic<string name, int to> {
3672   def : InstAlias<"td"#name#"i $rA, $imm", (TDI to, g8rc:$rA, s16imm:$imm)>;
3673   def : InstAlias<"td"#name#" $rA, $rB", (TD to, g8rc:$rA, g8rc:$rB)>;
3674   def : InstAlias<"tw"#name#"i $rA, $imm", (TWI to, gprc:$rA, s16imm:$imm)>;
3675   def : InstAlias<"tw"#name#" $rA, $rB", (TW to, gprc:$rA, gprc:$rB)>;
3676 }
3677 defm : TrapExtendedMnemonic<"lt", 16>;
3678 defm : TrapExtendedMnemonic<"le", 20>;
3679 defm : TrapExtendedMnemonic<"eq", 4>;
3680 defm : TrapExtendedMnemonic<"ge", 12>;
3681 defm : TrapExtendedMnemonic<"gt", 8>;
3682 defm : TrapExtendedMnemonic<"nl", 12>;
3683 defm : TrapExtendedMnemonic<"ne", 24>;
3684 defm : TrapExtendedMnemonic<"ng", 20>;
3685 defm : TrapExtendedMnemonic<"llt", 2>;
3686 defm : TrapExtendedMnemonic<"lle", 6>;
3687 defm : TrapExtendedMnemonic<"lge", 5>;
3688 defm : TrapExtendedMnemonic<"lgt", 1>;
3689 defm : TrapExtendedMnemonic<"lnl", 5>;
3690 defm : TrapExtendedMnemonic<"lng", 6>;
3691 defm : TrapExtendedMnemonic<"u", 31>;