lib/Target/PowerPC/PPCInstrAltivec.td

   1 //===- PPCInstrAltivec.td - The PowerPC Altivec Extension --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Altivec extension to the PowerPC instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Altivec transformation functions and pattern fragments.
  16 //
  17
  18 // VSPLT*_get_imm xform function: convert vector_shuffle mask to VSPLT* imm.
  19 def VSPLTB_get_imm : SDNodeXForm<build_vector, [{
  20   return getI32Imm(PPC::getVSPLTImmediate(N, 1));
  21 }]>;
  22 def VSPLTB_shuffle_mask : PatLeaf<(build_vector), [{
  23   return PPC::isSplatShuffleMask(N, 1);
  24 }], VSPLTB_get_imm>;
  25 def VSPLTH_get_imm : SDNodeXForm<build_vector, [{
  26   return getI32Imm(PPC::getVSPLTImmediate(N, 2));
  27 }]>;
  28 def VSPLTH_shuffle_mask : PatLeaf<(build_vector), [{
  29   return PPC::isSplatShuffleMask(N, 2);
  30 }], VSPLTH_get_imm>;
  31 def VSPLTW_get_imm : SDNodeXForm<build_vector, [{
  32   return getI32Imm(PPC::getVSPLTImmediate(N, 4));
  33 }]>;
  34 def VSPLTW_shuffle_mask : PatLeaf<(build_vector), [{
  35   return PPC::isSplatShuffleMask(N, 4);
  36 }], VSPLTW_get_imm>;
  37
  38
  39 // VSPLTISB_get_imm xform function: convert build_vector to VSPLTISB imm.
  40 def VSPLTISB_get_imm : SDNodeXForm<build_vector, [{
  41   char Val;
  42   PPC::isVecSplatImm(N, 1, &Val);
  43   return getI32Imm(Val);
  44 }]>;
  45 def vecspltisb : PatLeaf<(build_vector), [{
  46   return PPC::isVecSplatImm(N, 1);
  47 }], VSPLTISB_get_imm>;
  48
  49 // VSPLTISH_get_imm xform function: convert build_vector to VSPLTISH imm.
  50 def VSPLTISH_get_imm : SDNodeXForm<build_vector, [{
  51   char Val;
  52   PPC::isVecSplatImm(N, 2, &Val);
  53   return getI32Imm(Val);
  54 }]>;
  55 def vecspltish : PatLeaf<(build_vector), [{
  56   return PPC::isVecSplatImm(N, 2);
  57 }], VSPLTISH_get_imm>;
  58
  59 // VSPLTISW_get_imm xform function: convert build_vector to VSPLTISW imm.
  60 def VSPLTISW_get_imm : SDNodeXForm<build_vector, [{
  61   char Val;
  62   PPC::isVecSplatImm(N, 4, &Val);
  63   return getI32Imm(Val);
  64 }]>;
  65 def vecspltisw : PatLeaf<(build_vector), [{
  66   return PPC::isVecSplatImm(N, 4);
  67 }], VSPLTISW_get_imm>;
  68
  69 //===----------------------------------------------------------------------===//
  70 // Helpers for defining instructions that directly correspond to intrinsics.
  71
  72 // VA1a_Int - A VAForm_1a intrinsic definition.
  73 class VA1a_Int<bits<6> xo, string opc, Intrinsic IntID>
  74   : VAForm_1a<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB, VRRC:$vC),
  75               !strconcat(opc, " $vD, $vA, $vB, $vC"), VecFP,
  76                        [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB, VRRC:$vC))]>;
  77
  78 // VX1_Int - A VXForm_1 intrinsic definition.
  79 class VX1_Int<bits<11> xo, string opc, Intrinsic IntID>
  80   : VXForm_1<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
  81              !strconcat(opc, " $vD, $vA, $vB"), VecFP,
  82              [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB))]>;
  83
  84 // VX2_Int - A VXForm_2 intrinsic definition.
  85 class VX2_Int<bits<11> xo, string opc, Intrinsic IntID>
  86   : VXForm_2<xo, (ops VRRC:$vD, VRRC:$vB),
  87              !strconcat(opc, " $vD, $vB"), VecFP,
  88              [(set VRRC:$vD, (IntID VRRC:$vB))]>;
  89
  90 //===----------------------------------------------------------------------===//
  91 // Instruction Definitions.
  92
  93 def IMPLICIT_DEF_VRRC : Pseudo<(ops VRRC:$rD), "; $rD = IMPLICIT_DEF_VRRC",
  94                                [(set VRRC:$rD, (v4f32 (undef)))]>;
  95
  96 let noResults = 1 in {
  97 def DSS   : DSS_Form<822, (ops u5imm:$A, u5imm:$STRM,u5imm:$ZERO1,u5imm:$ZERO2),
  98                      "dss $STRM, $A", LdStGeneral /*FIXME*/, []>;
  99 def DST   : DSS_Form<342, (ops u5imm:$T, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 100                      "dst $rA, $rB, $STRM, $T", LdStGeneral /*FIXME*/, []>;
 101 def DSTST : DSS_Form<374, (ops u5imm:$T, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 102                    "dstst $rA, $rB, $STRM, $T", LdStGeneral /*FIXME*/, []>;
 103 }
 104
 105 def MFVSCR : VXForm_4<1540, (ops VRRC:$vD),
 106                       "mfvcr $vD", LdStGeneral,
 107                       [(set VRRC:$vD, (int_ppc_altivec_mfvscr))]>;
 108 def MTVSCR : VXForm_5<1604, (ops VRRC:$vB),
 109                       "mtvcr $vB", LdStGeneral,
 110                       [(int_ppc_altivec_mtvscr VRRC:$vB)]>;
 111
 112 let isLoad = 1, PPC970_Unit = 2 in {  // Loads.
 113 def LVEBX: XForm_1<31,   7, (ops VRRC:$vD, memrr:$src),
 114                    "lvebx $vD, $src", LdStGeneral,
 115                    [(set VRRC:$vD, (int_ppc_altivec_lvebx xoaddr:$src))]>;
 116 def LVEHX: XForm_1<31,  39, (ops VRRC:$vD, memrr:$src),
 117                    "lvehx $vD, $src", LdStGeneral,
 118                    [(set VRRC:$vD, (int_ppc_altivec_lvehx xoaddr:$src))]>;
 119 def LVEWX: XForm_1<31,  71, (ops VRRC:$vD, memrr:$src),
 120                    "lvewx $vD, $src", LdStGeneral,
 121                    [(set VRRC:$vD, (int_ppc_altivec_lvewx xoaddr:$src))]>;
 122 def LVX  : XForm_1<31, 103, (ops VRRC:$vD, memrr:$src),
 123                    "lvx $vD, $src", LdStGeneral,
 124                    [(set VRRC:$vD, (int_ppc_altivec_lvx xoaddr:$src))]>;
 125 def LVXL : XForm_1<31, 359, (ops VRRC:$vD, memrr:$src),
 126                    "lvxl $vD, $src", LdStGeneral,
 127                    [(set VRRC:$vD, (int_ppc_altivec_lvxl xoaddr:$src))]>;
 128 }
 129
 130 def LVSL : XForm_1<31,   6, (ops VRRC:$vD, memrr:$src),
 131                    "lvsl $vD, $src", LdStGeneral,
 132                    [(set VRRC:$vD, (int_ppc_altivec_lvsl xoaddr:$src))]>,
 133                    PPC970_Unit_LSU;
 134 def LVSR : XForm_1<31,  38, (ops VRRC:$vD, memrr:$src),
 135                    "lvsr $vD, $src", LdStGeneral,
 136                    [(set VRRC:$vD, (int_ppc_altivec_lvsr xoaddr:$src))]>,
 137                    PPC970_Unit_LSU;
 138
 139 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {   // Stores.
 140 def STVEBX: XForm_8<31, 135, (ops VRRC:$rS, memrr:$dst),
 141                    "stvebx $rS, $dst", LdStGeneral,
 142                    [(int_ppc_altivec_stvebx VRRC:$rS, xoaddr:$dst)]>;
 143 def STVEHX: XForm_8<31, 167, (ops VRRC:$rS, memrr:$dst),
 144                    "stvehx $rS, $dst", LdStGeneral,
 145                    [(int_ppc_altivec_stvehx VRRC:$rS, xoaddr:$dst)]>;
 146 def STVEWX: XForm_8<31, 199, (ops VRRC:$rS, memrr:$dst),
 147                    "stvewx $rS, $dst", LdStGeneral,
 148                    [(int_ppc_altivec_stvewx VRRC:$rS, xoaddr:$dst)]>;
 149 def STVX  : XForm_8<31, 231, (ops VRRC:$rS, memrr:$dst),
 150                    "stvx $rS, $dst", LdStGeneral,
 151                    [(int_ppc_altivec_stvx VRRC:$rS, xoaddr:$dst)]>;
 152 def STVXL : XForm_8<31, 487, (ops VRRC:$rS, memrr:$dst),
 153                    "stvxl $rS, $dst", LdStGeneral,
 154                    [(int_ppc_altivec_stvxl VRRC:$rS, xoaddr:$dst)]>;
 155 }
 156
 157 let PPC970_Unit = 5 in {  // VALU Operations.
 158 // VA-Form instructions.  3-input AltiVec ops.
 159 def VMADDFP : VAForm_1<46, (ops VRRC:$vD, VRRC:$vA, VRRC:$vC, VRRC:$vB),
 160                        "vmaddfp $vD, $vA, $vC, $vB", VecFP,
 161                        [(set VRRC:$vD, (fadd (fmul VRRC:$vA, VRRC:$vC),
 162                                              VRRC:$vB))]>,
 163                        Requires<[FPContractions]>;
 164 def VNMSUBFP: VAForm_1<47, (ops VRRC:$vD, VRRC:$vA, VRRC:$vC, VRRC:$vB),
 165                        "vnmsubfp $vD, $vA, $vC, $vB", VecFP,
 166                        [(set VRRC:$vD, (fneg (fsub (fmul VRRC:$vA, VRRC:$vC),
 167                                                    VRRC:$vB)))]>,
 168                        Requires<[FPContractions]>;
 169
 170 def VMHADDSHS  : VA1a_Int<32, "vmhaddshs",  int_ppc_altivec_vmhaddshs>;
 171 def VMHRADDSHS : VA1a_Int<33, "vmhraddshs", int_ppc_altivec_vmhraddshs>;
 172 def VMLADDUHM  : VA1a_Int<34, "vmladduhm",  int_ppc_altivec_vmladduhm>;
 173 def VPERM      : VA1a_Int<43, "vperm",      int_ppc_altivec_vperm>;
 174 def VSEL       : VA1a_Int<42, "vsel",       int_ppc_altivec_vsel>;
 175
 176 def VSLDOI  : VAForm_2<44, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB, u5imm:$SH),
 177                        "vsldoi $vD, $vA, $vB, $SH", VecFP,
 178                        [(set VRRC:$vD,
 179                              (int_ppc_altivec_vsldoi VRRC:$vA, VRRC:$vB,
 180                                                      imm:$SH))]>;
 181
 182 // VX-Form instructions.  AltiVec arithmetic ops.
 183 def VADDFP : VXForm_1<10, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 184                       "vaddfp $vD, $vA, $vB", VecFP,
 185                       [(set VRRC:$vD, (fadd VRRC:$vA, VRRC:$vB))]>;
 186
 187 def VADDUBM : VXForm_1<0, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 188                       "vaddubm $vD, $vA, $vB", VecGeneral,
 189                       [(set VRRC:$vD, (add (v16i8 VRRC:$vA), VRRC:$vB))]>;
 190 def VADDUHM : VXForm_1<64, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 191                       "vadduhm $vD, $vA, $vB", VecGeneral,
 192                       [(set VRRC:$vD, (add (v8i16 VRRC:$vA), VRRC:$vB))]>;
 193 def VADDUWM : VXForm_1<128, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 194                       "vadduwm $vD, $vA, $vB", VecGeneral,
 195                       [(set VRRC:$vD, (add (v4i32 VRRC:$vA), VRRC:$vB))]>;
 196
 197 def VADDCUW : VX1_Int<384, "vaddcuw", int_ppc_altivec_vaddcuw>;
 198 def VADDSBS : VX1_Int<768, "vaddsbs", int_ppc_altivec_vaddsbs>;
 199 def VADDSHS : VX1_Int<832, "vaddshs", int_ppc_altivec_vaddshs>;
 200 def VADDSWS : VX1_Int<896, "vaddsws", int_ppc_altivec_vaddsws>;
 201 def VADDUBS : VX1_Int<512, "vaddubs", int_ppc_altivec_vaddubs>;
 202 def VADDUHS : VX1_Int<576, "vadduhs", int_ppc_altivec_vadduhs>;
 203 def VADDUWS : VX1_Int<640, "vadduws", int_ppc_altivec_vadduws>;
 204
 205
 206 def VAND : VXForm_1<1028, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 207                     "vand $vD, $vA, $vB", VecFP,
 208                     [(set VRRC:$vD, (and (v4i32 VRRC:$vA), VRRC:$vB))]>;
 209 def VANDC : VXForm_1<1092, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 210                      "vandc $vD, $vA, $vB", VecFP,
 211                      [(set VRRC:$vD, (and (v4i32 VRRC:$vA), (vnot VRRC:$vB)))]>;
 212
 213 def VCFSX  : VXForm_1<842, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 214                       "vcfsx $vD, $vB, $UIMM", VecFP,
 215                       [(set VRRC:$vD,
 216                              (int_ppc_altivec_vcfsx VRRC:$vB, imm:$UIMM))]>;
 217 def VCFUX  : VXForm_1<778, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 218                       "vcfux $vD, $vB, $UIMM", VecFP,
 219                       [(set VRRC:$vD,
 220                              (int_ppc_altivec_vcfux VRRC:$vB, imm:$UIMM))]>;
 221 def VCTSXS : VXForm_1<970, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 222                       "vctsxs $vD, $vB, $UIMM", VecFP,
 223                       [(set VRRC:$vD,
 224                              (int_ppc_altivec_vctsxs VRRC:$vB, imm:$UIMM))]>;
 225 def VCTUXS : VXForm_1<906, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 226                       "vctuxs $vD, $vB, $UIMM", VecFP,
 227                       [(set VRRC:$vD,
 228                              (int_ppc_altivec_vctuxs VRRC:$vB, imm:$UIMM))]>;
 229 def VEXPTEFP : VX2_Int<394, "vexptefp", int_ppc_altivec_vexptefp>;
 230 def VLOGEFP  : VX2_Int<458, "vlogefp",  int_ppc_altivec_vlogefp>;
 231
 232 def VAVGSB : VX1_Int<1282, "vavgsb", int_ppc_altivec_vavgsb>;
 233 def VAVGSH : VX1_Int<1346, "vavgsh", int_ppc_altivec_vavgsh>;
 234 def VAVGSW : VX1_Int<1410, "vavgsw", int_ppc_altivec_vavgsw>;
 235 def VAVGUB : VX1_Int<1026, "vavgub", int_ppc_altivec_vavgub>;
 236 def VAVGUH : VX1_Int<1090, "vavguh", int_ppc_altivec_vavguh>;
 237 def VAVGUW : VX1_Int<1154, "vavguw", int_ppc_altivec_vavguw>;
 238
 239 def VMAXFP : VX1_Int<1034, "vmaxfp", int_ppc_altivec_vmaxfp>;
 240 def VMAXSB : VX1_Int< 258, "vmaxsb", int_ppc_altivec_vmaxsb>;
 241 def VMAXSH : VX1_Int< 322, "vmaxsh", int_ppc_altivec_vmaxsh>;
 242 def VMAXSW : VX1_Int< 386, "vmaxsw", int_ppc_altivec_vmaxsw>;
 243 def VMAXUB : VX1_Int<   2, "vmaxub", int_ppc_altivec_vmaxub>;
 244 def VMAXUH : VX1_Int<  66, "vmaxuh", int_ppc_altivec_vmaxuh>;
 245 def VMAXUW : VX1_Int< 130, "vmaxuw", int_ppc_altivec_vmaxuw>;
 246 def VMINFP : VX1_Int<1098, "vminfp", int_ppc_altivec_vminfp>;
 247 def VMINSB : VX1_Int< 770, "vminsb", int_ppc_altivec_vminsb>;
 248 def VMINSH : VX1_Int< 834, "vminsh", int_ppc_altivec_vminsh>;
 249 def VMINSW : VX1_Int< 896, "vminsw", int_ppc_altivec_vminsw>;
 250 def VMINUB : VX1_Int< 514, "vminub", int_ppc_altivec_vminub>;
 251 def VMINUH : VX1_Int< 578, "vminuh", int_ppc_altivec_vminuh>;
 252 def VMINUW : VX1_Int< 642, "vminuw", int_ppc_altivec_vminuw>;
 253
 254 def VMRGHB : VX1_Int<12 , "vmrghb", int_ppc_altivec_vmrghb>;
 255 def VMRGHH : VX1_Int<76 , "vmrghh", int_ppc_altivec_vmrghh>;
 256 def VMRGHW : VX1_Int<140, "vmrghw", int_ppc_altivec_vmrghw>;
 257 def VMRGLB : VX1_Int<268, "vmrglb", int_ppc_altivec_vmrglb>;
 258 def VMRGLH : VX1_Int<332, "vmrglh", int_ppc_altivec_vmrglh>;
 259 def VMRGLW : VX1_Int<396, "vmrglw", int_ppc_altivec_vmrglw>;
 260
 261 def VMSUMMBM : VA1a_Int<37, "vmsummbm", int_ppc_altivec_vmsummbm>;
 262 def VMSUMSHM : VA1a_Int<40, "vmsumshm", int_ppc_altivec_vmsumshm>;
 263 def VMSUMSHS : VA1a_Int<41, "vmsumshs", int_ppc_altivec_vmsumshs>;
 264 def VMSUMUBM : VA1a_Int<36, "vmsumubm", int_ppc_altivec_vmsumubm>;
 265 def VMSUMUHM : VA1a_Int<38, "vmsumuhm", int_ppc_altivec_vmsumuhm>;
 266 def VMSUMUHS : VA1a_Int<39, "vmsumuhs", int_ppc_altivec_vmsumuhs>;
 267
 268 def VMULESB : VX1_Int<776, "vmulesb", int_ppc_altivec_vmulesb>;
 269 def VMULESH : VX1_Int<840, "vmulesh", int_ppc_altivec_vmulesh>;
 270 def VMULEUB : VX1_Int<520, "vmuleub", int_ppc_altivec_vmuleub>;
 271 def VMULEUH : VX1_Int<584, "vmuleuh", int_ppc_altivec_vmuleuh>;
 272 def VMULOSB : VX1_Int<264, "vmulosb", int_ppc_altivec_vmulosb>;
 273 def VMULOSH : VX1_Int<328, "vmulosh", int_ppc_altivec_vmulosh>;
 274 def VMULOUB : VX1_Int<  8, "vmuloub", int_ppc_altivec_vmuloub>;
 275 def VMULOUH : VX1_Int< 72, "vmulouh", int_ppc_altivec_vmulouh>;
 276
 277 def VREFP     : VX2_Int<266, "vrefp",     int_ppc_altivec_vrefp>;
 278 def VRFIM     : VX2_Int<714, "vrfim",     int_ppc_altivec_vrfim>;
 279 def VRFIN     : VX2_Int<522, "vrfin",     int_ppc_altivec_vrfin>;
 280 def VRFIP     : VX2_Int<650, "vrfip",     int_ppc_altivec_vrfip>;
 281 def VRFIZ     : VX2_Int<586, "vrfiz",     int_ppc_altivec_vrfiz>;
 282 def VRSQRTEFP : VX2_Int<330, "vrsqrtefp", int_ppc_altivec_vrsqrtefp>;
 283
 284 def VSUBCUW : VX1_Int<74, "vsubcuw", int_ppc_altivec_vsubcuw>;
 285
 286 def VSUBFP  : VXForm_1<74, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 287                       "vsubfp $vD, $vA, $vB", VecGeneral,
 288                       [(set VRRC:$vD, (fsub VRRC:$vA, VRRC:$vB))]>;
 289 def VSUBUBM : VXForm_1<1024, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 290                       "vsububm $vD, $vA, $vB", VecGeneral,
 291                       [(set VRRC:$vD, (sub (v16i8 VRRC:$vA), VRRC:$vB))]>;
 292 def VSUBUHM : VXForm_1<1088, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 293                       "vsubuhm $vD, $vA, $vB", VecGeneral,
 294                       [(set VRRC:$vD, (sub (v8i16 VRRC:$vA), VRRC:$vB))]>;
 295 def VSUBUWM : VXForm_1<1152, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 296                       "vsubuwm $vD, $vA, $vB", VecGeneral,
 297                       [(set VRRC:$vD, (sub (v4i32 VRRC:$vA), VRRC:$vB))]>;
 298
 299 def VSUBSBS : VX1_Int<1792, "vsubsbs" , int_ppc_altivec_vsubsbs>;
 300 def VSUBSHS : VX1_Int<1856, "vsubshs" , int_ppc_altivec_vsubshs>;
 301 def VSUBSWS : VX1_Int<1920, "vsubsws" , int_ppc_altivec_vsubsws>;
 302 def VSUBUBS : VX1_Int<1536, "vsububs" , int_ppc_altivec_vsububs>;
 303 def VSUBUHS : VX1_Int<1600, "vsubuhs" , int_ppc_altivec_vsubuhs>;
 304 def VSUBUWS : VX1_Int<1664, "vsubuws" , int_ppc_altivec_vsubuws>;
 305 def VSUMSWS : VX1_Int<1928, "vsumsws" , int_ppc_altivec_vsumsws>;
 306 def VSUM2SWS: VX1_Int<1672, "vsum2sws", int_ppc_altivec_vsum2sws>;
 307 def VSUM4SBS: VX1_Int<1672, "vsum4sbs", int_ppc_altivec_vsum4sbs>;
 308 def VSUM4SHS: VX1_Int<1608, "vsum4shs", int_ppc_altivec_vsum4shs>;
 309 def VSUM4UBS: VX1_Int<1544, "vsum4ubs", int_ppc_altivec_vsum4ubs>;
 310
 311 def VNOR : VXForm_1<1284, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 312                     "vnor $vD, $vA, $vB", VecFP,
 313                     [(set VRRC:$vD, (vnot (or (v4i32 VRRC:$vA), VRRC:$vB)))]>;
 314 def VOR : VXForm_1<1156, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 315                       "vor $vD, $vA, $vB", VecFP,
 316                       [(set VRRC:$vD, (or (v4i32 VRRC:$vA), VRRC:$vB))]>;
 317 def VXOR : VXForm_1<1220, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 318                       "vxor $vD, $vA, $vB", VecFP,
 319                       [(set VRRC:$vD, (xor (v4i32 VRRC:$vA), VRRC:$vB))]>;
 320
 321 def VRLB   : VX1_Int<   4, "vrlb", int_ppc_altivec_vrlb>;
 322 def VRLH   : VX1_Int<  68, "vrlh", int_ppc_altivec_vrlh>;
 323 def VRLW   : VX1_Int< 132, "vrlw", int_ppc_altivec_vrlw>;
 324
 325 def VSL    : VX1_Int< 452, "vsl" , int_ppc_altivec_vsl >;
 326 def VSLO   : VX1_Int<1036, "vslo", int_ppc_altivec_vslo>;
 327 def VSLB   : VX1_Int< 260, "vslb", int_ppc_altivec_vslb>;
 328 def VSLH   : VX1_Int< 324, "vslh", int_ppc_altivec_vslh>;
 329 def VSLW   : VX1_Int< 388, "vslw", int_ppc_altivec_vslw>;
 330
 331 def VSPLTB : VXForm_1<524, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 332                       "vspltb $vD, $vB, $UIMM", VecPerm,
 333                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vB), (undef),
 334                                       VSPLTB_shuffle_mask:$UIMM))]>;
 335 def VSPLTH : VXForm_1<588, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 336                       "vsplth $vD, $vB, $UIMM", VecPerm,
 337                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vB), (undef),
 338                                       VSPLTH_shuffle_mask:$UIMM))]>;
 339 def VSPLTW : VXForm_1<652, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 340                       "vspltw $vD, $vB, $UIMM", VecPerm,
 341                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vB), (undef),
 342                                       VSPLTW_shuffle_mask:$UIMM))]>;
 343
 344 def VSR    : VX1_Int< 708, "vsr"  , int_ppc_altivec_vsr>;
 345 def VSRO   : VX1_Int<1100, "vsro" , int_ppc_altivec_vsro>;
 346 def VSRAB  : VX1_Int< 772, "vsrab", int_ppc_altivec_vsrab>;
 347 def VSRAH  : VX1_Int< 836, "vsrah", int_ppc_altivec_vsrah>;
 348 def VSRAW  : VX1_Int< 900, "vsraw", int_ppc_altivec_vsraw>;
 349 def VSRB   : VX1_Int< 516, "vsrb" , int_ppc_altivec_vsrb>;
 350 def VSRH   : VX1_Int< 580, "vsrh" , int_ppc_altivec_vsrh>;
 351 def VSRW   : VX1_Int< 644, "vsrw" , int_ppc_altivec_vsrw>;
 352
 353
 354 def VSPLTISB : VXForm_3<780, (ops VRRC:$vD, s5imm:$SIMM),
 355                        "vspltisb $vD, $SIMM", VecPerm,
 356                        [(set VRRC:$vD, (v4f32 vecspltisb:$SIMM))]>;
 357 def VSPLTISH : VXForm_3<844, (ops VRRC:$vD, s5imm:$SIMM),
 358                        "vspltish $vD, $SIMM", VecPerm,
 359                        [(set VRRC:$vD, (v4f32 vecspltish:$SIMM))]>;
 360 def VSPLTISW : VXForm_3<908, (ops VRRC:$vD, s5imm:$SIMM),
 361                        "vspltisw $vD, $SIMM", VecPerm,
 362                        [(set VRRC:$vD, (v4f32 vecspltisw:$SIMM))]>;
 363
 364 // Vector Pack.
 365 def VPKPX   : VX1_Int<782, "vpkpx", int_ppc_altivec_vpkpx>;
 366 def VPKSHSS : VX1_Int<398, "vpkshss", int_ppc_altivec_vpkshss>;
 367 def VPKSHUS : VX1_Int<270, "vpkshus", int_ppc_altivec_vpkshus>;
 368 def VPKSWSS : VX1_Int<462, "vpkswss", int_ppc_altivec_vpkswss>;
 369 def VPKSWUS : VX1_Int<334, "vpkswus", int_ppc_altivec_vpkswus>;
 370 def VPKUHUM : VXForm_1<14, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 371                        "vpkuhum $vD, $vA, $vB", VecFP,
 372                        [/*TODO*/]>;
 373 def VPKUHUS : VX1_Int<142, "vpkuhus", int_ppc_altivec_vpkuhus>;
 374 def VPKUWUM : VXForm_1<78, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 375                        "vpkuwum $vD, $vA, $vB", VecFP,
 376                        [/*TODO*/]>;
 377 def VPKUWUS : VX1_Int<206, "vpkuwus", int_ppc_altivec_vpkuwus>;
 378
 379 // Vector Unpack.
 380 def VUPKHPX : VX2_Int<846, "vupkhpx", int_ppc_altivec_vupkhpx>;
 381 def VUPKHSB : VX2_Int<526, "vupkhsb", int_ppc_altivec_vupkhsb>;
 382 def VUPKHSH : VX2_Int<590, "vupkhsh", int_ppc_altivec_vupkhsh>;
 383 def VUPKLPX : VX2_Int<974, "vupklpx", int_ppc_altivec_vupklpx>;
 384 def VUPKLSB : VX2_Int<654, "vupklsb", int_ppc_altivec_vupklsb>;
 385 def VUPKLSH : VX2_Int<718, "vupklsh", int_ppc_altivec_vupklsh>;
 386
 387
 388 // Altivec Comparisons.
 389
 390 class VCMP<bits<10> xo, string asmstr, ValueType Ty>
 391   : VXRForm_1<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB), asmstr, VecFPCompare,
 392               [(set VRRC:$vD, (Ty (PPCvcmp VRRC:$vA, VRRC:$vB, xo)))]>;
 393 class VCMPo<bits<10> xo, string asmstr, ValueType Ty>
 394   : VXRForm_1<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB), asmstr, VecFPCompare,
 395               [(set VRRC:$vD, (Ty (PPCvcmp_o VRRC:$vA, VRRC:$vB, xo)))]> {
 396   let Defs = [CR6];
 397   let RC = 1;
 398 }
 399
 400 // f32 element comparisons.0
 401 def VCMPBFP   : VCMP <966, "vcmpbfp $vD, $vA, $vB"  , v4f32>;
 402 def VCMPBFPo  : VCMPo<966, "vcmpbfp. $vD, $vA, $vB" , v4f32>;
 403 def VCMPEQFP  : VCMP <198, "vcmpeqfp $vD, $vA, $vB" , v4f32>;
 404 def VCMPEQFPo : VCMPo<198, "vcmpeqfp. $vD, $vA, $vB", v4f32>;
 405 def VCMPGEFP  : VCMP <454, "vcmpgefp $vD, $vA, $vB" , v4f32>;
 406 def VCMPGEFPo : VCMPo<454, "vcmpgefp. $vD, $vA, $vB", v4f32>;
 407 def VCMPGTFP  : VCMP <710, "vcmpgtfp $vD, $vA, $vB" , v4f32>;
 408 def VCMPGTFPo : VCMPo<710, "vcmpgtfp. $vD, $vA, $vB", v4f32>;
 409
 410 // i8 element comparisons.
 411 def VCMPEQUB  : VCMP <  6, "vcmpequb $vD, $vA, $vB" , v16i8>;
 412 def VCMPEQUBo : VCMPo<  6, "vcmpequb. $vD, $vA, $vB", v16i8>;
 413 def VCMPGTSB  : VCMP <774, "vcmpgtsb $vD, $vA, $vB" , v16i8>;
 414 def VCMPGTSBo : VCMPo<774, "vcmpgtsb. $vD, $vA, $vB", v16i8>;
 415 def VCMPGTUB  : VCMP <518, "vcmpgtub $vD, $vA, $vB" , v16i8>;
 416 def VCMPGTUBo : VCMPo<518, "vcmpgtub. $vD, $vA, $vB", v16i8>;
 417
 418 // i16 element comparisons.
 419 def VCMPEQUH  : VCMP < 70, "vcmpequh $vD, $vA, $vB" , v8i16>;
 420 def VCMPEQUHo : VCMPo< 70, "vcmpequh. $vD, $vA, $vB", v8i16>;
 421 def VCMPGTSH  : VCMP <838, "vcmpgtsh $vD, $vA, $vB" , v8i16>;
 422 def VCMPGTSHo : VCMPo<838, "vcmpgtsh. $vD, $vA, $vB", v8i16>;
 423 def VCMPGTUH  : VCMP <582, "vcmpgtuh $vD, $vA, $vB" , v8i16>;
 424 def VCMPGTUHo : VCMPo<582, "vcmpgtuh. $vD, $vA, $vB", v8i16>;
 425
 426 // i32 element comparisons.
 427 def VCMPEQUW  : VCMP <134, "vcmpequw $vD, $vA, $vB" , v4i32>;
 428 def VCMPEQUWo : VCMPo<134, "vcmpequw. $vD, $vA, $vB", v4i32>;
 429 def VCMPGTSW  : VCMP <902, "vcmpgtsw $vD, $vA, $vB" , v4i32>;
 430 def VCMPGTSWo : VCMPo<902, "vcmpgtsw. $vD, $vA, $vB", v4i32>;
 431 def VCMPGTUW  : VCMP <646, "vcmpgtuw $vD, $vA, $vB" , v4i32>;
 432 def VCMPGTUWo : VCMPo<646, "vcmpgtuw. $vD, $vA, $vB", v4i32>;
 433
 434 def V_SET0 : VXForm_setzero<1220, (ops VRRC:$vD),
 435                       "vxor $vD, $vD, $vD", VecFP,
 436                       [(set VRRC:$vD, (v4f32 immAllZerosV))]>;
 437 }
 438
 439 //===----------------------------------------------------------------------===//
 440 // Additional Altivec Patterns
 441 //
 442
 443 // DS* intrinsics.
 444 def : Pat<(int_ppc_altivec_dss imm:$STRM), (DSS 0, imm:$STRM, 0, 0)>;
 445 def : Pat<(int_ppc_altivec_dssall), (DSS 1, 0, 0, 0)>;
 446 def : Pat<(int_ppc_altivec_dst GPRC:$rA, GPRC:$rB, imm:$STRM),
 447           (DST 0, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 448 def : Pat<(int_ppc_altivec_dstt GPRC:$rA, GPRC:$rB, imm:$STRM),
 449           (DST 1, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 450 def : Pat<(int_ppc_altivec_dstst GPRC:$rA, GPRC:$rB, imm:$STRM),
 451           (DSTST 0, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 452 def : Pat<(int_ppc_altivec_dststt GPRC:$rA, GPRC:$rB, imm:$STRM),
 453           (DSTST 1, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 454
 455 // Undef/Zero.
 456 def : Pat<(v16i8 (undef)), (v16i8 (IMPLICIT_DEF_VRRC))>;
 457 def : Pat<(v8i16 (undef)), (v8i16 (IMPLICIT_DEF_VRRC))>;
 458 def : Pat<(v4i32 (undef)), (v4i32 (IMPLICIT_DEF_VRRC))>;
 459 def : Pat<(v16i8 immAllZerosV), (v16i8 (V_SET0))>;
 460 def : Pat<(v8i16 immAllZerosV), (v8i16 (V_SET0))>;
 461 def : Pat<(v4i32 immAllZerosV), (v4i32 (V_SET0))>;
 462
 463 // Loads.
 464 def : Pat<(v16i8 (load xoaddr:$src)), (v16i8 (LVX xoaddr:$src))>;
 465 def : Pat<(v8i16 (load xoaddr:$src)), (v8i16 (LVX xoaddr:$src))>;
 466 def : Pat<(v4i32 (load xoaddr:$src)), (v4i32 (LVX xoaddr:$src))>;
 467 def : Pat<(v4f32 (load xoaddr:$src)), (v4f32 (LVX xoaddr:$src))>;
 468
 469 // Stores.
 470 def : Pat<(store (v16i8 VRRC:$rS), xoaddr:$dst),
 471           (STVX (v16i8 VRRC:$rS), xoaddr:$dst)>;
 472 def : Pat<(store (v8i16 VRRC:$rS), xoaddr:$dst),
 473           (STVX (v8i16 VRRC:$rS), xoaddr:$dst)>;
 474 def : Pat<(store (v4i32 VRRC:$rS), xoaddr:$dst),
 475           (STVX (v4i32 VRRC:$rS), xoaddr:$dst)>;
 476 def : Pat<(store (v4f32 VRRC:$rS), xoaddr:$dst),
 477           (STVX (v4f32 VRRC:$rS), xoaddr:$dst)>;
 478
 479 // Bit conversions.
 480 def : Pat<(v16i8 (bitconvert (v8i16 VRRC:$src))), (v16i8 VRRC:$src)>;
 481 def : Pat<(v16i8 (bitconvert (v4i32 VRRC:$src))), (v16i8 VRRC:$src)>;
 482 def : Pat<(v16i8 (bitconvert (v4f32 VRRC:$src))), (v16i8 VRRC:$src)>;
 483
 484 def : Pat<(v8i16 (bitconvert (v16i8 VRRC:$src))), (v8i16 VRRC:$src)>;
 485 def : Pat<(v8i16 (bitconvert (v4i32 VRRC:$src))), (v8i16 VRRC:$src)>;
 486 def : Pat<(v8i16 (bitconvert (v4f32 VRRC:$src))), (v8i16 VRRC:$src)>;
 487
 488 def : Pat<(v4i32 (bitconvert (v16i8 VRRC:$src))), (v4i32 VRRC:$src)>;
 489 def : Pat<(v4i32 (bitconvert (v8i16 VRRC:$src))), (v4i32 VRRC:$src)>;
 490 def : Pat<(v4i32 (bitconvert (v4f32 VRRC:$src))), (v4i32 VRRC:$src)>;
 491
 492 def : Pat<(v4f32 (bitconvert (v16i8 VRRC:$src))), (v4f32 VRRC:$src)>;
 493 def : Pat<(v4f32 (bitconvert (v8i16 VRRC:$src))), (v4f32 VRRC:$src)>;
 494 def : Pat<(v4f32 (bitconvert (v4i32 VRRC:$src))), (v4f32 VRRC:$src)>;
 495
 496 // Immediate vector formation with vsplti*.
 497 def : Pat<(v16i8 vecspltisb:$invec), (v16i8 (VSPLTISB vecspltisb:$invec))>;
 498 def : Pat<(v16i8 vecspltish:$invec), (v16i8 (VSPLTISH vecspltish:$invec))>;
 499 def : Pat<(v16i8 vecspltisw:$invec), (v16i8 (VSPLTISW vecspltisw:$invec))>;
 500
 501 def : Pat<(v8i16 vecspltisb:$invec), (v8i16 (VSPLTISB vecspltisb:$invec))>;
 502 def : Pat<(v8i16 vecspltish:$invec), (v8i16 (VSPLTISH vecspltish:$invec))>;
 503 def : Pat<(v8i16 vecspltisw:$invec), (v8i16 (VSPLTISW vecspltisw:$invec))>;
 504
 505 def : Pat<(v4i32 vecspltisb:$invec), (v4i32 (VSPLTISB vecspltisb:$invec))>;
 506 def : Pat<(v4i32 vecspltish:$invec), (v4i32 (VSPLTISH vecspltish:$invec))>;
 507 def : Pat<(v4i32 vecspltisw:$invec), (v4i32 (VSPLTISW vecspltisw:$invec))>;
 508
 509 // Logical Operations
 510 def : Pat<(v16i8 (vnot VRRC:$vA)), (v16i8 (VNOR VRRC:$vA, VRRC:$vA))>;
 511 def : Pat<(v8i16 (vnot VRRC:$vA)), (v8i16 (VNOR VRRC:$vA, VRRC:$vA))>;
 512 def : Pat<(v4i32 (vnot VRRC:$vA)), (v4i32 (VNOR VRRC:$vA, VRRC:$vA))>;
 513
 514 def : Pat<(v16i8 (and VRRC:$A, VRRC:$B)), (v16i8 (VAND VRRC:$A, VRRC:$B))>;
 515 def : Pat<(v8i16 (and VRRC:$A, VRRC:$B)), (v8i16 (VAND VRRC:$A, VRRC:$B))>;
 516 def : Pat<(v16i8 (or  VRRC:$A, VRRC:$B)), (v16i8 (VOR  VRRC:$A, VRRC:$B))>;
 517 def : Pat<(v8i16 (or  VRRC:$A, VRRC:$B)), (v8i16 (VOR  VRRC:$A, VRRC:$B))>;
 518 def : Pat<(v16i8 (xor VRRC:$A, VRRC:$B)), (v16i8 (VXOR VRRC:$A, VRRC:$B))>;
 519 def : Pat<(v8i16 (xor VRRC:$A, VRRC:$B)), (v8i16 (VXOR VRRC:$A, VRRC:$B))>;
 520 def : Pat<(v16i8 (vnot (or VRRC:$A, VRRC:$B))),(v16i8 (VNOR VRRC:$A, VRRC:$B))>;
 521 def : Pat<(v8i16 (vnot (or VRRC:$A, VRRC:$B))),(v8i16 (VNOR VRRC:$A, VRRC:$B))>;
 522 def : Pat<(v16i8 (and VRRC:$A, (vnot VRRC:$B))),
 523           (v16i8 (VANDC VRRC:$A, VRRC:$B))>;
 524 def : Pat<(v8i16 (and VRRC:$A, (vnot VRRC:$B))),
 525           (v8i16 (VANDC VRRC:$A, VRRC:$B))>;
 526
 527 def : Pat<(fmul VRRC:$vA, VRRC:$vB),
 528           (VMADDFP VRRC:$vA, VRRC:$vB, (V_SET0))>;
 529
 530 // Fused multiply add and multiply sub for packed float.  These are represented
 531 // separately from the real instructions above, for operations that must have
 532 // the additional precision, such as Newton-Rhapson (used by divide, sqrt)
 533 def : Pat<(PPCvmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 534           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 535 def : Pat<(PPCvnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 536           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 537
 538 def : Pat<(int_ppc_altivec_vmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 539           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 540 def : Pat<(int_ppc_altivec_vnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 541           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 542
 543 def : Pat<(PPCvperm (v16i8 VRRC:$vA), VRRC:$vB, VRRC:$vC),
 544           (v16i8 (VPERM VRRC:$vA, VRRC:$vB, VRRC:$vC))>;